lib/PublicInbox/InboxWritable.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Extends read-only Inbox for writing
   5 package PublicInbox::InboxWritable;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::Inbox);
   9 use PublicInbox::Import;
  10 use PublicInbox::Filter::Base qw(REJECT);
  11
  12 use constant {
  13         PERM_UMASK => 0,
  14         OLD_PERM_GROUP => 1,
  15         OLD_PERM_EVERYBODY => 2,
  16         PERM_GROUP => 0660,
  17         PERM_EVERYBODY => 0664,
  18 };
  19
  20 sub new {
  21         my ($class, $ibx, $creat_opt) = @_;
  22         return $ibx if ref($ibx) eq $class;
  23         my $self = bless $ibx, $class;
  24
  25         # TODO: maybe stop supporting this
  26         if ($creat_opt) { # for { nproc => $N }
  27                 $self->{-creat_opt} = $creat_opt;
  28                 init_inbox($self) if $self->version == 1;
  29         }
  30         $self;
  31 }
  32
  33 sub assert_usable_dir {
  34         my ($self) = @_;
  35         my $dir = $self->{inboxdir};
  36         return $dir if defined($dir) && $dir ne '';
  37         die "no inboxdir defined for $self->{name}\n";
  38 }
  39
  40 sub init_inbox {
  41         my ($self, $shards, $skip_epoch, $skip_artnum) = @_;
  42         if ($self->version == 1) {
  43                 my $dir = assert_usable_dir($self);
  44                 PublicInbox::Import::init_bare($dir);
  45                 if (defined($self->{indexlevel}) || defined($skip_artnum)) {
  46                         require PublicInbox::SearchIdx;
  47                         my $sidx = PublicInbox::SearchIdx->new($self, 1); # just create
  48                         $sidx->begin_txn_lazy;
  49                         $self->with_umask(sub {
  50                                 my $mm = PublicInbox::Msgmap->new($dir, 1);
  51                                 $mm->{dbh}->begin_work;
  52                                 $mm->skip_artnum($skip_artnum);
  53                                 $mm->{dbh}->commit;
  54                         }) if defined($skip_artnum);
  55                         $sidx->commit_txn_lazy;
  56                 } else {
  57                         open my $fh, '>>', "$dir/ssoma.lock" or
  58                                 die "$dir/ssoma.lock: $!\n";
  59                 }
  60         } else {
  61                 my $v2w = importer($self);
  62                 $v2w->init_inbox($shards, $skip_epoch, $skip_artnum);
  63         }
  64 }
  65
  66 sub importer {
  67         my ($self, $parallel) = @_;
  68         my $v = $self->version;
  69         if ($v == 2) {
  70                 eval { require PublicInbox::V2Writable };
  71                 die "v2 not supported: $@\n" if $@;
  72                 my $opt = $self->{-creat_opt};
  73                 my $v2w = PublicInbox::V2Writable->new($self, $opt);
  74                 $v2w->{parallel} = $parallel if defined $parallel;
  75                 $v2w;
  76         } elsif ($v == 1) {
  77                 my @arg = (undef, undef, undef, $self);
  78                 PublicInbox::Import->new(@arg);
  79         } else {
  80                 $! = 78; # EX_CONFIG 5.3.5 local configuration error
  81                 die "unsupported inbox version: $v\n";
  82         }
  83 }
  84
  85 sub filter {
  86         my ($self, $im) = @_;
  87         my $f = $self->{filter};
  88         if ($f && $f =~ /::/) {
  89                 # v2 keeps msgmap open, which causes conflicts for filters
  90                 # such as PublicInbox::Filter::RubyLang which overload msgmap
  91                 # for a predictable serial number.
  92                 if ($im && $self->version >= 2 && $self->{altid}) {
  93                         $im->done;
  94                 }
  95
  96                 my @args = (-inbox => $self);
  97                 # basic line splitting, only
  98                 # Perhaps we can have proper quote splitting one day...
  99                 ($f, @args) = split(/\s+/, $f) if $f =~ /\s+/;
 100
 101                 eval "require $f";
 102                 if ($@) {
 103                         warn $@;
 104                 } else {
 105                         # e.g: PublicInbox::Filter::Vger->new(@args)
 106                         return $f->new(@args);
 107                 }
 108         }
 109         undef;
 110 }
 111
 112 sub is_maildir_basename ($) {
 113         my ($bn) = @_;
 114         return 0 if $bn !~ /\A[a-zA-Z0-9][\-\w:,=\.]+\z/;
 115         if ($bn =~ /:2,([A-Z]+)\z/i) {
 116                 my $flags = $1;
 117                 return 0 if $flags =~ /[DT]/; # no [D]rafts or [T]rashed mail
 118         }
 119         1;
 120 }
 121
 122 sub is_maildir_path ($) {
 123         my ($path) = @_;
 124         my @p = split(m!/+!, $path);
 125         (is_maildir_basename($p[-1]) && -f $path) ? 1 : 0;
 126 }
 127
 128 sub mime_from_path ($) {
 129         my ($path) = @_;
 130         if (open my $fh, '<', $path) {
 131                 local $/;
 132                 my $str = <$fh>;
 133                 $str or return;
 134                 return PublicInbox::Eml->new(\$str);
 135         } elsif ($!{ENOENT}) {
 136                 # common with Maildir
 137                 return;
 138         } else {
 139                 warn "failed to open $path: $!\n";
 140                 return;
 141         }
 142 }
 143
 144 sub import_maildir {
 145         my ($self, $dir) = @_;
 146         my $im = $self->importer(1);
 147
 148         foreach my $sub (qw(cur new tmp)) {
 149                 -d "$dir/$sub" or die "$dir is not a Maildir (missing $sub)\n";
 150         }
 151         foreach my $sub (qw(cur new)) {
 152                 opendir my $dh, "$dir/$sub" or die "opendir $dir/$sub: $!\n";
 153                 while (defined(my $fn = readdir($dh))) {
 154                         next unless is_maildir_basename($fn);
 155                         my $mime = mime_from_path("$dir/$fn") or next;
 156
 157                         if (my $filter = $self->filter($im)) {
 158                                 my $ret = $filter->scrub($mime) or return;
 159                                 return if $ret == REJECT();
 160                                 $mime = $ret;
 161                         }
 162                         $im->add($mime);
 163                 }
 164         }
 165         $im->done;
 166 }
 167
 168 # asctime: From example@example.com Fri Jun 23 02:56:55 2000
 169 my $from_strict = qr/^From \S+ +\S+ \S+ +\S+ [^:]+:[^:]+:[^:]+ [^:]+/;
 170
 171 sub mb_add ($$$$) {
 172         my ($im, $variant, $filter, $msg) = @_;
 173         $$msg =~ s/(\r?\n)+\z/$1/s;
 174         if ($variant eq 'mboxrd') {
 175                 $$msg =~ s/^>(>*From )/$1/gms;
 176         } elsif ($variant eq 'mboxo') {
 177                 $$msg =~ s/^>From /From /gms;
 178         }
 179         my $mime = PublicInbox::Eml->new($msg);
 180         if ($filter) {
 181                 my $ret = $filter->scrub($mime) or return;
 182                 return if $ret == REJECT();
 183                 $mime = $ret;
 184         }
 185         $im->add($mime)
 186 }
 187
 188 sub import_mbox {
 189         my ($self, $fh, $variant) = @_;
 190         if ($variant !~ /\A(?:mboxrd|mboxo)\z/) {
 191                 die "variant must be 'mboxrd' or 'mboxo'\n";
 192         }
 193         my $im = $self->importer(1);
 194         my $prev = undef;
 195         my $msg = '';
 196         my $filter = $self->filter;
 197         while (defined(my $l = <$fh>)) {
 198                 if ($l =~ /$from_strict/o) {
 199                         if (!defined($prev) || $prev =~ /^\r?$/) {
 200                                 mb_add($im, $variant, $filter, \$msg) if $msg;
 201                                 $msg = '';
 202                                 $prev = $l;
 203                                 next;
 204                         }
 205                         warn "W[$.] $l\n";
 206                 }
 207                 $prev = $l;
 208                 $msg .= $l;
 209         }
 210         mb_add($im, $variant, $filter, \$msg) if $msg;
 211         $im->done;
 212 }
 213
 214 sub _read_git_config_perm {
 215         my ($self) = @_;
 216         chomp(my $perm = $self->git->qx('config', 'core.sharedRepository'));
 217         $perm;
 218 }
 219
 220 sub _git_config_perm {
 221         my $self = shift;
 222         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 223         return PERM_UMASK if (!defined($perm) || $perm eq '');
 224         return PERM_UMASK if ($perm eq 'umask');
 225         return PERM_GROUP if ($perm eq 'group');
 226         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 227                 return PERM_EVERYBODY;
 228         }
 229         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 230         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 231
 232         my $i = oct($perm);
 233         return PERM_UMASK if ($i == PERM_UMASK);
 234         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 235         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 236
 237         if (($i & 0600) != 0600) {
 238                 die "core.sharedRepository mode invalid: ".
 239                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 240         }
 241         ($i & 0666);
 242 }
 243
 244 sub _umask_for {
 245         my ($perm) = @_; # _git_config_perm return value
 246         my $rv = $perm;
 247         return umask if $rv == 0;
 248
 249         # set +x bit if +r or +w were set
 250         $rv |= 0100 if ($rv & 0600);
 251         $rv |= 0010 if ($rv & 0060);
 252         $rv |= 0001 if ($rv & 0006);
 253         (~$rv & 0777);
 254 }
 255
 256 sub with_umask {
 257         my ($self, $cb) = @_;
 258         my $old = umask $self->{umask};
 259         my $rv = eval { $cb->() };
 260         my $err = $@;
 261         umask $old;
 262         die $err if $err;
 263         $rv;
 264 }
 265
 266 sub umask_prepare {
 267         my ($self) = @_;
 268         my $perm = _git_config_perm($self);
 269         my $umask = _umask_for($perm);
 270         $self->{umask} = $umask;
 271 }
 272
 273 sub cleanup ($) {
 274         delete @{$_[0]}{qw(over mm git search)};
 275 }
 276
 277 1;