lib/PublicInbox/InboxWritable.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Extends read-only Inbox for writing
   5 package PublicInbox::InboxWritable;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::Inbox);
   9 use PublicInbox::Import;
  10 use PublicInbox::Filter::Base qw(REJECT);
  11
  12 use constant {
  13         PERM_UMASK => 0,
  14         OLD_PERM_GROUP => 1,
  15         OLD_PERM_EVERYBODY => 2,
  16         PERM_GROUP => 0660,
  17         PERM_EVERYBODY => 0664,
  18 };
  19
  20 sub new {
  21         my ($class, $ibx, $creat_opt) = @_;
  22         return $ibx if ref($ibx) eq $class;
  23         my $self = bless $ibx, $class;
  24
  25         # TODO: maybe stop supporting this
  26         if ($creat_opt) { # for { nproc => $N }
  27                 $self->{-creat_opt} = $creat_opt;
  28                 init_inbox($self) if $self->version == 1;
  29         }
  30         $self;
  31 }
  32
  33 sub assert_usable_dir {
  34         my ($self) = @_;
  35         my $dir = $self->{inboxdir};
  36         return $dir if defined($dir) && $dir ne '';
  37         die "no inboxdir defined for $self->{name}\n";
  38 }
  39
  40 sub _init_v1 {
  41         my ($self, $skip_artnum) = @_;
  42         if (defined($self->{indexlevel}) || defined($skip_artnum)) {
  43                 require PublicInbox::SearchIdx;
  44                 require PublicInbox::Msgmap;
  45                 my $sidx = PublicInbox::SearchIdx->new($self, 1); # just create
  46                 $sidx->begin_txn_lazy;
  47                 if (defined $skip_artnum) {
  48                         my $mm = PublicInbox::Msgmap->new($self->{inboxdir}, 1);
  49                         $mm->{dbh}->begin_work;
  50                         $mm->skip_artnum($skip_artnum);
  51                         $mm->{dbh}->commit;
  52                 }
  53                 $sidx->commit_txn_lazy;
  54         } else {
  55                 open my $fh, '>>', "$self->{inboxdir}/ssoma.lock" or
  56                         die "$self->{inboxdir}/ssoma.lock: $!\n";
  57         }
  58 }
  59
  60 sub init_inbox {
  61         my ($self, $shards, $skip_epoch, $skip_artnum) = @_;
  62         if ($self->version == 1) {
  63                 my $dir = assert_usable_dir($self);
  64                 PublicInbox::Import::init_bare($dir);
  65                 $self->umask_prepare;
  66                 $self->with_umask(\&_init_v1, $self, $skip_artnum);
  67         } else {
  68                 my $v2w = importer($self);
  69                 $v2w->init_inbox($shards, $skip_epoch, $skip_artnum);
  70         }
  71 }
  72
  73 sub importer {
  74         my ($self, $parallel) = @_;
  75         my $v = $self->version;
  76         if ($v == 2) {
  77                 eval { require PublicInbox::V2Writable };
  78                 die "v2 not supported: $@\n" if $@;
  79                 my $opt = $self->{-creat_opt};
  80                 my $v2w = PublicInbox::V2Writable->new($self, $opt);
  81                 $v2w->{parallel} = $parallel if defined $parallel;
  82                 $v2w;
  83         } elsif ($v == 1) {
  84                 my @arg = (undef, undef, undef, $self);
  85                 PublicInbox::Import->new(@arg);
  86         } else {
  87                 $! = 78; # EX_CONFIG 5.3.5 local configuration error
  88                 die "unsupported inbox version: $v\n";
  89         }
  90 }
  91
  92 sub filter {
  93         my ($self, $im) = @_;
  94         my $f = $self->{filter};
  95         if ($f && $f =~ /::/) {
  96                 # v2 keeps msgmap open, which causes conflicts for filters
  97                 # such as PublicInbox::Filter::RubyLang which overload msgmap
  98                 # for a predictable serial number.
  99                 if ($im && $self->version >= 2 && $self->{altid}) {
 100                         $im->done;
 101                 }
 102
 103                 my @args = (-inbox => $self);
 104                 # basic line splitting, only
 105                 # Perhaps we can have proper quote splitting one day...
 106                 ($f, @args) = split(/\s+/, $f) if $f =~ /\s+/;
 107
 108                 eval "require $f";
 109                 if ($@) {
 110                         warn $@;
 111                 } else {
 112                         # e.g: PublicInbox::Filter::Vger->new(@args)
 113                         return $f->new(@args);
 114                 }
 115         }
 116         undef;
 117 }
 118
 119 sub is_maildir_basename ($) {
 120         my ($bn) = @_;
 121         return 0 if $bn !~ /\A[a-zA-Z0-9][\-\w:,=\.]+\z/;
 122         if ($bn =~ /:2,([A-Z]+)\z/i) {
 123                 my $flags = $1;
 124                 return 0 if $flags =~ /[DT]/; # no [D]rafts or [T]rashed mail
 125         }
 126         1;
 127 }
 128
 129 sub is_maildir_path ($) {
 130         my ($path) = @_;
 131         my @p = split(m!/+!, $path);
 132         (is_maildir_basename($p[-1]) && -f $path) ? 1 : 0;
 133 }
 134
 135 sub mime_from_path ($) {
 136         my ($path) = @_;
 137         if (open my $fh, '<', $path) {
 138                 local $/;
 139                 my $str = <$fh>;
 140                 $str or return;
 141                 return PublicInbox::Eml->new(\$str);
 142         } elsif ($!{ENOENT}) {
 143                 # common with Maildir
 144                 return;
 145         } else {
 146                 warn "failed to open $path: $!\n";
 147                 return;
 148         }
 149 }
 150
 151 sub import_maildir {
 152         my ($self, $dir) = @_;
 153         my $im = $self->importer(1);
 154
 155         foreach my $sub (qw(cur new tmp)) {
 156                 -d "$dir/$sub" or die "$dir is not a Maildir (missing $sub)\n";
 157         }
 158         foreach my $sub (qw(cur new)) {
 159                 opendir my $dh, "$dir/$sub" or die "opendir $dir/$sub: $!\n";
 160                 while (defined(my $fn = readdir($dh))) {
 161                         next unless is_maildir_basename($fn);
 162                         my $mime = mime_from_path("$dir/$fn") or next;
 163
 164                         if (my $filter = $self->filter($im)) {
 165                                 my $ret = $filter->scrub($mime) or return;
 166                                 return if $ret == REJECT();
 167                                 $mime = $ret;
 168                         }
 169                         $im->add($mime);
 170                 }
 171         }
 172         $im->done;
 173 }
 174
 175 # asctime: From example@example.com Fri Jun 23 02:56:55 2000
 176 my $from_strict = qr/^From \S+ +\S+ \S+ +\S+ [^:]+:[^:]+:[^:]+ [^:]+/;
 177
 178 sub mb_add ($$$$) {
 179         my ($im, $variant, $filter, $msg) = @_;
 180         $$msg =~ s/(\r?\n)+\z/$1/s;
 181         if ($variant eq 'mboxrd') {
 182                 $$msg =~ s/^>(>*From )/$1/gms;
 183         } elsif ($variant eq 'mboxo') {
 184                 $$msg =~ s/^>From /From /gms;
 185         }
 186         my $mime = PublicInbox::Eml->new($msg);
 187         if ($filter) {
 188                 my $ret = $filter->scrub($mime) or return;
 189                 return if $ret == REJECT();
 190                 $mime = $ret;
 191         }
 192         $im->add($mime)
 193 }
 194
 195 sub import_mbox {
 196         my ($self, $fh, $variant) = @_;
 197         if ($variant !~ /\A(?:mboxrd|mboxo)\z/) {
 198                 die "variant must be 'mboxrd' or 'mboxo'\n";
 199         }
 200         my $im = $self->importer(1);
 201         my $prev = undef;
 202         my $msg = '';
 203         my $filter = $self->filter;
 204         while (defined(my $l = <$fh>)) {
 205                 if ($l =~ /$from_strict/o) {
 206                         if (!defined($prev) || $prev =~ /^\r?$/) {
 207                                 mb_add($im, $variant, $filter, \$msg) if $msg;
 208                                 $msg = '';
 209                                 $prev = $l;
 210                                 next;
 211                         }
 212                         warn "W[$.] $l\n";
 213                 }
 214                 $prev = $l;
 215                 $msg .= $l;
 216         }
 217         mb_add($im, $variant, $filter, \$msg) if $msg;
 218         $im->done;
 219 }
 220
 221 sub _read_git_config_perm {
 222         my ($self) = @_;
 223         chomp(my $perm = $self->git->qx('config', 'core.sharedRepository'));
 224         $perm;
 225 }
 226
 227 sub _git_config_perm {
 228         my $self = shift;
 229         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 230         return PERM_UMASK if (!defined($perm) || $perm eq '');
 231         return PERM_UMASK if ($perm eq 'umask');
 232         return PERM_GROUP if ($perm eq 'group');
 233         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 234                 return PERM_EVERYBODY;
 235         }
 236         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 237         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 238
 239         my $i = oct($perm);
 240         return PERM_UMASK if ($i == PERM_UMASK);
 241         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 242         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 243
 244         if (($i & 0600) != 0600) {
 245                 die "core.sharedRepository mode invalid: ".
 246                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 247         }
 248         ($i & 0666);
 249 }
 250
 251 sub _umask_for {
 252         my ($perm) = @_; # _git_config_perm return value
 253         my $rv = $perm;
 254         return umask if $rv == 0;
 255
 256         # set +x bit if +r or +w were set
 257         $rv |= 0100 if ($rv & 0600);
 258         $rv |= 0010 if ($rv & 0060);
 259         $rv |= 0001 if ($rv & 0006);
 260         (~$rv & 0777);
 261 }
 262
 263 sub with_umask {
 264         my ($self, $cb, @arg) = @_;
 265         my $old = umask $self->{umask};
 266         my $rv = eval { $cb->(@arg) };
 267         my $err = $@;
 268         umask $old;
 269         die $err if $err;
 270         $rv;
 271 }
 272
 273 sub umask_prepare {
 274         my ($self) = @_;
 275         my $perm = _git_config_perm($self);
 276         my $umask = _umask_for($perm);
 277         $self->{umask} = $umask;
 278 }
 279
 280 sub cleanup ($) {
 281         delete @{$_[0]}{qw(over mm git search)};
 282 }
 283
 284 1;