lib/PublicInbox/InboxWritable.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Extends read-only Inbox for writing
   5 package PublicInbox::InboxWritable;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::Inbox);
   9 use PublicInbox::Import;
  10 use PublicInbox::Filter::Base qw(REJECT);
  11 use Errno qw(ENOENT);
  12
  13 use constant {
  14         PERM_UMASK => 0,
  15         OLD_PERM_GROUP => 1,
  16         OLD_PERM_EVERYBODY => 2,
  17         PERM_GROUP => 0660,
  18         PERM_EVERYBODY => 0664,
  19 };
  20
  21 sub new {
  22         my ($class, $ibx, $creat_opt) = @_;
  23         return $ibx if ref($ibx) eq $class;
  24         my $self = bless $ibx, $class;
  25
  26         # TODO: maybe stop supporting this
  27         if ($creat_opt) { # for { nproc => $N }
  28                 $self->{-creat_opt} = $creat_opt;
  29                 init_inbox($self) if $self->version == 1;
  30         }
  31         $self;
  32 }
  33
  34 sub assert_usable_dir {
  35         my ($self) = @_;
  36         my $dir = $self->{inboxdir};
  37         return $dir if defined($dir) && $dir ne '';
  38         die "no inboxdir defined for $self->{name}\n";
  39 }
  40
  41 sub _init_v1 {
  42         my ($self, $skip_artnum) = @_;
  43         if (defined($self->{indexlevel}) || defined($skip_artnum)) {
  44                 require PublicInbox::SearchIdx;
  45                 require PublicInbox::Msgmap;
  46                 my $sidx = PublicInbox::SearchIdx->new($self, 1); # just create
  47                 $sidx->begin_txn_lazy;
  48                 if (defined $skip_artnum) {
  49                         my $mm = PublicInbox::Msgmap->new($self->{inboxdir}, 1);
  50                         $mm->{dbh}->begin_work;
  51                         $mm->skip_artnum($skip_artnum);
  52                         $mm->{dbh}->commit;
  53                 }
  54                 $sidx->commit_txn_lazy;
  55         } else {
  56                 open my $fh, '>>', "$self->{inboxdir}/ssoma.lock" or
  57                         die "$self->{inboxdir}/ssoma.lock: $!\n";
  58         }
  59 }
  60
  61 sub init_inbox {
  62         my ($self, $shards, $skip_epoch, $skip_artnum) = @_;
  63         if ($self->version == 1) {
  64                 my $dir = assert_usable_dir($self);
  65                 PublicInbox::Import::init_bare($dir);
  66                 $self->umask_prepare;
  67                 $self->with_umask(\&_init_v1, $self, $skip_artnum);
  68         } else {
  69                 my $v2w = importer($self);
  70                 $v2w->init_inbox($shards, $skip_epoch, $skip_artnum);
  71         }
  72 }
  73
  74 sub importer {
  75         my ($self, $parallel) = @_;
  76         my $v = $self->version;
  77         if ($v == 2) {
  78                 eval { require PublicInbox::V2Writable };
  79                 die "v2 not supported: $@\n" if $@;
  80                 my $opt = $self->{-creat_opt};
  81                 my $v2w = PublicInbox::V2Writable->new($self, $opt);
  82                 $v2w->{parallel} = $parallel if defined $parallel;
  83                 $v2w;
  84         } elsif ($v == 1) {
  85                 my @arg = (undef, undef, undef, $self);
  86                 PublicInbox::Import->new(@arg);
  87         } else {
  88                 $! = 78; # EX_CONFIG 5.3.5 local configuration error
  89                 die "unsupported inbox version: $v\n";
  90         }
  91 }
  92
  93 sub filter {
  94         my ($self, $im) = @_;
  95         my $f = $self->{filter};
  96         if ($f && $f =~ /::/) {
  97                 # v2 keeps msgmap open, which causes conflicts for filters
  98                 # such as PublicInbox::Filter::RubyLang which overload msgmap
  99                 # for a predictable serial number.
 100                 if ($im && $self->version >= 2 && $self->{altid}) {
 101                         $im->done;
 102                 }
 103
 104                 my @args = (-inbox => $self);
 105                 # basic line splitting, only
 106                 # Perhaps we can have proper quote splitting one day...
 107                 ($f, @args) = split(/\s+/, $f) if $f =~ /\s+/;
 108
 109                 eval "require $f";
 110                 if ($@) {
 111                         warn $@;
 112                 } else {
 113                         # e.g: PublicInbox::Filter::Vger->new(@args)
 114                         return $f->new(@args);
 115                 }
 116         }
 117         undef;
 118 }
 119
 120 sub is_maildir_basename ($) {
 121         my ($bn) = @_;
 122         return 0 if $bn !~ /\A[a-zA-Z0-9][\-\w:,=\.]+\z/;
 123         if ($bn =~ /:2,([A-Z]+)\z/i) {
 124                 my $flags = $1;
 125                 return 0 if $flags =~ /[DT]/; # no [D]rafts or [T]rashed mail
 126         }
 127         1;
 128 }
 129
 130 sub is_maildir_path ($) {
 131         my ($path) = @_;
 132         my @p = split(m!/+!, $path);
 133         (is_maildir_basename($p[-1]) && -f $path) ? 1 : 0;
 134 }
 135
 136 sub mime_from_path ($) {
 137         my ($path) = @_;
 138         if (open my $fh, '<', $path) {
 139                 my $str = do { local $/; <$fh> } or return;
 140                 PublicInbox::Eml->new(\$str);
 141         } else { # ENOENT is common with Maildir
 142                 warn "failed to open $path: $!\n" if $! != ENOENT;
 143                 undef;
 144         }
 145 }
 146
 147 sub import_maildir {
 148         my ($self, $dir) = @_;
 149         my $im = $self->importer(1);
 150
 151         foreach my $sub (qw(cur new tmp)) {
 152                 -d "$dir/$sub" or die "$dir is not a Maildir (missing $sub)\n";
 153         }
 154         foreach my $sub (qw(cur new)) {
 155                 opendir my $dh, "$dir/$sub" or die "opendir $dir/$sub: $!\n";
 156                 while (defined(my $fn = readdir($dh))) {
 157                         next unless is_maildir_basename($fn);
 158                         my $mime = mime_from_path("$dir/$fn") or next;
 159
 160                         if (my $filter = $self->filter($im)) {
 161                                 my $ret = $filter->scrub($mime) or return;
 162                                 return if $ret == REJECT();
 163                                 $mime = $ret;
 164                         }
 165                         $im->add($mime);
 166                 }
 167         }
 168         $im->done;
 169 }
 170
 171 # asctime: From example@example.com Fri Jun 23 02:56:55 2000
 172 my $from_strict = qr/^From \S+ +\S+ \S+ +\S+ [^:]+:[^:]+:[^:]+ [^:]+/;
 173
 174 sub mb_add ($$$$) {
 175         my ($im, $variant, $filter, $msg) = @_;
 176         $$msg =~ s/(\r?\n)+\z/$1/s;
 177         if ($variant eq 'mboxrd') {
 178                 $$msg =~ s/^>(>*From )/$1/gms;
 179         } elsif ($variant eq 'mboxo') {
 180                 $$msg =~ s/^>From /From /gms;
 181         }
 182         my $mime = PublicInbox::Eml->new($msg);
 183         if ($filter) {
 184                 my $ret = $filter->scrub($mime) or return;
 185                 return if $ret == REJECT();
 186                 $mime = $ret;
 187         }
 188         $im->add($mime)
 189 }
 190
 191 sub import_mbox {
 192         my ($self, $fh, $variant) = @_;
 193         if ($variant !~ /\A(?:mboxrd|mboxo)\z/) {
 194                 die "variant must be 'mboxrd' or 'mboxo'\n";
 195         }
 196         my $im = $self->importer(1);
 197         my $prev = undef;
 198         my $msg = '';
 199         my $filter = $self->filter;
 200         while (defined(my $l = <$fh>)) {
 201                 if ($l =~ /$from_strict/o) {
 202                         if (!defined($prev) || $prev =~ /^\r?$/) {
 203                                 mb_add($im, $variant, $filter, \$msg) if $msg;
 204                                 $msg = '';
 205                                 $prev = $l;
 206                                 next;
 207                         }
 208                         warn "W[$.] $l\n";
 209                 }
 210                 $prev = $l;
 211                 $msg .= $l;
 212         }
 213         mb_add($im, $variant, $filter, \$msg) if $msg;
 214         $im->done;
 215 }
 216
 217 sub _read_git_config_perm {
 218         my ($self) = @_;
 219         chomp(my $perm = $self->git->qx('config', 'core.sharedRepository'));
 220         $perm;
 221 }
 222
 223 sub _git_config_perm {
 224         my $self = shift;
 225         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 226         return PERM_UMASK if (!defined($perm) || $perm eq '');
 227         return PERM_UMASK if ($perm eq 'umask');
 228         return PERM_GROUP if ($perm eq 'group');
 229         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 230                 return PERM_EVERYBODY;
 231         }
 232         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 233         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 234
 235         my $i = oct($perm);
 236         return PERM_UMASK if ($i == PERM_UMASK);
 237         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 238         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 239
 240         if (($i & 0600) != 0600) {
 241                 die "core.sharedRepository mode invalid: ".
 242                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 243         }
 244         ($i & 0666);
 245 }
 246
 247 sub _umask_for {
 248         my ($perm) = @_; # _git_config_perm return value
 249         my $rv = $perm;
 250         return umask if $rv == 0;
 251
 252         # set +x bit if +r or +w were set
 253         $rv |= 0100 if ($rv & 0600);
 254         $rv |= 0010 if ($rv & 0060);
 255         $rv |= 0001 if ($rv & 0006);
 256         (~$rv & 0777);
 257 }
 258
 259 sub with_umask {
 260         my ($self, $cb, @arg) = @_;
 261         my $old = umask $self->{umask};
 262         my $rv = eval { $cb->(@arg) };
 263         my $err = $@;
 264         umask $old;
 265         die $err if $err;
 266         $rv;
 267 }
 268
 269 sub umask_prepare {
 270         my ($self) = @_;
 271         my $perm = _git_config_perm($self);
 272         my $umask = _umask_for($perm);
 273         $self->{umask} = $umask;
 274 }
 275
 276 sub cleanup ($) {
 277         delete @{$_[0]}{qw(over mm git search)};
 278 }
 279
 280 1;