lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(EPOLLIN);
  22 use PublicInbox::DS qw(dwaitpid);
  23 use PublicInbox::Spawn qw(spawn popen_rd);
  24 use PublicInbox::Lock;
  25 use PublicInbox::Eml;
  26 use PublicInbox::Import;
  27 use PublicInbox::ContentHash qw(git_sha);
  28 use Time::HiRes qw(stat); # ctime comparisons for config cache
  29 use File::Path qw(mkpath);
  30 use File::Spec;
  31 use Sys::Syslog qw(openlog syslog closelog);
  32 our $quit = \&CORE::exit;
  33 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle,
  34         $recv_cmd, $send_cmd);
  35 my $GLP = Getopt::Long::Parser->new;
  36 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  37 my $GLP_PASS = Getopt::Long::Parser->new;
  38 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  39
  40 our %PATH2CFG; # persistent for socket daemon
  41 our $MDIR2CFGPATH; # /path/to/maildir => { /path/to/config => [ ino watches ] }
  42
  43 # TBD: this is a documentation mechanism to show a subcommand
  44 # (may) pass options through to another command:
  45 sub pass_through { $GLP_PASS }
  46
  47 my $OPT;
  48 sub opt_dash ($$) {
  49         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  50         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  51         my $cb = sub { # Getopt::Long "<>" catch-all handler
  52                 my ($arg) = @_;
  53                 if ($arg =~ /\A-($re_str)\z/) {
  54                         $OPT->{$key} = $1;
  55                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  56                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  57                 # lone (single) dash is handled elsewhere
  58                 } elsif (substr($arg, 0, 1) eq '-') {
  59                         if ($OPT->{'--'}) {
  60                                 push @{$OPT->{-argv}}, $arg;
  61                         } else {
  62                                 die "bad argument: $arg\n";
  63                         }
  64                 } else {
  65                         push @{$OPT->{-argv}}, $arg;
  66                 }
  67         };
  68         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  69 }
  70
  71 # rel2abs preserves symlinks in parent, unlike abs_path
  72 sub rel2abs {
  73         my ($self, $p) = @_;
  74         if (index($p, '/') == 0) { # already absolute
  75                 $p =~ tr!/!/!s; # squeeze redundant slashes
  76                 chop($p) if substr($p, -1, 1) eq '/';
  77                 return $p;
  78         }
  79         my $pwd = $self->{env}->{PWD};
  80         if (defined $pwd) {
  81                 if (my @st_pwd = stat($pwd)) {
  82                         my @st_cwd = stat($self->{3}) or die "stat({3}): $!";
  83                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  84                                 $self->{env}->{PWD} = $pwd = undef;
  85                 } else { # PWD was invalid
  86                         $self->{env}->{PWD} = $pwd = undef;
  87                 }
  88         }
  89         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd: $!";
  90         File::Spec->rel2abs($p, $pwd);
  91 }
  92
  93 # abs_path resolves symlinks in parent iff all parents exist
  94 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  95
  96 sub canonpath_harder {
  97         my $p = $_[-1]; # $_[0] may be self
  98         $p = File::Spec->canonpath($p);
  99         $p =~ m!(?:/*|\A)\.\.(?:/*|\z)! && -e $p ? Cwd::abs_path($p) : $p;
 100 }
 101
 102 sub share_path ($) { # $HOME/.local/share/lei/$FOO
 103         my ($self) = @_;
 104         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
 105                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 106                 .'/lei');
 107 }
 108
 109 sub store_path ($) { share_path($_[0]) . '/store' }
 110
 111 sub _config_path ($) {
 112         my ($self) = @_;
 113         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 114                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 115                 .'/lei/config');
 116 }
 117
 118 sub cache_dir ($) {
 119         my ($self) = @_;
 120         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 121                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 122                 .'/lei');
 123 }
 124
 125 sub url_folder_cache {
 126         my ($self) = @_;
 127         require PublicInbox::SharedKV; # URI => updated_at_sec_
 128         PublicInbox::SharedKV->new(cache_dir($self).'/uri_folder');
 129 }
 130
 131 sub ale {
 132         my ($self) = @_;
 133         $self->{ale} // do {
 134                 require PublicInbox::LeiALE;
 135                 my $cfg = $self->_lei_cfg(1);
 136                 $self->{ale} = $cfg->{ale} //= PublicInbox::LeiALE->new($self);
 137         };
 138 }
 139
 140 sub index_opt {
 141         # TODO: drop underscore variants everywhere, they're undocumented
 142         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 143         max_size|max-size=s sequential-shard
 144         batch_size|batch-size=s skip-docdata)
 145 }
 146
 147 my @c_opt = qw(c=s@ C=s@ quiet|q);
 148 my @net_opt = (qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt());
 149 my @lxs_opt = qw(remote! local! external! include|I=s@ exclude=s@ only|O=s@
 150         import-remote!);
 151
 152 # we don't support -C as an alias for --find-copies since it's already
 153 # used for chdir
 154 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 155         output-indicator-context=s indent-heuristic!
 156         minimal patience histogram anchored=s@ diff-algorithm=s
 157         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 158         word-diff:s word-diff-regex=s color-words:s no-renames
 159         rename-empty! check ws-error-highlight=s full-index binary
 160         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 161         find-copies-harder irreversible-delete|D l=i diff-filter=s
 162         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 163         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 164         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 165         inter-hunk-context=i function-context|W exit-code ext-diff
 166         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 167         line-prefix=s);
 168
 169 # we generate shell completion + help using %CMD and %OPTDESC,
 170 # see lei__complete() and PublicInbox::LeiHelp
 171 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 172 our %CMD = ( # sorted in order of importance/use:
 173 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 174         'stdin|', # /|\z/ must be first for lone dash
 175         @lxs_opt, @net_opt,
 176         qw(save! output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 177         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 178         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 179         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 180
 181 'up' => [ 'OUTPUT...|--all', 'update saved search',
 182         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ exclude=s@
 183         remote-fudge-time=s all:s remote! local! external!), @net_opt, @c_opt ],
 184
 185 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 186         'stdin|', # /|\z/ must be first for lone dash
 187         # some of these options are ridiculous for lcat
 188         @lxs_opt, @net_opt,
 189         qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 190         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 191         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 192         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 193
 194 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 195         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 196         @lxs_opt, @net_opt, @c_opt ],
 197
 198 'rediff' => [ '--stdin|LOCATION...',
 199                 'regenerate a diff with different options',
 200         'stdin|', # /|\z/ must be first for lone dash
 201         qw(git-dir=s@ cwd! verbose|v+ color:s no-color drq:1 dequote-only:1),
 202         @diff_opt, @lxs_opt, @net_opt, @c_opt ],
 203
 204 'mail-diff' => [ '--stdin|LOCATION...', 'diff the contents of emails',
 205         'stdin|', # /|\z/ must be first for lone dash
 206         qw(verbose|v+ in-format|F=s color:s no-color raw-header),
 207         @diff_opt, @net_opt, @c_opt ],
 208
 209 'add-external' => [ 'LOCATION',
 210         'add/set priority of a publicinbox|extindex for extra matches',
 211         qw(boost=i mirror=s inbox-version=i epoch=s verbose|v+),
 212         @c_opt, index_opt(), @net_opt ],
 213 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 214         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 215 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 216 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 217                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 218 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 219                 qw(z|0 ascii l pretty url), @net_opt, @c_opt ],
 220 'forget-external' => [ 'LOCATION...|--prune',
 221         'exclude further results from a publicinbox|extindex',
 222         qw(prune), @c_opt ],
 223
 224 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 225                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 226 'forget-search' => [ 'OUTPUT...|--prune', 'forget a saved search',
 227                 qw(verbose|v+ prune:s), @c_opt ],
 228 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 229                         @c_opt ],
 230 'rm' => [ '--stdin|LOCATION...',
 231         'remove a message from the index and prevent reindexing',
 232         'stdin|', # /|\z/ must be first for lone dash
 233         qw(in-format|F=s lock=s@), @net_opt, @c_opt ],
 234 'plonk' => [ '--threads|--from=IDENT',
 235         'exclude mail matching From: or threads from non-Message-ID searches',
 236         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 237 'tag' => [ 'KEYWORDS...',
 238         'set/unset keywords and/or labels on message(s)',
 239         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 240         @net_opt, @c_opt, pass_through('-kw:foo for delete') ],
 241
 242 'purge-mailsource' => [ 'LOCATION|--all',
 243         'remove imported messages from IMAP, Maildirs, and MH',
 244         qw(exact! all jobs:i indexed), @c_opt ],
 245
 246 'add-watch' => [ 'LOCATION...', 'watch for new messages and flag changes',
 247         qw(poll-interval=s state=s recursive|r), @c_opt ],
 248 'rm-watch' => [ 'LOCATION...', 'remove specified watch(es)',
 249         qw(recursive|r), @c_opt ],
 250 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 251                 qw(l z|0), @c_opt ],
 252 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 253 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 254 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 255         qw(prune), @c_opt ],
 256
 257 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 258         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 259         verbose|v+ incremental!), @net_opt, # mainly for --proxy=
 260          @c_opt ],
 261 'import' => [ 'LOCATION...|--stdin',
 262         'one-time import/update from URL or filesystem',
 263         qw(stdin| offset=i recursive|r exclude=s include|I=s new-only
 264         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 265         @net_opt, @c_opt ],
 266 'forget-mail-sync' => [ 'LOCATION...',
 267         'forget sync information for a mail folder', @c_opt ],
 268 'refresh-mail-sync' => [ 'LOCATION...|--all',
 269         'prune dangling sync data for a mail folder', 'all:s',
 270                 @net_opt, @c_opt ],
 271 'export-kw' => [ 'LOCATION...|--all',
 272         'one-time export of keywords of sync sources',
 273         qw(all:s mode=s), @net_opt, @c_opt ],
 274 'convert' => [ 'LOCATION...|--stdin',
 275         'one-time conversion from URL or filesystem to another format',
 276         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 277         @net_opt, @c_opt ],
 278 'p2q' => [ 'LOCATION_OR_COMMIT...|--stdin',
 279         "use a patch to generate a query for `lei q --stdin'",
 280         qw(stdin| in-format|F=s want|w=s@ uri debug), @net_opt, @c_opt ],
 281 'config' => [ '[...]', sub {
 282                 'git-config(1) wrapper for '._config_path($_[0]);
 283         }, qw(config-file|system|global|file|f=s), # for conflict detection
 284          qw(edit|e c=s@ C=s@), pass_through('git config') ],
 285 'inspect' => [ 'ITEMS...|--stdin', 'inspect lei/store and/or local external',
 286         qw(stdin| pretty ascii dir|d=s), @c_opt ],
 287
 288 'init' => [ '[DIRNAME]', sub {
 289         "initialize storage, default: ".store_path($_[0]);
 290         }, @c_opt ],
 291 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 292         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 293         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 294 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 295 'help' => [ '[SUBCOMMAND]', 'show help' ],
 296
 297 # TODO
 298 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 299 #       'rewrite git history in an attempt to improve compression',
 300 #       qw(gc!), @c_opt ],
 301 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 302 #
 303 # internal commands are prefixed with '_'
 304 '_complete' => [ '[...]', 'internal shell completion helper',
 305                 pass_through('everything') ],
 306 ); # @CMD
 307
 308 # switch descriptions, try to keep consistent across commands
 309 # $spec: Getopt::Long option specification
 310 # $spec => [@ALLOWED_VALUES (default is first), $description],
 311 # $spec => $description
 312 # "$SUB_COMMAND TAB $spec" => as above
 313 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 314                         'specify message input format' ];
 315 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 316
 317 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 318 my %OPTDESC = (
 319 'help|h' => 'show this built-in help',
 320 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 321 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 322 'quiet|q' => 'be quiet',
 323 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 324         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 325
 326 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 327 'globoff|g' => "do not match locations using '*?' wildcards ".
 328                 "and\xa0'[]'\x{a0}ranges",
 329 'invert-match|v' => 'select non-matching lines',
 330 'color!' => 'disable color (for --format=text)',
 331 'verbose|v+' => 'be more verbose',
 332 'external!' => 'do not use externals',
 333 'mail!' => 'do not look in mail storage for OID',
 334 'cwd!' => 'do not look in git repo of current working directory',
 335 'oid-a|A=s' => 'pre-image OID',
 336 'path-a|a=s' => 'pre-image pathname associated with OID',
 337 'path-b|b=s' => 'post-image pathname associated with OID',
 338 'git-dir=s@' => 'additional git repository to scan',
 339 'dir|d=s        inspect' =>
 340         'specify a inboxdir, extindex topdir or Xapian shard',
 341 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 342         "proxy for (e.g. `socks5h://0:9050')" ],
 343 'torsocks=s' => ['VAL|auto|no|yes',
 344                 'whether or not to wrap git and curl commands with torsocks'],
 345 'no-torsocks' => 'alias for --torsocks=no',
 346 'save!' =>  "do not save a search for `lei up'",
 347 'import-remote!' => 'do not memoize remote messages into local store',
 348
 349 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 350
 351 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 352                 'deduplication strategy'],
 353 'threads|t+' =>
 354         'return all messages in the same threads as the actual match(es)',
 355
 356 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 357                 'search prefixes to extract (default: dfpost7)' ],
 358 'uri    p2q' => [ 'URI escape output' ],
 359
 360 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 361         'run command(s) or perform ops when done writing to output ' .
 362         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 363         'nothing otherwise)' ],
 364
 365 'augment|a' => 'augment --output destination instead of clobbering',
 366
 367 'output|mfolder|o=s' => [ 'MFOLDER',
 368         "destination (e.g.\xa0`/path/to/Maildir', ".
 369         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 370 'mua=s' => [ 'CMD',
 371         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 372 'new-only       import' => 'only import new messages from IMAP source',
 373
 374 'inbox-version=i' => [ 'NUM|1|2',
 375                 'force a public-inbox version with --mirror'],
 376 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 377
 378 # public-inbox-index options
 379 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 380 'compact' => 'run compact index after mirroring',
 381 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 382         "indexlevel with --mirror (default: full)" ],
 383 'max_size|max-size=s' => [ 'SIZE',
 384         'do not index messages larger than SIZE (default: infinity)' ],
 385 'batch_size|batch-size=s' => [ 'SIZE',
 386         'flush changes to OS after given number of bytes (default: 1m)' ],
 387 'sequential-shard' =>
 388         'index Xapian shards sequentially for slow storage',
 389 'skip-docdata' =>
 390         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 391
 392 'format|f=s     q' => [
 393         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 394                 'specify output format, default depends on --output'],
 395 'exclude=s@     q' => [ 'LOCATION',
 396                 'exclude specified external(s) from search' ],
 397 'include|I=s@   q' => [ 'LOCATION',
 398                 'include specified external(s) in search' ],
 399 'only|O=s@      q' => [ 'LOCATION',
 400                 'only use specified external(s) for search' ],
 401 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 402                 'control number of search and writer jobs' ],
 403 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 404
 405 'in-format|F=s' => $stdin_formats,
 406 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 407                         'listing output format' ],
 408 'l      ls-search' => 'long listing format',
 409 'l      ls-watch' => 'long listing format',
 410 'l      ls-mail-source' => 'long listing format',
 411 'url    ls-mail-source' => 'show full URL of newsgroup or IMAP folder',
 412 'format|f=s     ls-external' => $ls_format,
 413
 414 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 415 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 416
 417 'sort|s=s' => [ 'VAL|received|relevance|docid',
 418                 "order of results is `--output'-dependent"],
 419 'reverse|r' => 'reverse search results', # like sort(1)
 420
 421 'boost=i' => 'increase/decrease priority of results (default: 0)',
 422
 423 'local' => 'limit operations to the local filesystem',
 424 'local!' => 'exclude results from the local filesystem',
 425 'remote' => 'limit operations to those requiring network access',
 426 'remote!' => 'prevent operations requiring network access',
 427
 428 # up, refresh-mail-sync, export-kw
 429 'all:s' => ['TYPE|local|remote', 'all remote or local folders' ],
 430
 431 'remote-fudge-time=s' => [ 'INTERVAL',
 432         'look for mail INTERVAL older than the last successful query' ],
 433
 434 'mid=s' => 'specify the Message-ID of a message',
 435 'oid=s' => 'specify the git object ID of a message',
 436
 437 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 438 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 439 'include=s' => 'include mailboxes/newsgroups based on pattern',
 440
 441 'exact' => 'operate on exact header matches only',
 442 'exact!' => 'rely on content match instead of exact header matches',
 443
 444 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 445
 446 'kw!' => 'disable/enable importing keywords (aka "flags")',
 447
 448 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 449 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 450
 451 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 452 ); # %OPTDESC
 453
 454 my %CONFIG_KEYS = (
 455         'leistore.dir' => 'top-level storage location',
 456 );
 457
 458 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1 lne v2w); # internal workers
 459
 460 sub _drop_wq {
 461         my ($self) = @_;
 462         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 463                 $wq->wq_kill('-TERM');
 464                 $wq->DESTROY;
 465         }
 466 }
 467
 468 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 469 sub x_it ($$) {
 470         my ($self, $code) = @_;
 471         local $current_lei = $self;
 472         # make sure client sees stdout before exit
 473         $self->{1}->autoflush(1) if $self->{1};
 474         stop_pager($self);
 475         if ($self->{pkt_op_p}) { # worker => lei-daemon
 476                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 477         } elsif ($self->{sock}) { # lei->daemon => lei(1) client
 478                 send($self->{sock}, "x_it $code", MSG_EOR);
 479         } elsif ($quit == \&CORE::exit) { # an admin (one-shot) command
 480                 exit($code >> 8);
 481         } # else ignore if client disconnected
 482 }
 483
 484 sub err ($;@) {
 485         my $self = shift;
 486         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 487         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 488         print $err @_, @eor and return;
 489         my $old_err = delete $self->{2};
 490         close($old_err) if $! == EPIPE && $old_err;
 491         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 492         print $err @_, @eor or print STDERR @_, @eor;
 493 }
 494
 495 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 496
 497 sub qfin { # show message on finalization (LeiFinmsg)
 498         my ($lei, $msg) = @_;
 499         return if $lei->{opt}->{quiet};
 500         $lei->{fmsg} ? push(@{$lei->{fmsg}}, "$msg\n") : qerr($lei, $msg);
 501 }
 502
 503 sub fail_handler ($;$$) {
 504         my ($lei, $code, $io) = @_;
 505         local $current_lei = $lei;
 506         close($io) if $io; # needed to avoid warnings on SIGPIPE
 507         _drop_wq($lei);
 508         x_it($lei, $code // (1 << 8));
 509 }
 510
 511 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 512         fail_handler($_[0], 13, delete $_[0]->{1});
 513 }
 514
 515 sub fail ($$;$) {
 516         my ($self, $msg, $exit_code) = @_;
 517         local $current_lei = $self;
 518         $self->{failed}++;
 519         warn(substr($msg, -1, 1) eq "\n" ? $msg : "$msg\n") if defined $msg;
 520         $self->{pkt_op_p}->pkt_do('fail_handler') if $self->{pkt_op_p};
 521         x_it($self, ($exit_code // 1) << 8);
 522         undef;
 523 }
 524
 525 sub out ($;@) {
 526         my $self = shift;
 527         return if print { $self->{1} // return } @_; # likely
 528         return note_sigpipe($self, 1) if $! == EPIPE;
 529         my $err = "error writing to output: $!";
 530         delete $self->{1};
 531         fail($self, $err);
 532 }
 533
 534 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 535
 536 sub child_error { # passes non-fatal curl exit codes to user
 537         my ($self, $child_error, $msg) = @_; # child_error is $?
 538         local $current_lei = $self;
 539         $child_error ||= 1 << 8;
 540         warn(substr($msg, -1, 1) eq "\n" ? $msg : "$msg\n") if defined $msg;
 541         if ($self->{pkt_op_p}) { # to top lei-daemon
 542                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 543         } elsif ($self->{sock}) { # to lei(1) client
 544                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 545         } else { # non-lei admin command
 546                 $self->{child_error} ||= $child_error;
 547         } # else noop if client disconnected
 548 }
 549
 550 sub note_sigpipe { # triggers sigpipe_handler
 551         my ($self, $fd) = @_;
 552         close(delete($self->{$fd})); # explicit close silences Perl warning
 553         $self->{pkt_op_p}->pkt_do('sigpipe_handler') if $self->{pkt_op_p};
 554         x_it($self, 13);
 555 }
 556
 557 sub _lei_atfork_child {
 558         my ($self, $persist) = @_;
 559         # we need to explicitly close things which are on stack
 560         if ($persist) {
 561                 open $self->{3}, '<', '/' or die "open(/) $!";
 562                 fchdir($self);
 563                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 564                 if (my $cfg = $self->{cfg}) {
 565                         delete @$cfg{qw(-lei_store -watches -lei_note_event)};
 566                 }
 567         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 568                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 569                 STDERR->autoflush(1);
 570                 POSIX::setpgid(0, $$) // die "setpgid(0, $$): $!";
 571         }
 572         close($_) for (grep(defined, delete @$self{qw(old_1 au_done)}));
 573         delete $self->{-socks};
 574         if (my $op_c = delete $self->{pkt_op_c}) {
 575                 close(delete $op_c->{sock});
 576         }
 577         if (my $pgr = delete $self->{pgr}) {
 578                 close($_) for (@$pgr[1,2]);
 579         }
 580         close $listener if $listener;
 581         undef $listener;
 582         $dir_idle->force_close if $dir_idle;
 583         undef $dir_idle;
 584         %PATH2CFG = ();
 585         $MDIR2CFGPATH = {};
 586         eval 'no warnings; undef $PublicInbox::LeiNoteEvent::to_flush';
 587         undef $errors_log;
 588         $quit = \&CORE::exit;
 589         if (!$self->{-eml_noisy}) { # only "lei import" sets this atm
 590                 my $cb = $SIG{__WARN__} // \&CORE::warn;
 591                 $SIG{__WARN__} = sub {
 592                         $cb->(@_) unless PublicInbox::Eml::warn_ignore(@_)
 593                 };
 594         }
 595         $SIG{TERM} = sub { exit(128 + 15) };
 596         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 597 }
 598
 599 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 600         my ($self) = @_;
 601         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 602                 $op->close; # PublicInbox::PktOp::close
 603         }
 604         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 605         close $pkt_op_p->{op_p};
 606 }
 607
 608 sub pkt_op_pair {
 609         my ($self) = @_;
 610         require PublicInbox::OnDestroy;
 611         require PublicInbox::PktOp;
 612         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 613         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 614         $end;
 615 }
 616
 617 sub incr {
 618         my ($self, $field, $nr) = @_;
 619         $self->{counters}->{$field} += $nr;
 620 }
 621
 622 sub pkt_ops {
 623         my ($lei, $ops) = @_;
 624         $ops->{fail_handler} = [ $lei ];
 625         $ops->{sigpipe_handler} = [ $lei ];
 626         $ops->{x_it} = [ $lei ];
 627         $ops->{child_error} = [ $lei ];
 628         $ops->{incr} = [ $lei ];
 629         $ops;
 630 }
 631
 632 sub workers_start {
 633         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 634         $ops = pkt_ops($lei, { ($ops ? %$ops : ()) });
 635         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 636         my $end = $lei->pkt_op_pair;
 637         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 638         $flds->{lei} = $lei;
 639         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 640         delete $lei->{pkt_op_p};
 641         my $op_c = delete $lei->{pkt_op_c};
 642         @$end = ();
 643         $lei->event_step_init;
 644         $wq->wq_wait_async($wq->can('_wq_done_wait') // \&wq_done_wait, $lei);
 645         ($op_c, $ops);
 646 }
 647
 648 # call this when we're ready to wait on events and yield to other clients
 649 sub wait_wq_events {
 650         my ($lei, $op_c, $ops) = @_;
 651         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 652                 $wq->wq_close;
 653         }
 654         $op_c->{ops} = $ops;
 655 }
 656
 657 sub _help {
 658         require PublicInbox::LeiHelp;
 659         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 660 }
 661
 662 sub optparse ($$$) {
 663         my ($self, $cmd, $argv) = @_;
 664         # allow _complete --help to complete, not show help
 665         return 1 if substr($cmd, 0, 1) eq '_';
 666         $self->{cmd} = $cmd;
 667         $OPT = $self->{opt} //= {};
 668         my $info = $CMD{$cmd} // [ '[...]' ];
 669         my ($proto, undef, @spec) = @$info;
 670         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 671         push @spec, qw(help|h);
 672         my $lone_dash;
 673         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 674                 $lone_dash = $spec[0];
 675                 $OPT->{$spec[0]} = \(my $var);
 676                 push @spec, '' => \$var;
 677         }
 678         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 679                 return _help($self, "bad arguments or options for $cmd");
 680         return _help($self) if $OPT->{help};
 681
 682         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 683
 684         # "-" aliases "stdin" or "clear"
 685         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 686
 687         my $i = 0;
 688         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 689         my ($err, $inf);
 690         my @args = split(/ /, $proto);
 691         for my $var (@args) {
 692                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 693                         $inf = defined($argv->[$i]) and last;
 694                         $var =~ s/\.\.\.\z//;
 695                         $err = "$var not supplied";
 696                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 697                         $argv->[$i++] // ($err = "$var not supplied");
 698                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 699                         $inf = 1;
 700                         last;
 701                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 702                         $i++;
 703                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 704                         $inf = 1 if index($var, '...') > 0;
 705                         my @or = split(/\|/, $var);
 706                         my $ok;
 707                         for my $o (@or) {
 708                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 709                                         my $sw = $1;
 710                                         # assume pipe/regular file on stdin
 711                                         # w/o args means stdin
 712                                         if ($sw eq 'stdin' && !@$argv &&
 713                                                         (-p $self->{0} ||
 714                                                          -f _) && -r _) {
 715                                                 $OPT->{stdin} //= 1;
 716                                         }
 717                                         $ok = defined($OPT->{$sw});
 718                                         last if $ok;
 719                                 } elsif (defined($argv->[$i])) {
 720                                         $ok = 1;
 721                                         $i++;
 722                                         last;
 723                                 } # else continue looping
 724                         }
 725                         last if $ok;
 726                         my $last = pop @or;
 727                         $err = join(', ', @or) . " or $last must be set";
 728                 } else {
 729                         warn "BUG: can't parse `$var' in $proto";
 730                 }
 731                 last if $err;
 732         }
 733         if (!$inf && scalar(@$argv) > scalar(@args)) {
 734                 $err //= 'too many arguments';
 735         }
 736         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 737 }
 738
 739 sub _tmp_cfg { # for lei -c <name>=<value> ...
 740         my ($self) = @_;
 741         my $cfg = _lei_cfg($self, 1);
 742         require File::Temp;
 743         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 744         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 745         $ft->autoflush(1);
 746         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 747 [include]
 748         path = $cfg->{-f}
 749 EOM
 750         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 751         for (@{$self->{opt}->{c}}) {
 752                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 753 `-c $_' is not of the form -c <name>=<value>'
 754 EOM
 755                 my $name = $1;
 756                 my $value = $2 // 1;
 757                 _config($self, '--add', $name, $value);
 758                 if (defined(my $v = $tmp->{$name})) {
 759                         if (ref($v) eq 'ARRAY') {
 760                                 push @$v, $value;
 761                         } else {
 762                                 $tmp->{$name} = [ $v, $value ];
 763                         }
 764                 } else {
 765                         $tmp->{$name} = $value;
 766                 }
 767         }
 768 }
 769
 770 sub lazy_cb ($$$) {
 771         my ($self, $cmd, $pfx) = @_;
 772         my $ucmd = $cmd;
 773         $ucmd =~ tr/-/_/;
 774         my $cb;
 775         $cb = $self->can($pfx.$ucmd) and return $cb;
 776         my $base = $ucmd;
 777         $base =~ s/_([a-z])/\u$1/g;
 778         my $pkg = "PublicInbox::Lei\u$base";
 779         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 780                 $pkg->can($pfx.$ucmd) : undef;
 781 }
 782
 783 sub dispatch {
 784         my ($self, $cmd, @argv) = @_;
 785         fchdir($self);
 786         local %ENV = %{$self->{env}};
 787         local $current_lei = $self; # for __WARN__
 788         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 789         return _help($self, 'no command given') unless defined($cmd);
 790         # do not support Getopt bundling for this
 791         while ($cmd eq '-C' || $cmd eq '-c') {
 792                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 793                                         '-C DIRECTORY' : '-c <name>=<value>');
 794                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 795                 $cmd = shift(@argv) // return _help($self, 'no command given');
 796         }
 797         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 798                 optparse($self, $cmd, \@argv) or return;
 799                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 800                 if (my $chdir = $self->{opt}->{C}) {
 801                         for my $d (@$chdir) {
 802                                 next if $d eq ''; # same as git(1)
 803                                 chdir $d or return fail($self, "cd $d: $!");
 804                         }
 805                         open $self->{3}, '.' or return fail($self, "open . $!");
 806                 }
 807                 $cb->($self, @argv);
 808         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 809                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 810                         or return _help($self, 'bad arguments or options');
 811                 _help($self);
 812         } else {
 813                 fail($self, "`$cmd' is not an lei command");
 814         }
 815 }
 816
 817 sub _lei_cfg ($;$) {
 818         my ($self, $creat) = @_;
 819         return $self->{cfg} if $self->{cfg};
 820         my $f = _config_path($self);
 821         my @st = stat($f);
 822         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 823         my ($sto, $sto_dir, $watches, $lne);
 824         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 825                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 826                 ($sto, $sto_dir, $watches, $lne) =
 827                                 @$cfg{qw(-lei_store leistore.dir -watches
 828                                         -lei_note_event)};
 829         }
 830         if (!@st) {
 831                 unless ($creat) {
 832                         delete $self->{cfg};
 833                         return bless {}, 'PublicInbox::Config';
 834                 }
 835                 my ($cfg_dir) = ($f =~ m!(.*?/)[^/]+\z!);
 836                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 837                 open my $fh, '>>', $f or die "open($f): $!\n";
 838                 @st = stat($fh) or die "fstat($f): $!\n";
 839                 $cur_st = pack('dd', $st[10], $st[7]);
 840                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 841         }
 842         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{2});
 843         $cfg->{-st} = $cur_st;
 844         $cfg->{'-f'} = $f;
 845         if ($sto && canonpath_harder($sto_dir // store_path($self))
 846                         eq canonpath_harder($cfg->{'leistore.dir'} //
 847                                                 store_path($self))) {
 848                 $cfg->{-lei_store} = $sto;
 849                 $cfg->{-lei_note_event} = $lne;
 850                 $cfg->{-watches} = $watches if $watches;
 851         }
 852         if (scalar(keys %PATH2CFG) > 5) {
 853                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 854                 delete(@PATH2CFG{grep(!-f, keys %PATH2CFG)});
 855         }
 856         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 857         refresh_watches($self);
 858         $cfg;
 859 }
 860
 861 sub _lei_store ($;$) {
 862         my ($self, $creat) = @_;
 863         my $cfg = _lei_cfg($self, $creat) // return;
 864         $cfg->{-lei_store} //= do {
 865                 require PublicInbox::LeiStore;
 866                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 867                 return unless $creat || -d $dir;
 868                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 869         };
 870 }
 871
 872 sub _config {
 873         my ($self, @argv) = @_;
 874         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 875         my $cfg = _lei_cfg($self, 1);
 876         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 877         my %rdr = map { $_ => $self->{$_} } (0..2);
 878         waitpid(spawn($cmd, \%env, \%rdr), 0);
 879 }
 880
 881 sub lei_daemon_pid { puts shift, $$ }
 882
 883 sub lei_daemon_kill {
 884         my ($self) = @_;
 885         my $sig = $self->{opt}->{signal} // 'TERM';
 886         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 887 }
 888
 889 # Shell completion helper.  Used by lei-completion.bash and hopefully
 890 # other shells.  Try to do as much here as possible to avoid redundancy
 891 # and improve maintainability.
 892 sub lei__complete {
 893         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 894         shift @argv; # ignore "lei", the entire command is sent
 895         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 896         my $cmd = shift @argv;
 897         my $info = $CMD{$cmd} // do { # filter matching commands
 898                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 899                 return;
 900         };
 901         my ($proto, undef, @spec) = @$info;
 902         my $cur = pop @argv;
 903         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 904         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 905                 # gross special case since the only git-config options
 906                 # Consider moving to a table if we need more special cases
 907                 # we use Getopt::Long for are the ones we reject, so these
 908                 # are the ones we don't reject:
 909                 if ($cmd eq 'config') {
 910                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 911                         @spec = qw(add z|null get get-all unset unset-all
 912                                 replace-all get-urlmatch
 913                                 remove-section rename-section
 914                                 name-only list|l edit|e
 915                                 get-color-name get-colorbool);
 916                         # fall-through
 917                 }
 918                 # generate short/long names from Getopt::Long specs
 919                 puts $self, grep(/$re/, qw(--help -h -C), map {
 920                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 921                         } elsif (s/\+\z//) { # verbose|v+
 922                         } elsif (s/!\z//) {
 923                                 # negation: mail! => no-mail|mail
 924                                 s/([\w\-]+)/$1|no-$1/g
 925                         }
 926                         map {
 927                                 my $x = length > 1 ? "--$_" : "-$_";
 928                                 $x eq $_cur ? () : $x;
 929                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 930                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 931         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 932                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 933         }
 934
 935         # switch args (e.g. lei q -f mbox<TAB>)
 936         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 937                 my $opt = quotemeta $1;
 938                 puts $self, map {
 939                         my $v = $OPTDESC{$_};
 940                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 941                         # get rid of ALL CAPS placeholder (e.g "OUT")
 942                         # (TODO: completion for external paths)
 943                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 944                         @v;
 945                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 946         }
 947         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 948                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 949         }
 950         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 951         # proto parsing.
 952 }
 953
 954 sub exec_buf ($$) {
 955         my ($argv, $env) = @_;
 956         my $argc = scalar @$argv;
 957         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 958         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 959         $buf;
 960 }
 961
 962 sub start_mua {
 963         my ($self) = @_;
 964         if ($self->{ovv}->{fmt} =~ /\A(?:maildir)\z/) { # TODO: IMAP
 965                 refresh_watches($self);
 966         }
 967         my $mua = $self->{opt}->{mua} // return;
 968         my $mfolder = $self->{ovv}->{dst};
 969         my (@cmd, $replaced);
 970         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 971                 @cmd = ($mua, '-f');
 972         # TODO: help wanted: other common FOSS MUAs
 973         } else {
 974                 require Text::ParseWords;
 975                 @cmd = Text::ParseWords::shellwords($mua);
 976                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 977                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 978         }
 979         push @cmd, $mfolder unless defined($replaced);
 980         if ($self->{sock}) { # lei(1) client process runs it
 981                 # restore terminal: echo $query | lei q --stdin --mua=...
 982                 my $io = [];
 983                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 984                 send_exec_cmd($self, $io, \@cmd, {});
 985         }
 986         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 987                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 988         }
 989         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 990         $self->{opt}->{quiet} = 1;
 991         delete $self->{-progress};
 992         delete $self->{opt}->{verbose};
 993 }
 994
 995 sub send_exec_cmd { # tell script/lei to execute a command
 996         my ($self, $io, $cmd, $env) = @_;
 997         my $sock = $self->{sock} // die 'lei client gone';
 998         my $fds = [ map { fileno($_) } @$io ];
 999         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
1000 }
1001
1002 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
1003         my ($self) = @_;
1004         my $alerts = $self->{opt}->{alert} // return;
1005         my $sock = $self->{sock};
1006         while (my $op = shift(@$alerts)) {
1007                 if ($op eq ':WINCH') {
1008                         # hit the process group that started the MUA
1009                         send($sock, '-WINCH', MSG_EOR) if $sock;
1010                 } elsif ($op eq ':bell') {
1011                         out($self, "\a");
1012                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
1013                         push @$alerts, split(/(?<!\\),/, $op);
1014                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
1015                         my $cmd = $1; # run an arbitrary command
1016                         require Text::ParseWords;
1017                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
1018                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
1019                 } else {
1020                         warn("W: unsupported --alert=$op\n"); # non-fatal
1021                 }
1022         }
1023 }
1024
1025 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
1026 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
1027
1028 # this also normalizes the path
1029 sub path_to_fd {
1030         my ($self, $path) = @_;
1031         $path = rel2abs($self, $path);
1032         $path =~ tr!/!/!s;
1033         $path_to_fd{$path} // (
1034                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
1035                         fail($self, "cannot open $path from daemon") : -1
1036         );
1037 }
1038
1039 # caller needs to "-t $self->{1}" to check if tty
1040 sub start_pager {
1041         my ($self, $new_env) = @_;
1042         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1043         chomp(my $pager = <$fh> // '');
1044         close($fh) or warn "`git var PAGER' error: \$?=$?";
1045         return if $pager eq 'cat' || $pager eq '';
1046         $new_env //= {};
1047         $new_env->{LESS} //= 'FRX';
1048         $new_env->{LV} //= '-c';
1049         $new_env->{MORE} = $new_env->{LESS} if $^O eq 'freebsd';
1050         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1051         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1052         my $pgr = [ undef, @$rdr{1, 2} ];
1053         my $env = $self->{env};
1054         if ($self->{sock}) { # lei(1) process runs it
1055                 delete @$new_env{keys %$env}; # only set iff unset
1056                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1057         } else {
1058                 die 'BUG: start_pager w/o socket';
1059         }
1060         $self->{1} = $wpager;
1061         $self->{2} = $wpager if -t $self->{2};
1062         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1063         $self->{pgr} = $pgr;
1064 }
1065
1066 # display a message for user before spawning full-screen $VISUAL
1067 sub pgr_err {
1068         my ($self, @msg) = @_;
1069         return warn(@msg) unless $self->{sock} && -t $self->{2};
1070         start_pager($self, { LESS => 'RX' }); # no 'F' so we prompt
1071         print { $self->{2} } @msg;
1072         $self->{2}->autoflush(1);
1073         stop_pager($self);
1074         send($self->{sock}, 'wait', MSG_EOR); # wait for user to quit pager
1075 }
1076
1077 sub stop_pager {
1078         my ($self) = @_;
1079         my $pgr = delete($self->{pgr}) or return;
1080         $self->{2} = $pgr->[2];
1081         close(delete($self->{1})) if $self->{1};
1082         $self->{1} = $pgr->[1];
1083 }
1084
1085 sub accept_dispatch { # Listener {post_accept} callback
1086         my ($sock) = @_; # ignore other
1087         $sock->autoflush(1);
1088         my $self = bless { sock => $sock }, __PACKAGE__;
1089         vec(my $rvec = '', fileno($sock), 1) = 1;
1090         select($rvec, undef, undef, 60) or
1091                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1092         # (4096 * 33) >MAX_ARG_STRLEN
1093         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1094         if (!defined($fds[0])) {
1095                 warn(my $msg = "recv_cmd failed: $!");
1096                 return send($sock, $msg, MSG_EOR);
1097         } else {
1098                 my $i = 0;
1099                 for my $fd (@fds) {
1100                         open($self->{$i++}, '+<&=', $fd) and next;
1101                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1102                 }
1103                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1104         }
1105         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1106         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1107         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1108                 return send($sock, 'request command truncated', MSG_EOR);
1109         my ($argc, @argv) = split(/\0/, $buf, -1);
1110         undef $buf;
1111         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1112         $self->{env} = \%env;
1113         eval { dispatch($self, @argv) };
1114         $self->fail($@) if $@;
1115 }
1116
1117 sub dclose {
1118         my ($self) = @_;
1119         local $current_lei = $self;
1120         delete $self->{-progress};
1121         _drop_wq($self) if $self->{failed};
1122         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1123 }
1124
1125 # for long-running results
1126 sub event_step {
1127         my ($self) = @_;
1128         local %ENV = %{$self->{env}};
1129         local $current_lei = $self;
1130         eval {
1131                 my @fds = $recv_cmd->($self->{sock} // return, my $buf, 4096);
1132                 if (scalar(@fds) == 1 && !defined($fds[0])) {
1133                         return if $! == EAGAIN;
1134                         die "recvmsg: $!" if $! != ECONNRESET;
1135                         @fds = (); # for open loop below:
1136                 }
1137                 for (@fds) { open my $rfh, '+<&=', $_ }
1138                 if ($buf eq '') {
1139                         _drop_wq($self); # EOF, client disconnected
1140                         dclose($self);
1141                         $buf = 'TERM';
1142                 }
1143                 if ($buf =~ /\A(?:STOP|CONT|TERM)\z/) {
1144                         my $sig = "-$buf";
1145                         for my $wq (grep(defined, @$self{@WQ_KEYS})) {
1146                                 $wq->wq_kill($sig);
1147                         }
1148                 } else {
1149                         die "unrecognized client signal: $buf";
1150                 }
1151                 my $s = $self->{-socks} // []; # lei up --all
1152                 @$s = grep { send($_, $buf, MSG_EOR) } @$s;
1153         };
1154         if (my $err = $@) {
1155                 eval { $self->fail($err) };
1156                 dclose($self);
1157         }
1158 }
1159
1160 sub event_step_init {
1161         my ($self) = @_;
1162         my $sock = $self->{sock} or return;
1163         $self->{-event_init_done} // do { # persist til $ops done
1164                 $sock->blocking(0);
1165                 $self->SUPER::new($sock, EPOLLIN);
1166                 $self->{-event_init_done} = $sock;
1167         };
1168 }
1169
1170 sub noop {}
1171
1172 sub oldset { $oldset }
1173
1174 sub dump_and_clear_log {
1175         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1176                 openlog('lei-daemon', 'pid,nowait,nofatal,ndelay', 'user');
1177                 chomp(my @lines = <STDIN>);
1178                 truncate(STDIN, 0) or
1179                         syslog('warning', "ftruncate (%s): %m", $errors_log);
1180                 for my $l (@lines) { syslog('warning', '%s', $l) }
1181                 closelog(); # don't share across fork
1182         }
1183 }
1184
1185 sub cfg2lei ($) {
1186         my ($cfg) = @_;
1187         my $lei = bless { env => { %{$cfg->{-env}} } }, __PACKAGE__;
1188         open($lei->{0}, '<&', \*STDIN) or die "dup 0: $!";
1189         open($lei->{1}, '>>&', \*STDOUT) or die "dup 1: $!";
1190         open($lei->{2}, '>>&', \*STDERR) or die "dup 2: $!";
1191         open($lei->{3}, '<', '/') or die "open /: $!";
1192         my ($x, $y);
1193         socketpair($x, $y, AF_UNIX, SOCK_SEQPACKET, 0) or die "socketpair: $!";
1194         $lei->{sock} = $x;
1195         require PublicInbox::LeiSelfSocket;
1196         PublicInbox::LeiSelfSocket->new($y); # adds to event loop
1197         $lei;
1198 }
1199
1200 sub dir_idle_handler ($) { # PublicInbox::DirIdle callback
1201         my ($ev) = @_; # Linux::Inotify2::Event or duck type
1202         my $fn = $ev->fullname;
1203         if ($fn =~ m!\A(.+)/(new|cur)/([^/]+)\z!) { # Maildir file
1204                 my ($mdir, $nc, $bn) = ($1, $2, $3);
1205                 $nc = '' if $ev->IN_DELETE || $ev->IN_MOVED_FROM;
1206                 for my $f (keys %{$MDIR2CFGPATH->{$mdir} // {}}) {
1207                         my $cfg = $PATH2CFG{$f} // next;
1208                         eval {
1209                                 my $lei = cfg2lei($cfg);
1210                                 $lei->dispatch('note-event',
1211                                                 "maildir:$mdir", $nc, $bn, $fn);
1212                         };
1213                         warn "E: note-event $f: $@\n" if $@;
1214                 }
1215         }
1216         if ($ev->can('cancel') && ($ev->IN_IGNORE || $ev->IN_UNMOUNT)) {
1217                 $ev->cancel;
1218         }
1219         if ($fn =~ m!\A(.+)/(?:new|cur)\z! && !-e $fn) {
1220                 delete $MDIR2CFGPATH->{$1};
1221         }
1222         if (!-e $fn) { # config file or Maildir gone
1223                 for my $cfgpaths (values %$MDIR2CFGPATH) {
1224                         delete $cfgpaths->{$fn};
1225                 }
1226                 delete $PATH2CFG{$fn};
1227         }
1228 }
1229
1230 # lei(1) calls this when it can't connect
1231 sub lazy_start {
1232         my ($path, $errno, $narg) = @_;
1233         local ($errors_log, $listener);
1234         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1235         $errors_log = "$sock_dir/errors.log";
1236         my $addr = pack_sockaddr_un($path);
1237         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1238         umask(077) // die("umask(077): $!");
1239         $lk->lock_acquire;
1240         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1241         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1242                 return if connect($listener, $addr); # another process won
1243                 if ($errno == ECONNREFUSED && -S $path) {
1244                         unlink($path) or die "unlink($path): $!";
1245                 }
1246         } else {
1247                 $! = $errno; # allow interpolation to stringify in die
1248                 die "connect($path): $!";
1249         }
1250         bind($listener, $addr) or die "bind($path): $!";
1251         $lk->lock_release;
1252         undef $lk;
1253         my @st = stat($path) or die "stat($path): $!";
1254         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1255         local $oldset = PublicInbox::DS::block_signals();
1256         if ($narg == 5) {
1257                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1258                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1259                         require PublicInbox::CmdIPC4;
1260                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1261                         PublicInbox::CmdIPC4->can('recv_cmd4');
1262                 };
1263         }
1264         $recv_cmd or die <<"";
1265 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1266
1267         require PublicInbox::Listener;
1268         require PublicInbox::PktOp;
1269         (-p STDOUT) or die "E: stdout must be a pipe\n";
1270         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1271         STDIN->autoflush(1);
1272         dump_and_clear_log();
1273         POSIX::setsid() > 0 or die "setsid: $!";
1274         my $pid = fork // die "fork: $!";
1275         return if $pid;
1276         $0 = "lei-daemon $path";
1277         local %PATH2CFG;
1278         local $MDIR2CFGPATH;
1279         $listener->blocking(0);
1280         my $exit_code;
1281         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1282         local $quit = do {
1283                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1284                 sub {
1285                         $exit_code //= shift;
1286                         eval 'PublicInbox::LeiNoteEvent::flush_task()';
1287                         my $lis = $pil or exit($exit_code);
1288                         # closing eof_p triggers \&noop wakeup
1289                         $listener = $eof_p = $pil = $path = undef;
1290                         $lis->close; # DS::close
1291                         PublicInbox::DS->SetLoopTimeout(1000);
1292                 };
1293         };
1294         my $sig = {
1295                 CHLD => \&PublicInbox::DS::enqueue_reap,
1296                 QUIT => $quit,
1297                 INT => $quit,
1298                 TERM => $quit,
1299                 HUP => \&noop,
1300                 USR1 => \&noop,
1301                 USR2 => \&noop,
1302         };
1303         require PublicInbox::DirIdle;
1304         local $dir_idle = PublicInbox::DirIdle->new(sub {
1305                 # just rely on wakeup to hit PostLoopCallback set below
1306                 dir_idle_handler($_[0]) if $_[0]->fullname ne $path;
1307         });
1308         $dir_idle->add_watches([$sock_dir]);
1309         PublicInbox::DS->SetPostLoopCallback(sub {
1310                 my ($dmap, undef) = @_;
1311                 if (@st = defined($path) ? stat($path) : ()) {
1312                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1313                                 warn "$path dev/ino changed, quitting\n";
1314                                 $path = undef;
1315                         }
1316                 } elsif (defined($path)) { # ENOENT is common
1317                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1318                         undef $path;
1319                         $quit->();
1320                 }
1321                 return 1 if defined($path);
1322                 my $n = 0;
1323                 for my $s (values %$dmap) {
1324                         $s->can('busy') or next;
1325                         if ($s->busy) {
1326                                 ++$n;
1327                         } else {
1328                                 $s->close;
1329                         }
1330                 }
1331                 $n; # true: continue, false: stop
1332         });
1333
1334         # STDIN was redirected to /dev/null above, closing STDERR and
1335         # STDOUT will cause the calling `lei' client process to finish
1336         # reading the <$daemon> pipe.
1337         local $SIG{__WARN__} = sub {
1338                 $current_lei ? err($current_lei, @_) : warn(
1339                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1340         };
1341         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1342         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1343         # $daemon pipe to `lei' closed, main loop begins:
1344         eval { PublicInbox::DS::event_loop($sig, $oldset) };
1345         warn "event loop error: $@\n" if $@;
1346         # exit() may trigger waitpid via various DESTROY, ensure interruptible
1347         PublicInbox::DS::sig_setmask($oldset);
1348         dump_and_clear_log();
1349         exit($exit_code // 0);
1350 }
1351
1352 sub busy { 1 } # prevent daemon-shutdown if client is connected
1353
1354 # ensures stdout hits the FS before sock disconnects so a client
1355 # can immediately reread it
1356 sub DESTROY {
1357         my ($self) = @_;
1358         if (my $counters = delete $self->{counters}) {
1359                 for my $k (sort keys %$counters) {
1360                         my $nr = $counters->{$k};
1361                         $self->child_error(0, "$nr $k messages");
1362                 }
1363         }
1364         $self->{1}->autoflush(1) if $self->{1};
1365         stop_pager($self);
1366         dump_and_clear_log();
1367         # preserve $? for ->fail or ->x_it code
1368 }
1369
1370 sub wq_done_wait { # dwaitpid callback
1371         my ($arg, $pid) = @_;
1372         my ($wq, $lei) = @$arg;
1373         local $current_lei = $lei;
1374         my $err_type = $lei->{-err_type};
1375         $? and $lei->child_error($?,
1376                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1377         $lei->dclose;
1378 }
1379
1380 sub fchdir {
1381         my ($lei) = @_;
1382         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1383         chdir($dh) || die "fchdir: $!";
1384 }
1385
1386 sub wq_eof { # EOF callback for main daemon
1387         my ($lei) = @_;
1388         local $current_lei = $lei;
1389         delete $lei->{wq1} // return $lei->fail; # already failed
1390 }
1391
1392 sub watch_state_ok ($) {
1393         my ($state) = $_[-1]; # $_[0] may be $self
1394         $state =~ /\Apause|(?:import|index|tag)-(?:ro|rw)\z/;
1395 }
1396
1397 sub cancel_maildir_watch ($$) {
1398         my ($d, $cfg_f) = @_;
1399         my $w = delete $MDIR2CFGPATH->{$d}->{$cfg_f};
1400         scalar(keys %{$MDIR2CFGPATH->{$d}}) or
1401                 delete $MDIR2CFGPATH->{$d};
1402         for my $x (@{$w // []}) { $x->cancel }
1403 }
1404
1405 sub add_maildir_watch ($$) {
1406         my ($d, $cfg_f) = @_;
1407         if (!exists($MDIR2CFGPATH->{$d}->{$cfg_f})) {
1408                 my @w = $dir_idle->add_watches(["$d/cur", "$d/new"], 1);
1409                 push @{$MDIR2CFGPATH->{$d}->{$cfg_f}}, @w if @w;
1410         }
1411 }
1412
1413 sub refresh_watches {
1414         my ($lei) = @_;
1415         $dir_idle or return;
1416         my $cfg = _lei_cfg($lei) or return;
1417         my $old = $cfg->{-watches};
1418         my $watches = $cfg->{-watches} //= {};
1419         my %seen;
1420         my $cfg_f = $cfg->{'-f'};
1421         for my $w (grep(/\Awatch\..+\.state\z/, keys %$cfg)) {
1422                 my $url = substr($w, length('watch.'), -length('.state'));
1423                 require PublicInbox::LeiWatch;
1424                 $watches->{$url} //= PublicInbox::LeiWatch->new($url);
1425                 $seen{$url} = undef;
1426                 my $state = $cfg->get_1("watch.$url.state");
1427                 if (!watch_state_ok($state)) {
1428                         warn("watch.$url.state=$state not supported\n");
1429                         next;
1430                 }
1431                 if ($url =~ /\Amaildir:(.+)/i) {
1432                         my $d = canonpath_harder($1);
1433                         if ($state eq 'pause') {
1434                                 cancel_maildir_watch($d, $cfg_f);
1435                         } else {
1436                                 add_maildir_watch($d, $cfg_f);
1437                         }
1438                 } else { # TODO: imap/nntp/jmap
1439                         $lei->child_error(0, "E: watch $url not supported, yet")
1440                 }
1441         }
1442
1443         # add all known Maildir folders as implicit watches
1444         my $lms = $lei->lms;
1445         if ($lms) {
1446                 $lms->lms_write_prepare;
1447                 for my $d ($lms->folders('maildir:')) {
1448                         substr($d, 0, length('maildir:')) = '';
1449
1450                         # fixup old bugs while we're iterating:
1451                         my $cd = canonpath_harder($d);
1452                         my $f = "maildir:$cd";
1453                         $lms->rename_folder("maildir:$d", $f) if $d ne $cd;
1454                         next if $watches->{$f}; # may be set to pause
1455                         require PublicInbox::LeiWatch;
1456                         $watches->{$f} = PublicInbox::LeiWatch->new($f);
1457                         $seen{$f} = undef;
1458                         add_maildir_watch($cd, $cfg_f);
1459                 }
1460         }
1461         if ($old) { # cull old non-existent entries
1462                 for my $url (keys %$old) {
1463                         next if exists $seen{$url};
1464                         delete $old->{$url};
1465                         if ($url =~ /\Amaildir:(.+)/i) {
1466                                 my $d = canonpath_harder($1);
1467                                 cancel_maildir_watch($d, $cfg_f);
1468                         } else { # TODO: imap/nntp/jmap
1469                                 $lei->child_error(0, "E: watch $url TODO");
1470                         }
1471                 }
1472         }
1473         if (scalar keys %$watches) {
1474                 $cfg->{-env} //= { %{$lei->{env}}, PWD => '/' }; # for cfg2lei
1475         } else {
1476                 delete $cfg->{-watches};
1477         }
1478 }
1479
1480 # TODO: support SHA-256
1481 sub git_oid {
1482         my $eml = $_[-1];
1483         $eml->header_set($_) for @PublicInbox::Import::UNWANTED_HEADERS;
1484         git_sha(1, $eml);
1485 }
1486
1487 sub lms {
1488         my ($lei, $rw) = @_;
1489         my $sto = $lei->{sto} // _lei_store($lei) // return;
1490         require PublicInbox::LeiMailSync;
1491         my $f = "$sto->{priv_eidx}->{topdir}/mail_sync.sqlite3";
1492         (-f $f || $rw) ? PublicInbox::LeiMailSync->new($f) : undef;
1493 }
1494
1495 sub sto_done_request {
1496         my ($lei, $sock) = @_;
1497         local $current_lei = $lei;
1498         eval {
1499                 if ($sock //= $lei->{sock}) { # issue, async wait
1500                         $lei->{sto}->wq_io_do('done', [ $sock ]);
1501                 } else { # forcibly wait
1502                         my $wait = $lei->{sto}->wq_do('done');
1503                 }
1504         };
1505         warn($@) if $@;
1506 }
1507
1508 sub cfg_dump ($$) {
1509         my ($lei, $f) = @_;
1510         my $ret = eval { PublicInbox::Config->git_config_dump($f, $lei->{2}) };
1511         return $ret if !$@;
1512         warn($@);
1513         undef;
1514 }
1515
1516 sub request_umask {
1517         my ($lei) = @_;
1518         my $s = $lei->{sock} // return;
1519         send($s, 'umask', MSG_EOR) // die "send: $!";
1520         vec(my $rvec = '', fileno($s), 1) = 1;
1521         select($rvec, undef, undef, 2) or die 'timeout waiting for umask';
1522         recv($s, my $v, 5, 0) // die "recv: $!";
1523         (my $u, $lei->{client_umask}) = unpack('AV', $v);
1524         $u eq 'u' or warn "E: recv $v has no umask";
1525 }
1526
1527 1;