lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use Time::HiRes qw(stat); # ctime comparisons for config cache
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log, $listener, $oldset);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub rel2abs ($$) {
  68         my ($self, $p) = @_;
  69         return $p if index($p, '/') == 0; # already absolute
  70         my $pwd = $self->{env}->{PWD};
  71         if (defined $pwd) {
  72                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  73                 if (my @st_pwd = stat($pwd)) {
  74                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  75                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  76                                 $self->{env}->{PWD} = $pwd = $cwd;
  77                 } else { # PWD was invalid
  78                         delete $self->{env}->{PWD};
  79                         undef $pwd;
  80                 }
  81         }
  82         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  83         File::Spec->rel2abs($p, $pwd);
  84 }
  85
  86 sub store_path ($) {
  87         my ($self) = @_;
  88         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  89                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  90                 .'/lei/store');
  91 }
  92
  93 sub _config_path ($) {
  94         my ($self) = @_;
  95         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  96                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  97                 .'/lei/config');
  98 }
  99
 100 sub cache_dir ($) {
 101         my ($self) = @_;
 102         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 103                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 104                 .'/lei');
 105 }
 106
 107 sub ale {
 108         my ($self) = @_;
 109         $self->{ale} //= do {
 110                 require PublicInbox::LeiALE;
 111                 PublicInbox::LeiALE->new(cache_dir($self).
 112                                         '/all_locals_ever.git');
 113         };
 114 }
 115
 116 sub index_opt {
 117         # TODO: drop underscore variants everywhere, they're undocumented
 118         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 119         max_size|max-size=s sequential_shard|sequential-shard
 120         batch_size|batch-size=s skip-docdata)
 121 }
 122
 123 # we generate shell completion + help using %CMD and %OPTDESC,
 124 # see lei__complete() and PublicInbox::LeiHelp
 125 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 126 our %CMD = ( # sorted in order of importance/use:
 127 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 128         'stdin|', # /|\z/ must be first for lone dash
 129         qw(save-as=s output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 130         sort|s=s reverse|r offset=i remote! local! external! pretty
 131         include|I=s@ exclude=s@ only=s@ jobs|j=s globoff|g augment|a
 132         import-remote! import-before! lock=s@ rsyncable
 133         alert=s@ mua=s no-torsocks torsocks=s verbose|v+ quiet|q C=s@),
 134         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 135
 136 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 137         qw(type=s solve! format|f=s dedupe|d=s threads|t remote local! C=s@),
 138         pass_through('git show') ],
 139
 140 'add-external' => [ 'LOCATION',
 141         'add/set priority of a publicinbox|extindex for extra matches',
 142         qw(boost=i c=s@ mirror=s no-torsocks torsocks=s inbox-version=i),
 143         qw(quiet|q verbose|v+ C=s@),
 144         index_opt(), PublicInbox::LeiQuery::curl_opt() ],
 145 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 146         qw(format|f=s z|0 globoff|g invert-match|v local remote C=s@) ],
 147 'forget-external' => [ 'LOCATION...|--prune',
 148         'exclude further results from a publicinbox|extindex',
 149         qw(prune quiet|q C=s@) ],
 150
 151 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 152                 qw(name-only format|f=s C=s@) ],
 153 'rm-query' => [ 'QUERY_NAME', 'remove a saved search', qw(C=s@) ],
 154 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search', qw(C=s@) ],
 155
 156 'plonk' => [ '--threads|--from=IDENT',
 157         'exclude mail matching From: or threads from non-Message-ID searches',
 158         qw(stdin| threads|t from|f=s mid=s oid=s C=s@) ],
 159 'mark' => [ 'MESSAGE_FLAGS...',
 160         'set/unset keywords on message(s) from stdin',
 161         qw(stdin| oid=s exact by-mid|mid:s C=s@) ],
 162 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 163         "exclude message(s) on stdin from `q' search results",
 164         qw(stdin| oid=s exact by-mid|mid:s quiet|q C=s@) ],
 165
 166 'purge-mailsource' => [ 'LOCATION|--all',
 167         'remove imported messages from IMAP, Maildirs, and MH',
 168         qw(exact! all jobs:i indexed C=s@) ],
 169
 170 # code repos are used for `show' to solve blobs from patch mails
 171 'add-coderepo' => [ 'DIRNAME', 'add or set priority of a git code repo',
 172         qw(boost=i C=s@) ],
 173 'ls-coderepo' => [ '[FILTER_TERMS...]',
 174                 'list known code repos', qw(format|f=s z C=s@) ],
 175 'forget-coderepo' => [ 'DIRNAME',
 176         'stop using repo to solve blobs from patches',
 177         qw(prune C=s@) ],
 178
 179 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 180         qw(import! kw|keywords|flags! interval=s recursive|r
 181         exclude=s include=s C=s@) ],
 182 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 183                 qw(format|f=s z C=s@) ],
 184 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote C=s@) ],
 185 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote C=s@) ],
 186 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 187         qw(prune C=s@) ],
 188
 189 'import' => [ 'LOCATION...|--stdin',
 190         'one-time import/update from URL or filesystem',
 191         qw(stdin| offset=i recursive|r exclude=s include|I=s
 192         lock=s@ in-format|F=s kw|keywords|flags! C=s@),
 193         ],
 194 'convert' => [ 'LOCATION...|--stdin',
 195         'one-time conversion from URL or filesystem to another format',
 196         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s quiet|q
 197         lock=s@ kw|keywords|flags! C=s@),
 198         ],
 199 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 200         "use a patch to generate a query for `lei q --stdin'",
 201         qw(stdin| want|w=s@ uri debug) ],
 202 'config' => [ '[...]', sub {
 203                 'git-config(1) wrapper for '._config_path($_[0]);
 204         }, qw(config-file|system|global|file|f=s), # for conflict detection
 205          qw(C=s@), pass_through('git config') ],
 206 'init' => [ '[DIRNAME]', sub {
 207         "initialize storage, default: ".store_path($_[0]);
 208         }, qw(quiet|q C=s@) ],
 209 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 210         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 211         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 212 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 213 'help' => [ '[SUBCOMMAND]', 'show help' ],
 214
 215 # XXX do we need this?
 216 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 217
 218 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 219         'rewrite git history in an attempt to improve compression',
 220         qw(gc! C=s@) ],
 221
 222 # internal commands are prefixed with '_'
 223 '_complete' => [ '[...]', 'internal shell completion helper',
 224                 pass_through('everything') ],
 225 ); # @CMD
 226
 227 # switch descriptions, try to keep consistent across commands
 228 # $spec: Getopt::Long option specification
 229 # $spec => [@ALLOWED_VALUES (default is first), $description],
 230 # $spec => $description
 231 # "$SUB_COMMAND TAB $spec" => as above
 232 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 233                         'specify message input format' ];
 234 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 235
 236 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 237 my %OPTDESC = (
 238 'help|h' => 'show this built-in help',
 239 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 240 'quiet|q' => 'be quiet',
 241 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 242         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 243
 244 'globoff|g' => "do not match locations using '*?' wildcards ".
 245                 "and\xa0'[]'\x{a0}ranges",
 246 'verbose|v+' => 'be more verbose',
 247 'external!' => 'do not use externals',
 248 'solve!' => 'do not attempt to reconstruct blobs from emails',
 249 'torsocks=s' => ['VAL|auto|no|yes',
 250                 'whether or not to wrap git and curl commands with torsocks'],
 251 'no-torsocks' => 'alias for --torsocks=no',
 252 'save-as=s' => ['NAME', 'save a search terms by given name'],
 253 'import-remote!' => 'do not memoize remote messages into local store',
 254
 255 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 256
 257 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 258                 'deduplication strategy'],
 259 'threads|t+' =>
 260         'return all messages in the same threads as the actual match(es)',
 261
 262 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 263                 'search prefixes to extract (default: dfpost7)' ],
 264
 265 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 266         'run command(s) or perform ops when done writing to output ' .
 267         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 268         'nothing otherwise)' ],
 269
 270 'augment|a' => 'augment --output destination instead of clobbering',
 271
 272 'output|mfolder|o=s' => [ 'MFOLDER',
 273         "destination (e.g.\xa0`/path/to/Maildir', ".
 274         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 275 'mua=s' => [ 'CMD',
 276         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 277
 278 'inbox-version=i' => [ 'NUM|1|2',
 279                 'force a public-inbox version with --mirror'],
 280 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 281
 282 # public-inbox-index options
 283 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 284 'compact' => 'run compact index after mirroring',
 285 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 286         "indexlevel with --mirror (default: full)" ],
 287 'max_size|max-size=s' => [ 'SIZE',
 288         'do not index messages larger than SIZE (default: infinity)' ],
 289 'batch_size|batch-size=s' => [ 'SIZE',
 290         'flush changes to OS after given number of bytes (default: 1m)' ],
 291 'sequential_shard|sequential-shard' =>
 292         'index Xapian shards sequentially for slow storage',
 293 'skip-docdata' =>
 294         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 295
 296 'format|f=s     q' => [
 297         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 298                 'specify output format, default depends on --output'],
 299 'exclude=s@     q' => [ 'LOCATION',
 300                 'exclude specified external(s) from search' ],
 301 'include|I=s@   q' => [ 'LOCATION',
 302                 'include specified external(s) in search' ],
 303 'only=s@        q' => [ 'LOCATION',
 304                 'only use specified external(s) for search' ],
 305 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 306                 'control number of search and writer jobs' ],
 307 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 308
 309 'in-format|F=s' => $stdin_formats,
 310 'format|f=s     ls-query' => $ls_format,
 311 'format|f=s     ls-external' => $ls_format,
 312
 313 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 314 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 315
 316 'sort|s=s' => [ 'VAL|received|relevance|docid',
 317                 "order of results is `--output'-dependent"],
 318 'reverse|r' => 'reverse search results', # like sort(1)
 319
 320 'boost=i' => 'increase/decrease priority of results (default: 0)',
 321
 322 'local' => 'limit operations to the local filesystem',
 323 'local!' => 'exclude results from the local filesystem',
 324 'remote' => 'limit operations to those requiring network access',
 325 'remote!' => 'prevent operations requiring network access',
 326
 327 'mid=s' => 'specify the Message-ID of a message',
 328 'oid=s' => 'specify the git object ID of a message',
 329
 330 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 331 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 332 'include=s' => 'include mailboxes/newsgroups based on pattern',
 333
 334 'exact' => 'operate on exact header matches only',
 335 'exact!' => 'rely on content match instead of exact header matches',
 336
 337 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 338
 339 'kw|keywords|flags!' => 'disable/enable importing flags',
 340
 341 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 342 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 343
 344 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 345 ); # %OPTDESC
 346
 347 my %CONFIG_KEYS = (
 348         'leistore.dir' => 'top-level storage location',
 349 );
 350
 351 my @WQ_KEYS = qw(lxs l2m imp mrr cnv p2q); # internal workers
 352
 353 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 354 sub x_it ($$) {
 355         my ($self, $code) = @_;
 356         # make sure client sees stdout before exit
 357         $self->{1}->autoflush(1) if $self->{1};
 358         dump_and_clear_log();
 359         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 360                 send($s, "x_it $code", MSG_EOR);
 361         } elsif ($self->{oneshot}) {
 362                 # don't want to end up using $? from child processes
 363                 for my $f (@WQ_KEYS) {
 364                         my $wq = delete $self->{$f} or next;
 365                         $wq->DESTROY;
 366                 }
 367                 # cleanup anything that has tempfiles or open file handles
 368                 %PATH2CFG = ();
 369                 delete @$self{qw(ovv dedupe sto cfg)};
 370                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 371                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 372                         kill $signum, $$;
 373                         sleep(1) while 1; # wait for signal
 374                 } else {
 375                         $quit->($code >> 8);
 376                 }
 377         } # else ignore if client disconnected
 378 }
 379
 380 sub err ($;@) {
 381         my $self = shift;
 382         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 383         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 384         print $err @_, @eor and return;
 385         my $old_err = delete $self->{2};
 386         close($old_err) if $! == EPIPE && $old_err;
 387         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 388         print $err @_, @eor or print STDERR @_, @eor;
 389 }
 390
 391 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 392
 393 sub fail_handler ($;$$) {
 394         my ($lei, $code, $io) = @_;
 395         for my $f (@WQ_KEYS) {
 396                 my $wq = delete $lei->{$f} or next;
 397                 $wq->wq_wait_old(undef, $lei) if $wq->wq_kill_old; # lei-daemon
 398         }
 399         close($io) if $io; # needed to avoid warnings on SIGPIPE
 400         x_it($lei, $code // (1 << 8));
 401 }
 402
 403 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 404         fail_handler($_[0], 13, delete $_[0]->{1});
 405 }
 406
 407 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 408 sub sigint_reap {
 409         my ($pgid) = @_;
 410         dwaitpid($pgid) if kill('-INT', $pgid);
 411 }
 412
 413 sub fail ($$;$) {
 414         my ($self, $buf, $exit_code) = @_;
 415         err($self, $buf) if defined $buf;
 416         # calls fail_handler:
 417         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 418         x_it($self, ($exit_code // 1) << 8);
 419         undef;
 420 }
 421
 422 sub check_input_format ($;$) {
 423         my ($self, $files) = @_;
 424         my $opt_key = 'in-format';
 425         my $fmt = $self->{opt}->{$opt_key};
 426         if (!$fmt) {
 427                 my $err = $files ? "regular file(s):\n@$files" : '--stdin';
 428                 return fail($self, "--$opt_key unset for $err");
 429         }
 430         require PublicInbox::MboxLock if $files;
 431         require PublicInbox::MboxReader;
 432         return 1 if $fmt eq 'eml';
 433         # XXX: should this handle {gz,bz2,xz}? that's currently in LeiToMail
 434         PublicInbox::MboxReader->can($fmt) or
 435                 return fail($self, "--$opt_key=$fmt unrecognized");
 436         1;
 437 }
 438
 439 sub out ($;@) {
 440         my $self = shift;
 441         return if print { $self->{1} // return } @_; # likely
 442         return note_sigpipe($self, 1) if $! == EPIPE;
 443         my $err = "error writing to output: $!";
 444         delete $self->{1};
 445         fail($self, $err);
 446 }
 447
 448 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 449
 450 sub child_error { # passes non-fatal curl exit codes to user
 451         my ($self, $child_error, $msg) = @_; # child_error is $?
 452         $self->err($msg) if $msg;
 453         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 454                 # send to the parent lei-daemon or to lei(1) client
 455                 send($s, "child_error $child_error", MSG_EOR);
 456         } elsif (!$PublicInbox::DS::in_loop) {
 457                 $self->{child_error} = $child_error;
 458         } # else noop if client disconnected
 459 }
 460
 461 sub note_sigpipe { # triggers sigpipe_handler
 462         my ($self, $fd) = @_;
 463         close(delete($self->{$fd})); # explicit close silences Perl warning
 464         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 465         x_it($self, 13);
 466 }
 467
 468 sub lei_atfork_child {
 469         my ($self, $persist) = @_;
 470         # we need to explicitly close things which are on stack
 471         if ($persist) {
 472                 my @io = delete @$self{qw(0 1 2 sock)};
 473                 unless ($self->{oneshot}) {
 474                         close($_) for @io;
 475                 }
 476         } else {
 477                 delete $self->{0};
 478         }
 479         delete @$self{qw(cnv)};
 480         for (delete @$self{qw(3 old_1 au_done)}) {
 481                 close($_) if defined($_);
 482         }
 483         if (my $op_c = delete $self->{pkt_op_c}) {
 484                 close(delete $op_c->{sock});
 485         }
 486         if (my $pgr = delete $self->{pgr}) {
 487                 close($_) for (@$pgr[1,2]);
 488         }
 489         close $listener if $listener;
 490         undef $listener;
 491         %PATH2CFG = ();
 492         undef $errors_log;
 493         $quit = \&CORE::exit;
 494         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 495 }
 496
 497 sub workers_start {
 498         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 499         $ops = {
 500                 '!' => [ $lei->can('fail_handler'), $lei ],
 501                 '|' => [ $lei->can('sigpipe_handler'), $lei ],
 502                 'x_it' => [ $lei->can('x_it'), $lei ],
 503                 'child_error' => [ $lei->can('child_error'), $lei ],
 504                 %$ops
 505         };
 506         require PublicInbox::PktOp;
 507         ($lei->{pkt_op_c}, $lei->{pkt_op_p}) = PublicInbox::PktOp->pair($ops);
 508         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 509         delete $lei->{pkt_op_p};
 510         my $op = delete $lei->{pkt_op_c};
 511         $lei->event_step_init;
 512         # oneshot needs $op, daemon-mode uses DS->EventLoop to handle $op
 513         $lei->{oneshot} ? $op : undef;
 514 }
 515
 516 sub _help {
 517         require PublicInbox::LeiHelp;
 518         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 519 }
 520
 521 sub optparse ($$$) {
 522         my ($self, $cmd, $argv) = @_;
 523         # allow _complete --help to complete, not show help
 524         return 1 if substr($cmd, 0, 1) eq '_';
 525         $self->{cmd} = $cmd;
 526         $OPT = $self->{opt} //= {};
 527         my $info = $CMD{$cmd} // [ '[...]' ];
 528         my ($proto, undef, @spec) = @$info;
 529         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 530         push @spec, qw(help|h);
 531         my $lone_dash;
 532         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 533                 $lone_dash = $spec[0];
 534                 $OPT->{$spec[0]} = \(my $var);
 535                 push @spec, '' => \$var;
 536         }
 537         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 538                 return _help($self, "bad arguments or options for $cmd");
 539         return _help($self) if $OPT->{help};
 540
 541         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 542
 543         # "-" aliases "stdin" or "clear"
 544         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 545
 546         my $i = 0;
 547         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 548         my ($err, $inf);
 549         my @args = split(/ /, $proto);
 550         for my $var (@args) {
 551                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 552                         $inf = defined($argv->[$i]) and last;
 553                         $var =~ s/\.\.\.\z//;
 554                         $err = "$var not supplied";
 555                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 556                         $argv->[$i++] // ($err = "$var not supplied");
 557                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 558                         $inf = 1;
 559                         last;
 560                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 561                         $i++;
 562                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 563                         $inf = 1 if index($var, '...') > 0;
 564                         my @or = split(/\|/, $var);
 565                         my $ok;
 566                         for my $o (@or) {
 567                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 568                                         $ok = defined($OPT->{$1});
 569                                         last if $ok;
 570                                 } elsif (defined($argv->[$i])) {
 571                                         $ok = 1;
 572                                         $i++;
 573                                         last;
 574                                 } # else continue looping
 575                         }
 576                         last if $ok;
 577                         my $last = pop @or;
 578                         $err = join(', ', @or) . " or $last must be set";
 579                 } else {
 580                         warn "BUG: can't parse `$var' in $proto";
 581                 }
 582                 last if $err;
 583         }
 584         if (!$inf && scalar(@$argv) > scalar(@args)) {
 585                 $err //= 'too many arguments';
 586         }
 587         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 588 }
 589
 590 sub dispatch {
 591         my ($self, $cmd, @argv) = @_;
 592         local $current_lei = $self; # for __WARN__
 593         dump_and_clear_log("from previous run\n");
 594         return _help($self, 'no command given') unless defined($cmd);
 595         while ($cmd eq '-C') { # do not support Getopt bundling for this
 596                 my $d = shift(@argv) // return fail($self, '-C DIRECTORY');
 597                 push @{$self->{opt}->{C}}, $d;
 598                 $cmd = shift(@argv) // return _help($self, 'no command given');
 599         }
 600         my $func = "lei_$cmd";
 601         $func =~ tr/-/_/;
 602         if (my $cb = __PACKAGE__->can($func)) {
 603                 optparse($self, $cmd, \@argv) or return;
 604                 if (my $chdir = $self->{opt}->{C}) {
 605                         for my $d (@$chdir) {
 606                                 next if $d eq ''; # same as git(1)
 607                                 chdir $d or return fail($self, "cd $d: $!");
 608                         }
 609                 }
 610                 $cb->($self, @argv);
 611         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 612                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 613                         or return _help($self, 'bad arguments or options');
 614                 _help($self);
 615         } else {
 616                 fail($self, "`$cmd' is not an lei command");
 617         }
 618 }
 619
 620 sub _lei_cfg ($;$) {
 621         my ($self, $creat) = @_;
 622         my $f = _config_path($self);
 623         my @st = stat($f);
 624         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 625         my ($sto, $sto_dir);
 626         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 627                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 628                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 629         }
 630         if (!@st) {
 631                 unless ($creat) {
 632                         delete $self->{cfg};
 633                         return bless {}, 'PublicInbox::Config';
 634                 }
 635                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 636                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 637                 open my $fh, '>>', $f or die "open($f): $!\n";
 638                 @st = stat($fh) or die "fstat($f): $!\n";
 639                 $cur_st = pack('dd', $st[10], $st[7]);
 640                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 641         }
 642         my $cfg = PublicInbox::Config::git_config_dump($f);
 643         bless $cfg, 'PublicInbox::Config';
 644         $cfg->{-st} = $cur_st;
 645         $cfg->{'-f'} = $f;
 646         if ($sto && File::Spec->canonpath($sto_dir) eq
 647                         File::Spec->canonpath($cfg->{'leistore.dir'})) {
 648                 $cfg->{-lei_store} = $sto;
 649         }
 650         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 651 }
 652
 653 sub _lei_store ($;$) {
 654         my ($self, $creat) = @_;
 655         my $cfg = _lei_cfg($self, $creat);
 656         $cfg->{-lei_store} //= do {
 657                 require PublicInbox::LeiStore;
 658                 my $dir = $cfg->{'leistore.dir'};
 659                 $dir //= $creat ? store_path($self) : return;
 660                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 661         };
 662 }
 663
 664 sub lei_show {
 665         my ($self, @argv) = @_;
 666 }
 667
 668 sub lei_mark {
 669         my ($self, @argv) = @_;
 670 }
 671
 672 sub _config {
 673         my ($self, @argv) = @_;
 674         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 675         my $cfg = _lei_cfg($self, 1);
 676         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 677         my %rdr = map { $_ => $self->{$_} } (0..2);
 678         waitpid(spawn($cmd, \%env, \%rdr), 0);
 679 }
 680
 681 sub lei_config {
 682         my ($self, @argv) = @_;
 683         $self->{opt}->{'config-file'} and return fail $self,
 684                 "config file switches not supported by `lei config'";
 685         _config(@_);
 686         x_it($self, $?) if $?;
 687 }
 688
 689 sub lei_import {
 690         require PublicInbox::LeiImport;
 691         PublicInbox::LeiImport->call(@_);
 692 }
 693
 694 sub lei_convert {
 695         require PublicInbox::LeiConvert;
 696         PublicInbox::LeiConvert->call(@_);
 697 }
 698
 699 sub lei_p2q {
 700         require PublicInbox::LeiP2q;
 701         PublicInbox::LeiP2q->call(@_);
 702 }
 703
 704 sub lei_init {
 705         my ($self, $dir) = @_;
 706         my $cfg = _lei_cfg($self, 1);
 707         my $cur = $cfg->{'leistore.dir'};
 708         $dir //= store_path($self);
 709         $dir = rel2abs($self, $dir);
 710         my @cur = stat($cur) if defined($cur);
 711         $cur = File::Spec->canonpath($cur // $dir);
 712         my @dir = stat($dir);
 713         my $exists = "# leistore.dir=$cur already initialized" if @dir;
 714         if (@cur) {
 715                 if ($cur eq $dir) {
 716                         _lei_store($self, 1)->done;
 717                         return qerr($self, $exists);
 718                 }
 719
 720                 # some folks like symlinks and bind mounts :P
 721                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 722                         lei_config($self, 'leistore.dir', $dir);
 723                         _lei_store($self, 1)->done;
 724                         return qerr($self, "$exists (as $cur)");
 725                 }
 726                 return fail($self, <<"");
 727 E: leistore.dir=$cur already initialized and it is not $dir
 728
 729         }
 730         lei_config($self, 'leistore.dir', $dir);
 731         _lei_store($self, 1)->done;
 732         $exists //= "# leistore.dir=$dir newly initialized";
 733         return qerr($self, $exists);
 734 }
 735
 736 sub lei_daemon_pid { puts shift, $$ }
 737
 738 sub lei_daemon_kill {
 739         my ($self) = @_;
 740         my $sig = $self->{opt}->{signal} // 'TERM';
 741         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 742 }
 743
 744 sub lei_help { _help($_[0]) }
 745
 746 # Shell completion helper.  Used by lei-completion.bash and hopefully
 747 # other shells.  Try to do as much here as possible to avoid redundancy
 748 # and improve maintainability.
 749 sub lei__complete {
 750         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 751         shift @argv; # ignore "lei", the entire command is sent
 752         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 753         my $cmd = shift @argv;
 754         my $info = $CMD{$cmd} // do { # filter matching commands
 755                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 756                 return;
 757         };
 758         my ($proto, undef, @spec) = @$info;
 759         my $cur = pop @argv;
 760         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 761         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 762                 # gross special case since the only git-config options
 763                 # Consider moving to a table if we need more special cases
 764                 # we use Getopt::Long for are the ones we reject, so these
 765                 # are the ones we don't reject:
 766                 if ($cmd eq 'config') {
 767                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 768                         @spec = qw(add z|null get get-all unset unset-all
 769                                 replace-all get-urlmatch
 770                                 remove-section rename-section
 771                                 name-only list|l edit|e
 772                                 get-color-name get-colorbool);
 773                         # fall-through
 774                 }
 775                 # generate short/long names from Getopt::Long specs
 776                 puts $self, grep(/$re/, qw(--help -h -C), map {
 777                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 778                         } elsif (s/\+\z//) { # verbose|v+
 779                         } elsif (s/!\z//) {
 780                                 # negation: solve! => no-solve|solve
 781                                 s/([\w\-]+)/$1|no-$1/g
 782                         }
 783                         map {
 784                                 my $x = length > 1 ? "--$_" : "-$_";
 785                                 $x eq $cur ? () : $x;
 786                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 787                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 788         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 789                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 790         }
 791
 792         # switch args (e.g. lei q -f mbox<TAB>)
 793         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 794                 my $opt = quotemeta $1;
 795                 puts $self, map {
 796                         my $v = $OPTDESC{$_};
 797                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 798                         # get rid of ALL CAPS placeholder (e.g "OUT")
 799                         # (TODO: completion for external paths)
 800                         shift(@v) if uc($v[0]) eq $v[0];
 801                         @v;
 802                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 803         }
 804         $cmd =~ tr/-/_/;
 805         if (my $sub = $self->can("_complete_$cmd")) {
 806                 puts $self, $sub->($self, @argv, $cur);
 807         }
 808         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 809         # proto parsing.
 810 }
 811
 812 sub exec_buf ($$) {
 813         my ($argv, $env) = @_;
 814         my $argc = scalar @$argv;
 815         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 816         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 817         $buf;
 818 }
 819
 820 sub start_mua {
 821         my ($self) = @_;
 822         my $mua = $self->{opt}->{mua} // return;
 823         my $mfolder = $self->{ovv}->{dst};
 824         my (@cmd, $replaced);
 825         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 826                 @cmd = ($mua, '-f');
 827         # TODO: help wanted: other common FOSS MUAs
 828         } else {
 829                 require Text::ParseWords;
 830                 @cmd = Text::ParseWords::shellwords($mua);
 831                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 832                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 833         }
 834         push @cmd, $mfolder unless defined($replaced);
 835         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 836                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 837         } elsif ($self->{oneshot}) {
 838                 $self->{"pid.$self.$$"}->{spawn(\@cmd)} = \@cmd;
 839         }
 840         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 841                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 842         }
 843         $self->{opt}->{quiet} = 1;
 844         delete $self->{-progress};
 845         delete $self->{opt}->{verbose};
 846 }
 847
 848 sub send_exec_cmd { # tell script/lei to execute a command
 849         my ($self, $io, $cmd, $env) = @_;
 850         my $sock = $self->{sock} // die 'lei client gone';
 851         my $fds = [ map { fileno($_) } @$io ];
 852         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 853 }
 854
 855 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 856         my ($self) = @_;
 857         my $alerts = $self->{opt}->{alert} // return;
 858         while (my $op = shift(@$alerts)) {
 859                 if ($op eq ':WINCH') {
 860                         # hit the process group that started the MUA
 861                         if ($self->{sock}) {
 862                                 send($self->{sock}, '-WINCH', MSG_EOR);
 863                         } elsif ($self->{oneshot}) {
 864                                 kill('-WINCH', $$);
 865                         }
 866                 } elsif ($op eq ':bell') {
 867                         out($self, "\a");
 868                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 869                         push @$alerts, split(/(?<!\\),/, $op);
 870                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 871                         my $cmd = $1; # run an arbitrary command
 872                         require Text::ParseWords;
 873                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 874                         if (my $s = $self->{sock}) {
 875                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 876                         } elsif ($self->{oneshot}) {
 877                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 878                         }
 879                 } else {
 880                         err($self, "W: unsupported --alert=$op"); # non-fatal
 881                 }
 882         }
 883 }
 884
 885 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 886 $path_to_fd{"/dev/fd/$_"} = $path_to_fd{"/proc/self/fd/$_"} for (0..2);
 887 sub fopen {
 888         my ($self, $mode, $path) = @_;
 889         rel2abs($self, $path);
 890         $path =~ tr!/!/!s;
 891         if (defined(my $fd = $path_to_fd{$path})) {
 892                 return $self->{$fd};
 893         }
 894         if ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) {
 895                 return fail($self, "cannot open $path from daemon");
 896         }
 897         open my $fh, $mode, $path or return;
 898         $fh;
 899 }
 900
 901 # caller needs to "-t $self->{1}" to check if tty
 902 sub start_pager {
 903         my ($self) = @_;
 904         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 905         chomp(my $pager = <$fh> // '');
 906         close($fh) or warn "`git var PAGER' error: \$?=$?";
 907         return if $pager eq 'cat' || $pager eq '';
 908         my $new_env = { LESS => 'FRX', LV => '-c' };
 909         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 910         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 911         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 912         my $pgr = [ undef, @$rdr{1, 2} ];
 913         my $env = $self->{env};
 914         if ($self->{sock}) { # lei(1) process runs it
 915                 delete @$new_env{keys %$env}; # only set iff unset
 916                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 917         } elsif ($self->{oneshot}) {
 918                 my $cmd = [$pager];
 919                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 920         } else {
 921                 die 'BUG: start_pager w/o socket';
 922         }
 923         $self->{1} = $wpager;
 924         $self->{2} = $wpager if -t $self->{2};
 925         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 926         $self->{pgr} = $pgr;
 927 }
 928
 929 sub stop_pager {
 930         my ($self) = @_;
 931         my $pgr = delete($self->{pgr}) or return;
 932         $self->{2} = $pgr->[2];
 933         # do not restore original stdout, just close it so we error out
 934         close(delete($self->{1})) if $self->{1};
 935 }
 936
 937 sub accept_dispatch { # Listener {post_accept} callback
 938         my ($sock) = @_; # ignore other
 939         $sock->autoflush(1);
 940         my $self = bless { sock => $sock }, __PACKAGE__;
 941         vec(my $rvec = '', fileno($sock), 1) = 1;
 942         select($rvec, undef, undef, 60) or
 943                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 944         # (4096 * 33) >MAX_ARG_STRLEN
 945         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
 946         if (scalar(@fds) == 4) {
 947                 for my $i (0..3) {
 948                         my $fd = shift(@fds);
 949                         open($self->{$i}, '+<&=', $fd) and next;
 950                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 951                 }
 952         } elsif (!defined($fds[0])) {
 953                 warn(my $msg = "recv_cmd failed: $!");
 954                 return send($sock, $msg, MSG_EOR);
 955         } else {
 956                 return;
 957         }
 958         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 959         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 960         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 961         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 962                 return send($sock, 'request command truncated', MSG_EOR);
 963         my ($argc, @argv) = split(/\0/, $buf, -1);
 964         undef $buf;
 965         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 966         if (chdir($self->{3})) {
 967                 local %ENV = %env;
 968                 $self->{env} = \%env;
 969                 eval { dispatch($self, @argv) };
 970                 send($sock, $@, MSG_EOR) if $@;
 971         } else {
 972                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 973         }
 974 }
 975
 976 sub dclose {
 977         my ($self) = @_;
 978         delete $self->{-progress};
 979         for my $f (@WQ_KEYS) {
 980                 my $wq = delete $self->{$f} or next;
 981                 if ($wq->wq_kill) {
 982                         $wq->wq_close(0, undef, $self);
 983                 } elsif ($wq->wq_kill_old) {
 984                         $wq->wq_wait_old(undef, $self);
 985                 }
 986         }
 987         close(delete $self->{1}) if $self->{1}; # may reap_compress
 988         if (my $sto = delete $self->{sto}) {
 989                 $sto->ipc_do('done');
 990         }
 991         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
 992 }
 993
 994 # for long-running results
 995 sub event_step {
 996         my ($self) = @_;
 997         local %ENV = %{$self->{env}};
 998         my $sock = $self->{sock};
 999         local $current_lei = $self;
1000         eval {
1001                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1002                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1003                                 return if $! == EAGAIN;
1004                                 next if $! == EINTR;
1005                                 last if $! == ECONNRESET;
1006                                 die "recvmsg: $!";
1007                         }
1008                         for my $fd (@fds) {
1009                                 open my $rfh, '+<&=', $fd;
1010                         }
1011                         die "unrecognized client signal: $buf";
1012                 }
1013                 dclose($self);
1014         };
1015         if (my $err = $@) {
1016                 eval { $self->fail($err) };
1017                 dclose($self);
1018         }
1019 }
1020
1021 sub event_step_init {
1022         my ($self) = @_;
1023         return if $self->{-event_init_done}++;
1024         if (my $sock = $self->{sock}) { # using DS->EventLoop
1025                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1026         }
1027 }
1028
1029 sub noop {}
1030
1031 sub oldset { $oldset }
1032
1033 sub dump_and_clear_log {
1034         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1035                 my @pfx = @_;
1036                 unshift(@pfx, "$errors_log ") if @pfx;
1037                 warn @pfx, do { local $/; <STDIN> };
1038                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1039         }
1040 }
1041
1042 # lei(1) calls this when it can't connect
1043 sub lazy_start {
1044         my ($path, $errno, $narg) = @_;
1045         local ($errors_log, $listener);
1046         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1047         $errors_log .= 'errors.log';
1048         my $addr = pack_sockaddr_un($path);
1049         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1050         $lk->lock_acquire;
1051         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1052         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1053                 return if connect($listener, $addr); # another process won
1054                 if ($errno == ECONNREFUSED && -S $path) {
1055                         unlink($path) or die "unlink($path): $!";
1056                 }
1057         } else {
1058                 $! = $errno; # allow interpolation to stringify in die
1059                 die "connect($path): $!";
1060         }
1061         umask(077) // die("umask(077): $!");
1062         bind($listener, $addr) or die "bind($path): $!";
1063         listen($listener, 1024) or die "listen: $!";
1064         $lk->lock_release;
1065         undef $lk;
1066         my @st = stat($path) or die "stat($path): $!";
1067         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1068         local $oldset = PublicInbox::DS::block_signals();
1069         if ($narg == 5) {
1070                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1071                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1072                         require PublicInbox::CmdIPC4;
1073                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1074                         PublicInbox::CmdIPC4->can('recv_cmd4');
1075                 };
1076         }
1077         $recv_cmd or die <<"";
1078 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1079
1080         require PublicInbox::Listener;
1081         require PublicInbox::EOFpipe;
1082         (-p STDOUT) or die "E: stdout must be a pipe\n";
1083         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1084         STDIN->autoflush(1);
1085         dump_and_clear_log("from previous daemon process:\n");
1086         POSIX::setsid() > 0 or die "setsid: $!";
1087         my $pid = fork // die "fork: $!";
1088         return if $pid;
1089         $0 = "lei-daemon $path";
1090         local %PATH2CFG;
1091         $listener->blocking(0);
1092         my $exit_code;
1093         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1094         local $quit = do {
1095                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1096                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1097                 sub {
1098                         $exit_code //= shift;
1099                         my $lis = $pil or exit($exit_code);
1100                         # closing eof_w triggers \&noop wakeup
1101                         $listener = $eof_w = $pil = $path = undef;
1102                         $lis->close; # DS::close
1103                         PublicInbox::DS->SetLoopTimeout(1000);
1104                 };
1105         };
1106         my $sig = {
1107                 CHLD => \&PublicInbox::DS::enqueue_reap,
1108                 QUIT => $quit,
1109                 INT => $quit,
1110                 TERM => $quit,
1111                 HUP => \&noop,
1112                 USR1 => \&noop,
1113                 USR2 => \&noop,
1114         };
1115         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1116         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1117         undef $sig;
1118         local $SIG{PIPE} = 'IGNORE';
1119         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1120                 undef $sigfd;
1121                 PublicInbox::DS->SetLoopTimeout(5000);
1122         } else {
1123                 # wake up every second to accept signals if we don't
1124                 # have signalfd or IO::KQueue:
1125                 PublicInbox::DS::sig_setmask($oldset);
1126                 PublicInbox::DS->SetLoopTimeout(1000);
1127         }
1128         PublicInbox::DS->SetPostLoopCallback(sub {
1129                 my ($dmap, undef) = @_;
1130                 if (@st = defined($path) ? stat($path) : ()) {
1131                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1132                                 warn "$path dev/ino changed, quitting\n";
1133                                 $path = undef;
1134                         }
1135                 } elsif (defined($path)) { # ENOENT is common
1136                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1137                         undef $path;
1138                         $quit->();
1139                 }
1140                 return 1 if defined($path);
1141                 my $now = now();
1142                 my $n = 0;
1143                 for my $s (values %$dmap) {
1144                         $s->can('busy') or next;
1145                         if ($s->busy($now)) {
1146                                 ++$n;
1147                         } else {
1148                                 $s->close;
1149                         }
1150                 }
1151                 $n; # true: continue, false: stop
1152         });
1153
1154         # STDIN was redirected to /dev/null above, closing STDERR and
1155         # STDOUT will cause the calling `lei' client process to finish
1156         # reading the <$daemon> pipe.
1157         local $SIG{__WARN__} = sub {
1158                 $current_lei ? err($current_lei, @_) : warn(
1159                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1160         };
1161         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1162         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1163         # $daemon pipe to `lei' closed, main loop begins:
1164         PublicInbox::DS->EventLoop;
1165         exit($exit_code // 0);
1166 }
1167
1168 sub busy { 1 } # prevent daemon-shutdown if client is connected
1169
1170 # for users w/o Socket::Msghdr installed or Inline::C enabled
1171 sub oneshot {
1172         my ($main_pkg) = @_;
1173         my $exit = $main_pkg->can('exit'); # caller may override exit()
1174         local $quit = $exit if $exit;
1175         local %PATH2CFG;
1176         umask(077) // die("umask(077): $!");
1177         my $self = bless {
1178                 oneshot => 1,
1179                 0 => *STDIN{GLOB},
1180                 1 => *STDOUT{GLOB},
1181                 2 => *STDERR{GLOB},
1182                 env => \%ENV
1183         }, __PACKAGE__;
1184         dispatch($self, @ARGV);
1185         x_it($self, $self->{child_error}) if $self->{child_error};
1186 }
1187
1188 # ensures stdout hits the FS before sock disconnects so a client
1189 # can immediately reread it
1190 sub DESTROY {
1191         my ($self) = @_;
1192         $self->{1}->autoflush(1) if $self->{1};
1193         stop_pager($self);
1194         my $err = $?;
1195         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1196         waitpid($_, 0) for keys %$oneshot_pids;
1197         $? = $err if $err; # preserve ->fail or ->x_it code
1198 }
1199
1200 1;