lib/PublicInbox/Import.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # git fast-import-based ssoma-mda MDA replacement
   5 # This is only ever run by public-inbox-mda, public-inbox-learn
   6 # and public-inbox-watch. Not the WWW or NNTP code which only
   7 # requires read-only access.
   8 package PublicInbox::Import;
   9 use strict;
  10 use parent qw(PublicInbox::Lock);
  11 use v5.10.1;
  12 use PublicInbox::Spawn qw(spawn popen_rd);
  13 use PublicInbox::MID qw(mids mid2path);
  14 use PublicInbox::Address;
  15 use PublicInbox::Smsg;
  16 use PublicInbox::MsgTime qw(msg_datestamp);
  17 use PublicInbox::ContentHash qw(content_digest);
  18 use PublicInbox::MDA;
  19 use PublicInbox::Eml;
  20 use POSIX qw(strftime);
  21
  22 sub new {
  23         # we can't change arg order, this is documented in POD
  24         # and external projects may rely on it:
  25         my ($class, $git, $name, $email, $ibx) = @_;
  26         my $ref = 'refs/heads/master';
  27         if ($ibx) {
  28                 $ref = $ibx->{ref_head} // 'refs/heads/master';
  29                 $name //= $ibx->{name};
  30                 $email //= $ibx->{-primary_address};
  31                 $git //= $ibx->git;
  32         }
  33         bless {
  34                 git => $git,
  35                 ident => "$name <$email>",
  36                 mark => 1,
  37                 ref => $ref,
  38                 ibx => $ibx,
  39                 path_type => '2/38', # or 'v2'
  40                 lock_path => "$git->{git_dir}/ssoma.lock", # v2 changes this
  41                 bytes_added => 0,
  42         }, $class
  43 }
  44
  45 # idempotent start function
  46 sub gfi_start {
  47         my ($self) = @_;
  48
  49         return ($self->{in}, $self->{out}) if $self->{pid};
  50
  51         my (@ret, $out_r, $out_w);
  52         pipe($out_r, $out_w) or die "pipe failed: $!";
  53
  54         $self->lock_acquire;
  55         eval {
  56                 my ($git, $ref) = @$self{qw(git ref)};
  57                 local $/ = "\n";
  58                 chomp($self->{tip} = $git->qx(qw(rev-parse --revs-only), $ref));
  59                 if ($self->{path_type} ne '2/38' && $self->{tip}) {
  60                         local $/ = "\0";
  61                         my @t = $git->qx(qw(ls-tree -r -z --name-only), $ref);
  62                         chomp @t;
  63                         $self->{-tree} = { map { $_ => 1 } @t };
  64                 }
  65                 my @cmd = ('git', "--git-dir=$git->{git_dir}",
  66                         qw(fast-import --quiet --done --date-format=raw));
  67                 my ($in_r, $pid) = popen_rd(\@cmd, undef, { 0 => $out_r });
  68                 $out_w->autoflush(1);
  69                 $self->{in} = $in_r;
  70                 $self->{out} = $out_w;
  71                 $self->{pid} = $pid;
  72                 $self->{nchg} = 0;
  73                 @ret = ($in_r, $out_w);
  74         };
  75         if ($@) {
  76                 $self->lock_release;
  77                 die $@;
  78         }
  79         @ret;
  80 }
  81
  82 sub wfail () { die "write to fast-import failed: $!" }
  83
  84 sub now_raw () { time . ' +0000' }
  85
  86 sub norm_body ($) {
  87         my ($mime) = @_;
  88         my $b = $mime->body_raw;
  89         $b =~ s/(\r?\n)+\z//s;
  90         $b
  91 }
  92
  93 # only used for v1 (ssoma) inboxes
  94 sub _check_path ($$$$) {
  95         my ($r, $w, $tip, $path) = @_;
  96         return if $tip eq '';
  97         print $w "ls $tip $path\n" or wfail;
  98         local $/ = "\n";
  99         defined(my $info = <$r>) or die "EOF from fast-import: $!";
 100         $info =~ /\Amissing / ? undef : $info;
 101 }
 102
 103 sub _cat_blob ($$$) {
 104         my ($r, $w, $oid) = @_;
 105         print $w "cat-blob $oid\n" or wfail;
 106         local $/ = "\n";
 107         my $info = <$r>;
 108         defined $info or die "EOF from fast-import / cat-blob: $!";
 109         $info =~ /\A[a-f0-9]{40} blob ([0-9]+)\n\z/ or return;
 110         my $left = $1;
 111         my $offset = 0;
 112         my $buf = '';
 113         my $n;
 114         while ($left > 0) {
 115                 $n = read($r, $buf, $left, $offset);
 116                 defined($n) or die "read cat-blob failed: $!";
 117                 $n == 0 and die 'fast-export (cat-blob) died';
 118                 $left -= $n;
 119                 $offset += $n;
 120         }
 121         $n = read($r, my $lf, 1);
 122         defined($n) or die "read final byte of cat-blob failed: $!";
 123         die "bad read on final byte: <$lf>" if $lf ne "\n";
 124
 125         # fixup some bugginess in old versions:
 126         $buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 127         \$buf;
 128 }
 129
 130 sub cat_blob {
 131         my ($self, $oid) = @_;
 132         my ($r, $w) = $self->gfi_start;
 133         _cat_blob($r, $w, $oid);
 134 }
 135
 136 sub check_remove_v1 {
 137         my ($r, $w, $tip, $path, $mime) = @_;
 138
 139         my $info = _check_path($r, $w, $tip, $path) or return ('MISSING',undef);
 140         $info =~ m!\A100644 blob ([a-f0-9]{40})\t!s or die "not blob: $info";
 141         my $oid = $1;
 142         my $msg = _cat_blob($r, $w, $oid) or die "BUG: cat-blob $1 failed";
 143         my $cur = PublicInbox::Eml->new($msg);
 144         my $cur_s = $cur->header('Subject');
 145         $cur_s = '' unless defined $cur_s;
 146         my $cur_m = $mime->header('Subject');
 147         $cur_m = '' unless defined $cur_m;
 148         if ($cur_s ne $cur_m || norm_body($cur) ne norm_body($mime)) {
 149                 return ('MISMATCH', $cur);
 150         }
 151         (undef, $cur);
 152 }
 153
 154 sub checkpoint {
 155         my ($self) = @_;
 156         return unless $self->{pid};
 157         print { $self->{out} } "checkpoint\n" or wfail;
 158         undef;
 159 }
 160
 161 sub progress {
 162         my ($self, $msg) = @_;
 163         return unless $self->{pid};
 164         print { $self->{out} } "progress $msg\n" or wfail;
 165         readline($self->{in}) eq "progress $msg\n" or die
 166                 "progress $msg not received\n";
 167         undef;
 168 }
 169
 170 sub _update_git_info ($$) {
 171         my ($self, $do_gc) = @_;
 172         # for compatibility with existing ssoma installations
 173         # we can probably remove this entirely by 2020
 174         my $git_dir = $self->{git}->{git_dir};
 175         my @cmd = ('git', "--git-dir=$git_dir");
 176         my $index = "$git_dir/ssoma.index";
 177         if (-e $index && !$ENV{FAST}) {
 178                 my $env = { GIT_INDEX_FILE => $index };
 179                 run_die([@cmd, qw(read-tree -m -v -i), $self->{ref}], $env);
 180         }
 181         eval { run_die([@cmd, 'update-server-info']) };
 182         my $ibx = $self->{ibx};
 183         if ($ibx && $ibx->version == 1 && -d "$ibx->{inboxdir}/public-inbox" &&
 184                                 eval { require PublicInbox::SearchIdx }) {
 185                 eval {
 186                         my $s = PublicInbox::SearchIdx->new($ibx);
 187                         $s->index_sync({ ref => $self->{ref} });
 188                 };
 189                 warn "$ibx->{inboxdir} index failed: $@\n" if $@;
 190         }
 191         eval { run_die([@cmd, qw(gc --auto)]) } if $do_gc;
 192 }
 193
 194 sub barrier {
 195         my ($self) = @_;
 196
 197         # For safety, we ensure git checkpoint is complete before because
 198         # the data in git is still more important than what is in Xapian
 199         # in v2.  Performance may be gained by delaying the ->progress
 200         # call but we lose safety
 201         if ($self->{nchg}) {
 202                 $self->checkpoint;
 203                 $self->progress('checkpoint');
 204                 _update_git_info($self, 0);
 205                 $self->{nchg} = 0;
 206         }
 207 }
 208
 209 # used for v2
 210 sub get_mark {
 211         my ($self, $mark) = @_;
 212         die "not active\n" unless $self->{pid};
 213         my ($r, $w) = $self->gfi_start;
 214         print $w "get-mark $mark\n" or wfail;
 215         defined(my $oid = <$r>) or die "get-mark failed, need git 2.6.0+\n";
 216         chomp($oid);
 217         $oid;
 218 }
 219
 220 # returns undef on non-existent
 221 # ('MISMATCH', PublicInbox::Eml) on mismatch
 222 # (:MARK, PublicInbox::Eml) on success
 223 #
 224 # v2 callers should check with Xapian before calling this as
 225 # it is not idempotent.
 226 sub remove {
 227         my ($self, $mime, $msg) = @_; # mime = PublicInbox::Eml or Email::MIME
 228
 229         my $path_type = $self->{path_type};
 230         my ($path, $err, $cur, $blob);
 231
 232         my ($r, $w) = $self->gfi_start;
 233         my $tip = $self->{tip};
 234         if ($path_type eq '2/38') {
 235                 $path = mid2path(v1_mid0($mime));
 236                 ($err, $cur) = check_remove_v1($r, $w, $tip, $path, $mime);
 237                 return ($err, $cur) if $err;
 238         } else {
 239                 my $sref;
 240                 if (ref($mime) eq 'SCALAR') { # optimization used by V2Writable
 241                         $sref = $mime;
 242                 } else { # XXX should not be necessary:
 243                         my $str = $mime->as_string;
 244                         $sref = \$str;
 245                 }
 246                 my $len = length($$sref);
 247                 $blob = $self->{mark}++;
 248                 print $w "blob\nmark :$blob\ndata $len\n",
 249                         $$sref, "\n" or wfail;
 250         }
 251
 252         my $ref = $self->{ref};
 253         my $commit = $self->{mark}++;
 254         my $parent = $tip =~ /\A:/ ? $tip : undef;
 255         unless ($parent) {
 256                 print $w "reset $ref\n" or wfail;
 257         }
 258         my $ident = $self->{ident};
 259         my $now = now_raw();
 260         $msg //= 'rm';
 261         my $len = length($msg) + 1;
 262         print $w "commit $ref\nmark :$commit\n",
 263                 "author $ident $now\n",
 264                 "committer $ident $now\n",
 265                 "data $len\n$msg\n\n",
 266                 'from ', ($parent ? $parent : $tip), "\n" or wfail;
 267         if (defined $path) {
 268                 print $w "D $path\n\n" or wfail;
 269         } else {
 270                 clean_tree_v2($self, $w, 'd');
 271                 print $w "M 100644 :$blob d\n\n" or wfail;
 272         }
 273         $self->{nchg}++;
 274         (($self->{tip} = ":$commit"), $cur);
 275 }
 276
 277 sub git_timestamp ($) {
 278         my ($ts, $zone) = @{$_[0]};
 279         $ts = 0 if $ts < 0; # git uses unsigned times
 280         "$ts $zone";
 281 }
 282
 283 sub extract_cmt_info ($;$) {
 284         my ($mime, $smsg) = @_;
 285         # $mime is PublicInbox::Eml, but remains Email::MIME-compatible
 286         $smsg //= bless {}, 'PublicInbox::Smsg';
 287
 288         $smsg->populate($mime);
 289
 290         my $sender = '';
 291         my $from = delete($smsg->{From}) // '';
 292         my ($email) = PublicInbox::Address::emails($from);
 293         my ($name) = PublicInbox::Address::names($from);
 294         if (!defined($name) || !defined($email)) {
 295                 $sender = $mime->header('Sender') // '';
 296                 $name //= (PublicInbox::Address::names($sender))[0];
 297                 $email //= (PublicInbox::Address::emails($sender))[0];
 298         }
 299         if (defined $email) {
 300                 # Email::Address::XS may leave quoted '<' in addresses,
 301                 # which git-fast-import doesn't like
 302                 $email =~ tr/<>//d;
 303
 304                 # quiet down wide character warnings with utf8::encode
 305                 utf8::encode($email);
 306         } else {
 307                 $email = '';
 308                 warn "no email in From: $from or Sender: $sender\n";
 309         }
 310
 311         # git gets confused with:
 312         #  "'A U Thor <u@example.com>' via foo" <foo@example.com>
 313         # ref:
 314         # <CAD0k6qSUYANxbjjbE4jTW4EeVwOYgBD=bXkSu=akiYC_CB7Ffw@mail.gmail.com>
 315         if (defined $name) {
 316                 $name =~ tr/<>//d;
 317                 utf8::encode($name);
 318         } else {
 319                 $name = '';
 320                 warn "no name in From: $from or Sender: $sender\n";
 321         }
 322
 323         my $subject = delete($smsg->{Subject}) // '(no subject)';
 324         utf8::encode($subject);
 325         my $at = git_timestamp(delete $smsg->{-ds});
 326         my $ct = git_timestamp(delete $smsg->{-ts});
 327         ("$name <$email>", $at, $ct, $subject);
 328 }
 329
 330 # kill potentially confusing/misleading headers
 331 sub drop_unwanted_headers ($) {
 332         my ($mime) = @_;
 333
 334         $mime->header_set($_) for qw(Bytes Lines Content-Length Status);
 335         $mime->header_set($_) for @PublicInbox::MDA::BAD_HEADERS;
 336 }
 337
 338 # used by V2Writable, too
 339 sub append_mid ($$) {
 340         my ($hdr, $mid0) = @_;
 341         # @cur is likely empty if we need to call this sub, but it could
 342         # have random unparseable crap which we'll preserve, too.
 343         my @cur = $hdr->header_raw('Message-ID');
 344         $hdr->header_set('Message-ID', @cur, "<$mid0>");
 345 }
 346
 347 sub v1_mid0 ($) {
 348         my ($eml) = @_;
 349         my $mids = mids($eml);
 350
 351         if (!scalar(@$mids)) { # spam often has no Message-ID
 352                 my $mid0 = digest2mid(content_digest($eml), $eml);
 353                 append_mid($eml, $mid0);
 354                 return $mid0;
 355         }
 356         $mids->[0];
 357 }
 358 sub clean_tree_v2 ($$$) {
 359         my ($self, $w, $keep) = @_;
 360         my $tree = $self->{-tree} or return; #v2 only
 361         delete $tree->{$keep};
 362         foreach (keys %$tree) {
 363                 print $w "D $_\n" or wfail;
 364         }
 365         %$tree = ($keep => 1);
 366 }
 367
 368 # returns undef on duplicate
 369 # returns the :MARK of the most recent commit
 370 sub add {
 371         my ($self, $mime, $check_cb, $smsg) = @_;
 372
 373         my ($author, $at, $ct, $subject) = extract_cmt_info($mime, $smsg);
 374         my $path_type = $self->{path_type};
 375         my $path;
 376         if ($path_type eq '2/38') {
 377                 $path = mid2path(v1_mid0($mime));
 378         } else { # v2 layout, one file:
 379                 $path = 'm';
 380         }
 381
 382         my ($r, $w) = $self->gfi_start;
 383         my $tip = $self->{tip};
 384         if ($path_type eq '2/38') {
 385                 _check_path($r, $w, $tip, $path) and return;
 386         }
 387
 388         drop_unwanted_headers($mime);
 389
 390         # spam check:
 391         if ($check_cb) {
 392                 $mime = $check_cb->($mime, $self->{ibx}) or return;
 393         }
 394
 395         my $blob = $self->{mark}++;
 396         my $raw_email = $mime->{-public_inbox_raw} // $mime->as_string;
 397         my $n = length($raw_email);
 398         $self->{bytes_added} += $n;
 399         print $w "blob\nmark :$blob\ndata ", $n, "\n" or wfail;
 400         print $w $raw_email, "\n" or wfail;
 401
 402         # v2: we need this for Xapian
 403         if ($smsg) {
 404                 $smsg->{blob} = $self->get_mark(":$blob");
 405                 $smsg->{raw_bytes} = $n;
 406                 $smsg->{-raw_email} = \$raw_email;
 407         }
 408         my $ref = $self->{ref};
 409         my $commit = $self->{mark}++;
 410         my $parent = $tip =~ /\A:/ ? $tip : undef;
 411
 412         unless ($parent) {
 413                 print $w "reset $ref\n" or wfail;
 414         }
 415
 416         print $w "commit $ref\nmark :$commit\n",
 417                 "author $author $at\n",
 418                 "committer $self->{ident} $ct\n" or wfail;
 419         print $w "data ", (length($subject) + 1), "\n",
 420                 $subject, "\n\n" or wfail;
 421         if ($tip ne '') {
 422                 print $w 'from ', ($parent ? $parent : $tip), "\n" or wfail;
 423         }
 424         clean_tree_v2($self, $w, $path);
 425         print $w "M 100644 :$blob $path\n\n" or wfail;
 426         $self->{nchg}++;
 427         $self->{tip} = ":$commit";
 428 }
 429
 430 sub run_die ($;$$) {
 431         my ($cmd, $env, $rdr) = @_;
 432         my $pid = spawn($cmd, $env, $rdr);
 433         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 434         $? == 0 or die join(' ', @$cmd) . " failed: $?\n";
 435 }
 436
 437 my @INIT_FILES = ('HEAD' => "ref: refs/heads/master\n",
 438                 'description' => <<EOD,
 439 Unnamed repository; edit this file 'description' to name the repository.
 440 EOD
 441                 'config' => <<EOC);
 442 [core]
 443         repositoryFormatVersion = 0
 444         filemode = true
 445         bare = true
 446 [repack]
 447         writeBitmaps = true
 448 EOC
 449
 450 sub init_bare {
 451         my ($dir) = @_; # or self
 452         $dir = $dir->{git}->{git_dir} if ref($dir);
 453         require File::Path;
 454         File::Path::mkpath([ map { "$dir/$_" } qw(objects/info refs/heads) ]);
 455         for (my $i = 0; $i < @INIT_FILES; $i++) {
 456                 my $f = $dir.'/'.$INIT_FILES[$i++];
 457                 next if -f $f;
 458                 open my $fh, '>', $f or die "open $f: $!";
 459                 print $fh $INIT_FILES[$i] or die "print $f: $!";
 460                 close $fh or die "close $f: $!";
 461         }
 462 }
 463
 464 sub done {
 465         my ($self) = @_;
 466         my $w = delete $self->{out} or return;
 467         eval {
 468                 my $r = delete $self->{in} or die 'BUG: missing {in} when done';
 469                 print $w "done\n" or wfail;
 470                 my $pid = delete $self->{pid} or
 471                                 die 'BUG: missing {pid} when done';
 472                 waitpid($pid, 0) == $pid or die 'fast-import did not finish';
 473                 $? == 0 or die "fast-import failed: $?";
 474         };
 475         my $wait_err = $@;
 476         my $nchg = delete $self->{nchg};
 477         if ($nchg && !$wait_err) {
 478                 eval { _update_git_info($self, 1) };
 479                 warn "E: $self->{git}->{git_dir} update info: $@\n" if $@;
 480         }
 481         $self->lock_release(!!$nchg);
 482         $self->{git}->cleanup;
 483         die $wait_err if $wait_err;
 484 }
 485
 486 sub atfork_child {
 487         my ($self) = @_;
 488         foreach my $f (qw(in out)) {
 489                 next unless defined($self->{$f});
 490                 close $self->{$f} or die "failed to close import[$f]: $!\n";
 491         }
 492 }
 493
 494 sub digest2mid ($$) {
 495         my ($dig, $hdr) = @_;
 496         my $b64 = $dig->clone->b64digest;
 497         # Make our own URLs nicer:
 498         # See "Base 64 Encoding with URL and Filename Safe Alphabet" in RFC4648
 499         $b64 =~ tr!+/=!-_!d;
 500
 501         # Add a date prefix to prevent a leading '-' in case that trips
 502         # up some tools (e.g. if a Message-ID were a expected as a
 503         # command-line arg)
 504         my $dt = msg_datestamp($hdr);
 505         $dt = POSIX::strftime('%Y%m%d%H%M%S', gmtime($dt));
 506         "$dt.$b64" . '@z';
 507 }
 508
 509 sub rewrite_commit ($$$$) {
 510         my ($self, $oids, $buf, $mime) = @_;
 511         my ($author, $at, $ct, $subject);
 512         if ($mime) {
 513                 ($author, $at, $ct, $subject) = extract_cmt_info($mime);
 514         } else {
 515                 $author = '<>';
 516                 $subject = 'purged '.join(' ', @$oids);
 517         }
 518         @$oids = ();
 519         $subject .= "\n";
 520         foreach my $i (0..$#$buf) {
 521                 my $l = $buf->[$i];
 522                 if ($l =~ /^author .* ([0-9]+ [\+-]?[0-9]+)$/) {
 523                         $at //= $1;
 524                         $buf->[$i] = "author $author $at\n";
 525                 } elsif ($l =~ /^committer .* ([0-9]+ [\+-]?[0-9]+)$/) {
 526                         $ct //= $1;
 527                         $buf->[$i] = "committer $self->{ident} $ct\n";
 528                 } elsif ($l =~ /^data ([0-9]+)/) {
 529                         $buf->[$i++] = "data " . length($subject) . "\n";
 530                         $buf->[$i] = $subject;
 531                         last;
 532                 }
 533         }
 534 }
 535
 536 # returns the new commit OID if a replacement was done
 537 # returns undef if nothing was done
 538 sub replace_oids {
 539         my ($self, $mime, $replace_map) = @_; # oid => raw string
 540         my $tmp = "refs/heads/replace-".((keys %$replace_map)[0]);
 541         my $old = $self->{'ref'};
 542         my $git = $self->{git};
 543         my @export = (qw(fast-export --no-data --use-done-feature), $old);
 544         my $rd = $git->popen(@export);
 545         my ($r, $w) = $self->gfi_start;
 546         my @buf;
 547         my $nreplace = 0;
 548         my @oids;
 549         my ($done, $mark);
 550         my $tree = $self->{-tree};
 551         while (<$rd>) {
 552                 if (/^reset (?:.+)/) {
 553                         push @buf, "reset $tmp\n";
 554                 } elsif (/^commit (?:.+)/) {
 555                         if (@buf) {
 556                                 print $w @buf or wfail;
 557                                 @buf = ();
 558                         }
 559                         push @buf, "commit $tmp\n";
 560                 } elsif (/^data ([0-9]+)/) {
 561                         # only commit message, so $len is small:
 562                         my $len = $1; # + 1 for trailing "\n"
 563                         push @buf, $_;
 564                         my $n = read($rd, my $buf, $len) or die "read: $!";
 565                         $len == $n or die "short read ($n < $len)";
 566                         push @buf, $buf;
 567                 } elsif (/^M 100644 ([a-f0-9]+) (\w+)/) {
 568                         my ($oid, $path) = ($1, $2);
 569                         $tree->{$path} = 1;
 570                         my $sref = $replace_map->{$oid};
 571                         if (defined $sref) {
 572                                 push @oids, $oid;
 573                                 my $n = length($$sref);
 574                                 push @buf, "M 100644 inline $path\ndata $n\n";
 575                                 push @buf, $$sref; # hope CoW works...
 576                                 push @buf, "\n";
 577                         } else {
 578                                 push @buf, $_;
 579                         }
 580                 } elsif (/^D (\w+)/) {
 581                         my $path = $1;
 582                         push @buf, $_ if $tree->{$path};
 583                 } elsif ($_ eq "\n") {
 584                         if (@oids) {
 585                                 if (!$mime) {
 586                                         my $out = join('', @buf);
 587                                         $out =~ s/^/# /sgm;
 588                                         warn "purge rewriting\n", $out, "\n";
 589                                 }
 590                                 rewrite_commit($self, \@oids, \@buf, $mime);
 591                                 $nreplace++;
 592                         }
 593                         print $w @buf, "\n" or wfail;
 594                         @buf = ();
 595                 } elsif ($_ eq "done\n") {
 596                         $done = 1;
 597                 } elsif (/^mark :([0-9]+)$/) {
 598                         push @buf, $_;
 599                         $mark = $1;
 600                 } else {
 601                         push @buf, $_;
 602                 }
 603         }
 604         close $rd or die "close fast-export failed: $?";
 605         if (@buf) {
 606                 print $w @buf or wfail;
 607         }
 608         die 'done\n not seen from fast-export' unless $done;
 609         chomp(my $cmt = $self->get_mark(":$mark")) if $nreplace;
 610         $self->{nchg} = 0; # prevent _update_git_info until update-ref:
 611         $self->done;
 612         my @git = ('git', "--git-dir=$git->{git_dir}");
 613
 614         run_die([@git, qw(update-ref), $old, $tmp]) if $nreplace;
 615
 616         run_die([@git, qw(update-ref -d), $tmp]);
 617
 618         return if $nreplace == 0;
 619
 620         run_die([@git, qw(-c gc.reflogExpire=now gc --prune=all --quiet)]);
 621
 622         # check that old OIDs are gone
 623         my $err = 0;
 624         foreach my $oid (keys %$replace_map) {
 625                 my @info = $git->check($oid);
 626                 if (@info) {
 627                         warn "$oid not replaced\n";
 628                         $err++;
 629                 }
 630         }
 631         _update_git_info($self, 0);
 632         die "Failed to replace $err object(s)\n" if $err;
 633         $cmt;
 634 }
 635
 636 1;
 637 __END__
 638 =pod
 639
 640 =head1 NAME
 641
 642 PublicInbox::Import - message importer for public-inbox v1 inboxes
 643
 644 =head1 VERSION
 645
 646 version 1.0
 647
 648 =head1 SYNOPSIS
 649
 650         use PublicInbox::Eml;
 651         # PublicInbox::Eml exists as of public-inbox 1.5.0,
 652         # Email::MIME was used in older versions
 653
 654         use PublicInbox::Git;
 655         use PublicInbox::Import;
 656
 657         chomp(my $git_dir = `git rev-parse --git-dir`);
 658         $git_dir or die "GIT_DIR= must be specified\n";
 659         my $git = PublicInbox::Git->new($git_dir);
 660         my @committer = ('inbox', 'inbox@example.org');
 661         my $im = PublicInbox::Import->new($git, @committer);
 662
 663         # to add a message:
 664         my $message = "From: <u\@example.org>\n".
 665                 "Subject: test message \n" .
 666                 "Date: Thu, 01 Jan 1970 00:00:00 +0000\n" .
 667                 "Message-ID: <m\@example.org>\n".
 668                 "\ntest message";
 669         my $parsed = PublicInbox::Eml->new($message);
 670         my $ret = $im->add($parsed);
 671         if (!defined $ret) {
 672                 warn "duplicate: ", $parsed->header_raw('Message-ID'), "\n";
 673         } else {
 674                 print "imported at mark $ret\n";
 675         }
 676         $im->done;
 677
 678         # to remove a message
 679         my $junk = PublicInbox::Eml->new($message);
 680         my ($mark, $orig) = $im->remove($junk);
 681         if ($mark eq 'MISSING') {
 682                 print "not found\n";
 683         } elsif ($mark eq 'MISMATCH') {
 684                 print "Message exists but does not match\n\n",
 685                         $orig->as_string, "\n",;
 686         } else {
 687                 print "removed at mark $mark\n\n",
 688                         $orig->as_string, "\n";
 689         }
 690         $im->done;
 691
 692 =head1 DESCRIPTION
 693
 694 An importer and remover for public-inboxes which takes C<PublicInbox::Eml>
 695 or L<Email::MIME> messages as input and stores them in a git repository as
 696 documented in L<https://public-inbox.org/public-inbox-v1-format.txt>,
 697 except it does not allow duplicate Message-IDs.
 698
 699 It requires L<git(1)> and L<git-fast-import(1)> to be installed.
 700
 701 =head1 METHODS
 702
 703 =cut
 704
 705 =head2 new
 706
 707         my $im = PublicInbox::Import->new($git, @committer);
 708
 709 Initialize a new PublicInbox::Import object.
 710
 711 =head2 add
 712
 713         my $parsed = PublicInbox::Eml->new($message);
 714         $im->add($parsed);
 715
 716 Adds a message to to the git repository.  This will acquire
 717 C<$GIT_DIR/ssoma.lock> and start L<git-fast-import(1)> if necessary.
 718
 719 Messages added will not be visible to other processes until L</done>
 720 is called, but L</remove> may be called on them.
 721
 722 =head2 remove
 723
 724         my $junk = PublicInbox::Eml->new($message);
 725         my ($code, $orig) = $im->remove($junk);
 726
 727 Removes a message from the repository.  On success, it returns
 728 a ':'-prefixed numeric code representing the git-fast-import
 729 mark and the original messages as a PublicInbox::Eml
 730 (or Email::MIME) object.
 731 If the message could not be found, the code is "MISSING"
 732 and the original message is undef.  If there is a mismatch where
 733 the "Message-ID" is matched but the subject and body do not match,
 734 the returned code is "MISMATCH" and the conflicting message
 735 is returned as orig.
 736
 737 =head2 done
 738
 739 Finalizes the L<git-fast-import(1)> and unlocks the repository.
 740 Calling this is required to finalize changes to a repository.
 741
 742 =head1 SEE ALSO
 743
 744 L<Email::MIME>
 745
 746 =head1 CONTACT
 747
 748 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
 749
 750 The mail archives are hosted at L<https://public-inbox.org/meta/>
 751
 752 =head1 COPYRIGHT
 753
 754 Copyright (C) 2016-2020 all contributors L<mailto:meta@public-inbox.org>
 755
 756 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>
 757
 758 =cut