lib/PublicInbox/Inbox.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Represents a public-inbox (which may have multiple mailing addresses)
   5 package PublicInbox::Inbox;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::Git;
   9 use PublicInbox::MID qw(mid2path);
  10 use PublicInbox::Eml;
  11
  12 # Long-running "git-cat-file --batch" processes won't notice
  13 # unlinked packs, so we need to restart those processes occasionally.
  14 # Xapian and SQLite file handles are mostly stable, but sometimes an
  15 # admin will attempt to replace them atomically after compact/vacuum
  16 # and we need to be prepared for that.
  17 my $cleanup_timer;
  18 my $cleanup_avail = -1; # 0, or 1
  19 my $have_devel_peek;
  20 my $CLEANUP = {}; # string(inbox) -> inbox
  21
  22 sub git_cleanup ($) {
  23         my ($self) = @_;
  24         my $git = $self->{git} or return;
  25         $git->cleanup;
  26 }
  27
  28 sub cleanup_task () {
  29         $cleanup_timer = undef;
  30         my $next = {};
  31         for my $ibx (values %$CLEANUP) {
  32                 my $again;
  33                 if ($have_devel_peek) {
  34                         foreach my $f (qw(mm search over)) {
  35                                 # we bump refcnt by assigning tmp, here:
  36                                 my $tmp = $ibx->{$f} or next;
  37                                 next if Devel::Peek::SvREFCNT($tmp) > 2;
  38                                 delete $ibx->{$f};
  39                                 # refcnt is zero when tmp is out-of-scope
  40                         }
  41                 }
  42                 git_cleanup($ibx);
  43                 if (my $gits = $ibx->{-repo_objs}) {
  44                         foreach my $git (@$gits) {
  45                                 $again = 1 if $git->cleanup;
  46                         }
  47                 }
  48                 if ($have_devel_peek) {
  49                         $again ||= !!($ibx->{over} || $ibx->{mm} ||
  50                                       $ibx->{search});
  51                 }
  52                 $next->{"$ibx"} = $ibx if $again;
  53         }
  54         $CLEANUP = $next;
  55 }
  56
  57 sub cleanup_possible () {
  58         # no need to require DS, here, if it were enabled another
  59         # module would've require'd it, already
  60         eval { PublicInbox::DS::in_loop() } or return 0;
  61
  62         eval {
  63                 require Devel::Peek; # needs separate package in Fedora
  64                 $have_devel_peek = 1;
  65         };
  66         1;
  67 }
  68
  69 sub _cleanup_later ($) {
  70         my ($self) = @_;
  71         $cleanup_avail = cleanup_possible() if $cleanup_avail < 0;
  72         return if $cleanup_avail != 1;
  73         $cleanup_timer ||= PublicInbox::DS::later(*cleanup_task);
  74         $CLEANUP->{"$self"} = $self;
  75 }
  76
  77 sub _set_uint ($$$) {
  78         my ($opts, $field, $default) = @_;
  79         my $val = $opts->{$field};
  80         if (defined $val) {
  81                 $val = $val->[-1] if ref($val) eq 'ARRAY';
  82                 $val = undef if $val !~ /\A[0-9]+\z/;
  83         }
  84         $opts->{$field} = $val || $default;
  85 }
  86
  87 sub _set_limiter ($$$) {
  88         my ($self, $pi_config, $pfx) = @_;
  89         my $lkey = "-${pfx}_limiter";
  90         $self->{$lkey} ||= do {
  91                 # full key is: publicinbox.$NAME.httpbackendmax
  92                 my $mkey = $pfx.'max';
  93                 my $val = $self->{$mkey} or return;
  94                 my $lim;
  95                 if ($val =~ /\A[0-9]+\z/) {
  96                         require PublicInbox::Qspawn;
  97                         $lim = PublicInbox::Qspawn::Limiter->new($val);
  98                 } elsif ($val =~ /\A[a-z][a-z0-9]*\z/) {
  99                         $lim = $pi_config->limiter($val);
 100                         warn "$mkey limiter=$val not found\n" if !$lim;
 101                 } else {
 102                         warn "$mkey limiter=$val not understood\n";
 103                 }
 104                 $lim;
 105         }
 106 }
 107
 108 sub new {
 109         my ($class, $opts) = @_;
 110         my $v = $opts->{address} ||= [ 'public-inbox@example.com' ];
 111         my $p = $opts->{-primary_address} = ref($v) eq 'ARRAY' ? $v->[0] : $v;
 112         $opts->{domain} = ($p =~ /\@(\S+)\z/) ? $1 : 'localhost';
 113         my $pi_config = delete $opts->{-pi_config};
 114         _set_limiter($opts, $pi_config, 'httpbackend');
 115         _set_uint($opts, 'feedmax', 25);
 116         $opts->{nntpserver} ||= $pi_config->{'publicinbox.nntpserver'};
 117         my $dir = $opts->{inboxdir};
 118         if (defined $dir && -f "$dir/inbox.lock") {
 119                 $opts->{version} = 2;
 120         }
 121
 122         # allow any combination of multi-line or comma-delimited hide entries
 123         my $hide = {};
 124         if (defined(my $h = $opts->{hide})) {
 125                 foreach my $v (@$h) {
 126                         $hide->{$_} = 1 foreach (split(/\s*,\s*/, $v));
 127                 }
 128                 $opts->{-hide} = $hide;
 129         }
 130         bless $opts, $class;
 131 }
 132
 133 sub version { $_[0]->{version} // 1 }
 134
 135 sub git_epoch {
 136         my ($self, $epoch) = @_;
 137         $self->version == 2 or return;
 138         $self->{"$epoch.git"} ||= do {
 139                 my $git_dir = "$self->{inboxdir}/git/$epoch.git";
 140                 my $g = PublicInbox::Git->new($git_dir);
 141                 $g->{-httpbackend_limiter} = $self->{-httpbackend_limiter};
 142                 # no cleanup needed, we never cat-file off this, only clone
 143                 $g;
 144         };
 145 }
 146
 147 sub git {
 148         my ($self) = @_;
 149         $self->{git} ||= do {
 150                 my $git_dir = $self->{inboxdir};
 151                 $git_dir .= '/all.git' if $self->version == 2;
 152                 my $g = PublicInbox::Git->new($git_dir);
 153                 $g->{-httpbackend_limiter} = $self->{-httpbackend_limiter};
 154                 _cleanup_later($self);
 155                 $g;
 156         };
 157 }
 158
 159 sub max_git_epoch {
 160         my ($self) = @_;
 161         return if $self->version < 2;
 162         my $cur = $self->{-max_git_epoch};
 163         my $changed = git($self)->alternates_changed;
 164         if (!defined($cur) || $changed) {
 165                 git_cleanup($self) if $changed;
 166                 my $gits = "$self->{inboxdir}/git";
 167                 if (opendir my $dh, $gits) {
 168                         my $max = -1;
 169                         while (defined(my $git_dir = readdir($dh))) {
 170                                 $git_dir =~ m!\A([0-9]+)\.git\z! or next;
 171                                 $max = $1 if $1 > $max;
 172                         }
 173                         $cur = $self->{-max_git_epoch} = $max if $max >= 0;
 174                 } else {
 175                         warn "opendir $gits failed: $!\n";
 176                 }
 177         }
 178         $cur;
 179 }
 180
 181 sub mm {
 182         my ($self) = @_;
 183         $self->{mm} ||= eval {
 184                 require PublicInbox::Msgmap;
 185                 _cleanup_later($self);
 186                 my $dir = $self->{inboxdir};
 187                 if ($self->version >= 2) {
 188                         PublicInbox::Msgmap->new_file("$dir/msgmap.sqlite3");
 189                 } else {
 190                         PublicInbox::Msgmap->new($dir);
 191                 }
 192         };
 193 }
 194
 195 sub search ($;$) {
 196         my ($self, $over_only) = @_;
 197         my $srch = $self->{search} ||= eval {
 198                 _cleanup_later($self);
 199                 require PublicInbox::Search;
 200                 PublicInbox::Search->new($self);
 201         };
 202         ($over_only || eval { $srch->xdb }) ? $srch : undef;
 203 }
 204
 205 sub over ($) {
 206         my ($self) = @_;
 207         my $srch = search($self, 1) or return;
 208         $self->{over} ||= eval {
 209                 my $over = $srch->{over_ro};
 210                 $over->dbh_new; # may fail
 211                 $over;
 212         }
 213 }
 214
 215 sub try_cat {
 216         my ($path) = @_;
 217         my $rv = '';
 218         if (open(my $fh, '<', $path)) {
 219                 local $/;
 220                 $rv = <$fh>;
 221         }
 222         $rv;
 223 }
 224
 225 sub description {
 226         my ($self) = @_;
 227         ($self->{description} //= do {
 228                 my $desc = try_cat("$self->{inboxdir}/description");
 229                 local $/ = "\n";
 230                 chomp $desc;
 231                 utf8::decode($desc);
 232                 $desc =~ s/\s+/ /smg;
 233                 $desc eq '' ? undef : $desc;
 234         }) // '($INBOX_DIR/description missing)';
 235 }
 236
 237 sub cloneurl {
 238         my ($self) = @_;
 239         ($self->{cloneurl} //= do {
 240                 my $s = try_cat("$self->{inboxdir}/cloneurl");
 241                 my @urls = split(/\s+/s, $s);
 242                 scalar(@urls) ? \@urls : undef
 243         }) // [];
 244 }
 245
 246 sub base_url {
 247         my ($self, $env) = @_; # env - PSGI env
 248         if ($env) {
 249                 my $url = PublicInbox::Git::host_prefix_url($env, '');
 250                 # for mount in Plack::Builder
 251                 $url .= '/' if $url !~ m!/\z!;
 252                 return $url .= $self->{name} . '/';
 253         }
 254         # called from a non-PSGI environment (e.g. NNTP/POP3):
 255         $self->{-base_url} ||= do {
 256                 my $url = $self->{url}->[0] or return undef;
 257                 # expand protocol-relative URLs to HTTPS if we're
 258                 # not inside a web server
 259                 $url = "https:$url" if $url =~ m!\A//!;
 260                 $url .= '/' if $url !~ m!/\z!;
 261                 $url;
 262         };
 263 }
 264
 265 sub nntp_url {
 266         my ($self) = @_;
 267         $self->{-nntp_url} ||= do {
 268                 # no checking for nntp_usable here, we can point entirely
 269                 # to non-local servers or users run by a different user
 270                 my $ns = $self->{nntpserver};
 271                 my $group = $self->{newsgroup};
 272                 my @urls;
 273                 if ($ns && $group) {
 274                         $ns = [ $ns ] if ref($ns) ne 'ARRAY';
 275                         @urls = map {
 276                                 my $u = m!\Anntps?://! ? $_ : "nntp://$_";
 277                                 $u .= '/' if $u !~ m!/\z!;
 278                                 $u.$group;
 279                         } @$ns;
 280                 }
 281
 282                 my $mirrors = $self->{nntpmirror};
 283                 if ($mirrors) {
 284                         my @m;
 285                         foreach (@$mirrors) {
 286                                 my $u = m!\Anntps?://! ? $_ : "nntp://$_";
 287                                 if ($u =~ m!\Anntps?://[^/]+/?\z!) {
 288                                         if ($group) {
 289                                                 $u .= '/' if $u !~ m!/\z!;
 290                                                 $u .= $group;
 291                                         } else {
 292                                                 warn
 293 "publicinbox.$self->{name}.nntpmirror=$_ missing newsgroup name\n";
 294                                         }
 295                                 }
 296                                 # else: allow full URLs like:
 297                                 # nntp://news.example.com/alt.example
 298                                 push @m, $u;
 299                         }
 300
 301                         # List::Util::uniq requires Perl 5.26+, maybe we
 302                         # can use it by 2030 or so
 303                         my %seen;
 304                         @urls = grep { !$seen{$_}++ } (@urls, @m);
 305                 }
 306                 \@urls;
 307         };
 308 }
 309
 310 sub nntp_usable {
 311         my ($self) = @_;
 312         my $ret = mm($self) && over($self);
 313         $self->{mm} = $self->{over} = $self->{search} = undef;
 314         $ret;
 315 }
 316
 317 # for v1 users w/o SQLite only
 318 sub msg_by_path ($$) {
 319         my ($self, $path) = @_;
 320         git($self)->cat_file('HEAD:'.$path);
 321 }
 322
 323 sub msg_by_smsg ($$) {
 324         my ($self, $smsg) = @_;
 325
 326         # ghosts may have undef smsg (from SearchThread.node) or
 327         # no {blob} field
 328         return unless defined $smsg;
 329         defined(my $blob = $smsg->{blob}) or return;
 330
 331         git($self)->cat_file($blob);
 332 }
 333
 334 sub smsg_eml {
 335         my ($self, $smsg) = @_;
 336         my $bref = msg_by_smsg($self, $smsg) or return;
 337         my $eml = PublicInbox::Eml->new($bref);
 338         $smsg->populate($eml) unless exists($smsg->{num}); # v1 w/o SQLite
 339         $eml;
 340 }
 341
 342 sub mid2num($$) {
 343         my ($self, $mid) = @_;
 344         my $mm = mm($self) or return;
 345         $mm->num_for($mid);
 346 }
 347
 348 sub smsg_by_mid ($$) {
 349         my ($self, $mid) = @_;
 350         my $over = over($self) or return;
 351         # favor the Message-ID we used for the NNTP article number:
 352         defined(my $num = mid2num($self, $mid)) or return;
 353         my $smsg = $over->get_art($num) or return;
 354         PublicInbox::Smsg::psgi_cull($smsg);
 355 }
 356
 357 sub msg_by_mid ($$) {
 358         my ($self, $mid) = @_;
 359
 360         over($self) or
 361                 return msg_by_path($self, mid2path($mid));
 362
 363         my $smsg = smsg_by_mid($self, $mid);
 364         $smsg ? msg_by_smsg($self, $smsg) : undef;
 365 }
 366
 367 sub recent {
 368         my ($self, $opts, $after, $before) = @_;
 369         over($self)->recent($opts, $after, $before);
 370 }
 371
 372 sub modified {
 373         my ($self) = @_;
 374         if (my $over = over($self)) {
 375                 my $msgs = $over->recent({limit => 1});
 376                 if (my $smsg = $msgs->[0]) {
 377                         return $smsg->{ts};
 378                 }
 379                 return time;
 380         }
 381         git($self)->modified; # v1
 382 }
 383
 384 # returns prefix => pathname mapping
 385 # (pathname is NOT public, but prefix is used for Xapian queries)
 386 sub altid_map ($) {
 387         my ($self) = @_;
 388         $self->{-altid_map} //= eval {
 389                 require PublicInbox::AltId;
 390                 my $altid = $self->{altid} or return {};
 391                 my %h = map {;
 392                         my $x = PublicInbox::AltId->new($self, $_);
 393                         "$x->{prefix}" => $x->{filename}
 394                 } @$altid;
 395                 \%h;
 396         } // {};
 397 }
 398
 399 # $obj must respond to ->on_inbox_unlock, which takes Inbox ($self) as an arg
 400 sub subscribe_unlock {
 401         my ($self, $ident, $obj) = @_;
 402         $self->{unlock_subs}->{$ident} = $obj;
 403 }
 404
 405 sub unsubscribe_unlock {
 406         my ($self, $ident) = @_;
 407         delete $self->{unlock_subs}->{$ident};
 408 }
 409
 410 # called by inotify
 411 sub on_unlock {
 412         my ($self) = @_;
 413         my $subs = $self->{unlock_subs} or return;
 414         for (values %$subs) {
 415                 eval { $_->on_inbox_unlock($self) };
 416         }
 417 }
 418
 419 1;