lib/PublicInbox/Import.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # git fast-import-based ssoma-mda MDA replacement
   5 # This is only ever run by public-inbox-mda and public-inbox-learn,
   6 # not the WWW or NNTP code which only requires read-only access.
   7 package PublicInbox::Import;
   8 use strict;
   9 use warnings;
  10 use base qw(PublicInbox::Lock);
  11 use PublicInbox::Spawn qw(spawn);
  12 use PublicInbox::MID qw(mids mid_mime mid2path);
  13 use PublicInbox::Address;
  14 use PublicInbox::MsgTime qw(msg_timestamp);
  15 use PublicInbox::ContentId qw(content_digest);
  16 use PublicInbox::MDA;
  17
  18 sub new {
  19         my ($class, $git, $name, $email, $ibx) = @_;
  20         my $ref = 'refs/heads/master';
  21         if ($ibx) {
  22                 $ref = $ibx->{ref_head} || 'refs/heads/master';
  23                 $name ||= $ibx->{name};
  24                 $email ||= $ibx->{-primary_address};
  25         }
  26         bless {
  27                 git => $git,
  28                 ident => "$name <$email>",
  29                 mark => 1,
  30                 ref => $ref,
  31                 inbox => $ibx,
  32                 path_type => '2/38', # or 'v2'
  33                 lock_path => "$git->{git_dir}/ssoma.lock", # v2 changes this
  34                 bytes_added => 0,
  35         }, $class
  36 }
  37
  38 # idempotent start function
  39 sub gfi_start {
  40         my ($self) = @_;
  41
  42         return ($self->{in}, $self->{out}) if $self->{pid};
  43
  44         my ($in_r, $in_w, $out_r, $out_w);
  45         pipe($in_r, $in_w) or die "pipe failed: $!";
  46         pipe($out_r, $out_w) or die "pipe failed: $!";
  47         my $git = $self->{git};
  48
  49         $self->lock_acquire;
  50
  51         local $/ = "\n";
  52         chomp($self->{tip} = $git->qx(qw(rev-parse --revs-only), $self->{ref}));
  53
  54         my $git_dir = $git->{git_dir};
  55         my @cmd = ('git', "--git-dir=$git_dir", qw(fast-import
  56                         --quiet --done --date-format=raw));
  57         my $rdr = { 0 => fileno($out_r), 1 => fileno($in_w) };
  58         my $pid = spawn(\@cmd, undef, $rdr);
  59         die "spawn fast-import failed: $!" unless defined $pid;
  60         $out_w->autoflush(1);
  61         $self->{in} = $in_r;
  62         $self->{out} = $out_w;
  63         $self->{pid} = $pid;
  64         $self->{nchg} = 0;
  65         binmode $out_w, ':raw' or die "binmode :raw failed: $!";
  66         binmode $in_r, ':raw' or die "binmode :raw failed: $!";
  67         ($in_r, $out_w);
  68 }
  69
  70 sub wfail () { die "write to fast-import failed: $!" }
  71
  72 sub now_raw () { time . ' +0000' }
  73
  74 sub norm_body ($) {
  75         my ($mime) = @_;
  76         my $b = $mime->body_raw;
  77         $b =~ s/(\r?\n)+\z//s;
  78         $b
  79 }
  80
  81 # only used for v1 (ssoma) inboxes
  82 sub _check_path ($$$$) {
  83         my ($r, $w, $tip, $path) = @_;
  84         return if $tip eq '';
  85         print $w "ls $tip $path\n" or wfail;
  86         local $/ = "\n";
  87         defined(my $info = <$r>) or die "EOF from fast-import: $!";
  88         $info =~ /\Amissing / ? undef : $info;
  89 }
  90
  91 sub check_remove_v1 {
  92         my ($r, $w, $tip, $path, $mime) = @_;
  93
  94         my $info = _check_path($r, $w, $tip, $path) or return ('MISSING',undef);
  95         $info =~ m!\A100644 blob ([a-f0-9]{40})\t!s or die "not blob: $info";
  96         my $blob = $1;
  97
  98         print $w "cat-blob $blob\n" or wfail;
  99         local $/ = "\n";
 100         $info = <$r>;
 101         defined $info or die "EOF from fast-import / cat-blob: $!";
 102         $info =~ /\A[a-f0-9]{40} blob (\d+)\n\z/ or
 103                                 die "unexpected cat-blob response: $info";
 104         my $left = $1;
 105         my $offset = 0;
 106         my $buf = '';
 107         my $n;
 108         while ($left > 0) {
 109                 $n = read($r, $buf, $left, $offset);
 110                 defined($n) or die "read cat-blob failed: $!";
 111                 $n == 0 and die 'fast-export (cat-blob) died';
 112                 $left -= $n;
 113                 $offset += $n;
 114         }
 115         $n = read($r, my $lf, 1);
 116         defined($n) or die "read final byte of cat-blob failed: $!";
 117         die "bad read on final byte: <$lf>" if $lf ne "\n";
 118         my $cur = PublicInbox::MIME->new(\$buf);
 119         my $cur_s = $cur->header('Subject');
 120         $cur_s = '' unless defined $cur_s;
 121         my $cur_m = $mime->header('Subject');
 122         $cur_m = '' unless defined $cur_m;
 123         if ($cur_s ne $cur_m || norm_body($cur) ne norm_body($mime)) {
 124                 return ('MISMATCH', $cur);
 125         }
 126         (undef, $cur);
 127 }
 128
 129 sub checkpoint {
 130         my ($self) = @_;
 131         return unless $self->{pid};
 132         print { $self->{out} } "checkpoint\n" or wfail;
 133         undef;
 134 }
 135
 136 sub progress {
 137         my ($self, $msg) = @_;
 138         return unless $self->{pid};
 139         print { $self->{out} } "progress $msg\n" or wfail;
 140         $self->{in}->getline eq "progress $msg\n" or die
 141                 "progress $msg not received\n";
 142         undef;
 143 }
 144
 145 sub _update_git_info ($$) {
 146         my ($self, $do_gc) = @_;
 147         # for compatibility with existing ssoma installations
 148         # we can probably remove this entirely by 2020
 149         my $git_dir = $self->{git}->{git_dir};
 150         my @cmd = ('git', "--git-dir=$git_dir");
 151         my $index = "$git_dir/ssoma.index";
 152         if (-e $index && !$ENV{FAST}) {
 153                 my $env = { GIT_INDEX_FILE => $index };
 154                 run_die([@cmd, qw(read-tree -m -v -i), $self->{ref}], $env);
 155         }
 156         run_die([@cmd, 'update-server-info'], undef);
 157         ($self->{path_type} eq '2/38') and eval {
 158                 require PublicInbox::SearchIdx;
 159                 my $inbox = $self->{inbox} || $git_dir;
 160                 my $s = PublicInbox::SearchIdx->new($inbox);
 161                 $s->index_sync({ ref => $self->{ref} });
 162         };
 163         eval { run_die([@cmd, qw(gc --auto)], undef) } if $do_gc;
 164 }
 165
 166 sub barrier {
 167         my ($self) = @_;
 168
 169         # For safety, we ensure git checkpoint is complete before because
 170         # the data in git is still more important than what is in Xapian
 171         # in v2.  Performance may be gained by delaying the ->progress
 172         # call but we lose safety
 173         if ($self->{nchg}) {
 174                 $self->checkpoint;
 175                 $self->progress('checkpoint');
 176                 _update_git_info($self, 0);
 177                 $self->{nchg} = 0;
 178         }
 179 }
 180
 181 # used for v2
 182 sub get_mark {
 183         my ($self, $mark) = @_;
 184         die "not active\n" unless $self->{pid};
 185         my ($r, $w) = $self->gfi_start;
 186         print $w "get-mark $mark\n" or wfail;
 187         defined(my $oid = <$r>) or die "get-mark failed, need git 2.6.0+\n";
 188         $oid;
 189 }
 190
 191 # returns undef on non-existent
 192 # ('MISMATCH', Email::MIME) on mismatch
 193 # (:MARK, Email::MIME) on success
 194 #
 195 # v2 callers should check with Xapian before calling this as
 196 # it is not idempotent.
 197 sub remove {
 198         my ($self, $mime, $msg) = @_; # mime = Email::MIME
 199
 200         my $path_type = $self->{path_type};
 201         my ($path, $err, $cur, $blob);
 202
 203         my ($r, $w) = $self->gfi_start;
 204         my $tip = $self->{tip};
 205         if ($path_type eq '2/38') {
 206                 $path = mid2path(mid_mime($mime));
 207                 ($err, $cur) = check_remove_v1($r, $w, $tip, $path, $mime);
 208                 return ($err, $cur) if $err;
 209         } else {
 210                 my $sref;
 211                 if (ref($mime) eq 'SCALAR') { # optimization used by V2Writable
 212                         $sref = $mime;
 213                 } else { # XXX should not be necessary:
 214                         my $str = $mime->as_string;
 215                         $sref = \$str;
 216                 }
 217                 my $len = length($$sref);
 218                 $blob = $self->{mark}++;
 219                 print $w "blob\nmark :$blob\ndata $len\n",
 220                         $$sref, "\n" or wfail;
 221         }
 222
 223         my $ref = $self->{ref};
 224         my $commit = $self->{mark}++;
 225         my $parent = $tip =~ /\A:/ ? $tip : undef;
 226         unless ($parent) {
 227                 print $w "reset $ref\n" or wfail;
 228         }
 229         my $ident = $self->{ident};
 230         my $now = now_raw();
 231         $msg ||= 'rm';
 232         my $len = length($msg) + 1;
 233         print $w "commit $ref\nmark :$commit\n",
 234                 "author $ident $now\n",
 235                 "committer $ident $now\n",
 236                 "data $len\n$msg\n\n",
 237                 'from ', ($parent ? $parent : $tip), "\n" or wfail;
 238         if (defined $path) {
 239                 print $w "D $path\n\n" or wfail;
 240         } else {
 241                 print $w "M 100644 :$blob _/D\n\n" or wfail;
 242         }
 243         $self->{nchg}++;
 244         (($self->{tip} = ":$commit"), $cur);
 245 }
 246
 247 sub parse_date ($) {
 248         my ($mime) = @_;
 249         my ($ts, $zone) = msg_timestamp($mime->header_obj);
 250         $ts = 0 if $ts < 0; # git uses unsigned times
 251         "$ts $zone";
 252 }
 253
 254 sub extract_author_info ($) {
 255         my ($mime) = @_;
 256
 257         my $sender = '';
 258         my $from = $mime->header('From');
 259         my ($email) = PublicInbox::Address::emails($from);
 260         my ($name) = PublicInbox::Address::names($from);
 261         if (!defined($name) || !defined($email)) {
 262                 $sender = $mime->header('Sender');
 263                 if (!defined($name)) {
 264                         ($name) = PublicInbox::Address::names($sender);
 265                 }
 266                 if (!defined($email)) {
 267                         ($email) = PublicInbox::Address::emails($sender);
 268                 }
 269         }
 270         if (defined $email) {
 271                 # quiet down wide character warnings with utf8::encode
 272                 utf8::encode($email);
 273         } else {
 274                 $email = '';
 275                 warn "no email in From: $from or Sender: $sender\n";
 276         }
 277
 278         # git gets confused with:
 279         #  "'A U Thor <u@example.com>' via foo" <foo@example.com>
 280         # ref:
 281         # <CAD0k6qSUYANxbjjbE4jTW4EeVwOYgBD=bXkSu=akiYC_CB7Ffw@mail.gmail.com>
 282         if (defined $name) {
 283                 $name =~ tr/<>//d;
 284                 utf8::encode($name);
 285         } else {
 286                 $name = '';
 287                 warn "no name in From: $from or Sender: $sender\n";
 288         }
 289         ($name, $email);
 290 }
 291
 292 # returns undef on duplicate
 293 # returns the :MARK of the most recent commit
 294 sub add {
 295         my ($self, $mime, $check_cb) = @_; # mime = Email::MIME
 296
 297         my ($name, $email) = extract_author_info($mime);
 298         my $date_raw = parse_date($mime);
 299         my $subject = $mime->header('Subject');
 300         $subject = '(no subject)' unless defined $subject;
 301         my $path_type = $self->{path_type};
 302
 303         my $path;
 304         if ($path_type eq '2/38') {
 305                 my $mids = mids($mime->header_obj);
 306                 if (!scalar(@$mids)) {
 307                         my $dig = content_digest($mime);
 308                         @$mids = (digest2mid($dig));
 309                 }
 310                 $path = mid2path($mids->[0]);
 311         } else { # v2 layout, one file:
 312                 $path = 'm';
 313         }
 314
 315         my ($r, $w) = $self->gfi_start;
 316         my $tip = $self->{tip};
 317         if ($path_type eq '2/38') {
 318                 _check_path($r, $w, $tip, $path) and return;
 319         }
 320
 321         # kill potentially confusing/misleading headers
 322         $mime->header_set($_) for qw(bytes lines content-length status);
 323         $mime->header_set($_) for @PublicInbox::MDA::BAD_HEADERS;
 324
 325         # spam check:
 326         if ($check_cb) {
 327                 $mime = $check_cb->($mime) or return;
 328         }
 329
 330         my $blob = $self->{mark}++;
 331         my $str = $mime->as_string;
 332         my $n = length($str);
 333         $self->{bytes_added} += $n;
 334         print $w "blob\nmark :$blob\ndata ", $n, "\n" or wfail;
 335         print $w $str, "\n" or wfail;
 336
 337         # v2: we need this for Xapian
 338         if ($self->{want_object_info}) {
 339                 chomp(my $oid = $self->get_mark(":$blob"));
 340                 $self->{last_object} = [ $oid, $n, \$str ];
 341         }
 342         my $ref = $self->{ref};
 343         my $commit = $self->{mark}++;
 344         my $parent = $tip =~ /\A:/ ? $tip : undef;
 345
 346         unless ($parent) {
 347                 print $w "reset $ref\n" or wfail;
 348         }
 349
 350         utf8::encode($subject);
 351         print $w "commit $ref\nmark :$commit\n",
 352                 "author $name <$email> $date_raw\n",
 353                 "committer $self->{ident} ", now_raw(), "\n" or wfail;
 354         print $w "data ", (length($subject) + 1), "\n",
 355                 $subject, "\n\n" or wfail;
 356         if ($tip ne '') {
 357                 print $w 'from ', ($parent ? $parent : $tip), "\n" or wfail;
 358         }
 359         print $w "M 100644 :$blob $path\n\n" or wfail;
 360         $self->{nchg}++;
 361         $self->{tip} = ":$commit";
 362 }
 363
 364 sub run_die ($;$) {
 365         my ($cmd, $env) = @_;
 366         my $pid = spawn($cmd, $env, undef);
 367         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 368         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 369         $? == 0 or die join(' ', @$cmd) . " failed: $?\n";
 370 }
 371
 372 sub done {
 373         my ($self) = @_;
 374         my $w = delete $self->{out} or return;
 375         my $r = delete $self->{in} or die 'BUG: missing {in} when done';
 376         print $w "done\n" or wfail;
 377         my $pid = delete $self->{pid} or die 'BUG: missing {pid} when done';
 378         waitpid($pid, 0) == $pid or die 'fast-import did not finish';
 379         $? == 0 or die "fast-import failed: $?";
 380
 381         _update_git_info($self, 1) if delete $self->{nchg};
 382
 383         $self->lock_release;
 384 }
 385
 386 sub atfork_child {
 387         my ($self) = @_;
 388         foreach my $f (qw(in out)) {
 389                 close $self->{$f} or die "failed to close import[$f]: $!\n";
 390         }
 391 }
 392
 393 sub digest2mid ($) {
 394         my ($dig) = @_;
 395         my $b64 = $dig->clone->b64digest;
 396         # Make our own URLs nicer:
 397         # See "Base 64 Encoding with URL and Filename Safe Alphabet" in RFC4648
 398         $b64 =~ tr!+/=!-_!d;
 399
 400         # We can make this more meaningful with a date prefix or other things,
 401         # but this is only needed for crap that fails to generate a Message-ID
 402         # or reuses one.  In other words, it's usually spammers who hit this
 403         # so they don't deserve nice Message-IDs :P
 404         $b64 . '@localhost';
 405 }
 406
 407 1;
 408 __END__
 409 =pod
 410
 411 =head1 NAME
 412
 413 PublicInbox::Import - message importer for public-inbox
 414
 415 =head1 VERSION
 416
 417 version 1.0
 418
 419 =head1 SYNOPSYS
 420
 421         use Email::MIME;
 422         use PublicInbox::Git;
 423         use PublicInbox::Import;
 424
 425         chomp(my $git_dir = `git rev-parse --git-dir`);
 426         $git_dir or die "GIT_DIR= must be specified\n";
 427         my $git = PublicInbox::Git->new($git_dir);
 428         my @committer = ('inbox', 'inbox@example.org');
 429         my $im = PublicInbox::Import->new($git, @committer);
 430
 431         # to add a message:
 432         my $message = "From: <u\@example.org>\n".
 433                 "Subject: test message \n" .
 434                 "Date: Thu, 01 Jan 1970 00:00:00 +0000\n" .
 435                 "Message-ID: <m\@example.org>\n".
 436                 "\ntest message";
 437         my $parsed = Email::MIME->new($message);
 438         my $ret = $im->add($parsed);
 439         if (!defined $ret) {
 440                 warn "duplicate: ",
 441                         $parsed->header_obj->header_raw('Message-ID'), "\n";
 442         } else {
 443                 print "imported at mark $ret\n";
 444         }
 445         $im->done;
 446
 447         # to remove a message
 448         my $junk = Email::MIME->new($message);
 449         my ($mark, $orig) = $im->remove($junk);
 450         if ($mark eq 'MISSING') {
 451                 print "not found\n";
 452         } elsif ($mark eq 'MISMATCH') {
 453                 print "Message exists but does not match\n\n",
 454                         $orig->as_string, "\n",;
 455         } else {
 456                 print "removed at mark $mark\n\n",
 457                         $orig->as_string, "\n";
 458         }
 459         $im->done;
 460
 461 =head1 DESCRIPTION
 462
 463 An importer and remover for public-inboxes which takes L<Email::MIME>
 464 messages as input and stores them in a ssoma repository as
 465 documented in L<https://ssoma.public-inbox.org/ssoma_repository.txt>,
 466 except it does not allow duplicate Message-IDs.
 467
 468 It requires L<git(1)> and L<git-fast-import(1)> to be installed.
 469
 470 =head1 METHODS
 471
 472 =cut
 473
 474 =head2 new
 475
 476         my $im = PublicInbox::Import->new($git, @committer);
 477
 478 Initialize a new PublicInbox::Import object.
 479
 480 =head2 add
 481
 482         my $parsed = Email::MIME->new($message);
 483         $im->add($parsed);
 484
 485 Adds a message to to the git repository.  This will acquire
 486 C<$GIT_DIR/ssoma.lock> and start L<git-fast-import(1)> if necessary.
 487
 488 Messages added will not be visible to other processes until L</done>
 489 is called, but L</remove> may be called on them.
 490
 491 =head2 remove
 492
 493         my $junk = Email::MIME->new($message);
 494         my ($code, $orig) = $im->remove($junk);
 495
 496 Removes a message from the repository.  On success, it returns
 497 a ':'-prefixed numeric code representing the git-fast-import
 498 mark and the original messages as an Email::MIME object.
 499 If the message could not be found, the code is "MISSING"
 500 and the original message is undef.  If there is a mismatch where
 501 the "Message-ID" is matched but the subject and body do not match,
 502 the returned code is "MISMATCH" and the conflicting message
 503 is returned as orig.
 504
 505 =head2 done
 506
 507 Finalizes the L<git-fast-import(1)> and unlocks the repository.
 508 Calling this is required to finalize changes to a repository.
 509
 510 =head1 SEE ALSO
 511
 512 L<Email::MIME>
 513
 514 =head1 CONTACT
 515
 516 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
 517
 518 The mail archives are hosted at L<https://public-inbox.org/meta/>
 519
 520 =head1 COPYRIGHT
 521
 522 Copyright (C) 2016 all contributors L<mailto:meta@public-inbox.org>
 523
 524 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>
 525
 526 =cut