]> Sergey Matveev's repositories - public-inbox.git/blob - lib/PublicInbox/Import.pm
import: drop X-Status in addition to Status
[public-inbox.git] / lib / PublicInbox / Import.pm
1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
3 #
4 # git fast-import-based ssoma-mda MDA replacement
5 # This is only ever run by public-inbox-mda, public-inbox-learn
6 # and public-inbox-watch. Not the WWW or NNTP code which only
7 # requires read-only access.
8 package PublicInbox::Import;
9 use strict;
10 use parent qw(PublicInbox::Lock);
11 use v5.10.1;
12 use PublicInbox::Spawn qw(spawn popen_rd);
13 use PublicInbox::MID qw(mids mid2path);
14 use PublicInbox::Address;
15 use PublicInbox::Smsg;
16 use PublicInbox::MsgTime qw(msg_datestamp);
17 use PublicInbox::ContentHash qw(content_digest);
18 use PublicInbox::MDA;
19 use PublicInbox::Eml;
20 use POSIX qw(strftime);
21
22 sub new {
23         # we can't change arg order, this is documented in POD
24         # and external projects may rely on it:
25         my ($class, $git, $name, $email, $ibx) = @_;
26         my $ref = 'refs/heads/master';
27         if ($ibx) {
28                 $ref = $ibx->{ref_head} // 'refs/heads/master';
29                 $name //= $ibx->{name};
30                 $email //= $ibx->{-primary_address};
31                 $git //= $ibx->git;
32         }
33         bless {
34                 git => $git,
35                 ident => "$name <$email>",
36                 mark => 1,
37                 ref => $ref,
38                 ibx => $ibx,
39                 path_type => '2/38', # or 'v2'
40                 lock_path => "$git->{git_dir}/ssoma.lock", # v2 changes this
41                 bytes_added => 0,
42         }, $class
43 }
44
45 # idempotent start function
46 sub gfi_start {
47         my ($self) = @_;
48
49         return ($self->{in}, $self->{out}) if $self->{pid};
50
51         my (@ret, $out_r, $out_w);
52         pipe($out_r, $out_w) or die "pipe failed: $!";
53
54         $self->lock_acquire;
55         eval {
56                 my ($git, $ref) = @$self{qw(git ref)};
57                 local $/ = "\n";
58                 chomp($self->{tip} = $git->qx(qw(rev-parse --revs-only), $ref));
59                 if ($self->{path_type} ne '2/38' && $self->{tip}) {
60                         local $/ = "\0";
61                         my @t = $git->qx(qw(ls-tree -r -z --name-only), $ref);
62                         chomp @t;
63                         $self->{-tree} = { map { $_ => 1 } @t };
64                 }
65                 my @cmd = ('git', "--git-dir=$git->{git_dir}",
66                         qw(fast-import --quiet --done --date-format=raw));
67                 my ($in_r, $pid) = popen_rd(\@cmd, undef, { 0 => $out_r });
68                 $out_w->autoflush(1);
69                 $self->{in} = $in_r;
70                 $self->{out} = $out_w;
71                 $self->{pid} = $pid;
72                 $self->{nchg} = 0;
73                 @ret = ($in_r, $out_w);
74         };
75         if ($@) {
76                 $self->lock_release;
77                 die $@;
78         }
79         @ret;
80 }
81
82 sub wfail () { die "write to fast-import failed: $!" }
83
84 sub now_raw () { time . ' +0000' }
85
86 sub norm_body ($) {
87         my ($mime) = @_;
88         my $b = $mime->body_raw;
89         $b =~ s/(\r?\n)+\z//s;
90         $b
91 }
92
93 # only used for v1 (ssoma) inboxes
94 sub _check_path ($$$$) {
95         my ($r, $w, $tip, $path) = @_;
96         return if $tip eq '';
97         print $w "ls $tip $path\n" or wfail;
98         local $/ = "\n";
99         defined(my $info = <$r>) or die "EOF from fast-import: $!";
100         $info =~ /\Amissing / ? undef : $info;
101 }
102
103 sub _cat_blob ($$$) {
104         my ($r, $w, $oid) = @_;
105         print $w "cat-blob $oid\n" or wfail;
106         local $/ = "\n";
107         my $info = <$r>;
108         defined $info or die "EOF from fast-import / cat-blob: $!";
109         $info =~ /\A[a-f0-9]{40,} blob ([0-9]+)\n\z/ or return;
110         my $left = $1;
111         my $offset = 0;
112         my $buf = '';
113         my $n;
114         while ($left > 0) {
115                 $n = read($r, $buf, $left, $offset);
116                 defined($n) or die "read cat-blob failed: $!";
117                 $n == 0 and die 'fast-export (cat-blob) died';
118                 $left -= $n;
119                 $offset += $n;
120         }
121         $n = read($r, my $lf, 1);
122         defined($n) or die "read final byte of cat-blob failed: $!";
123         die "bad read on final byte: <$lf>" if $lf ne "\n";
124
125         # fixup some bugginess in old versions:
126         $buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
127         \$buf;
128 }
129
130 sub cat_blob {
131         my ($self, $oid) = @_;
132         my ($r, $w) = $self->gfi_start;
133         _cat_blob($r, $w, $oid);
134 }
135
136 sub check_remove_v1 {
137         my ($r, $w, $tip, $path, $mime) = @_;
138
139         my $info = _check_path($r, $w, $tip, $path) or return ('MISSING',undef);
140         $info =~ m!\A100644 blob ([a-f0-9]{40,})\t!s or die "not blob: $info";
141         my $oid = $1;
142         my $msg = _cat_blob($r, $w, $oid) or die "BUG: cat-blob $1 failed";
143         my $cur = PublicInbox::Eml->new($msg);
144         my $cur_s = $cur->header('Subject');
145         $cur_s = '' unless defined $cur_s;
146         my $cur_m = $mime->header('Subject');
147         $cur_m = '' unless defined $cur_m;
148         if ($cur_s ne $cur_m || norm_body($cur) ne norm_body($mime)) {
149                 return ('MISMATCH', $cur);
150         }
151         (undef, $cur);
152 }
153
154 sub checkpoint {
155         my ($self) = @_;
156         return unless $self->{pid};
157         print { $self->{out} } "checkpoint\n" or wfail;
158         undef;
159 }
160
161 sub progress {
162         my ($self, $msg) = @_;
163         return unless $self->{pid};
164         print { $self->{out} } "progress $msg\n" or wfail;
165         readline($self->{in}) eq "progress $msg\n" or die
166                 "progress $msg not received\n";
167         undef;
168 }
169
170 sub _update_git_info ($$) {
171         my ($self, $do_gc) = @_;
172         # for compatibility with existing ssoma installations
173         # we can probably remove this entirely by 2020
174         my $git_dir = $self->{git}->{git_dir};
175         my @cmd = ('git', "--git-dir=$git_dir");
176         my $index = "$git_dir/ssoma.index";
177         if (-e $index && !$ENV{FAST}) {
178                 my $env = { GIT_INDEX_FILE => $index };
179                 run_die([@cmd, qw(read-tree -m -v -i), $self->{ref}], $env);
180         }
181         eval { run_die([@cmd, 'update-server-info']) };
182         my $ibx = $self->{ibx};
183         if ($ibx && $ibx->version == 1 && -d "$ibx->{inboxdir}/public-inbox" &&
184                                 eval { require PublicInbox::SearchIdx }) {
185                 eval {
186                         my $s = PublicInbox::SearchIdx->new($ibx);
187                         $s->index_sync({ ref => $self->{ref} });
188                 };
189                 warn "$ibx->{inboxdir} index failed: $@\n" if $@;
190         }
191         eval { run_die([@cmd, qw(gc --auto)]) } if $do_gc;
192 }
193
194 sub barrier {
195         my ($self) = @_;
196
197         # For safety, we ensure git checkpoint is complete before because
198         # the data in git is still more important than what is in Xapian
199         # in v2.  Performance may be gained by delaying the ->progress
200         # call but we lose safety
201         if ($self->{nchg}) {
202                 $self->checkpoint;
203                 $self->progress('checkpoint');
204                 _update_git_info($self, 0);
205                 $self->{nchg} = 0;
206         }
207 }
208
209 # used for v2
210 sub get_mark {
211         my ($self, $mark) = @_;
212         die "not active\n" unless $self->{pid};
213         my ($r, $w) = $self->gfi_start;
214         print $w "get-mark $mark\n" or wfail;
215         defined(my $oid = <$r>) or die "get-mark failed, need git 2.6.0+\n";
216         chomp($oid);
217         $oid;
218 }
219
220 # returns undef on non-existent
221 # ('MISMATCH', PublicInbox::Eml) on mismatch
222 # (:MARK, PublicInbox::Eml) on success
223 #
224 # v2 callers should check with Xapian before calling this as
225 # it is not idempotent.
226 sub remove {
227         my ($self, $mime, $msg) = @_; # mime = PublicInbox::Eml or Email::MIME
228
229         my $path_type = $self->{path_type};
230         my ($path, $err, $cur, $blob);
231
232         my ($r, $w) = $self->gfi_start;
233         my $tip = $self->{tip};
234         if ($path_type eq '2/38') {
235                 $path = mid2path(v1_mid0($mime));
236                 ($err, $cur) = check_remove_v1($r, $w, $tip, $path, $mime);
237                 return ($err, $cur) if $err;
238         } else {
239                 my $sref;
240                 if (ref($mime) eq 'SCALAR') { # optimization used by V2Writable
241                         $sref = $mime;
242                 } else { # XXX should not be necessary:
243                         my $str = $mime->as_string;
244                         $sref = \$str;
245                 }
246                 my $len = length($$sref);
247                 $blob = $self->{mark}++;
248                 print $w "blob\nmark :$blob\ndata $len\n",
249                         $$sref, "\n" or wfail;
250         }
251
252         my $ref = $self->{ref};
253         my $commit = $self->{mark}++;
254         my $parent = $tip =~ /\A:/ ? $tip : undef;
255         unless ($parent) {
256                 print $w "reset $ref\n" or wfail;
257         }
258         my $ident = $self->{ident};
259         my $now = now_raw();
260         $msg //= 'rm';
261         my $len = length($msg) + 1;
262         print $w "commit $ref\nmark :$commit\n",
263                 "author $ident $now\n",
264                 "committer $ident $now\n",
265                 "data $len\n$msg\n\n",
266                 'from ', ($parent ? $parent : $tip), "\n" or wfail;
267         if (defined $path) {
268                 print $w "D $path\n\n" or wfail;
269         } else {
270                 clean_tree_v2($self, $w, 'd');
271                 print $w "M 100644 :$blob d\n\n" or wfail;
272         }
273         $self->{nchg}++;
274         (($self->{tip} = ":$commit"), $cur);
275 }
276
277 sub git_timestamp ($) {
278         my ($ts, $zone) = @{$_[0]};
279         $ts = 0 if $ts < 0; # git uses unsigned times
280         "$ts $zone";
281 }
282
283 sub extract_cmt_info ($;$) {
284         my ($mime, $smsg) = @_;
285         # $mime is PublicInbox::Eml, but remains Email::MIME-compatible
286         $smsg //= bless {}, 'PublicInbox::Smsg';
287
288         $smsg->populate($mime);
289
290         my $sender = '';
291         my $from = delete($smsg->{From}) // '';
292         my ($email) = PublicInbox::Address::emails($from);
293         my ($name) = PublicInbox::Address::names($from);
294         if (!defined($name) || !defined($email)) {
295                 $sender = $mime->header('Sender') // '';
296                 $name //= (PublicInbox::Address::names($sender))[0];
297                 $email //= (PublicInbox::Address::emails($sender))[0];
298         }
299         if (defined $email) {
300                 # Email::Address::XS may leave quoted '<' in addresses,
301                 # which git-fast-import doesn't like
302                 $email =~ tr/<>//d;
303
304                 # quiet down wide character warnings with utf8::encode
305                 utf8::encode($email);
306         } else {
307                 $email = '';
308                 warn "no email in From: $from or Sender: $sender\n";
309         }
310
311         # git gets confused with:
312         #  "'A U Thor <u@example.com>' via foo" <foo@example.com>
313         # ref:
314         # <CAD0k6qSUYANxbjjbE4jTW4EeVwOYgBD=bXkSu=akiYC_CB7Ffw@mail.gmail.com>
315         if (defined $name) {
316                 $name =~ tr/<>//d;
317                 utf8::encode($name);
318         } else {
319                 $name = '';
320                 warn "no name in From: $from or Sender: $sender\n";
321         }
322
323         my $subject = delete($smsg->{Subject}) // '(no subject)';
324         utf8::encode($subject);
325         my $at = git_timestamp(delete $smsg->{-ds});
326         my $ct = git_timestamp(delete $smsg->{-ts});
327         ("$name <$email>", $at, $ct, $subject);
328 }
329
330 # kill potentially confusing/misleading headers
331 our @UNWANTED_HEADERS = (qw(Bytes Lines Content-Length),
332                         qw(Status X-Status));
333 sub drop_unwanted_headers ($) {
334         my ($eml) = @_;
335         for (@UNWANTED_HEADERS, @PublicInbox::MDA::BAD_HEADERS) {
336                 $eml->header_set($_);
337         }
338 }
339
340 # used by V2Writable, too
341 sub append_mid ($$) {
342         my ($hdr, $mid0) = @_;
343         # @cur is likely empty if we need to call this sub, but it could
344         # have random unparseable crap which we'll preserve, too.
345         my @cur = $hdr->header_raw('Message-ID');
346         $hdr->header_set('Message-ID', @cur, "<$mid0>");
347 }
348
349 sub v1_mid0 ($) {
350         my ($eml) = @_;
351         my $mids = mids($eml);
352
353         if (!scalar(@$mids)) { # spam often has no Message-ID
354                 my $mid0 = digest2mid(content_digest($eml), $eml);
355                 append_mid($eml, $mid0);
356                 return $mid0;
357         }
358         $mids->[0];
359 }
360 sub clean_tree_v2 ($$$) {
361         my ($self, $w, $keep) = @_;
362         my $tree = $self->{-tree} or return; #v2 only
363         delete $tree->{$keep};
364         foreach (keys %$tree) {
365                 print $w "D $_\n" or wfail;
366         }
367         %$tree = ($keep => 1);
368 }
369
370 # returns undef on duplicate
371 # returns the :MARK of the most recent commit
372 sub add {
373         my ($self, $mime, $check_cb, $smsg) = @_;
374
375         my ($author, $at, $ct, $subject) = extract_cmt_info($mime, $smsg);
376         my $path_type = $self->{path_type};
377         my $path;
378         if ($path_type eq '2/38') {
379                 $path = mid2path(v1_mid0($mime));
380         } else { # v2 layout, one file:
381                 $path = 'm';
382         }
383
384         my ($r, $w) = $self->gfi_start;
385         my $tip = $self->{tip};
386         if ($path_type eq '2/38') {
387                 _check_path($r, $w, $tip, $path) and return;
388         }
389
390         drop_unwanted_headers($mime);
391
392         # spam check:
393         if ($check_cb) {
394                 $mime = $check_cb->($mime, $self->{ibx}) or return;
395         }
396
397         my $blob = $self->{mark}++;
398         my $raw_email = $mime->{-public_inbox_raw} // $mime->as_string;
399         my $n = length($raw_email);
400         $self->{bytes_added} += $n;
401         print $w "blob\nmark :$blob\ndata ", $n, "\n" or wfail;
402         print $w $raw_email, "\n" or wfail;
403
404         # v2: we need this for Xapian
405         if ($smsg) {
406                 $smsg->{blob} = $self->get_mark(":$blob");
407                 $smsg->{raw_bytes} = $n;
408                 $smsg->{-raw_email} = \$raw_email;
409         }
410         my $ref = $self->{ref};
411         my $commit = $self->{mark}++;
412         my $parent = $tip =~ /\A:/ ? $tip : undef;
413
414         unless ($parent) {
415                 print $w "reset $ref\n" or wfail;
416         }
417
418         print $w "commit $ref\nmark :$commit\n",
419                 "author $author $at\n",
420                 "committer $self->{ident} $ct\n" or wfail;
421         print $w "data ", (length($subject) + 1), "\n",
422                 $subject, "\n\n" or wfail;
423         if ($tip ne '') {
424                 print $w 'from ', ($parent ? $parent : $tip), "\n" or wfail;
425         }
426         clean_tree_v2($self, $w, $path);
427         print $w "M 100644 :$blob $path\n\n" or wfail;
428         $self->{nchg}++;
429         $self->{tip} = ":$commit";
430 }
431
432 sub run_die ($;$$) {
433         my ($cmd, $env, $rdr) = @_;
434         my $pid = spawn($cmd, $env, $rdr);
435         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
436         $? == 0 or die join(' ', @$cmd) . " failed: $?\n";
437 }
438
439 my @INIT_FILES = ('HEAD' => "ref: refs/heads/master\n",
440                 'description' => <<EOD,
441 Unnamed repository; edit this file 'description' to name the repository.
442 EOD
443                 'config' => <<EOC);
444 [core]
445         repositoryFormatVersion = 0
446         filemode = true
447         bare = true
448 [repack]
449         writeBitmaps = true
450 EOC
451
452 sub init_bare {
453         my ($dir) = @_; # or self
454         $dir = $dir->{git}->{git_dir} if ref($dir);
455         require File::Path;
456         File::Path::mkpath([ map { "$dir/$_" } qw(objects/info refs/heads) ]);
457         for (my $i = 0; $i < @INIT_FILES; $i++) {
458                 my $f = $dir.'/'.$INIT_FILES[$i++];
459                 next if -f $f;
460                 open my $fh, '>', $f or die "open $f: $!";
461                 print $fh $INIT_FILES[$i] or die "print $f: $!";
462                 close $fh or die "close $f: $!";
463         }
464 }
465
466 # true if locked and active
467 sub active { !!$_[0]->{out} }
468
469 sub done {
470         my ($self) = @_;
471         my $w = delete $self->{out} or return;
472         eval {
473                 my $r = delete $self->{in} or die 'BUG: missing {in} when done';
474                 print $w "done\n" or wfail;
475                 my $pid = delete $self->{pid} or
476                                 die 'BUG: missing {pid} when done';
477                 waitpid($pid, 0) == $pid or die 'fast-import did not finish';
478                 $? == 0 or die "fast-import failed: $?";
479         };
480         my $wait_err = $@;
481         my $nchg = delete $self->{nchg};
482         if ($nchg && !$wait_err) {
483                 eval { _update_git_info($self, 1) };
484                 warn "E: $self->{git}->{git_dir} update info: $@\n" if $@;
485         }
486         $self->lock_release(!!$nchg);
487         $self->{git}->cleanup;
488         die $wait_err if $wait_err;
489 }
490
491 sub atfork_child {
492         my ($self) = @_;
493         foreach my $f (qw(in out)) {
494                 next unless defined($self->{$f});
495                 close $self->{$f} or die "failed to close import[$f]: $!\n";
496         }
497 }
498
499 sub digest2mid ($$) {
500         my ($dig, $hdr) = @_;
501         my $b64 = $dig->clone->b64digest;
502         # Make our own URLs nicer:
503         # See "Base 64 Encoding with URL and Filename Safe Alphabet" in RFC4648
504         $b64 =~ tr!+/=!-_!d;
505
506         # Add a date prefix to prevent a leading '-' in case that trips
507         # up some tools (e.g. if a Message-ID were a expected as a
508         # command-line arg)
509         my $dt = msg_datestamp($hdr);
510         $dt = POSIX::strftime('%Y%m%d%H%M%S', gmtime($dt));
511         "$dt.$b64" . '@z';
512 }
513
514 sub rewrite_commit ($$$$) {
515         my ($self, $oids, $buf, $mime) = @_;
516         my ($author, $at, $ct, $subject);
517         if ($mime) {
518                 ($author, $at, $ct, $subject) = extract_cmt_info($mime);
519         } else {
520                 $author = '<>';
521                 $subject = 'purged '.join(' ', @$oids);
522         }
523         @$oids = ();
524         $subject .= "\n";
525         foreach my $i (0..$#$buf) {
526                 my $l = $buf->[$i];
527                 if ($l =~ /^author .* ([0-9]+ [\+-]?[0-9]+)$/) {
528                         $at //= $1;
529                         $buf->[$i] = "author $author $at\n";
530                 } elsif ($l =~ /^committer .* ([0-9]+ [\+-]?[0-9]+)$/) {
531                         $ct //= $1;
532                         $buf->[$i] = "committer $self->{ident} $ct\n";
533                 } elsif ($l =~ /^data ([0-9]+)/) {
534                         $buf->[$i++] = "data " . length($subject) . "\n";
535                         $buf->[$i] = $subject;
536                         last;
537                 }
538         }
539 }
540
541 # returns the new commit OID if a replacement was done
542 # returns undef if nothing was done
543 sub replace_oids {
544         my ($self, $mime, $replace_map) = @_; # oid => raw string
545         my $tmp = "refs/heads/replace-".((keys %$replace_map)[0]);
546         my $old = $self->{'ref'};
547         my $git = $self->{git};
548         my @export = (qw(fast-export --no-data --use-done-feature), $old);
549         my $rd = $git->popen(@export);
550         my ($r, $w) = $self->gfi_start;
551         my @buf;
552         my $nreplace = 0;
553         my @oids;
554         my ($done, $mark);
555         my $tree = $self->{-tree};
556         while (<$rd>) {
557                 if (/^reset (?:.+)/) {
558                         push @buf, "reset $tmp\n";
559                 } elsif (/^commit (?:.+)/) {
560                         if (@buf) {
561                                 print $w @buf or wfail;
562                                 @buf = ();
563                         }
564                         push @buf, "commit $tmp\n";
565                 } elsif (/^data ([0-9]+)/) {
566                         # only commit message, so $len is small:
567                         my $len = $1; # + 1 for trailing "\n"
568                         push @buf, $_;
569                         my $n = read($rd, my $buf, $len) or die "read: $!";
570                         $len == $n or die "short read ($n < $len)";
571                         push @buf, $buf;
572                 } elsif (/^M 100644 ([a-f0-9]+) (\w+)/) {
573                         my ($oid, $path) = ($1, $2);
574                         $tree->{$path} = 1;
575                         my $sref = $replace_map->{$oid};
576                         if (defined $sref) {
577                                 push @oids, $oid;
578                                 my $n = length($$sref);
579                                 push @buf, "M 100644 inline $path\ndata $n\n";
580                                 push @buf, $$sref; # hope CoW works...
581                                 push @buf, "\n";
582                         } else {
583                                 push @buf, $_;
584                         }
585                 } elsif (/^D (\w+)/) {
586                         my $path = $1;
587                         push @buf, $_ if $tree->{$path};
588                 } elsif ($_ eq "\n") {
589                         if (@oids) {
590                                 if (!$mime) {
591                                         my $out = join('', @buf);
592                                         $out =~ s/^/# /sgm;
593                                         warn "purge rewriting\n", $out, "\n";
594                                 }
595                                 rewrite_commit($self, \@oids, \@buf, $mime);
596                                 $nreplace++;
597                         }
598                         print $w @buf, "\n" or wfail;
599                         @buf = ();
600                 } elsif ($_ eq "done\n") {
601                         $done = 1;
602                 } elsif (/^mark :([0-9]+)$/) {
603                         push @buf, $_;
604                         $mark = $1;
605                 } else {
606                         push @buf, $_;
607                 }
608         }
609         close $rd or die "close fast-export failed: $?";
610         if (@buf) {
611                 print $w @buf or wfail;
612         }
613         die 'done\n not seen from fast-export' unless $done;
614         chomp(my $cmt = $self->get_mark(":$mark")) if $nreplace;
615         $self->{nchg} = 0; # prevent _update_git_info until update-ref:
616         $self->done;
617         my @git = ('git', "--git-dir=$git->{git_dir}");
618
619         run_die([@git, qw(update-ref), $old, $tmp]) if $nreplace;
620
621         run_die([@git, qw(update-ref -d), $tmp]);
622
623         return if $nreplace == 0;
624
625         run_die([@git, qw(-c gc.reflogExpire=now gc --prune=all --quiet)]);
626
627         # check that old OIDs are gone
628         my $err = 0;
629         foreach my $oid (keys %$replace_map) {
630                 my @info = $git->check($oid);
631                 if (@info) {
632                         warn "$oid not replaced\n";
633                         $err++;
634                 }
635         }
636         _update_git_info($self, 0);
637         die "Failed to replace $err object(s)\n" if $err;
638         $cmt;
639 }
640
641 1;
642 __END__
643 =pod
644
645 =head1 NAME
646
647 PublicInbox::Import - message importer for public-inbox v1 inboxes
648
649 =head1 VERSION
650
651 version 1.0
652
653 =head1 SYNOPSIS
654
655         use PublicInbox::Eml;
656         # PublicInbox::Eml exists as of public-inbox 1.5.0,
657         # Email::MIME was used in older versions
658
659         use PublicInbox::Git;
660         use PublicInbox::Import;
661
662         chomp(my $git_dir = `git rev-parse --git-dir`);
663         $git_dir or die "GIT_DIR= must be specified\n";
664         my $git = PublicInbox::Git->new($git_dir);
665         my @committer = ('inbox', 'inbox@example.org');
666         my $im = PublicInbox::Import->new($git, @committer);
667
668         # to add a message:
669         my $message = "From: <u\@example.org>\n".
670                 "Subject: test message \n" .
671                 "Date: Thu, 01 Jan 1970 00:00:00 +0000\n" .
672                 "Message-ID: <m\@example.org>\n".
673                 "\ntest message";
674         my $parsed = PublicInbox::Eml->new($message);
675         my $ret = $im->add($parsed);
676         if (!defined $ret) {
677                 warn "duplicate: ", $parsed->header_raw('Message-ID'), "\n";
678         } else {
679                 print "imported at mark $ret\n";
680         }
681         $im->done;
682
683         # to remove a message
684         my $junk = PublicInbox::Eml->new($message);
685         my ($mark, $orig) = $im->remove($junk);
686         if ($mark eq 'MISSING') {
687                 print "not found\n";
688         } elsif ($mark eq 'MISMATCH') {
689                 print "Message exists but does not match\n\n",
690                         $orig->as_string, "\n",;
691         } else {
692                 print "removed at mark $mark\n\n",
693                         $orig->as_string, "\n";
694         }
695         $im->done;
696
697 =head1 DESCRIPTION
698
699 An importer and remover for public-inboxes which takes C<PublicInbox::Eml>
700 or L<Email::MIME> messages as input and stores them in a git repository as
701 documented in L<https://public-inbox.org/public-inbox-v1-format.txt>,
702 except it does not allow duplicate Message-IDs.
703
704 It requires L<git(1)> and L<git-fast-import(1)> to be installed.
705
706 =head1 METHODS
707
708 =cut
709
710 =head2 new
711
712         my $im = PublicInbox::Import->new($git, @committer);
713
714 Initialize a new PublicInbox::Import object.
715
716 =head2 add
717
718         my $parsed = PublicInbox::Eml->new($message);
719         $im->add($parsed);
720
721 Adds a message to to the git repository.  This will acquire
722 C<$GIT_DIR/ssoma.lock> and start L<git-fast-import(1)> if necessary.
723
724 Messages added will not be visible to other processes until L</done>
725 is called, but L</remove> may be called on them.
726
727 =head2 remove
728
729         my $junk = PublicInbox::Eml->new($message);
730         my ($code, $orig) = $im->remove($junk);
731
732 Removes a message from the repository.  On success, it returns
733 a ':'-prefixed numeric code representing the git-fast-import
734 mark and the original messages as a PublicInbox::Eml
735 (or Email::MIME) object.
736 If the message could not be found, the code is "MISSING"
737 and the original message is undef.  If there is a mismatch where
738 the "Message-ID" is matched but the subject and body do not match,
739 the returned code is "MISMATCH" and the conflicting message
740 is returned as orig.
741
742 =head2 done
743
744 Finalizes the L<git-fast-import(1)> and unlocks the repository.
745 Calling this is required to finalize changes to a repository.
746
747 =head1 SEE ALSO
748
749 L<Email::MIME>
750
751 =head1 CONTACT
752
753 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
754
755 The mail archives are hosted at L<https://public-inbox.org/meta/>
756
757 =head1 COPYRIGHT
758
759 Copyright (C) 2016-2020 all contributors L<mailto:meta@public-inbox.org>
760
761 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>
762
763 =cut