lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal);
  12 use Getopt::Long ();
  13 use Socket qw(AF_UNIX SOCK_STREAM pack_sockaddr_un);
  14 use Errno qw(EAGAIN ECONNREFUSED ENOENT);
  15 use POSIX ();
  16 use IO::Handle ();
  17 use Sys::Syslog qw(syslog openlog);
  18 use PublicInbox::Config;
  19 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLONESHOT);
  20 use PublicInbox::Sigfd;
  21 use PublicInbox::DS qw(now dwaitpid);
  22 use PublicInbox::Spawn qw(spawn run_die);
  23 use PublicInbox::OnDestroy;
  24 use Text::Wrap qw(wrap);
  25 use File::Path qw(mkpath);
  26 use File::Spec;
  27 our $quit = \&CORE::exit;
  28 my $GLP = Getopt::Long::Parser->new;
  29 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  30 my $GLP_PASS = Getopt::Long::Parser->new;
  31 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  32
  33 our %PATH2CFG; # persistent for socket daemon
  34
  35 # TBD: this is a documentation mechanism to show a subcommand
  36 # (may) pass options through to another command:
  37 sub pass_through { $GLP_PASS }
  38
  39 my $OPT;
  40 sub opt_dash {
  41         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  42         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  43         my $cb = sub { # Getopt::Long "<>" catch-all handler
  44                 my ($arg) = @_;
  45                 if ($arg =~ /\A-($re_str)\z/) {
  46                         $OPT->{$key} = $1;
  47                 } else {
  48                         die "bad argument for --$key: $arg\n";
  49                 }
  50         };
  51         ($spec, '<>' => $cb, $GLP_PASS)
  52 }
  53
  54 sub _store_path ($) {
  55         my ($env) = @_;
  56         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  57                 ($env->{HOME} // '/nonexistent').'/.local/share')
  58                 .'/lei/store', $env->{PWD});
  59 }
  60
  61 sub _config_path ($) {
  62         my ($env) = @_;
  63         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  64                 ($env->{HOME} // '/nonexistent').'/.config')
  65                 .'/lei/config', $env->{PWD});
  66 }
  67
  68 # TODO: generate shell completion + help using %CMD and %OPTDESC
  69 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  70 our %CMD = ( # sorted in order of importance/use:
  71 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  72         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  73         sort|s=s@ reverse|r offset=i remote local! external!
  74         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  75
  76 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  77         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  78         pass_through('git show') ],
  79
  80 'add-external' => [ 'URL_OR_PATHNAME',
  81         'add/set priority of a publicinbox|extindex for extra matches',
  82         qw(boost=i quiet|q) ],
  83 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  84         qw(format|f=s z|0 local remote quiet|q) ],
  85 'forget-external' => [ '{URL_OR_PATHNAME|--prune}',
  86         'exclude further results from a publicinbox|extindex',
  87         qw(prune quiet|q) ],
  88
  89 'ls-query' => [ '[FILTER...]', 'list saved search queries',
  90                 qw(name-only format|f=s z) ],
  91 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
  92 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
  93
  94 'plonk' => [ '--thread|--from=IDENT',
  95         'exclude mail matching From: or thread from non-Message-ID searches',
  96         qw(stdin| thread|t from|f=s mid=s oid=s) ],
  97 'mark' => [ 'MESSAGE_FLAGS...',
  98         'set/unset flags on message(s) from stdin',
  99         qw(stdin| oid=s exact by-mid|mid:s) ],
 100 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 101         "exclude message(s) on stdin from `q' search results",
 102         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 103
 104 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 105         'remove imported messages from IMAP, Maildirs, and MH',
 106         qw(exact! all jobs:i indexed) ],
 107
 108 # code repos are used for `show' to solve blobs from patch mails
 109 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 110         qw(boost=i) ],
 111 'ls-coderepo' => [ '[FILTER_TERMS...]',
 112                 'list known code repos', qw(format|f=s z) ],
 113 'forget-coderepo' => [ 'PATHNAME',
 114         'stop using repo to solve blobs from patches',
 115         qw(prune) ],
 116
 117 'add-watch' => [ '[URL_OR_PATHNAME]',
 118                 'watch for new messages and flag changes',
 119         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 120 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 121                 qw(format|f=s z) ],
 122 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 123 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 124 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 125         qw(prune) ],
 126
 127 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 128         'one-shot import/update from URL or filesystem',
 129         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 130         ],
 131
 132 'config' => [ '[...]', sub {
 133                 'git-config(1) wrapper for '._config_path($_[0]);
 134         }, qw(config-file|system|global|file|f=s), # for conflict detection
 135         pass_through('git config') ],
 136 'init' => [ '[PATHNAME]', sub {
 137                 'initialize storage, default: '._store_path($_[0]);
 138         }, qw(quiet|q) ],
 139 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 140         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 141 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 142 'daemon-env' => [ '[NAME=VALUE...]', 'set, unset, or show daemon environment',
 143         qw(clear| unset|u=s@ z|0) ],
 144 'help' => [ '[SUBCOMMAND]', 'show help' ],
 145
 146 # XXX do we need this?
 147 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 148
 149 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 150         'rewrite git history in an attempt to improve compression',
 151         'gc!' ],
 152
 153 # internal commands are prefixed with '_'
 154 '_complete' => [ '[...]', 'internal shell completion helper',
 155                 pass_through('everything') ],
 156 ); # @CMD
 157
 158 # switch descriptions, try to keep consistent across commands
 159 # $spec: Getopt::Long option specification
 160 # $spec => [@ALLOWED_VALUES (default is first), $description],
 161 # $spec => $description
 162 # "$SUB_COMMAND TAB $spec" => as above
 163 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 164                 'specify message input format' ];
 165 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 166
 167 my %OPTDESC = (
 168 'help|h' => 'show this built-in help',
 169 'quiet|q' => 'be quiet',
 170 'solve!' => 'do not attempt to reconstruct blobs from emails',
 171 'save-as=s' => ['NAME', 'save a search terms by given name'],
 172
 173 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 174
 175 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 176                 'deduplication strategy'],
 177 'show   thread|t' => 'display entire thread a message belongs to',
 178 'q      thread|t' =>
 179         'return all messages in the same thread as the actual match(es)',
 180 'augment|a' => 'augment --output destination instead of clobbering',
 181
 182 'output|o=s' => [ 'DEST',
 183         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 184
 185 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 186                         'message/object output format' ],
 187 'mark   format|f=s' => $stdin_formats,
 188 'forget format|f=s' => $stdin_formats,
 189 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 190                 'specify output format, default depends on --output'],
 191 'ls-query       format|f=s' => $ls_format,
 192 'ls-external    format|f=s' => $ls_format,
 193
 194 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 195 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 196
 197 'sort|s=s@' => [ 'VAL|internaldate,date,relevance,docid',
 198                 "order of results `--output'-dependent"],
 199
 200 'boost=i' => 'increase/decrease priority of results (default: 0)',
 201
 202 'local' => 'limit operations to the local filesystem',
 203 'local!' => 'exclude results from the local filesystem',
 204 'remote' => 'limit operations to those requiring network access',
 205 'remote!' => 'prevent operations requiring network access',
 206
 207 'mid=s' => 'specify the Message-ID of a message',
 208 'oid=s' => 'specify the git object ID of a message',
 209
 210 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 211 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 212 'include=s' => 'include mailboxes/newsgroups based on pattern',
 213
 214 'exact' => 'operate on exact header matches only',
 215 'exact!' => 'rely on content match instead of exact header matches',
 216
 217 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 218 'jobs:i' => 'set parallelism level',
 219
 220 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 221 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 222
 223 # note: no "--ignore-environment" / "-i" support like env(1) since that
 224 # is one-shot and this is for a persistent daemon:
 225 'clear|' => 'clear the daemon environment',
 226 'unset|u=s@' => ['NAME',
 227         'unset matching NAME, may be specified multiple times'],
 228
 229 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 230 ); # %OPTDESC
 231
 232 my %CONFIG_KEYS = (
 233         'leistore.dir' => 'top-level storage location',
 234 );
 235
 236 sub x_it ($$) { # pronounced "exit"
 237         my ($self, $code) = @_;
 238         if (my $sig = ($code & 127)) {
 239                 kill($sig, $self->{pid} // $$);
 240         } else {
 241                 $code >>= 8;
 242                 if (my $sock = $self->{sock}) {
 243                         say $sock "exit=$code";
 244                 } else { # for oneshot
 245                         $quit->($code);
 246                 }
 247         }
 248 }
 249
 250 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 251
 252 sub out ($;@) { print { shift->{1} } @_ }
 253
 254 sub err ($;@) {
 255         print { shift->{2} } @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 256 }
 257
 258 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 259
 260 sub fail ($$;$) {
 261         my ($self, $buf, $exit_code) = @_;
 262         err($self, $buf);
 263         x_it($self, ($exit_code // 1) << 8);
 264         undef;
 265 }
 266
 267 sub _help ($;$) {
 268         my ($self, $errmsg) = @_;
 269         my $cmd = $self->{cmd} // 'COMMAND';
 270         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 271         my @top = ($cmd, shift(@info) // ());
 272         my $cmd_desc = shift(@info);
 273         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 274         my @opt_desc;
 275         my $lpad = 2;
 276         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 277                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 278                 my $arg_vals = '';
 279                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 280
 281                 # lower-case is a keyword (e.g. `content', `oid'),
 282                 # ALL_CAPS is a string description (e.g. `PATH')
 283                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 284                         $desc .= "\ndefault: `$1'";
 285                 }
 286                 my (@vals, @s, @l);
 287                 my $x = $sw;
 288                 if ($x =~ s/!\z//) { # solve! => --no-solve
 289                         $x = "no-$x";
 290                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 291                         @vals = (' [', undef, ']');
 292                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 293                         @vals = (' ', undef);
 294                 } # else: no args $x = 'thread|t'
 295                 for (split(/\|/, $x)) { # help|h
 296                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 297                 }
 298                 if (!scalar(@vals)) { # no args 'thread|t'
 299                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 300                         $vals[1] = $1;
 301                 } else {
 302                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 303                 }
 304                 if ($arg_vals =~ /([,\|])/) {
 305                         my $sep = $1;
 306                         my @allow = split(/\Q$sep\E/, $arg_vals);
 307                         my $must = $sep eq '|' ? 'Must' : 'Can';
 308                         @allow = map { "`$_'" } @allow;
 309                         my $last = pop @allow;
 310                         $desc .= "\n$must be one of: " .
 311                                 join(', ', @allow) . " or $last";
 312                 }
 313                 my $lhs = join(', ', @s, @l) . join('', @vals);
 314                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 315                         $lhs =~ s/\A--/- , --/;
 316                 } else {
 317                         $lhs =~ s/\A--/    --/; # pad if no short options
 318                 }
 319                 $lpad = length($lhs) if length($lhs) > $lpad;
 320                 push @opt_desc, $lhs, $desc;
 321         }
 322         my $msg = $errmsg ? "E: $errmsg\n" : '';
 323         $msg .= <<EOF;
 324 usage: lei @top
 325   $cmd_desc
 326
 327 EOF
 328         $lpad += 2;
 329         local $Text::Wrap::columns = 78 - $lpad;
 330         my $padding = ' ' x ($lpad + 2);
 331         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 332                 $msg .= '  '.pack("A$lpad", $lhs);
 333                 $rhs = wrap('', '', $rhs);
 334                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 335                 $msg .= $rhs;
 336                 $msg .= "\n";
 337         }
 338         print { $self->{$errmsg ? 2 : 1} } $msg;
 339         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 340         undef;
 341 }
 342
 343 sub optparse ($$$) {
 344         my ($self, $cmd, $argv) = @_;
 345         $self->{cmd} = $cmd;
 346         $OPT = $self->{opt} = {};
 347         my $info = $CMD{$cmd} // [ '[...]' ];
 348         my ($proto, undef, @spec) = @$info;
 349         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 350         push @spec, qw(help|h);
 351         my $lone_dash;
 352         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 353                 $lone_dash = $spec[0];
 354                 $OPT->{$spec[0]} = \(my $var);
 355                 push @spec, '' => \$var;
 356         }
 357         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 358                 return _help($self, "bad arguments or options for $cmd");
 359         return _help($self) if $OPT->{help};
 360
 361         # "-" aliases "stdin" or "clear"
 362         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 363
 364         my $i = 0;
 365         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 366         my ($err, $inf);
 367         my @args = split(/ /, $proto);
 368         for my $var (@args) {
 369                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 370                         $inf = defined($argv->[$i]) and last;
 371                         $var =~ s/\.\.\.\z//;
 372                         $err = "$var not supplied";
 373                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 374                         $argv->[$i++] // ($err = "$var not supplied");
 375                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 376                         $inf = 1;
 377                         last;
 378                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 379                         $i++;
 380                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 381                         my @or = split(/\|/, $var);
 382                         my $ok;
 383                         for my $o (@or) {
 384                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 385                                         $ok = defined($OPT->{$1});
 386                                         last;
 387                                 } elsif (defined($argv->[$i])) {
 388                                         $ok = 1;
 389                                         $i++;
 390                                         last;
 391                                 } # else continue looping
 392                         }
 393                         my $last = pop @or;
 394                         $err = join(', ', @or) . " or $last must be set";
 395                 } else {
 396                         warn "BUG: can't parse `$var' in $proto";
 397                 }
 398                 last if $err;
 399         }
 400         if (!$inf && scalar(@$argv) > scalar(@args)) {
 401                 $err //= 'too many arguments';
 402         }
 403         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 404 }
 405
 406 sub dispatch {
 407         my ($self, $cmd, @argv) = @_;
 408         local $SIG{__WARN__} = sub { err($self, @_) };
 409         return _help($self, 'no command given') unless defined($cmd);
 410         my $func = "lei_$cmd";
 411         $func =~ tr/-/_/;
 412         if (my $cb = __PACKAGE__->can($func)) {
 413                 optparse($self, $cmd, \@argv) or return;
 414                 $cb->($self, @argv);
 415         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 416                 my $opt = {};
 417                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 418                         return _help($self, 'bad arguments or options');
 419                 _help($self);
 420         } else {
 421                 fail($self, "`$cmd' is not an lei command");
 422         }
 423 }
 424
 425 sub _lei_cfg ($;$) {
 426         my ($self, $creat) = @_;
 427         my $f = _config_path($self->{env});
 428         my @st = stat($f);
 429         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 430         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 431                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 432         }
 433         if (!@st) {
 434                 unless ($creat) {
 435                         delete $self->{cfg};
 436                         return;
 437                 }
 438                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 439                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 440                 open my $fh, '>>', $f or die "open($f): $!\n";
 441                 @st = stat($fh) or die "fstat($f): $!\n";
 442                 $cur_st = pack('dd', $st[10], $st[7]);
 443                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 444         }
 445         my $cfg = PublicInbox::Config::git_config_dump($f);
 446         $cfg->{-st} = $cur_st;
 447         $cfg->{'-f'} = $f;
 448         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 449 }
 450
 451 sub _lei_store ($;$) {
 452         my ($self, $creat) = @_;
 453         my $cfg = _lei_cfg($self, $creat);
 454         $cfg->{-lei_store} //= do {
 455                 require PublicInbox::LeiStore;
 456                 PublicInbox::SearchIdx::load_xapian_writable();
 457                 my $dir = $cfg->{'leistore.dir'};
 458                 $dir //= _store_path($self->{env}) if $creat;
 459                 return unless $dir;
 460                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 461         };
 462 }
 463
 464 sub lei_show {
 465         my ($self, @argv) = @_;
 466 }
 467
 468 sub lei_query {
 469         my ($self, @argv) = @_;
 470 }
 471
 472 sub lei_mark {
 473         my ($self, @argv) = @_;
 474 }
 475
 476 sub lei_config {
 477         my ($self, @argv) = @_;
 478         $self->{opt}->{'config-file'} and return fail $self,
 479                 "config file switches not supported by `lei config'";
 480         my $env = $self->{env};
 481         delete local $env->{GIT_CONFIG};
 482         my $cfg = _lei_cfg($self, 1);
 483         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 484         my %rdr = map { $_ => $self->{$_} } (0..2);
 485         run_die($cmd, $env, \%rdr);
 486 }
 487
 488 sub lei_init {
 489         my ($self, $dir) = @_;
 490         my $cfg = _lei_cfg($self, 1);
 491         my $cur = $cfg->{'leistore.dir'};
 492         my $env = $self->{env};
 493         $dir //= _store_path($env);
 494         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 495         my @cur = stat($cur) if defined($cur);
 496         $cur = File::Spec->canonpath($cur) if $cur;
 497         my @dir = stat($dir);
 498         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 499         if (@cur) {
 500                 if ($cur eq $dir) {
 501                         _lei_store($self, 1)->done;
 502                         return qerr($self, $exists);
 503                 }
 504
 505                 # some folks like symlinks and bind mounts :P
 506                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 507                         lei_config($self, 'leistore.dir', $dir);
 508                         _lei_store($self, 1)->done;
 509                         return qerr($self, "$exists (as $cur)");
 510                 }
 511                 return fail($self, <<"");
 512 E: leistore.dir=$cur already initialized and it is not $dir
 513
 514         }
 515         lei_config($self, 'leistore.dir', $dir);
 516         _lei_store($self, 1)->done;
 517         $exists //= "I: leistore.dir=$dir newly initialized";
 518         return qerr($self, $exists);
 519 }
 520
 521 sub lei_daemon_pid { puts shift, $$ }
 522
 523 sub lei_daemon_kill {
 524         my ($self) = @_;
 525         my $sig = $self->{opt}->{signal} // 'TERM';
 526         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 527 }
 528
 529 sub lei_daemon_env {
 530         my ($self, @argv) = @_;
 531         my $opt = $self->{opt};
 532         if (defined $opt->{clear}) {
 533                 %ENV = ();
 534         } elsif (my $u = $opt->{unset}) {
 535                 delete @ENV{@$u};
 536         }
 537         if (@argv) {
 538                 %ENV = (%ENV, map { split(/=/, $_, 2) } @argv);
 539         } elsif (!defined($opt->{clear}) && !$opt->{unset}) {
 540                 my $eor = $opt->{z} ? "\0" : "\n";
 541                 my $buf = '';
 542                 while (my ($k, $v) = each %ENV) { $buf .= "$k=$v$eor" }
 543                 out $self, $buf;
 544         }
 545 }
 546
 547 sub lei_help { _help($_[0]) }
 548
 549 # Shell completion helper.  Used by lei-completion.bash and hopefully
 550 # other shells.  Try to do as much here as possible to avoid redundancy
 551 # and improve maintainability.
 552 sub lei__complete {
 553         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 554         shift @argv; # ignore "lei", the entire command is sent
 555         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 556         my $cmd = shift @argv;
 557         my $info = $CMD{$cmd} // do { # filter matching commands
 558                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 559                 return;
 560         };
 561         my ($proto, undef, @spec) = @$info;
 562         my $cur = pop @argv;
 563         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 564         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 565                 # gross special case since the only git-config options
 566                 # Consider moving to a table if we need more special cases
 567                 # we use Getopt::Long for are the ones we reject, so these
 568                 # are the ones we don't reject:
 569                 if ($cmd eq 'config') {
 570                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 571                         @spec = qw(add z|null get get-all unset unset-all
 572                                 replace-all get-urlmatch
 573                                 remove-section rename-section
 574                                 name-only list|l edit|e
 575                                 get-color-name get-colorbool);
 576                         # fall-through
 577                 }
 578                 # TODO: arg support
 579                 puts $self, grep(/$re/, map { # generate short/long names
 580                         my $eq = '';
 581                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 582                                 $eq = '=';
 583                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 584                         } else { # negation: solve! => no-solve|solve
 585                                 s/\A(.+)!\z/no-$1|$1/;
 586                         }
 587                         map {
 588                                 length > 1 ? "--$_$eq" : "-$_"
 589                         } split(/\|/, $_, -1) # help|h
 590                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 591         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 592                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 593         }
 594         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 595         # proto parsing.
 596 }
 597
 598 sub reap_exec { # dwaitpid callback
 599         my ($self, $pid) = @_;
 600         x_it($self, $?);
 601 }
 602
 603 sub lei_git { # support passing through random git commands
 604         my ($self, @argv) = @_;
 605         my %rdr = map { $_ => $self->{$_} } (0..2);
 606         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 607         dwaitpid($pid, \&reap_exec, $self);
 608 }
 609
 610 sub accept_dispatch { # Listener {post_accept} callback
 611         my ($sock) = @_; # ignore other
 612         $sock->blocking(1);
 613         $sock->autoflush(1);
 614         my $self = bless { sock => $sock }, __PACKAGE__;
 615         vec(my $rin = '', fileno($sock), 1) = 1;
 616         # `say $sock' triggers "die" in lei(1)
 617         for my $i (0..2) {
 618                 if (select(my $rout = $rin, undef, undef, 1)) {
 619                         my $fd = IO::FDPass::recv(fileno($sock));
 620                         if ($fd >= 0) {
 621                                 my $rdr = ($fd == 0 ? '<&=' : '>&=');
 622                                 if (open(my $fh, $rdr, $fd)) {
 623                                         $self->{$i} = $fh;
 624                                 } else {
 625                                         say $sock "open($rdr$fd) (FD=$i): $!";
 626                                         return;
 627                                 }
 628                         } else {
 629                                 say $sock "recv FD=$i: $!";
 630                                 return;
 631                         }
 632                 } else {
 633                         say $sock "timed out waiting to recv FD=$i";
 634                         return;
 635                 }
 636         }
 637         # $ARGV_STR = join("]\0[", @ARGV);
 638         # $ENV_STR = join('', map { "$_=$ENV{$_}\0" } keys %ENV);
 639         # $line = "$$\0\0>$ARGV_STR\0\0>$ENV_STR\0\0";
 640         my ($client_pid, $argv, $env) = do {
 641                 local $/ = "\0\0\0"; # yes, 3 NULs at EOL, not 2
 642                 chomp(my $line = <$sock>);
 643                 split(/\0\0>/, $line, 3);
 644         };
 645         my %env = map { split(/=/, $_, 2) } split(/\0/, $env);
 646         if (chdir($env{PWD})) {
 647                 $self->{env} = \%env;
 648                 $self->{pid} = $client_pid;
 649                 eval { dispatch($self, split(/\]\0\[/, $argv)) };
 650                 say $sock $@ if $@;
 651         } else {
 652                 say $sock "chdir($env{PWD}): $!"; # implicit close
 653         }
 654 }
 655
 656 sub noop {}
 657
 658 # lei(1) calls this when it can't connect
 659 sub lazy_start {
 660         my ($path, $errno) = @_;
 661         if ($errno == ECONNREFUSED) {
 662                 unlink($path) or die "unlink($path): $!";
 663         } elsif ($errno != ENOENT) {
 664                 $! = $errno; # allow interpolation to stringify in die
 665                 die "connect($path): $!";
 666         }
 667         umask(077) // die("umask(077): $!");
 668         socket(my $l, AF_UNIX, SOCK_STREAM, 0) or die "socket: $!";
 669         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 670         listen($l, 1024) or die "listen: $!";
 671         my @st = stat($path) or die "stat($path): $!";
 672         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 673         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 674         my $oldset = PublicInbox::Sigfd::block_signals();
 675         require IO::FDPass;
 676         require PublicInbox::Listener;
 677         require PublicInbox::EOFpipe;
 678         (-p STDOUT) or die "E: stdout must be a pipe\n";
 679         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 680         POSIX::setsid() > 0 or die "setsid: $!";
 681         my $pid = fork // die "fork: $!";
 682         return if $pid;
 683         $0 = "lei-daemon $path";
 684         local %PATH2CFG;
 685         $_->blocking(0) for ($l, $eof_r, $eof_w);
 686         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 687         my $exit_code;
 688         local $quit = sub {
 689                 $exit_code //= shift;
 690                 my $listener = $l or exit($exit_code);
 691                 unlink($path) if defined($path);
 692                 # closing eof_w triggers \&noop wakeup
 693                 $eof_w = $l = $path = undef;
 694                 $listener->close; # DS::close
 695                 PublicInbox::DS->SetLoopTimeout(1000);
 696         };
 697         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 698         my $sig = {
 699                 CHLD => \&PublicInbox::DS::enqueue_reap,
 700                 QUIT => $quit,
 701                 INT => $quit,
 702                 TERM => $quit,
 703                 HUP => \&noop,
 704                 USR1 => \&noop,
 705                 USR2 => \&noop,
 706         };
 707         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 708         local %SIG = (%SIG, %$sig) if !$sigfd;
 709         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 710                 PublicInbox::DS->SetLoopTimeout(5000);
 711         } else {
 712                 # wake up every second to accept signals if we don't
 713                 # have signalfd or IO::KQueue:
 714                 PublicInbox::Sigfd::sig_setmask($oldset);
 715                 PublicInbox::DS->SetLoopTimeout(1000);
 716         }
 717         PublicInbox::DS->SetPostLoopCallback(sub {
 718                 my ($dmap, undef) = @_;
 719                 if (@st = defined($path) ? stat($path) : ()) {
 720                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 721                                 warn "$path dev/ino changed, quitting\n";
 722                                 $path = undef;
 723                         }
 724                 } elsif (defined($path)) {
 725                         warn "stat($path): $!, quitting ...\n";
 726                         undef $path; # don't unlink
 727                         $quit->();
 728                 }
 729                 return 1 if defined($path);
 730                 my $now = now();
 731                 my $n = 0;
 732                 for my $s (values %$dmap) {
 733                         $s->can('busy') or next;
 734                         if ($s->busy($now)) {
 735                                 ++$n;
 736                         } else {
 737                                 $s->close;
 738                         }
 739                 }
 740                 $n; # true: continue, false: stop
 741         });
 742
 743         # STDIN was redirected to /dev/null above, closing STDERR and
 744         # STDOUT will cause the calling `lei' client process to finish
 745         # reading the <$daemon> pipe.
 746         openlog($path, 'pid', 'user');
 747         local $SIG{__WARN__} = sub { syslog('warning', "@_") };
 748         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 749                 syslog('crit', "$@") if $@;
 750         });
 751         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 752         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 753         # $daemon pipe to `lei' closed, main loop begins:
 754         PublicInbox::DS->EventLoop;
 755         @$on_destroy = (); # cancel on_destroy if we get here
 756         exit($exit_code // 0);
 757 }
 758
 759 # for users w/o IO::FDPass
 760 sub oneshot {
 761         my ($main_pkg) = @_;
 762         my $exit = $main_pkg->can('exit'); # caller may override exit()
 763         local $quit = $exit if $exit;
 764         local %PATH2CFG;
 765         umask(077) // die("umask(077): $!");
 766         dispatch((bless {
 767                 0 => *STDIN{IO},
 768                 1 => *STDOUT{IO},
 769                 2 => *STDERR{IO},
 770                 env => \%ENV
 771         }, __PACKAGE__), @ARGV);
 772 }
 773
 774 1;