lib/PublicInbox/Import.pm

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # git fast-import-based ssoma-mda MDA replacement
   5 # This is only ever run by public-inbox-mda, public-inbox-learn
   6 # and public-inbox-watch. Not the WWW or NNTP code which only
   7 # requires read-only access.
   8 package PublicInbox::Import;
   9 use strict;
  10 use warnings;
  11 use base qw(PublicInbox::Lock);
  12 use PublicInbox::Spawn qw(spawn);
  13 use PublicInbox::MID qw(mids mid_mime mid2path);
  14 use PublicInbox::Address;
  15 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  16 use PublicInbox::ContentId qw(content_digest);
  17 use PublicInbox::MDA;
  18 use POSIX qw(strftime);
  19
  20 sub new {
  21         # we can't change arg order, this is documented in POD
  22         # and external projects may rely on it:
  23         my ($class, $git, $name, $email, $ibx) = @_;
  24         my $ref = 'refs/heads/master';
  25         if ($ibx) {
  26                 $ref = $ibx->{ref_head} || 'refs/heads/master';
  27                 $name ||= $ibx->{name};
  28                 $email ||= $ibx->{-primary_address};
  29                 $git ||= $ibx->git;
  30         }
  31         bless {
  32                 git => $git,
  33                 ident => "$name <$email>",
  34                 mark => 1,
  35                 ref => $ref,
  36                 -inbox => $ibx,
  37                 path_type => '2/38', # or 'v2'
  38                 lock_path => "$git->{git_dir}/ssoma.lock", # v2 changes this
  39                 bytes_added => 0,
  40         }, $class
  41 }
  42
  43 # idempotent start function
  44 sub gfi_start {
  45         my ($self) = @_;
  46
  47         return ($self->{in}, $self->{out}) if $self->{pid};
  48
  49         my ($in_r, $in_w, $out_r, $out_w);
  50         pipe($in_r, $in_w) or die "pipe failed: $!";
  51         pipe($out_r, $out_w) or die "pipe failed: $!";
  52         my $git = $self->{git};
  53
  54         $self->lock_acquire;
  55
  56         local $/ = "\n";
  57         my $ref = $self->{ref};
  58         chomp($self->{tip} = $git->qx(qw(rev-parse --revs-only), $ref));
  59         if ($self->{path_type} ne '2/38' && $self->{tip}) {
  60                 local $/ = "\0";
  61                 my @tree = $git->qx(qw(ls-tree -r -z --name-only), $ref);
  62                 chomp @tree;
  63                 $self->{-tree} = { map { $_ => 1 } @tree };
  64         }
  65
  66         my $git_dir = $git->{git_dir};
  67         my @cmd = ('git', "--git-dir=$git_dir", qw(fast-import
  68                         --quiet --done --date-format=raw));
  69         my $rdr = { 0 => fileno($out_r), 1 => fileno($in_w) };
  70         my $pid = spawn(\@cmd, undef, $rdr);
  71         die "spawn fast-import failed: $!" unless defined $pid;
  72         $out_w->autoflush(1);
  73         $self->{in} = $in_r;
  74         $self->{out} = $out_w;
  75         $self->{pid} = $pid;
  76         $self->{nchg} = 0;
  77         binmode $out_w, ':raw' or die "binmode :raw failed: $!";
  78         binmode $in_r, ':raw' or die "binmode :raw failed: $!";
  79         ($in_r, $out_w);
  80 }
  81
  82 sub wfail () { die "write to fast-import failed: $!" }
  83
  84 sub now_raw () { time . ' +0000' }
  85
  86 sub norm_body ($) {
  87         my ($mime) = @_;
  88         my $b = $mime->body_raw;
  89         $b =~ s/(\r?\n)+\z//s;
  90         $b
  91 }
  92
  93 # only used for v1 (ssoma) inboxes
  94 sub _check_path ($$$$) {
  95         my ($r, $w, $tip, $path) = @_;
  96         return if $tip eq '';
  97         print $w "ls $tip $path\n" or wfail;
  98         local $/ = "\n";
  99         defined(my $info = <$r>) or die "EOF from fast-import: $!";
 100         $info =~ /\Amissing / ? undef : $info;
 101 }
 102
 103 sub _cat_blob ($$$) {
 104         my ($r, $w, $oid) = @_;
 105         print $w "cat-blob $oid\n" or wfail;
 106         local $/ = "\n";
 107         my $info = <$r>;
 108         defined $info or die "EOF from fast-import / cat-blob: $!";
 109         $info =~ /\A[a-f0-9]{40} blob (\d+)\n\z/ or return;
 110         my $left = $1;
 111         my $offset = 0;
 112         my $buf = '';
 113         my $n;
 114         while ($left > 0) {
 115                 $n = read($r, $buf, $left, $offset);
 116                 defined($n) or die "read cat-blob failed: $!";
 117                 $n == 0 and die 'fast-export (cat-blob) died';
 118                 $left -= $n;
 119                 $offset += $n;
 120         }
 121         $n = read($r, my $lf, 1);
 122         defined($n) or die "read final byte of cat-blob failed: $!";
 123         die "bad read on final byte: <$lf>" if $lf ne "\n";
 124
 125         # fixup some bugginess in old versions:
 126         $buf =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 127         \$buf;
 128 }
 129
 130 sub cat_blob {
 131         my ($self, $oid) = @_;
 132         my ($r, $w) = $self->gfi_start;
 133         _cat_blob($r, $w, $oid);
 134 }
 135
 136 sub check_remove_v1 {
 137         my ($r, $w, $tip, $path, $mime) = @_;
 138
 139         my $info = _check_path($r, $w, $tip, $path) or return ('MISSING',undef);
 140         $info =~ m!\A100644 blob ([a-f0-9]{40})\t!s or die "not blob: $info";
 141         my $oid = $1;
 142         my $msg = _cat_blob($r, $w, $oid) or die "BUG: cat-blob $1 failed";
 143         my $cur = PublicInbox::MIME->new($msg);
 144         my $cur_s = $cur->header('Subject');
 145         $cur_s = '' unless defined $cur_s;
 146         my $cur_m = $mime->header('Subject');
 147         $cur_m = '' unless defined $cur_m;
 148         if ($cur_s ne $cur_m || norm_body($cur) ne norm_body($mime)) {
 149                 return ('MISMATCH', $cur);
 150         }
 151         (undef, $cur);
 152 }
 153
 154 sub checkpoint {
 155         my ($self) = @_;
 156         return unless $self->{pid};
 157         print { $self->{out} } "checkpoint\n" or wfail;
 158         undef;
 159 }
 160
 161 sub progress {
 162         my ($self, $msg) = @_;
 163         return unless $self->{pid};
 164         print { $self->{out} } "progress $msg\n" or wfail;
 165         $self->{in}->getline eq "progress $msg\n" or die
 166                 "progress $msg not received\n";
 167         undef;
 168 }
 169
 170 sub _update_git_info ($$) {
 171         my ($self, $do_gc) = @_;
 172         # for compatibility with existing ssoma installations
 173         # we can probably remove this entirely by 2020
 174         my $git_dir = $self->{git}->{git_dir};
 175         my @cmd = ('git', "--git-dir=$git_dir");
 176         my $index = "$git_dir/ssoma.index";
 177         if (-e $index && !$ENV{FAST}) {
 178                 my $env = { GIT_INDEX_FILE => $index };
 179                 run_die([@cmd, qw(read-tree -m -v -i), $self->{ref}], $env);
 180         }
 181         run_die([@cmd, 'update-server-info'], undef);
 182         ($self->{path_type} eq '2/38') and eval {
 183                 require PublicInbox::SearchIdx;
 184                 my $ibx = $self->{-inbox} || $git_dir;
 185                 my $s = PublicInbox::SearchIdx->new($ibx);
 186                 $s->index_sync({ ref => $self->{ref} });
 187         };
 188         eval { run_die([@cmd, qw(gc --auto)], undef) } if $do_gc;
 189 }
 190
 191 sub barrier {
 192         my ($self) = @_;
 193
 194         # For safety, we ensure git checkpoint is complete before because
 195         # the data in git is still more important than what is in Xapian
 196         # in v2.  Performance may be gained by delaying the ->progress
 197         # call but we lose safety
 198         if ($self->{nchg}) {
 199                 $self->checkpoint;
 200                 $self->progress('checkpoint');
 201                 _update_git_info($self, 0);
 202                 $self->{nchg} = 0;
 203         }
 204 }
 205
 206 # used for v2
 207 sub get_mark {
 208         my ($self, $mark) = @_;
 209         die "not active\n" unless $self->{pid};
 210         my ($r, $w) = $self->gfi_start;
 211         print $w "get-mark $mark\n" or wfail;
 212         defined(my $oid = <$r>) or die "get-mark failed, need git 2.6.0+\n";
 213         chomp($oid);
 214         $oid;
 215 }
 216
 217 # returns undef on non-existent
 218 # ('MISMATCH', Email::MIME) on mismatch
 219 # (:MARK, Email::MIME) on success
 220 #
 221 # v2 callers should check with Xapian before calling this as
 222 # it is not idempotent.
 223 sub remove {
 224         my ($self, $mime, $msg) = @_; # mime = Email::MIME
 225
 226         my $path_type = $self->{path_type};
 227         my ($path, $err, $cur, $blob);
 228
 229         my ($r, $w) = $self->gfi_start;
 230         my $tip = $self->{tip};
 231         if ($path_type eq '2/38') {
 232                 $path = mid2path(v1_mid0($mime));
 233                 ($err, $cur) = check_remove_v1($r, $w, $tip, $path, $mime);
 234                 return ($err, $cur) if $err;
 235         } else {
 236                 my $sref;
 237                 if (ref($mime) eq 'SCALAR') { # optimization used by V2Writable
 238                         $sref = $mime;
 239                 } else { # XXX should not be necessary:
 240                         my $str = $mime->as_string;
 241                         $sref = \$str;
 242                 }
 243                 my $len = length($$sref);
 244                 $blob = $self->{mark}++;
 245                 print $w "blob\nmark :$blob\ndata $len\n",
 246                         $$sref, "\n" or wfail;
 247         }
 248
 249         my $ref = $self->{ref};
 250         my $commit = $self->{mark}++;
 251         my $parent = $tip =~ /\A:/ ? $tip : undef;
 252         unless ($parent) {
 253                 print $w "reset $ref\n" or wfail;
 254         }
 255         my $ident = $self->{ident};
 256         my $now = now_raw();
 257         $msg ||= 'rm';
 258         my $len = length($msg) + 1;
 259         print $w "commit $ref\nmark :$commit\n",
 260                 "author $ident $now\n",
 261                 "committer $ident $now\n",
 262                 "data $len\n$msg\n\n",
 263                 'from ', ($parent ? $parent : $tip), "\n" or wfail;
 264         if (defined $path) {
 265                 print $w "D $path\n\n" or wfail;
 266         } else {
 267                 clean_tree_v2($self, $w, 'd');
 268                 print $w "M 100644 :$blob d\n\n" or wfail;
 269         }
 270         $self->{nchg}++;
 271         (($self->{tip} = ":$commit"), $cur);
 272 }
 273
 274 sub git_timestamp {
 275         my ($ts, $zone) = @_;
 276         $ts = 0 if $ts < 0; # git uses unsigned times
 277         "$ts $zone";
 278 }
 279
 280 sub extract_author_info ($) {
 281         my ($mime) = @_;
 282
 283         my $sender = '';
 284         my $from = $mime->header('From');
 285         $from ||= '';
 286         my ($email) = PublicInbox::Address::emails($from);
 287         my ($name) = PublicInbox::Address::names($from);
 288         if (!defined($name) || !defined($email)) {
 289                 $sender = $mime->header('Sender');
 290                 $sender ||= '';
 291                 if (!defined($name)) {
 292                         ($name) = PublicInbox::Address::names($sender);
 293                 }
 294                 if (!defined($email)) {
 295                         ($email) = PublicInbox::Address::emails($sender);
 296                 }
 297         }
 298         if (defined $email) {
 299                 # quiet down wide character warnings with utf8::encode
 300                 utf8::encode($email);
 301         } else {
 302                 $email = '';
 303                 warn "no email in From: $from or Sender: $sender\n";
 304         }
 305
 306         # git gets confused with:
 307         #  "'A U Thor <u@example.com>' via foo" <foo@example.com>
 308         # ref:
 309         # <CAD0k6qSUYANxbjjbE4jTW4EeVwOYgBD=bXkSu=akiYC_CB7Ffw@mail.gmail.com>
 310         if (defined $name) {
 311                 $name =~ tr/<>//d;
 312                 utf8::encode($name);
 313         } else {
 314                 $name = '';
 315                 warn "no name in From: $from or Sender: $sender\n";
 316         }
 317         ($name, $email);
 318 }
 319
 320 # kill potentially confusing/misleading headers
 321 sub drop_unwanted_headers ($) {
 322         my ($mime) = @_;
 323
 324         $mime->header_set($_) for qw(bytes lines content-length status);
 325         $mime->header_set($_) for @PublicInbox::MDA::BAD_HEADERS;
 326 }
 327
 328 # used by V2Writable, too
 329 sub append_mid ($$) {
 330         my ($hdr, $mid0) = @_;
 331         # @cur is likely empty if we need to call this sub, but it could
 332         # have random unparseable crap which we'll preserve, too.
 333         my @cur = $hdr->header_raw('Message-ID');
 334         $hdr->header_set('Message-ID', @cur, "<$mid0>");
 335 }
 336
 337 sub v1_mid0 ($) {
 338         my ($mime) = @_;
 339         my $hdr = $mime->header_obj;
 340         my $mids = mids($hdr);
 341
 342         if (!scalar(@$mids)) { # spam often has no Message-Id
 343                 my $mid0 = digest2mid(content_digest($mime), $hdr);
 344                 append_mid($hdr, $mid0);
 345                 return $mid0;
 346         }
 347         $mids->[0];
 348 }
 349 sub clean_tree_v2 ($$$) {
 350         my ($self, $w, $keep) = @_;
 351         my $tree = $self->{-tree} or return; #v2 only
 352         delete $tree->{$keep};
 353         foreach (keys %$tree) {
 354                 print $w "D $_\n" or wfail;
 355         }
 356         %$tree = ($keep => 1);
 357 }
 358
 359 # returns undef on duplicate
 360 # returns the :MARK of the most recent commit
 361 sub add {
 362         my ($self, $mime, $check_cb) = @_; # mime = Email::MIME
 363
 364         my ($name, $email) = extract_author_info($mime);
 365         my $hdr = $mime->header_obj;
 366         my @at = msg_datestamp($hdr);
 367         my @ct = msg_timestamp($hdr);
 368         my $author_time_raw = git_timestamp(@at);
 369         my $commit_time_raw = git_timestamp(@ct);
 370         my $subject = $mime->header('Subject');
 371         $subject = '(no subject)' unless defined $subject;
 372         my $path_type = $self->{path_type};
 373
 374         my $path;
 375         if ($path_type eq '2/38') {
 376                 $path = mid2path(v1_mid0($mime));
 377         } else { # v2 layout, one file:
 378                 $path = 'm';
 379         }
 380
 381         my ($r, $w) = $self->gfi_start;
 382         my $tip = $self->{tip};
 383         if ($path_type eq '2/38') {
 384                 _check_path($r, $w, $tip, $path) and return;
 385         }
 386
 387         drop_unwanted_headers($mime);
 388
 389         # spam check:
 390         if ($check_cb) {
 391                 $mime = $check_cb->($mime) or return;
 392         }
 393
 394         my $blob = $self->{mark}++;
 395         my $str = $mime->as_string;
 396         my $n = length($str);
 397         $self->{bytes_added} += $n;
 398         print $w "blob\nmark :$blob\ndata ", $n, "\n" or wfail;
 399         print $w $str, "\n" or wfail;
 400
 401         # v2: we need this for Xapian
 402         if ($self->{want_object_info}) {
 403                 my $oid = $self->get_mark(":$blob");
 404                 $self->{last_object} = [ $oid, $n, \$str ];
 405         }
 406         my $ref = $self->{ref};
 407         my $commit = $self->{mark}++;
 408         my $parent = $tip =~ /\A:/ ? $tip : undef;
 409
 410         unless ($parent) {
 411                 print $w "reset $ref\n" or wfail;
 412         }
 413
 414         # Mime decoding can create nulls replace them with spaces to protect git
 415         $subject =~ tr/\0/ /;
 416         utf8::encode($subject);
 417         print $w "commit $ref\nmark :$commit\n",
 418                 "author $name <$email> $author_time_raw\n",
 419                 "committer $self->{ident} $commit_time_raw\n" or wfail;
 420         print $w "data ", (length($subject) + 1), "\n",
 421                 $subject, "\n\n" or wfail;
 422         if ($tip ne '') {
 423                 print $w 'from ', ($parent ? $parent : $tip), "\n" or wfail;
 424         }
 425         clean_tree_v2($self, $w, $path);
 426         print $w "M 100644 :$blob $path\n\n" or wfail;
 427         $self->{nchg}++;
 428         $self->{tip} = ":$commit";
 429 }
 430
 431 sub run_die ($;$$) {
 432         my ($cmd, $env, $rdr) = @_;
 433         my $pid = spawn($cmd, $env, $rdr);
 434         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 435         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 436         $? == 0 or die join(' ', @$cmd) . " failed: $?\n";
 437 }
 438
 439 sub init_bare {
 440         my ($dir) = @_;
 441         my @cmd = (qw(git init --bare -q), $dir);
 442         run_die(\@cmd);
 443         # set a reasonable default:
 444         @cmd = (qw/git config/, "--file=$dir/config",
 445                 'repack.writeBitmaps', 'true');
 446         run_die(\@cmd);
 447 }
 448
 449 sub done {
 450         my ($self) = @_;
 451         my $w = delete $self->{out} or return;
 452         my $r = delete $self->{in} or die 'BUG: missing {in} when done';
 453         print $w "done\n" or wfail;
 454         my $pid = delete $self->{pid} or die 'BUG: missing {pid} when done';
 455         waitpid($pid, 0) == $pid or die 'fast-import did not finish';
 456         $? == 0 or die "fast-import failed: $?";
 457
 458         _update_git_info($self, 1) if delete $self->{nchg};
 459
 460         $self->lock_release;
 461
 462         $self->{git}->cleanup;
 463 }
 464
 465 sub atfork_child {
 466         my ($self) = @_;
 467         foreach my $f (qw(in out)) {
 468                 next unless defined($self->{$f});
 469                 close $self->{$f} or die "failed to close import[$f]: $!\n";
 470         }
 471 }
 472
 473 sub digest2mid ($$) {
 474         my ($dig, $hdr) = @_;
 475         my $b64 = $dig->clone->b64digest;
 476         # Make our own URLs nicer:
 477         # See "Base 64 Encoding with URL and Filename Safe Alphabet" in RFC4648
 478         $b64 =~ tr!+/=!-_!d;
 479
 480         # Add a date prefix to prevent a leading '-' in case that trips
 481         # up some tools (e.g. if a Message-ID were a expected as a
 482         # command-line arg)
 483         my $dt = msg_datestamp($hdr);
 484         $dt = POSIX::strftime('%Y%m%d%H%M%S', gmtime($dt));
 485         "$dt.$b64" . '@z';
 486 }
 487
 488 sub clean_purge_buffer {
 489         my ($oids, $buf) = @_;
 490         my $cmt_msg = 'purged '.join(' ',@$oids)."\n";
 491         @$oids = ();
 492
 493         foreach my $i (0..$#$buf) {
 494                 my $l = $buf->[$i];
 495                 if ($l =~ /^author .* (\d+ [\+-]?\d+)$/) {
 496                         $buf->[$i] = "author <> $1\n";
 497                 } elsif ($l =~ /^data (\d+)/) {
 498                         $buf->[$i++] = "data " . length($cmt_msg) . "\n";
 499                         $buf->[$i] = $cmt_msg;
 500                         last;
 501                 }
 502         }
 503 }
 504
 505 sub purge_oids {
 506         my ($self, $purge) = @_;
 507         my $tmp = "refs/heads/purge-".((keys %$purge)[0]);
 508         my $old = $self->{'ref'};
 509         my $git = $self->{git};
 510         my @export = (qw(fast-export --no-data --use-done-feature), $old);
 511         my $rd = $git->popen(@export);
 512         my ($r, $w) = $self->gfi_start;
 513         my @buf;
 514         my $npurge = 0;
 515         my @oids;
 516         my ($done, $mark);
 517         my $tree = $self->{-tree};
 518         while (<$rd>) {
 519                 if (/^reset (?:.+)/) {
 520                         push @buf, "reset $tmp\n";
 521                 } elsif (/^commit (?:.+)/) {
 522                         if (@buf) {
 523                                 $w->print(@buf) or wfail;
 524                                 @buf = ();
 525                         }
 526                         push @buf, "commit $tmp\n";
 527                 } elsif (/^data (\d+)/) {
 528                         # only commit message, so $len is small:
 529                         my $len = $1; # + 1 for trailing "\n"
 530                         push @buf, $_;
 531                         my $n = read($rd, my $buf, $len) or die "read: $!";
 532                         $len == $n or die "short read ($n < $len)";
 533                         push @buf, $buf;
 534                 } elsif (/^M 100644 ([a-f0-9]+) (\w+)/) {
 535                         my ($oid, $path) = ($1, $2);
 536                         $tree->{$path} = 1;
 537                         if ($purge->{$oid}) {
 538                                 push @oids, $oid;
 539                                 my $cmd = "M 100644 inline $path\ndata 0\n\n";
 540                                 push @buf, $cmd;
 541                         } else {
 542                                 push @buf, $_;
 543                         }
 544                 } elsif (/^D (\w+)/) {
 545                         my $path = $1;
 546                         push @buf, $_ if $tree->{$path};
 547                 } elsif ($_ eq "\n") {
 548                         if (@oids) {
 549                                 my $out = join('', @buf);
 550                                 $out =~ s/^/# /sgm;
 551                                 warn "purge rewriting\n", $out, "\n";
 552                                 clean_purge_buffer(\@oids, \@buf);
 553                                 $npurge++;
 554                         }
 555                         $w->print(@buf, "\n") or wfail;
 556                         @buf = ();
 557                 } elsif ($_ eq "done\n") {
 558                         $done = 1;
 559                 } elsif (/^mark :(\d+)$/) {
 560                         push @buf, $_;
 561                         $mark = $1;
 562                 } else {
 563                         push @buf, $_;
 564                 }
 565         }
 566         close $rd or die "close fast-export failed: $?";
 567         if (@buf) {
 568                 $w->print(@buf) or wfail;
 569         }
 570         die 'done\n not seen from fast-export' unless $done;
 571         chomp(my $cmt = $self->get_mark(":$mark")) if $npurge;
 572         $self->{nchg} = 0; # prevent _update_git_info until update-ref:
 573         $self->done;
 574         my @git = ('git', "--git-dir=$git->{git_dir}");
 575
 576         run_die([@git, qw(update-ref), $old, $tmp]) if $npurge;
 577
 578         run_die([@git, qw(update-ref -d), $tmp]);
 579
 580         return if $npurge == 0;
 581
 582         run_die([@git, qw(-c gc.reflogExpire=now gc --prune=all)]);
 583         my $err = 0;
 584         foreach my $oid (keys %$purge) {
 585                 my @info = $git->check($oid);
 586                 if (@info) {
 587                         warn "$oid not purged\n";
 588                         $err++;
 589                 }
 590         }
 591         _update_git_info($self, 0);
 592         die "Failed to purge $err object(s)\n" if $err;
 593         $cmt;
 594 }
 595
 596 1;
 597 __END__
 598 =pod
 599
 600 =head1 NAME
 601
 602 PublicInbox::Import - message importer for public-inbox v1 inboxes
 603
 604 =head1 VERSION
 605
 606 version 1.0
 607
 608 =head1 SYNOPSYS
 609
 610         use Email::MIME;
 611         use PublicInbox::Git;
 612         use PublicInbox::Import;
 613
 614         chomp(my $git_dir = `git rev-parse --git-dir`);
 615         $git_dir or die "GIT_DIR= must be specified\n";
 616         my $git = PublicInbox::Git->new($git_dir);
 617         my @committer = ('inbox', 'inbox@example.org');
 618         my $im = PublicInbox::Import->new($git, @committer);
 619
 620         # to add a message:
 621         my $message = "From: <u\@example.org>\n".
 622                 "Subject: test message \n" .
 623                 "Date: Thu, 01 Jan 1970 00:00:00 +0000\n" .
 624                 "Message-ID: <m\@example.org>\n".
 625                 "\ntest message";
 626         my $parsed = Email::MIME->new($message);
 627         my $ret = $im->add($parsed);
 628         if (!defined $ret) {
 629                 warn "duplicate: ",
 630                         $parsed->header_obj->header_raw('Message-ID'), "\n";
 631         } else {
 632                 print "imported at mark $ret\n";
 633         }
 634         $im->done;
 635
 636         # to remove a message
 637         my $junk = Email::MIME->new($message);
 638         my ($mark, $orig) = $im->remove($junk);
 639         if ($mark eq 'MISSING') {
 640                 print "not found\n";
 641         } elsif ($mark eq 'MISMATCH') {
 642                 print "Message exists but does not match\n\n",
 643                         $orig->as_string, "\n",;
 644         } else {
 645                 print "removed at mark $mark\n\n",
 646                         $orig->as_string, "\n";
 647         }
 648         $im->done;
 649
 650 =head1 DESCRIPTION
 651
 652 An importer and remover for public-inboxes which takes L<Email::MIME>
 653 messages as input and stores them in a git repository as
 654 documented in L<https://public-inbox.org/public-inbox-v1-format.txt>,
 655 except it does not allow duplicate Message-IDs.
 656
 657 It requires L<git(1)> and L<git-fast-import(1)> to be installed.
 658
 659 =head1 METHODS
 660
 661 =cut
 662
 663 =head2 new
 664
 665         my $im = PublicInbox::Import->new($git, @committer);
 666
 667 Initialize a new PublicInbox::Import object.
 668
 669 =head2 add
 670
 671         my $parsed = Email::MIME->new($message);
 672         $im->add($parsed);
 673
 674 Adds a message to to the git repository.  This will acquire
 675 C<$GIT_DIR/ssoma.lock> and start L<git-fast-import(1)> if necessary.
 676
 677 Messages added will not be visible to other processes until L</done>
 678 is called, but L</remove> may be called on them.
 679
 680 =head2 remove
 681
 682         my $junk = Email::MIME->new($message);
 683         my ($code, $orig) = $im->remove($junk);
 684
 685 Removes a message from the repository.  On success, it returns
 686 a ':'-prefixed numeric code representing the git-fast-import
 687 mark and the original messages as an Email::MIME object.
 688 If the message could not be found, the code is "MISSING"
 689 and the original message is undef.  If there is a mismatch where
 690 the "Message-ID" is matched but the subject and body do not match,
 691 the returned code is "MISMATCH" and the conflicting message
 692 is returned as orig.
 693
 694 =head2 done
 695
 696 Finalizes the L<git-fast-import(1)> and unlocks the repository.
 697 Calling this is required to finalize changes to a repository.
 698
 699 =head1 SEE ALSO
 700
 701 L<Email::MIME>
 702
 703 =head1 CONTACT
 704
 705 All feedback welcome via plain-text mail to L<mailto:meta@public-inbox.org>
 706
 707 The mail archives are hosted at L<https://public-inbox.org/meta/>
 708
 709 =head1 COPYRIGHT
 710
 711 Copyright (C) 2016 all contributors L<mailto:meta@public-inbox.org>
 712
 713 License: AGPL-3.0+ L<http://www.gnu.org/licenses/agpl-3.0.txt>
 714
 715 =cut