lib/PublicInbox/Import.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # git fast-import-based ssoma-mda MDA replacement
   5 # This is only ever run by public-inbox-mda, public-inbox-learn
   6 # and public-inbox-watch. Not the WWW or NNTP code which only
   7 # requires read-only access.
   8 package PublicInbox::Import;
   9 use strict;
  10 use warnings;
  11 use base qw(PublicInbox::Lock);
  12 use PublicInbox::Spawn qw(spawn popen_rd);
  13 use PublicInbox::MID qw(mids mid2path);
  14 use PublicInbox::Address;
  15 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  16 use PublicInbox::ContentId qw(content_digest);
  17 use PublicInbox::MDA;
  18 use POSIX qw(strftime);
  19
  20 sub new {
  21         # we can't change arg order, this is documented in POD
  22         # and external projects may rely on it:
  23         my ($class, $git, $name, $email, $ibx) = @_;
  24         my $ref = 'refs/heads/master';
  25         if ($ibx) {
  26                 $ref = $ibx->{ref_head} || 'refs/heads/master';
  27                 $name ||= $ibx->{name};
  28                 $email ||= $ibx->{-primary_address};
  29                 $git ||= $ibx->git;
  30         }
  31         bless {
  32                 git => $git,
  33                 ident => "$name <$email>",
  34                 mark => 1,
  35                 ref => $ref,
  36                 -inbox => $ibx,
  37                 path_type => '2/38', # or 'v2'
  38                 lock_path => "$git->{git_dir}/ssoma.lock", # v2 changes this
  39                 bytes_added => 0,
  40         }, $class
  41 }
  42
  43 # idempotent start function
  44 sub gfi_start {
  45         my ($self) = @_;
  46
  47         return ($self->{in}, $self->{out}) if $self->{pid};
  48
  49         my ($out_r, $out_w);
  50         pipe($out_r, $out_w) or die "pipe failed: $!";
  51         my $git = $self->{git};
  52
  53         $self->lock_acquire;
  54
  55         local $/ = "\n";
  56         my $ref = $self->{ref};
  57         chomp($self->{tip} = $git->qx(qw(rev-parse --revs-only), $ref));
  58         if ($self->{path_type} ne '2/38' && $self->{tip}) {
  59                 local $/ = "\0";
  60                 my @tree = $git->qx(qw(ls-tree -r -z --name-only), $ref);
  61                 chomp @tree;
  62                 $self->{-tree} = { map { $_ => 1 } @tree };
  63         }
  64
  65         my $git_dir = $git->{git_dir};
  66         my @cmd = ('git', "--git-dir=$git_dir", qw(fast-import
  67                         --quiet --done --date-format=raw));
  68         my ($in_r, $pid) = popen_rd(\@cmd, undef, { 0 => $out_r });
  69         $out_w->autoflush(1);
  70         $self->{in} = $in_r;
  71         $self->{out} = $out_w;
  72         $self->{pid} = $pid;
  73         $self->{nchg} = 0;
  74         binmode $out_w, ':raw' or die "binmode :raw failed: $!";
  75         binmode $in_r, ':raw' or die "binmode :raw failed: $!";
  76         ($in_r, $out_w);
  77 }
  78
  79 sub wfail () { die "write to fast-import failed: $!" }
  80
  81 sub now_raw () { time . ' +0000' }
  82
  83 sub norm_body ($) {
  84         my ($mime) = @_;
  85         my $b = $mime->body_raw;
  86         $b =~ s/(\r?\n)+\z//s;
  87         $b
  88 }
  89
  90 # only used for v1 (ssoma) inboxes
  91 sub _check_path ($$$$) {
  92         my ($r, $w, $tip, $path) = @_;
  93         return if $tip eq '';
  94         print $w "ls $tip $path\n" or wfail;
  95         local $/ = "\n";
  96         defined(my $info = <$r>) or die "EOF from fast-import: $!";
  97         $info =~ /\Amissing / ? undef : $info;
  98 }
  99
 100 sub _cat_blob ($$$) {
 101         my ($r, $w, $oid) = @_;
 102         print $w "cat-blob $oid\n" or wfail;
 103         local $/ = "\n";
 104         my $info = <$r>;
 105         defined $info or die "EOF from fast-import / cat-blob: $!";
 106         $info =~ /\A[a-f0-9]{40} blob ([0-9]+)\n\z/ or return;
 107         my $left = $1;
 108         my $offset = 0;
 109         my $buf = '';
 110         my $n;
 111         while ($left > 0) {
 112                 $n = read($r, $buf, $left, $offset);
 113                 defined($n) or die "read cat-blob failed: $!";
 114                 $n == 0 and die 'fast-export (cat-blob) died';
 115                 $left -= $n;
 116                 $offset += $n;
 117         }
 118         $n = read($r, my $lf, 1);
 119         defined($n) or die "read final byte of cat-blob failed: $!";
 120         die "bad read on final byte: <$lf>" if $lf ne "\n";
 121
 122         # fixup some bugginess in old versions:
 123         $buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 124         \$buf;
 125 }
 126
 127 sub cat_blob {
 128         my ($self, $oid) = @_;
 129         my ($r, $w) = $self->gfi_start;
 130         _cat_blob($r, $w, $oid);
 131 }
 132
 133 sub check_remove_v1 {
 134         my ($r, $w, $tip, $path, $mime) = @_;
 135
 136         my $info = _check_path($r, $w, $tip, $path) or return ('MISSING',undef);
 137         $info =~ m!\A100644 blob ([a-f0-9]{40})\t!s or die "not blob: $info";
 138         my $oid = $1;
 139         my $msg = _cat_blob($r, $w, $oid) or die "BUG: cat-blob $1 failed";
 140         my $cur = PublicInbox::MIME->new($msg);
 141         my $cur_s = $cur->header('Subject');
 142         $cur_s = '' unless defined $cur_s;
 143         my $cur_m = $mime->header('Subject');
 144         $cur_m = '' unless defined $cur_m;
 145         if ($cur_s ne $cur_m || norm_body($cur) ne norm_body($mime)) {
 146                 return ('MISMATCH', $cur);
 147         }
 148         (undef, $cur);
 149 }
 150
 151 sub checkpoint {
 152         my ($self) = @_;
 153         return unless $self->{pid};
 154         print { $self->{out} } "checkpoint\n" or wfail;
 155         undef;
 156 }
 157
 158 sub progress {
 159         my ($self, $msg) = @_;
 160         return unless $self->{pid};
 161         print { $self->{out} } "progress $msg\n" or wfail;
 162         $self->{in}->getline eq "progress $msg\n" or die
 163                 "progress $msg not received\n";
 164         undef;
 165 }
 166
 167 sub _update_git_info ($$) {
 168         my ($self, $do_gc) = @_;
 169         # for compatibility with existing ssoma installations
 170         # we can probably remove this entirely by 2020
 171         my $git_dir = $self->{git}->{git_dir};
 172         my @cmd = ('git', "--git-dir=$git_dir");
 173         my $index = "$git_dir/ssoma.index";
 174         if (-e $index && !$ENV{FAST}) {
 175                 my $env = { GIT_INDEX_FILE => $index };
 176                 run_die([@cmd, qw(read-tree -m -v -i), $self->{ref}], $env);
 177         }
 178         run_die([@cmd, 'update-server-info']);
 179         my $ibx = $self->{-inbox};
 180         ($ibx && $self->{path_type} eq '2/38') and eval {
 181                 require PublicInbox::SearchIdx;
 182                 my $s = PublicInbox::SearchIdx->new($ibx);
 183                 $s->index_sync({ ref => $self->{ref} });
 184         };
 185         eval { run_die([@cmd, qw(gc --auto)]) } if $do_gc;
 186 }
 187
 188 sub barrier {
 189         my ($self) = @_;
 190
 191         # For safety, we ensure git checkpoint is complete before because
 192         # the data in git is still more important than what is in Xapian
 193         # in v2.  Performance may be gained by delaying the ->progress
 194         # call but we lose safety
 195         if ($self->{nchg}) {
 196                 $self->checkpoint;
 197                 $self->progress('checkpoint');
 198                 _update_git_info($self, 0);
 199                 $self->{nchg} = 0;
 200         }
 201 }
 202
 203 # used for v2
 204 sub get_mark {
 205         my ($self, $mark) = @_;
 206         die "not active\n" unless $self->{pid};
 207         my ($r, $w) = $self->gfi_start;
 208         print $w "get-mark $mark\n" or wfail;
 209         defined(my $oid = <$r>) or die "get-mark failed, need git 2.6.0+\n";
 210         chomp($oid);
 211         $oid;
 212 }
 213
 214 # returns undef on non-existent
 215 # ('MISMATCH', Email::MIME) on mismatch
 216 # (:MARK, Email::MIME) on success
 217 #
 218 # v2 callers should check with Xapian before calling this as
 219 # it is not idempotent.
 220 sub remove {
 221         my ($self, $mime, $msg) = @_; # mime = Email::MIME
 222
 223         my $path_type = $self->{path_type};
 224         my ($path, $err, $cur, $blob);
 225
 226         my ($r, $w) = $self->gfi_start;
 227         my $tip = $self->{tip};
 228         if ($path_type eq '2/38') {
 229                 $path = mid2path(v1_mid0($mime));
 230                 ($err, $cur) = check_remove_v1($r, $w, $tip, $path, $mime);
 231                 return ($err, $cur) if $err;
 232         } else {
 233                 my $sref;
 234                 if (ref($mime) eq 'SCALAR') { # optimization used by V2Writable
 235                         $sref = $mime;
 236                 } else { # XXX should not be necessary:
 237                         my $str = $mime->as_string;
 238                         $sref = \$str;
 239                 }
 240                 my $len = length($$sref);
 241                 $blob = $self->{mark}++;
 242                 print $w "blob\nmark :$blob\ndata $len\n",
 243                         $$sref, "\n" or wfail;
 244         }
 245
 246         my $ref = $self->{ref};
 247         my $commit = $self->{mark}++;
 248         my $parent = $tip =~ /\A:/ ? $tip : undef;
 249         unless ($parent) {
 250                 print $w "reset $ref\n" or wfail;
 251         }
 252         my $ident = $self->{ident};
 253         my $now = now_raw();
 254         $msg ||= 'rm';
 255         my $len = length($msg) + 1;
 256         print $w "commit $ref\nmark :$commit\n",
 257                 "author $ident $now\n",
 258                 "committer $ident $now\n",
 259                 "data $len\n$msg\n\n",
 260                 'from ', ($parent ? $parent : $tip), "\n" or wfail;
 261         if (defined $path) {
 262                 print $w "D $path\n\n" or wfail;
 263         } else {
 264                 clean_tree_v2($self, $w, 'd');
 265                 print $w "M 100644 :$blob d\n\n" or wfail;
 266         }
 267         $self->{nchg}++;
 268         (($self->{tip} = ":$commit"), $cur);
 269 }
 270
 271 sub git_timestamp {
 272         my ($ts, $zone) = @_;
 273         $ts = 0 if $ts < 0; # git uses unsigned times
 274         "$ts $zone";
 275 }
 276
 277 sub extract_cmt_info ($;$) {
 278         my ($mime, $smsg) = @_;
 279
 280         my $sender = '';
 281         my $from = $mime->header('From');
 282         $from ||= '';
 283         my ($email) = PublicInbox::Address::emails($from);
 284         my ($name) = PublicInbox::Address::names($from);
 285         if (!defined($name) || !defined($email)) {
 286                 $sender = $mime->header('Sender');
 287                 $sender ||= '';
 288                 if (!defined($name)) {
 289                         ($name) = PublicInbox::Address::names($sender);
 290                 }
 291                 if (!defined($email)) {
 292                         ($email) = PublicInbox::Address::emails($sender);
 293                 }
 294         }
 295         if (defined $email) {
 296                 # Email::Address::XS may leave quoted '<' in addresses,
 297                 # which git-fast-import doesn't like
 298                 $email =~ tr/<>//d;
 299
 300                 # quiet down wide character warnings with utf8::encode
 301                 utf8::encode($email);
 302         } else {
 303                 $email = '';
 304                 warn "no email in From: $from or Sender: $sender\n";
 305         }
 306
 307         # git gets confused with:
 308         #  "'A U Thor <u@example.com>' via foo" <foo@example.com>
 309         # ref:
 310         # <CAD0k6qSUYANxbjjbE4jTW4EeVwOYgBD=bXkSu=akiYC_CB7Ffw@mail.gmail.com>
 311         if (defined $name) {
 312                 $name =~ tr/<>//d;
 313                 utf8::encode($name);
 314         } else {
 315                 $name = '';
 316                 warn "no name in From: $from or Sender: $sender\n";
 317         }
 318
 319         my $hdr = $mime->header_obj;
 320
 321         my $subject = $hdr->header('Subject');
 322         $subject = '(no subject)' unless defined $subject;
 323         # Mime decoding can create nulls replace them with spaces to protect git
 324         $subject =~ tr/\0/ /;
 325         utf8::encode($subject);
 326         my $at = git_timestamp(my @at = msg_datestamp($hdr));
 327         my $ct = git_timestamp(my @ct = msg_timestamp($hdr));
 328         if ($smsg) {
 329                 $smsg->{ds} = $at[0];
 330                 $smsg->{ts} = $ct[0];
 331         }
 332         ($name, $email, $at, $ct, $subject);
 333 }
 334
 335 # kill potentially confusing/misleading headers
 336 sub drop_unwanted_headers ($) {
 337         my ($mime) = @_;
 338
 339         $mime->header_set($_) for qw(bytes lines content-length status);
 340         $mime->header_set($_) for @PublicInbox::MDA::BAD_HEADERS;
 341 }
 342
 343 # used by V2Writable, too
 344 sub append_mid ($$) {
 345         my ($hdr, $mid0) = @_;
 346         # @cur is likely empty if we need to call this sub, but it could
 347         # have random unparseable crap which we'll preserve, too.
 348         my @cur = $hdr->header_raw('Message-ID');
 349         $hdr->header_set('Message-ID', @cur, "<$mid0>");
 350 }
 351
 352 sub v1_mid0 ($) {
 353         my ($mime) = @_;
 354         my $hdr = $mime->header_obj;
 355         my $mids = mids($hdr);
 356
 357         if (!scalar(@$mids)) { # spam often has no Message-Id
 358                 my $mid0 = digest2mid(content_digest($mime), $hdr);
 359                 append_mid($hdr, $mid0);
 360                 return $mid0;
 361         }
 362         $mids->[0];
 363 }
 364 sub clean_tree_v2 ($$$) {
 365         my ($self, $w, $keep) = @_;
 366         my $tree = $self->{-tree} or return; #v2 only
 367         delete $tree->{$keep};
 368         foreach (keys %$tree) {
 369                 print $w "D $_\n" or wfail;
 370         }
 371         %$tree = ($keep => 1);
 372 }
 373
 374 # returns undef on duplicate
 375 # returns the :MARK of the most recent commit
 376 sub add {
 377         my ($self, $mime, $check_cb, $smsg) = @_; # mime = Email::MIME
 378
 379         my ($name, $email, $at, $ct, $subject) = extract_cmt_info($mime, $smsg);
 380         my $path_type = $self->{path_type};
 381         my $path;
 382         if ($path_type eq '2/38') {
 383                 $path = mid2path(v1_mid0($mime));
 384         } else { # v2 layout, one file:
 385                 $path = 'm';
 386         }
 387
 388         my ($r, $w) = $self->gfi_start;
 389         my $tip = $self->{tip};
 390         if ($path_type eq '2/38') {
 391                 _check_path($r, $w, $tip, $path) and return;
 392         }
 393
 394         drop_unwanted_headers($mime);
 395
 396         # spam check:
 397         if ($check_cb) {
 398                 $mime = $check_cb->($mime) or return;
 399         }
 400
 401         my $blob = $self->{mark}++;
 402         my $raw_email = $mime->{-public_inbox_raw} // $mime->as_string;
 403         my $n = length($raw_email);
 404         $self->{bytes_added} += $n;
 405         print $w "blob\nmark :$blob\ndata ", $n, "\n" or wfail;
 406         print $w $raw_email, "\n" or wfail;
 407
 408         # v2: we need this for Xapian
 409         if ($smsg) {
 410                 $smsg->{blob} = $self->get_mark(":$blob");
 411                 $smsg->{bytes} = $n;
 412                 $smsg->{-raw_email} = \$raw_email;
 413         }
 414         my $ref = $self->{ref};
 415         my $commit = $self->{mark}++;
 416         my $parent = $tip =~ /\A:/ ? $tip : undef;
 417
 418         unless ($parent) {
 419                 print $w "reset $ref\n" or wfail;
 420         }
 421
 422         print $w "commit $ref\nmark :$commit\n",
 423                 "author $name <$email> $at\n",
 424                 "committer $self->{ident} $ct\n" or wfail;
 425         print $w "data ", (length($subject) + 1), "\n",
 426                 $subject, "\n\n" or wfail;
 427         if ($tip ne '') {
 428                 print $w 'from ', ($parent ? $parent : $tip), "\n" or wfail;
 429         }
 430         clean_tree_v2($self, $w, $path);
 431         print $w "M 100644 :$blob $path\n\n" or wfail;
 432         $self->{nchg}++;
 433         $self->{tip} = ":$commit";
 434 }
 435
 436 sub run_die ($;$$) {
 437         my ($cmd, $env, $rdr) = @_;
 438         my $pid = spawn($cmd, $env, $rdr);
 439         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 440         $? == 0 or die join(' ', @$cmd) . " failed: $?\n";
 441 }
 442
 443 my @INIT_FILES = ('HEAD' => "ref: refs/heads/master\n",
 444                 'description' => <<EOD,
 445 Unnamed repository; edit this file 'description' to name the repository.
 446 EOD
 447                 'config' => <<EOC);
 448 [core]
 449         repositoryFormatVersion = 0
 450         filemode = true
 451         bare = true
 452 [repack]
 453         writeBitmaps = true
 454 EOC
 455
 456 sub init_bare {
 457         my ($dir) = @_; # or self
 458         $dir = $dir->{git}->{git_dir} if ref($dir);
 459         require File::Path;
 460         File::Path::mkpath([ map { "$dir/$_" } qw(objects/info refs/heads) ]);
 461         for (my $i = 0; $i < @INIT_FILES; $i++) {
 462                 my $f = $dir.'/'.$INIT_FILES[$i++];
 463                 next if -f $f;
 464                 open my $fh, '>', $f or die "open $f: $!";
 465                 print $fh $INIT_FILES[$i] or die "print $f: $!";
 466                 close $fh or die "close $f: $!";
 467         }
 468 }
 469
 470 sub done {
 471         my ($self) = @_;
 472         my $w = delete $self->{out} or return;
 473         my $r = delete $self->{in} or die 'BUG: missing {in} when done';
 474         print $w "done\n" or wfail;
 475         my $pid = delete $self->{pid} or die 'BUG: missing {pid} when done';
 476         waitpid($pid, 0) == $pid or die 'fast-import did not finish';
 477         $? == 0 or die "fast-import failed: $?";
 478
 479         _update_git_info($self, 1) if delete $self->{nchg};
 480
 481         $self->lock_release;
 482
 483         $self->{git}->cleanup;
 484 }
 485
 486 sub atfork_child {
 487         my ($self) = @_;
 488         foreach my $f (qw(in out)) {
 489                 next unless defined($self->{$f});
 490                 close $self->{$f} or die "failed to close import[$f]: $!\n";
 491         }
 492 }
 493
 494 sub digest2mid ($$) {
 495         my ($dig, $hdr) = @_;
 496         my $b64 = $dig->clone->b64digest;
 497         # Make our own URLs nicer:
 498         # See "Base 64 Encoding with URL and Filename Safe Alphabet" in RFC4648
 499         $b64 =~ tr!+/=!-_!d;
 500
 501         # Add a date prefix to prevent a leading '-' in case that trips
 502         # up some tools (e.g. if a Message-ID were a expected as a
 503         # command-line arg)
 504         my $dt = msg_datestamp($hdr);
 505         $dt = POSIX::strftime('%Y%m%d%H%M%S', gmtime($dt));
 506         "$dt.$b64" . '@z';
 507 }
 508
 509 sub rewrite_commit ($$$$) {
 510         my ($self, $oids, $buf, $mime) = @_;
 511         my ($name, $email, $at, $ct, $subject);
 512         if ($mime) {
 513                 ($name, $email, $at, $ct, $subject) = extract_cmt_info($mime);
 514         } else {
 515                 $name = $email = '';
 516                 $subject = 'purged '.join(' ', @$oids);
 517         }
 518         @$oids = ();
 519         $subject .= "\n";
 520         foreach my $i (0..$#$buf) {
 521                 my $l = $buf->[$i];
 522                 if ($l =~ /^author .* ([0-9]+ [\+-]?[0-9]+)$/) {
 523                         $at //= $1;
 524                         $buf->[$i] = "author $name <$email> $at\n";
 525                 } elsif ($l =~ /^committer .* ([0-9]+ [\+-]?[0-9]+)$/) {
 526                         $ct //= $1;
 527                         $buf->[$i] = "committer $self->{ident} $ct\n";
 528                 } elsif ($l =~ /^data ([0-9]+)/) {
 529                         $buf->[$i++] = "data " . length($subject) . "\n";
 530                         $buf->[$i] = $subject;
 531                         last;
 532                 }
 533         }
 534 }
 535
 536 # returns the new commit OID if a replacement was done
 537 # returns undef if nothing was done
 538 sub replace_oids {
 539         my ($self, $mime, $replace_map) = @_; # oid => raw string
 540         my $tmp = "refs/heads/replace-".((keys %$replace_map)[0]);
 541         my $old = $self->{'ref'};
 542         my $git = $self->{git};
 543         my @export = (qw(fast-export --no-data --use-done-feature), $old);
 544         my $rd = $git->popen(@export);
 545         my ($r, $w) = $self->gfi_start;
 546         my @buf;
 547         my $nreplace = 0;
 548         my @oids;
 549         my ($done, $mark);
 550         my $tree = $self->{-tree};
 551         while (<$rd>) {
 552                 if (/^reset (?:.+)/) {
 553                         push @buf, "reset $tmp\n";
 554                 } elsif (/^commit (?:.+)/) {
 555                         if (@buf) {
 556                                 $w->print(@buf) or wfail;
 557                                 @buf = ();
 558                         }
 559                         push @buf, "commit $tmp\n";
 560                 } elsif (/^data ([0-9]+)/) {
 561                         # only commit message, so $len is small:
 562                         my $len = $1; # + 1 for trailing "\n"
 563                         push @buf, $_;
 564                         my $n = read($rd, my $buf, $len) or die "read: $!";
 565                         $len == $n or die "short read ($n < $len)";
 566                         push @buf, $buf;
 567                 } elsif (/^M 100644 ([a-f0-9]+) (\w+)/) {
 568                         my ($oid, $path) = ($1, $2);
 569                         $tree->{$path} = 1;
 570                         my $sref = $replace_map->{$oid};
 571                         if (defined $sref) {
 572                                 push @oids, $oid;
 573                                 my $n = length($$sref);
 574                                 push @buf, "M 100644 inline $path\ndata $n\n";
 575                                 push @buf, $$sref; # hope CoW works...
 576                                 push @buf, "\n";
 577                         } else {
 578                                 push @buf, $_;
 579                         }
 580                 } elsif (/^D (\w+)/) {
 581                         my $path = $1;
 582                         push @buf, $_ if $tree->{$path};
 583                 } elsif ($_ eq "\n") {
 584                         if (@oids) {
 585                                 if (!$mime) {
 586                                         my $out = join('', @buf);
 587                                         $out =~ s/^/# /sgm;
 588                                         warn "purge rewriting\n", $out, "\n";
 589                                 }
 590                                 rewrite_commit($self, \@oids, \@buf, $mime);
 591                                 $nreplace++;
 592                         }
 593                         $w->print(@buf, "\n") or wfail;
 594                         @buf = ();
 595                 } elsif ($_ eq "done\n") {
 596                         $done = 1;
 597                 } elsif (/^mark :([0-9]+)$/) {
 598                         push @buf, $_;
 599                         $mark = $1;
 600                 } else {
 601                         push @buf, $_;
 602                 }
 603         }
 604         close $rd or die "close fast-export failed: $?";
 605         if (@buf) {
 606                 $w->print(@buf) or wfail;
 607         }
 608         die 'done\n not seen from fast-export' unless $done;
 609         chomp(my $cmt = $self->get_mark(":$mark")) if $nreplace;
 610         $self->{nchg} = 0; # prevent _update_git_info until update-ref:
 611         $self->done;
 612         my @git = ('git', "--git-dir=$git->{git_dir}");
 613
 614         run_die([@git, qw(update-ref), $old, $tmp]) if $nreplace;
 615
 616         run_die([@git, qw(update-ref -d), $tmp]);
 617
 618         return if $nreplace == 0;
 619
 620         run_die([@git, qw(-c gc.reflogExpire=now gc --prune=all --quiet)]);
 621
 622         # check that old OIDs are gone
 623         my $err = 0;
 624         foreach my $oid (keys %$replace_map) {
 625                 my @info = $git->check($oid);
 626                 if (@info) {
 627                         warn "$oid not replaced\n";
 628                         $err++;
 629                 }
 630         }
 631         _update_git_info($self, 0);
 632         die "Failed to replace $err object(s)\n" if $err;
 633         $cmt;
 634 }
 635
 636 1;
 637 __END__
 638 =pod
 639
 640 =head1 NAME
 641
 642 PublicInbox::Import - message importer for public-inbox v1 inboxes
 643
 644 =head1 VERSION
 645
 646 version 1.0
 647
 648 =head1 SYNOPSIS
 649
 650         use Email::MIME;
 651         use PublicInbox::Git;
 652         use PublicInbox::Import;
 653
 654         chomp(my $git_dir = `git rev-parse --git-dir`);
 655         $git_dir or die "GIT_DIR= must be specified\n";
 656         my $git = PublicInbox::Git->new($git_dir);
 657         my @committer = ('inbox', 'inbox@example.org');
 658         my $im = PublicInbox::Import->new($git, @committer);
 659
 660         # to add a message:
 661         my $message = "From: <u\@example.org>\n".
 662                 "Subject: test message \n" .
 663                 "Date: Thu, 01 Jan 1970 00:00:00 +0000\n" .
 664                 "Message-ID: <m\@example.org>\n".
 665                 "\ntest message";
 666         my $parsed = Email::MIME->new($message);
 667         my $ret = $im->add($parsed);
 668         if (!defined $ret) {
 669                 warn "duplicate: ",
 670                         $parsed->header_obj->header_raw('Message-ID'), "\n";
 671         } else {
 672                 print "imported at mark $ret\n";
 673         }
 674         $im->done;
 675
 676         # to remove a message
 677         my $junk = Email::MIME->new($message);
 678         my ($mark, $orig) = $im->remove($junk);
 679         if ($mark eq 'MISSING') {
 680                 print "not found\n";
 681         } elsif ($mark eq 'MISMATCH') {
 682                 print "Message exists but does not match\n\n",
 683                         $orig->as_string, "\n",;
 684         } else {
 685                 print "removed at mark $mark\n\n",
 686                         $orig->as_string, "\n";
 687         }
 688         $im->done;
 689
 690 =head1 DESCRIPTION
 691
 692 An importer and remover for public-inboxes which takes L<Email::MIME>
 693 messages as input and stores them in a git repository as
 694 documented in L<https://public-inbox.org/public-inbox-v1-format.txt>,
 695 except it does not allow duplicate Message-IDs.
 696
 697 It requires L<git(1)> and L<git-fast-import(1)> to be installed.
 698
 699 =head1 METHODS
 700
 701 =cut
 702
 703 =head2 new
 704
 705         my $im = PublicInbox::Import->new($git, @committer);
 706
 707 Initialize a new PublicInbox::Import object.
 708
 709 =head2 add
 710
 711         my $parsed = Email::MIME->new($message);
 712         $im->add($parsed);
 713
 714 Adds a message to to the git repository.  This will acquire
 715 C<$GIT_DIR/ssoma.lock> and start L<git-fast-import(1)> if necessary.
 716
 717 Messages added will not be visible to other processes until L</done>
 718 is called, but L</remove> may be called on them.
 719
 720 =head2 remove
 721
 722         my $junk = Email::MIME->new($message);
 723         my ($code, $orig) = $im->remove($junk);
 724
 725 Removes a message from the repository.  On success, it returns
 726 a ':'-prefixed numeric code representing the git-fast-import
 727 mark and the original messages as an Email::MIME object.
 728 If the message could not be found, the code is "MISSING"
 729 and the original message is undef.  If there is a mismatch where
 730 the "Message-ID" is matched but the subject and body do not match,
 731 the returned code is "MISMATCH" and the conflicting message
 732 is returned as orig.
 733
 734 =head2 done
 735
 736 Finalizes the L<git-fast-import(1)> and unlocks the repository.
 737 Calling this is required to finalize changes to a repository.
 738
 739 =head1 SEE ALSO
 740
 741 L<Email::MIME>
 742
 743 =head1 CONTACT
 744
 745 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
 746
 747 The mail archives are hosted at L<https://public-inbox.org/meta/>
 748
 749 =head1 COPYRIGHT
 750
 751 Copyright (C) 2016 all contributors L<mailto:meta@public-inbox.org>
 752
 753 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>
 754
 755 =cut