lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(EPOLLIN);
  22 use PublicInbox::DS qw(dwaitpid);
  23 use PublicInbox::Spawn qw(spawn popen_rd);
  24 use PublicInbox::Lock;
  25 use PublicInbox::Eml;
  26 use PublicInbox::Import;
  27 use PublicInbox::ContentHash qw(git_sha);
  28 use Time::HiRes qw(stat); # ctime comparisons for config cache
  29 use File::Path qw(mkpath);
  30 use File::Spec;
  31 use Sys::Syslog qw(openlog syslog closelog);
  32 our $quit = \&CORE::exit;
  33 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle,
  34         $recv_cmd, $send_cmd);
  35 my $GLP = Getopt::Long::Parser->new;
  36 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  37 my $GLP_PASS = Getopt::Long::Parser->new;
  38 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  39
  40 our %PATH2CFG; # persistent for socket daemon
  41 our $MDIR2CFGPATH; # /path/to/maildir => { /path/to/config => [ ino watches ] }
  42
  43 # TBD: this is a documentation mechanism to show a subcommand
  44 # (may) pass options through to another command:
  45 sub pass_through { $GLP_PASS }
  46
  47 my $OPT;
  48 sub opt_dash ($$) {
  49         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  50         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  51         my $cb = sub { # Getopt::Long "<>" catch-all handler
  52                 my ($arg) = @_;
  53                 if ($arg =~ /\A-($re_str)\z/) {
  54                         $OPT->{$key} = $1;
  55                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  56                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  57                 # lone (single) dash is handled elsewhere
  58                 } elsif (substr($arg, 0, 1) eq '-') {
  59                         if ($OPT->{'--'}) {
  60                                 push @{$OPT->{-argv}}, $arg;
  61                         } else {
  62                                 die "bad argument: $arg\n";
  63                         }
  64                 } else {
  65                         push @{$OPT->{-argv}}, $arg;
  66                 }
  67         };
  68         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  69 }
  70
  71 # rel2abs preserves symlinks in parent, unlike abs_path
  72 sub rel2abs {
  73         my ($self, $p) = @_;
  74         if (index($p, '/') == 0) { # already absolute
  75                 $p =~ tr!/!/!s; # squeeze redundant slashes
  76                 chop($p) if substr($p, -1, 1) eq '/';
  77                 return $p;
  78         }
  79         my $pwd = $self->{env}->{PWD};
  80         if (defined $pwd) {
  81                 if (my @st_pwd = stat($pwd)) {
  82                         my @st_cwd = stat($self->{3}) or die "stat({3}): $!";
  83                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  84                                 $self->{env}->{PWD} = $pwd = undef;
  85                 } else { # PWD was invalid
  86                         $self->{env}->{PWD} = $pwd = undef;
  87                 }
  88         }
  89         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd: $!";
  90         File::Spec->rel2abs($p, $pwd);
  91 }
  92
  93 # abs_path resolves symlinks in parent iff all parents exist
  94 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  95
  96 sub canonpath_harder {
  97         my $p = $_[-1]; # $_[0] may be self
  98         $p = File::Spec->canonpath($p);
  99         $p =~ m!(?:/*|\A)\.\.(?:/*|\z)! && -e $p ? Cwd::abs_path($p) : $p;
 100 }
 101
 102 sub share_path ($) { # $HOME/.local/share/lei/$FOO
 103         my ($self) = @_;
 104         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
 105                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 106                 .'/lei');
 107 }
 108
 109 sub store_path ($) { share_path($_[0]) . '/store' }
 110
 111 sub _config_path ($) {
 112         my ($self) = @_;
 113         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 114                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 115                 .'/lei/config');
 116 }
 117
 118 sub cache_dir ($) {
 119         my ($self) = @_;
 120         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 121                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 122                 .'/lei');
 123 }
 124
 125 sub url_folder_cache {
 126         my ($self) = @_;
 127         require PublicInbox::SharedKV; # URI => updated_at_sec_
 128         PublicInbox::SharedKV->new(cache_dir($self).'/uri_folder');
 129 }
 130
 131 sub ale {
 132         my ($self) = @_;
 133         $self->{ale} //= do {
 134                 require PublicInbox::LeiALE;
 135                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 136         };
 137 }
 138
 139 sub index_opt {
 140         # TODO: drop underscore variants everywhere, they're undocumented
 141         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 142         max_size|max-size=s sequential-shard
 143         batch_size|batch-size=s skip-docdata)
 144 }
 145
 146 my @c_opt = qw(c=s@ C=s@ quiet|q);
 147 my @net_opt = (qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt());
 148 my @lxs_opt = qw(remote! local! external! include|I=s@ exclude=s@ only|O=s@
 149         import-remote!);
 150
 151 # we don't support -C as an alias for --find-copies since it's already
 152 # used for chdir
 153 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 154         output-indicator-context=s indent-heuristic!
 155         minimal patience histogram anchored=s@ diff-algorithm=s
 156         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 157         word-diff:s word-diff-regex=s color-words:s no-renames
 158         rename-empty! check ws-error-highlight=s full-index binary
 159         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 160         find-copies-harder irreversible-delete|D l=i diff-filter=s
 161         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 162         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 163         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 164         inter-hunk-context=i function-context|W exit-code ext-diff
 165         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 166         line-prefix=s);
 167
 168 # we generate shell completion + help using %CMD and %OPTDESC,
 169 # see lei__complete() and PublicInbox::LeiHelp
 170 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 171 our %CMD = ( # sorted in order of importance/use:
 172 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 173         'stdin|', # /|\z/ must be first for lone dash
 174         @lxs_opt, @net_opt,
 175         qw(save! output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 176         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 177         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 178         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 179
 180 'up' => [ 'OUTPUT...|--all', 'update saved search',
 181         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ exclude=s@
 182         remote-fudge-time=s all:s remote! local! external!), @c_opt ],
 183
 184 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 185         'stdin|', # /|\z/ must be first for lone dash
 186         # some of these options are ridiculous for lcat
 187         @lxs_opt, @net_opt,
 188         qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 189         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 190         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 191         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 192
 193 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 194         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 195         @lxs_opt, @net_opt, @c_opt ],
 196
 197 'rediff' => [ '--stdin|LOCATION...',
 198                 'regenerate a diff with different options',
 199         'stdin|', # /|\z/ must be first for lone dash
 200         qw(git-dir=s@ cwd! verbose|v+ color:s no-color drq:1 dequote-only:1),
 201         @diff_opt, @lxs_opt, @net_opt, @c_opt ],
 202
 203 'mail-diff' => [ '--stdin|LOCATION...', 'diff the contents of emails',
 204         'stdin|', # /|\z/ must be first for lone dash
 205         qw(verbose|v+ color:s no-color raw-header),
 206         @diff_opt, @net_opt, @c_opt ],
 207
 208 'add-external' => [ 'LOCATION',
 209         'add/set priority of a publicinbox|extindex for extra matches',
 210         qw(boost=i mirror=s inbox-version=i epoch=s verbose|v+),
 211         @c_opt, index_opt(), @net_opt ],
 212 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 213         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 214 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 215 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 216                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 217 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 218                 qw(z|0 ascii l pretty url), @c_opt ],
 219 'forget-external' => [ 'LOCATION...|--prune',
 220         'exclude further results from a publicinbox|extindex',
 221         qw(prune), @c_opt ],
 222
 223 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 224                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 225 'forget-search' => [ 'OUTPUT...|--prune', 'forget a saved search',
 226                 qw(verbose|v+ prune:s), @c_opt ],
 227 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 228                         @c_opt ],
 229 'rm' => [ '--stdin|LOCATION...',
 230         'remove a message from the index and prevent reindexing',
 231         'stdin|', # /|\z/ must be first for lone dash
 232         qw(in-format|F=s lock=s@), @net_opt, @c_opt ],
 233 'plonk' => [ '--threads|--from=IDENT',
 234         'exclude mail matching From: or threads from non-Message-ID searches',
 235         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 236 'tag' => [ 'KEYWORDS...',
 237         'set/unset keywords and/or labels on message(s)',
 238         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 239         @net_opt, @c_opt, pass_through('-kw:foo for delete') ],
 240
 241 'purge-mailsource' => [ 'LOCATION|--all',
 242         'remove imported messages from IMAP, Maildirs, and MH',
 243         qw(exact! all jobs:i indexed), @c_opt ],
 244
 245 'add-watch' => [ 'LOCATION...', 'watch for new messages and flag changes',
 246         qw(poll-interval=s state=s recursive|r), @c_opt ],
 247 'rm-watch' => [ 'LOCATION...', 'remove specified watch(es)',
 248         qw(recursive|r), @c_opt ],
 249 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 250                 qw(l z|0), @c_opt ],
 251 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 252 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 253 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 254         qw(prune), @c_opt ],
 255
 256 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 257         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 258         verbose|v+ incremental!), @net_opt, # mainly for --proxy=
 259          @c_opt ],
 260 'import' => [ 'LOCATION...|--stdin',
 261         'one-time import/update from URL or filesystem',
 262         qw(stdin| offset=i recursive|r exclude=s include|I=s new-only
 263         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 264         @net_opt, @c_opt ],
 265 'forget-mail-sync' => [ 'LOCATION...',
 266         'forget sync information for a mail folder', @c_opt ],
 267 'refresh-mail-sync' => [ 'LOCATION...|--all',
 268         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 269 'export-kw' => [ 'LOCATION...|--all',
 270         'one-time export of keywords of sync sources',
 271         qw(all:s mode=s), @net_opt, @c_opt ],
 272 'convert' => [ 'LOCATION...|--stdin',
 273         'one-time conversion from URL or filesystem to another format',
 274         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 275         @net_opt, @c_opt ],
 276 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 277         "use a patch to generate a query for `lei q --stdin'",
 278         qw(stdin| want|w=s@ uri debug), @c_opt ],
 279 'config' => [ '[...]', sub {
 280                 'git-config(1) wrapper for '._config_path($_[0]);
 281         }, qw(config-file|system|global|file|f=s), # for conflict detection
 282          qw(edit|e c=s@ C=s@), pass_through('git config') ],
 283 'inspect' => [ 'ITEMS...|--stdin', 'inspect lei/store and/or local external',
 284         qw(stdin| pretty ascii dir|d=s), @c_opt ],
 285
 286 'init' => [ '[DIRNAME]', sub {
 287         "initialize storage, default: ".store_path($_[0]);
 288         }, @c_opt ],
 289 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 290         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 291         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 292 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 293 'help' => [ '[SUBCOMMAND]', 'show help' ],
 294
 295 # TODO
 296 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 297 #       'rewrite git history in an attempt to improve compression',
 298 #       qw(gc!), @c_opt ],
 299 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 300 #
 301 # internal commands are prefixed with '_'
 302 '_complete' => [ '[...]', 'internal shell completion helper',
 303                 pass_through('everything') ],
 304 ); # @CMD
 305
 306 # switch descriptions, try to keep consistent across commands
 307 # $spec: Getopt::Long option specification
 308 # $spec => [@ALLOWED_VALUES (default is first), $description],
 309 # $spec => $description
 310 # "$SUB_COMMAND TAB $spec" => as above
 311 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 312                         'specify message input format' ];
 313 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 314
 315 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 316 my %OPTDESC = (
 317 'help|h' => 'show this built-in help',
 318 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 319 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 320 'quiet|q' => 'be quiet',
 321 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 322         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 323
 324 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 325 'globoff|g' => "do not match locations using '*?' wildcards ".
 326                 "and\xa0'[]'\x{a0}ranges",
 327 'invert-match|v' => 'select non-matching lines',
 328 'color!' => 'disable color (for --format=text)',
 329 'verbose|v+' => 'be more verbose',
 330 'external!' => 'do not use externals',
 331 'mail!' => 'do not look in mail storage for OID',
 332 'cwd!' => 'do not look in git repo of current working directory',
 333 'oid-a|A=s' => 'pre-image OID',
 334 'path-a|a=s' => 'pre-image pathname associated with OID',
 335 'path-b|b=s' => 'post-image pathname associated with OID',
 336 'git-dir=s@' => 'additional git repository to scan',
 337 'dir|d=s        inspect' =>
 338         'specify a inboxdir, extindex topdir or Xapian shard',
 339 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 340         "proxy for (e.g. `socks5h://0:9050')" ],
 341 'torsocks=s' => ['VAL|auto|no|yes',
 342                 'whether or not to wrap git and curl commands with torsocks'],
 343 'no-torsocks' => 'alias for --torsocks=no',
 344 'save!' =>  "do not save a search for `lei up'",
 345 'import-remote!' => 'do not memoize remote messages into local store',
 346
 347 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 348
 349 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 350                 'deduplication strategy'],
 351 'threads|t+' =>
 352         'return all messages in the same threads as the actual match(es)',
 353
 354 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 355                 'search prefixes to extract (default: dfpost7)' ],
 356 'uri    p2q' => [ 'URI escape output' ],
 357
 358 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 359         'run command(s) or perform ops when done writing to output ' .
 360         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 361         'nothing otherwise)' ],
 362
 363 'augment|a' => 'augment --output destination instead of clobbering',
 364
 365 'output|mfolder|o=s' => [ 'MFOLDER',
 366         "destination (e.g.\xa0`/path/to/Maildir', ".
 367         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 368 'mua=s' => [ 'CMD',
 369         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 370 'new-only       import' => 'only import new messages from IMAP source',
 371
 372 'inbox-version=i' => [ 'NUM|1|2',
 373                 'force a public-inbox version with --mirror'],
 374 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 375
 376 # public-inbox-index options
 377 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 378 'compact' => 'run compact index after mirroring',
 379 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 380         "indexlevel with --mirror (default: full)" ],
 381 'max_size|max-size=s' => [ 'SIZE',
 382         'do not index messages larger than SIZE (default: infinity)' ],
 383 'batch_size|batch-size=s' => [ 'SIZE',
 384         'flush changes to OS after given number of bytes (default: 1m)' ],
 385 'sequential-shard' =>
 386         'index Xapian shards sequentially for slow storage',
 387 'skip-docdata' =>
 388         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 389
 390 'format|f=s     q' => [
 391         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 392                 'specify output format, default depends on --output'],
 393 'exclude=s@     q' => [ 'LOCATION',
 394                 'exclude specified external(s) from search' ],
 395 'include|I=s@   q' => [ 'LOCATION',
 396                 'include specified external(s) in search' ],
 397 'only|O=s@      q' => [ 'LOCATION',
 398                 'only use specified external(s) for search' ],
 399 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 400                 'control number of search and writer jobs' ],
 401 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 402
 403 'in-format|F=s' => $stdin_formats,
 404 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 405                         'listing output format' ],
 406 'l      ls-search' => 'long listing format',
 407 'l      ls-watch' => 'long listing format',
 408 'l      ls-mail-source' => 'long listing format',
 409 'url    ls-mail-source' => 'show full URL of newsgroup or IMAP folder',
 410 'format|f=s     ls-external' => $ls_format,
 411
 412 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 413 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 414
 415 'sort|s=s' => [ 'VAL|received|relevance|docid',
 416                 "order of results is `--output'-dependent"],
 417 'reverse|r' => 'reverse search results', # like sort(1)
 418
 419 'boost=i' => 'increase/decrease priority of results (default: 0)',
 420
 421 'local' => 'limit operations to the local filesystem',
 422 'local!' => 'exclude results from the local filesystem',
 423 'remote' => 'limit operations to those requiring network access',
 424 'remote!' => 'prevent operations requiring network access',
 425
 426 # up, refresh-mail-sync, export-kw
 427 'all:s' => ['TYPE|local|remote', 'all remote or local folders' ],
 428
 429 'remote-fudge-time=s' => [ 'INTERVAL',
 430         'look for mail INTERVAL older than the last successful query' ],
 431
 432 'mid=s' => 'specify the Message-ID of a message',
 433 'oid=s' => 'specify the git object ID of a message',
 434
 435 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 436 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 437 'include=s' => 'include mailboxes/newsgroups based on pattern',
 438
 439 'exact' => 'operate on exact header matches only',
 440 'exact!' => 'rely on content match instead of exact header matches',
 441
 442 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 443
 444 'kw!' => 'disable/enable importing keywords (aka "flags")',
 445
 446 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 447 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 448
 449 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 450 ); # %OPTDESC
 451
 452 my %CONFIG_KEYS = (
 453         'leistore.dir' => 'top-level storage location',
 454 );
 455
 456 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1 lne v2w); # internal workers
 457
 458 sub _drop_wq {
 459         my ($self) = @_;
 460         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 461                 $wq->wq_kill('-TERM');
 462                 $wq->DESTROY;
 463         }
 464 }
 465
 466 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 467 sub x_it ($$) {
 468         my ($self, $code) = @_;
 469         local $current_lei = $self;
 470         # make sure client sees stdout before exit
 471         $self->{1}->autoflush(1) if $self->{1};
 472         stop_pager($self);
 473         if ($self->{pkt_op_p}) { # worker => lei-daemon
 474                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 475         } elsif ($self->{sock}) { # lei->daemon => lei(1) client
 476                 send($self->{sock}, "x_it $code", MSG_EOR);
 477         } elsif ($quit == \&CORE::exit) { # an admin (one-shot) command
 478                 exit($code >> 8);
 479         } # else ignore if client disconnected
 480 }
 481
 482 sub err ($;@) {
 483         my $self = shift;
 484         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 485         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 486         print $err @_, @eor and return;
 487         my $old_err = delete $self->{2};
 488         close($old_err) if $! == EPIPE && $old_err;
 489         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 490         print $err @_, @eor or print STDERR @_, @eor;
 491 }
 492
 493 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 494
 495 sub qfin { # show message on finalization (LeiFinmsg)
 496         my ($lei, $msg) = @_;
 497         return if $lei->{opt}->{quiet};
 498         $lei->{fmsg} ? push(@{$lei->{fmsg}}, "$msg\n") : qerr($lei, $msg);
 499 }
 500
 501 sub fail_handler ($;$$) {
 502         my ($lei, $code, $io) = @_;
 503         local $current_lei = $lei;
 504         close($io) if $io; # needed to avoid warnings on SIGPIPE
 505         _drop_wq($lei);
 506         x_it($lei, $code // (1 << 8));
 507 }
 508
 509 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 510         fail_handler($_[0], 13, delete $_[0]->{1});
 511 }
 512
 513 sub fail ($$;$) {
 514         my ($self, $msg, $exit_code) = @_;
 515         local $current_lei = $self;
 516         $self->{failed}++;
 517         warn(substr($msg, -1, 1) eq "\n" ? $msg : "$msg\n") if defined $msg;
 518         $self->{pkt_op_p}->pkt_do('fail_handler') if $self->{pkt_op_p};
 519         x_it($self, ($exit_code // 1) << 8);
 520         undef;
 521 }
 522
 523 sub out ($;@) {
 524         my $self = shift;
 525         return if print { $self->{1} // return } @_; # likely
 526         return note_sigpipe($self, 1) if $! == EPIPE;
 527         my $err = "error writing to output: $!";
 528         delete $self->{1};
 529         fail($self, $err);
 530 }
 531
 532 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 533
 534 sub child_error { # passes non-fatal curl exit codes to user
 535         my ($self, $child_error, $msg) = @_; # child_error is $?
 536         local $current_lei = $self;
 537         $child_error ||= 1 << 8;
 538         warn(substr($msg, -1, 1) eq "\n" ? $msg : "$msg\n") if defined $msg;
 539         if ($self->{pkt_op_p}) { # to top lei-daemon
 540                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 541         } elsif ($self->{sock}) { # to lei(1) client
 542                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 543         } else { # non-lei admin command
 544                 $self->{child_error} ||= $child_error;
 545         } # else noop if client disconnected
 546 }
 547
 548 sub note_sigpipe { # triggers sigpipe_handler
 549         my ($self, $fd) = @_;
 550         close(delete($self->{$fd})); # explicit close silences Perl warning
 551         $self->{pkt_op_p}->pkt_do('sigpipe_handler') if $self->{pkt_op_p};
 552         x_it($self, 13);
 553 }
 554
 555 sub _lei_atfork_child {
 556         my ($self, $persist) = @_;
 557         # we need to explicitly close things which are on stack
 558         if ($persist) {
 559                 open $self->{3}, '<', '/' or die "open(/) $!";
 560                 fchdir($self);
 561                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 562                 if (my $cfg = $self->{cfg}) {
 563                         delete @$cfg{qw(-lei_store -watches -lei_note_event)};
 564                 }
 565         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 566                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 567                 STDERR->autoflush(1);
 568                 POSIX::setpgid(0, $$) // die "setpgid(0, $$): $!";
 569         }
 570         close($_) for (grep(defined, delete @$self{qw(old_1 au_done)}));
 571         delete $self->{-socks};
 572         if (my $op_c = delete $self->{pkt_op_c}) {
 573                 close(delete $op_c->{sock});
 574         }
 575         if (my $pgr = delete $self->{pgr}) {
 576                 close($_) for (@$pgr[1,2]);
 577         }
 578         close $listener if $listener;
 579         undef $listener;
 580         $dir_idle->force_close if $dir_idle;
 581         undef $dir_idle;
 582         %PATH2CFG = ();
 583         $MDIR2CFGPATH = {};
 584         eval 'no warnings; undef $PublicInbox::LeiNoteEvent::to_flush';
 585         undef $errors_log;
 586         $quit = \&CORE::exit;
 587         if (!$self->{-eml_noisy}) { # only "lei import" sets this atm
 588                 my $cb = $SIG{__WARN__} // \&CORE::warn;
 589                 $SIG{__WARN__} = sub {
 590                         $cb->(@_) unless PublicInbox::Eml::warn_ignore(@_)
 591                 };
 592         }
 593         $SIG{TERM} = sub { exit(128 + 15) };
 594         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 595 }
 596
 597 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 598         my ($self) = @_;
 599         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 600                 $op->close; # PublicInbox::PktOp::close
 601         }
 602         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 603         close $pkt_op_p->{op_p};
 604 }
 605
 606 sub pkt_op_pair {
 607         my ($self) = @_;
 608         require PublicInbox::OnDestroy;
 609         require PublicInbox::PktOp;
 610         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 611         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 612         $end;
 613 }
 614
 615 sub incr {
 616         my ($self, $field, $nr) = @_;
 617         $self->{counters}->{$field} += $nr;
 618 }
 619
 620 sub pkt_ops {
 621         my ($lei, $ops) = @_;
 622         $ops->{fail_handler} = [ $lei ];
 623         $ops->{sigpipe_handler} = [ $lei ];
 624         $ops->{x_it} = [ $lei ];
 625         $ops->{child_error} = [ $lei ];
 626         $ops->{incr} = [ $lei ];
 627         $ops;
 628 }
 629
 630 sub workers_start {
 631         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 632         $ops = pkt_ops($lei, { ($ops ? %$ops : ()) });
 633         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 634         my $end = $lei->pkt_op_pair;
 635         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 636         $flds->{lei} = $lei;
 637         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 638         delete $lei->{pkt_op_p};
 639         my $op_c = delete $lei->{pkt_op_c};
 640         @$end = ();
 641         $lei->event_step_init;
 642         $wq->wq_wait_async($wq->can('_wq_done_wait') // \&wq_done_wait, $lei);
 643         ($op_c, $ops);
 644 }
 645
 646 # call this when we're ready to wait on events and yield to other clients
 647 sub wait_wq_events {
 648         my ($lei, $op_c, $ops) = @_;
 649         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 650                 $wq->wq_close;
 651         }
 652         $op_c->{ops} = $ops;
 653 }
 654
 655 sub _help {
 656         require PublicInbox::LeiHelp;
 657         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 658 }
 659
 660 sub optparse ($$$) {
 661         my ($self, $cmd, $argv) = @_;
 662         # allow _complete --help to complete, not show help
 663         return 1 if substr($cmd, 0, 1) eq '_';
 664         $self->{cmd} = $cmd;
 665         $OPT = $self->{opt} //= {};
 666         my $info = $CMD{$cmd} // [ '[...]' ];
 667         my ($proto, undef, @spec) = @$info;
 668         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 669         push @spec, qw(help|h);
 670         my $lone_dash;
 671         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 672                 $lone_dash = $spec[0];
 673                 $OPT->{$spec[0]} = \(my $var);
 674                 push @spec, '' => \$var;
 675         }
 676         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 677                 return _help($self, "bad arguments or options for $cmd");
 678         return _help($self) if $OPT->{help};
 679
 680         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 681
 682         # "-" aliases "stdin" or "clear"
 683         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 684
 685         my $i = 0;
 686         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 687         my ($err, $inf);
 688         my @args = split(/ /, $proto);
 689         for my $var (@args) {
 690                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 691                         $inf = defined($argv->[$i]) and last;
 692                         $var =~ s/\.\.\.\z//;
 693                         $err = "$var not supplied";
 694                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 695                         $argv->[$i++] // ($err = "$var not supplied");
 696                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 697                         $inf = 1;
 698                         last;
 699                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 700                         $i++;
 701                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 702                         $inf = 1 if index($var, '...') > 0;
 703                         my @or = split(/\|/, $var);
 704                         my $ok;
 705                         for my $o (@or) {
 706                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 707                                         my $sw = $1;
 708                                         # assume pipe/regular file on stdin
 709                                         # w/o args means stdin
 710                                         if ($sw eq 'stdin' && !@$argv &&
 711                                                         (-p $self->{0} ||
 712                                                          -f _) && -r _) {
 713                                                 $OPT->{stdin} //= 1;
 714                                         }
 715                                         $ok = defined($OPT->{$sw});
 716                                         last if $ok;
 717                                 } elsif (defined($argv->[$i])) {
 718                                         $ok = 1;
 719                                         $i++;
 720                                         last;
 721                                 } # else continue looping
 722                         }
 723                         last if $ok;
 724                         my $last = pop @or;
 725                         $err = join(', ', @or) . " or $last must be set";
 726                 } else {
 727                         warn "BUG: can't parse `$var' in $proto";
 728                 }
 729                 last if $err;
 730         }
 731         if (!$inf && scalar(@$argv) > scalar(@args)) {
 732                 $err //= 'too many arguments';
 733         }
 734         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 735 }
 736
 737 sub _tmp_cfg { # for lei -c <name>=<value> ...
 738         my ($self) = @_;
 739         my $cfg = _lei_cfg($self, 1);
 740         require File::Temp;
 741         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 742         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 743         $ft->autoflush(1);
 744         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 745 [include]
 746         path = $cfg->{-f}
 747 EOM
 748         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 749         for (@{$self->{opt}->{c}}) {
 750                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 751 `-c $_' is not of the form -c <name>=<value>'
 752 EOM
 753                 my $name = $1;
 754                 my $value = $2 // 1;
 755                 _config($self, '--add', $name, $value);
 756                 if (defined(my $v = $tmp->{$name})) {
 757                         if (ref($v) eq 'ARRAY') {
 758                                 push @$v, $value;
 759                         } else {
 760                                 $tmp->{$name} = [ $v, $value ];
 761                         }
 762                 } else {
 763                         $tmp->{$name} = $value;
 764                 }
 765         }
 766 }
 767
 768 sub lazy_cb ($$$) {
 769         my ($self, $cmd, $pfx) = @_;
 770         my $ucmd = $cmd;
 771         $ucmd =~ tr/-/_/;
 772         my $cb;
 773         $cb = $self->can($pfx.$ucmd) and return $cb;
 774         my $base = $ucmd;
 775         $base =~ s/_([a-z])/\u$1/g;
 776         my $pkg = "PublicInbox::Lei\u$base";
 777         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 778                 $pkg->can($pfx.$ucmd) : undef;
 779 }
 780
 781 sub dispatch {
 782         my ($self, $cmd, @argv) = @_;
 783         fchdir($self);
 784         local %ENV = %{$self->{env}};
 785         local $current_lei = $self; # for __WARN__
 786         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 787         return _help($self, 'no command given') unless defined($cmd);
 788         # do not support Getopt bundling for this
 789         while ($cmd eq '-C' || $cmd eq '-c') {
 790                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 791                                         '-C DIRECTORY' : '-c <name>=<value>');
 792                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 793                 $cmd = shift(@argv) // return _help($self, 'no command given');
 794         }
 795         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 796                 optparse($self, $cmd, \@argv) or return;
 797                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 798                 if (my $chdir = $self->{opt}->{C}) {
 799                         for my $d (@$chdir) {
 800                                 next if $d eq ''; # same as git(1)
 801                                 chdir $d or return fail($self, "cd $d: $!");
 802                         }
 803                         open $self->{3}, '.' or return fail($self, "open . $!");
 804                 }
 805                 $cb->($self, @argv);
 806         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 807                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 808                         or return _help($self, 'bad arguments or options');
 809                 _help($self);
 810         } else {
 811                 fail($self, "`$cmd' is not an lei command");
 812         }
 813 }
 814
 815 sub _lei_cfg ($;$) {
 816         my ($self, $creat) = @_;
 817         return $self->{cfg} if $self->{cfg};
 818         my $f = _config_path($self);
 819         my @st = stat($f);
 820         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 821         my ($sto, $sto_dir, $watches, $lne);
 822         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 823                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 824                 ($sto, $sto_dir, $watches, $lne) =
 825                                 @$cfg{qw(-lei_store leistore.dir -watches
 826                                         -lei_note_event)};
 827         }
 828         if (!@st) {
 829                 unless ($creat) {
 830                         delete $self->{cfg};
 831                         return bless {}, 'PublicInbox::Config';
 832                 }
 833                 my ($cfg_dir) = ($f =~ m!(.*?/)[^/]+\z!);
 834                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 835                 open my $fh, '>>', $f or die "open($f): $!\n";
 836                 @st = stat($fh) or die "fstat($f): $!\n";
 837                 $cur_st = pack('dd', $st[10], $st[7]);
 838                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 839         }
 840         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{2});
 841         $cfg->{-st} = $cur_st;
 842         $cfg->{'-f'} = $f;
 843         if ($sto && canonpath_harder($sto_dir // store_path($self))
 844                         eq canonpath_harder($cfg->{'leistore.dir'} //
 845                                                 store_path($self))) {
 846                 $cfg->{-lei_store} = $sto;
 847                 $cfg->{-lei_note_event} = $lne;
 848                 $cfg->{-watches} = $watches if $watches;
 849         }
 850         if (scalar(keys %PATH2CFG) > 5) {
 851                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 852                 delete(@PATH2CFG{grep(!-f, keys %PATH2CFG)});
 853         }
 854         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 855         refresh_watches($self);
 856         $cfg;
 857 }
 858
 859 sub _lei_store ($;$) {
 860         my ($self, $creat) = @_;
 861         my $cfg = _lei_cfg($self, $creat) // return;
 862         $cfg->{-lei_store} //= do {
 863                 require PublicInbox::LeiStore;
 864                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 865                 return unless $creat || -d $dir;
 866                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 867         };
 868 }
 869
 870 sub _config {
 871         my ($self, @argv) = @_;
 872         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 873         my $cfg = _lei_cfg($self, 1);
 874         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 875         my %rdr = map { $_ => $self->{$_} } (0..2);
 876         waitpid(spawn($cmd, \%env, \%rdr), 0);
 877 }
 878
 879 sub lei_daemon_pid { puts shift, $$ }
 880
 881 sub lei_daemon_kill {
 882         my ($self) = @_;
 883         my $sig = $self->{opt}->{signal} // 'TERM';
 884         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 885 }
 886
 887 # Shell completion helper.  Used by lei-completion.bash and hopefully
 888 # other shells.  Try to do as much here as possible to avoid redundancy
 889 # and improve maintainability.
 890 sub lei__complete {
 891         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 892         shift @argv; # ignore "lei", the entire command is sent
 893         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 894         my $cmd = shift @argv;
 895         my $info = $CMD{$cmd} // do { # filter matching commands
 896                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 897                 return;
 898         };
 899         my ($proto, undef, @spec) = @$info;
 900         my $cur = pop @argv;
 901         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 902         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 903                 # gross special case since the only git-config options
 904                 # Consider moving to a table if we need more special cases
 905                 # we use Getopt::Long for are the ones we reject, so these
 906                 # are the ones we don't reject:
 907                 if ($cmd eq 'config') {
 908                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 909                         @spec = qw(add z|null get get-all unset unset-all
 910                                 replace-all get-urlmatch
 911                                 remove-section rename-section
 912                                 name-only list|l edit|e
 913                                 get-color-name get-colorbool);
 914                         # fall-through
 915                 }
 916                 # generate short/long names from Getopt::Long specs
 917                 puts $self, grep(/$re/, qw(--help -h -C), map {
 918                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 919                         } elsif (s/\+\z//) { # verbose|v+
 920                         } elsif (s/!\z//) {
 921                                 # negation: mail! => no-mail|mail
 922                                 s/([\w\-]+)/$1|no-$1/g
 923                         }
 924                         map {
 925                                 my $x = length > 1 ? "--$_" : "-$_";
 926                                 $x eq $_cur ? () : $x;
 927                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 928                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 929         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 930                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 931         }
 932
 933         # switch args (e.g. lei q -f mbox<TAB>)
 934         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 935                 my $opt = quotemeta $1;
 936                 puts $self, map {
 937                         my $v = $OPTDESC{$_};
 938                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 939                         # get rid of ALL CAPS placeholder (e.g "OUT")
 940                         # (TODO: completion for external paths)
 941                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 942                         @v;
 943                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 944         }
 945         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 946                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 947         }
 948         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 949         # proto parsing.
 950 }
 951
 952 sub exec_buf ($$) {
 953         my ($argv, $env) = @_;
 954         my $argc = scalar @$argv;
 955         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 956         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 957         $buf;
 958 }
 959
 960 sub start_mua {
 961         my ($self) = @_;
 962         if ($self->{ovv}->{fmt} =~ /\A(?:maildir)\z/) { # TODO: IMAP
 963                 refresh_watches($self);
 964         }
 965         my $mua = $self->{opt}->{mua} // return;
 966         my $mfolder = $self->{ovv}->{dst};
 967         my (@cmd, $replaced);
 968         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 969                 @cmd = ($mua, '-f');
 970         # TODO: help wanted: other common FOSS MUAs
 971         } else {
 972                 require Text::ParseWords;
 973                 @cmd = Text::ParseWords::shellwords($mua);
 974                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 975                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 976         }
 977         push @cmd, $mfolder unless defined($replaced);
 978         if ($self->{sock}) { # lei(1) client process runs it
 979                 # restore terminal: echo $query | lei q --stdin --mua=...
 980                 my $io = [];
 981                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 982                 send_exec_cmd($self, $io, \@cmd, {});
 983         }
 984         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 985                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 986         }
 987         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 988         $self->{opt}->{quiet} = 1;
 989         delete $self->{-progress};
 990         delete $self->{opt}->{verbose};
 991 }
 992
 993 sub send_exec_cmd { # tell script/lei to execute a command
 994         my ($self, $io, $cmd, $env) = @_;
 995         my $sock = $self->{sock} // die 'lei client gone';
 996         my $fds = [ map { fileno($_) } @$io ];
 997         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 998 }
 999
1000 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
1001         my ($self) = @_;
1002         my $alerts = $self->{opt}->{alert} // return;
1003         my $sock = $self->{sock};
1004         while (my $op = shift(@$alerts)) {
1005                 if ($op eq ':WINCH') {
1006                         # hit the process group that started the MUA
1007                         send($sock, '-WINCH', MSG_EOR) if $sock;
1008                 } elsif ($op eq ':bell') {
1009                         out($self, "\a");
1010                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
1011                         push @$alerts, split(/(?<!\\),/, $op);
1012                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
1013                         my $cmd = $1; # run an arbitrary command
1014                         require Text::ParseWords;
1015                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
1016                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
1017                 } else {
1018                         warn("W: unsupported --alert=$op\n"); # non-fatal
1019                 }
1020         }
1021 }
1022
1023 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
1024 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
1025
1026 # this also normalizes the path
1027 sub path_to_fd {
1028         my ($self, $path) = @_;
1029         $path = rel2abs($self, $path);
1030         $path =~ tr!/!/!s;
1031         $path_to_fd{$path} // (
1032                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
1033                         fail($self, "cannot open $path from daemon") : -1
1034         );
1035 }
1036
1037 # caller needs to "-t $self->{1}" to check if tty
1038 sub start_pager {
1039         my ($self, $new_env) = @_;
1040         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1041         chomp(my $pager = <$fh> // '');
1042         close($fh) or warn "`git var PAGER' error: \$?=$?";
1043         return if $pager eq 'cat' || $pager eq '';
1044         $new_env //= {};
1045         $new_env->{LESS} //= 'FRX';
1046         $new_env->{LV} //= '-c';
1047         $new_env->{MORE} = $new_env->{LESS} if $^O eq 'freebsd';
1048         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1049         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1050         my $pgr = [ undef, @$rdr{1, 2} ];
1051         my $env = $self->{env};
1052         if ($self->{sock}) { # lei(1) process runs it
1053                 delete @$new_env{keys %$env}; # only set iff unset
1054                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1055         } else {
1056                 die 'BUG: start_pager w/o socket';
1057         }
1058         $self->{1} = $wpager;
1059         $self->{2} = $wpager if -t $self->{2};
1060         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1061         $self->{pgr} = $pgr;
1062 }
1063
1064 # display a message for user before spawning full-screen $VISUAL
1065 sub pgr_err {
1066         my ($self, @msg) = @_;
1067         return warn(@msg) unless $self->{sock} && -t $self->{2};
1068         start_pager($self, { LESS => 'RX' }); # no 'F' so we prompt
1069         print { $self->{2} } @msg;
1070         $self->{2}->autoflush(1);
1071         stop_pager($self);
1072         send($self->{sock}, 'wait', MSG_EOR); # wait for user to quit pager
1073 }
1074
1075 sub stop_pager {
1076         my ($self) = @_;
1077         my $pgr = delete($self->{pgr}) or return;
1078         $self->{2} = $pgr->[2];
1079         close(delete($self->{1})) if $self->{1};
1080         $self->{1} = $pgr->[1];
1081 }
1082
1083 sub accept_dispatch { # Listener {post_accept} callback
1084         my ($sock) = @_; # ignore other
1085         $sock->autoflush(1);
1086         my $self = bless { sock => $sock }, __PACKAGE__;
1087         vec(my $rvec = '', fileno($sock), 1) = 1;
1088         select($rvec, undef, undef, 60) or
1089                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1090         # (4096 * 33) >MAX_ARG_STRLEN
1091         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1092         if (!defined($fds[0])) {
1093                 warn(my $msg = "recv_cmd failed: $!");
1094                 return send($sock, $msg, MSG_EOR);
1095         } else {
1096                 my $i = 0;
1097                 for my $fd (@fds) {
1098                         open($self->{$i++}, '+<&=', $fd) and next;
1099                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1100                 }
1101                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1102         }
1103         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1104         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1105         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1106                 return send($sock, 'request command truncated', MSG_EOR);
1107         my ($argc, @argv) = split(/\0/, $buf, -1);
1108         undef $buf;
1109         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1110         $self->{env} = \%env;
1111         eval { dispatch($self, @argv) };
1112         $self->fail($@) if $@;
1113 }
1114
1115 sub dclose {
1116         my ($self) = @_;
1117         local $current_lei = $self;
1118         delete $self->{-progress};
1119         _drop_wq($self) if $self->{failed};
1120         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1121 }
1122
1123 # for long-running results
1124 sub event_step {
1125         my ($self) = @_;
1126         local %ENV = %{$self->{env}};
1127         local $current_lei = $self;
1128         eval {
1129                 my @fds = $recv_cmd->($self->{sock}, my $buf, 4096);
1130                 if (scalar(@fds) == 1 && !defined($fds[0])) {
1131                         return if $! == EAGAIN;
1132                         die "recvmsg: $!" if $! != ECONNRESET;
1133                         @fds = (); # for open loop below:
1134                 }
1135                 for (@fds) { open my $rfh, '+<&=', $_ }
1136                 if ($buf eq '') {
1137                         _drop_wq($self); # EOF, client disconnected
1138                         dclose($self);
1139                         $buf = 'TERM';
1140                 }
1141                 if ($buf =~ /\A(?:STOP|CONT|TERM)\z/) {
1142                         my $sig = "-$buf";
1143                         for my $wq (grep(defined, @$self{@WQ_KEYS})) {
1144                                 $wq->wq_kill($sig);
1145                         }
1146                 } else {
1147                         die "unrecognized client signal: $buf";
1148                 }
1149                 my $s = $self->{-socks} // []; # lei up --all
1150                 @$s = grep { send($_, $buf, MSG_EOR) } @$s;
1151         };
1152         if (my $err = $@) {
1153                 eval { $self->fail($err) };
1154                 dclose($self);
1155         }
1156 }
1157
1158 sub event_step_init {
1159         my ($self) = @_;
1160         my $sock = $self->{sock} or return;
1161         $self->{-event_init_done} //= do { # persist til $ops done
1162                 $sock->blocking(0);
1163                 $self->SUPER::new($sock, EPOLLIN);
1164                 $sock;
1165         };
1166 }
1167
1168 sub noop {}
1169
1170 sub oldset { $oldset }
1171
1172 sub dump_and_clear_log {
1173         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1174                 openlog('lei-daemon', 'pid,nowait,nofatal,ndelay', 'user');
1175                 chomp(my @lines = <STDIN>);
1176                 truncate(STDIN, 0) or
1177                         syslog('warning', "ftruncate (%s): %m", $errors_log);
1178                 for my $l (@lines) { syslog('warning', '%s', $l) }
1179                 closelog(); # don't share across fork
1180         }
1181 }
1182
1183 sub cfg2lei ($) {
1184         my ($cfg) = @_;
1185         my $lei = bless { env => { %{$cfg->{-env}} } }, __PACKAGE__;
1186         open($lei->{0}, '<&', \*STDIN) or die "dup 0: $!";
1187         open($lei->{1}, '>>&', \*STDOUT) or die "dup 1: $!";
1188         open($lei->{2}, '>>&', \*STDERR) or die "dup 2: $!";
1189         open($lei->{3}, '<', '/') or die "open /: $!";
1190         my ($x, $y);
1191         socketpair($x, $y, AF_UNIX, SOCK_SEQPACKET, 0) or die "socketpair: $!";
1192         $lei->{sock} = $x;
1193         require PublicInbox::LeiSelfSocket;
1194         PublicInbox::LeiSelfSocket->new($y); # adds to event loop
1195         $lei;
1196 }
1197
1198 sub dir_idle_handler ($) { # PublicInbox::DirIdle callback
1199         my ($ev) = @_; # Linux::Inotify2::Event or duck type
1200         my $fn = $ev->fullname;
1201         if ($fn =~ m!\A(.+)/(new|cur)/([^/]+)\z!) { # Maildir file
1202                 my ($mdir, $nc, $bn) = ($1, $2, $3);
1203                 $nc = '' if $ev->IN_DELETE || $ev->IN_MOVED_FROM;
1204                 for my $f (keys %{$MDIR2CFGPATH->{$mdir} // {}}) {
1205                         my $cfg = $PATH2CFG{$f} // next;
1206                         eval {
1207                                 my $lei = cfg2lei($cfg);
1208                                 $lei->dispatch('note-event',
1209                                                 "maildir:$mdir", $nc, $bn, $fn);
1210                         };
1211                         warn "E: note-event $f: $@\n" if $@;
1212                 }
1213         }
1214         if ($ev->can('cancel') && ($ev->IN_IGNORE || $ev->IN_UNMOUNT)) {
1215                 $ev->cancel;
1216         }
1217         if ($fn =~ m!\A(.+)/(?:new|cur)\z! && !-e $fn) {
1218                 delete $MDIR2CFGPATH->{$1};
1219         }
1220         if (!-e $fn) { # config file or Maildir gone
1221                 for my $cfgpaths (values %$MDIR2CFGPATH) {
1222                         delete $cfgpaths->{$fn};
1223                 }
1224                 delete $PATH2CFG{$fn};
1225         }
1226 }
1227
1228 # lei(1) calls this when it can't connect
1229 sub lazy_start {
1230         my ($path, $errno, $narg) = @_;
1231         local ($errors_log, $listener);
1232         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1233         $errors_log = "$sock_dir/errors.log";
1234         my $addr = pack_sockaddr_un($path);
1235         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1236         umask(077) // die("umask(077): $!");
1237         $lk->lock_acquire;
1238         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1239         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1240                 return if connect($listener, $addr); # another process won
1241                 if ($errno == ECONNREFUSED && -S $path) {
1242                         unlink($path) or die "unlink($path): $!";
1243                 }
1244         } else {
1245                 $! = $errno; # allow interpolation to stringify in die
1246                 die "connect($path): $!";
1247         }
1248         bind($listener, $addr) or die "bind($path): $!";
1249         $lk->lock_release;
1250         undef $lk;
1251         my @st = stat($path) or die "stat($path): $!";
1252         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1253         local $oldset = PublicInbox::DS::block_signals();
1254         if ($narg == 5) {
1255                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1256                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1257                         require PublicInbox::CmdIPC4;
1258                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1259                         PublicInbox::CmdIPC4->can('recv_cmd4');
1260                 };
1261         }
1262         $recv_cmd or die <<"";
1263 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1264
1265         require PublicInbox::Listener;
1266         require PublicInbox::PktOp;
1267         (-p STDOUT) or die "E: stdout must be a pipe\n";
1268         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1269         STDIN->autoflush(1);
1270         dump_and_clear_log();
1271         POSIX::setsid() > 0 or die "setsid: $!";
1272         my $pid = fork // die "fork: $!";
1273         return if $pid;
1274         $0 = "lei-daemon $path";
1275         local %PATH2CFG;
1276         local $MDIR2CFGPATH;
1277         $listener->blocking(0);
1278         my $exit_code;
1279         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1280         local $quit = do {
1281                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1282                 sub {
1283                         $exit_code //= shift;
1284                         eval 'PublicInbox::LeiNoteEvent::flush_task()';
1285                         my $lis = $pil or exit($exit_code);
1286                         # closing eof_p triggers \&noop wakeup
1287                         $listener = $eof_p = $pil = $path = undef;
1288                         $lis->close; # DS::close
1289                         PublicInbox::DS->SetLoopTimeout(1000);
1290                 };
1291         };
1292         my $sig = {
1293                 CHLD => \&PublicInbox::DS::enqueue_reap,
1294                 QUIT => $quit,
1295                 INT => $quit,
1296                 TERM => $quit,
1297                 HUP => \&noop,
1298                 USR1 => \&noop,
1299                 USR2 => \&noop,
1300         };
1301         require PublicInbox::DirIdle;
1302         local $dir_idle = PublicInbox::DirIdle->new(sub {
1303                 # just rely on wakeup to hit PostLoopCallback set below
1304                 dir_idle_handler($_[0]) if $_[0]->fullname ne $path;
1305         });
1306         $dir_idle->add_watches([$sock_dir]);
1307         PublicInbox::DS->SetPostLoopCallback(sub {
1308                 my ($dmap, undef) = @_;
1309                 if (@st = defined($path) ? stat($path) : ()) {
1310                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1311                                 warn "$path dev/ino changed, quitting\n";
1312                                 $path = undef;
1313                         }
1314                 } elsif (defined($path)) { # ENOENT is common
1315                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1316                         undef $path;
1317                         $quit->();
1318                 }
1319                 return 1 if defined($path);
1320                 my $n = 0;
1321                 for my $s (values %$dmap) {
1322                         $s->can('busy') or next;
1323                         if ($s->busy) {
1324                                 ++$n;
1325                         } else {
1326                                 $s->close;
1327                         }
1328                 }
1329                 $n; # true: continue, false: stop
1330         });
1331
1332         # STDIN was redirected to /dev/null above, closing STDERR and
1333         # STDOUT will cause the calling `lei' client process to finish
1334         # reading the <$daemon> pipe.
1335         local $SIG{__WARN__} = sub {
1336                 $current_lei ? err($current_lei, @_) : warn(
1337                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1338         };
1339         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1340         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1341         # $daemon pipe to `lei' closed, main loop begins:
1342         eval { PublicInbox::DS::event_loop($sig, $oldset) };
1343         warn "event loop error: $@\n" if $@;
1344         # exit() may trigger waitpid via various DESTROY, ensure interruptible
1345         PublicInbox::DS::sig_setmask($oldset);
1346         dump_and_clear_log();
1347         exit($exit_code // 0);
1348 }
1349
1350 sub busy { 1 } # prevent daemon-shutdown if client is connected
1351
1352 # ensures stdout hits the FS before sock disconnects so a client
1353 # can immediately reread it
1354 sub DESTROY {
1355         my ($self) = @_;
1356         if (my $counters = delete $self->{counters}) {
1357                 for my $k (sort keys %$counters) {
1358                         my $nr = $counters->{$k};
1359                         $self->child_error(0, "$nr $k messages");
1360                 }
1361         }
1362         $self->{1}->autoflush(1) if $self->{1};
1363         stop_pager($self);
1364         dump_and_clear_log();
1365         # preserve $? for ->fail or ->x_it code
1366 }
1367
1368 sub wq_done_wait { # dwaitpid callback
1369         my ($arg, $pid) = @_;
1370         my ($wq, $lei) = @$arg;
1371         local $current_lei = $lei;
1372         my $err_type = $lei->{-err_type};
1373         $? and $lei->child_error($?,
1374                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1375         $lei->dclose;
1376 }
1377
1378 sub fchdir {
1379         my ($lei) = @_;
1380         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1381         chdir($dh) || die "fchdir: $!";
1382 }
1383
1384 sub wq_eof { # EOF callback for main daemon
1385         my ($lei) = @_;
1386         local $current_lei = $lei;
1387         delete $lei->{wq1} // return $lei->fail; # already failed
1388 }
1389
1390 sub watch_state_ok ($) {
1391         my ($state) = $_[-1]; # $_[0] may be $self
1392         $state =~ /\Apause|(?:import|index|tag)-(?:ro|rw)\z/;
1393 }
1394
1395 sub cancel_maildir_watch ($$) {
1396         my ($d, $cfg_f) = @_;
1397         my $w = delete $MDIR2CFGPATH->{$d}->{$cfg_f};
1398         scalar(keys %{$MDIR2CFGPATH->{$d}}) or
1399                 delete $MDIR2CFGPATH->{$d};
1400         for my $x (@{$w // []}) { $x->cancel }
1401 }
1402
1403 sub add_maildir_watch ($$) {
1404         my ($d, $cfg_f) = @_;
1405         if (!exists($MDIR2CFGPATH->{$d}->{$cfg_f})) {
1406                 my @w = $dir_idle->add_watches(["$d/cur", "$d/new"], 1);
1407                 push @{$MDIR2CFGPATH->{$d}->{$cfg_f}}, @w if @w;
1408         }
1409 }
1410
1411 sub refresh_watches {
1412         my ($lei) = @_;
1413         $dir_idle or return;
1414         my $cfg = _lei_cfg($lei) or return;
1415         my $old = $cfg->{-watches};
1416         my $watches = $cfg->{-watches} //= {};
1417         my %seen;
1418         my $cfg_f = $cfg->{'-f'};
1419         for my $w (grep(/\Awatch\..+\.state\z/, keys %$cfg)) {
1420                 my $url = substr($w, length('watch.'), -length('.state'));
1421                 require PublicInbox::LeiWatch;
1422                 $watches->{$url} //= PublicInbox::LeiWatch->new($url);
1423                 $seen{$url} = undef;
1424                 my $state = $cfg->get_1("watch.$url.state");
1425                 if (!watch_state_ok($state)) {
1426                         warn("watch.$url.state=$state not supported\n");
1427                         next;
1428                 }
1429                 if ($url =~ /\Amaildir:(.+)/i) {
1430                         my $d = canonpath_harder($1);
1431                         if ($state eq 'pause') {
1432                                 cancel_maildir_watch($d, $cfg_f);
1433                         } else {
1434                                 add_maildir_watch($d, $cfg_f);
1435                         }
1436                 } else { # TODO: imap/nntp/jmap
1437                         $lei->child_error(0, "E: watch $url not supported, yet")
1438                 }
1439         }
1440
1441         # add all known Maildir folders as implicit watches
1442         my $lms = $lei->lms;
1443         if ($lms) {
1444                 $lms->lms_write_prepare;
1445                 for my $d ($lms->folders('maildir:')) {
1446                         substr($d, 0, length('maildir:')) = '';
1447
1448                         # fixup old bugs while we're iterating:
1449                         my $cd = canonpath_harder($d);
1450                         my $f = "maildir:$cd";
1451                         $lms->rename_folder("maildir:$d", $f) if $d ne $cd;
1452                         next if $watches->{$f}; # may be set to pause
1453                         require PublicInbox::LeiWatch;
1454                         $watches->{$f} = PublicInbox::LeiWatch->new($f);
1455                         $seen{$f} = undef;
1456                         add_maildir_watch($cd, $cfg_f);
1457                 }
1458         }
1459         if ($old) { # cull old non-existent entries
1460                 for my $url (keys %$old) {
1461                         next if exists $seen{$url};
1462                         delete $old->{$url};
1463                         if ($url =~ /\Amaildir:(.+)/i) {
1464                                 my $d = canonpath_harder($1);
1465                                 cancel_maildir_watch($d, $cfg_f);
1466                         } else { # TODO: imap/nntp/jmap
1467                                 $lei->child_error(0, "E: watch $url TODO");
1468                         }
1469                 }
1470         }
1471         if (scalar keys %$watches) {
1472                 $cfg->{-env} //= { %{$lei->{env}}, PWD => '/' }; # for cfg2lei
1473         } else {
1474                 delete $cfg->{-watches};
1475         }
1476 }
1477
1478 # TODO: support SHA-256
1479 sub git_oid {
1480         my $eml = $_[-1];
1481         $eml->header_set($_) for @PublicInbox::Import::UNWANTED_HEADERS;
1482         git_sha(1, $eml);
1483 }
1484
1485 sub lms {
1486         my ($lei, $rw) = @_;
1487         my $sto = $lei->{sto} // _lei_store($lei) // return;
1488         require PublicInbox::LeiMailSync;
1489         my $f = "$sto->{priv_eidx}->{topdir}/mail_sync.sqlite3";
1490         (-f $f || $rw) ? PublicInbox::LeiMailSync->new($f) : undef;
1491 }
1492
1493 sub sto_done_request {
1494         my ($lei, $sock) = @_;
1495         local $current_lei = $lei;
1496         eval {
1497                 if ($sock //= $lei->{sock}) { # issue, async wait
1498                         $lei->{sto}->wq_io_do('done', [ $sock ]);
1499                 } else { # forcibly wait
1500                         my $wait = $lei->{sto}->wq_do('done');
1501                 }
1502         };
1503         warn($@) if $@;
1504 }
1505
1506 sub cfg_dump ($$) {
1507         my ($lei, $f) = @_;
1508         my $ret = eval { PublicInbox::Config->git_config_dump($f, $lei->{2}) };
1509         return $ret if !$@;
1510         warn($@);
1511         undef;
1512 }
1513
1514 sub request_umask {
1515         my ($lei) = @_;
1516         my $s = $lei->{sock} // return;
1517         send($s, 'umask', MSG_EOR) // die "send: $!";
1518         vec(my $rvec = '', fileno($s), 1) = 1;
1519         select($rvec, undef, undef, 2) or die 'timeout waiting for umask';
1520         recv($s, my $v, 5, 0) // die "recv: $!";
1521         (my $u, $lei->{client_umask}) = unpack('AV', $v);
1522         $u eq 'u' or warn "E: recv $v has no umask";
1523 }
1524
1525 1;