lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 sub rel2abs ($$) {
  69         my ($self, $p) = @_;
  70         return $p if index($p, '/') == 0; # already absolute
  71         my $pwd = $self->{env}->{PWD};
  72         if (defined $pwd) {
  73                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  74                 if (my @st_pwd = stat($pwd)) {
  75                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  76                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  77                                 $self->{env}->{PWD} = $pwd = $cwd;
  78                 } else { # PWD was invalid
  79                         delete $self->{env}->{PWD};
  80                         undef $pwd;
  81                 }
  82         }
  83         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  84         File::Spec->rel2abs($p, $pwd);
  85 }
  86
  87 sub _store_path ($) {
  88         my ($self) = @_;
  89         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  90                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  91                 .'/lei/store');
  92 }
  93
  94 sub _config_path ($) {
  95         my ($self) = @_;
  96         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  97                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  98                 .'/lei/config');
  99 }
 100
 101 # TODO: generate shell completion + help using %CMD and %OPTDESC
 102 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 103 our %CMD = ( # sorted in order of importance/use:
 104 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
 105         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
 106         sort|s=s reverse|r offset=i remote! local! external! pretty
 107         include|I=s@ exclude=s@ only=s@ jobs|j=s globoff|g
 108         mua-cmd|mua=s no-torsocks torsocks=s verbose|v quiet|q
 109         received-after=s received-before=s sent-after=s sent-since=s),
 110         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 111
 112 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 113         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
 114         pass_through('git show') ],
 115
 116 'add-external' => [ 'URL_OR_PATHNAME',
 117         'add/set priority of a publicinbox|extindex for extra matches',
 118         qw(boost=i quiet|q) ],
 119 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
 120         qw(format|f=s z|0 local remote quiet|q) ],
 121 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 122         'exclude further results from a publicinbox|extindex',
 123         qw(prune quiet|q) ],
 124
 125 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 126                 qw(name-only format|f=s z) ],
 127 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 128 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 129
 130 'plonk' => [ '--thread|--from=IDENT',
 131         'exclude mail matching From: or thread from non-Message-ID searches',
 132         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 133 'mark' => [ 'MESSAGE_FLAGS...',
 134         'set/unset flags on message(s) from stdin',
 135         qw(stdin| oid=s exact by-mid|mid:s) ],
 136 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 137         "exclude message(s) on stdin from `q' search results",
 138         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 139
 140 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 141         'remove imported messages from IMAP, Maildirs, and MH',
 142         qw(exact! all jobs:i indexed) ],
 143
 144 # code repos are used for `show' to solve blobs from patch mails
 145 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 146         qw(boost=i) ],
 147 'ls-coderepo' => [ '[FILTER_TERMS...]',
 148                 'list known code repos', qw(format|f=s z) ],
 149 'forget-coderepo' => [ 'PATHNAME',
 150         'stop using repo to solve blobs from patches',
 151         qw(prune) ],
 152
 153 'add-watch' => [ '[URL_OR_PATHNAME]',
 154                 'watch for new messages and flag changes',
 155         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 156 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 157                 qw(format|f=s z) ],
 158 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 159 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 160 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 161         qw(prune) ],
 162
 163 'import' => [ 'URL_OR_PATHNAME|--stdin',
 164         'one-shot import/update from URL or filesystem',
 165         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 166         ],
 167
 168 'config' => [ '[...]', sub {
 169                 'git-config(1) wrapper for '._config_path($_[0]);
 170         }, qw(config-file|system|global|file|f=s), # for conflict detection
 171         pass_through('git config') ],
 172 'init' => [ '[PATHNAME]', sub {
 173                 'initialize storage, default: '._store_path($_[0]);
 174         }, qw(quiet|q) ],
 175 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 176         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 177 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 178 'help' => [ '[SUBCOMMAND]', 'show help' ],
 179
 180 # XXX do we need this?
 181 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 182
 183 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 184         'rewrite git history in an attempt to improve compression',
 185         'gc!' ],
 186
 187 # internal commands are prefixed with '_'
 188 '_complete' => [ '[...]', 'internal shell completion helper',
 189                 pass_through('everything') ],
 190 ); # @CMD
 191
 192 # switch descriptions, try to keep consistent across commands
 193 # $spec: Getopt::Long option specification
 194 # $spec => [@ALLOWED_VALUES (default is first), $description],
 195 # $spec => $description
 196 # "$SUB_COMMAND TAB $spec" => as above
 197 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 198                 'specify message input format' ];
 199 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 200
 201 my %OPTDESC = (
 202 'help|h' => 'show this built-in help',
 203 'quiet|q' => 'be quiet',
 204 'globoff|g' => "do not match locations using '*?' wildcards and '[]' ranges",
 205 'verbose|v' => 'be more verbose',
 206 'solve!' => 'do not attempt to reconstruct blobs from emails',
 207 'torsocks=s' => ['auto|no|yes',
 208                 'whether or not to wrap git and curl commands with torsocks'],
 209 'no-torsocks' => 'alias for --torsocks=no',
 210 'save-as=s' => ['NAME', 'save a search terms by given name'],
 211
 212 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 213
 214 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 215                 'deduplication strategy'],
 216 'show   thread|t' => 'display entire thread a message belongs to',
 217 'q      thread|t' =>
 218         'return all messages in the same thread as the actual match(es)',
 219 'augment|a' => 'augment --output destination instead of clobbering',
 220
 221 'output|mfolder|o=s' => [ 'DEST',
 222         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 223 'mua-cmd|mua=s' => [ 'COMMAND',
 224         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 225
 226 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 227                         'message/object output format' ],
 228 'mark   format|f=s' => $stdin_formats,
 229 'forget format|f=s' => $stdin_formats,
 230 'q      format|f=s' => [
 231         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 232                 'specify output format, default depends on --output'],
 233 'q      exclude=s@' => [ 'URL_OR_PATHNAME',
 234                 'exclude specified external(s) from search' ],
 235 'q      include|I=s@' => [ 'URL_OR_PATHNAME',
 236                 'include specified external(s) in search' ],
 237 'q      only=s@' => [ 'URL_OR_PATHNAME',
 238                 'only use specified external(s) for search' ],
 239
 240 'q      jobs=s' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 241                 'control number of search and writer jobs' ],
 242
 243 'ls-query       format|f=s' => $ls_format,
 244 'ls-external    format|f=s' => $ls_format,
 245
 246 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 247 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 248
 249 'sort|s=s' => [ 'VAL|received,relevance,docid',
 250                 "order of results `--output'-dependent"],
 251 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 252
 253 'boost=i' => 'increase/decrease priority of results (default: 0)',
 254
 255 'local' => 'limit operations to the local filesystem',
 256 'local!' => 'exclude results from the local filesystem',
 257 'remote' => 'limit operations to those requiring network access',
 258 'remote!' => 'prevent operations requiring network access',
 259
 260 'mid=s' => 'specify the Message-ID of a message',
 261 'oid=s' => 'specify the git object ID of a message',
 262
 263 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 264 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 265 'include=s' => 'include mailboxes/newsgroups based on pattern',
 266
 267 'exact' => 'operate on exact header matches only',
 268 'exact!' => 'rely on content match instead of exact header matches',
 269
 270 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 271 'jobs:i' => 'set parallelism level',
 272
 273 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 274 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 275
 276 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 277 ); # %OPTDESC
 278
 279 my %CONFIG_KEYS = (
 280         'leistore.dir' => 'top-level storage location',
 281 );
 282
 283 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 284 sub x_it ($$) {
 285         my ($self, $code) = @_;
 286         # make sure client sees stdout before exit
 287         $self->{1}->autoflush(1) if $self->{1};
 288         dump_and_clear_log();
 289         if (my $s = $self->{pkt_op} // $self->{sock}) {
 290                 send($s, "x_it $code", MSG_EOR);
 291         } elsif ($self->{oneshot}) {
 292                 # don't want to end up using $? from child processes
 293                 for my $f (qw(lxs l2m)) {
 294                         my $wq = delete $self->{$f} or next;
 295                         $wq->DESTROY;
 296                 }
 297                 # cleanup anything that has tempfiles
 298                 delete @$self{qw(ovv dedupe)};
 299                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 300                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 301                         kill $signum, $$;
 302                         sleep; # wait for signal
 303                 } else {
 304                         $quit->($code >> 8);
 305                 }
 306         } # else ignore if client disconnected
 307 }
 308
 309 sub err ($;@) {
 310         my $self = shift;
 311         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 312         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 313         print $err @_, @eor and return;
 314         my $old_err = delete $self->{2};
 315         close($old_err) if $! == EPIPE && $old_err;
 316         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 317         print $err @_, @eor or print STDERR @_, @eor;
 318 }
 319
 320 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 321
 322 sub fail ($$;$) {
 323         my ($self, $buf, $exit_code) = @_;
 324         err($self, $buf) if defined $buf;
 325         send($self->{pkt_op}, '!', MSG_EOR) if $self->{pkt_op}; # fail_handler
 326         x_it($self, ($exit_code // 1) << 8);
 327         undef;
 328 }
 329
 330 sub out ($;@) {
 331         my $self = shift;
 332         return if print { $self->{1} // return } @_; # likely
 333         return note_sigpipe($self, 1) if $! == EPIPE;
 334         my $err = "error writing to stdout: $!";
 335         delete $self->{1};
 336         fail($self, $err);
 337 }
 338
 339 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 340
 341 sub child_error { # passes non-fatal curl exit codes to user
 342         my ($self, $child_error) = @_; # child_error is $?
 343         if (my $s = $self->{pkt_op} // $self->{sock}) {
 344                 # send to the parent lei-daemon or to lei(1) client
 345                 send($s, "child_error $child_error", MSG_EOR);
 346         } elsif (!$PublicInbox::DS::in_loop) {
 347                 $self->{child_error} = $child_error;
 348         } # else noop if client disconnected
 349 }
 350
 351 sub atfork_prepare_wq {
 352         my ($self, $wq) = @_;
 353         my $tcafc = $wq->{-ipc_atfork_child_close} //= [ $listener // () ];
 354         if (my $sock = $self->{sock}) {
 355                 push @$tcafc, @$self{qw(0 1 2 3)}, $sock;
 356         }
 357         if (my $pgr = $self->{pgr}) {
 358                 push @$tcafc, @$pgr[1,2];
 359         }
 360         if (my $old_1 = $self->{old_1}) {
 361                 push @$tcafc, $old_1;
 362         }
 363         for my $f (qw(lxs l2m)) {
 364                 my $ipc = $self->{$f} or next;
 365                 push @$tcafc, grep { defined }
 366                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 367         }
 368 }
 369
 370 sub io_restore ($$) {
 371         my ($dst, $src) = @_;
 372         for my $i (0..2) { # standard FDs
 373                 my $io = delete $src->{$i} or next;
 374                 $dst->{$i} = $io;
 375         }
 376         for my $i (3..9) { # named (non-standard) FDs
 377                 my $io = $src->{$i} or next;
 378                 my @st = stat($io) or die "stat $src.$i ($io): $!";
 379                 my $f = delete $dst->{"dev=$st[0],ino=$st[1]"} // next;
 380                 $dst->{$f} = $io;
 381                 delete $src->{$i};
 382         }
 383 }
 384
 385 sub note_sigpipe { # triggers sigpipe_handler
 386         my ($self, $fd) = @_;
 387         close(delete($self->{$fd})); # explicit close silences Perl warning
 388         send($self->{pkt_op}, '|', MSG_EOR) if $self->{pkt_op};
 389         x_it($self, 13);
 390 }
 391
 392 sub atfork_child_wq {
 393         my ($self, $wq) = @_;
 394         io_restore($self, $wq);
 395         -S $self->{pkt_op} or die 'BUG: {pkt_op} expected';
 396         io_restore($self->{l2m}, $wq);
 397         %PATH2CFG = ();
 398         undef $errors_log;
 399         $quit = \&CORE::exit;
 400         $current_lei = $self; # for SIG{__WARN__}
 401 }
 402
 403 sub io_extract ($;@) {
 404         my ($obj, @fields) = @_;
 405         my @io;
 406         for my $f (@fields) {
 407                 my $io = delete $obj->{$f} or next;
 408                 my @st = stat($io) or die "W: stat $obj.$f ($io): $!";
 409                 $obj->{"dev=$st[0],ino=$st[1]"} = $f;
 410                 push @io, $io;
 411         }
 412         @io
 413 }
 414
 415 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 416 sub atfork_parent_wq {
 417         my ($self, $wq) = @_;
 418         my $env = delete $self->{env}; # env is inherited at fork
 419         my $lei = bless { %$self }, ref($self);
 420         for my $f (qw(dedupe ovv)) {
 421                 my $tmp = delete($lei->{$f}) or next;
 422                 $lei->{$f} = $wq->deep_clone($tmp);
 423         }
 424         $self->{env} = $env;
 425         delete @$lei{qw(sock 3 -lei_store cfg old_1 pgr lxs)}; # keep l2m
 426         my @io = (delete(@$lei{qw(0 1 2)}),
 427                         io_extract($lei, qw(pkt_op startq)));
 428         my $l2m = $lei->{l2m};
 429         if ($l2m && $l2m != $wq) { # $wq == lxs
 430                 if (my $wq_s1 = $l2m->{-wq_s1}) {
 431                         push @io, io_extract($l2m, '-wq_s1');
 432                         $l2m->{-wq_s1} = $wq_s1;
 433                 }
 434                 $l2m->wq_close(1);
 435         }
 436         ($lei, @io);
 437 }
 438
 439 sub _help ($;$) {
 440         my ($self, $errmsg) = @_;
 441         my $cmd = $self->{cmd} // 'COMMAND';
 442         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 443         my @top = ($cmd, shift(@info) // ());
 444         my $cmd_desc = shift(@info);
 445         $cmd_desc = $cmd_desc->($self) if ref($cmd_desc) eq 'CODE';
 446         my @opt_desc;
 447         my $lpad = 2;
 448         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 449                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 450                 my $arg_vals = '';
 451                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 452
 453                 # lower-case is a keyword (e.g. `content', `oid'),
 454                 # ALL_CAPS is a string description (e.g. `PATH')
 455                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 456                         $desc .= "\ndefault: `$1'";
 457                 }
 458                 my (@vals, @s, @l);
 459                 my $x = $sw;
 460                 if ($x =~ s/!\z//) { # solve! => --no-solve
 461                         $x = "no-$x";
 462                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 463                         @vals = (' [', undef, ']');
 464                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 465                         @vals = (' ', undef);
 466                 } # else: no args $x = 'thread|t'
 467                 for (split(/\|/, $x)) { # help|h
 468                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 469                 }
 470                 if (!scalar(@vals)) { # no args 'thread|t'
 471                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 472                         $vals[1] = $1;
 473                 } else {
 474                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 475                 }
 476                 if ($arg_vals =~ /([,\|])/) {
 477                         my $sep = $1;
 478                         my @allow = split(/\Q$sep\E/, $arg_vals);
 479                         my $must = $sep eq '|' ? 'Must' : 'Can';
 480                         @allow = map { "`$_'" } @allow;
 481                         my $last = pop @allow;
 482                         $desc .= "\n$must be one of: " .
 483                                 join(', ', @allow) . " or $last";
 484                 }
 485                 my $lhs = join(', ', @s, @l) . join('', @vals);
 486                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 487                         $lhs =~ s/\A--/- , --/;
 488                 } else {
 489                         $lhs =~ s/\A--/    --/; # pad if no short options
 490                 }
 491                 $lpad = length($lhs) if length($lhs) > $lpad;
 492                 push @opt_desc, $lhs, $desc;
 493         }
 494         my $msg = $errmsg ? "E: $errmsg\n" : '';
 495         $msg .= <<EOF;
 496 usage: lei @top
 497   $cmd_desc
 498
 499 EOF
 500         $lpad += 2;
 501         local $Text::Wrap::columns = 78 - $lpad;
 502         my $padding = ' ' x ($lpad + 2);
 503         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 504                 $msg .= '  '.pack("A$lpad", $lhs);
 505                 $rhs = wrap('', '', $rhs);
 506                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 507                 $msg .= $rhs;
 508                 $msg .= "\n";
 509         }
 510         my $out = $self->{$errmsg ? 2 : 1};
 511         start_pager($self) if -t $out;
 512         print $out $msg;
 513         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 514         undef;
 515 }
 516
 517 sub optparse ($$$) {
 518         my ($self, $cmd, $argv) = @_;
 519         $self->{cmd} = $cmd;
 520         $OPT = $self->{opt} = {};
 521         my $info = $CMD{$cmd} // [ '[...]' ];
 522         my ($proto, undef, @spec) = @$info;
 523         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 524         push @spec, qw(help|h);
 525         my $lone_dash;
 526         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 527                 $lone_dash = $spec[0];
 528                 $OPT->{$spec[0]} = \(my $var);
 529                 push @spec, '' => \$var;
 530         }
 531         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 532                 return _help($self, "bad arguments or options for $cmd");
 533         return _help($self) if $OPT->{help};
 534
 535         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 536
 537         # "-" aliases "stdin" or "clear"
 538         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 539
 540         my $i = 0;
 541         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 542         my ($err, $inf);
 543         my @args = split(/ /, $proto);
 544         for my $var (@args) {
 545                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 546                         $inf = defined($argv->[$i]) and last;
 547                         $var =~ s/\.\.\.\z//;
 548                         $err = "$var not supplied";
 549                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 550                         $argv->[$i++] // ($err = "$var not supplied");
 551                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 552                         $inf = 1;
 553                         last;
 554                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 555                         $i++;
 556                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 557                         my @or = split(/\|/, $var);
 558                         my $ok;
 559                         for my $o (@or) {
 560                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 561                                         $ok = defined($OPT->{$1});
 562                                         last;
 563                                 } elsif (defined($argv->[$i])) {
 564                                         $ok = 1;
 565                                         $i++;
 566                                         last;
 567                                 } # else continue looping
 568                         }
 569                         last if $ok;
 570                         my $last = pop @or;
 571                         $err = join(', ', @or) . " or $last must be set";
 572                 } else {
 573                         warn "BUG: can't parse `$var' in $proto";
 574                 }
 575                 last if $err;
 576         }
 577         if (!$inf && scalar(@$argv) > scalar(@args)) {
 578                 $err //= 'too many arguments';
 579         }
 580         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 581 }
 582
 583 sub dispatch {
 584         my ($self, $cmd, @argv) = @_;
 585         local $current_lei = $self; # for __WARN__
 586         dump_and_clear_log("from previous run\n");
 587         return _help($self, 'no command given') unless defined($cmd);
 588         my $func = "lei_$cmd";
 589         $func =~ tr/-/_/;
 590         if (my $cb = __PACKAGE__->can($func)) {
 591                 optparse($self, $cmd, \@argv) or return;
 592                 $cb->($self, @argv);
 593         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 594                 my $opt = {};
 595                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 596                         return _help($self, 'bad arguments or options');
 597                 _help($self);
 598         } else {
 599                 fail($self, "`$cmd' is not an lei command");
 600         }
 601 }
 602
 603 sub _lei_cfg ($;$) {
 604         my ($self, $creat) = @_;
 605         my $f = _config_path($self);
 606         my @st = stat($f);
 607         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 608         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 609                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 610         }
 611         if (!@st) {
 612                 unless ($creat) {
 613                         delete $self->{cfg};
 614                         return;
 615                 }
 616                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 617                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 618                 open my $fh, '>>', $f or die "open($f): $!\n";
 619                 @st = stat($fh) or die "fstat($f): $!\n";
 620                 $cur_st = pack('dd', $st[10], $st[7]);
 621                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 622         }
 623         my $cfg = PublicInbox::Config::git_config_dump($f);
 624         $cfg->{-st} = $cur_st;
 625         $cfg->{'-f'} = $f;
 626         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 627 }
 628
 629 sub _lei_store ($;$) {
 630         my ($self, $creat) = @_;
 631         my $cfg = _lei_cfg($self, $creat);
 632         $cfg->{-lei_store} //= do {
 633                 require PublicInbox::LeiStore;
 634                 my $dir = $cfg->{'leistore.dir'};
 635                 $dir //= $creat ? _store_path($self) : return;
 636                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 637         };
 638 }
 639
 640 sub lei_show {
 641         my ($self, @argv) = @_;
 642 }
 643
 644 sub lei_mark {
 645         my ($self, @argv) = @_;
 646 }
 647
 648 sub _config {
 649         my ($self, @argv) = @_;
 650         my $env = $self->{env};
 651         delete local $env->{GIT_CONFIG};
 652         delete local $ENV{GIT_CONFIG};
 653         my $cfg = _lei_cfg($self, 1);
 654         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 655         my %rdr = map { $_ => $self->{$_} } (0..2);
 656         waitpid(spawn($cmd, $env, \%rdr), 0);
 657 }
 658
 659 sub lei_config {
 660         my ($self, @argv) = @_;
 661         $self->{opt}->{'config-file'} and return fail $self,
 662                 "config file switches not supported by `lei config'";
 663         _config(@_);
 664         x_it($self, $?) if $?;
 665 }
 666
 667 sub lei_init {
 668         my ($self, $dir) = @_;
 669         my $cfg = _lei_cfg($self, 1);
 670         my $cur = $cfg->{'leistore.dir'};
 671         $dir //= _store_path($self);
 672         $dir = rel2abs($self, $dir);
 673         my @cur = stat($cur) if defined($cur);
 674         $cur = File::Spec->canonpath($cur // $dir);
 675         my @dir = stat($dir);
 676         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 677         if (@cur) {
 678                 if ($cur eq $dir) {
 679                         _lei_store($self, 1)->done;
 680                         return qerr($self, $exists);
 681                 }
 682
 683                 # some folks like symlinks and bind mounts :P
 684                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 685                         lei_config($self, 'leistore.dir', $dir);
 686                         _lei_store($self, 1)->done;
 687                         return qerr($self, "$exists (as $cur)");
 688                 }
 689                 return fail($self, <<"");
 690 E: leistore.dir=$cur already initialized and it is not $dir
 691
 692         }
 693         lei_config($self, 'leistore.dir', $dir);
 694         _lei_store($self, 1)->done;
 695         $exists //= "I: leistore.dir=$dir newly initialized";
 696         return qerr($self, $exists);
 697 }
 698
 699 sub lei_daemon_pid { puts shift, $$ }
 700
 701 sub lei_daemon_kill {
 702         my ($self) = @_;
 703         my $sig = $self->{opt}->{signal} // 'TERM';
 704         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 705 }
 706
 707 sub lei_help { _help($_[0]) }
 708
 709 # Shell completion helper.  Used by lei-completion.bash and hopefully
 710 # other shells.  Try to do as much here as possible to avoid redundancy
 711 # and improve maintainability.
 712 sub lei__complete {
 713         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 714         shift @argv; # ignore "lei", the entire command is sent
 715         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 716         my $cmd = shift @argv;
 717         my $info = $CMD{$cmd} // do { # filter matching commands
 718                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 719                 return;
 720         };
 721         my ($proto, undef, @spec) = @$info;
 722         my $cur = pop @argv;
 723         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 724         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 725                 # gross special case since the only git-config options
 726                 # Consider moving to a table if we need more special cases
 727                 # we use Getopt::Long for are the ones we reject, so these
 728                 # are the ones we don't reject:
 729                 if ($cmd eq 'config') {
 730                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 731                         @spec = qw(add z|null get get-all unset unset-all
 732                                 replace-all get-urlmatch
 733                                 remove-section rename-section
 734                                 name-only list|l edit|e
 735                                 get-color-name get-colorbool);
 736                         # fall-through
 737                 }
 738                 puts $self, grep(/$re/, map { # generate short/long names
 739                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 740                         } else { # negation: solve! => no-solve|solve
 741                                 s/\A(.+)!\z/no-$1|$1/;
 742                         }
 743                         map {
 744                                 my $x = length > 1 ? "--$_" : "-$_";
 745                                 $x eq $cur ? () : $x;
 746                         } split(/\|/, $_, -1) # help|h
 747                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 748         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 749                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 750         }
 751
 752         # switch args (e.g. lei q -f mbox<TAB>)
 753         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 754                 my $opt = quotemeta $1;
 755                 puts $self, map {
 756                         my $v = $OPTDESC{$_};
 757                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 758                         # get rid of ALL CAPS placeholder (e.g "OUT")
 759                         # (TODO: completion for external paths)
 760                         shift(@v) if uc($v[0]) eq $v[0];
 761                         @v;
 762                 } grep(/\A(?:$cmd\t|)(?:[\w-]+\|)*$opt\b/, keys %OPTDESC);
 763         }
 764         $cmd =~ tr/-/_/;
 765         if (my $sub = $self->can("_complete_$cmd")) {
 766                 puts $self, $sub->($self, @argv, $cur);
 767         }
 768         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 769         # proto parsing.
 770 }
 771
 772 sub exec_buf ($$) {
 773         my ($argv, $env) = @_;
 774         my $argc = scalar @$argv;
 775         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 776         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 777         $buf;
 778 }
 779
 780 sub start_mua {
 781         my ($self) = @_;
 782         my $mua = $self->{opt}->{'mua-cmd'} // return;
 783         my $mfolder = $self->{ovv}->{dst};
 784         my (@cmd, $replaced);
 785         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 786                 @cmd = ($mua, '-f');
 787         # TODO: help wanted: other common FOSS MUAs
 788         } else {
 789                 require Text::ParseWords;
 790                 my @cmd = Text::ParseWords::shellwords($mua);
 791                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 792                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 793         }
 794         push @cmd, $mfolder unless defined($replaced);
 795         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 796                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 797         } elsif ($self->{oneshot}) {
 798                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 799         }
 800 }
 801
 802 # caller needs to "-t $self->{1}" to check if tty
 803 sub start_pager {
 804         my ($self) = @_;
 805         my $env = $self->{env};
 806         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 807         chomp(my $pager = <$fh> // '');
 808         close($fh) or warn "`git var PAGER' error: \$?=$?";
 809         return if $pager eq 'cat' || $pager eq '';
 810         # TODO TIOCGWINSZ
 811         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 812         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 813         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 814         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 815         my $pgr = [ undef, @$rdr{1, 2} ];
 816         if (my $sock = $self->{sock}) { # lei(1) process runs it
 817                 delete @$new_env{keys %$env}; # only set iff unset
 818                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 819                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 820         } elsif ($self->{oneshot}) {
 821                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 822                 $pgr->[3] = $$; # ew'll reap it
 823         } else {
 824                 die 'BUG: start_pager w/o socket';
 825         }
 826         $self->{1} = $wpager;
 827         $self->{2} = $wpager if -t $self->{2};
 828         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 829         $self->{pgr} = $pgr;
 830 }
 831
 832 sub stop_pager {
 833         my ($self) = @_;
 834         my $pgr = delete($self->{pgr}) or return;
 835         $self->{2} = $pgr->[2];
 836         # do not restore original stdout, just close it so we error out
 837         close(delete($self->{1})) if $self->{1};
 838         my $pid = $pgr->[0];
 839         dwaitpid($pid) if $pid && ($pgr->[3] // 0) == $$;
 840 }
 841
 842 sub accept_dispatch { # Listener {post_accept} callback
 843         my ($sock) = @_; # ignore other
 844         $sock->autoflush(1);
 845         my $self = bless { sock => $sock }, __PACKAGE__;
 846         vec(my $rvec = '', fileno($sock), 1) = 1;
 847         select($rvec, undef, undef, 60) or
 848                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 849         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 850         if (scalar(@fds) == 4) {
 851                 for my $i (0..3) {
 852                         my $fd = shift(@fds);
 853                         open($self->{$i}, '+<&=', $fd) and next;
 854                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 855                 }
 856         } else {
 857                 my $msg = "recv_cmd failed: $!";
 858                 warn $msg;
 859                 return send($sock, $msg, MSG_EOR);
 860         }
 861         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 862         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 863         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 864         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 865                 return send($sock, 'request command truncated', MSG_EOR);
 866         my ($argc, @argv) = split(/\0/, $buf, -1);
 867         undef $buf;
 868         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 869         if (chdir($self->{3})) {
 870                 local %ENV = %env;
 871                 $self->{env} = \%env;
 872                 eval { dispatch($self, @argv) };
 873                 send($sock, $@, MSG_EOR) if $@;
 874         } else {
 875                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 876         }
 877 }
 878
 879 sub dclose {
 880         my ($self) = @_;
 881         delete $self->{-progress};
 882         for my $f (qw(lxs l2m)) {
 883                 my $wq = delete $self->{$f} or next;
 884                 if ($wq->wq_kill) {
 885                         $wq->wq_close
 886                 } elsif ($wq->wq_kill_old) {
 887                         $wq->wq_wait_old($self);
 888                 }
 889         }
 890         close(delete $self->{1}) if $self->{1}; # may reap_compress
 891         $self->close if $self->{sock}; # PublicInbox::DS::close
 892 }
 893
 894 # for long-running results
 895 sub event_step {
 896         my ($self) = @_;
 897         local %ENV = %{$self->{env}};
 898         my $sock = $self->{sock};
 899         local $current_lei = $self;
 900         eval {
 901                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 902                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 903                                 return if $! == EAGAIN;
 904                                 next if $! == EINTR;
 905                                 last if $! == ECONNRESET;
 906                                 die "recvmsg: $!";
 907                         }
 908                         for my $fd (@fds) {
 909                                 open my $rfh, '+<&=', $fd;
 910                         }
 911                         die "unrecognized client signal: $buf";
 912                 }
 913                 dclose($self);
 914         };
 915         if (my $err = $@) {
 916                 eval { $self->fail($err) };
 917                 dclose($self);
 918         }
 919 }
 920
 921 sub event_step_init {
 922         my ($self) = @_;
 923         if (my $sock = $self->{sock}) { # using DS->EventLoop
 924                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 925         }
 926 }
 927
 928 sub noop {}
 929
 930 our $oldset; sub oldset { $oldset }
 931
 932 sub dump_and_clear_log {
 933         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 934                 my @pfx = @_;
 935                 unshift(@pfx, "$errors_log ") if @pfx;
 936                 warn @pfx, do { local $/; <STDIN> };
 937                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 938         }
 939 }
 940
 941 # lei(1) calls this when it can't connect
 942 sub lazy_start {
 943         my ($path, $errno, $narg) = @_;
 944         if ($errno == ECONNREFUSED) {
 945                 unlink($path) or die "unlink($path): $!";
 946         } elsif ($errno != ENOENT) {
 947                 $! = $errno; # allow interpolation to stringify in die
 948                 die "connect($path): $!";
 949         }
 950         if (eval { require BSD::Resource }) {
 951                 my $NOFILE = BSD::Resource::RLIMIT_NOFILE();
 952                 my ($s, $h) = BSD::Resource::getrlimit($NOFILE);
 953                 BSD::Resource::setrlimit($NOFILE, $h, $h) if $s < $h;
 954         }
 955         umask(077) // die("umask(077): $!");
 956         local $listener;
 957         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 958         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 959         listen($listener, 1024) or die "listen: $!";
 960         my @st = stat($path) or die "stat($path): $!";
 961         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 962         local $oldset = PublicInbox::DS::block_signals();
 963         if ($narg == 5) {
 964                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 965                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 966                         require PublicInbox::CmdIPC4;
 967                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 968                         PublicInbox::CmdIPC4->can('recv_cmd4');
 969                 };
 970         }
 971         $recv_cmd or die <<"";
 972 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 973
 974         require PublicInbox::Listener;
 975         require PublicInbox::EOFpipe;
 976         (-p STDOUT) or die "E: stdout must be a pipe\n";
 977         local $errors_log;
 978         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 979         $errors_log .= 'errors.log';
 980         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 981         STDIN->autoflush(1);
 982         dump_and_clear_log("from previous daemon process:\n");
 983         POSIX::setsid() > 0 or die "setsid: $!";
 984         my $pid = fork // die "fork: $!";
 985         return if $pid;
 986         $0 = "lei-daemon $path";
 987         local %PATH2CFG;
 988         $listener->blocking(0);
 989         my $exit_code;
 990         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 991         local $quit = do {
 992                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 993                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 994                 sub {
 995                         $exit_code //= shift;
 996                         my $lis = $pil or exit($exit_code);
 997                         # closing eof_w triggers \&noop wakeup
 998                         $listener = $eof_w = $pil = $path = undef;
 999                         $lis->close; # DS::close
1000                         PublicInbox::DS->SetLoopTimeout(1000);
1001                 };
1002         };
1003         my $sig = {
1004                 CHLD => \&PublicInbox::DS::enqueue_reap,
1005                 QUIT => $quit,
1006                 INT => $quit,
1007                 TERM => $quit,
1008                 HUP => \&noop,
1009                 USR1 => \&noop,
1010                 USR2 => \&noop,
1011         };
1012         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1013         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1014         undef $sig;
1015         local $SIG{PIPE} = 'IGNORE';
1016         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1017                 undef $sigfd;
1018                 PublicInbox::DS->SetLoopTimeout(5000);
1019         } else {
1020                 # wake up every second to accept signals if we don't
1021                 # have signalfd or IO::KQueue:
1022                 PublicInbox::DS::sig_setmask($oldset);
1023                 PublicInbox::DS->SetLoopTimeout(1000);
1024         }
1025         PublicInbox::DS->SetPostLoopCallback(sub {
1026                 my ($dmap, undef) = @_;
1027                 if (@st = defined($path) ? stat($path) : ()) {
1028                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1029                                 warn "$path dev/ino changed, quitting\n";
1030                                 $path = undef;
1031                         }
1032                 } elsif (defined($path)) { # ENOENT is common
1033                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1034                         undef $path;
1035                         $quit->();
1036                 }
1037                 return 1 if defined($path);
1038                 my $now = now();
1039                 my $n = 0;
1040                 for my $s (values %$dmap) {
1041                         $s->can('busy') or next;
1042                         if ($s->busy($now)) {
1043                                 ++$n;
1044                         } else {
1045                                 $s->close;
1046                         }
1047                 }
1048                 $n; # true: continue, false: stop
1049         });
1050
1051         # STDIN was redirected to /dev/null above, closing STDERR and
1052         # STDOUT will cause the calling `lei' client process to finish
1053         # reading the <$daemon> pipe.
1054         local $SIG{__WARN__} = sub {
1055                 $current_lei ? err($current_lei, @_) : warn(
1056                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1057         };
1058         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1059         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1060         # $daemon pipe to `lei' closed, main loop begins:
1061         PublicInbox::DS->EventLoop;
1062         exit($exit_code // 0);
1063 }
1064
1065 # for users w/o Socket::Msghdr installed or Inline::C enabled
1066 sub oneshot {
1067         my ($main_pkg) = @_;
1068         my $exit = $main_pkg->can('exit'); # caller may override exit()
1069         local $quit = $exit if $exit;
1070         local %PATH2CFG;
1071         umask(077) // die("umask(077): $!");
1072         my $self = bless {
1073                 oneshot => 1,
1074                 0 => *STDIN{GLOB},
1075                 1 => *STDOUT{GLOB},
1076                 2 => *STDERR{GLOB},
1077                 env => \%ENV
1078         }, __PACKAGE__;
1079         dispatch($self, @ARGV);
1080         x_it($self, $self->{child_error}) if $self->{child_error};
1081 }
1082
1083 # ensures stdout hits the FS before sock disconnects so a client
1084 # can immediately reread it
1085 sub DESTROY {
1086         my ($self) = @_;
1087         $self->{1}->autoflush(1) if $self->{1};
1088         stop_pager($self);
1089         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1090                 waitpid($mua_pid, 0);
1091         }
1092 }
1093
1094 1;