lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 sub rel2abs ($$) {
  69         my ($self, $p) = @_;
  70         return $p if index($p, '/') == 0; # already absolute
  71         my $pwd = $self->{env}->{PWD};
  72         if (defined $pwd) {
  73                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  74                 if (my @st_pwd = stat($pwd)) {
  75                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  76                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  77                                 $self->{env}->{PWD} = $pwd = $cwd;
  78                 } else { # PWD was invalid
  79                         delete $self->{env}->{PWD};
  80                         undef $pwd;
  81                 }
  82         }
  83         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  84         File::Spec->rel2abs($p, $pwd);
  85 }
  86
  87 sub _store_path ($) {
  88         my ($self) = @_;
  89         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  90                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  91                 .'/lei/store');
  92 }
  93
  94 sub _config_path ($) {
  95         my ($self) = @_;
  96         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  97                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  98                 .'/lei/config');
  99 }
 100
 101 # TODO: generate shell completion + help using %CMD and %OPTDESC
 102 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 103 our %CMD = ( # sorted in order of importance/use:
 104 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms', qw(
 105         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
 106         sort|s=s reverse|r offset=i remote! local! external! pretty
 107         include|I=s@ exclude=s@ only=s@ jobs|j=s globoff|g stdin|
 108         mua-cmd|mua=s no-torsocks torsocks=s verbose|v quiet|q
 109         received-after=s received-before=s sent-after=s sent-since=s),
 110         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 111
 112 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 113         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
 114         pass_through('git show') ],
 115
 116 'add-external' => [ 'URL_OR_PATHNAME',
 117         'add/set priority of a publicinbox|extindex for extra matches',
 118         qw(boost=i quiet|q) ],
 119 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
 120         qw(format|f=s z|0 local remote quiet|q) ],
 121 'forget-external' => [ 'URL_OR_PATHNAME...|--prune',
 122         'exclude further results from a publicinbox|extindex',
 123         qw(prune quiet|q) ],
 124
 125 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 126                 qw(name-only format|f=s z) ],
 127 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 128 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 129
 130 'plonk' => [ '--thread|--from=IDENT',
 131         'exclude mail matching From: or thread from non-Message-ID searches',
 132         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 133 'mark' => [ 'MESSAGE_FLAGS...',
 134         'set/unset keywords on message(s) from stdin',
 135         qw(stdin| oid=s exact by-mid|mid:s) ],
 136 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 137         "exclude message(s) on stdin from `q' search results",
 138         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 139
 140 'purge-mailsource' => [ 'URL_OR_PATHNAME|--all',
 141         'remove imported messages from IMAP, Maildirs, and MH',
 142         qw(exact! all jobs:i indexed) ],
 143
 144 # code repos are used for `show' to solve blobs from patch mails
 145 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 146         qw(boost=i) ],
 147 'ls-coderepo' => [ '[FILTER_TERMS...]',
 148                 'list known code repos', qw(format|f=s z) ],
 149 'forget-coderepo' => [ 'PATHNAME',
 150         'stop using repo to solve blobs from patches',
 151         qw(prune) ],
 152
 153 'add-watch' => [ '[URL_OR_PATHNAME]',
 154                 'watch for new messages and flag changes',
 155         qw(import! kw|keywords|flags! interval=s recursive|r
 156         exclude=s include=s) ],
 157 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 158                 qw(format|f=s z) ],
 159 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 160 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 161 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 162         qw(prune) ],
 163
 164 'import' => [ 'URLS_OR_PATHNAMES...|--stdin',
 165         'one-time import/update from URL or filesystem',
 166         qw(stdin| offset=i recursive|r exclude=s include|I=s
 167         format|f=s kw|keywords|flags!),
 168         ],
 169
 170 'config' => [ '[...]', sub {
 171                 'git-config(1) wrapper for '._config_path($_[0]);
 172         }, qw(config-file|system|global|file|f=s), # for conflict detection
 173         pass_through('git config') ],
 174 'init' => [ '[PATHNAME]', sub {
 175                 'initialize storage, default: '._store_path($_[0]);
 176         }, qw(quiet|q) ],
 177 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 178         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 179 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 180 'help' => [ '[SUBCOMMAND]', 'show help' ],
 181
 182 # XXX do we need this?
 183 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 184
 185 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 186         'rewrite git history in an attempt to improve compression',
 187         'gc!' ],
 188
 189 # internal commands are prefixed with '_'
 190 '_complete' => [ '[...]', 'internal shell completion helper',
 191                 pass_through('everything') ],
 192 ); # @CMD
 193
 194 # switch descriptions, try to keep consistent across commands
 195 # $spec: Getopt::Long option specification
 196 # $spec => [@ALLOWED_VALUES (default is first), $description],
 197 # $spec => $description
 198 # "$SUB_COMMAND TAB $spec" => as above
 199 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 200                         'specify message input format' ];
 201 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 202
 203 my %OPTDESC = (
 204 'help|h' => 'show this built-in help',
 205 'quiet|q' => 'be quiet',
 206 'globoff|g' => "do not match locations using '*?' wildcards and '[]' ranges",
 207 'verbose|v' => 'be more verbose',
 208 'solve!' => 'do not attempt to reconstruct blobs from emails',
 209 'torsocks=s' => ['auto|no|yes',
 210                 'whether or not to wrap git and curl commands with torsocks'],
 211 'no-torsocks' => 'alias for --torsocks=no',
 212 'save-as=s' => ['NAME', 'save a search terms by given name'],
 213
 214 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 215
 216 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 217                 'deduplication strategy'],
 218 'show   thread|t' => 'display entire thread a message belongs to',
 219 'q      thread|t' =>
 220         'return all messages in the same thread as the actual match(es)',
 221 'augment|a' => 'augment --output destination instead of clobbering',
 222
 223 'output|mfolder|o=s' => [ 'DEST',
 224         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 225 'mua-cmd|mua=s' => [ 'COMMAND',
 226         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 227
 228 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 229                         'message/object output format' ],
 230 'mark   format|f=s' => $stdin_formats,
 231 'forget format|f=s' => $stdin_formats,
 232 'q      format|f=s' => [
 233         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 234                 'specify output format, default depends on --output'],
 235 'q      exclude=s@' => [ 'URL_OR_PATHNAME',
 236                 'exclude specified external(s) from search' ],
 237 'q      include|I=s@' => [ 'URL_OR_PATHNAME',
 238                 'include specified external(s) in search' ],
 239 'q      only=s@' => [ 'URL_OR_PATHNAME',
 240                 'only use specified external(s) for search' ],
 241
 242 'q      jobs=s' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 243                 'control number of search and writer jobs' ],
 244
 245 'import format|f=s' => $stdin_formats,
 246
 247 'ls-query       format|f=s' => $ls_format,
 248 'ls-external    format|f=s' => $ls_format,
 249
 250 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 251 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 252
 253 'sort|s=s' => [ 'VAL|received,relevance,docid',
 254                 "order of results `--output'-dependent"],
 255 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 256
 257 'boost=i' => 'increase/decrease priority of results (default: 0)',
 258
 259 'local' => 'limit operations to the local filesystem',
 260 'local!' => 'exclude results from the local filesystem',
 261 'remote' => 'limit operations to those requiring network access',
 262 'remote!' => 'prevent operations requiring network access',
 263
 264 'mid=s' => 'specify the Message-ID of a message',
 265 'oid=s' => 'specify the git object ID of a message',
 266
 267 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 268 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 269 'include=s' => 'include mailboxes/newsgroups based on pattern',
 270
 271 'exact' => 'operate on exact header matches only',
 272 'exact!' => 'rely on content match instead of exact header matches',
 273
 274 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 275 'jobs:i' => 'set parallelism level',
 276
 277 'kw|keywords|flags!' => 'disable/enable importing flags',
 278
 279 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 280 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 281
 282 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 283 ); # %OPTDESC
 284
 285 my %CONFIG_KEYS = (
 286         'leistore.dir' => 'top-level storage location',
 287 );
 288
 289 my @WQ_KEYS = qw(lxs l2m imp); # internal workers
 290
 291 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 292 sub x_it ($$) {
 293         my ($self, $code) = @_;
 294         # make sure client sees stdout before exit
 295         $self->{1}->autoflush(1) if $self->{1};
 296         dump_and_clear_log();
 297         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 298                 send($s, "x_it $code", MSG_EOR);
 299         } elsif ($self->{oneshot}) {
 300                 # don't want to end up using $? from child processes
 301                 for my $f (@WQ_KEYS) {
 302                         my $wq = delete $self->{$f} or next;
 303                         $wq->DESTROY;
 304                 }
 305                 # cleanup anything that has tempfiles
 306                 delete @$self{qw(ovv dedupe)};
 307                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 308                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 309                         kill $signum, $$;
 310                         sleep(1) while 1; # wait for signal
 311                 } else {
 312                         $quit->($code >> 8);
 313                 }
 314         } # else ignore if client disconnected
 315 }
 316
 317 sub err ($;@) {
 318         my $self = shift;
 319         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 320         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 321         print $err @_, @eor and return;
 322         my $old_err = delete $self->{2};
 323         close($old_err) if $! == EPIPE && $old_err;
 324         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 325         print $err @_, @eor or print STDERR @_, @eor;
 326 }
 327
 328 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 329
 330 sub fail_handler ($;$$) {
 331         my ($lei, $code, $io) = @_;
 332         for my $f (@WQ_KEYS) {
 333                 my $wq = delete $lei->{$f} or next;
 334                 $wq->wq_wait_old($lei) if $wq->wq_kill_old; # lei-daemon
 335         }
 336         close($io) if $io; # needed to avoid warnings on SIGPIPE
 337         $lei->x_it($code // (1 >> 8));
 338 }
 339
 340 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 341         fail_handler($_[0], 13, delete $_[0]->{1});
 342 }
 343
 344 sub fail ($$;$) {
 345         my ($self, $buf, $exit_code) = @_;
 346         err($self, $buf) if defined $buf;
 347         # calls fail_handler:
 348         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 349         x_it($self, ($exit_code // 1) << 8);
 350         undef;
 351 }
 352
 353 sub out ($;@) {
 354         my $self = shift;
 355         return if print { $self->{1} // return } @_; # likely
 356         return note_sigpipe($self, 1) if $! == EPIPE;
 357         my $err = "error writing to stdout: $!";
 358         delete $self->{1};
 359         fail($self, $err);
 360 }
 361
 362 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 363
 364 sub child_error { # passes non-fatal curl exit codes to user
 365         my ($self, $child_error, $msg) = @_; # child_error is $?
 366         $self->err($msg) if $msg;
 367         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 368                 # send to the parent lei-daemon or to lei(1) client
 369                 send($s, "child_error $child_error", MSG_EOR);
 370         } elsif (!$PublicInbox::DS::in_loop) {
 371                 $self->{child_error} = $child_error;
 372         } # else noop if client disconnected
 373 }
 374
 375 sub note_sigpipe { # triggers sigpipe_handler
 376         my ($self, $fd) = @_;
 377         close(delete($self->{$fd})); # explicit close silences Perl warning
 378         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 379         x_it($self, 13);
 380 }
 381
 382 sub lei_atfork_child {
 383         my ($self, $persist) = @_;
 384         # we need to explicitly close things which are on stack
 385         if ($persist) {
 386                 my @io = delete @$self{0,1,2};
 387                 unless ($self->{oneshot}) {
 388                         close($_) for @io;
 389                 }
 390         } else {
 391                 delete $self->{0};
 392         }
 393         for (delete @$self{qw(3 sock old_1 au_done)}) {
 394                 close($_) if defined($_);
 395         }
 396         if (my $op_c = delete $self->{pkt_op_c}) {
 397                 close(delete $op_c->{sock});
 398         }
 399         if (my $pgr = delete $self->{pgr}) {
 400                 close($_) for (@$pgr[1,2]);
 401         }
 402         close $listener if $listener;
 403         undef $listener;
 404         %PATH2CFG = ();
 405         undef $errors_log;
 406         $quit = \&CORE::exit;
 407         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 408 }
 409
 410 sub _help ($;$) {
 411         my ($self, $errmsg) = @_;
 412         my $cmd = $self->{cmd} // 'COMMAND';
 413         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 414         my @top = ($cmd, shift(@info) // ());
 415         my $cmd_desc = shift(@info);
 416         $cmd_desc = $cmd_desc->($self) if ref($cmd_desc) eq 'CODE';
 417         my @opt_desc;
 418         my $lpad = 2;
 419         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 420                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 421                 my $arg_vals = '';
 422                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 423
 424                 # lower-case is a keyword (e.g. `content', `oid'),
 425                 # ALL_CAPS is a string description (e.g. `PATH')
 426                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 427                         $desc .= "\ndefault: `$1'";
 428                 }
 429                 my (@vals, @s, @l);
 430                 my $x = $sw;
 431                 if ($x =~ s/!\z//) { # solve! => --no-solve
 432                         $x =~ s/(\A|\|)/$1no-/g
 433                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 434                         @vals = (' [', undef, ']');
 435                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 436                         @vals = (' ', undef);
 437                 } # else: no args $x = 'thread|t'
 438                 for (split(/\|/, $x)) { # help|h
 439                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 440                 }
 441                 if (!scalar(@vals)) { # no args 'thread|t'
 442                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 443                         $vals[1] = $1;
 444                 } else {
 445                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 446                 }
 447                 if ($arg_vals =~ /([,\|])/) {
 448                         my $sep = $1;
 449                         my @allow = split(/\Q$sep\E/, $arg_vals);
 450                         my $must = $sep eq '|' ? 'Must' : 'Can';
 451                         @allow = map { "`$_'" } @allow;
 452                         my $last = pop @allow;
 453                         $desc .= "\n$must be one of: " .
 454                                 join(', ', @allow) . " or $last";
 455                 }
 456                 my $lhs = join(', ', @s, @l) . join('', @vals);
 457                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 458                         $lhs =~ s/\A--/- , --/;
 459                 } else {
 460                         $lhs =~ s/\A--/    --/; # pad if no short options
 461                 }
 462                 $lpad = length($lhs) if length($lhs) > $lpad;
 463                 push @opt_desc, $lhs, $desc;
 464         }
 465         my $msg = $errmsg ? "E: $errmsg\n" : '';
 466         $msg .= <<EOF;
 467 usage: lei @top
 468   $cmd_desc
 469
 470 EOF
 471         $lpad += 2;
 472         local $Text::Wrap::columns = 78 - $lpad;
 473         my $padding = ' ' x ($lpad + 2);
 474         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 475                 $msg .= '  '.pack("A$lpad", $lhs);
 476                 $rhs = wrap('', '', $rhs);
 477                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 478                 $msg .= $rhs;
 479                 $msg .= "\n";
 480         }
 481         my $out = $self->{$errmsg ? 2 : 1};
 482         start_pager($self) if -t $out;
 483         print $out $msg;
 484         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 485         undef;
 486 }
 487
 488 sub optparse ($$$) {
 489         my ($self, $cmd, $argv) = @_;
 490         $self->{cmd} = $cmd;
 491         $OPT = $self->{opt} = {};
 492         my $info = $CMD{$cmd} // [ '[...]' ];
 493         my ($proto, undef, @spec) = @$info;
 494         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 495         push @spec, qw(help|h);
 496         my $lone_dash;
 497         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 498                 $lone_dash = $spec[0];
 499                 $OPT->{$spec[0]} = \(my $var);
 500                 push @spec, '' => \$var;
 501         }
 502         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 503                 return _help($self, "bad arguments or options for $cmd");
 504         return _help($self) if $OPT->{help};
 505
 506         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 507
 508         # "-" aliases "stdin" or "clear"
 509         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 510
 511         my $i = 0;
 512         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 513         my ($err, $inf);
 514         my @args = split(/ /, $proto);
 515         for my $var (@args) {
 516                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 517                         $inf = defined($argv->[$i]) and last;
 518                         $var =~ s/\.\.\.\z//;
 519                         $err = "$var not supplied";
 520                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 521                         $argv->[$i++] // ($err = "$var not supplied");
 522                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 523                         $inf = 1;
 524                         last;
 525                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 526                         $i++;
 527                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 528                         $inf = 1 if index($var, '...') > 0;
 529                         my @or = split(/\|/, $var);
 530                         my $ok;
 531                         for my $o (@or) {
 532                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 533                                         $ok = defined($OPT->{$1});
 534                                         last if $ok;
 535                                 } elsif (defined($argv->[$i])) {
 536                                         $ok = 1;
 537                                         $i++;
 538                                         last;
 539                                 } # else continue looping
 540                         }
 541                         last if $ok;
 542                         my $last = pop @or;
 543                         $err = join(', ', @or) . " or $last must be set";
 544                 } else {
 545                         warn "BUG: can't parse `$var' in $proto";
 546                 }
 547                 last if $err;
 548         }
 549         if (!$inf && scalar(@$argv) > scalar(@args)) {
 550                 $err //= 'too many arguments';
 551         }
 552         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 553 }
 554
 555 sub dispatch {
 556         my ($self, $cmd, @argv) = @_;
 557         local $current_lei = $self; # for __WARN__
 558         dump_and_clear_log("from previous run\n");
 559         return _help($self, 'no command given') unless defined($cmd);
 560         my $func = "lei_$cmd";
 561         $func =~ tr/-/_/;
 562         if (my $cb = __PACKAGE__->can($func)) {
 563                 optparse($self, $cmd, \@argv) or return;
 564                 $cb->($self, @argv);
 565         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 566                 my $opt = {};
 567                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 568                         return _help($self, 'bad arguments or options');
 569                 _help($self);
 570         } else {
 571                 fail($self, "`$cmd' is not an lei command");
 572         }
 573 }
 574
 575 sub _lei_cfg ($;$) {
 576         my ($self, $creat) = @_;
 577         my $f = _config_path($self);
 578         my @st = stat($f);
 579         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 580         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 581                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 582         }
 583         if (!@st) {
 584                 unless ($creat) {
 585                         delete $self->{cfg};
 586                         return;
 587                 }
 588                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 589                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 590                 open my $fh, '>>', $f or die "open($f): $!\n";
 591                 @st = stat($fh) or die "fstat($f): $!\n";
 592                 $cur_st = pack('dd', $st[10], $st[7]);
 593                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 594         }
 595         my $cfg = PublicInbox::Config::git_config_dump($f);
 596         $cfg->{-st} = $cur_st;
 597         $cfg->{'-f'} = $f;
 598         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 599 }
 600
 601 sub _lei_store ($;$) {
 602         my ($self, $creat) = @_;
 603         my $cfg = _lei_cfg($self, $creat);
 604         $cfg->{-lei_store} //= do {
 605                 require PublicInbox::LeiStore;
 606                 my $dir = $cfg->{'leistore.dir'};
 607                 $dir //= $creat ? _store_path($self) : return;
 608                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 609         };
 610 }
 611
 612 sub lei_show {
 613         my ($self, @argv) = @_;
 614 }
 615
 616 sub lei_mark {
 617         my ($self, @argv) = @_;
 618 }
 619
 620 sub _config {
 621         my ($self, @argv) = @_;
 622         my $env = $self->{env};
 623         delete local $env->{GIT_CONFIG};
 624         delete local $ENV{GIT_CONFIG};
 625         my $cfg = _lei_cfg($self, 1);
 626         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 627         my %rdr = map { $_ => $self->{$_} } (0..2);
 628         waitpid(spawn($cmd, $env, \%rdr), 0);
 629 }
 630
 631 sub lei_config {
 632         my ($self, @argv) = @_;
 633         $self->{opt}->{'config-file'} and return fail $self,
 634                 "config file switches not supported by `lei config'";
 635         _config(@_);
 636         x_it($self, $?) if $?;
 637 }
 638
 639 sub lei_import {
 640         require PublicInbox::LeiImport;
 641         PublicInbox::LeiImport->call(@_);
 642 }
 643
 644 sub lei_init {
 645         my ($self, $dir) = @_;
 646         my $cfg = _lei_cfg($self, 1);
 647         my $cur = $cfg->{'leistore.dir'};
 648         $dir //= _store_path($self);
 649         $dir = rel2abs($self, $dir);
 650         my @cur = stat($cur) if defined($cur);
 651         $cur = File::Spec->canonpath($cur // $dir);
 652         my @dir = stat($dir);
 653         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 654         if (@cur) {
 655                 if ($cur eq $dir) {
 656                         _lei_store($self, 1)->done;
 657                         return qerr($self, $exists);
 658                 }
 659
 660                 # some folks like symlinks and bind mounts :P
 661                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 662                         lei_config($self, 'leistore.dir', $dir);
 663                         _lei_store($self, 1)->done;
 664                         return qerr($self, "$exists (as $cur)");
 665                 }
 666                 return fail($self, <<"");
 667 E: leistore.dir=$cur already initialized and it is not $dir
 668
 669         }
 670         lei_config($self, 'leistore.dir', $dir);
 671         _lei_store($self, 1)->done;
 672         $exists //= "I: leistore.dir=$dir newly initialized";
 673         return qerr($self, $exists);
 674 }
 675
 676 sub lei_daemon_pid { puts shift, $$ }
 677
 678 sub lei_daemon_kill {
 679         my ($self) = @_;
 680         my $sig = $self->{opt}->{signal} // 'TERM';
 681         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 682 }
 683
 684 sub lei_help { _help($_[0]) }
 685
 686 # Shell completion helper.  Used by lei-completion.bash and hopefully
 687 # other shells.  Try to do as much here as possible to avoid redundancy
 688 # and improve maintainability.
 689 sub lei__complete {
 690         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 691         shift @argv; # ignore "lei", the entire command is sent
 692         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 693         my $cmd = shift @argv;
 694         my $info = $CMD{$cmd} // do { # filter matching commands
 695                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 696                 return;
 697         };
 698         my ($proto, undef, @spec) = @$info;
 699         my $cur = pop @argv;
 700         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 701         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 702                 # gross special case since the only git-config options
 703                 # Consider moving to a table if we need more special cases
 704                 # we use Getopt::Long for are the ones we reject, so these
 705                 # are the ones we don't reject:
 706                 if ($cmd eq 'config') {
 707                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 708                         @spec = qw(add z|null get get-all unset unset-all
 709                                 replace-all get-urlmatch
 710                                 remove-section rename-section
 711                                 name-only list|l edit|e
 712                                 get-color-name get-colorbool);
 713                         # fall-through
 714                 }
 715                 puts $self, grep(/$re/, map { # generate short/long names
 716                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 717                         } elsif (s/!\z//) {
 718                                 # negation: solve! => no-solve|solve
 719                                 s/([\w\-]+)/$1|no-$1/g
 720                         }
 721                         map {
 722                                 my $x = length > 1 ? "--$_" : "-$_";
 723                                 $x eq $cur ? () : $x;
 724                         } split(/\|/, $_, -1) # help|h
 725                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 726         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 727                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 728         }
 729
 730         # switch args (e.g. lei q -f mbox<TAB>)
 731         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 732                 my $opt = quotemeta $1;
 733                 puts $self, map {
 734                         my $v = $OPTDESC{$_};
 735                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 736                         # get rid of ALL CAPS placeholder (e.g "OUT")
 737                         # (TODO: completion for external paths)
 738                         shift(@v) if uc($v[0]) eq $v[0];
 739                         @v;
 740                 } grep(/\A(?:$cmd\t|)(?:[\w-]+\|)*$opt\b/, keys %OPTDESC);
 741         }
 742         $cmd =~ tr/-/_/;
 743         if (my $sub = $self->can("_complete_$cmd")) {
 744                 puts $self, $sub->($self, @argv, $cur);
 745         }
 746         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 747         # proto parsing.
 748 }
 749
 750 sub exec_buf ($$) {
 751         my ($argv, $env) = @_;
 752         my $argc = scalar @$argv;
 753         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 754         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 755         $buf;
 756 }
 757
 758 sub start_mua {
 759         my ($self) = @_;
 760         my $mua = $self->{opt}->{'mua-cmd'} // return;
 761         my $mfolder = $self->{ovv}->{dst};
 762         my (@cmd, $replaced);
 763         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 764                 @cmd = ($mua, '-f');
 765         # TODO: help wanted: other common FOSS MUAs
 766         } else {
 767                 require Text::ParseWords;
 768                 my @cmd = Text::ParseWords::shellwords($mua);
 769                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 770                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 771         }
 772         push @cmd, $mfolder unless defined($replaced);
 773         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 774                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 775         } elsif ($self->{oneshot}) {
 776                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 777         }
 778         delete $self->{-progress};
 779 }
 780
 781 # caller needs to "-t $self->{1}" to check if tty
 782 sub start_pager {
 783         my ($self) = @_;
 784         my $env = $self->{env};
 785         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 786         chomp(my $pager = <$fh> // '');
 787         close($fh) or warn "`git var PAGER' error: \$?=$?";
 788         return if $pager eq 'cat' || $pager eq '';
 789         # TODO TIOCGWINSZ
 790         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 791         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 792         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 793         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 794         my $pgr = [ undef, @$rdr{1, 2} ];
 795         if (my $sock = $self->{sock}) { # lei(1) process runs it
 796                 delete @$new_env{keys %$env}; # only set iff unset
 797                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 798                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 799         } elsif ($self->{oneshot}) {
 800                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 801                 $pgr->[3] = $$; # ew'll reap it
 802         } else {
 803                 die 'BUG: start_pager w/o socket';
 804         }
 805         $self->{1} = $wpager;
 806         $self->{2} = $wpager if -t $self->{2};
 807         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 808         $self->{pgr} = $pgr;
 809 }
 810
 811 sub stop_pager {
 812         my ($self) = @_;
 813         my $pgr = delete($self->{pgr}) or return;
 814         $self->{2} = $pgr->[2];
 815         # do not restore original stdout, just close it so we error out
 816         close(delete($self->{1})) if $self->{1};
 817         my $pid = $pgr->[0];
 818         dwaitpid($pid) if $pid && ($pgr->[3] // 0) == $$;
 819 }
 820
 821 sub accept_dispatch { # Listener {post_accept} callback
 822         my ($sock) = @_; # ignore other
 823         $sock->autoflush(1);
 824         my $self = bless { sock => $sock }, __PACKAGE__;
 825         vec(my $rvec = '', fileno($sock), 1) = 1;
 826         select($rvec, undef, undef, 60) or
 827                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 828         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 829         if (scalar(@fds) == 4) {
 830                 for my $i (0..3) {
 831                         my $fd = shift(@fds);
 832                         open($self->{$i}, '+<&=', $fd) and next;
 833                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 834                 }
 835         } else {
 836                 my $msg = "recv_cmd failed: $!";
 837                 warn $msg;
 838                 return send($sock, $msg, MSG_EOR);
 839         }
 840         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 841         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 842         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 843         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 844                 return send($sock, 'request command truncated', MSG_EOR);
 845         my ($argc, @argv) = split(/\0/, $buf, -1);
 846         undef $buf;
 847         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 848         if (chdir($self->{3})) {
 849                 local %ENV = %env;
 850                 $self->{env} = \%env;
 851                 eval { dispatch($self, @argv) };
 852                 send($sock, $@, MSG_EOR) if $@;
 853         } else {
 854                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 855         }
 856 }
 857
 858 sub dclose {
 859         my ($self) = @_;
 860         delete $self->{-progress};
 861         for my $f (@WQ_KEYS) {
 862                 my $wq = delete $self->{$f} or next;
 863                 if ($wq->wq_kill) {
 864                         $wq->wq_close
 865                 } elsif ($wq->wq_kill_old) {
 866                         $wq->wq_wait_old($self);
 867                 }
 868         }
 869         close(delete $self->{1}) if $self->{1}; # may reap_compress
 870         $self->close if $self->{sock}; # PublicInbox::DS::close
 871 }
 872
 873 # for long-running results
 874 sub event_step {
 875         my ($self) = @_;
 876         local %ENV = %{$self->{env}};
 877         my $sock = $self->{sock};
 878         local $current_lei = $self;
 879         eval {
 880                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 881                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 882                                 return if $! == EAGAIN;
 883                                 next if $! == EINTR;
 884                                 last if $! == ECONNRESET;
 885                                 die "recvmsg: $!";
 886                         }
 887                         for my $fd (@fds) {
 888                                 open my $rfh, '+<&=', $fd;
 889                         }
 890                         die "unrecognized client signal: $buf";
 891                 }
 892                 dclose($self);
 893         };
 894         if (my $err = $@) {
 895                 eval { $self->fail($err) };
 896                 dclose($self);
 897         }
 898 }
 899
 900 sub event_step_init {
 901         my ($self) = @_;
 902         if (my $sock = $self->{sock}) { # using DS->EventLoop
 903                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 904         }
 905 }
 906
 907 sub noop {}
 908
 909 our $oldset; sub oldset { $oldset }
 910
 911 sub dump_and_clear_log {
 912         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 913                 my @pfx = @_;
 914                 unshift(@pfx, "$errors_log ") if @pfx;
 915                 warn @pfx, do { local $/; <STDIN> };
 916                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 917         }
 918 }
 919
 920 # lei(1) calls this when it can't connect
 921 sub lazy_start {
 922         my ($path, $errno, $narg) = @_;
 923         if ($errno == ECONNREFUSED) {
 924                 unlink($path) or die "unlink($path): $!";
 925         } elsif ($errno != ENOENT) {
 926                 $! = $errno; # allow interpolation to stringify in die
 927                 die "connect($path): $!";
 928         }
 929         if (eval { require BSD::Resource }) {
 930                 my $NOFILE = BSD::Resource::RLIMIT_NOFILE();
 931                 my ($s, $h) = BSD::Resource::getrlimit($NOFILE);
 932                 BSD::Resource::setrlimit($NOFILE, $h, $h) if $s < $h;
 933         }
 934         umask(077) // die("umask(077): $!");
 935         local $listener;
 936         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 937         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 938         listen($listener, 1024) or die "listen: $!";
 939         my @st = stat($path) or die "stat($path): $!";
 940         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 941         local $oldset = PublicInbox::DS::block_signals();
 942         if ($narg == 5) {
 943                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 944                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 945                         require PublicInbox::CmdIPC4;
 946                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 947                         PublicInbox::CmdIPC4->can('recv_cmd4');
 948                 };
 949         }
 950         $recv_cmd or die <<"";
 951 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 952
 953         require PublicInbox::Listener;
 954         require PublicInbox::EOFpipe;
 955         (-p STDOUT) or die "E: stdout must be a pipe\n";
 956         local $errors_log;
 957         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 958         $errors_log .= 'errors.log';
 959         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 960         STDIN->autoflush(1);
 961         dump_and_clear_log("from previous daemon process:\n");
 962         POSIX::setsid() > 0 or die "setsid: $!";
 963         my $pid = fork // die "fork: $!";
 964         return if $pid;
 965         $0 = "lei-daemon $path";
 966         local %PATH2CFG;
 967         $listener->blocking(0);
 968         my $exit_code;
 969         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 970         local $quit = do {
 971                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 972                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 973                 sub {
 974                         $exit_code //= shift;
 975                         my $lis = $pil or exit($exit_code);
 976                         # closing eof_w triggers \&noop wakeup
 977                         $listener = $eof_w = $pil = $path = undef;
 978                         $lis->close; # DS::close
 979                         PublicInbox::DS->SetLoopTimeout(1000);
 980                 };
 981         };
 982         my $sig = {
 983                 CHLD => \&PublicInbox::DS::enqueue_reap,
 984                 QUIT => $quit,
 985                 INT => $quit,
 986                 TERM => $quit,
 987                 HUP => \&noop,
 988                 USR1 => \&noop,
 989                 USR2 => \&noop,
 990         };
 991         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 992         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 993         undef $sig;
 994         local $SIG{PIPE} = 'IGNORE';
 995         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 996                 undef $sigfd;
 997                 PublicInbox::DS->SetLoopTimeout(5000);
 998         } else {
 999                 # wake up every second to accept signals if we don't
1000                 # have signalfd or IO::KQueue:
1001                 PublicInbox::DS::sig_setmask($oldset);
1002                 PublicInbox::DS->SetLoopTimeout(1000);
1003         }
1004         PublicInbox::DS->SetPostLoopCallback(sub {
1005                 my ($dmap, undef) = @_;
1006                 if (@st = defined($path) ? stat($path) : ()) {
1007                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1008                                 warn "$path dev/ino changed, quitting\n";
1009                                 $path = undef;
1010                         }
1011                 } elsif (defined($path)) { # ENOENT is common
1012                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1013                         undef $path;
1014                         $quit->();
1015                 }
1016                 return 1 if defined($path);
1017                 my $now = now();
1018                 my $n = 0;
1019                 for my $s (values %$dmap) {
1020                         $s->can('busy') or next;
1021                         if ($s->busy($now)) {
1022                                 ++$n;
1023                         } else {
1024                                 $s->close;
1025                         }
1026                 }
1027                 $n; # true: continue, false: stop
1028         });
1029
1030         # STDIN was redirected to /dev/null above, closing STDERR and
1031         # STDOUT will cause the calling `lei' client process to finish
1032         # reading the <$daemon> pipe.
1033         local $SIG{__WARN__} = sub {
1034                 $current_lei ? err($current_lei, @_) : warn(
1035                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1036         };
1037         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1038         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1039         # $daemon pipe to `lei' closed, main loop begins:
1040         PublicInbox::DS->EventLoop;
1041         exit($exit_code // 0);
1042 }
1043
1044 # for users w/o Socket::Msghdr installed or Inline::C enabled
1045 sub oneshot {
1046         my ($main_pkg) = @_;
1047         my $exit = $main_pkg->can('exit'); # caller may override exit()
1048         local $quit = $exit if $exit;
1049         local %PATH2CFG;
1050         umask(077) // die("umask(077): $!");
1051         my $self = bless {
1052                 oneshot => 1,
1053                 0 => *STDIN{GLOB},
1054                 1 => *STDOUT{GLOB},
1055                 2 => *STDERR{GLOB},
1056                 env => \%ENV
1057         }, __PACKAGE__;
1058         dispatch($self, @ARGV);
1059         x_it($self, $self->{child_error}) if $self->{child_error};
1060 }
1061
1062 # ensures stdout hits the FS before sock disconnects so a client
1063 # can immediately reread it
1064 sub DESTROY {
1065         my ($self) = @_;
1066         $self->{1}->autoflush(1) if $self->{1};
1067         stop_pager($self);
1068         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
1069                 waitpid($mua_pid, 0);
1070         }
1071 }
1072
1073 1;