lib/PublicInbox/Inbox.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Represents a public-inbox (which may have multiple mailing addresses)
   5 package PublicInbox::Inbox;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::Git;
   9 use PublicInbox::MID qw(mid2path);
  10 use PublicInbox::Eml;
  11
  12 # Long-running "git-cat-file --batch" processes won't notice
  13 # unlinked packs, so we need to restart those processes occasionally.
  14 # Xapian and SQLite file handles are mostly stable, but sometimes an
  15 # admin will attempt to replace them atomically after compact/vacuum
  16 # and we need to be prepared for that.
  17 my $cleanup_timer;
  18 my $cleanup_avail = -1; # 0, or 1
  19 my $have_devel_peek;
  20 my $CLEANUP = {}; # string(inbox) -> inbox
  21
  22 sub git_cleanup ($) {
  23         my ($self) = @_;
  24         my $git = $self->{git} or return;
  25         $git->cleanup;
  26 }
  27
  28 sub cleanup_task () {
  29         $cleanup_timer = undef;
  30         my $next = {};
  31         for my $ibx (values %$CLEANUP) {
  32                 my $again;
  33                 if ($have_devel_peek) {
  34                         foreach my $f (qw(search)) {
  35                                 # we bump refcnt by assigning tmp, here:
  36                                 my $tmp = $ibx->{$f} or next;
  37                                 next if Devel::Peek::SvREFCNT($tmp) > 2;
  38                                 delete $ibx->{$f};
  39                                 # refcnt is zero when tmp is out-of-scope
  40                         }
  41                 }
  42                 git_cleanup($ibx);
  43                 if (my $gits = $ibx->{-repo_objs}) {
  44                         foreach my $git (@$gits) {
  45                                 $again = 1 if $git->cleanup;
  46                         }
  47                 }
  48                 check_inodes($ibx);
  49                 if ($have_devel_peek) {
  50                         $again ||= !!$ibx->{search};
  51                 }
  52                 $next->{"$ibx"} = $ibx if $again;
  53         }
  54         $CLEANUP = $next;
  55 }
  56
  57 sub cleanup_possible () {
  58         # no need to require DS, here, if it were enabled another
  59         # module would've require'd it, already
  60         eval { PublicInbox::DS::in_loop() } or return 0;
  61
  62         eval {
  63                 require Devel::Peek; # needs separate package in Fedora
  64                 $have_devel_peek = 1;
  65         };
  66         1;
  67 }
  68
  69 sub _cleanup_later ($) {
  70         my ($self) = @_;
  71         $cleanup_avail = cleanup_possible() if $cleanup_avail < 0;
  72         return if $cleanup_avail != 1;
  73         $cleanup_timer //= PublicInbox::DS::later(\&cleanup_task);
  74         $CLEANUP->{"$self"} = $self;
  75 }
  76
  77 sub _set_uint ($$$) {
  78         my ($opts, $field, $default) = @_;
  79         my $val = $opts->{$field};
  80         if (defined $val) {
  81                 $val = $val->[-1] if ref($val) eq 'ARRAY';
  82                 $val = undef if $val !~ /\A[0-9]+\z/;
  83         }
  84         $opts->{$field} = $val || $default;
  85 }
  86
  87 sub _set_limiter ($$$) {
  88         my ($self, $pi_config, $pfx) = @_;
  89         my $lkey = "-${pfx}_limiter";
  90         $self->{$lkey} ||= do {
  91                 # full key is: publicinbox.$NAME.httpbackendmax
  92                 my $mkey = $pfx.'max';
  93                 my $val = $self->{$mkey} or return;
  94                 my $lim;
  95                 if ($val =~ /\A[0-9]+\z/) {
  96                         require PublicInbox::Qspawn;
  97                         $lim = PublicInbox::Qspawn::Limiter->new($val);
  98                 } elsif ($val =~ /\A[a-z][a-z0-9]*\z/) {
  99                         $lim = $pi_config->limiter($val);
 100                         warn "$mkey limiter=$val not found\n" if !$lim;
 101                 } else {
 102                         warn "$mkey limiter=$val not understood\n";
 103                 }
 104                 $lim;
 105         }
 106 }
 107
 108 sub new {
 109         my ($class, $opts) = @_;
 110         my $v = $opts->{address} ||= [ 'public-inbox@example.com' ];
 111         my $p = $opts->{-primary_address} = ref($v) eq 'ARRAY' ? $v->[0] : $v;
 112         $opts->{domain} = ($p =~ /\@(\S+)\z/) ? $1 : 'localhost';
 113         my $pi_config = delete $opts->{-pi_config};
 114         _set_limiter($opts, $pi_config, 'httpbackend');
 115         _set_uint($opts, 'feedmax', 25);
 116         $opts->{nntpserver} ||= $pi_config->{'publicinbox.nntpserver'};
 117         my $dir = $opts->{inboxdir};
 118         if (defined $dir && -f "$dir/inbox.lock") {
 119                 $opts->{version} = 2;
 120         }
 121
 122         # allow any combination of multi-line or comma-delimited hide entries
 123         my $hide = {};
 124         if (defined(my $h = $opts->{hide})) {
 125                 foreach my $v (@$h) {
 126                         $hide->{$_} = 1 foreach (split(/\s*,\s*/, $v));
 127                 }
 128                 $opts->{-hide} = $hide;
 129         }
 130         bless $opts, $class;
 131 }
 132
 133 sub version { $_[0]->{version} // 1 }
 134
 135 sub git_epoch {
 136         my ($self, $epoch) = @_; # v2-only, callers always supply $epoch
 137         $self->{"$epoch.git"} ||= do {
 138                 my $git_dir = "$self->{inboxdir}/git/$epoch.git";
 139                 return unless -d $git_dir;
 140                 my $g = PublicInbox::Git->new($git_dir);
 141                 $g->{-httpbackend_limiter} = $self->{-httpbackend_limiter};
 142                 # no cleanup needed, we never cat-file off this, only clone
 143                 $g;
 144         };
 145 }
 146
 147 sub git {
 148         my ($self) = @_;
 149         $self->{git} ||= do {
 150                 my $git_dir = $self->{inboxdir};
 151                 $git_dir .= '/all.git' if $self->version == 2;
 152                 my $g = PublicInbox::Git->new($git_dir);
 153                 $g->{-httpbackend_limiter} = $self->{-httpbackend_limiter};
 154                 _cleanup_later($self);
 155                 $g;
 156         };
 157 }
 158
 159 sub max_git_epoch {
 160         my ($self) = @_;
 161         return if $self->version < 2;
 162         my $cur = $self->{-max_git_epoch};
 163         my $changed = git($self)->alternates_changed;
 164         if (!defined($cur) || $changed) {
 165                 git_cleanup($self) if $changed;
 166                 my $gits = "$self->{inboxdir}/git";
 167                 if (opendir my $dh, $gits) {
 168                         my $max = -1;
 169                         while (defined(my $git_dir = readdir($dh))) {
 170                                 $git_dir =~ m!\A([0-9]+)\.git\z! or next;
 171                                 $max = $1 if $1 > $max;
 172                         }
 173                         $cur = $self->{-max_git_epoch} = $max if $max >= 0;
 174                 } else {
 175                         warn "opendir $gits failed: $!\n";
 176                 }
 177         }
 178         $cur;
 179 }
 180
 181 sub mm {
 182         my ($self) = @_;
 183         $self->{mm} ||= eval {
 184                 require PublicInbox::Msgmap;
 185                 my $dir = $self->{inboxdir};
 186                 if ($self->version >= 2) {
 187                         PublicInbox::Msgmap->new_file("$dir/msgmap.sqlite3");
 188                 } else {
 189                         PublicInbox::Msgmap->new($dir);
 190                 }
 191         };
 192 }
 193
 194 sub search {
 195         my ($self) = @_;
 196         my $srch = $self->{search} //= eval {
 197                 _cleanup_later($self);
 198                 require PublicInbox::Search;
 199                 PublicInbox::Search->new($self);
 200         };
 201         (eval { $srch->xdb }) ? $srch : undef;
 202 }
 203
 204 sub over {
 205         $_[0]->{over} //= eval {
 206                 my $srch = $_[0]->{search} //= eval {
 207                         _cleanup_later($_[0]);
 208                         require PublicInbox::Search;
 209                         PublicInbox::Search->new($_[0]);
 210                 };
 211                 my $over = PublicInbox::Over->new("$srch->{xpfx}/over.sqlite3");
 212                 $over->dbh; # may fail
 213                 $over;
 214         };
 215 }
 216
 217
 218 sub try_cat {
 219         my ($path) = @_;
 220         my $rv = '';
 221         if (open(my $fh, '<', $path)) {
 222                 local $/;
 223                 $rv = <$fh>;
 224         }
 225         $rv;
 226 }
 227
 228 sub cat_desc ($) {
 229         my $desc = try_cat($_[0]);
 230         local $/ = "\n";
 231         chomp $desc;
 232         utf8::decode($desc);
 233         $desc =~ s/\s+/ /smg;
 234         $desc eq '' ? undef : $desc;
 235 }
 236
 237 sub description {
 238         my ($self) = @_;
 239         ($self->{description} //= cat_desc("$self->{inboxdir}/description")) //
 240                 '($INBOX_DIR/description missing)';
 241 }
 242
 243 sub cloneurl {
 244         my ($self) = @_;
 245         ($self->{cloneurl} //= do {
 246                 my $s = try_cat("$self->{inboxdir}/cloneurl");
 247                 my @urls = split(/\s+/s, $s);
 248                 scalar(@urls) ? \@urls : undef
 249         }) // [];
 250 }
 251
 252 sub base_url {
 253         my ($self, $env) = @_; # env - PSGI env
 254         if ($env) {
 255                 my $url = PublicInbox::Git::host_prefix_url($env, '');
 256                 # for mount in Plack::Builder
 257                 $url .= '/' if $url !~ m!/\z!;
 258                 return $url .= $self->{name} . '/';
 259         }
 260         # called from a non-PSGI environment (e.g. NNTP/POP3):
 261         $self->{-base_url} ||= do {
 262                 my $url = $self->{url}->[0] or return undef;
 263                 # expand protocol-relative URLs to HTTPS if we're
 264                 # not inside a web server
 265                 $url = "https:$url" if $url =~ m!\A//!;
 266                 $url .= '/' if $url !~ m!/\z!;
 267                 $url;
 268         };
 269 }
 270
 271 sub nntp_url {
 272         my ($self) = @_;
 273         $self->{-nntp_url} ||= do {
 274                 # no checking for nntp_usable here, we can point entirely
 275                 # to non-local servers or users run by a different user
 276                 my $ns = $self->{nntpserver};
 277                 my $group = $self->{newsgroup};
 278                 my @urls;
 279                 if ($ns && $group) {
 280                         $ns = [ $ns ] if ref($ns) ne 'ARRAY';
 281                         @urls = map {
 282                                 my $u = m!\Anntps?://! ? $_ : "nntp://$_";
 283                                 $u .= '/' if $u !~ m!/\z!;
 284                                 $u.$group;
 285                         } @$ns;
 286                 }
 287
 288                 my $mirrors = $self->{nntpmirror};
 289                 if ($mirrors) {
 290                         my @m;
 291                         foreach (@$mirrors) {
 292                                 my $u = m!\Anntps?://! ? $_ : "nntp://$_";
 293                                 if ($u =~ m!\Anntps?://[^/]+/?\z!) {
 294                                         if ($group) {
 295                                                 $u .= '/' if $u !~ m!/\z!;
 296                                                 $u .= $group;
 297                                         } else {
 298                                                 warn
 299 "publicinbox.$self->{name}.nntpmirror=$_ missing newsgroup name\n";
 300                                         }
 301                                 }
 302                                 # else: allow full URLs like:
 303                                 # nntp://news.example.com/alt.example
 304                                 push @m, $u;
 305                         }
 306
 307                         # List::Util::uniq requires Perl 5.26+, maybe we
 308                         # can use it by 2030 or so
 309                         my %seen;
 310                         @urls = grep { !$seen{$_}++ } (@urls, @m);
 311                 }
 312                 \@urls;
 313         };
 314 }
 315
 316 sub nntp_usable {
 317         my ($self) = @_;
 318         my $ret = mm($self) && over($self);
 319         $self->{mm} = $self->{over} = $self->{search} = undef;
 320         $ret;
 321 }
 322
 323 # for v1 users w/o SQLite only
 324 sub msg_by_path ($$) {
 325         my ($self, $path) = @_;
 326         git($self)->cat_file('HEAD:'.$path);
 327 }
 328
 329 sub msg_by_smsg ($$) {
 330         my ($self, $smsg) = @_;
 331
 332         # ghosts may have undef smsg (from SearchThread.node) or
 333         # no {blob} field
 334         return unless defined $smsg;
 335         defined(my $blob = $smsg->{blob}) or return;
 336
 337         $self->git->cat_file($blob);
 338 }
 339
 340 sub smsg_eml {
 341         my ($self, $smsg) = @_;
 342         my $bref = msg_by_smsg($self, $smsg) or return;
 343         my $eml = PublicInbox::Eml->new($bref);
 344         $smsg->populate($eml) unless exists($smsg->{num}); # v1 w/o SQLite
 345         $eml;
 346 }
 347
 348 sub smsg_by_mid ($$) {
 349         my ($self, $mid) = @_;
 350         my $over = $self->over or return;
 351         my $smsg;
 352         if (my $mm = $self->mm) {
 353                 # favor the Message-ID we used for the NNTP article number:
 354                 defined(my $num = $mm->num_for($mid)) or return;
 355                 $smsg = $over->get_art($num);
 356         } else {
 357                 my ($id, $prev);
 358                 $smsg = $over->next_by_mid($mid, \$id, \$prev);
 359         }
 360         $smsg ? PublicInbox::Smsg::psgi_cull($smsg) : undef;
 361 }
 362
 363 sub msg_by_mid ($$) {
 364         my ($self, $mid) = @_;
 365         my $smsg = smsg_by_mid($self, $mid);
 366         $smsg ? msg_by_smsg($self, $smsg) : msg_by_path($self, mid2path($mid));
 367 }
 368
 369 sub recent {
 370         my ($self, $opts, $after, $before) = @_;
 371         $self->over->recent($opts, $after, $before);
 372 }
 373
 374 sub modified {
 375         my ($self) = @_;
 376         if (my $over = $self->over) {
 377                 my $msgs = $over->recent({limit => 1});
 378                 if (my $smsg = $msgs->[0]) {
 379                         return $smsg->{ts};
 380                 }
 381                 return time;
 382         }
 383         git($self)->modified; # v1
 384 }
 385
 386 # returns prefix => pathname mapping
 387 # (pathname is NOT public, but prefix is used for Xapian queries)
 388 sub altid_map ($) {
 389         my ($self) = @_;
 390         $self->{-altid_map} //= eval {
 391                 require PublicInbox::AltId;
 392                 my $altid = $self->{altid} or return {};
 393                 my %h = map {;
 394                         my $x = PublicInbox::AltId->new($self, $_);
 395                         "$x->{prefix}" => $x->{filename}
 396                 } @$altid;
 397                 \%h;
 398         } // {};
 399 }
 400
 401 # $obj must respond to ->on_inbox_unlock, which takes Inbox ($self) as an arg
 402 sub subscribe_unlock {
 403         my ($self, $ident, $obj) = @_;
 404         $self->{unlock_subs}->{$ident} = $obj;
 405 }
 406
 407 sub unsubscribe_unlock {
 408         my ($self, $ident) = @_;
 409         delete $self->{unlock_subs}->{$ident};
 410 }
 411
 412 sub check_inodes ($) {
 413         my ($self) = @_;
 414         for (qw(over mm)) { # TODO: search
 415                 $self->{$_}->check_inodes if $self->{$_};
 416         }
 417 }
 418
 419 # called by inotify
 420 sub on_unlock {
 421         my ($self) = @_;
 422         check_inodes($self);
 423         my $subs = $self->{unlock_subs} or return;
 424         for (values %$subs) {
 425                 eval { $_->on_inbox_unlock($self) };
 426                 warn "E: $@ ($self->{inboxdir})\n" if $@;
 427         }
 428 }
 429
 430 sub uidvalidity  { $_[0]->{uidvalidity} //= $_[0]->mm->created_at }
 431
 432 sub eidx_key { $_[0]->{newsgroup} // $_[0]->{inboxdir} }
 433
 434 1;