lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use Time::HiRes qw(stat); # ctime comparisons for config cache
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log, $listener, $oldset);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub rel2abs ($$) {
  68         my ($self, $p) = @_;
  69         return $p if index($p, '/') == 0; # already absolute
  70         my $pwd = $self->{env}->{PWD};
  71         if (defined $pwd) {
  72                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  73                 if (my @st_pwd = stat($pwd)) {
  74                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  75                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  76                                 $self->{env}->{PWD} = $pwd = $cwd;
  77                 } else { # PWD was invalid
  78                         delete $self->{env}->{PWD};
  79                         undef $pwd;
  80                 }
  81         }
  82         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  83         File::Spec->rel2abs($p, $pwd);
  84 }
  85
  86 sub store_path ($) {
  87         my ($self) = @_;
  88         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  89                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  90                 .'/lei/store');
  91 }
  92
  93 sub _config_path ($) {
  94         my ($self) = @_;
  95         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  96                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  97                 .'/lei/config');
  98 }
  99
 100 sub cache_dir ($) {
 101         my ($self) = @_;
 102         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 103                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 104                 .'/lei');
 105 }
 106
 107 sub ale {
 108         my ($self) = @_;
 109         $self->{ale} //= do {
 110                 require PublicInbox::LeiALE;
 111                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 112         };
 113 }
 114
 115 sub index_opt {
 116         # TODO: drop underscore variants everywhere, they're undocumented
 117         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 118         max_size|max-size=s sequential_shard|sequential-shard
 119         batch_size|batch-size=s skip-docdata)
 120 }
 121
 122 my @c_opt = qw(c=s@ C=s@ quiet|q);
 123
 124 # we generate shell completion + help using %CMD and %OPTDESC,
 125 # see lei__complete() and PublicInbox::LeiHelp
 126 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 127 our %CMD = ( # sorted in order of importance/use:
 128 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 129         'stdin|', # /|\z/ must be first for lone dash
 130         qw(save-as=s output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 131         sort|s=s reverse|r offset=i remote! local! external! pretty
 132         include|I=s@ exclude=s@ only=s@ jobs|j=s globoff|g augment|a
 133         import-remote! import-before! lock=s@ rsyncable
 134         alert=s@ mua=s no-torsocks torsocks=s verbose|v+), @c_opt,
 135         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 136
 137 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 138         qw(type=s solve! format|f=s dedupe|d=s threads|t remote local!
 139         verbose|v+), @c_opt, pass_through('git show') ],
 140
 141 'add-external' => [ 'LOCATION',
 142         'add/set priority of a publicinbox|extindex for extra matches',
 143         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 144         verbose|v+), @c_opt, index_opt(),
 145         PublicInbox::LeiQuery::curl_opt() ],
 146 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 147         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 148 'forget-external' => [ 'LOCATION...|--prune',
 149         'exclude further results from a publicinbox|extindex',
 150         qw(prune), @c_opt ],
 151
 152 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 153                 qw(name-only format|f=s), @c_opt ],
 154 'rm-query' => [ 'QUERY_NAME', 'remove a saved search', @c_opt ],
 155 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search', @c_opt ],
 156
 157 'plonk' => [ '--threads|--from=IDENT',
 158         'exclude mail matching From: or threads from non-Message-ID searches',
 159         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 160 'mark' => [ 'MESSAGE_FLAGS...',
 161         'set/unset keywords on message(s) from stdin',
 162         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 163 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 164         "exclude message(s) on stdin from `q' search results",
 165         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 166
 167 'purge-mailsource' => [ 'LOCATION|--all',
 168         'remove imported messages from IMAP, Maildirs, and MH',
 169         qw(exact! all jobs:i indexed), @c_opt ],
 170
 171 # code repos are used for `show' to solve blobs from patch mails
 172 'add-coderepo' => [ 'DIRNAME', 'add or set priority of a git code repo',
 173         qw(boost=i), @c_opt ],
 174 'ls-coderepo' => [ '[FILTER_TERMS...]',
 175                 'list known code repos', qw(format|f=s z), @c_opt ],
 176 'forget-coderepo' => [ 'DIRNAME',
 177         'stop using repo to solve blobs from patches',
 178         qw(prune), @c_opt ],
 179
 180 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 181         qw(import! kw|keywords|flags! interval=s recursive|r
 182         exclude=s include=s), @c_opt ],
 183 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 184                 qw(format|f=s z), @c_opt ],
 185 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 186 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 187 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 188         qw(prune), @c_opt ],
 189
 190 'import' => [ 'LOCATION...|--stdin',
 191         'one-time import/update from URL or filesystem',
 192         qw(stdin| offset=i recursive|r exclude=s include|I=s
 193         lock=s@ in-format|F=s kw|keywords|flags! verbose|v+), @c_opt ],
 194 'convert' => [ 'LOCATION...|--stdin',
 195         'one-time conversion from URL or filesystem to another format',
 196         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s
 197         lock=s@ kw|keywords|flags!), @c_opt ],
 198 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 199         "use a patch to generate a query for `lei q --stdin'",
 200         qw(stdin| want|w=s@ uri debug), @c_opt ],
 201 'config' => [ '[...]', sub {
 202                 'git-config(1) wrapper for '._config_path($_[0]);
 203         }, qw(config-file|system|global|file|f=s), # for conflict detection
 204          qw(c=s@ C=s@), pass_through('git config') ],
 205 'init' => [ '[DIRNAME]', sub {
 206         "initialize storage, default: ".store_path($_[0]);
 207         }, @c_opt ],
 208 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 209         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 210         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 211 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 212 'help' => [ '[SUBCOMMAND]', 'show help' ],
 213
 214 # XXX do we need this?
 215 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 216
 217 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 218         'rewrite git history in an attempt to improve compression',
 219         qw(gc!), @c_opt ],
 220
 221 # internal commands are prefixed with '_'
 222 '_complete' => [ '[...]', 'internal shell completion helper',
 223                 pass_through('everything') ],
 224 ); # @CMD
 225
 226 # switch descriptions, try to keep consistent across commands
 227 # $spec: Getopt::Long option specification
 228 # $spec => [@ALLOWED_VALUES (default is first), $description],
 229 # $spec => $description
 230 # "$SUB_COMMAND TAB $spec" => as above
 231 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 232                         'specify message input format' ];
 233 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 234
 235 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 236 my %OPTDESC = (
 237 'help|h' => 'show this built-in help',
 238 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 239 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 240 'quiet|q' => 'be quiet',
 241 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 242         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 243
 244 'globoff|g' => "do not match locations using '*?' wildcards ".
 245                 "and\xa0'[]'\x{a0}ranges",
 246 'verbose|v+' => 'be more verbose',
 247 'external!' => 'do not use externals',
 248 'solve!' => 'do not attempt to reconstruct blobs from emails',
 249 'torsocks=s' => ['VAL|auto|no|yes',
 250                 'whether or not to wrap git and curl commands with torsocks'],
 251 'no-torsocks' => 'alias for --torsocks=no',
 252 'save-as=s' => ['NAME', 'save a search terms by given name'],
 253 'import-remote!' => 'do not memoize remote messages into local store',
 254
 255 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 256
 257 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 258                 'deduplication strategy'],
 259 'threads|t+' =>
 260         'return all messages in the same threads as the actual match(es)',
 261
 262 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 263                 'search prefixes to extract (default: dfpost7)' ],
 264
 265 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 266         'run command(s) or perform ops when done writing to output ' .
 267         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 268         'nothing otherwise)' ],
 269
 270 'augment|a' => 'augment --output destination instead of clobbering',
 271
 272 'output|mfolder|o=s' => [ 'MFOLDER',
 273         "destination (e.g.\xa0`/path/to/Maildir', ".
 274         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 275 'mua=s' => [ 'CMD',
 276         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 277
 278 'inbox-version=i' => [ 'NUM|1|2',
 279                 'force a public-inbox version with --mirror'],
 280 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 281
 282 # public-inbox-index options
 283 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 284 'compact' => 'run compact index after mirroring',
 285 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 286         "indexlevel with --mirror (default: full)" ],
 287 'max_size|max-size=s' => [ 'SIZE',
 288         'do not index messages larger than SIZE (default: infinity)' ],
 289 'batch_size|batch-size=s' => [ 'SIZE',
 290         'flush changes to OS after given number of bytes (default: 1m)' ],
 291 'sequential_shard|sequential-shard' =>
 292         'index Xapian shards sequentially for slow storage',
 293 'skip-docdata' =>
 294         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 295
 296 'format|f=s     q' => [
 297         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 298                 'specify output format, default depends on --output'],
 299 'exclude=s@     q' => [ 'LOCATION',
 300                 'exclude specified external(s) from search' ],
 301 'include|I=s@   q' => [ 'LOCATION',
 302                 'include specified external(s) in search' ],
 303 'only=s@        q' => [ 'LOCATION',
 304                 'only use specified external(s) for search' ],
 305 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 306                 'control number of search and writer jobs' ],
 307 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 308
 309 'in-format|F=s' => $stdin_formats,
 310 'format|f=s     ls-query' => $ls_format,
 311 'format|f=s     ls-external' => $ls_format,
 312
 313 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 314 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 315
 316 'sort|s=s' => [ 'VAL|received|relevance|docid',
 317                 "order of results is `--output'-dependent"],
 318 'reverse|r' => 'reverse search results', # like sort(1)
 319
 320 'boost=i' => 'increase/decrease priority of results (default: 0)',
 321
 322 'local' => 'limit operations to the local filesystem',
 323 'local!' => 'exclude results from the local filesystem',
 324 'remote' => 'limit operations to those requiring network access',
 325 'remote!' => 'prevent operations requiring network access',
 326
 327 'mid=s' => 'specify the Message-ID of a message',
 328 'oid=s' => 'specify the git object ID of a message',
 329
 330 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 331 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 332 'include=s' => 'include mailboxes/newsgroups based on pattern',
 333
 334 'exact' => 'operate on exact header matches only',
 335 'exact!' => 'rely on content match instead of exact header matches',
 336
 337 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 338
 339 'kw|keywords|flags!' => 'disable/enable importing flags',
 340
 341 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 342 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 343
 344 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 345 ); # %OPTDESC
 346
 347 my %CONFIG_KEYS = (
 348         'leistore.dir' => 'top-level storage location',
 349 );
 350
 351 my @WQ_KEYS = qw(lxs l2m imp mrr cnv p2q); # internal workers
 352
 353 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 354 sub x_it ($$) {
 355         my ($self, $code) = @_;
 356         # make sure client sees stdout before exit
 357         $self->{1}->autoflush(1) if $self->{1};
 358         dump_and_clear_log();
 359         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 360                 send($s, "x_it $code", MSG_EOR);
 361         } elsif ($self->{oneshot}) {
 362                 # don't want to end up using $? from child processes
 363                 for my $f (@WQ_KEYS) {
 364                         my $wq = delete $self->{$f} or next;
 365                         $wq->DESTROY;
 366                 }
 367                 # cleanup anything that has tempfiles or open file handles
 368                 %PATH2CFG = ();
 369                 delete @$self{qw(ovv dedupe sto cfg)};
 370                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 371                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 372                         kill $signum, $$;
 373                         sleep(1) while 1; # wait for signal
 374                 } else {
 375                         $quit->($code >> 8);
 376                 }
 377         } # else ignore if client disconnected
 378 }
 379
 380 sub err ($;@) {
 381         my $self = shift;
 382         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 383         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 384         print $err @_, @eor and return;
 385         my $old_err = delete $self->{2};
 386         close($old_err) if $! == EPIPE && $old_err;
 387         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 388         print $err @_, @eor or print STDERR @_, @eor;
 389 }
 390
 391 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 392
 393 sub fail_handler ($;$$) {
 394         my ($lei, $code, $io) = @_;
 395         for my $f (@WQ_KEYS) {
 396                 my $wq = delete $lei->{$f} or next;
 397                 $wq->wq_wait_old(undef, $lei) if $wq->wq_kill_old; # lei-daemon
 398         }
 399         close($io) if $io; # needed to avoid warnings on SIGPIPE
 400         x_it($lei, $code // (1 << 8));
 401 }
 402
 403 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 404         fail_handler($_[0], 13, delete $_[0]->{1});
 405 }
 406
 407 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 408 sub sigint_reap {
 409         my ($pgid) = @_;
 410         dwaitpid($pgid) if kill('-INT', $pgid);
 411 }
 412
 413 sub fail ($$;$) {
 414         my ($self, $buf, $exit_code) = @_;
 415         err($self, $buf) if defined $buf;
 416         # calls fail_handler:
 417         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 418         x_it($self, ($exit_code // 1) << 8);
 419         undef;
 420 }
 421
 422 sub out ($;@) {
 423         my $self = shift;
 424         return if print { $self->{1} // return } @_; # likely
 425         return note_sigpipe($self, 1) if $! == EPIPE;
 426         my $err = "error writing to output: $!";
 427         delete $self->{1};
 428         fail($self, $err);
 429 }
 430
 431 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 432
 433 sub child_error { # passes non-fatal curl exit codes to user
 434         my ($self, $child_error, $msg) = @_; # child_error is $?
 435         $self->err($msg) if $msg;
 436         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 437                 # send to the parent lei-daemon or to lei(1) client
 438                 send($s, "child_error $child_error", MSG_EOR);
 439         } elsif (!$PublicInbox::DS::in_loop) {
 440                 $self->{child_error} = $child_error;
 441         } # else noop if client disconnected
 442 }
 443
 444 sub note_sigpipe { # triggers sigpipe_handler
 445         my ($self, $fd) = @_;
 446         close(delete($self->{$fd})); # explicit close silences Perl warning
 447         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 448         x_it($self, 13);
 449 }
 450
 451 sub lei_atfork_child {
 452         my ($self, $persist) = @_;
 453         # we need to explicitly close things which are on stack
 454         if ($persist) {
 455                 my @io = delete @$self{qw(0 1 2 sock)};
 456                 unless ($self->{oneshot}) {
 457                         close($_) for @io;
 458                 }
 459         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 460                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 461                 delete $self->{0};
 462         }
 463         delete @$self{qw(cnv)};
 464         for (delete @$self{qw(3 old_1 au_done)}) {
 465                 close($_) if defined($_);
 466         }
 467         if (my $op_c = delete $self->{pkt_op_c}) {
 468                 close(delete $op_c->{sock});
 469         }
 470         if (my $pgr = delete $self->{pgr}) {
 471                 close($_) for (@$pgr[1,2]);
 472         }
 473         close $listener if $listener;
 474         undef $listener;
 475         %PATH2CFG = ();
 476         undef $errors_log;
 477         $quit = \&CORE::exit;
 478         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 479 }
 480
 481 sub workers_start {
 482         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 483         $ops = {
 484                 '!' => [ \&fail_handler, $lei ],
 485                 '|' => [ \&sigpipe_handler, $lei ],
 486                 'x_it' => [ \&x_it, $lei ],
 487                 'child_error' => [ \&child_error, $lei ],
 488                 ($ops ? %$ops : ()),
 489         };
 490         $ops->{''} //= [ \&dclose, $lei ];
 491         require PublicInbox::PktOp;
 492         ($lei->{pkt_op_c}, $lei->{pkt_op_p}) = PublicInbox::PktOp->pair($ops);
 493         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 494         delete $lei->{pkt_op_p};
 495         my $op = delete $lei->{pkt_op_c};
 496         $lei->event_step_init;
 497         # oneshot needs $op, daemon-mode uses DS->EventLoop to handle $op
 498         $lei->{oneshot} ? $op : undef;
 499 }
 500
 501 sub _help {
 502         require PublicInbox::LeiHelp;
 503         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 504 }
 505
 506 sub optparse ($$$) {
 507         my ($self, $cmd, $argv) = @_;
 508         # allow _complete --help to complete, not show help
 509         return 1 if substr($cmd, 0, 1) eq '_';
 510         $self->{cmd} = $cmd;
 511         $OPT = $self->{opt} //= {};
 512         my $info = $CMD{$cmd} // [ '[...]' ];
 513         my ($proto, undef, @spec) = @$info;
 514         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 515         push @spec, qw(help|h);
 516         my $lone_dash;
 517         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 518                 $lone_dash = $spec[0];
 519                 $OPT->{$spec[0]} = \(my $var);
 520                 push @spec, '' => \$var;
 521         }
 522         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 523                 return _help($self, "bad arguments or options for $cmd");
 524         return _help($self) if $OPT->{help};
 525
 526         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 527
 528         # "-" aliases "stdin" or "clear"
 529         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 530
 531         my $i = 0;
 532         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 533         my ($err, $inf);
 534         my @args = split(/ /, $proto);
 535         for my $var (@args) {
 536                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 537                         $inf = defined($argv->[$i]) and last;
 538                         $var =~ s/\.\.\.\z//;
 539                         $err = "$var not supplied";
 540                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 541                         $argv->[$i++] // ($err = "$var not supplied");
 542                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 543                         $inf = 1;
 544                         last;
 545                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 546                         $i++;
 547                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 548                         $inf = 1 if index($var, '...') > 0;
 549                         my @or = split(/\|/, $var);
 550                         my $ok;
 551                         for my $o (@or) {
 552                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 553                                         $ok = defined($OPT->{$1});
 554                                         last if $ok;
 555                                 } elsif (defined($argv->[$i])) {
 556                                         $ok = 1;
 557                                         $i++;
 558                                         last;
 559                                 } # else continue looping
 560                         }
 561                         last if $ok;
 562                         my $last = pop @or;
 563                         $err = join(', ', @or) . " or $last must be set";
 564                 } else {
 565                         warn "BUG: can't parse `$var' in $proto";
 566                 }
 567                 last if $err;
 568         }
 569         if (!$inf && scalar(@$argv) > scalar(@args)) {
 570                 $err //= 'too many arguments';
 571         }
 572         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 573 }
 574
 575 sub _tmp_cfg { # for lei -c <name>=<value> ...
 576         my ($self) = @_;
 577         my $cfg = _lei_cfg($self, 1);
 578         require File::Temp;
 579         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 580         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 581         $ft->autoflush(1);
 582         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 583 [include]
 584         path = $cfg->{-f}
 585 EOM
 586         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 587         for (@{$self->{opt}->{c}}) {
 588                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 589 `-c $_' is not of the form -c <name>=<value>'
 590 EOM
 591                 my $name = $1;
 592                 my $value = $2 // 1;
 593                 _config($self, '--add', $name, $value);
 594                 if (defined(my $v = $tmp->{$name})) {
 595                         if (ref($v) eq 'ARRAY') {
 596                                 push @$v, $value;
 597                         } else {
 598                                 $tmp->{$name} = [ $v, $value ];
 599                         }
 600                 } else {
 601                         $tmp->{$name} = $value;
 602                 }
 603         }
 604 }
 605
 606 sub dispatch {
 607         my ($self, $cmd, @argv) = @_;
 608         local $current_lei = $self; # for __WARN__
 609         dump_and_clear_log("from previous run\n");
 610         return _help($self, 'no command given') unless defined($cmd);
 611         # do not support Getopt bundling for this
 612         while ($cmd eq '-C' || $cmd eq '-c') {
 613                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 614                                         '-C DIRECTORY' : '-c <name>=<value>');
 615                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 616                 $cmd = shift(@argv) // return _help($self, 'no command given');
 617         }
 618         my $func = "lei_$cmd";
 619         $func =~ tr/-/_/;
 620         my $cb = __PACKAGE__->can($func) // ($CMD{$cmd} ? do {
 621                 my $mod = "PublicInbox::Lei\u$cmd";
 622                 ($INC{"PublicInbox/Lei\u$cmd.pm"} //
 623                         eval("require $mod")) ? $mod->can($func) : undef;
 624         } : undef);
 625         if ($cb) {
 626                 optparse($self, $cmd, \@argv) or return;
 627                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 628                 if (my $chdir = $self->{opt}->{C}) {
 629                         for my $d (@$chdir) {
 630                                 next if $d eq ''; # same as git(1)
 631                                 chdir $d or return fail($self, "cd $d: $!");
 632                         }
 633                 }
 634                 $cb->($self, @argv);
 635         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 636                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 637                         or return _help($self, 'bad arguments or options');
 638                 _help($self);
 639         } else {
 640                 fail($self, "`$cmd' is not an lei command");
 641         }
 642 }
 643
 644 sub _lei_cfg ($;$) {
 645         my ($self, $creat) = @_;
 646         return $self->{cfg} if $self->{cfg};
 647         my $f = _config_path($self);
 648         my @st = stat($f);
 649         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 650         my ($sto, $sto_dir);
 651         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 652                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 653                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 654         }
 655         if (!@st) {
 656                 unless ($creat) {
 657                         delete $self->{cfg};
 658                         return bless {}, 'PublicInbox::Config';
 659                 }
 660                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 661                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 662                 open my $fh, '>>', $f or die "open($f): $!\n";
 663                 @st = stat($fh) or die "fstat($f): $!\n";
 664                 $cur_st = pack('dd', $st[10], $st[7]);
 665                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 666         }
 667         my $cfg = PublicInbox::Config::git_config_dump($f);
 668         bless $cfg, 'PublicInbox::Config';
 669         $cfg->{-st} = $cur_st;
 670         $cfg->{'-f'} = $f;
 671         if ($sto && File::Spec->canonpath($sto_dir) eq
 672                         File::Spec->canonpath($cfg->{'leistore.dir'})) {
 673                 $cfg->{-lei_store} = $sto;
 674         }
 675         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 676 }
 677
 678 sub _lei_store ($;$) {
 679         my ($self, $creat) = @_;
 680         my $cfg = _lei_cfg($self, $creat);
 681         $cfg->{-lei_store} //= do {
 682                 require PublicInbox::LeiStore;
 683                 my $dir = $cfg->{'leistore.dir'};
 684                 $dir //= $creat ? store_path($self) : return;
 685                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 686         };
 687 }
 688
 689 sub lei_show {
 690         my ($self, @argv) = @_;
 691 }
 692
 693 sub lei_mark {
 694         my ($self, @argv) = @_;
 695 }
 696
 697 sub _config {
 698         my ($self, @argv) = @_;
 699         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 700         my $cfg = _lei_cfg($self, 1);
 701         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 702         my %rdr = map { $_ => $self->{$_} } (0..2);
 703         waitpid(spawn($cmd, \%env, \%rdr), 0);
 704 }
 705
 706 sub lei_config {
 707         my ($self, @argv) = @_;
 708         $self->{opt}->{'config-file'} and return fail $self,
 709                 "config file switches not supported by `lei config'";
 710         _config(@_);
 711         x_it($self, $?) if $?;
 712 }
 713
 714 sub lei_init {
 715         my ($self, $dir) = @_;
 716         my $cfg = _lei_cfg($self, 1);
 717         my $cur = $cfg->{'leistore.dir'};
 718         $dir //= store_path($self);
 719         $dir = rel2abs($self, $dir);
 720         my @cur = stat($cur) if defined($cur);
 721         $cur = File::Spec->canonpath($cur // $dir);
 722         my @dir = stat($dir);
 723         my $exists = "# leistore.dir=$cur already initialized" if @dir;
 724         if (@cur) {
 725                 if ($cur eq $dir) {
 726                         _lei_store($self, 1)->done;
 727                         return qerr($self, $exists);
 728                 }
 729
 730                 # some folks like symlinks and bind mounts :P
 731                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 732                         lei_config($self, 'leistore.dir', $dir);
 733                         _lei_store($self, 1)->done;
 734                         return qerr($self, "$exists (as $cur)");
 735                 }
 736                 return fail($self, <<"");
 737 E: leistore.dir=$cur already initialized and it is not $dir
 738
 739         }
 740         lei_config($self, 'leistore.dir', $dir);
 741         _lei_store($self, 1)->done;
 742         $exists //= "# leistore.dir=$dir newly initialized";
 743         return qerr($self, $exists);
 744 }
 745
 746 sub lei_daemon_pid { puts shift, $$ }
 747
 748 sub lei_daemon_kill {
 749         my ($self) = @_;
 750         my $sig = $self->{opt}->{signal} // 'TERM';
 751         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 752 }
 753
 754 sub lei_help { _help($_[0]) }
 755
 756 # Shell completion helper.  Used by lei-completion.bash and hopefully
 757 # other shells.  Try to do as much here as possible to avoid redundancy
 758 # and improve maintainability.
 759 sub lei__complete {
 760         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 761         shift @argv; # ignore "lei", the entire command is sent
 762         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 763         my $cmd = shift @argv;
 764         my $info = $CMD{$cmd} // do { # filter matching commands
 765                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 766                 return;
 767         };
 768         my ($proto, undef, @spec) = @$info;
 769         my $cur = pop @argv;
 770         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 771         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 772                 # gross special case since the only git-config options
 773                 # Consider moving to a table if we need more special cases
 774                 # we use Getopt::Long for are the ones we reject, so these
 775                 # are the ones we don't reject:
 776                 if ($cmd eq 'config') {
 777                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 778                         @spec = qw(add z|null get get-all unset unset-all
 779                                 replace-all get-urlmatch
 780                                 remove-section rename-section
 781                                 name-only list|l edit|e
 782                                 get-color-name get-colorbool);
 783                         # fall-through
 784                 }
 785                 # generate short/long names from Getopt::Long specs
 786                 puts $self, grep(/$re/, qw(--help -h -C), map {
 787                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 788                         } elsif (s/\+\z//) { # verbose|v+
 789                         } elsif (s/!\z//) {
 790                                 # negation: solve! => no-solve|solve
 791                                 s/([\w\-]+)/$1|no-$1/g
 792                         }
 793                         map {
 794                                 my $x = length > 1 ? "--$_" : "-$_";
 795                                 $x eq $_cur ? () : $x;
 796                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 797                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 798         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 799                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 800         }
 801
 802         # switch args (e.g. lei q -f mbox<TAB>)
 803         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 804                 my $opt = quotemeta $1;
 805                 puts $self, map {
 806                         my $v = $OPTDESC{$_};
 807                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 808                         # get rid of ALL CAPS placeholder (e.g "OUT")
 809                         # (TODO: completion for external paths)
 810                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 811                         @v;
 812                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 813         }
 814         $cmd =~ tr/-/_/;
 815         if (my $sub = $self->can("_complete_$cmd")) {
 816                 puts $self, $sub->($self, @argv, $cur ? ($cur) : ());
 817         }
 818         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 819         # proto parsing.
 820 }
 821
 822 sub exec_buf ($$) {
 823         my ($argv, $env) = @_;
 824         my $argc = scalar @$argv;
 825         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 826         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 827         $buf;
 828 }
 829
 830 sub start_mua {
 831         my ($self) = @_;
 832         my $mua = $self->{opt}->{mua} // return;
 833         my $mfolder = $self->{ovv}->{dst};
 834         my (@cmd, $replaced);
 835         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 836                 @cmd = ($mua, '-f');
 837         # TODO: help wanted: other common FOSS MUAs
 838         } else {
 839                 require Text::ParseWords;
 840                 @cmd = Text::ParseWords::shellwords($mua);
 841                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 842                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 843         }
 844         push @cmd, $mfolder unless defined($replaced);
 845         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 846                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 847         } elsif ($self->{oneshot}) {
 848                 $self->{"pid.$self.$$"}->{spawn(\@cmd)} = \@cmd;
 849         }
 850         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 851                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 852         }
 853         $self->{opt}->{quiet} = 1;
 854         delete $self->{-progress};
 855         delete $self->{opt}->{verbose};
 856 }
 857
 858 sub send_exec_cmd { # tell script/lei to execute a command
 859         my ($self, $io, $cmd, $env) = @_;
 860         my $sock = $self->{sock} // die 'lei client gone';
 861         my $fds = [ map { fileno($_) } @$io ];
 862         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 863 }
 864
 865 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 866         my ($self) = @_;
 867         my $alerts = $self->{opt}->{alert} // return;
 868         while (my $op = shift(@$alerts)) {
 869                 if ($op eq ':WINCH') {
 870                         # hit the process group that started the MUA
 871                         if ($self->{sock}) {
 872                                 send($self->{sock}, '-WINCH', MSG_EOR);
 873                         } elsif ($self->{oneshot}) {
 874                                 kill('-WINCH', $$);
 875                         }
 876                 } elsif ($op eq ':bell') {
 877                         out($self, "\a");
 878                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 879                         push @$alerts, split(/(?<!\\),/, $op);
 880                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 881                         my $cmd = $1; # run an arbitrary command
 882                         require Text::ParseWords;
 883                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 884                         if (my $s = $self->{sock}) {
 885                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 886                         } elsif ($self->{oneshot}) {
 887                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 888                         }
 889                 } else {
 890                         err($self, "W: unsupported --alert=$op"); # non-fatal
 891                 }
 892         }
 893 }
 894
 895 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 896 $path_to_fd{"/dev/fd/$_"} = $path_to_fd{"/proc/self/fd/$_"} for (0..2);
 897 sub fopen {
 898         my ($self, $mode, $path) = @_;
 899         rel2abs($self, $path);
 900         $path =~ tr!/!/!s;
 901         if (defined(my $fd = $path_to_fd{$path})) {
 902                 return $self->{$fd};
 903         }
 904         if ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) {
 905                 return fail($self, "cannot open $path from daemon");
 906         }
 907         open my $fh, $mode, $path or return;
 908         $fh;
 909 }
 910
 911 # caller needs to "-t $self->{1}" to check if tty
 912 sub start_pager {
 913         my ($self) = @_;
 914         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 915         chomp(my $pager = <$fh> // '');
 916         close($fh) or warn "`git var PAGER' error: \$?=$?";
 917         return if $pager eq 'cat' || $pager eq '';
 918         my $new_env = { LESS => 'FRX', LV => '-c' };
 919         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 920         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 921         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 922         my $pgr = [ undef, @$rdr{1, 2} ];
 923         my $env = $self->{env};
 924         if ($self->{sock}) { # lei(1) process runs it
 925                 delete @$new_env{keys %$env}; # only set iff unset
 926                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 927         } elsif ($self->{oneshot}) {
 928                 my $cmd = [$pager];
 929                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 930         } else {
 931                 die 'BUG: start_pager w/o socket';
 932         }
 933         $self->{1} = $wpager;
 934         $self->{2} = $wpager if -t $self->{2};
 935         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 936         $self->{pgr} = $pgr;
 937 }
 938
 939 sub stop_pager {
 940         my ($self) = @_;
 941         my $pgr = delete($self->{pgr}) or return;
 942         $self->{2} = $pgr->[2];
 943         # do not restore original stdout, just close it so we error out
 944         close(delete($self->{1})) if $self->{1};
 945 }
 946
 947 sub accept_dispatch { # Listener {post_accept} callback
 948         my ($sock) = @_; # ignore other
 949         $sock->autoflush(1);
 950         my $self = bless { sock => $sock }, __PACKAGE__;
 951         vec(my $rvec = '', fileno($sock), 1) = 1;
 952         select($rvec, undef, undef, 60) or
 953                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 954         # (4096 * 33) >MAX_ARG_STRLEN
 955         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
 956         if (scalar(@fds) == 4) {
 957                 for my $i (0..3) {
 958                         my $fd = shift(@fds);
 959                         open($self->{$i}, '+<&=', $fd) and next;
 960                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 961                 }
 962         } elsif (!defined($fds[0])) {
 963                 warn(my $msg = "recv_cmd failed: $!");
 964                 return send($sock, $msg, MSG_EOR);
 965         } else {
 966                 return;
 967         }
 968         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 969         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 970         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 971         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 972                 return send($sock, 'request command truncated', MSG_EOR);
 973         my ($argc, @argv) = split(/\0/, $buf, -1);
 974         undef $buf;
 975         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 976         if (chdir($self->{3})) {
 977                 local %ENV = %env;
 978                 $self->{env} = \%env;
 979                 eval { dispatch($self, @argv) };
 980                 send($sock, $@, MSG_EOR) if $@;
 981         } else {
 982                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 983         }
 984 }
 985
 986 sub dclose {
 987         my ($self) = @_;
 988         delete $self->{-progress};
 989         for my $f (@WQ_KEYS) {
 990                 my $wq = delete $self->{$f} or next;
 991                 if ($wq->wq_kill) {
 992                         $wq->wq_close(0, undef, $self);
 993                 } elsif ($wq->wq_kill_old) {
 994                         $wq->wq_wait_old(undef, $self);
 995                 }
 996         }
 997         close(delete $self->{1}) if $self->{1}; # may reap_compress
 998         if (my $sto = delete $self->{sto}) {
 999                 $sto->ipc_do('done');
1000         }
1001         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1002 }
1003
1004 # for long-running results
1005 sub event_step {
1006         my ($self) = @_;
1007         local %ENV = %{$self->{env}};
1008         my $sock = $self->{sock};
1009         local $current_lei = $self;
1010         eval {
1011                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1012                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1013                                 return if $! == EAGAIN;
1014                                 next if $! == EINTR;
1015                                 last if $! == ECONNRESET;
1016                                 die "recvmsg: $!";
1017                         }
1018                         for my $fd (@fds) {
1019                                 open my $rfh, '+<&=', $fd;
1020                         }
1021                         die "unrecognized client signal: $buf";
1022                 }
1023                 dclose($self);
1024         };
1025         if (my $err = $@) {
1026                 eval { $self->fail($err) };
1027                 dclose($self);
1028         }
1029 }
1030
1031 sub event_step_init {
1032         my ($self) = @_;
1033         return if $self->{-event_init_done}++;
1034         if (my $sock = $self->{sock}) { # using DS->EventLoop
1035                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1036         }
1037 }
1038
1039 sub noop {}
1040
1041 sub oldset { $oldset }
1042
1043 sub dump_and_clear_log {
1044         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1045                 my @pfx = @_;
1046                 unshift(@pfx, "$errors_log ") if @pfx;
1047                 warn @pfx, do { local $/; <STDIN> };
1048                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1049         }
1050 }
1051
1052 # lei(1) calls this when it can't connect
1053 sub lazy_start {
1054         my ($path, $errno, $narg) = @_;
1055         local ($errors_log, $listener);
1056         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1057         $errors_log .= 'errors.log';
1058         my $addr = pack_sockaddr_un($path);
1059         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1060         $lk->lock_acquire;
1061         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1062         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1063                 return if connect($listener, $addr); # another process won
1064                 if ($errno == ECONNREFUSED && -S $path) {
1065                         unlink($path) or die "unlink($path): $!";
1066                 }
1067         } else {
1068                 $! = $errno; # allow interpolation to stringify in die
1069                 die "connect($path): $!";
1070         }
1071         umask(077) // die("umask(077): $!");
1072         bind($listener, $addr) or die "bind($path): $!";
1073         listen($listener, 1024) or die "listen: $!";
1074         $lk->lock_release;
1075         undef $lk;
1076         my @st = stat($path) or die "stat($path): $!";
1077         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1078         local $oldset = PublicInbox::DS::block_signals();
1079         if ($narg == 5) {
1080                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1081                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1082                         require PublicInbox::CmdIPC4;
1083                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1084                         PublicInbox::CmdIPC4->can('recv_cmd4');
1085                 };
1086         }
1087         $recv_cmd or die <<"";
1088 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1089
1090         require PublicInbox::Listener;
1091         require PublicInbox::EOFpipe;
1092         (-p STDOUT) or die "E: stdout must be a pipe\n";
1093         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1094         STDIN->autoflush(1);
1095         dump_and_clear_log("from previous daemon process:\n");
1096         POSIX::setsid() > 0 or die "setsid: $!";
1097         my $pid = fork // die "fork: $!";
1098         return if $pid;
1099         $0 = "lei-daemon $path";
1100         local %PATH2CFG;
1101         $listener->blocking(0);
1102         my $exit_code;
1103         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1104         local $quit = do {
1105                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1106                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1107                 sub {
1108                         $exit_code //= shift;
1109                         my $lis = $pil or exit($exit_code);
1110                         # closing eof_w triggers \&noop wakeup
1111                         $listener = $eof_w = $pil = $path = undef;
1112                         $lis->close; # DS::close
1113                         PublicInbox::DS->SetLoopTimeout(1000);
1114                 };
1115         };
1116         my $sig = {
1117                 CHLD => \&PublicInbox::DS::enqueue_reap,
1118                 QUIT => $quit,
1119                 INT => $quit,
1120                 TERM => $quit,
1121                 HUP => \&noop,
1122                 USR1 => \&noop,
1123                 USR2 => \&noop,
1124         };
1125         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1126         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1127         undef $sig;
1128         local $SIG{PIPE} = 'IGNORE';
1129         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1130                 undef $sigfd;
1131                 PublicInbox::DS->SetLoopTimeout(5000);
1132         } else {
1133                 # wake up every second to accept signals if we don't
1134                 # have signalfd or IO::KQueue:
1135                 PublicInbox::DS::sig_setmask($oldset);
1136                 PublicInbox::DS->SetLoopTimeout(1000);
1137         }
1138         PublicInbox::DS->SetPostLoopCallback(sub {
1139                 my ($dmap, undef) = @_;
1140                 if (@st = defined($path) ? stat($path) : ()) {
1141                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1142                                 warn "$path dev/ino changed, quitting\n";
1143                                 $path = undef;
1144                         }
1145                 } elsif (defined($path)) { # ENOENT is common
1146                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1147                         undef $path;
1148                         $quit->();
1149                 }
1150                 return 1 if defined($path);
1151                 my $now = now();
1152                 my $n = 0;
1153                 for my $s (values %$dmap) {
1154                         $s->can('busy') or next;
1155                         if ($s->busy($now)) {
1156                                 ++$n;
1157                         } else {
1158                                 $s->close;
1159                         }
1160                 }
1161                 $n; # true: continue, false: stop
1162         });
1163
1164         # STDIN was redirected to /dev/null above, closing STDERR and
1165         # STDOUT will cause the calling `lei' client process to finish
1166         # reading the <$daemon> pipe.
1167         local $SIG{__WARN__} = sub {
1168                 $current_lei ? err($current_lei, @_) : warn(
1169                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1170         };
1171         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1172         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1173         # $daemon pipe to `lei' closed, main loop begins:
1174         PublicInbox::DS->EventLoop;
1175         exit($exit_code // 0);
1176 }
1177
1178 sub busy { 1 } # prevent daemon-shutdown if client is connected
1179
1180 # for users w/o Socket::Msghdr installed or Inline::C enabled
1181 sub oneshot {
1182         my ($main_pkg) = @_;
1183         my $exit = $main_pkg->can('exit'); # caller may override exit()
1184         local $quit = $exit if $exit;
1185         local %PATH2CFG;
1186         umask(077) // die("umask(077): $!");
1187         my $self = bless {
1188                 oneshot => 1,
1189                 0 => *STDIN{GLOB},
1190                 1 => *STDOUT{GLOB},
1191                 2 => *STDERR{GLOB},
1192                 env => \%ENV
1193         }, __PACKAGE__;
1194         dispatch($self, @ARGV);
1195         x_it($self, $self->{child_error}) if $self->{child_error};
1196 }
1197
1198 # ensures stdout hits the FS before sock disconnects so a client
1199 # can immediately reread it
1200 sub DESTROY {
1201         my ($self) = @_;
1202         $self->{1}->autoflush(1) if $self->{1};
1203         stop_pager($self);
1204         my $err = $?;
1205         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1206         waitpid($_, 0) for keys %$oneshot_pids;
1207         $? = $err if $err; # preserve ->fail or ->x_it code
1208 }
1209
1210 1;