lib/PublicInbox/InboxWritable.pm

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Extends read-only Inbox for writing
   5 package PublicInbox::InboxWritable;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::Inbox);
   9 use PublicInbox::Import;
  10 use PublicInbox::Filter::Base;
  11 *REJECT = *PublicInbox::Filter::Base::REJECT;
  12
  13 use constant {
  14         PERM_UMASK => 0,
  15         OLD_PERM_GROUP => 1,
  16         OLD_PERM_EVERYBODY => 2,
  17         PERM_GROUP => 0660,
  18         PERM_EVERYBODY => 0664,
  19 };
  20
  21 sub new {
  22         my ($class, $ibx) = @_;
  23         bless $ibx, $class;
  24 }
  25
  26 sub importer {
  27         my ($self, $parallel) = @_;
  28         $self->{-importer} ||= eval {
  29                 my $v = $self->{version} || 1;
  30                 if ($v == 2) {
  31                         eval { require PublicInbox::V2Writable };
  32                         die "v2 not supported: $@\n" if $@;
  33                         my $v2w = PublicInbox::V2Writable->new($self);
  34                         $v2w->{parallel} = $parallel;
  35                         $v2w;
  36                 } elsif ($v == 1) {
  37                         my $git = $self->git;
  38                         my $name = $self->{name};
  39                         my $addr = $self->{-primary_address};
  40                         PublicInbox::Import->new($git, $name, $addr, $self);
  41                 } else {
  42                         $! = 78; # EX_CONFIG 5.3.5 local configuration error
  43                         die "unsupported inbox version: $v\n";
  44                 }
  45         }
  46 }
  47
  48 sub filter {
  49         my ($self) = @_;
  50         my $f = $self->{filter};
  51         if ($f && $f =~ /::/) {
  52                 my @args = (-inbox => $self);
  53                 # basic line splitting, only
  54                 # Perhaps we can have proper quote splitting one day...
  55                 ($f, @args) = split(/\s+/, $f) if $f =~ /\s+/;
  56
  57                 eval "require $f";
  58                 if ($@) {
  59                         warn $@;
  60                 } else {
  61                         # e.g: PublicInbox::Filter::Vger->new(@args)
  62                         return $f->new(@args);
  63                 }
  64         }
  65         undef;
  66 }
  67
  68 sub is_maildir_basename ($) {
  69         my ($bn) = @_;
  70         return 0 if $bn !~ /\A[a-zA-Z0-9][\-\w:,=\.]+\z/;
  71         if ($bn =~ /:2,([A-Z]+)\z/i) {
  72                 my $flags = $1;
  73                 return 0 if $flags =~ /[DT]/; # no [D]rafts or [T]rashed mail
  74         }
  75         1;
  76 }
  77
  78 sub is_maildir_path ($) {
  79         my ($path) = @_;
  80         my @p = split(m!/+!, $path);
  81         (is_maildir_basename($p[-1]) && -f $path) ? 1 : 0;
  82 }
  83
  84 sub maildir_path_load ($) {
  85         my ($path) = @_;
  86         if (open my $fh, '<', $path) {
  87                 local $/;
  88                 my $str = <$fh>;
  89                 $str or return;
  90                 return PublicInbox::MIME->new(\$str);
  91         } elsif ($!{ENOENT}) {
  92                 # common with Maildir
  93                 return;
  94         } else {
  95                 warn "failed to open $path: $!\n";
  96                 return;
  97         }
  98 }
  99
 100 sub import_maildir {
 101         my ($self, $dir) = @_;
 102         my $im = $self->importer(1);
 103         my $filter = $self->filter;
 104         foreach my $sub (qw(cur new tmp)) {
 105                 -d "$dir/$sub" or die "$dir is not a Maildir (missing $sub)\n";
 106         }
 107         foreach my $sub (qw(cur new)) {
 108                 opendir my $dh, "$dir/$sub" or die "opendir $dir/$sub: $!\n";
 109                 while (defined(my $fn = readdir($dh))) {
 110                         next unless is_maildir_basename($fn);
 111                         my $mime = maildir_file_load("$dir/$fn") or next;
 112                         if ($filter) {
 113                                 my $ret = $filter->scrub($mime) or return;
 114                                 return if $ret == REJECT();
 115                                 $mime = $ret;
 116                         }
 117                         $im->add($mime);
 118                 }
 119         }
 120         $im->done;
 121 }
 122
 123 # asctime: From example@example.com Fri Jun 23 02:56:55 2000
 124 my $from_strict = qr/^From \S+ +\S+ \S+ +\S+ [^:]+:[^:]+:[^:]+ [^:]+/;
 125
 126 sub mb_add ($$$$) {
 127         my ($im, $variant, $filter, $msg) = @_;
 128         $$msg =~ s/(\r?\n)+\z/$1/s;
 129         my $mime = PublicInbox::MIME->new($msg);
 130         if ($variant eq 'mboxrd') {
 131                 $$msg =~ s/^>(>*From )/$1/sm;
 132         } elsif ($variant eq 'mboxo') {
 133                 $$msg =~ s/^>From /From /sm;
 134         }
 135         if ($filter) {
 136                 my $ret = $filter->scrub($mime) or return;
 137                 return if $ret == REJECT();
 138                 $mime = $ret;
 139         }
 140         $im->add($mime)
 141 }
 142
 143 sub import_mbox {
 144         my ($self, $fh, $variant) = @_;
 145         if ($variant !~ /\A(?:mboxrd|mboxo)\z/) {
 146                 die "variant must be 'mboxrd' or 'mboxo'\n";
 147         }
 148         my $im = $self->importer(1);
 149         my $prev = undef;
 150         my $msg = '';
 151         my $filter = $self->filter;
 152         while (defined(my $l = <$fh>)) {
 153                 if ($l =~ /$from_strict/o) {
 154                         if (!defined($prev) || $prev =~ /^\r?$/) {
 155                                 mb_add($im, $variant, $filter, \$msg) if $msg;
 156                                 $msg = '';
 157                                 $prev = $l;
 158                                 next;
 159                         }
 160                         warn "W[$.] $l\n";
 161                 }
 162                 $prev = $l;
 163                 $msg .= $l;
 164         }
 165         mb_add($im, $variant, $filter, \$msg) if $msg;
 166         $im->done;
 167 }
 168
 169 sub _read_git_config_perm {
 170         my ($self) = @_;
 171         chomp(my $perm = $self->git->qx('config', 'core.sharedRepository'));
 172         $perm;
 173 }
 174
 175 sub _git_config_perm {
 176         my $self = shift;
 177         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 178         return PERM_UMASK if (!defined($perm) || $perm eq '');
 179         return PERM_UMASK if ($perm eq 'umask');
 180         return PERM_GROUP if ($perm eq 'group');
 181         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 182                 return PERM_EVERYBODY;
 183         }
 184         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 185         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 186
 187         my $i = oct($perm);
 188         return PERM_UMASK if ($i == PERM_UMASK);
 189         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 190         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 191
 192         if (($i & 0600) != 0600) {
 193                 die "core.sharedRepository mode invalid: ".
 194                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 195         }
 196         ($i & 0666);
 197 }
 198
 199 sub _umask_for {
 200         my ($perm) = @_; # _git_config_perm return value
 201         my $rv = $perm;
 202         return umask if $rv == 0;
 203
 204         # set +x bit if +r or +w were set
 205         $rv |= 0100 if ($rv & 0600);
 206         $rv |= 0010 if ($rv & 0060);
 207         $rv |= 0001 if ($rv & 0006);
 208         (~$rv & 0777);
 209 }
 210
 211 sub with_umask {
 212         my ($self, $cb) = @_;
 213         my $old = umask $self->{umask};
 214         my $rv = eval { $cb->() };
 215         my $err = $@;
 216         umask $old;
 217         die $err if $err;
 218         $rv;
 219 }
 220
 221 sub umask_prepare {
 222         my ($self) = @_;
 223         my $perm = _git_config_perm($self);
 224         my $umask = _umask_for($perm);
 225         $self->{umask} = $umask;
 226 }
 227
 228 1;