lib/PublicInbox/Import.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # git fast-import-based ssoma-mda MDA replacement
   5 # This is only ever run by public-inbox-mda and public-inbox-learn,
   6 # not the WWW or NNTP code which only requires read-only access.
   7 package PublicInbox::Import;
   8 use strict;
   9 use warnings;
  10 use Fcntl qw(:flock :DEFAULT);
  11 use PublicInbox::Spawn qw(spawn);
  12 use PublicInbox::MID qw(mid_mime mid2path);
  13 use PublicInbox::Address;
  14
  15 sub new {
  16         my ($class, $git, $name, $email, $inbox) = @_;
  17         bless {
  18                 git => $git,
  19                 ident => "$name <$email>",
  20                 mark => 1,
  21                 ref => 'refs/heads/master',
  22                 inbox => $inbox,
  23         }, $class
  24 }
  25
  26 # idempotent start function
  27 sub gfi_start {
  28         my ($self) = @_;
  29
  30         return ($self->{in}, $self->{out}) if $self->{pid};
  31
  32         my ($in_r, $in_w, $out_r, $out_w);
  33         pipe($in_r, $in_w) or die "pipe failed: $!";
  34         pipe($out_r, $out_w) or die "pipe failed: $!";
  35         my $git = $self->{git};
  36         my $git_dir = $git->{git_dir};
  37         my $lockpath = "$git_dir/ssoma.lock";
  38         sysopen(my $lockfh, $lockpath, O_WRONLY|O_CREAT) or
  39                 die "failed to open lock $lockpath: $!";
  40
  41         # wait for other processes to be done
  42         flock($lockfh, LOCK_EX) or die "lock failed: $!\n";
  43         local $/ = "\n";
  44         chomp($self->{tip} = $git->qx(qw(rev-parse --revs-only), $self->{ref}));
  45
  46         my @cmd = ('git', "--git-dir=$git_dir", qw(fast-import
  47                         --quiet --done --date-format=rfc2822));
  48         my $rdr = { 0 => fileno($out_r), 1 => fileno($in_w) };
  49         my $pid = spawn(\@cmd, undef, $rdr);
  50         die "spawn fast-import failed: $!" unless defined $pid;
  51         $out_w->autoflush(1);
  52         $self->{in} = $in_r;
  53         $self->{out} = $out_w;
  54         $self->{lockfh} = $lockfh;
  55         $self->{pid} = $pid;
  56         $self->{nchg} = 0;
  57         binmode $out_w, ':raw' or die "binmode :raw failed: $!";
  58         binmode $in_r, ':raw' or die "binmode :raw failed: $!";
  59         ($in_r, $out_w);
  60 }
  61
  62 sub wfail () { die "write to fast-import failed: $!" }
  63
  64 sub now2822 () {
  65         my @t = gmtime(time);
  66         my $day = qw(Sun Mon Tue Wed Thu Fri Sat)[$t[6]];
  67         my $mon = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec)[$t[4]];
  68
  69         sprintf('%s, %2d %s %d %02d:%02d:%02d +0000',
  70                 $day, $t[3], $mon, $t[5] + 1900, $t[2], $t[1], $t[0]);
  71 }
  72
  73 sub norm_body ($) {
  74         my ($mime) = @_;
  75         my $b = $mime->body_raw;
  76         $b =~ s/(\r?\n)+\z//s;
  77         $b
  78 }
  79
  80 sub _check_path ($$$$) {
  81         my ($r, $w, $tip, $path) = @_;
  82         return if $tip eq '';
  83         print $w "ls $tip $path\n" or wfail;
  84         local $/ = "\n";
  85         defined(my $info = <$r>) or die "EOF from fast-import: $!";
  86         $info =~ /\Amissing / ? undef : $info;
  87 }
  88
  89 # returns undef on non-existent
  90 # ('MISMATCH', msg) on mismatch
  91 # (:MARK, msg) on success
  92 sub remove {
  93         my ($self, $mime) = @_; # mime = Email::MIME
  94
  95         my $mid = mid_mime($mime);
  96         my $path = mid2path($mid);
  97
  98         my ($r, $w) = $self->gfi_start;
  99         my $tip = $self->{tip};
 100         my $info = _check_path($r, $w, $tip, $path) or return ('MISSING',undef);
 101         $info =~ m!\A100644 blob ([a-f0-9]{40})\t!s or die "not blob: $info";
 102         my $blob = $1;
 103
 104         print $w "cat-blob $blob\n" or wfail;
 105         local $/ = "\n";
 106         $info = <$r>;
 107         defined $info or die "EOF from fast-import / cat-blob: $!";
 108         $info =~ /\A[a-f0-9]{40} blob (\d+)\n\z/ or
 109                                 die "unexpected cat-blob response: $info";
 110         my $left = $1;
 111         my $offset = 0;
 112         my $buf = '';
 113         my $n;
 114         while ($left > 0) {
 115                 $n = read($r, $buf, $left, $offset);
 116                 defined($n) or die "read cat-blob failed: $!";
 117                 $n == 0 and die 'fast-export (cat-blob) died';
 118                 $left -= $n;
 119                 $offset += $n;
 120         }
 121         $n = read($r, my $lf, 1);
 122         defined($n) or die "read final byte of cat-blob failed: $!";
 123         die "bad read on final byte: <$lf>" if $lf ne "\n";
 124         my $cur = PublicInbox::MIME->new($buf);
 125         my $cur_s = $cur->header('Subject');
 126         $cur_s = '' unless defined $cur_s;
 127         my $cur_m = $mime->header('Subject');
 128         $cur_m = '' unless defined $cur_m;
 129         if ($cur_s ne $cur_m || norm_body($cur) ne norm_body($mime)) {
 130                 return ('MISMATCH', $cur);
 131         }
 132
 133         my $ref = $self->{ref};
 134         my $commit = $self->{mark}++;
 135         my $parent = $tip =~ /\A:/ ? $tip : undef;
 136         unless ($parent) {
 137                 print $w "reset $ref\n" or wfail;
 138         }
 139         my $ident = $self->{ident};
 140         my $now = now2822();
 141         print $w "commit $ref\nmark :$commit\n",
 142                 "author $ident $now\n",
 143                 "committer $ident $now\n",
 144                 "data 3\nrm\n\n",
 145                 'from ', ($parent ? $parent : $tip), "\n" or wfail;
 146         print $w "D $path\n\n" or wfail;
 147         $self->{nchg}++;
 148         (($self->{tip} = ":$commit"), $cur);
 149 }
 150
 151 # returns undef on duplicate
 152 sub add {
 153         my ($self, $mime, $check_cb) = @_; # mime = Email::MIME
 154
 155         my $from = $mime->header('From');
 156         my ($email) = PublicInbox::Address::emails($from);
 157         my ($name) = PublicInbox::Address::names($from);
 158         # git gets confused with:
 159         #  "'A U Thor <u@example.com>' via foo" <foo@example.com>
 160         # ref:
 161         # <CAD0k6qSUYANxbjjbE4jTW4EeVwOYgBD=bXkSu=akiYC_CB7Ffw@mail.gmail.com>
 162         $name =~ tr/<>//d;
 163
 164         my $date = $mime->header('Date');
 165         my $subject = $mime->header('Subject');
 166         $subject = '(no subject)' unless defined $subject;
 167         my $mid = mid_mime($mime);
 168         my $path = mid2path($mid);
 169
 170         my ($r, $w) = $self->gfi_start;
 171         my $tip = $self->{tip};
 172         _check_path($r, $w, $tip, $path) and return;
 173
 174         # kill potentially confusing/misleading headers
 175         $mime->header_set($_) for qw(bytes lines content-length status);
 176         if ($check_cb) {
 177                 $mime = $check_cb->($mime) or return;
 178         }
 179
 180         $mime = $mime->as_string;
 181         my $blob = $self->{mark}++;
 182         print $w "blob\nmark :$blob\ndata ", length($mime), "\n" or wfail;
 183         print $w $mime, "\n" or wfail;
 184         my $ref = $self->{ref};
 185         my $commit = $self->{mark}++;
 186         my $parent = $tip =~ /\A:/ ? $tip : undef;
 187
 188         unless ($parent) {
 189                 print $w "reset $ref\n" or wfail;
 190         }
 191
 192         utf8::encode($email);
 193         utf8::encode($name);
 194         utf8::encode($subject);
 195         # quiet down wide character warnings:
 196         print $w "commit $ref\nmark :$commit\n",
 197                 "author $name <$email> $date\n",
 198                 "committer $self->{ident} ", now2822(), "\n" or wfail;
 199         print $w "data ", (length($subject) + 1), "\n",
 200                 $subject, "\n\n" or wfail;
 201         if ($tip ne '') {
 202                 print $w 'from ', ($parent ? $parent : $tip), "\n" or wfail;
 203         }
 204         print $w "M 100644 :$blob $path\n\n" or wfail;
 205         $self->{nchg}++;
 206         $self->{tip} = ":$commit";
 207 }
 208
 209 sub run_die ($$) {
 210         my ($cmd, $env) = @_;
 211         my $pid = spawn($cmd, $env, undef);
 212         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 213         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 214         $? == 0 or die join(' ', @$cmd) . " failed: $?\n";
 215 }
 216
 217 sub done {
 218         my ($self) = @_;
 219         my $w = delete $self->{out} or return;
 220         my $r = delete $self->{in} or die 'BUG: missing {in} when done';
 221         print $w "done\n" or wfail;
 222         my $pid = delete $self->{pid} or die 'BUG: missing {pid} when done';
 223         waitpid($pid, 0) == $pid or die 'fast-import did not finish';
 224         $? == 0 or die "fast-import failed: $?";
 225         my $nchg = delete $self->{nchg};
 226
 227         # for compatibility with existing ssoma installations
 228         # we can probably remove this entirely by 2020
 229         my $git_dir = $self->{git}->{git_dir};
 230         # XXX: change the following scope to: if (-e $index) # in 2018 or so..
 231         my @cmd = ('git', "--git-dir=$git_dir");
 232         if ($nchg && !$ENV{FAST}) {
 233                 my $index = "$git_dir/ssoma.index";
 234                 my $env = { GIT_INDEX_FILE => $index };
 235                 run_die([@cmd, qw(read-tree -m -v -i), $self->{ref}], $env);
 236         }
 237         if ($nchg) {
 238                 run_die([@cmd, 'update-server-info'], undef);
 239                 eval {
 240                         require PublicInbox::SearchIdx;
 241                         my $inbox = $self->{inbox} || $git_dir;
 242                         my $s = PublicInbox::SearchIdx->new($inbox);
 243                         $s->index_sync({ ref => $self->{ref} });
 244                 };
 245
 246                 eval { run_die([@cmd, qw(gc --auto)], undef) };
 247         }
 248
 249         my $lockfh = delete $self->{lockfh} or die "BUG: not locked: $!";
 250         flock($lockfh, LOCK_UN) or die "unlock failed: $!";
 251         close $lockfh or die "close lock failed: $!";
 252 }
 253
 254 1;
 255 __END__
 256 =pod
 257
 258 =head1 NAME
 259
 260 PublicInbox::Import - message importer for public-inbox
 261
 262 =head1 VERSION
 263
 264 version 1.0
 265
 266 =head1 SYNOPSYS
 267
 268         use Email::MIME;
 269         use PublicInbox::Git;
 270         use PublicInbox::Import;
 271
 272         chomp(my $git_dir = `git rev-parse --git-dir`);
 273         $git_dir or die "GIT_DIR= must be specified\n";
 274         my $git = PublicInbox::Git->new($git_dir);
 275         my @committer = ('inbox', 'inbox@example.org');
 276         my $im = PublicInbox::Import->new($git, @committer);
 277
 278         # to add a message:
 279         my $message = "From: <u\@example.org>\n".
 280                 "Subject: test message \n" .
 281                 "Date: Thu, 01 Jan 1970 00:00:00 +0000\n" .
 282                 "Message-ID: <m\@example.org>\n".
 283                 "\ntest message";
 284         my $parsed = Email::MIME->new($message);
 285         my $ret = $im->add($parsed);
 286         if (!defined $ret) {
 287                 warn "duplicate: ",
 288                         $parsed->header_obj->header_raw('Message-ID'), "\n";
 289         } else {
 290                 print "imported at mark $ret\n";
 291         }
 292         $im->done;
 293
 294         # to remove a message
 295         my $junk = Email::MIME->new($message);
 296         my ($mark, $orig) = $im->remove($junk);
 297         if ($mark eq 'MISSING') {
 298                 print "not found\n";
 299         } elsif ($mark eq 'MISMATCH') {
 300                 print "Message exists but does not match\n\n",
 301                         $orig->as_string, "\n",;
 302         } else {
 303                 print "removed at mark $mark\n\n",
 304                         $orig->as_string, "\n";
 305         }
 306         $im->done;
 307
 308 =head1 DESCRIPTION
 309
 310 An importer and remover for public-inboxes which takes L<Email::MIME>
 311 messages as input and stores them in a ssoma repository as
 312 documented in L<https://ssoma.public-inbox.org/ssoma_repository.txt>,
 313 except it does not allow duplicate Message-IDs.
 314
 315 It requires L<git(1)> and L<git-fast-import(1)> to be installed.
 316
 317 =head1 METHODS
 318
 319 =cut
 320
 321 =head2 new
 322
 323         my $im = PublicInbox::Import->new($git, @committer);
 324
 325 Initialize a new PublicInbox::Import object.
 326
 327 =head2 add
 328
 329         my $parsed = Email::MIME->new($message);
 330         $im->add($parsed);
 331
 332 Adds a message to to the git repository.  This will acquire
 333 C<$GIT_DIR/ssoma.lock> and start L<git-fast-import(1)> if necessary.
 334
 335 Messages added will not be visible to other processes until L</done>
 336 is called, but L</remove> may be called on them.
 337
 338 =head2 remove
 339
 340         my $junk = Email::MIME->new($message);
 341         my ($code, $orig) = $im->remove($junk);
 342
 343 Removes a message from the repository.  On success, it returns
 344 a ':'-prefixed numeric code representing the git-fast-import
 345 mark and the original messages as an Email::MIME object.
 346 If the message could not be found, the code is "MISSING"
 347 and the original message is undef.  If there is a mismatch where
 348 the "Message-ID" is matched but the subject and body do not match,
 349 the returned code is "MISMATCH" and the conflicting message
 350 is returned as orig.
 351
 352 =head2 done
 353
 354 Finalizes the L<git-fast-import(1)> and unlocks the repository.
 355 Calling this is required to finalize changes to a repository.
 356
 357 =head1 SEE ALSO
 358
 359 L<Email::MIME>
 360
 361 =head1 CONTACT
 362
 363 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
 364
 365 The mail archives are hosted at L<https://public-inbox.org/meta/>
 366
 367 =head1 COPYRIGHT
 368
 369 Copyright (C) 2016 all contributors L<mailto:meta@public-inbox.org>
 370
 371 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>
 372
 373 =cut