]> Sergey Matveev's repositories - public-inbox.git/blob - lib/PublicInbox/LEI.pm
lei blob: aka "git-show-harder" for blobs
[public-inbox.git] / lib / PublicInbox / LEI.pm
1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
3
4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
6 # local clients with read/write access to the FS and use as many
7 # system resources as the local user has access to.
8 package PublicInbox::LEI;
9 use strict;
10 use v5.10.1;
11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
12         PublicInbox::LeiQuery);
13 use Getopt::Long ();
14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
16 use Cwd qw(getcwd);
17 use POSIX qw(strftime);
18 use IO::Handle ();
19 use Fcntl qw(SEEK_SET);
20 use PublicInbox::Config;
21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
22 use PublicInbox::Sigfd;
23 use PublicInbox::DS qw(now dwaitpid);
24 use PublicInbox::Spawn qw(spawn popen_rd);
25 use PublicInbox::Lock;
26 use Time::HiRes qw(stat); # ctime comparisons for config cache
27 use File::Path qw(mkpath);
28 use File::Spec;
29 our $quit = \&CORE::exit;
30 our ($current_lei, $errors_log, $listener, $oldset);
31 my ($recv_cmd, $send_cmd);
32 my $GLP = Getopt::Long::Parser->new;
33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
34 my $GLP_PASS = Getopt::Long::Parser->new;
35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
36
37 our %PATH2CFG; # persistent for socket daemon
38
39 # TBD: this is a documentation mechanism to show a subcommand
40 # (may) pass options through to another command:
41 sub pass_through { $GLP_PASS }
42
43 my $OPT;
44 sub opt_dash ($$) {
45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
47         my $cb = sub { # Getopt::Long "<>" catch-all handler
48                 my ($arg) = @_;
49                 if ($arg =~ /\A-($re_str)\z/) {
50                         $OPT->{$key} = $1;
51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
53                 # lone (single) dash is handled elsewhere
54                 } elsif (substr($arg, 0, 1) eq '-') {
55                         if ($OPT->{'--'}) {
56                                 push @{$OPT->{-argv}}, $arg;
57                         } else {
58                                 die "bad argument: $arg\n";
59                         }
60                 } else {
61                         push @{$OPT->{-argv}}, $arg;
62                 }
63         };
64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
65 }
66
67 sub rel2abs ($$) {
68         my ($self, $p) = @_;
69         return $p if index($p, '/') == 0; # already absolute
70         my $pwd = $self->{env}->{PWD};
71         if (defined $pwd) {
72                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
73                 if (my @st_pwd = stat($pwd)) {
74                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
75                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
76                                 $self->{env}->{PWD} = $pwd = $cwd;
77                 } else { # PWD was invalid
78                         delete $self->{env}->{PWD};
79                         undef $pwd;
80                 }
81         }
82         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
83         File::Spec->rel2abs($p, $pwd);
84 }
85
86 sub store_path ($) {
87         my ($self) = @_;
88         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
89                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
90                 .'/lei/store');
91 }
92
93 sub _config_path ($) {
94         my ($self) = @_;
95         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
96                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
97                 .'/lei/config');
98 }
99
100 sub cache_dir ($) {
101         my ($self) = @_;
102         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
103                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
104                 .'/lei');
105 }
106
107 sub ale {
108         my ($self) = @_;
109         $self->{ale} //= do {
110                 require PublicInbox::LeiALE;
111                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
112         };
113 }
114
115 sub index_opt {
116         # TODO: drop underscore variants everywhere, they're undocumented
117         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
118         max_size|max-size=s sequential_shard|sequential-shard
119         batch_size|batch-size=s skip-docdata)
120 }
121
122 my @c_opt = qw(c=s@ C=s@ quiet|q);
123 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
124         import-remote!  no-torsocks torsocks=s),
125         PublicInbox::LeiQuery::curl_opt());
126
127 # we generate shell completion + help using %CMD and %OPTDESC,
128 # see lei__complete() and PublicInbox::LeiHelp
129 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
130 our %CMD = ( # sorted in order of importance/use:
131 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
132         'stdin|', # /|\z/ must be first for lone dash
133         @lxs_opt,
134         qw(save-as=s output|mfolder|o=s format|f=s dedupe|d=s threads|t+
135         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
136         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+), @c_opt,
137         opt_dash('limit|n=i', '[0-9]+') ],
138
139 'blob' => [ 'OID', 'display a git blob object, solving if necessary',
140         qw(git-dir=s@ cwd! verbose|v+ oid-a|A=s path-a|a=s path-b|b=s),
141         @lxs_opt, @c_opt ],
142
143 'add-external' => [ 'LOCATION',
144         'add/set priority of a publicinbox|extindex for extra matches',
145         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
146         verbose|v+), @c_opt, index_opt(),
147         PublicInbox::LeiQuery::curl_opt() ],
148 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
149         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
150 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
151 'forget-external' => [ 'LOCATION...|--prune',
152         'exclude further results from a publicinbox|extindex',
153         qw(prune), @c_opt ],
154
155 'ls-query' => [ '[FILTER...]', 'list saved search queries',
156                 qw(name-only format|f=s), @c_opt ],
157 'rm-query' => [ 'QUERY_NAME', 'remove a saved search', @c_opt ],
158 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search', @c_opt ],
159
160 'plonk' => [ '--threads|--from=IDENT',
161         'exclude mail matching From: or threads from non-Message-ID searches',
162         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
163 'mark' => [ 'KEYWORDS...',
164         'set/unset keywords on message(s)',
165         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@), @c_opt,
166         pass_through('-kw:foo for delete') ],
167 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
168         "exclude message(s) on stdin from `q' search results",
169         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
170
171 'purge-mailsource' => [ 'LOCATION|--all',
172         'remove imported messages from IMAP, Maildirs, and MH',
173         qw(exact! all jobs:i indexed), @c_opt ],
174
175 # code repos are used for `show' to solve blobs from patch mails
176 'add-coderepo' => [ 'DIRNAME', 'add or set priority of a git code repo',
177         qw(boost=i), @c_opt ],
178 'ls-coderepo' => [ '[FILTER_TERMS...]',
179                 'list known code repos', qw(format|f=s z), @c_opt ],
180 'forget-coderepo' => [ 'DIRNAME',
181         'stop using repo to solve blobs from patches',
182         qw(prune), @c_opt ],
183
184 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
185         qw(import! kw|keywords|flags! interval=s recursive|r
186         exclude=s include=s), @c_opt ],
187 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
188                 qw(format|f=s z), @c_opt ],
189 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
190 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
191 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
192         qw(prune), @c_opt ],
193
194 'import' => [ 'LOCATION...|--stdin',
195         'one-time import/update from URL or filesystem',
196         qw(stdin| offset=i recursive|r exclude=s include|I=s
197         lock=s@ in-format|F=s kw|keywords|flags! verbose|v+), @c_opt ],
198 'convert' => [ 'LOCATION...|--stdin',
199         'one-time conversion from URL or filesystem to another format',
200         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s
201         lock=s@ kw|keywords|flags!), @c_opt ],
202 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
203         "use a patch to generate a query for `lei q --stdin'",
204         qw(stdin| want|w=s@ uri debug), @c_opt ],
205 'config' => [ '[...]', sub {
206                 'git-config(1) wrapper for '._config_path($_[0]);
207         }, qw(config-file|system|global|file|f=s), # for conflict detection
208          qw(c=s@ C=s@), pass_through('git config') ],
209 'init' => [ '[DIRNAME]', sub {
210         "initialize storage, default: ".store_path($_[0]);
211         }, @c_opt ],
212 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
213         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
214         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
215 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
216 'help' => [ '[SUBCOMMAND]', 'show help' ],
217
218 # XXX do we need this?
219 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
220
221 'reorder-local-store-and-break-history' => [ '[REFNAME]',
222         'rewrite git history in an attempt to improve compression',
223         qw(gc!), @c_opt ],
224
225 # internal commands are prefixed with '_'
226 '_complete' => [ '[...]', 'internal shell completion helper',
227                 pass_through('everything') ],
228 ); # @CMD
229
230 # switch descriptions, try to keep consistent across commands
231 # $spec: Getopt::Long option specification
232 # $spec => [@ALLOWED_VALUES (default is first), $description],
233 # $spec => $description
234 # "$SUB_COMMAND TAB $spec" => as above
235 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
236                         'specify message input format' ];
237 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
238
239 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
240 my %OPTDESC = (
241 'help|h' => 'show this built-in help',
242 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
243 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
244 'quiet|q' => 'be quiet',
245 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
246         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
247
248 'globoff|g' => "do not match locations using '*?' wildcards ".
249                 "and\xa0'[]'\x{a0}ranges",
250 'verbose|v+' => 'be more verbose',
251 'external!' => 'do not use externals',
252 'solve!' => 'do not attempt to reconstruct blobs from emails',
253 'torsocks=s' => ['VAL|auto|no|yes',
254                 'whether or not to wrap git and curl commands with torsocks'],
255 'no-torsocks' => 'alias for --torsocks=no',
256 'save-as=s' => ['NAME', 'save a search terms by given name'],
257 'import-remote!' => 'do not memoize remote messages into local store',
258
259 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
260
261 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
262                 'deduplication strategy'],
263 'threads|t+' =>
264         'return all messages in the same threads as the actual match(es)',
265
266 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
267                 'search prefixes to extract (default: dfpost7)' ],
268
269 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
270         'run command(s) or perform ops when done writing to output ' .
271         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
272         'nothing otherwise)' ],
273
274 'augment|a' => 'augment --output destination instead of clobbering',
275
276 'output|mfolder|o=s' => [ 'MFOLDER',
277         "destination (e.g.\xa0`/path/to/Maildir', ".
278         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
279 'mua=s' => [ 'CMD',
280         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
281
282 'inbox-version=i' => [ 'NUM|1|2',
283                 'force a public-inbox version with --mirror'],
284 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
285
286 # public-inbox-index options
287 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
288 'compact' => 'run compact index after mirroring',
289 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
290         "indexlevel with --mirror (default: full)" ],
291 'max_size|max-size=s' => [ 'SIZE',
292         'do not index messages larger than SIZE (default: infinity)' ],
293 'batch_size|batch-size=s' => [ 'SIZE',
294         'flush changes to OS after given number of bytes (default: 1m)' ],
295 'sequential_shard|sequential-shard' =>
296         'index Xapian shards sequentially for slow storage',
297 'skip-docdata' =>
298         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
299
300 'format|f=s     q' => [
301         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
302                 'specify output format, default depends on --output'],
303 'exclude=s@     q' => [ 'LOCATION',
304                 'exclude specified external(s) from search' ],
305 'include|I=s@   q' => [ 'LOCATION',
306                 'include specified external(s) in search' ],
307 'only=s@        q' => [ 'LOCATION',
308                 'only use specified external(s) for search' ],
309 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
310                 'control number of search and writer jobs' ],
311 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
312
313 'in-format|F=s' => $stdin_formats,
314 'format|f=s     ls-query' => $ls_format,
315 'format|f=s     ls-external' => $ls_format,
316
317 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
318 'offset=i' => ['OFF', 'search result offset (default: 0)'],
319
320 'sort|s=s' => [ 'VAL|received|relevance|docid',
321                 "order of results is `--output'-dependent"],
322 'reverse|r' => 'reverse search results', # like sort(1)
323
324 'boost=i' => 'increase/decrease priority of results (default: 0)',
325
326 'local' => 'limit operations to the local filesystem',
327 'local!' => 'exclude results from the local filesystem',
328 'remote' => 'limit operations to those requiring network access',
329 'remote!' => 'prevent operations requiring network access',
330
331 'mid=s' => 'specify the Message-ID of a message',
332 'oid=s' => 'specify the git object ID of a message',
333
334 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
335 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
336 'include=s' => 'include mailboxes/newsgroups based on pattern',
337
338 'exact' => 'operate on exact header matches only',
339 'exact!' => 'rely on content match instead of exact header matches',
340
341 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
342
343 'kw|keywords|flags!' => 'disable/enable importing flags',
344
345 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
346 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
347
348 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
349 ); # %OPTDESC
350
351 my %CONFIG_KEYS = (
352         'leistore.dir' => 'top-level storage location',
353 );
354
355 my @WQ_KEYS = qw(lxs l2m imp mrr cnv p2q mark sol); # internal workers
356
357 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
358 sub x_it ($$) {
359         my ($self, $code) = @_;
360         # make sure client sees stdout before exit
361         $self->{1}->autoflush(1) if $self->{1};
362         dump_and_clear_log();
363         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
364                 send($s, "x_it $code", MSG_EOR);
365         } elsif ($self->{oneshot}) {
366                 # don't want to end up using $? from child processes
367                 for my $f (@WQ_KEYS) {
368                         my $wq = delete $self->{$f} or next;
369                         $wq->DESTROY;
370                 }
371                 # cleanup anything that has tempfiles or open file handles
372                 %PATH2CFG = ();
373                 delete @$self{qw(ovv dedupe sto cfg)};
374                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
375                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
376                         kill $signum, $$;
377                         sleep(1) while 1; # wait for signal
378                 } else {
379                         $quit->($code >> 8);
380                 }
381         } # else ignore if client disconnected
382 }
383
384 sub err ($;@) {
385         my $self = shift;
386         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
387         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
388         print $err @_, @eor and return;
389         my $old_err = delete $self->{2};
390         close($old_err) if $! == EPIPE && $old_err;
391         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
392         print $err @_, @eor or print STDERR @_, @eor;
393 }
394
395 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
396
397 sub fail_handler ($;$$) {
398         my ($lei, $code, $io) = @_;
399         for my $f (@WQ_KEYS) {
400                 my $wq = delete $lei->{$f} or next;
401                 $wq->wq_wait_old(undef, $lei) if $wq->wq_kill_old; # lei-daemon
402         }
403         close($io) if $io; # needed to avoid warnings on SIGPIPE
404         x_it($lei, $code // (1 << 8));
405 }
406
407 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
408         fail_handler($_[0], 13, delete $_[0]->{1});
409 }
410
411 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
412 sub sigint_reap {
413         my ($pgid) = @_;
414         dwaitpid($pgid) if kill('-INT', $pgid);
415 }
416
417 sub fail ($$;$) {
418         my ($self, $buf, $exit_code) = @_;
419         err($self, $buf) if defined $buf;
420         # calls fail_handler:
421         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
422         x_it($self, ($exit_code // 1) << 8);
423         undef;
424 }
425
426 sub out ($;@) {
427         my $self = shift;
428         return if print { $self->{1} // return } @_; # likely
429         return note_sigpipe($self, 1) if $! == EPIPE;
430         my $err = "error writing to output: $!";
431         delete $self->{1};
432         fail($self, $err);
433 }
434
435 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
436
437 sub child_error { # passes non-fatal curl exit codes to user
438         my ($self, $child_error, $msg) = @_; # child_error is $?
439         $self->err($msg) if $msg;
440         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
441                 # send to the parent lei-daemon or to lei(1) client
442                 send($s, "child_error $child_error", MSG_EOR);
443         } elsif (!$PublicInbox::DS::in_loop) {
444                 $self->{child_error} = $child_error;
445         } # else noop if client disconnected
446 }
447
448 sub note_sigpipe { # triggers sigpipe_handler
449         my ($self, $fd) = @_;
450         close(delete($self->{$fd})); # explicit close silences Perl warning
451         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
452         x_it($self, 13);
453 }
454
455 sub _lei_atfork_child {
456         my ($self, $persist) = @_;
457         # we need to explicitly close things which are on stack
458         if ($persist) {
459                 chdir '/' or die "chdir(/): $!";
460                 my @io = delete @$self{qw(0 1 2 sock)};
461                 unless ($self->{oneshot}) {
462                         close($_) for @io;
463                 }
464                 if (my $cfg = $self->{cfg}) {
465                         delete $cfg->{-lei_store};
466                 }
467         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
468                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
469         }
470         for (delete @$self{qw(3 old_1 au_done)}) {
471                 close($_) if defined($_);
472         }
473         if (my $op_c = delete $self->{pkt_op_c}) {
474                 close(delete $op_c->{sock});
475         }
476         if (my $pgr = delete $self->{pgr}) {
477                 close($_) for (@$pgr[1,2]);
478         }
479         close $listener if $listener;
480         undef $listener;
481         %PATH2CFG = ();
482         undef $errors_log;
483         $quit = \&CORE::exit;
484         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
485 }
486
487 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
488         my ($self) = @_;
489         if (my $op = delete $self->{pkt_op_c}) { # in case of die
490                 $op->close; # PublicInbox::PktOp::close
491         }
492         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
493         close $unclosed_after_die;
494 }
495
496 sub pkt_op_pair {
497         my ($self, $ops) = @_;
498         require PublicInbox::OnDestroy;
499         require PublicInbox::PktOp;
500         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
501         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair($ops);
502         $end;
503 }
504
505 sub workers_start {
506         my ($lei, $wq, $ident, $jobs, $ops) = @_;
507         $ops = {
508                 '!' => [ \&fail_handler, $lei ],
509                 '|' => [ \&sigpipe_handler, $lei ],
510                 'x_it' => [ \&x_it, $lei ],
511                 'child_error' => [ \&child_error, $lei ],
512                 ($ops ? %$ops : ()),
513         };
514         $ops->{''} //= [ \&dclose, $lei ];
515         my $end = $lei->pkt_op_pair($ops);
516         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
517         delete $lei->{pkt_op_p};
518         my $op = delete $lei->{pkt_op_c};
519         @$end = ();
520         $lei->event_step_init;
521         # oneshot needs $op, daemon-mode uses DS->EventLoop to handle $op
522         $lei->{oneshot} ? $op : undef;
523 }
524
525 sub _help {
526         require PublicInbox::LeiHelp;
527         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
528 }
529
530 sub optparse ($$$) {
531         my ($self, $cmd, $argv) = @_;
532         # allow _complete --help to complete, not show help
533         return 1 if substr($cmd, 0, 1) eq '_';
534         $self->{cmd} = $cmd;
535         $OPT = $self->{opt} //= {};
536         my $info = $CMD{$cmd} // [ '[...]' ];
537         my ($proto, undef, @spec) = @$info;
538         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
539         push @spec, qw(help|h);
540         my $lone_dash;
541         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
542                 $lone_dash = $spec[0];
543                 $OPT->{$spec[0]} = \(my $var);
544                 push @spec, '' => \$var;
545         }
546         $glp->getoptionsfromarray($argv, $OPT, @spec) or
547                 return _help($self, "bad arguments or options for $cmd");
548         return _help($self) if $OPT->{help};
549
550         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
551
552         # "-" aliases "stdin" or "clear"
553         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
554
555         my $i = 0;
556         my $POS_ARG = '[A-Z][A-Z0-9_]+';
557         my ($err, $inf);
558         my @args = split(/ /, $proto);
559         for my $var (@args) {
560                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
561                         $inf = defined($argv->[$i]) and last;
562                         $var =~ s/\.\.\.\z//;
563                         $err = "$var not supplied";
564                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
565                         $argv->[$i++] // ($err = "$var not supplied");
566                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
567                         $inf = 1;
568                         last;
569                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
570                         $i++;
571                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
572                         $inf = 1 if index($var, '...') > 0;
573                         my @or = split(/\|/, $var);
574                         my $ok;
575                         for my $o (@or) {
576                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
577                                         $ok = defined($OPT->{$1});
578                                         last if $ok;
579                                 } elsif (defined($argv->[$i])) {
580                                         $ok = 1;
581                                         $i++;
582                                         last;
583                                 } # else continue looping
584                         }
585                         last if $ok;
586                         my $last = pop @or;
587                         $err = join(', ', @or) . " or $last must be set";
588                 } else {
589                         warn "BUG: can't parse `$var' in $proto";
590                 }
591                 last if $err;
592         }
593         if (!$inf && scalar(@$argv) > scalar(@args)) {
594                 $err //= 'too many arguments';
595         }
596         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
597 }
598
599 sub _tmp_cfg { # for lei -c <name>=<value> ...
600         my ($self) = @_;
601         my $cfg = _lei_cfg($self, 1);
602         require File::Temp;
603         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
604         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
605         $ft->autoflush(1);
606         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
607 [include]
608         path = $cfg->{-f}
609 EOM
610         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
611         for (@{$self->{opt}->{c}}) {
612                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
613 `-c $_' is not of the form -c <name>=<value>'
614 EOM
615                 my $name = $1;
616                 my $value = $2 // 1;
617                 _config($self, '--add', $name, $value);
618                 if (defined(my $v = $tmp->{$name})) {
619                         if (ref($v) eq 'ARRAY') {
620                                 push @$v, $value;
621                         } else {
622                                 $tmp->{$name} = [ $v, $value ];
623                         }
624                 } else {
625                         $tmp->{$name} = $value;
626                 }
627         }
628 }
629
630 sub lazy_cb ($$$) {
631         my ($self, $cmd, $pfx) = @_;
632         my $ucmd = $cmd;
633         $ucmd =~ tr/-/_/;
634         my $cb;
635         $cb = $self->can($pfx.$ucmd) and return $cb;
636         my $base = $ucmd;
637         $base =~ s/_([a-z])/\u$1/g;
638         my $pkg = "PublicInbox::Lei\u$base";
639         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
640                 $pkg->can($pfx.$ucmd) : undef;
641 }
642
643 sub dispatch {
644         my ($self, $cmd, @argv) = @_;
645         local $current_lei = $self; # for __WARN__
646         dump_and_clear_log("from previous run\n");
647         return _help($self, 'no command given') unless defined($cmd);
648         # do not support Getopt bundling for this
649         while ($cmd eq '-C' || $cmd eq '-c') {
650                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
651                                         '-C DIRECTORY' : '-c <name>=<value>');
652                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
653                 $cmd = shift(@argv) // return _help($self, 'no command given');
654         }
655         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
656                 optparse($self, $cmd, \@argv) or return;
657                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
658                 if (my $chdir = $self->{opt}->{C}) {
659                         for my $d (@$chdir) {
660                                 next if $d eq ''; # same as git(1)
661                                 chdir $d or return fail($self, "cd $d: $!");
662                         }
663                         if (delete $self->{3}) { # update cwd for rel2abs
664                                 opendir my $dh, '.' or
665                                         return fail($self, "opendir . $!");
666                                 $self->{3} = $dh;
667                         }
668                 }
669                 $cb->($self, @argv);
670         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
671                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
672                         or return _help($self, 'bad arguments or options');
673                 _help($self);
674         } else {
675                 fail($self, "`$cmd' is not an lei command");
676         }
677 }
678
679 sub _lei_cfg ($;$) {
680         my ($self, $creat) = @_;
681         return $self->{cfg} if $self->{cfg};
682         my $f = _config_path($self);
683         my @st = stat($f);
684         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
685         my ($sto, $sto_dir);
686         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
687                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
688                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
689         }
690         if (!@st) {
691                 unless ($creat) {
692                         delete $self->{cfg};
693                         return bless {}, 'PublicInbox::Config';
694                 }
695                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
696                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
697                 open my $fh, '>>', $f or die "open($f): $!\n";
698                 @st = stat($fh) or die "fstat($f): $!\n";
699                 $cur_st = pack('dd', $st[10], $st[7]);
700                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
701         }
702         my $cfg = PublicInbox::Config::git_config_dump($f);
703         bless $cfg, 'PublicInbox::Config';
704         $cfg->{-st} = $cur_st;
705         $cfg->{'-f'} = $f;
706         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
707                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
708                                                 store_path($self))) {
709                 $cfg->{-lei_store} = $sto;
710         }
711         if (scalar(keys %PATH2CFG) > 5) {
712                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
713                 for my $k (keys %PATH2CFG) {
714                         delete($PATH2CFG{$k}) unless -f $k
715                 }
716         }
717         $self->{cfg} = $PATH2CFG{$f} = $cfg;
718 }
719
720 sub _lei_store ($;$) {
721         my ($self, $creat) = @_;
722         my $cfg = _lei_cfg($self, $creat);
723         $cfg->{-lei_store} //= do {
724                 require PublicInbox::LeiStore;
725                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
726                 return unless $creat || -d $dir;
727                 PublicInbox::LeiStore->new($dir, { creat => $creat });
728         };
729 }
730
731 sub _config {
732         my ($self, @argv) = @_;
733         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
734         my $cfg = _lei_cfg($self, 1);
735         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
736         my %rdr = map { $_ => $self->{$_} } (0..2);
737         waitpid(spawn($cmd, \%env, \%rdr), 0);
738 }
739
740 sub lei_config {
741         my ($self, @argv) = @_;
742         $self->{opt}->{'config-file'} and return fail $self,
743                 "config file switches not supported by `lei config'";
744         _config(@_);
745         x_it($self, $?) if $?;
746 }
747
748 sub lei_init {
749         my ($self, $dir) = @_;
750         my $cfg = _lei_cfg($self, 1);
751         my $cur = $cfg->{'leistore.dir'};
752         $dir //= store_path($self);
753         $dir = rel2abs($self, $dir);
754         my @cur = stat($cur) if defined($cur);
755         $cur = File::Spec->canonpath($cur // $dir);
756         my @dir = stat($dir);
757         my $exists = "# leistore.dir=$cur already initialized" if @dir;
758         if (@cur) {
759                 if ($cur eq $dir) {
760                         _lei_store($self, 1)->done;
761                         return qerr($self, $exists);
762                 }
763
764                 # some folks like symlinks and bind mounts :P
765                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
766                         lei_config($self, 'leistore.dir', $dir);
767                         _lei_store($self, 1)->done;
768                         return qerr($self, "$exists (as $cur)");
769                 }
770                 return fail($self, <<"");
771 E: leistore.dir=$cur already initialized and it is not $dir
772
773         }
774         lei_config($self, 'leistore.dir', $dir);
775         _lei_store($self, 1)->done;
776         $exists //= "# leistore.dir=$dir newly initialized";
777         return qerr($self, $exists);
778 }
779
780 sub lei_daemon_pid { puts shift, $$ }
781
782 sub lei_daemon_kill {
783         my ($self) = @_;
784         my $sig = $self->{opt}->{signal} // 'TERM';
785         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
786 }
787
788 # Shell completion helper.  Used by lei-completion.bash and hopefully
789 # other shells.  Try to do as much here as possible to avoid redundancy
790 # and improve maintainability.
791 sub lei__complete {
792         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
793         shift @argv; # ignore "lei", the entire command is sent
794         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
795         my $cmd = shift @argv;
796         my $info = $CMD{$cmd} // do { # filter matching commands
797                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
798                 return;
799         };
800         my ($proto, undef, @spec) = @$info;
801         my $cur = pop @argv;
802         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
803         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
804                 # gross special case since the only git-config options
805                 # Consider moving to a table if we need more special cases
806                 # we use Getopt::Long for are the ones we reject, so these
807                 # are the ones we don't reject:
808                 if ($cmd eq 'config') {
809                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
810                         @spec = qw(add z|null get get-all unset unset-all
811                                 replace-all get-urlmatch
812                                 remove-section rename-section
813                                 name-only list|l edit|e
814                                 get-color-name get-colorbool);
815                         # fall-through
816                 }
817                 # generate short/long names from Getopt::Long specs
818                 puts $self, grep(/$re/, qw(--help -h -C), map {
819                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
820                         } elsif (s/\+\z//) { # verbose|v+
821                         } elsif (s/!\z//) {
822                                 # negation: solve! => no-solve|solve
823                                 s/([\w\-]+)/$1|no-$1/g
824                         }
825                         map {
826                                 my $x = length > 1 ? "--$_" : "-$_";
827                                 $x eq $_cur ? () : $x;
828                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
829                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
830         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
831                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
832         }
833
834         # switch args (e.g. lei q -f mbox<TAB>)
835         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
836                 my $opt = quotemeta $1;
837                 puts $self, map {
838                         my $v = $OPTDESC{$_};
839                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
840                         # get rid of ALL CAPS placeholder (e.g "OUT")
841                         # (TODO: completion for external paths)
842                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
843                         @v;
844                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
845         }
846         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
847                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
848         }
849         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
850         # proto parsing.
851 }
852
853 sub exec_buf ($$) {
854         my ($argv, $env) = @_;
855         my $argc = scalar @$argv;
856         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
857         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
858         $buf;
859 }
860
861 sub start_mua {
862         my ($self) = @_;
863         my $mua = $self->{opt}->{mua} // return;
864         my $mfolder = $self->{ovv}->{dst};
865         my (@cmd, $replaced);
866         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
867                 @cmd = ($mua, '-f');
868         # TODO: help wanted: other common FOSS MUAs
869         } else {
870                 require Text::ParseWords;
871                 @cmd = Text::ParseWords::shellwords($mua);
872                 # mutt uses '%f' for open-hook with compressed mbox, we follow
873                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
874         }
875         push @cmd, $mfolder unless defined($replaced);
876         if (my $sock = $self->{sock}) { # lei(1) client process runs it
877                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
878         } elsif ($self->{oneshot}) {
879                 $self->{"pid.$self.$$"}->{spawn(\@cmd)} = \@cmd;
880         }
881         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
882                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
883         }
884         $self->{opt}->{quiet} = 1;
885         delete $self->{-progress};
886         delete $self->{opt}->{verbose};
887 }
888
889 sub send_exec_cmd { # tell script/lei to execute a command
890         my ($self, $io, $cmd, $env) = @_;
891         my $sock = $self->{sock} // die 'lei client gone';
892         my $fds = [ map { fileno($_) } @$io ];
893         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
894 }
895
896 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
897         my ($self) = @_;
898         my $alerts = $self->{opt}->{alert} // return;
899         while (my $op = shift(@$alerts)) {
900                 if ($op eq ':WINCH') {
901                         # hit the process group that started the MUA
902                         if ($self->{sock}) {
903                                 send($self->{sock}, '-WINCH', MSG_EOR);
904                         } elsif ($self->{oneshot}) {
905                                 kill('-WINCH', $$);
906                         }
907                 } elsif ($op eq ':bell') {
908                         out($self, "\a");
909                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
910                         push @$alerts, split(/(?<!\\),/, $op);
911                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
912                         my $cmd = $1; # run an arbitrary command
913                         require Text::ParseWords;
914                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
915                         if (my $s = $self->{sock}) {
916                                 send($s, exec_buf($cmd, {}), MSG_EOR);
917                         } elsif ($self->{oneshot}) {
918                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
919                         }
920                 } else {
921                         err($self, "W: unsupported --alert=$op"); # non-fatal
922                 }
923         }
924 }
925
926 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
927 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
928
929 # this also normalizes the path
930 sub path_to_fd {
931         my ($self, $path) = @_;
932         $path = rel2abs($self, $path);
933         $path =~ tr!/!/!s;
934         $path_to_fd{$path} // (
935                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
936                         fail($self, "cannot open $path from daemon") : -1
937         );
938 }
939
940 # caller needs to "-t $self->{1}" to check if tty
941 sub start_pager {
942         my ($self) = @_;
943         my $fh = popen_rd([qw(git var GIT_PAGER)]);
944         chomp(my $pager = <$fh> // '');
945         close($fh) or warn "`git var PAGER' error: \$?=$?";
946         return if $pager eq 'cat' || $pager eq '';
947         my $new_env = { LESS => 'FRX', LV => '-c' };
948         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
949         pipe(my ($r, $wpager)) or return warn "pipe: $!";
950         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
951         my $pgr = [ undef, @$rdr{1, 2} ];
952         my $env = $self->{env};
953         if ($self->{sock}) { # lei(1) process runs it
954                 delete @$new_env{keys %$env}; # only set iff unset
955                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
956         } elsif ($self->{oneshot}) {
957                 my $cmd = [$pager];
958                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
959         } else {
960                 die 'BUG: start_pager w/o socket';
961         }
962         $self->{1} = $wpager;
963         $self->{2} = $wpager if -t $self->{2};
964         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
965         $self->{pgr} = $pgr;
966 }
967
968 sub stop_pager {
969         my ($self) = @_;
970         my $pgr = delete($self->{pgr}) or return;
971         $self->{2} = $pgr->[2];
972         # do not restore original stdout, just close it so we error out
973         close(delete($self->{1})) if $self->{1};
974 }
975
976 sub accept_dispatch { # Listener {post_accept} callback
977         my ($sock) = @_; # ignore other
978         $sock->autoflush(1);
979         my $self = bless { sock => $sock }, __PACKAGE__;
980         vec(my $rvec = '', fileno($sock), 1) = 1;
981         select($rvec, undef, undef, 60) or
982                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
983         # (4096 * 33) >MAX_ARG_STRLEN
984         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
985         if (!defined($fds[0])) {
986                 warn(my $msg = "recv_cmd failed: $!");
987                 return send($sock, $msg, MSG_EOR);
988         } else {
989                 my $i = 0;
990                 for my $fd (@fds) {
991                         open($self->{$i++}, '+<&=', $fd) and next;
992                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
993                 }
994                 return if scalar(@fds) != 4;
995         }
996         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
997         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
998         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
999         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1000                 return send($sock, 'request command truncated', MSG_EOR);
1001         my ($argc, @argv) = split(/\0/, $buf, -1);
1002         undef $buf;
1003         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1004         if (chdir($self->{3})) {
1005                 local %ENV = %env;
1006                 $self->{env} = \%env;
1007                 eval { dispatch($self, @argv) };
1008                 send($sock, $@, MSG_EOR) if $@;
1009         } else {
1010                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1011         }
1012 }
1013
1014 sub dclose {
1015         my ($self) = @_;
1016         delete $self->{-progress};
1017         for my $f (@WQ_KEYS) {
1018                 my $wq = delete $self->{$f} or next;
1019                 if ($wq->wq_kill) {
1020                         $wq->wq_close(0, undef, $self);
1021                 } elsif ($wq->wq_kill_old) {
1022                         $wq->wq_wait_old(undef, $self);
1023                 }
1024         }
1025         close(delete $self->{1}) if $self->{1}; # may reap_compress
1026         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1027 }
1028
1029 # for long-running results
1030 sub event_step {
1031         my ($self) = @_;
1032         local %ENV = %{$self->{env}};
1033         my $sock = $self->{sock};
1034         local $current_lei = $self;
1035         eval {
1036                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1037                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1038                                 return if $! == EAGAIN;
1039                                 next if $! == EINTR;
1040                                 last if $! == ECONNRESET;
1041                                 die "recvmsg: $!";
1042                         }
1043                         for my $fd (@fds) {
1044                                 open my $rfh, '+<&=', $fd;
1045                         }
1046                         die "unrecognized client signal: $buf";
1047                 }
1048                 dclose($self);
1049         };
1050         if (my $err = $@) {
1051                 eval { $self->fail($err) };
1052                 dclose($self);
1053         }
1054 }
1055
1056 sub event_step_init {
1057         my ($self) = @_;
1058         return if $self->{-event_init_done}++;
1059         if (my $sock = $self->{sock}) { # using DS->EventLoop
1060                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1061         }
1062 }
1063
1064 sub noop {}
1065
1066 sub oldset { $oldset }
1067
1068 sub dump_and_clear_log {
1069         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1070                 my @pfx = @_;
1071                 unshift(@pfx, "$errors_log ") if @pfx;
1072                 warn @pfx, do { local $/; <STDIN> };
1073                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1074         }
1075 }
1076
1077 # lei(1) calls this when it can't connect
1078 sub lazy_start {
1079         my ($path, $errno, $narg) = @_;
1080         local ($errors_log, $listener);
1081         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1082         $errors_log .= 'errors.log';
1083         my $addr = pack_sockaddr_un($path);
1084         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1085         $lk->lock_acquire;
1086         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1087         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1088                 return if connect($listener, $addr); # another process won
1089                 if ($errno == ECONNREFUSED && -S $path) {
1090                         unlink($path) or die "unlink($path): $!";
1091                 }
1092         } else {
1093                 $! = $errno; # allow interpolation to stringify in die
1094                 die "connect($path): $!";
1095         }
1096         umask(077) // die("umask(077): $!");
1097         bind($listener, $addr) or die "bind($path): $!";
1098         listen($listener, 1024) or die "listen: $!";
1099         $lk->lock_release;
1100         undef $lk;
1101         my @st = stat($path) or die "stat($path): $!";
1102         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1103         local $oldset = PublicInbox::DS::block_signals();
1104         if ($narg == 5) {
1105                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1106                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1107                         require PublicInbox::CmdIPC4;
1108                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1109                         PublicInbox::CmdIPC4->can('recv_cmd4');
1110                 };
1111         }
1112         $recv_cmd or die <<"";
1113 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1114
1115         require PublicInbox::Listener;
1116         require PublicInbox::EOFpipe;
1117         (-p STDOUT) or die "E: stdout must be a pipe\n";
1118         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1119         STDIN->autoflush(1);
1120         dump_and_clear_log("from previous daemon process:\n");
1121         POSIX::setsid() > 0 or die "setsid: $!";
1122         my $pid = fork // die "fork: $!";
1123         return if $pid;
1124         $0 = "lei-daemon $path";
1125         local %PATH2CFG;
1126         $listener->blocking(0);
1127         my $exit_code;
1128         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1129         local $quit = do {
1130                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1131                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1132                 sub {
1133                         $exit_code //= shift;
1134                         my $lis = $pil or exit($exit_code);
1135                         # closing eof_w triggers \&noop wakeup
1136                         $listener = $eof_w = $pil = $path = undef;
1137                         $lis->close; # DS::close
1138                         PublicInbox::DS->SetLoopTimeout(1000);
1139                 };
1140         };
1141         my $sig = {
1142                 CHLD => \&PublicInbox::DS::enqueue_reap,
1143                 QUIT => $quit,
1144                 INT => $quit,
1145                 TERM => $quit,
1146                 HUP => \&noop,
1147                 USR1 => \&noop,
1148                 USR2 => \&noop,
1149         };
1150         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1151         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1152         undef $sig;
1153         local $SIG{PIPE} = 'IGNORE';
1154         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1155                 undef $sigfd;
1156                 PublicInbox::DS->SetLoopTimeout(5000);
1157         } else {
1158                 # wake up every second to accept signals if we don't
1159                 # have signalfd or IO::KQueue:
1160                 PublicInbox::DS::sig_setmask($oldset);
1161                 PublicInbox::DS->SetLoopTimeout(1000);
1162         }
1163         PublicInbox::DS->SetPostLoopCallback(sub {
1164                 my ($dmap, undef) = @_;
1165                 if (@st = defined($path) ? stat($path) : ()) {
1166                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1167                                 warn "$path dev/ino changed, quitting\n";
1168                                 $path = undef;
1169                         }
1170                 } elsif (defined($path)) { # ENOENT is common
1171                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1172                         undef $path;
1173                         $quit->();
1174                 }
1175                 return 1 if defined($path);
1176                 my $now = now();
1177                 my $n = 0;
1178                 for my $s (values %$dmap) {
1179                         $s->can('busy') or next;
1180                         if ($s->busy($now)) {
1181                                 ++$n;
1182                         } else {
1183                                 $s->close;
1184                         }
1185                 }
1186                 $n; # true: continue, false: stop
1187         });
1188
1189         # STDIN was redirected to /dev/null above, closing STDERR and
1190         # STDOUT will cause the calling `lei' client process to finish
1191         # reading the <$daemon> pipe.
1192         local $SIG{__WARN__} = sub {
1193                 $current_lei ? err($current_lei, @_) : warn(
1194                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1195         };
1196         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1197         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1198         # $daemon pipe to `lei' closed, main loop begins:
1199         PublicInbox::DS->EventLoop;
1200         exit($exit_code // 0);
1201 }
1202
1203 sub busy { 1 } # prevent daemon-shutdown if client is connected
1204
1205 # for users w/o Socket::Msghdr installed or Inline::C enabled
1206 sub oneshot {
1207         my ($main_pkg) = @_;
1208         my $exit = $main_pkg->can('exit'); # caller may override exit()
1209         local $quit = $exit if $exit;
1210         local %PATH2CFG;
1211         umask(077) // die("umask(077): $!");
1212         my $self = bless {
1213                 oneshot => 1,
1214                 0 => *STDIN{GLOB},
1215                 1 => *STDOUT{GLOB},
1216                 2 => *STDERR{GLOB},
1217                 env => \%ENV
1218         }, __PACKAGE__;
1219         dispatch($self, @ARGV);
1220         x_it($self, $self->{child_error}) if $self->{child_error};
1221 }
1222
1223 # ensures stdout hits the FS before sock disconnects so a client
1224 # can immediately reread it
1225 sub DESTROY {
1226         my ($self) = @_;
1227         $self->{1}->autoflush(1) if $self->{1};
1228         stop_pager($self);
1229         my $err = $?;
1230         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1231         waitpid($_, 0) for keys %$oneshot_pids;
1232         $? = $err if $err; # preserve ->fail or ->x_it code
1233 }
1234
1235 1;