lib/PublicInbox/Inbox.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Represents a public-inbox (which may have multiple mailing addresses)
   5 package PublicInbox::Inbox;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::Git;
   9 use PublicInbox::MID qw(mid2path);
  10 use PublicInbox::MIME;
  11
  12 # Long-running "git-cat-file --batch" processes won't notice
  13 # unlinked packs, so we need to restart those processes occasionally.
  14 # Xapian and SQLite file handles are mostly stable, but sometimes an
  15 # admin will attempt to replace them atomically after compact/vacuum
  16 # and we need to be prepared for that.
  17 my $cleanup_timer;
  18 my $cleanup_avail = -1; # 0, or 1
  19 my $have_devel_peek;
  20 my $CLEANUP = {}; # string(inbox) -> inbox
  21 sub cleanup_task () {
  22         $cleanup_timer = undef;
  23         my $next = {};
  24         for my $ibx (values %$CLEANUP) {
  25                 my $again;
  26                 if ($have_devel_peek) {
  27                         foreach my $f (qw(mm search over)) {
  28                                 # we bump refcnt by assigning tmp, here:
  29                                 my $tmp = $ibx->{$f} or next;
  30                                 next if Devel::Peek::SvREFCNT($tmp) > 2;
  31                                 delete $ibx->{$f};
  32                                 # refcnt is zero when tmp is out-of-scope
  33                         }
  34                 }
  35                 if (my $git = $ibx->{git}) {
  36                         $again = $git->cleanup;
  37                 }
  38                 if (my $gits = $ibx->{-repo_objs}) {
  39                         foreach my $git (@$gits) {
  40                                 $again = 1 if $git->cleanup;
  41                         }
  42                 }
  43                 if ($have_devel_peek) {
  44                         $again ||= !!($ibx->{over} || $ibx->{mm} ||
  45                                       $ibx->{search});
  46                 }
  47                 $next->{"$ibx"} = $ibx if $again;
  48         }
  49         $CLEANUP = $next;
  50 }
  51
  52 sub cleanup_possible () {
  53         # no need to require DS, here, if it were enabled another
  54         # module would've require'd it, already
  55         eval { PublicInbox::DS::in_loop() } or return 0;
  56
  57         eval {
  58                 require Devel::Peek; # needs separate package in Fedora
  59                 $have_devel_peek = 1;
  60         };
  61         1;
  62 }
  63
  64 sub _cleanup_later ($) {
  65         my ($self) = @_;
  66         $cleanup_avail = cleanup_possible() if $cleanup_avail < 0;
  67         return if $cleanup_avail != 1;
  68         $cleanup_timer ||= PublicInbox::DS::later(*cleanup_task);
  69         $CLEANUP->{"$self"} = $self;
  70 }
  71
  72 sub _set_uint ($$$) {
  73         my ($opts, $field, $default) = @_;
  74         my $val = $opts->{$field};
  75         if (defined $val) {
  76                 $val = $val->[-1] if ref($val) eq 'ARRAY';
  77                 $val = undef if $val !~ /\A[0-9]+\z/;
  78         }
  79         $opts->{$field} = $val || $default;
  80 }
  81
  82 sub _set_limiter ($$$) {
  83         my ($self, $pi_config, $pfx) = @_;
  84         my $lkey = "-${pfx}_limiter";
  85         $self->{$lkey} ||= eval {
  86                 # full key is: publicinbox.$NAME.httpbackendmax
  87                 my $mkey = $pfx.'max';
  88                 my $val = $self->{$mkey} or return;
  89                 my $lim;
  90                 if ($val =~ /\A[0-9]+\z/) {
  91                         require PublicInbox::Qspawn;
  92                         $lim = PublicInbox::Qspawn::Limiter->new($val);
  93                 } elsif ($val =~ /\A[a-z][a-z0-9]*\z/) {
  94                         $lim = $pi_config->limiter($val);
  95                         warn "$mkey limiter=$val not found\n" if !$lim;
  96                 } else {
  97                         warn "$mkey limiter=$val not understood\n";
  98                 }
  99                 $lim;
 100         }
 101 }
 102
 103 sub new {
 104         my ($class, $opts) = @_;
 105         my $v = $opts->{address} ||= 'public-inbox@example.com';
 106         my $p = $opts->{-primary_address} = ref($v) eq 'ARRAY' ? $v->[0] : $v;
 107         $opts->{domain} = ($p =~ /\@(\S+)\z/) ? $1 : 'localhost';
 108         my $pi_config = delete $opts->{-pi_config};
 109         _set_limiter($opts, $pi_config, 'httpbackend');
 110         _set_uint($opts, 'feedmax', 25);
 111         $opts->{nntpserver} ||= $pi_config->{'publicinbox.nntpserver'};
 112         my $dir = $opts->{inboxdir};
 113         if (defined $dir && -f "$dir/inbox.lock") {
 114                 $opts->{version} = 2;
 115         }
 116
 117         # allow any combination of multi-line or comma-delimited hide entries
 118         my $hide = {};
 119         if (defined(my $h = $opts->{hide})) {
 120                 foreach my $v (@$h) {
 121                         $hide->{$_} = 1 foreach (split(/\s*,\s*/, $v));
 122                 }
 123                 $opts->{-hide} = $hide;
 124         }
 125         bless $opts, $class;
 126 }
 127
 128 sub version { $_[0]->{version} // 1 }
 129
 130 sub git_epoch {
 131         my ($self, $epoch) = @_;
 132         $self->version == 2 or return;
 133         $self->{"$epoch.git"} ||= eval {
 134                 my $git_dir = "$self->{inboxdir}/git/$epoch.git";
 135                 my $g = PublicInbox::Git->new($git_dir);
 136                 $g->{-httpbackend_limiter} = $self->{-httpbackend_limiter};
 137                 # no cleanup needed, we never cat-file off this, only clone
 138                 $g;
 139         };
 140 }
 141
 142 sub git {
 143         my ($self) = @_;
 144         $self->{git} ||= eval {
 145                 my $git_dir = $self->{inboxdir};
 146                 $git_dir .= '/all.git' if $self->version == 2;
 147                 my $g = PublicInbox::Git->new($git_dir);
 148                 $g->{-httpbackend_limiter} = $self->{-httpbackend_limiter};
 149                 _cleanup_later($self);
 150                 $g;
 151         };
 152 }
 153
 154 sub max_git_epoch {
 155         my ($self) = @_;
 156         return if $self->version < 2;
 157         my $cur = $self->{-max_git_epoch};
 158         my $changed = git($self)->alternates_changed;
 159         if (!defined($cur) || $changed) {
 160                 $self->git->cleanup if $changed;
 161                 my $gits = "$self->{inboxdir}/git";
 162                 if (opendir my $dh, $gits) {
 163                         my $max = -1;
 164                         while (defined(my $git_dir = readdir($dh))) {
 165                                 $git_dir =~ m!\A([0-9]+)\.git\z! or next;
 166                                 $max = $1 if $1 > $max;
 167                         }
 168                         $cur = $self->{-max_git_epoch} = $max if $max >= 0;
 169                 } else {
 170                         warn "opendir $gits failed: $!\n";
 171                 }
 172         }
 173         $cur;
 174 }
 175
 176 sub mm {
 177         my ($self) = @_;
 178         $self->{mm} ||= eval {
 179                 require PublicInbox::Msgmap;
 180                 _cleanup_later($self);
 181                 my $dir = $self->{inboxdir};
 182                 if ($self->version >= 2) {
 183                         PublicInbox::Msgmap->new_file("$dir/msgmap.sqlite3");
 184                 } else {
 185                         PublicInbox::Msgmap->new($dir);
 186                 }
 187         };
 188 }
 189
 190 sub search ($;$) {
 191         my ($self, $over_only) = @_;
 192         my $srch = $self->{search} ||= eval {
 193                 _cleanup_later($self);
 194                 require PublicInbox::Search;
 195                 PublicInbox::Search->new($self);
 196         };
 197         ($over_only || eval { $srch->xdb }) ? $srch : undef;
 198 }
 199
 200 sub over ($) {
 201         my ($self) = @_;
 202         my $srch = search($self, 1) or return;
 203         $self->{over} ||= eval {
 204                 my $over = $srch->{over_ro};
 205                 $over->dbh_new; # may fail
 206                 $over;
 207         }
 208 }
 209
 210 sub try_cat {
 211         my ($path) = @_;
 212         my $rv = '';
 213         if (open(my $fh, '<', $path)) {
 214                 local $/;
 215                 $rv = <$fh>;
 216         }
 217         $rv;
 218 }
 219
 220 sub description {
 221         my ($self) = @_;
 222         $self->{description} //= do {
 223                 my $desc = try_cat("$self->{inboxdir}/description");
 224                 local $/ = "\n";
 225                 chomp $desc;
 226                 $desc =~ s/\s+/ /smg;
 227                 $desc eq '' ? '($INBOX_DIR/description missing)' : $desc;
 228         };
 229 }
 230
 231 sub cloneurl {
 232         my ($self) = @_;
 233         $self->{cloneurl} //=
 234                 [ split(/\s+/s, try_cat("$self->{inboxdir}/cloneurl")) ];
 235 }
 236
 237 sub base_url {
 238         my ($self, $env) = @_; # env - PSGI env
 239         if ($env) {
 240                 my $url = PublicInbox::Git::host_prefix_url($env, '');
 241                 # for mount in Plack::Builder
 242                 $url .= '/' if $url !~ m!/\z!;
 243                 return $url .= $self->{name} . '/';
 244         }
 245         # called from a non-PSGI environment (e.g. NNTP/POP3):
 246         $self->{-base_url} ||= do {
 247                 my $url = $self->{url}->[0] or return undef;
 248                 # expand protocol-relative URLs to HTTPS if we're
 249                 # not inside a web server
 250                 $url = "https:$url" if $url =~ m!\A//!;
 251                 $url .= '/' if $url !~ m!/\z!;
 252                 $url;
 253         };
 254 }
 255
 256 sub nntp_url {
 257         my ($self) = @_;
 258         $self->{-nntp_url} ||= do {
 259                 # no checking for nntp_usable here, we can point entirely
 260                 # to non-local servers or users run by a different user
 261                 my $ns = $self->{nntpserver};
 262                 my $group = $self->{newsgroup};
 263                 my @urls;
 264                 if ($ns && $group) {
 265                         $ns = [ $ns ] if ref($ns) ne 'ARRAY';
 266                         @urls = map {
 267                                 my $u = m!\Anntps?://! ? $_ : "nntp://$_";
 268                                 $u .= '/' if $u !~ m!/\z!;
 269                                 $u.$group;
 270                         } @$ns;
 271                 }
 272
 273                 my $mirrors = $self->{nntpmirror};
 274                 if ($mirrors) {
 275                         my @m;
 276                         foreach (@$mirrors) {
 277                                 my $u = m!\Anntps?://! ? $_ : "nntp://$_";
 278                                 if ($u =~ m!\Anntps?://[^/]+/?\z!) {
 279                                         if ($group) {
 280                                                 $u .= '/' if $u !~ m!/\z!;
 281                                                 $u .= $group;
 282                                         } else {
 283                                                 warn
 284 "publicinbox.$self->{name}.nntpmirror=$_ missing newsgroup name\n";
 285                                         }
 286                                 }
 287                                 # else: allow full URLs like:
 288                                 # nntp://news.example.com/alt.example
 289                                 push @m, $u;
 290                         }
 291
 292                         # List::Util::uniq requires Perl 5.26+, maybe we
 293                         # can use it by 2030 or so
 294                         my %seen;
 295                         @urls = grep { !$seen{$_}++ } (@urls, @m);
 296                 }
 297                 \@urls;
 298         };
 299 }
 300
 301 sub nntp_usable {
 302         my ($self) = @_;
 303         my $ret = mm($self) && over($self);
 304         $self->{mm} = $self->{over} = $self->{search} = undef;
 305         $ret;
 306 }
 307
 308 # for v1 users w/o SQLite only
 309 sub msg_by_path ($$;$) {
 310         my ($self, $path, $ref) = @_;
 311         my $str = git($self)->cat_file('HEAD:'.$path, $ref);
 312         $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s if $str;
 313         $str;
 314 }
 315
 316 sub msg_by_smsg ($$;$) {
 317         my ($self, $smsg, $ref) = @_;
 318
 319         # ghosts may have undef smsg (from SearchThread.node) or
 320         # no {blob} field
 321         return unless defined $smsg;
 322         defined(my $blob = $smsg->{blob}) or return;
 323
 324         my $str = git($self)->cat_file($blob, $ref);
 325         $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s if $str;
 326         $str;
 327 }
 328
 329 sub smsg_mime {
 330         my ($self, $smsg, $ref) = @_;
 331         if (my $s = msg_by_smsg($self, $smsg, $ref)) {
 332                 $smsg->{mime} = PublicInbox::MIME->new($s);
 333                 return $smsg;
 334         }
 335 }
 336
 337 sub mid2num($$) {
 338         my ($self, $mid) = @_;
 339         my $mm = mm($self) or return;
 340         $mm->num_for($mid);
 341 }
 342
 343 sub smsg_by_mid ($$) {
 344         my ($self, $mid) = @_;
 345         my $over = over($self) or return;
 346         # favor the Message-ID we used for the NNTP article number:
 347         defined(my $num = mid2num($self, $mid)) or return;
 348         my $smsg = $over->get_art($num) or return;
 349         PublicInbox::SearchMsg::psgi_cull($smsg);
 350 }
 351
 352 sub msg_by_mid ($$;$) {
 353         my ($self, $mid, $ref) = @_;
 354
 355         over($self) or
 356                 return msg_by_path($self, mid2path($mid), $ref);
 357
 358         my $smsg = smsg_by_mid($self, $mid);
 359         $smsg ? msg_by_smsg($self, $smsg, $ref) : undef;
 360 }
 361
 362 sub recent {
 363         my ($self, $opts, $after, $before) = @_;
 364         over($self)->recent($opts, $after, $before);
 365 }
 366
 367 sub modified {
 368         my ($self) = @_;
 369         if (my $over = over($self)) {
 370                 my $msgs = $over->recent({limit => 1});
 371                 if (my $smsg = $msgs->[0]) {
 372                         return $smsg->{ts};
 373                 }
 374                 return time;
 375         }
 376         git($self)->modified; # v1
 377 }
 378
 379 1;