lib/PublicInbox/Inbox.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Represents a public-inbox (which may have multiple mailing addresses)
   5 package PublicInbox::Inbox;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::Git;
   9 use PublicInbox::MID qw(mid2path);
  10 use PublicInbox::Eml;
  11
  12 # Long-running "git-cat-file --batch" processes won't notice
  13 # unlinked packs, so we need to restart those processes occasionally.
  14 # Xapian and SQLite file handles are mostly stable, but sometimes an
  15 # admin will attempt to replace them atomically after compact/vacuum
  16 # and we need to be prepared for that.
  17 my $cleanup_timer;
  18 my $cleanup_avail = -1; # 0, or 1
  19 my $have_devel_peek;
  20 my $CLEANUP = {}; # string(inbox) -> inbox
  21
  22 sub git_cleanup ($) {
  23         my ($self) = @_;
  24         my $git = $self->{git} or return;
  25         $git->cleanup;
  26 }
  27
  28 sub cleanup_task () {
  29         $cleanup_timer = undef;
  30         my $next = {};
  31         for my $ibx (values %$CLEANUP) {
  32                 my $again;
  33                 if ($have_devel_peek) {
  34                         foreach my $f (qw(search)) {
  35                                 # we bump refcnt by assigning tmp, here:
  36                                 my $tmp = $ibx->{$f} or next;
  37                                 next if Devel::Peek::SvREFCNT($tmp) > 2;
  38                                 delete $ibx->{$f};
  39                                 # refcnt is zero when tmp is out-of-scope
  40                         }
  41                 }
  42                 git_cleanup($ibx);
  43                 if (my $gits = $ibx->{-repo_objs}) {
  44                         foreach my $git (@$gits) {
  45                                 $again = 1 if $git->cleanup;
  46                         }
  47                 }
  48                 check_inodes($ibx);
  49                 if ($have_devel_peek) {
  50                         $again ||= !!$ibx->{search};
  51                 }
  52                 $next->{"$ibx"} = $ibx if $again;
  53         }
  54         $CLEANUP = $next;
  55 }
  56
  57 sub cleanup_possible () {
  58         # no need to require DS, here, if it were enabled another
  59         # module would've require'd it, already
  60         eval { PublicInbox::DS::in_loop() } or return 0;
  61
  62         eval {
  63                 require Devel::Peek; # needs separate package in Fedora
  64                 $have_devel_peek = 1;
  65         };
  66         1;
  67 }
  68
  69 sub _cleanup_later ($) {
  70         my ($self) = @_;
  71         $cleanup_avail = cleanup_possible() if $cleanup_avail < 0;
  72         return if $cleanup_avail != 1;
  73         $cleanup_timer ||= PublicInbox::DS::later(*cleanup_task);
  74         $CLEANUP->{"$self"} = $self;
  75 }
  76
  77 sub _set_uint ($$$) {
  78         my ($opts, $field, $default) = @_;
  79         my $val = $opts->{$field};
  80         if (defined $val) {
  81                 $val = $val->[-1] if ref($val) eq 'ARRAY';
  82                 $val = undef if $val !~ /\A[0-9]+\z/;
  83         }
  84         $opts->{$field} = $val || $default;
  85 }
  86
  87 sub _set_limiter ($$$) {
  88         my ($self, $pi_config, $pfx) = @_;
  89         my $lkey = "-${pfx}_limiter";
  90         $self->{$lkey} ||= do {
  91                 # full key is: publicinbox.$NAME.httpbackendmax
  92                 my $mkey = $pfx.'max';
  93                 my $val = $self->{$mkey} or return;
  94                 my $lim;
  95                 if ($val =~ /\A[0-9]+\z/) {
  96                         require PublicInbox::Qspawn;
  97                         $lim = PublicInbox::Qspawn::Limiter->new($val);
  98                 } elsif ($val =~ /\A[a-z][a-z0-9]*\z/) {
  99                         $lim = $pi_config->limiter($val);
 100                         warn "$mkey limiter=$val not found\n" if !$lim;
 101                 } else {
 102                         warn "$mkey limiter=$val not understood\n";
 103                 }
 104                 $lim;
 105         }
 106 }
 107
 108 sub new {
 109         my ($class, $opts) = @_;
 110         my $v = $opts->{address} ||= [ 'public-inbox@example.com' ];
 111         my $p = $opts->{-primary_address} = ref($v) eq 'ARRAY' ? $v->[0] : $v;
 112         $opts->{domain} = ($p =~ /\@(\S+)\z/) ? $1 : 'localhost';
 113         my $pi_config = delete $opts->{-pi_config};
 114         _set_limiter($opts, $pi_config, 'httpbackend');
 115         _set_uint($opts, 'feedmax', 25);
 116         $opts->{nntpserver} ||= $pi_config->{'publicinbox.nntpserver'};
 117         my $dir = $opts->{inboxdir};
 118         if (defined $dir && -f "$dir/inbox.lock") {
 119                 $opts->{version} = 2;
 120         }
 121
 122         # allow any combination of multi-line or comma-delimited hide entries
 123         my $hide = {};
 124         if (defined(my $h = $opts->{hide})) {
 125                 foreach my $v (@$h) {
 126                         $hide->{$_} = 1 foreach (split(/\s*,\s*/, $v));
 127                 }
 128                 $opts->{-hide} = $hide;
 129         }
 130         bless $opts, $class;
 131 }
 132
 133 sub version { $_[0]->{version} // 1 }
 134
 135 sub git_epoch {
 136         my ($self, $epoch) = @_;
 137         $self->version == 2 or return;
 138         $self->{"$epoch.git"} ||= do {
 139                 my $git_dir = "$self->{inboxdir}/git/$epoch.git";
 140                 my $g = PublicInbox::Git->new($git_dir);
 141                 $g->{-httpbackend_limiter} = $self->{-httpbackend_limiter};
 142                 # no cleanup needed, we never cat-file off this, only clone
 143                 $g;
 144         };
 145 }
 146
 147 sub git {
 148         my ($self) = @_;
 149         $self->{git} ||= do {
 150                 my $git_dir = $self->{inboxdir};
 151                 $git_dir .= '/all.git' if $self->version == 2;
 152                 my $g = PublicInbox::Git->new($git_dir);
 153                 $g->{-httpbackend_limiter} = $self->{-httpbackend_limiter};
 154                 _cleanup_later($self);
 155                 $g;
 156         };
 157 }
 158
 159 sub max_git_epoch {
 160         my ($self) = @_;
 161         return if $self->version < 2;
 162         my $cur = $self->{-max_git_epoch};
 163         my $changed = git($self)->alternates_changed;
 164         if (!defined($cur) || $changed) {
 165                 git_cleanup($self) if $changed;
 166                 my $gits = "$self->{inboxdir}/git";
 167                 if (opendir my $dh, $gits) {
 168                         my $max = -1;
 169                         while (defined(my $git_dir = readdir($dh))) {
 170                                 $git_dir =~ m!\A([0-9]+)\.git\z! or next;
 171                                 $max = $1 if $1 > $max;
 172                         }
 173                         $cur = $self->{-max_git_epoch} = $max if $max >= 0;
 174                 } else {
 175                         warn "opendir $gits failed: $!\n";
 176                 }
 177         }
 178         $cur;
 179 }
 180
 181 sub mm {
 182         my ($self) = @_;
 183         $self->{mm} ||= eval {
 184                 require PublicInbox::Msgmap;
 185                 my $dir = $self->{inboxdir};
 186                 if ($self->version >= 2) {
 187                         PublicInbox::Msgmap->new_file("$dir/msgmap.sqlite3");
 188                 } else {
 189                         PublicInbox::Msgmap->new($dir);
 190                 }
 191         };
 192 }
 193
 194 sub search ($;$$) {
 195         my ($self, $over_only, $ctx) = @_;
 196         my $srch = $self->{search} ||= eval {
 197                 _cleanup_later($self);
 198                 require PublicInbox::Search;
 199                 PublicInbox::Search->new($self);
 200         };
 201         ($over_only || eval { $srch->xdb }) ? $srch : do {
 202                 $ctx and $ctx->{env}->{'psgi.errors'}->print(<<EOF);
 203 `$self->{name}' search went away unexpectedly
 204 EOF
 205                 undef;
 206         };
 207 }
 208
 209 sub over {
 210         $_[0]->{over} //= eval {
 211                 my $srch = search($_[0], 1) or return;
 212                 my $over = PublicInbox::Over->new("$srch->{xpfx}/over.sqlite3");
 213                 $over->dbh; # may fail
 214                 $over;
 215         };
 216 }
 217
 218 sub try_cat {
 219         my ($path) = @_;
 220         my $rv = '';
 221         if (open(my $fh, '<', $path)) {
 222                 local $/;
 223                 $rv = <$fh>;
 224         }
 225         $rv;
 226 }
 227
 228 sub description {
 229         my ($self) = @_;
 230         ($self->{description} //= do {
 231                 my $desc = try_cat("$self->{inboxdir}/description");
 232                 local $/ = "\n";
 233                 chomp $desc;
 234                 utf8::decode($desc);
 235                 $desc =~ s/\s+/ /smg;
 236                 $desc eq '' ? undef : $desc;
 237         }) // '($INBOX_DIR/description missing)';
 238 }
 239
 240 sub cloneurl {
 241         my ($self) = @_;
 242         ($self->{cloneurl} //= do {
 243                 my $s = try_cat("$self->{inboxdir}/cloneurl");
 244                 my @urls = split(/\s+/s, $s);
 245                 scalar(@urls) ? \@urls : undef
 246         }) // [];
 247 }
 248
 249 sub base_url {
 250         my ($self, $env) = @_; # env - PSGI env
 251         if ($env) {
 252                 my $url = PublicInbox::Git::host_prefix_url($env, '');
 253                 # for mount in Plack::Builder
 254                 $url .= '/' if $url !~ m!/\z!;
 255                 return $url .= $self->{name} . '/';
 256         }
 257         # called from a non-PSGI environment (e.g. NNTP/POP3):
 258         $self->{-base_url} ||= do {
 259                 my $url = $self->{url}->[0] or return undef;
 260                 # expand protocol-relative URLs to HTTPS if we're
 261                 # not inside a web server
 262                 $url = "https:$url" if $url =~ m!\A//!;
 263                 $url .= '/' if $url !~ m!/\z!;
 264                 $url;
 265         };
 266 }
 267
 268 sub nntp_url {
 269         my ($self) = @_;
 270         $self->{-nntp_url} ||= do {
 271                 # no checking for nntp_usable here, we can point entirely
 272                 # to non-local servers or users run by a different user
 273                 my $ns = $self->{nntpserver};
 274                 my $group = $self->{newsgroup};
 275                 my @urls;
 276                 if ($ns && $group) {
 277                         $ns = [ $ns ] if ref($ns) ne 'ARRAY';
 278                         @urls = map {
 279                                 my $u = m!\Anntps?://! ? $_ : "nntp://$_";
 280                                 $u .= '/' if $u !~ m!/\z!;
 281                                 $u.$group;
 282                         } @$ns;
 283                 }
 284
 285                 my $mirrors = $self->{nntpmirror};
 286                 if ($mirrors) {
 287                         my @m;
 288                         foreach (@$mirrors) {
 289                                 my $u = m!\Anntps?://! ? $_ : "nntp://$_";
 290                                 if ($u =~ m!\Anntps?://[^/]+/?\z!) {
 291                                         if ($group) {
 292                                                 $u .= '/' if $u !~ m!/\z!;
 293                                                 $u .= $group;
 294                                         } else {
 295                                                 warn
 296 "publicinbox.$self->{name}.nntpmirror=$_ missing newsgroup name\n";
 297                                         }
 298                                 }
 299                                 # else: allow full URLs like:
 300                                 # nntp://news.example.com/alt.example
 301                                 push @m, $u;
 302                         }
 303
 304                         # List::Util::uniq requires Perl 5.26+, maybe we
 305                         # can use it by 2030 or so
 306                         my %seen;
 307                         @urls = grep { !$seen{$_}++ } (@urls, @m);
 308                 }
 309                 \@urls;
 310         };
 311 }
 312
 313 sub nntp_usable {
 314         my ($self) = @_;
 315         my $ret = mm($self) && over($self);
 316         $self->{mm} = $self->{over} = $self->{search} = undef;
 317         $ret;
 318 }
 319
 320 # for v1 users w/o SQLite only
 321 sub msg_by_path ($$) {
 322         my ($self, $path) = @_;
 323         git($self)->cat_file('HEAD:'.$path);
 324 }
 325
 326 sub msg_by_smsg ($$) {
 327         my ($self, $smsg) = @_;
 328
 329         # ghosts may have undef smsg (from SearchThread.node) or
 330         # no {blob} field
 331         return unless defined $smsg;
 332         defined(my $blob = $smsg->{blob}) or return;
 333
 334         git($self)->cat_file($blob);
 335 }
 336
 337 sub smsg_eml {
 338         my ($self, $smsg) = @_;
 339         my $bref = msg_by_smsg($self, $smsg) or return;
 340         my $eml = PublicInbox::Eml->new($bref);
 341         $smsg->populate($eml) unless exists($smsg->{num}); # v1 w/o SQLite
 342         $eml;
 343 }
 344
 345 sub mid2num($$) {
 346         my ($self, $mid) = @_;
 347         my $mm = mm($self) or return;
 348         $mm->num_for($mid);
 349 }
 350
 351 sub smsg_by_mid ($$) {
 352         my ($self, $mid) = @_;
 353         my $over = over($self) or return;
 354         # favor the Message-ID we used for the NNTP article number:
 355         defined(my $num = mid2num($self, $mid)) or return;
 356         my $smsg = $over->get_art($num) or return;
 357         PublicInbox::Smsg::psgi_cull($smsg);
 358 }
 359
 360 sub msg_by_mid ($$) {
 361         my ($self, $mid) = @_;
 362
 363         over($self) or
 364                 return msg_by_path($self, mid2path($mid));
 365
 366         my $smsg = smsg_by_mid($self, $mid);
 367         $smsg ? msg_by_smsg($self, $smsg) : undef;
 368 }
 369
 370 sub recent {
 371         my ($self, $opts, $after, $before) = @_;
 372         over($self)->recent($opts, $after, $before);
 373 }
 374
 375 sub modified {
 376         my ($self) = @_;
 377         if (my $over = over($self)) {
 378                 my $msgs = $over->recent({limit => 1});
 379                 if (my $smsg = $msgs->[0]) {
 380                         return $smsg->{ts};
 381                 }
 382                 return time;
 383         }
 384         git($self)->modified; # v1
 385 }
 386
 387 # returns prefix => pathname mapping
 388 # (pathname is NOT public, but prefix is used for Xapian queries)
 389 sub altid_map ($) {
 390         my ($self) = @_;
 391         $self->{-altid_map} //= eval {
 392                 require PublicInbox::AltId;
 393                 my $altid = $self->{altid} or return {};
 394                 my %h = map {;
 395                         my $x = PublicInbox::AltId->new($self, $_);
 396                         "$x->{prefix}" => $x->{filename}
 397                 } @$altid;
 398                 \%h;
 399         } // {};
 400 }
 401
 402 # $obj must respond to ->on_inbox_unlock, which takes Inbox ($self) as an arg
 403 sub subscribe_unlock {
 404         my ($self, $ident, $obj) = @_;
 405         $self->{unlock_subs}->{$ident} = $obj;
 406 }
 407
 408 sub unsubscribe_unlock {
 409         my ($self, $ident) = @_;
 410         delete $self->{unlock_subs}->{$ident};
 411 }
 412
 413 sub check_inodes ($) {
 414         my ($self) = @_;
 415         for (qw(over mm)) { # TODO: search
 416                 $self->{$_}->check_inodes if $self->{$_};
 417         }
 418 }
 419
 420 # called by inotify
 421 sub on_unlock {
 422         my ($self) = @_;
 423         check_inodes($self);
 424         my $subs = $self->{unlock_subs} or return;
 425         for (values %$subs) {
 426                 eval { $_->on_inbox_unlock($self) };
 427                 warn "E: $@ ($self->{inboxdir})\n" if $@;
 428         }
 429 }
 430
 431 1;