lib/PublicInbox/InboxWritable.pm

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Extends read-only Inbox for writing
   5 package PublicInbox::InboxWritable;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::Inbox);
   9 use PublicInbox::Import;
  10 use PublicInbox::Filter::Base;
  11 *REJECT = *PublicInbox::Filter::Base::REJECT;
  12
  13 use constant {
  14         PERM_UMASK => 0,
  15         OLD_PERM_GROUP => 1,
  16         OLD_PERM_EVERYBODY => 2,
  17         PERM_GROUP => 0660,
  18         PERM_EVERYBODY => 0664,
  19 };
  20
  21 sub new {
  22         my ($class, $ibx) = @_;
  23         bless $ibx, $class;
  24 }
  25
  26 sub importer {
  27         my ($self, $parallel) = @_;
  28         $self->{-importer} ||= eval {
  29                 my $v = $self->{version} || 1;
  30                 if ($v == 2) {
  31                         eval { require PublicInbox::V2Writable };
  32                         die "v2 not supported: $@\n" if $@;
  33                         my $v2w = PublicInbox::V2Writable->new($self);
  34                         $v2w->{parallel} = $parallel;
  35                         $v2w;
  36                 } elsif ($v == 1) {
  37                         my $git = $self->git;
  38                         my $name = $self->{name};
  39                         my $addr = $self->{-primary_address};
  40                         PublicInbox::Import->new($git, $name, $addr, $self);
  41                 } else {
  42                         $! = 78; # EX_CONFIG 5.3.5 local configuration error
  43                         die "unsupported inbox version: $v\n";
  44                 }
  45         }
  46 }
  47
  48 sub filter {
  49         my ($self, $im) = @_;
  50         my $f = $self->{filter};
  51         if ($f && $f =~ /::/) {
  52                 # v2 keeps msgmap open, which causes conflicts for filters
  53                 # such as PublicInbox::Filter::RubyLang which overload msgmap
  54                 # for a predictable serial number.
  55                 if ($im && ($self->{version} || 1) >= 2 && $self->{altid}) {
  56                         $im->done;
  57                 }
  58
  59                 my @args = (-inbox => $self);
  60                 # basic line splitting, only
  61                 # Perhaps we can have proper quote splitting one day...
  62                 ($f, @args) = split(/\s+/, $f) if $f =~ /\s+/;
  63
  64                 eval "require $f";
  65                 if ($@) {
  66                         warn $@;
  67                 } else {
  68                         # e.g: PublicInbox::Filter::Vger->new(@args)
  69                         return $f->new(@args);
  70                 }
  71         }
  72         undef;
  73 }
  74
  75 sub is_maildir_basename ($) {
  76         my ($bn) = @_;
  77         return 0 if $bn !~ /\A[a-zA-Z0-9][\-\w:,=\.]+\z/;
  78         if ($bn =~ /:2,([A-Z]+)\z/i) {
  79                 my $flags = $1;
  80                 return 0 if $flags =~ /[DT]/; # no [D]rafts or [T]rashed mail
  81         }
  82         1;
  83 }
  84
  85 sub is_maildir_path ($) {
  86         my ($path) = @_;
  87         my @p = split(m!/+!, $path);
  88         (is_maildir_basename($p[-1]) && -f $path) ? 1 : 0;
  89 }
  90
  91 sub maildir_path_load ($) {
  92         my ($path) = @_;
  93         if (open my $fh, '<', $path) {
  94                 local $/;
  95                 my $str = <$fh>;
  96                 $str or return;
  97                 return PublicInbox::MIME->new(\$str);
  98         } elsif ($!{ENOENT}) {
  99                 # common with Maildir
 100                 return;
 101         } else {
 102                 warn "failed to open $path: $!\n";
 103                 return;
 104         }
 105 }
 106
 107 sub import_maildir {
 108         my ($self, $dir) = @_;
 109         my $im = $self->importer(1);
 110
 111         foreach my $sub (qw(cur new tmp)) {
 112                 -d "$dir/$sub" or die "$dir is not a Maildir (missing $sub)\n";
 113         }
 114         foreach my $sub (qw(cur new)) {
 115                 opendir my $dh, "$dir/$sub" or die "opendir $dir/$sub: $!\n";
 116                 while (defined(my $fn = readdir($dh))) {
 117                         next unless is_maildir_basename($fn);
 118                         my $mime = maildir_file_load("$dir/$fn") or next;
 119
 120                         if (my $filter = $self->filter($im)) {
 121                                 my $ret = $filter->scrub($mime) or return;
 122                                 return if $ret == REJECT();
 123                                 $mime = $ret;
 124                         }
 125                         $im->add($mime);
 126                 }
 127         }
 128         $im->done;
 129 }
 130
 131 # asctime: From example@example.com Fri Jun 23 02:56:55 2000
 132 my $from_strict = qr/^From \S+ +\S+ \S+ +\S+ [^:]+:[^:]+:[^:]+ [^:]+/;
 133
 134 sub mb_add ($$$$) {
 135         my ($im, $variant, $filter, $msg) = @_;
 136         $$msg =~ s/(\r?\n)+\z/$1/s;
 137         my $mime = PublicInbox::MIME->new($msg);
 138         if ($variant eq 'mboxrd') {
 139                 $$msg =~ s/^>(>*From )/$1/sm;
 140         } elsif ($variant eq 'mboxo') {
 141                 $$msg =~ s/^>From /From /sm;
 142         }
 143         if ($filter) {
 144                 my $ret = $filter->scrub($mime) or return;
 145                 return if $ret == REJECT();
 146                 $mime = $ret;
 147         }
 148         $im->add($mime)
 149 }
 150
 151 sub import_mbox {
 152         my ($self, $fh, $variant) = @_;
 153         if ($variant !~ /\A(?:mboxrd|mboxo)\z/) {
 154                 die "variant must be 'mboxrd' or 'mboxo'\n";
 155         }
 156         my $im = $self->importer(1);
 157         my $prev = undef;
 158         my $msg = '';
 159         my $filter = $self->filter;
 160         while (defined(my $l = <$fh>)) {
 161                 if ($l =~ /$from_strict/o) {
 162                         if (!defined($prev) || $prev =~ /^\r?$/) {
 163                                 mb_add($im, $variant, $filter, \$msg) if $msg;
 164                                 $msg = '';
 165                                 $prev = $l;
 166                                 next;
 167                         }
 168                         warn "W[$.] $l\n";
 169                 }
 170                 $prev = $l;
 171                 $msg .= $l;
 172         }
 173         mb_add($im, $variant, $filter, \$msg) if $msg;
 174         $im->done;
 175 }
 176
 177 sub _read_git_config_perm {
 178         my ($self) = @_;
 179         chomp(my $perm = $self->git->qx('config', 'core.sharedRepository'));
 180         $perm;
 181 }
 182
 183 sub _git_config_perm {
 184         my $self = shift;
 185         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 186         return PERM_UMASK if (!defined($perm) || $perm eq '');
 187         return PERM_UMASK if ($perm eq 'umask');
 188         return PERM_GROUP if ($perm eq 'group');
 189         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 190                 return PERM_EVERYBODY;
 191         }
 192         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 193         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 194
 195         my $i = oct($perm);
 196         return PERM_UMASK if ($i == PERM_UMASK);
 197         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 198         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 199
 200         if (($i & 0600) != 0600) {
 201                 die "core.sharedRepository mode invalid: ".
 202                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 203         }
 204         ($i & 0666);
 205 }
 206
 207 sub _umask_for {
 208         my ($perm) = @_; # _git_config_perm return value
 209         my $rv = $perm;
 210         return umask if $rv == 0;
 211
 212         # set +x bit if +r or +w were set
 213         $rv |= 0100 if ($rv & 0600);
 214         $rv |= 0010 if ($rv & 0060);
 215         $rv |= 0001 if ($rv & 0006);
 216         (~$rv & 0777);
 217 }
 218
 219 sub with_umask {
 220         my ($self, $cb) = @_;
 221         my $old = umask $self->{umask};
 222         my $rv = eval { $cb->() };
 223         my $err = $@;
 224         umask $old;
 225         die $err if $err;
 226         $rv;
 227 }
 228
 229 sub umask_prepare {
 230         my ($self) = @_;
 231         my $perm = _git_config_perm($self);
 232         my $umask = _umask_for($perm);
 233         $self->{umask} = $umask;
 234 }
 235
 236 1;