lib/PublicInbox/Inbox.pm

   1 # Copyright (C) 2016-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Represents a public-inbox (which may have multiple mailing addresses)
   5 package PublicInbox::Inbox;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::Git;
   9 use PublicInbox::MID qw(mid2path);
  10 use PublicInbox::MIME;
  11
  12 # Long-running "git-cat-file --batch" processes won't notice
  13 # unlinked packs, so we need to restart those processes occasionally.
  14 # Xapian and SQLite file handles are mostly stable, but sometimes an
  15 # admin will attempt to replace them atomically after compact/vacuum
  16 # and we need to be prepared for that.
  17 my $cleanup_timer;
  18 my $cleanup_avail = -1; # 0, or 1
  19 my $have_devel_peek;
  20 my $CLEANUP = {}; # string(inbox) -> inbox
  21 sub cleanup_task () {
  22         $cleanup_timer = undef;
  23         my $next = {};
  24         for my $ibx (values %$CLEANUP) {
  25                 my $again;
  26                 if ($have_devel_peek) {
  27                         foreach my $f (qw(mm search over)) {
  28                                 # we bump refcnt by assigning tmp, here:
  29                                 my $tmp = $ibx->{$f} or next;
  30                                 next if Devel::Peek::SvREFCNT($tmp) > 2;
  31                                 delete $ibx->{$f};
  32                                 # refcnt is zero when tmp is out-of-scope
  33                         }
  34                 }
  35                 if (my $git = $ibx->{git}) {
  36                         $again = $git->cleanup;
  37                 }
  38                 if (my $gits = $ibx->{-repo_objs}) {
  39                         foreach my $git (@$gits) {
  40                                 $again = 1 if $git->cleanup;
  41                         }
  42                 }
  43                 if ($have_devel_peek) {
  44                         $again ||= !!($ibx->{over} || $ibx->{mm} ||
  45                                       $ibx->{search});
  46                 }
  47                 $next->{"$ibx"} = $ibx if $again;
  48         }
  49         $CLEANUP = $next;
  50 }
  51
  52 sub cleanup_possible () {
  53         # no need to require EvCleanup, here, if it were enabled another
  54         # module would've require'd it, already
  55         eval { PublicInbox::EvCleanup::enabled() } or return 0;
  56
  57         eval {
  58                 require Devel::Peek; # needs separate package in Fedora
  59                 $have_devel_peek = 1;
  60         };
  61         1;
  62 }
  63
  64 sub _cleanup_later ($) {
  65         my ($self) = @_;
  66         $cleanup_avail = cleanup_possible() if $cleanup_avail < 0;
  67         return if $cleanup_avail != 1;
  68         $cleanup_timer ||= PublicInbox::EvCleanup::later(*cleanup_task);
  69         $CLEANUP->{"$self"} = $self;
  70 }
  71
  72 sub _set_uint ($$$) {
  73         my ($opts, $field, $default) = @_;
  74         my $val = $opts->{$field};
  75         if (defined $val) {
  76                 $val = $val->[-1] if ref($val) eq 'ARRAY';
  77                 $val = undef if $val !~ /\A[0-9]+\z/;
  78         }
  79         $opts->{$field} = $val || $default;
  80 }
  81
  82 sub _set_limiter ($$$) {
  83         my ($self, $pi_config, $pfx) = @_;
  84         my $lkey = "-${pfx}_limiter";
  85         $self->{$lkey} ||= eval {
  86                 # full key is: publicinbox.$NAME.httpbackendmax
  87                 my $mkey = $pfx.'max';
  88                 my $val = $self->{$mkey} or return;
  89                 my $lim;
  90                 if ($val =~ /\A[0-9]+\z/) {
  91                         require PublicInbox::Qspawn;
  92                         $lim = PublicInbox::Qspawn::Limiter->new($val);
  93                 } elsif ($val =~ /\A[a-z][a-z0-9]*\z/) {
  94                         $lim = $pi_config->limiter($val);
  95                         warn "$mkey limiter=$val not found\n" if !$lim;
  96                 } else {
  97                         warn "$mkey limiter=$val not understood\n";
  98                 }
  99                 $lim;
 100         }
 101 }
 102
 103 sub new {
 104         my ($class, $opts) = @_;
 105         my $v = $opts->{address} ||= 'public-inbox@example.com';
 106         my $p = $opts->{-primary_address} = ref($v) eq 'ARRAY' ? $v->[0] : $v;
 107         $opts->{domain} = ($p =~ /\@(\S+)\z/) ? $1 : 'localhost';
 108         my $pi_config = delete $opts->{-pi_config};
 109         _set_limiter($opts, $pi_config, 'httpbackend');
 110         _set_uint($opts, 'feedmax', 25);
 111         $opts->{nntpserver} ||= $pi_config->{'publicinbox.nntpserver'};
 112         my $dir = $opts->{mainrepo};
 113         if (defined $dir && -f "$dir/inbox.lock") {
 114                 $opts->{version} = 2;
 115         }
 116
 117         # allow any combination of multi-line or comma-delimited hide entries
 118         my $hide = {};
 119         if (defined(my $h = $opts->{hide})) {
 120                 foreach my $v (@$h) {
 121                         $hide->{$_} = 1 foreach (split(/\s*,\s*/, $v));
 122                 }
 123                 $opts->{-hide} = $hide;
 124         }
 125         bless $opts, $class;
 126 }
 127
 128 sub git_epoch {
 129         my ($self, $epoch) = @_;
 130         ($self->{version} || 1) == 2 or return;
 131         $self->{"$epoch.git"} ||= eval {
 132                 my $git_dir = "$self->{mainrepo}/git/$epoch.git";
 133                 my $g = PublicInbox::Git->new($git_dir);
 134                 $g->{-httpbackend_limiter} = $self->{-httpbackend_limiter};
 135                 # no cleanup needed, we never cat-file off this, only clone
 136                 $g;
 137         };
 138 }
 139
 140 sub git {
 141         my ($self) = @_;
 142         $self->{git} ||= eval {
 143                 my $git_dir = $self->{mainrepo};
 144                 $git_dir .= '/all.git' if (($self->{version} || 1) == 2);
 145                 my $g = PublicInbox::Git->new($git_dir);
 146                 $g->{-httpbackend_limiter} = $self->{-httpbackend_limiter};
 147                 _cleanup_later($self);
 148                 $g;
 149         };
 150 }
 151
 152 sub max_git_epoch {
 153         my ($self) = @_;
 154         my $v = $self->{version};
 155         return unless defined($v) && $v == 2;
 156         my $cur = $self->{-max_git_epoch};
 157         my $changed = git($self)->alternates_changed;
 158         if (!defined($cur) || $changed) {
 159                 $self->git->cleanup if $changed;
 160                 my $gits = "$self->{mainrepo}/git";
 161                 if (opendir my $dh, $gits) {
 162                         my $max = -1;
 163                         while (defined(my $git_dir = readdir($dh))) {
 164                                 $git_dir =~ m!\A([0-9]+)\.git\z! or next;
 165                                 $max = $1 if $1 > $max;
 166                         }
 167                         $cur = $self->{-max_git_epoch} = $max if $max >= 0;
 168                 } else {
 169                         warn "opendir $gits failed: $!\n";
 170                 }
 171         }
 172         $cur;
 173 }
 174
 175 sub mm {
 176         my ($self) = @_;
 177         $self->{mm} ||= eval {
 178                 require PublicInbox::Msgmap;
 179                 _cleanup_later($self);
 180                 my $dir = $self->{mainrepo};
 181                 if (($self->{version} || 1) >= 2) {
 182                         PublicInbox::Msgmap->new_file("$dir/msgmap.sqlite3");
 183                 } else {
 184                         PublicInbox::Msgmap->new($dir);
 185                 }
 186         };
 187 }
 188
 189 sub search ($;$) {
 190         my ($self, $over_only) = @_;
 191         my $srch = $self->{search} ||= eval {
 192                 _cleanup_later($self);
 193                 require PublicInbox::Search;
 194                 PublicInbox::Search->new($self);
 195         };
 196         ($over_only || eval { $srch->xdb }) ? $srch : undef;
 197 }
 198
 199 sub over ($) {
 200         my ($self) = @_;
 201         my $srch = search($self, 1) or return;
 202         $self->{over} ||= eval {
 203                 my $over = $srch->{over_ro};
 204                 $over->dbh_new; # may fail
 205                 $over;
 206         }
 207 }
 208
 209 sub try_cat {
 210         my ($path) = @_;
 211         my $rv = '';
 212         if (open(my $fh, '<', $path)) {
 213                 local $/;
 214                 $rv = <$fh>;
 215         }
 216         $rv;
 217 }
 218
 219 sub description {
 220         my ($self) = @_;
 221         my $desc = $self->{description};
 222         return $desc if defined $desc;
 223         $desc = try_cat("$self->{mainrepo}/description");
 224         local $/ = "\n";
 225         chomp $desc;
 226         $desc =~ s/\s+/ /smg;
 227         $desc = '($INBOX_DIR/description missing)' if $desc eq '';
 228         $self->{description} = $desc;
 229 }
 230
 231 sub cloneurl {
 232         my ($self) = @_;
 233         my $url = $self->{cloneurl};
 234         return $url if $url;
 235         $url = try_cat("$self->{mainrepo}/cloneurl");
 236         my @url = split(/\s+/s, $url);
 237         local $/ = "\n";
 238         chomp @url;
 239         $self->{cloneurl} = \@url;
 240 }
 241
 242 sub base_url {
 243         my ($self, $env) = @_;
 244         my $scheme;
 245         if ($env && ($scheme = $env->{'psgi.url_scheme'})) { # PSGI env
 246                 my $host_port = $env->{HTTP_HOST} ||
 247                         "$env->{SERVER_NAME}:$env->{SERVER_PORT}";
 248                 my $url = "$scheme://$host_port". ($env->{SCRIPT_NAME} || '/');
 249                 # for mount in Plack::Builder
 250                 $url .= '/' if $url !~ m!/\z!;
 251                 $url .= $self->{name} . '/';
 252         } else {
 253                 # either called from a non-PSGI environment (e.g. NNTP/POP3)
 254                 $self->{-base_url} ||= do {
 255                         my $url = $self->{url} or return undef;
 256                         # expand protocol-relative URLs to HTTPS if we're
 257                         # not inside a web server
 258                         $url = "https:$url" if $url =~ m!\A//!;
 259                         $url .= '/' if $url !~ m!/\z!;
 260                         $url;
 261                 };
 262         }
 263 }
 264
 265 sub nntp_url {
 266         my ($self) = @_;
 267         $self->{-nntp_url} ||= do {
 268                 # no checking for nntp_usable here, we can point entirely
 269                 # to non-local servers or users run by a different user
 270                 my $ns = $self->{nntpserver};
 271                 my $group = $self->{newsgroup};
 272                 my @urls;
 273                 if ($ns && $group) {
 274                         $ns = [ $ns ] if ref($ns) ne 'ARRAY';
 275                         @urls = map {
 276                                 my $u = m!\Anntps?://! ? $_ : "nntp://$_";
 277                                 $u .= '/' if $u !~ m!/\z!;
 278                                 $u.$group;
 279                         } @$ns;
 280                 }
 281
 282                 my $mirrors = $self->{nntpmirror};
 283                 if ($mirrors) {
 284                         my @m;
 285                         foreach (@$mirrors) {
 286                                 my $u = m!\Anntps?://! ? $_ : "nntp://$_";
 287                                 if ($u =~ m!\Anntps?://[^/]+/?\z!) {
 288                                         if ($group) {
 289                                                 $u .= '/' if $u !~ m!/\z!;
 290                                                 $u .= $group;
 291                                         } else {
 292                                                 warn
 293 "publicinbox.$self->{name}.nntpmirror=$_ missing newsgroup name\n";
 294                                         }
 295                                 }
 296                                 # else: allow full URLs like:
 297                                 # nntp://news.example.com/alt.example
 298                                 push @m, $u;
 299                         }
 300                         my %seen = map { $_ => 1 } @urls;
 301                         foreach my $u (@m) {
 302                                 next if $seen{$u};
 303                                 $seen{$u} = 1;
 304                                 push @urls, $u;
 305                         }
 306                 }
 307                 \@urls;
 308         };
 309 }
 310
 311 sub nntp_usable {
 312         my ($self) = @_;
 313         my $ret = mm($self) && over($self);
 314         $self->{mm} = $self->{over} = $self->{search} = undef;
 315         $ret;
 316 }
 317
 318 sub msg_by_path ($$;$) {
 319         my ($self, $path, $ref) = @_;
 320         # TODO: allow other refs:
 321         my $str = git($self)->cat_file('HEAD:'.$path, $ref);
 322         $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s if $str;
 323         $str;
 324 }
 325
 326 sub msg_by_smsg ($$;$) {
 327         my ($self, $smsg, $ref) = @_;
 328
 329         # ghosts may have undef smsg (from SearchThread.node) or
 330         # no {blob} field
 331         return unless defined $smsg;
 332         defined(my $blob = $smsg->{blob}) or return;
 333
 334         my $str = git($self)->cat_file($blob, $ref);
 335         $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s if $str;
 336         $str;
 337 }
 338
 339 sub smsg_mime {
 340         my ($self, $smsg, $ref) = @_;
 341         if (my $s = msg_by_smsg($self, $smsg, $ref)) {
 342                 $smsg->{mime} = PublicInbox::MIME->new($s);
 343                 return $smsg;
 344         }
 345 }
 346
 347 sub mid2num($$) {
 348         my ($self, $mid) = @_;
 349         my $mm = mm($self) or return;
 350         $mm->num_for($mid);
 351 }
 352
 353 sub smsg_by_mid ($$) {
 354         my ($self, $mid) = @_;
 355         my $over = over($self) or return;
 356         # favor the Message-ID we used for the NNTP article number:
 357         defined(my $num = mid2num($self, $mid)) or return;
 358         my $smsg = $over->get_art($num) or return;
 359         PublicInbox::SearchMsg::psgi_cull($smsg);
 360 }
 361
 362 sub msg_by_mid ($$;$) {
 363         my ($self, $mid, $ref) = @_;
 364
 365         over($self) or
 366                 return msg_by_path($self, mid2path($mid), $ref);
 367
 368         my $smsg = smsg_by_mid($self, $mid);
 369         $smsg ? msg_by_smsg($self, $smsg, $ref) : undef;
 370 }
 371
 372 sub recent {
 373         my ($self, $opts, $after, $before) = @_;
 374         over($self)->recent($opts, $after, $before);
 375 }
 376
 377 sub modified {
 378         my ($self) = @_;
 379         if (my $over = over($self)) {
 380                 my $msgs = $over->recent({limit => 1});
 381                 if (my $smsg = $msgs->[0]) {
 382                         return $smsg->{ts};
 383                 }
 384                 return time;
 385         }
 386         git($self)->modified; # v1
 387 }
 388
 389 1;