lib/PublicInbox/InboxIdle.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # fields:
   5 # pi_config: PublicInbox::Config ref
   6 # inot: Linux::Inotify2-like object
   7 # pathmap => { inboxdir => [ ibx, watch1, watch2, watch3... ] } mapping
   8 package PublicInbox::InboxIdle;
   9 use strict;
  10 use parent qw(PublicInbox::DS);
  11 use Cwd qw(abs_path);
  12 use PublicInbox::Syscall qw(EPOLLIN EPOLLET);
  13 my $IN_MODIFY = 0x02; # match Linux inotify
  14 my $ino_cls;
  15 if ($^O eq 'linux' && eval { require Linux::Inotify2; 1 }) {
  16         $IN_MODIFY = Linux::Inotify2::IN_MODIFY();
  17         $ino_cls = 'Linux::Inotify2';
  18 } elsif (eval { require PublicInbox::KQNotify }) {
  19         $IN_MODIFY = PublicInbox::KQNotify::NOTE_WRITE();
  20         $ino_cls = 'PublicInbox::KQNotify';
  21 }
  22 require PublicInbox::In2Tie if $ino_cls;
  23
  24 sub in2_arm ($$) { # PublicInbox::Config::each_inbox callback
  25         my ($ibx, $self) = @_;
  26         my $dir = abs_path($ibx->{inboxdir});
  27         if (!defined($dir)) {
  28                 warn "W: $ibx->{inboxdir} not watched: $!\n";
  29                 return;
  30         }
  31         my $inot = $self->{inot};
  32         my $cur = $self->{pathmap}->{$dir} //= [];
  33
  34         # transfer old subscriptions to the current inbox, cancel the old watch
  35         if (my $old_ibx = $cur->[0]) {
  36                 $ibx->{unlock_subs} and
  37                         die "BUG: $dir->{unlock_subs} should not exist";
  38                 $ibx->{unlock_subs} = $old_ibx->{unlock_subs};
  39                 $cur->[1]->cancel; # Linux::Inotify2::Watch::cancel
  40         }
  41         $cur->[0] = $ibx;
  42
  43         my $lock = "$dir/".($ibx->version >= 2 ? 'inbox.lock' : 'ssoma.lock');
  44         if (my $w = $cur->[1] = $inot->watch($lock, $IN_MODIFY)) {
  45                 $self->{on_unlock}->{$w->name} = $ibx;
  46         } else {
  47                 warn "E: ".ref($inot)."->watch($lock, IN_MODIFY) failed: $!\n";
  48                 if ($!{ENOSPC} && $^O eq 'linux') {
  49                         warn <<"";
  50 I: consider increasing /proc/sys/fs/inotify/max_user_watches
  51
  52                 }
  53         }
  54
  55         # TODO: detect deleted packs (and possibly other files)
  56 }
  57
  58 sub refresh {
  59         my ($self, $pi_config) = @_;
  60         $pi_config->each_inbox(\&in2_arm, $self);
  61 }
  62
  63 sub new {
  64         my ($class, $pi_config) = @_;
  65         my $self = bless {}, $class;
  66         my $inot;
  67         if ($ino_cls) {
  68                 $inot = $ino_cls->new or die "E: $ino_cls->new: $!";
  69                 my $io = PublicInbox::In2Tie::io($inot);
  70                 $self->SUPER::new($io, EPOLLIN | EPOLLET);
  71         } else {
  72                 require PublicInbox::FakeInotify;
  73                 $inot = PublicInbox::FakeInotify->new;
  74         }
  75         $self->{inot} = $inot;
  76         $self->{pathmap} = {}; # inboxdir => [ ibx, watch1, watch2, watch3...]
  77         $self->{on_unlock} = {}; # lock path => ibx
  78         refresh($self, $pi_config);
  79         PublicInbox::FakeInotify::poll_once($self) if !$ino_cls;
  80         $self;
  81 }
  82
  83 sub event_step {
  84         my ($self) = @_;
  85         eval {
  86                 my @events = $self->{inot}->read; # Linux::Inotify2::read
  87                 my $on_unlock = $self->{on_unlock};
  88                 for my $ev (@events) {
  89                         if (my $ibx = $on_unlock->{$ev->fullname}) {
  90                                 $ibx->on_unlock;
  91                         }
  92                 }
  93         };
  94         warn "{inot}->read err: $@\n" if $@;
  95 }
  96
  97 # for graceful shutdown in PublicInbox::Daemon,
  98 # just ensure the FD gets closed ASAP and subscribers
  99 sub busy { 0 }
 100
 101 1;