lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use POSIX ();
  17 use IO::Handle ();
  18 use Fcntl qw(SEEK_SET);
  19 use Sys::Syslog qw(syslog openlog);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn run_die popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log, $listener);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub _store_path ($) {
  68         my ($env) = @_;
  69         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  70                 ($env->{HOME} // '/nonexistent').'/.local/share')
  71                 .'/lei/store', $env->{PWD});
  72 }
  73
  74 sub _config_path ($) {
  75         my ($env) = @_;
  76         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  77                 ($env->{HOME} // '/nonexistent').'/.config')
  78                 .'/lei/config', $env->{PWD});
  79 }
  80
  81 # TODO: generate shell completion + help using %CMD and %OPTDESC
  82 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  83 our %CMD = ( # sorted in order of importance/use:
  84 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  85         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  86         sort|s=s reverse|r offset=i remote local! external! pretty mua-cmd=s
  87         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  88
  89 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  90         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  91         pass_through('git show') ],
  92
  93 'add-external' => [ 'URL_OR_PATHNAME',
  94         'add/set priority of a publicinbox|extindex for extra matches',
  95         qw(boost=i quiet|q) ],
  96 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  97         qw(format|f=s z|0 local remote quiet|q) ],
  98 'forget-external' => [ '{URL_OR_PATHNAME|--prune}',
  99         'exclude further results from a publicinbox|extindex',
 100         qw(prune quiet|q) ],
 101
 102 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 103                 qw(name-only format|f=s z) ],
 104 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 105 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 106
 107 'plonk' => [ '--thread|--from=IDENT',
 108         'exclude mail matching From: or thread from non-Message-ID searches',
 109         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 110 'mark' => [ 'MESSAGE_FLAGS...',
 111         'set/unset flags on message(s) from stdin',
 112         qw(stdin| oid=s exact by-mid|mid:s) ],
 113 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 114         "exclude message(s) on stdin from `q' search results",
 115         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 116
 117 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 118         'remove imported messages from IMAP, Maildirs, and MH',
 119         qw(exact! all jobs:i indexed) ],
 120
 121 # code repos are used for `show' to solve blobs from patch mails
 122 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 123         qw(boost=i) ],
 124 'ls-coderepo' => [ '[FILTER_TERMS...]',
 125                 'list known code repos', qw(format|f=s z) ],
 126 'forget-coderepo' => [ 'PATHNAME',
 127         'stop using repo to solve blobs from patches',
 128         qw(prune) ],
 129
 130 'add-watch' => [ '[URL_OR_PATHNAME]',
 131                 'watch for new messages and flag changes',
 132         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 133 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 134                 qw(format|f=s z) ],
 135 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 136 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 137 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 138         qw(prune) ],
 139
 140 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 141         'one-shot import/update from URL or filesystem',
 142         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 143         ],
 144
 145 'config' => [ '[...]', sub {
 146                 'git-config(1) wrapper for '._config_path($_[0]);
 147         }, qw(config-file|system|global|file|f=s), # for conflict detection
 148         pass_through('git config') ],
 149 'init' => [ '[PATHNAME]', sub {
 150                 'initialize storage, default: '._store_path($_[0]);
 151         }, qw(quiet|q) ],
 152 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 153         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 154 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 155 'help' => [ '[SUBCOMMAND]', 'show help' ],
 156
 157 # XXX do we need this?
 158 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 159
 160 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 161         'rewrite git history in an attempt to improve compression',
 162         'gc!' ],
 163
 164 # internal commands are prefixed with '_'
 165 '_complete' => [ '[...]', 'internal shell completion helper',
 166                 pass_through('everything') ],
 167 ); # @CMD
 168
 169 # switch descriptions, try to keep consistent across commands
 170 # $spec: Getopt::Long option specification
 171 # $spec => [@ALLOWED_VALUES (default is first), $description],
 172 # $spec => $description
 173 # "$SUB_COMMAND TAB $spec" => as above
 174 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 175                 'specify message input format' ];
 176 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 177
 178 my %OPTDESC = (
 179 'help|h' => 'show this built-in help',
 180 'quiet|q' => 'be quiet',
 181 'solve!' => 'do not attempt to reconstruct blobs from emails',
 182 'save-as=s' => ['NAME', 'save a search terms by given name'],
 183
 184 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 185
 186 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 187                 'deduplication strategy'],
 188 'show   thread|t' => 'display entire thread a message belongs to',
 189 'q      thread|t' =>
 190         'return all messages in the same thread as the actual match(es)',
 191 'augment|a' => 'augment --output destination instead of clobbering',
 192
 193 'output|o=s' => [ 'DEST',
 194         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 195 'mua-cmd|mua=s' => [ 'COMMAND',
 196         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 197
 198 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 199                         'message/object output format' ],
 200 'mark   format|f=s' => $stdin_formats,
 201 'forget format|f=s' => $stdin_formats,
 202 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 203                 'specify output format, default depends on --output'],
 204 'ls-query       format|f=s' => $ls_format,
 205 'ls-external    format|f=s' => $ls_format,
 206
 207 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 208 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 209
 210 'sort|s=s' => [ 'VAL|received,relevance,docid',
 211                 "order of results `--output'-dependent"],
 212 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 213
 214 'boost=i' => 'increase/decrease priority of results (default: 0)',
 215
 216 'local' => 'limit operations to the local filesystem',
 217 'local!' => 'exclude results from the local filesystem',
 218 'remote' => 'limit operations to those requiring network access',
 219 'remote!' => 'prevent operations requiring network access',
 220
 221 'mid=s' => 'specify the Message-ID of a message',
 222 'oid=s' => 'specify the git object ID of a message',
 223
 224 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 225 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 226 'include=s' => 'include mailboxes/newsgroups based on pattern',
 227
 228 'exact' => 'operate on exact header matches only',
 229 'exact!' => 'rely on content match instead of exact header matches',
 230
 231 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 232 'jobs:i' => 'set parallelism level',
 233
 234 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 235 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 236
 237 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 238 ); # %OPTDESC
 239
 240 my %CONFIG_KEYS = (
 241         'leistore.dir' => 'top-level storage location',
 242 );
 243
 244 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 245 sub x_it ($$) {
 246         my ($self, $code) = @_;
 247         # make sure client sees stdout before exit
 248         $self->{1}->autoflush(1) if $self->{1};
 249         dump_and_clear_log();
 250         if (my $sock = $self->{sock}) {
 251                 send($sock, "x_it $code", MSG_EOR);
 252         } elsif (!($code & 127)) { # oneshot, ignore signals
 253                 # don't want to end up using $? from child processes
 254                 for my $f (qw(lxs l2m)) {
 255                         my $wq = delete $self->{$f} or next;
 256                         $wq->DESTROY;
 257                 }
 258                 $quit->($code >> 8);
 259         }
 260 }
 261
 262 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 263
 264 sub out ($;@) { print { shift->{1} } @_ }
 265
 266 sub err ($;@) {
 267         my $self = shift;
 268         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{IO};
 269         print $err @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 270 }
 271
 272 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 273
 274 sub fail ($$;$) {
 275         my ($self, $buf, $exit_code) = @_;
 276         err($self, $buf);
 277         x_it($self, ($exit_code // 1) << 8);
 278         undef;
 279 }
 280
 281 sub atfork_prepare_wq {
 282         my ($self, $wq) = @_;
 283         my $tcafc = $wq->{-ipc_atfork_child_close} //= [ $listener // () ];
 284         if (my $sock = $self->{sock}) {
 285                 push @$tcafc, @$self{qw(0 1 2)}, $sock;
 286         }
 287         if (my $pgr = $self->{pgr}) {
 288                 push @$tcafc, @$pgr[1,2];
 289         }
 290         for my $f (qw(lxs l2m)) {
 291                 my $ipc = $self->{$f} or next;
 292                 push @$tcafc, grep { defined }
 293                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 294         }
 295 }
 296
 297 # usage: my %sig = $lei->atfork_child_wq($wq);
 298 #        local @SIG{keys %sig} = values %sig;
 299 sub atfork_child_wq {
 300         my ($self, $wq) = @_;
 301         my ($sock, $l2m_wq_s1);
 302         (@$self{qw(0 1 2)}, $sock, $l2m_wq_s1) = delete(@$wq{0..4});
 303         $self->{sock} = $sock if -S $sock;
 304         $self->{l2m}->{-wq_s1} = $l2m_wq_s1 if $l2m_wq_s1 && -S $l2m_wq_s1;
 305         %PATH2CFG = ();
 306         undef $errors_log;
 307         $quit = \&CORE::exit;
 308         (__WARN__ => sub { err($self, @_) },
 309         PIPE => sub {
 310                 $self->x_it(13); # SIGPIPE = 13
 311                 # we need to close explicitly to avoid Perl warning on SIGPIPE
 312                 for my $i (1, 2) {
 313                         next unless $self->{$i} && (-p $self->{$i} || -S _);
 314                         close(delete $self->{$i});
 315                 }
 316                 # trigger the LeiXSearch $done OpPipe:
 317                 syswrite($self->{0}, '!') if $self->{0} && -p $self->{0};
 318                 $SIG{PIPE} = 'DEFAULT';
 319                 die bless(\"$_[0]", 'PublicInbox::SIGPIPE'),
 320         });
 321 }
 322
 323 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 324 sub atfork_parent_wq {
 325         my ($self, $wq) = @_;
 326         my $env = delete $self->{env}; # env is inherited at fork
 327         my $ret = bless { %$self }, ref($self);
 328         if (my $dedupe = delete $ret->{dedupe}) {
 329                 $ret->{dedupe} = $wq->deep_clone($dedupe);
 330         }
 331         $self->{env} = $env;
 332         delete @$ret{qw(-lei_store cfg pgr lxs)}; # keep l2m
 333         my @io = delete @$ret{0..2};
 334         $io[3] = delete($ret->{sock}) // $io[2];
 335         my $l2m = $ret->{l2m};
 336         if ($l2m && $l2m != $wq) { # $wq == lxs
 337                 $io[4] = $l2m->{-wq_s1} if $l2m->{-wq_s1};
 338                 $l2m->wq_close(1);
 339         }
 340         ($ret, @io);
 341 }
 342
 343 sub _help ($;$) {
 344         my ($self, $errmsg) = @_;
 345         my $cmd = $self->{cmd} // 'COMMAND';
 346         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 347         my @top = ($cmd, shift(@info) // ());
 348         my $cmd_desc = shift(@info);
 349         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 350         my @opt_desc;
 351         my $lpad = 2;
 352         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 353                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 354                 my $arg_vals = '';
 355                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 356
 357                 # lower-case is a keyword (e.g. `content', `oid'),
 358                 # ALL_CAPS is a string description (e.g. `PATH')
 359                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 360                         $desc .= "\ndefault: `$1'";
 361                 }
 362                 my (@vals, @s, @l);
 363                 my $x = $sw;
 364                 if ($x =~ s/!\z//) { # solve! => --no-solve
 365                         $x = "no-$x";
 366                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 367                         @vals = (' [', undef, ']');
 368                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 369                         @vals = (' ', undef);
 370                 } # else: no args $x = 'thread|t'
 371                 for (split(/\|/, $x)) { # help|h
 372                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 373                 }
 374                 if (!scalar(@vals)) { # no args 'thread|t'
 375                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 376                         $vals[1] = $1;
 377                 } else {
 378                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 379                 }
 380                 if ($arg_vals =~ /([,\|])/) {
 381                         my $sep = $1;
 382                         my @allow = split(/\Q$sep\E/, $arg_vals);
 383                         my $must = $sep eq '|' ? 'Must' : 'Can';
 384                         @allow = map { "`$_'" } @allow;
 385                         my $last = pop @allow;
 386                         $desc .= "\n$must be one of: " .
 387                                 join(', ', @allow) . " or $last";
 388                 }
 389                 my $lhs = join(', ', @s, @l) . join('', @vals);
 390                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 391                         $lhs =~ s/\A--/- , --/;
 392                 } else {
 393                         $lhs =~ s/\A--/    --/; # pad if no short options
 394                 }
 395                 $lpad = length($lhs) if length($lhs) > $lpad;
 396                 push @opt_desc, $lhs, $desc;
 397         }
 398         my $msg = $errmsg ? "E: $errmsg\n" : '';
 399         $msg .= <<EOF;
 400 usage: lei @top
 401   $cmd_desc
 402
 403 EOF
 404         $lpad += 2;
 405         local $Text::Wrap::columns = 78 - $lpad;
 406         my $padding = ' ' x ($lpad + 2);
 407         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 408                 $msg .= '  '.pack("A$lpad", $lhs);
 409                 $rhs = wrap('', '', $rhs);
 410                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 411                 $msg .= $rhs;
 412                 $msg .= "\n";
 413         }
 414         print { $self->{$errmsg ? 2 : 1} } $msg;
 415         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 416         undef;
 417 }
 418
 419 sub optparse ($$$) {
 420         my ($self, $cmd, $argv) = @_;
 421         $self->{cmd} = $cmd;
 422         $OPT = $self->{opt} = {};
 423         my $info = $CMD{$cmd} // [ '[...]' ];
 424         my ($proto, undef, @spec) = @$info;
 425         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 426         push @spec, qw(help|h);
 427         my $lone_dash;
 428         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 429                 $lone_dash = $spec[0];
 430                 $OPT->{$spec[0]} = \(my $var);
 431                 push @spec, '' => \$var;
 432         }
 433         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 434                 return _help($self, "bad arguments or options for $cmd");
 435         return _help($self) if $OPT->{help};
 436
 437         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 438
 439         # "-" aliases "stdin" or "clear"
 440         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 441
 442         my $i = 0;
 443         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 444         my ($err, $inf);
 445         my @args = split(/ /, $proto);
 446         for my $var (@args) {
 447                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 448                         $inf = defined($argv->[$i]) and last;
 449                         $var =~ s/\.\.\.\z//;
 450                         $err = "$var not supplied";
 451                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 452                         $argv->[$i++] // ($err = "$var not supplied");
 453                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 454                         $inf = 1;
 455                         last;
 456                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 457                         $i++;
 458                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 459                         my @or = split(/\|/, $var);
 460                         my $ok;
 461                         for my $o (@or) {
 462                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 463                                         $ok = defined($OPT->{$1});
 464                                         last;
 465                                 } elsif (defined($argv->[$i])) {
 466                                         $ok = 1;
 467                                         $i++;
 468                                         last;
 469                                 } # else continue looping
 470                         }
 471                         my $last = pop @or;
 472                         $err = join(', ', @or) . " or $last must be set";
 473                 } else {
 474                         warn "BUG: can't parse `$var' in $proto";
 475                 }
 476                 last if $err;
 477         }
 478         if (!$inf && scalar(@$argv) > scalar(@args)) {
 479                 $err //= 'too many arguments';
 480         }
 481         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 482 }
 483
 484 sub dispatch {
 485         my ($self, $cmd, @argv) = @_;
 486         local $current_lei = $self; # for __WARN__
 487         dump_and_clear_log("from previous run\n");
 488         return _help($self, 'no command given') unless defined($cmd);
 489         my $func = "lei_$cmd";
 490         $func =~ tr/-/_/;
 491         if (my $cb = __PACKAGE__->can($func)) {
 492                 optparse($self, $cmd, \@argv) or return;
 493                 $cb->($self, @argv);
 494         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 495                 my $opt = {};
 496                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 497                         return _help($self, 'bad arguments or options');
 498                 _help($self);
 499         } else {
 500                 fail($self, "`$cmd' is not an lei command");
 501         }
 502 }
 503
 504 sub _lei_cfg ($;$) {
 505         my ($self, $creat) = @_;
 506         my $f = _config_path($self->{env});
 507         my @st = stat($f);
 508         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 509         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 510                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 511         }
 512         if (!@st) {
 513                 unless ($creat) {
 514                         delete $self->{cfg};
 515                         return;
 516                 }
 517                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 518                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 519                 open my $fh, '>>', $f or die "open($f): $!\n";
 520                 @st = stat($fh) or die "fstat($f): $!\n";
 521                 $cur_st = pack('dd', $st[10], $st[7]);
 522                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 523         }
 524         my $cfg = PublicInbox::Config::git_config_dump($f);
 525         $cfg->{-st} = $cur_st;
 526         $cfg->{'-f'} = $f;
 527         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 528 }
 529
 530 sub _lei_store ($;$) {
 531         my ($self, $creat) = @_;
 532         my $cfg = _lei_cfg($self, $creat);
 533         $cfg->{-lei_store} //= do {
 534                 require PublicInbox::LeiStore;
 535                 my $dir = $cfg->{'leistore.dir'};
 536                 $dir //= _store_path($self->{env}) if $creat;
 537                 return unless $dir;
 538                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 539         };
 540 }
 541
 542 sub lei_show {
 543         my ($self, @argv) = @_;
 544 }
 545
 546 sub lei_mark {
 547         my ($self, @argv) = @_;
 548 }
 549
 550 sub lei_config {
 551         my ($self, @argv) = @_;
 552         $self->{opt}->{'config-file'} and return fail $self,
 553                 "config file switches not supported by `lei config'";
 554         my $env = $self->{env};
 555         delete local $env->{GIT_CONFIG};
 556         my $cfg = _lei_cfg($self, 1);
 557         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 558         my %rdr = map { $_ => $self->{$_} } (0..2);
 559         run_die($cmd, $env, \%rdr);
 560 }
 561
 562 sub lei_init {
 563         my ($self, $dir) = @_;
 564         my $cfg = _lei_cfg($self, 1);
 565         my $cur = $cfg->{'leistore.dir'};
 566         my $env = $self->{env};
 567         $dir //= _store_path($env);
 568         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 569         my @cur = stat($cur) if defined($cur);
 570         $cur = File::Spec->canonpath($cur // $dir);
 571         my @dir = stat($dir);
 572         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 573         if (@cur) {
 574                 if ($cur eq $dir) {
 575                         _lei_store($self, 1)->done;
 576                         return qerr($self, $exists);
 577                 }
 578
 579                 # some folks like symlinks and bind mounts :P
 580                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 581                         lei_config($self, 'leistore.dir', $dir);
 582                         _lei_store($self, 1)->done;
 583                         return qerr($self, "$exists (as $cur)");
 584                 }
 585                 return fail($self, <<"");
 586 E: leistore.dir=$cur already initialized and it is not $dir
 587
 588         }
 589         lei_config($self, 'leistore.dir', $dir);
 590         _lei_store($self, 1)->done;
 591         $exists //= "I: leistore.dir=$dir newly initialized";
 592         return qerr($self, $exists);
 593 }
 594
 595 sub lei_daemon_pid { puts shift, $$ }
 596
 597 sub lei_daemon_kill {
 598         my ($self) = @_;
 599         my $sig = $self->{opt}->{signal} // 'TERM';
 600         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 601 }
 602
 603 sub lei_help { _help($_[0]) }
 604
 605 # Shell completion helper.  Used by lei-completion.bash and hopefully
 606 # other shells.  Try to do as much here as possible to avoid redundancy
 607 # and improve maintainability.
 608 sub lei__complete {
 609         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 610         shift @argv; # ignore "lei", the entire command is sent
 611         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 612         my $cmd = shift @argv;
 613         my $info = $CMD{$cmd} // do { # filter matching commands
 614                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 615                 return;
 616         };
 617         my ($proto, undef, @spec) = @$info;
 618         my $cur = pop @argv;
 619         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 620         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 621                 # gross special case since the only git-config options
 622                 # Consider moving to a table if we need more special cases
 623                 # we use Getopt::Long for are the ones we reject, so these
 624                 # are the ones we don't reject:
 625                 if ($cmd eq 'config') {
 626                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 627                         @spec = qw(add z|null get get-all unset unset-all
 628                                 replace-all get-urlmatch
 629                                 remove-section rename-section
 630                                 name-only list|l edit|e
 631                                 get-color-name get-colorbool);
 632                         # fall-through
 633                 }
 634                 # TODO: arg support
 635                 puts $self, grep(/$re/, map { # generate short/long names
 636                         my $eq = '';
 637                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 638                                 $eq = '=';
 639                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 640                         } else { # negation: solve! => no-solve|solve
 641                                 s/\A(.+)!\z/no-$1|$1/;
 642                         }
 643                         map {
 644                                 length > 1 ? "--$_$eq" : "-$_"
 645                         } split(/\|/, $_, -1) # help|h
 646                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 647         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 648                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 649         }
 650         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 651         # proto parsing.
 652 }
 653
 654 sub reap_exec { # dwaitpid callback
 655         my ($self, $pid) = @_;
 656         x_it($self, $?);
 657 }
 658
 659 sub lei_git { # support passing through random git commands
 660         my ($self, @argv) = @_;
 661         my %rdr = map { $_ => $self->{$_} } (0..2);
 662         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 663         dwaitpid($pid, \&reap_exec, $self);
 664 }
 665
 666 sub exec_buf ($$) {
 667         my ($argv, $env) = @_;
 668         my $argc = scalar @$argv;
 669         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 670         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 671         $buf;
 672 }
 673
 674 sub start_mua {
 675         my ($self, $sock) = @_;
 676         my $mua = $self->{opt}->{'mua-cmd'} // return;
 677         my $mfolder = $self->{ovv}->{dst};
 678         require Text::ParseWords;
 679         my $replaced;
 680         my @cmd = Text::ParseWords::shellwords($mua);
 681         # mutt uses '%f' for open-hook with compressed folders, so we use %f
 682         @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 683         push @cmd, $mfolder unless defined($replaced);
 684         $sock //= $self->{sock};
 685         if ($sock) { # lei(1) client process runs it
 686                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 687         } else { # oneshot
 688                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 689         }
 690 }
 691
 692 # caller needs to "-t $self->{1}" to check if tty
 693 sub start_pager {
 694         my ($self) = @_;
 695         my $env = $self->{env};
 696         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 697         chomp(my $pager = <$fh> // '');
 698         close($fh) or warn "`git var PAGER' error: \$?=$?";
 699         return if $pager eq 'cat' || $pager eq '';
 700         # TODO TIOCGWINSZ
 701         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 702         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 703         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 704         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 705         my $pgr = [ undef, @$rdr{1, 2}, $$ ];
 706         if (my $sock = $self->{sock}) { # lei(1) process runs it
 707                 delete @$new_env{keys %$env}; # only set iff unset
 708                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 709                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 710         } else {
 711                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 712         }
 713         $self->{1} = $wpager;
 714         $self->{2} = $wpager if -t $self->{2};
 715         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 716         $self->{pgr} = $pgr;
 717 }
 718
 719 sub stop_pager {
 720         my ($self) = @_;
 721         my $pgr = delete($self->{pgr}) or return;
 722         $self->{2} = $pgr->[2];
 723         # do not restore original stdout, just close it so we error out
 724         close(delete($self->{1})) if $self->{1};
 725         my $pid = $pgr->[0];
 726         dwaitpid($pid, undef, $self->{sock}) if $pid && $pgr->[3] == $$;
 727 }
 728
 729 sub accept_dispatch { # Listener {post_accept} callback
 730         my ($sock) = @_; # ignore other
 731         $sock->autoflush(1);
 732         my $self = bless { sock => $sock }, __PACKAGE__;
 733         vec(my $rvec = '', fileno($sock), 1) = 1;
 734         select($rvec, undef, undef, 1) or
 735                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 736         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 737         if (scalar(@fds) == 4) {
 738                 my $i = 0;
 739                 for my $rdr (qw(<&= >&= >&= <&=)) {
 740                         my $fd = shift(@fds);
 741                         open($self->{$i++}, $rdr, $fd) and next;
 742                         send($sock, "open($rdr$fd) (FD=$i): $!", MSG_EOR);
 743                 }
 744         } else {
 745                 return send($sock, "recv_cmd failed: $!", MSG_EOR);
 746         }
 747         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 748         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 749         # $buf = "$$\0$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 750         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 751                 return send($sock, 'request command truncated', MSG_EOR);
 752         my ($argc, @argv) = split(/\0/, $buf, -1);
 753         undef $buf;
 754         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 755         if (chdir(delete($self->{3}))) {
 756                 local %ENV = %env;
 757                 $self->{env} = \%env;
 758                 eval { dispatch($self, @argv) };
 759                 send($sock, $@, MSG_EOR) if $@;
 760         } else {
 761                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 762         }
 763 }
 764
 765 sub dclose {
 766         my ($self) = @_;
 767         for my $f (qw(lxs l2m)) {
 768                 my $wq = delete $self->{$f} or next;
 769                 if ($wq->wq_kill) {
 770                         $self->wq_close
 771                 } elsif ($wq->wq_kill_old) {
 772                         $wq->wq_wait_old;
 773                 }
 774         }
 775         close(delete $self->{1}) if $self->{1}; # may reap_compress
 776         $self->close if $self->{sock}; # PublicInbox::DS::close
 777 }
 778
 779 # for long-running results
 780 sub event_step {
 781         my ($self) = @_;
 782         local %ENV = %{$self->{env}};
 783         my $sock = $self->{sock};
 784         local $current_lei = $self;
 785         eval {
 786                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 787                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 788                                 return if $! == EAGAIN;
 789                                 next if $! == EINTR;
 790                                 last if $! == ECONNRESET;
 791                                 die "recvmsg: $!";
 792                         }
 793                         for my $fd (@fds) {
 794                                 open my $rfh, '+<&=', $fd;
 795                         }
 796                         die "unrecognized client signal: $buf";
 797                 }
 798                 dclose($self);
 799         };
 800         if (my $err = $@) {
 801                 eval { $self->fail($err) };
 802                 dclose($self);
 803         }
 804 }
 805
 806 sub event_step_init {
 807         my ($self) = @_;
 808         if (my $sock = $self->{sock}) { # using DS->EventLoop
 809                 $sock->blocking(0);
 810                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 811         }
 812 }
 813
 814 sub noop {}
 815
 816 our $oldset; sub oldset { $oldset }
 817
 818 sub dump_and_clear_log {
 819         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 820                 my @pfx = @_;
 821                 unshift(@pfx, "$errors_log ") if @pfx;
 822                 warn @pfx, do { local $/; <STDIN> };
 823                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 824         }
 825 }
 826
 827 # lei(1) calls this when it can't connect
 828 sub lazy_start {
 829         my ($path, $errno, $narg) = @_;
 830         if ($errno == ECONNREFUSED) {
 831                 unlink($path) or die "unlink($path): $!";
 832         } elsif ($errno != ENOENT) {
 833                 $! = $errno; # allow interpolation to stringify in die
 834                 die "connect($path): $!";
 835         }
 836         umask(077) // die("umask(077): $!");
 837         local $listener;
 838         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 839         bind($listener, pack_sockaddr_un($path)) or die "bind($path): $!";
 840         listen($listener, 1024) or die "listen: $!";
 841         my @st = stat($path) or die "stat($path): $!";
 842         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 843         local $oldset = PublicInbox::DS::block_signals();
 844         if ($narg == 5) {
 845                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 846                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 847                         require PublicInbox::CmdIPC4;
 848                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 849                         PublicInbox::CmdIPC4->can('recv_cmd4');
 850                 };
 851         }
 852         $recv_cmd or die <<"";
 853 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 854
 855         require PublicInbox::Listener;
 856         require PublicInbox::EOFpipe;
 857         (-p STDOUT) or die "E: stdout must be a pipe\n";
 858         local $errors_log;
 859         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 860         $errors_log .= 'errors.log';
 861         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 862         STDIN->autoflush(1);
 863         dump_and_clear_log("from previous daemon process:\n");
 864         POSIX::setsid() > 0 or die "setsid: $!";
 865         my $pid = fork // die "fork: $!";
 866         return if $pid;
 867         $0 = "lei-daemon $path";
 868         local %PATH2CFG;
 869         $listener->blocking(0);
 870         my $exit_code;
 871         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
 872         local $quit = do {
 873                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 874                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 875                 sub {
 876                         $exit_code //= shift;
 877                         my $lis = $pil or exit($exit_code);
 878                         # closing eof_w triggers \&noop wakeup
 879                         $listener = $eof_w = $pil = $path = undef;
 880                         $lis->close; # DS::close
 881                         PublicInbox::DS->SetLoopTimeout(1000);
 882                 };
 883         };
 884         my $sig = {
 885                 CHLD => \&PublicInbox::DS::enqueue_reap,
 886                 QUIT => $quit,
 887                 INT => $quit,
 888                 TERM => $quit,
 889                 HUP => \&noop,
 890                 USR1 => \&noop,
 891                 USR2 => \&noop,
 892         };
 893         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 894         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 895         undef $sig;
 896         local $SIG{PIPE} = 'IGNORE';
 897         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 898                 undef $sigfd;
 899                 PublicInbox::DS->SetLoopTimeout(5000);
 900         } else {
 901                 # wake up every second to accept signals if we don't
 902                 # have signalfd or IO::KQueue:
 903                 PublicInbox::DS::sig_setmask($oldset);
 904                 PublicInbox::DS->SetLoopTimeout(1000);
 905         }
 906         PublicInbox::DS->SetPostLoopCallback(sub {
 907                 my ($dmap, undef) = @_;
 908                 if (@st = defined($path) ? stat($path) : ()) {
 909                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 910                                 warn "$path dev/ino changed, quitting\n";
 911                                 $path = undef;
 912                         }
 913                 } elsif (defined($path)) {
 914                         warn "stat($path): $!, quitting ...\n";
 915                         undef $path; # don't unlink
 916                         $quit->();
 917                 }
 918                 return 1 if defined($path);
 919                 my $now = now();
 920                 my $n = 0;
 921                 for my $s (values %$dmap) {
 922                         $s->can('busy') or next;
 923                         if ($s->busy($now)) {
 924                                 ++$n;
 925                         } else {
 926                                 $s->close;
 927                         }
 928                 }
 929                 $n; # true: continue, false: stop
 930         });
 931
 932         # STDIN was redirected to /dev/null above, closing STDERR and
 933         # STDOUT will cause the calling `lei' client process to finish
 934         # reading the <$daemon> pipe.
 935         openlog($path, 'pid', 'user');
 936         local $SIG{__WARN__} = sub {
 937                 $current_lei ? err($current_lei, @_) : syslog('warning', "@_");
 938         };
 939         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 940                 syslog('crit', "$@") if $@;
 941         });
 942         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 943         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 944         # $daemon pipe to `lei' closed, main loop begins:
 945         PublicInbox::DS->EventLoop;
 946         @$on_destroy = (); # cancel on_destroy if we get here
 947         exit($exit_code // 0);
 948 }
 949
 950 # for users w/o Socket::Msghdr
 951 sub oneshot {
 952         my ($main_pkg) = @_;
 953         my $exit = $main_pkg->can('exit'); # caller may override exit()
 954         local $quit = $exit if $exit;
 955         local %PATH2CFG;
 956         umask(077) // die("umask(077): $!");
 957         dispatch((bless {
 958                 0 => *STDIN{GLOB},
 959                 1 => *STDOUT{GLOB},
 960                 2 => *STDERR{GLOB},
 961                 env => \%ENV
 962         }, __PACKAGE__), @ARGV);
 963 }
 964
 965 # ensures stdout hits the FS before sock disconnects so a client
 966 # can immediately reread it
 967 sub DESTROY {
 968         my ($self) = @_;
 969         $self->{1}->autoflush(1) if $self->{1};
 970         stop_pager($self);
 971         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
 972                 waitpid($mua_pid, 0);
 973         }
 974 }
 975
 976 1;