lib/PublicInbox/InboxWritable.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Extends read-only Inbox for writing
   5 package PublicInbox::InboxWritable;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::Inbox);
   9 use PublicInbox::Import;
  10 use PublicInbox::Filter::Base qw(REJECT);
  11
  12 use constant {
  13         PERM_UMASK => 0,
  14         OLD_PERM_GROUP => 1,
  15         OLD_PERM_EVERYBODY => 2,
  16         PERM_GROUP => 0660,
  17         PERM_EVERYBODY => 0664,
  18 };
  19
  20 sub new {
  21         my ($class, $ibx, $creat_opt) = @_;
  22         return $ibx if ref($ibx) eq $class;
  23         my $self = bless $ibx, $class;
  24
  25         # TODO: maybe stop supporting this
  26         if ($creat_opt) { # for { nproc => $N }
  27                 $self->{-creat_opt} = $creat_opt;
  28                 init_inbox($self) if $self->version == 1;
  29         }
  30         $self;
  31 }
  32
  33 sub assert_usable_dir {
  34         my ($self) = @_;
  35         my $dir = $self->{inboxdir};
  36         return $dir if defined($dir) && $dir ne '';
  37         die "no inboxdir defined for $self->{name}\n";
  38 }
  39
  40 sub init_inbox {
  41         my ($self, $shards, $skip_epoch, $skip_artnum) = @_;
  42         if ($self->version == 1) {
  43                 my $dir = assert_usable_dir($self);
  44                 PublicInbox::Import::init_bare($dir);
  45                 if (defined($self->{indexlevel}) || defined($skip_artnum)) {
  46                         require PublicInbox::SearchIdx;
  47                         require PublicInbox::Msgmap;
  48                         my $sidx = PublicInbox::SearchIdx->new($self, 1); # just create
  49                         $sidx->begin_txn_lazy;
  50                         $self->with_umask(sub {
  51                                 my $mm = PublicInbox::Msgmap->new($dir, 1);
  52                                 $mm->{dbh}->begin_work;
  53                                 $mm->skip_artnum($skip_artnum);
  54                                 $mm->{dbh}->commit;
  55                         }) if defined($skip_artnum);
  56                         $sidx->commit_txn_lazy;
  57                 } else {
  58                         open my $fh, '>>', "$dir/ssoma.lock" or
  59                                 die "$dir/ssoma.lock: $!\n";
  60                 }
  61         } else {
  62                 my $v2w = importer($self);
  63                 $v2w->init_inbox($shards, $skip_epoch, $skip_artnum);
  64         }
  65 }
  66
  67 sub importer {
  68         my ($self, $parallel) = @_;
  69         my $v = $self->version;
  70         if ($v == 2) {
  71                 eval { require PublicInbox::V2Writable };
  72                 die "v2 not supported: $@\n" if $@;
  73                 my $opt = $self->{-creat_opt};
  74                 my $v2w = PublicInbox::V2Writable->new($self, $opt);
  75                 $v2w->{parallel} = $parallel if defined $parallel;
  76                 $v2w;
  77         } elsif ($v == 1) {
  78                 my @arg = (undef, undef, undef, $self);
  79                 PublicInbox::Import->new(@arg);
  80         } else {
  81                 $! = 78; # EX_CONFIG 5.3.5 local configuration error
  82                 die "unsupported inbox version: $v\n";
  83         }
  84 }
  85
  86 sub filter {
  87         my ($self, $im) = @_;
  88         my $f = $self->{filter};
  89         if ($f && $f =~ /::/) {
  90                 # v2 keeps msgmap open, which causes conflicts for filters
  91                 # such as PublicInbox::Filter::RubyLang which overload msgmap
  92                 # for a predictable serial number.
  93                 if ($im && $self->version >= 2 && $self->{altid}) {
  94                         $im->done;
  95                 }
  96
  97                 my @args = (-inbox => $self);
  98                 # basic line splitting, only
  99                 # Perhaps we can have proper quote splitting one day...
 100                 ($f, @args) = split(/\s+/, $f) if $f =~ /\s+/;
 101
 102                 eval "require $f";
 103                 if ($@) {
 104                         warn $@;
 105                 } else {
 106                         # e.g: PublicInbox::Filter::Vger->new(@args)
 107                         return $f->new(@args);
 108                 }
 109         }
 110         undef;
 111 }
 112
 113 sub is_maildir_basename ($) {
 114         my ($bn) = @_;
 115         return 0 if $bn !~ /\A[a-zA-Z0-9][\-\w:,=\.]+\z/;
 116         if ($bn =~ /:2,([A-Z]+)\z/i) {
 117                 my $flags = $1;
 118                 return 0 if $flags =~ /[DT]/; # no [D]rafts or [T]rashed mail
 119         }
 120         1;
 121 }
 122
 123 sub is_maildir_path ($) {
 124         my ($path) = @_;
 125         my @p = split(m!/+!, $path);
 126         (is_maildir_basename($p[-1]) && -f $path) ? 1 : 0;
 127 }
 128
 129 sub mime_from_path ($) {
 130         my ($path) = @_;
 131         if (open my $fh, '<', $path) {
 132                 local $/;
 133                 my $str = <$fh>;
 134                 $str or return;
 135                 return PublicInbox::Eml->new(\$str);
 136         } elsif ($!{ENOENT}) {
 137                 # common with Maildir
 138                 return;
 139         } else {
 140                 warn "failed to open $path: $!\n";
 141                 return;
 142         }
 143 }
 144
 145 sub import_maildir {
 146         my ($self, $dir) = @_;
 147         my $im = $self->importer(1);
 148
 149         foreach my $sub (qw(cur new tmp)) {
 150                 -d "$dir/$sub" or die "$dir is not a Maildir (missing $sub)\n";
 151         }
 152         foreach my $sub (qw(cur new)) {
 153                 opendir my $dh, "$dir/$sub" or die "opendir $dir/$sub: $!\n";
 154                 while (defined(my $fn = readdir($dh))) {
 155                         next unless is_maildir_basename($fn);
 156                         my $mime = mime_from_path("$dir/$fn") or next;
 157
 158                         if (my $filter = $self->filter($im)) {
 159                                 my $ret = $filter->scrub($mime) or return;
 160                                 return if $ret == REJECT();
 161                                 $mime = $ret;
 162                         }
 163                         $im->add($mime);
 164                 }
 165         }
 166         $im->done;
 167 }
 168
 169 # asctime: From example@example.com Fri Jun 23 02:56:55 2000
 170 my $from_strict = qr/^From \S+ +\S+ \S+ +\S+ [^:]+:[^:]+:[^:]+ [^:]+/;
 171
 172 sub mb_add ($$$$) {
 173         my ($im, $variant, $filter, $msg) = @_;
 174         $$msg =~ s/(\r?\n)+\z/$1/s;
 175         if ($variant eq 'mboxrd') {
 176                 $$msg =~ s/^>(>*From )/$1/gms;
 177         } elsif ($variant eq 'mboxo') {
 178                 $$msg =~ s/^>From /From /gms;
 179         }
 180         my $mime = PublicInbox::Eml->new($msg);
 181         if ($filter) {
 182                 my $ret = $filter->scrub($mime) or return;
 183                 return if $ret == REJECT();
 184                 $mime = $ret;
 185         }
 186         $im->add($mime)
 187 }
 188
 189 sub import_mbox {
 190         my ($self, $fh, $variant) = @_;
 191         if ($variant !~ /\A(?:mboxrd|mboxo)\z/) {
 192                 die "variant must be 'mboxrd' or 'mboxo'\n";
 193         }
 194         my $im = $self->importer(1);
 195         my $prev = undef;
 196         my $msg = '';
 197         my $filter = $self->filter;
 198         while (defined(my $l = <$fh>)) {
 199                 if ($l =~ /$from_strict/o) {
 200                         if (!defined($prev) || $prev =~ /^\r?$/) {
 201                                 mb_add($im, $variant, $filter, \$msg) if $msg;
 202                                 $msg = '';
 203                                 $prev = $l;
 204                                 next;
 205                         }
 206                         warn "W[$.] $l\n";
 207                 }
 208                 $prev = $l;
 209                 $msg .= $l;
 210         }
 211         mb_add($im, $variant, $filter, \$msg) if $msg;
 212         $im->done;
 213 }
 214
 215 sub _read_git_config_perm {
 216         my ($self) = @_;
 217         chomp(my $perm = $self->git->qx('config', 'core.sharedRepository'));
 218         $perm;
 219 }
 220
 221 sub _git_config_perm {
 222         my $self = shift;
 223         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 224         return PERM_UMASK if (!defined($perm) || $perm eq '');
 225         return PERM_UMASK if ($perm eq 'umask');
 226         return PERM_GROUP if ($perm eq 'group');
 227         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 228                 return PERM_EVERYBODY;
 229         }
 230         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 231         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 232
 233         my $i = oct($perm);
 234         return PERM_UMASK if ($i == PERM_UMASK);
 235         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 236         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 237
 238         if (($i & 0600) != 0600) {
 239                 die "core.sharedRepository mode invalid: ".
 240                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 241         }
 242         ($i & 0666);
 243 }
 244
 245 sub _umask_for {
 246         my ($perm) = @_; # _git_config_perm return value
 247         my $rv = $perm;
 248         return umask if $rv == 0;
 249
 250         # set +x bit if +r or +w were set
 251         $rv |= 0100 if ($rv & 0600);
 252         $rv |= 0010 if ($rv & 0060);
 253         $rv |= 0001 if ($rv & 0006);
 254         (~$rv & 0777);
 255 }
 256
 257 sub with_umask {
 258         my ($self, $cb) = @_;
 259         my $old = umask $self->{umask};
 260         my $rv = eval { $cb->() };
 261         my $err = $@;
 262         umask $old;
 263         die $err if $err;
 264         $rv;
 265 }
 266
 267 sub umask_prepare {
 268         my ($self) = @_;
 269         my $perm = _git_config_perm($self);
 270         my $umask = _umask_for($perm);
 271         $self->{umask} = $umask;
 272 }
 273
 274 sub cleanup ($) {
 275         delete @{$_[0]}{qw(over mm git search)};
 276 }
 277
 278 1;