lib/PublicInbox/Import.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # git fast-import-based ssoma-mda MDA replacement
   5 # This is only ever run by public-inbox-mda and public-inbox-learn,
   6 # not the WWW or NNTP code which only requires read-only access.
   7 package PublicInbox::Import;
   8 use strict;
   9 use warnings;
  10 use base qw(PublicInbox::Lock);
  11 use PublicInbox::Spawn qw(spawn);
  12 use PublicInbox::MID qw(mids mid_mime mid2path);
  13 use PublicInbox::Address;
  14 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  15 use PublicInbox::ContentId qw(content_digest);
  16 use PublicInbox::MDA;
  17
  18 sub new {
  19         my ($class, $git, $name, $email, $ibx) = @_;
  20         my $ref = 'refs/heads/master';
  21         if ($ibx) {
  22                 $ref = $ibx->{ref_head} || 'refs/heads/master';
  23                 $name ||= $ibx->{name};
  24                 $email ||= $ibx->{-primary_address};
  25         }
  26         bless {
  27                 git => $git,
  28                 ident => "$name <$email>",
  29                 mark => 1,
  30                 ref => $ref,
  31                 inbox => $ibx,
  32                 path_type => '2/38', # or 'v2'
  33                 lock_path => "$git->{git_dir}/ssoma.lock", # v2 changes this
  34                 bytes_added => 0,
  35         }, $class
  36 }
  37
  38 # idempotent start function
  39 sub gfi_start {
  40         my ($self) = @_;
  41
  42         return ($self->{in}, $self->{out}) if $self->{pid};
  43
  44         my ($in_r, $in_w, $out_r, $out_w);
  45         pipe($in_r, $in_w) or die "pipe failed: $!";
  46         pipe($out_r, $out_w) or die "pipe failed: $!";
  47         my $git = $self->{git};
  48
  49         $self->lock_acquire;
  50
  51         local $/ = "\n";
  52         chomp($self->{tip} = $git->qx(qw(rev-parse --revs-only), $self->{ref}));
  53
  54         my $git_dir = $git->{git_dir};
  55         my @cmd = ('git', "--git-dir=$git_dir", qw(fast-import
  56                         --quiet --done --date-format=raw));
  57         my $rdr = { 0 => fileno($out_r), 1 => fileno($in_w) };
  58         my $pid = spawn(\@cmd, undef, $rdr);
  59         die "spawn fast-import failed: $!" unless defined $pid;
  60         $out_w->autoflush(1);
  61         $self->{in} = $in_r;
  62         $self->{out} = $out_w;
  63         $self->{pid} = $pid;
  64         $self->{nchg} = 0;
  65         binmode $out_w, ':raw' or die "binmode :raw failed: $!";
  66         binmode $in_r, ':raw' or die "binmode :raw failed: $!";
  67         ($in_r, $out_w);
  68 }
  69
  70 sub wfail () { die "write to fast-import failed: $!" }
  71
  72 sub now_raw () { time . ' +0000' }
  73
  74 sub norm_body ($) {
  75         my ($mime) = @_;
  76         my $b = $mime->body_raw;
  77         $b =~ s/(\r?\n)+\z//s;
  78         $b
  79 }
  80
  81 # only used for v1 (ssoma) inboxes
  82 sub _check_path ($$$$) {
  83         my ($r, $w, $tip, $path) = @_;
  84         return if $tip eq '';
  85         print $w "ls $tip $path\n" or wfail;
  86         local $/ = "\n";
  87         defined(my $info = <$r>) or die "EOF from fast-import: $!";
  88         $info =~ /\Amissing / ? undef : $info;
  89 }
  90
  91 sub check_remove_v1 {
  92         my ($r, $w, $tip, $path, $mime) = @_;
  93
  94         my $info = _check_path($r, $w, $tip, $path) or return ('MISSING',undef);
  95         $info =~ m!\A100644 blob ([a-f0-9]{40})\t!s or die "not blob: $info";
  96         my $blob = $1;
  97
  98         print $w "cat-blob $blob\n" or wfail;
  99         local $/ = "\n";
 100         $info = <$r>;
 101         defined $info or die "EOF from fast-import / cat-blob: $!";
 102         $info =~ /\A[a-f0-9]{40} blob (\d+)\n\z/ or
 103                                 die "unexpected cat-blob response: $info";
 104         my $left = $1;
 105         my $offset = 0;
 106         my $buf = '';
 107         my $n;
 108         while ($left > 0) {
 109                 $n = read($r, $buf, $left, $offset);
 110                 defined($n) or die "read cat-blob failed: $!";
 111                 $n == 0 and die 'fast-export (cat-blob) died';
 112                 $left -= $n;
 113                 $offset += $n;
 114         }
 115         $n = read($r, my $lf, 1);
 116         defined($n) or die "read final byte of cat-blob failed: $!";
 117         die "bad read on final byte: <$lf>" if $lf ne "\n";
 118         my $cur = PublicInbox::MIME->new(\$buf);
 119         my $cur_s = $cur->header('Subject');
 120         $cur_s = '' unless defined $cur_s;
 121         my $cur_m = $mime->header('Subject');
 122         $cur_m = '' unless defined $cur_m;
 123         if ($cur_s ne $cur_m || norm_body($cur) ne norm_body($mime)) {
 124                 return ('MISMATCH', $cur);
 125         }
 126         (undef, $cur);
 127 }
 128
 129 sub checkpoint {
 130         my ($self) = @_;
 131         return unless $self->{pid};
 132         print { $self->{out} } "checkpoint\n" or wfail;
 133         undef;
 134 }
 135
 136 sub progress {
 137         my ($self, $msg) = @_;
 138         return unless $self->{pid};
 139         print { $self->{out} } "progress $msg\n" or wfail;
 140         $self->{in}->getline eq "progress $msg\n" or die
 141                 "progress $msg not received\n";
 142         undef;
 143 }
 144
 145 sub _update_git_info ($$) {
 146         my ($self, $do_gc) = @_;
 147         # for compatibility with existing ssoma installations
 148         # we can probably remove this entirely by 2020
 149         my $git_dir = $self->{git}->{git_dir};
 150         my @cmd = ('git', "--git-dir=$git_dir");
 151         my $index = "$git_dir/ssoma.index";
 152         if (-e $index && !$ENV{FAST}) {
 153                 my $env = { GIT_INDEX_FILE => $index };
 154                 run_die([@cmd, qw(read-tree -m -v -i), $self->{ref}], $env);
 155         }
 156         run_die([@cmd, 'update-server-info'], undef);
 157         ($self->{path_type} eq '2/38') and eval {
 158                 require PublicInbox::SearchIdx;
 159                 my $inbox = $self->{inbox} || $git_dir;
 160                 my $s = PublicInbox::SearchIdx->new($inbox);
 161                 $s->index_sync({ ref => $self->{ref} });
 162         };
 163         eval { run_die([@cmd, qw(gc --auto)], undef) } if $do_gc;
 164 }
 165
 166 sub barrier {
 167         my ($self) = @_;
 168
 169         # For safety, we ensure git checkpoint is complete before because
 170         # the data in git is still more important than what is in Xapian
 171         # in v2.  Performance may be gained by delaying the ->progress
 172         # call but we lose safety
 173         if ($self->{nchg}) {
 174                 $self->checkpoint;
 175                 $self->progress('checkpoint');
 176                 _update_git_info($self, 0);
 177                 $self->{nchg} = 0;
 178         }
 179 }
 180
 181 # used for v2
 182 sub get_mark {
 183         my ($self, $mark) = @_;
 184         die "not active\n" unless $self->{pid};
 185         my ($r, $w) = $self->gfi_start;
 186         print $w "get-mark $mark\n" or wfail;
 187         defined(my $oid = <$r>) or die "get-mark failed, need git 2.6.0+\n";
 188         $oid;
 189 }
 190
 191 # returns undef on non-existent
 192 # ('MISMATCH', Email::MIME) on mismatch
 193 # (:MARK, Email::MIME) on success
 194 #
 195 # v2 callers should check with Xapian before calling this as
 196 # it is not idempotent.
 197 sub remove {
 198         my ($self, $mime, $msg) = @_; # mime = Email::MIME
 199
 200         my $path_type = $self->{path_type};
 201         my ($path, $err, $cur, $blob);
 202
 203         my ($r, $w) = $self->gfi_start;
 204         my $tip = $self->{tip};
 205         if ($path_type eq '2/38') {
 206                 $path = mid2path(mid_mime($mime));
 207                 ($err, $cur) = check_remove_v1($r, $w, $tip, $path, $mime);
 208                 return ($err, $cur) if $err;
 209         } else {
 210                 my $sref;
 211                 if (ref($mime) eq 'SCALAR') { # optimization used by V2Writable
 212                         $sref = $mime;
 213                 } else { # XXX should not be necessary:
 214                         my $str = $mime->as_string;
 215                         $sref = \$str;
 216                 }
 217                 my $len = length($$sref);
 218                 $blob = $self->{mark}++;
 219                 print $w "blob\nmark :$blob\ndata $len\n",
 220                         $$sref, "\n" or wfail;
 221         }
 222
 223         my $ref = $self->{ref};
 224         my $commit = $self->{mark}++;
 225         my $parent = $tip =~ /\A:/ ? $tip : undef;
 226         unless ($parent) {
 227                 print $w "reset $ref\n" or wfail;
 228         }
 229         my $ident = $self->{ident};
 230         my $now = now_raw();
 231         $msg ||= 'rm';
 232         my $len = length($msg) + 1;
 233         print $w "commit $ref\nmark :$commit\n",
 234                 "author $ident $now\n",
 235                 "committer $ident $now\n",
 236                 "data $len\n$msg\n\n",
 237                 'from ', ($parent ? $parent : $tip), "\n" or wfail;
 238         if (defined $path) {
 239                 print $w "D $path\n\n" or wfail;
 240         } else {
 241                 print $w "M 100644 :$blob _/D\n\n" or wfail;
 242         }
 243         $self->{nchg}++;
 244         (($self->{tip} = ":$commit"), $cur);
 245 }
 246
 247 sub git_timestamp {
 248         my ($ts, $zone) = @_;
 249         $ts = 0 if $ts < 0; # git uses unsigned times
 250         "$ts $zone";
 251 }
 252
 253 sub extract_author_info ($) {
 254         my ($mime) = @_;
 255
 256         my $sender = '';
 257         my $from = $mime->header('From');
 258         my ($email) = PublicInbox::Address::emails($from);
 259         my ($name) = PublicInbox::Address::names($from);
 260         if (!defined($name) || !defined($email)) {
 261                 $sender = $mime->header('Sender');
 262                 if (!defined($name)) {
 263                         ($name) = PublicInbox::Address::names($sender);
 264                 }
 265                 if (!defined($email)) {
 266                         ($email) = PublicInbox::Address::emails($sender);
 267                 }
 268         }
 269         if (defined $email) {
 270                 # quiet down wide character warnings with utf8::encode
 271                 utf8::encode($email);
 272         } else {
 273                 $email = '';
 274                 warn "no email in From: $from or Sender: $sender\n";
 275         }
 276
 277         # git gets confused with:
 278         #  "'A U Thor <u@example.com>' via foo" <foo@example.com>
 279         # ref:
 280         # <CAD0k6qSUYANxbjjbE4jTW4EeVwOYgBD=bXkSu=akiYC_CB7Ffw@mail.gmail.com>
 281         if (defined $name) {
 282                 $name =~ tr/<>//d;
 283                 utf8::encode($name);
 284         } else {
 285                 $name = '';
 286                 warn "no name in From: $from or Sender: $sender\n";
 287         }
 288         ($name, $email);
 289 }
 290
 291 # kill potentially confusing/misleading headers
 292 sub drop_unwanted_headers ($) {
 293         my ($mime) = @_;
 294
 295         $mime->header_set($_) for qw(bytes lines content-length status);
 296         $mime->header_set($_) for @PublicInbox::MDA::BAD_HEADERS;
 297 }
 298
 299 # returns undef on duplicate
 300 # returns the :MARK of the most recent commit
 301 sub add {
 302         my ($self, $mime, $check_cb) = @_; # mime = Email::MIME
 303
 304         my ($name, $email) = extract_author_info($mime);
 305         my $hdr = $mime->header_obj;
 306         my @at = msg_datestamp($hdr);
 307         my @ct = msg_timestamp($hdr);
 308         my $author_time_raw = git_timestamp(@at);
 309         my $commit_time_raw = git_timestamp(@ct);
 310         my $subject = $mime->header('Subject');
 311         $subject = '(no subject)' unless defined $subject;
 312         my $path_type = $self->{path_type};
 313
 314         my $path;
 315         if ($path_type eq '2/38') {
 316                 my $mids = mids($mime->header_obj);
 317                 if (!scalar(@$mids)) {
 318                         my $dig = content_digest($mime);
 319                         @$mids = (digest2mid($dig));
 320                 }
 321                 $path = mid2path($mids->[0]);
 322         } else { # v2 layout, one file:
 323                 $path = 'm';
 324         }
 325
 326         my ($r, $w) = $self->gfi_start;
 327         my $tip = $self->{tip};
 328         if ($path_type eq '2/38') {
 329                 _check_path($r, $w, $tip, $path) and return;
 330         }
 331
 332         drop_unwanted_headers($mime);
 333
 334         # spam check:
 335         if ($check_cb) {
 336                 $mime = $check_cb->($mime) or return;
 337         }
 338
 339         my $blob = $self->{mark}++;
 340         my $str = $mime->as_string;
 341         my $n = length($str);
 342         $self->{bytes_added} += $n;
 343         print $w "blob\nmark :$blob\ndata ", $n, "\n" or wfail;
 344         print $w $str, "\n" or wfail;
 345
 346         # v2: we need this for Xapian
 347         if ($self->{want_object_info}) {
 348                 chomp(my $oid = $self->get_mark(":$blob"));
 349                 $self->{last_object} = [ $oid, $n, \$str ];
 350         }
 351         my $ref = $self->{ref};
 352         my $commit = $self->{mark}++;
 353         my $parent = $tip =~ /\A:/ ? $tip : undef;
 354
 355         unless ($parent) {
 356                 print $w "reset $ref\n" or wfail;
 357         }
 358
 359         utf8::encode($subject);
 360         print $w "commit $ref\nmark :$commit\n",
 361                 "author $name <$email> $author_time_raw\n",
 362                 "committer $self->{ident} $commit_time_raw\n" or wfail;
 363         print $w "data ", (length($subject) + 1), "\n",
 364                 $subject, "\n\n" or wfail;
 365         if ($tip ne '') {
 366                 print $w 'from ', ($parent ? $parent : $tip), "\n" or wfail;
 367         }
 368         print $w "M 100644 :$blob $path\n\n" or wfail;
 369         $self->{nchg}++;
 370         $self->{tip} = ":$commit";
 371 }
 372
 373 sub run_die ($;$) {
 374         my ($cmd, $env) = @_;
 375         my $pid = spawn($cmd, $env, undef);
 376         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 377         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 378         $? == 0 or die join(' ', @$cmd) . " failed: $?\n";
 379 }
 380
 381 sub done {
 382         my ($self) = @_;
 383         my $w = delete $self->{out} or return;
 384         my $r = delete $self->{in} or die 'BUG: missing {in} when done';
 385         print $w "done\n" or wfail;
 386         my $pid = delete $self->{pid} or die 'BUG: missing {pid} when done';
 387         waitpid($pid, 0) == $pid or die 'fast-import did not finish';
 388         $? == 0 or die "fast-import failed: $?";
 389
 390         _update_git_info($self, 1) if delete $self->{nchg};
 391
 392         $self->lock_release;
 393 }
 394
 395 sub atfork_child {
 396         my ($self) = @_;
 397         foreach my $f (qw(in out)) {
 398                 close $self->{$f} or die "failed to close import[$f]: $!\n";
 399         }
 400 }
 401
 402 sub digest2mid ($) {
 403         my ($dig) = @_;
 404         my $b64 = $dig->clone->b64digest;
 405         # Make our own URLs nicer:
 406         # See "Base 64 Encoding with URL and Filename Safe Alphabet" in RFC4648
 407         $b64 =~ tr!+/=!-_!d;
 408
 409         # We can make this more meaningful with a date prefix or other things,
 410         # but this is only needed for crap that fails to generate a Message-ID
 411         # or reuses one.  In other words, it's usually spammers who hit this
 412         # so they don't deserve nice Message-IDs :P
 413         $b64 . '@localhost';
 414 }
 415
 416 1;
 417 __END__
 418 =pod
 419
 420 =head1 NAME
 421
 422 PublicInbox::Import - message importer for public-inbox
 423
 424 =head1 VERSION
 425
 426 version 1.0
 427
 428 =head1 SYNOPSYS
 429
 430         use Email::MIME;
 431         use PublicInbox::Git;
 432         use PublicInbox::Import;
 433
 434         chomp(my $git_dir = `git rev-parse --git-dir`);
 435         $git_dir or die "GIT_DIR= must be specified\n";
 436         my $git = PublicInbox::Git->new($git_dir);
 437         my @committer = ('inbox', 'inbox@example.org');
 438         my $im = PublicInbox::Import->new($git, @committer);
 439
 440         # to add a message:
 441         my $message = "From: <u\@example.org>\n".
 442                 "Subject: test message \n" .
 443                 "Date: Thu, 01 Jan 1970 00:00:00 +0000\n" .
 444                 "Message-ID: <m\@example.org>\n".
 445                 "\ntest message";
 446         my $parsed = Email::MIME->new($message);
 447         my $ret = $im->add($parsed);
 448         if (!defined $ret) {
 449                 warn "duplicate: ",
 450                         $parsed->header_obj->header_raw('Message-ID'), "\n";
 451         } else {
 452                 print "imported at mark $ret\n";
 453         }
 454         $im->done;
 455
 456         # to remove a message
 457         my $junk = Email::MIME->new($message);
 458         my ($mark, $orig) = $im->remove($junk);
 459         if ($mark eq 'MISSING') {
 460                 print "not found\n";
 461         } elsif ($mark eq 'MISMATCH') {
 462                 print "Message exists but does not match\n\n",
 463                         $orig->as_string, "\n",;
 464         } else {
 465                 print "removed at mark $mark\n\n",
 466                         $orig->as_string, "\n";
 467         }
 468         $im->done;
 469
 470 =head1 DESCRIPTION
 471
 472 An importer and remover for public-inboxes which takes L<Email::MIME>
 473 messages as input and stores them in a ssoma repository as
 474 documented in L<https://ssoma.public-inbox.org/ssoma_repository.txt>,
 475 except it does not allow duplicate Message-IDs.
 476
 477 It requires L<git(1)> and L<git-fast-import(1)> to be installed.
 478
 479 =head1 METHODS
 480
 481 =cut
 482
 483 =head2 new
 484
 485         my $im = PublicInbox::Import->new($git, @committer);
 486
 487 Initialize a new PublicInbox::Import object.
 488
 489 =head2 add
 490
 491         my $parsed = Email::MIME->new($message);
 492         $im->add($parsed);
 493
 494 Adds a message to to the git repository.  This will acquire
 495 C<$GIT_DIR/ssoma.lock> and start L<git-fast-import(1)> if necessary.
 496
 497 Messages added will not be visible to other processes until L</done>
 498 is called, but L</remove> may be called on them.
 499
 500 =head2 remove
 501
 502         my $junk = Email::MIME->new($message);
 503         my ($code, $orig) = $im->remove($junk);
 504
 505 Removes a message from the repository.  On success, it returns
 506 a ':'-prefixed numeric code representing the git-fast-import
 507 mark and the original messages as an Email::MIME object.
 508 If the message could not be found, the code is "MISSING"
 509 and the original message is undef.  If there is a mismatch where
 510 the "Message-ID" is matched but the subject and body do not match,
 511 the returned code is "MISMATCH" and the conflicting message
 512 is returned as orig.
 513
 514 =head2 done
 515
 516 Finalizes the L<git-fast-import(1)> and unlocks the repository.
 517 Calling this is required to finalize changes to a repository.
 518
 519 =head1 SEE ALSO
 520
 521 L<Email::MIME>
 522
 523 =head1 CONTACT
 524
 525 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
 526
 527 The mail archives are hosted at L<https://public-inbox.org/meta/>
 528
 529 =head1 COPYRIGHT
 530
 531 Copyright (C) 2016 all contributors L<mailto:meta@public-inbox.org>
 532
 533 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>
 534
 535 =cut