lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use POSIX ();
  17 use IO::Handle ();
  18 use Sys::Syslog qw(syslog openlog);
  19 use PublicInbox::Config;
  20 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::DS qw(now dwaitpid);
  23 use PublicInbox::Spawn qw(spawn run_die popen_rd);
  24 use PublicInbox::OnDestroy;
  25 use Text::Wrap qw(wrap);
  26 use File::Path qw(mkpath);
  27 use File::Spec;
  28 our $quit = \&CORE::exit;
  29 our $current_lei;
  30 my ($recv_cmd, $send_cmd);
  31 my $GLP = Getopt::Long::Parser->new;
  32 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  33 my $GLP_PASS = Getopt::Long::Parser->new;
  34 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  35
  36 our %PATH2CFG; # persistent for socket daemon
  37 our @TO_CLOSE_ATFORK_CHILD;
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub _store_path ($) {
  68         my ($env) = @_;
  69         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  70                 ($env->{HOME} // '/nonexistent').'/.local/share')
  71                 .'/lei/store', $env->{PWD});
  72 }
  73
  74 sub _config_path ($) {
  75         my ($env) = @_;
  76         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  77                 ($env->{HOME} // '/nonexistent').'/.config')
  78                 .'/lei/config', $env->{PWD});
  79 }
  80
  81 # TODO: generate shell completion + help using %CMD and %OPTDESC
  82 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  83 our %CMD = ( # sorted in order of importance/use:
  84 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  85         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  86         sort|s=s reverse|r offset=i remote local! external! pretty mua-cmd=s
  87         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  88
  89 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  90         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  91         pass_through('git show') ],
  92
  93 'add-external' => [ 'URL_OR_PATHNAME',
  94         'add/set priority of a publicinbox|extindex for extra matches',
  95         qw(boost=i quiet|q) ],
  96 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  97         qw(format|f=s z|0 local remote quiet|q) ],
  98 'forget-external' => [ '{URL_OR_PATHNAME|--prune}',
  99         'exclude further results from a publicinbox|extindex',
 100         qw(prune quiet|q) ],
 101
 102 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 103                 qw(name-only format|f=s z) ],
 104 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 105 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 106
 107 'plonk' => [ '--thread|--from=IDENT',
 108         'exclude mail matching From: or thread from non-Message-ID searches',
 109         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 110 'mark' => [ 'MESSAGE_FLAGS...',
 111         'set/unset flags on message(s) from stdin',
 112         qw(stdin| oid=s exact by-mid|mid:s) ],
 113 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 114         "exclude message(s) on stdin from `q' search results",
 115         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 116
 117 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 118         'remove imported messages from IMAP, Maildirs, and MH',
 119         qw(exact! all jobs:i indexed) ],
 120
 121 # code repos are used for `show' to solve blobs from patch mails
 122 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 123         qw(boost=i) ],
 124 'ls-coderepo' => [ '[FILTER_TERMS...]',
 125                 'list known code repos', qw(format|f=s z) ],
 126 'forget-coderepo' => [ 'PATHNAME',
 127         'stop using repo to solve blobs from patches',
 128         qw(prune) ],
 129
 130 'add-watch' => [ '[URL_OR_PATHNAME]',
 131                 'watch for new messages and flag changes',
 132         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 133 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 134                 qw(format|f=s z) ],
 135 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 136 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 137 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 138         qw(prune) ],
 139
 140 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 141         'one-shot import/update from URL or filesystem',
 142         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 143         ],
 144
 145 'config' => [ '[...]', sub {
 146                 'git-config(1) wrapper for '._config_path($_[0]);
 147         }, qw(config-file|system|global|file|f=s), # for conflict detection
 148         pass_through('git config') ],
 149 'init' => [ '[PATHNAME]', sub {
 150                 'initialize storage, default: '._store_path($_[0]);
 151         }, qw(quiet|q) ],
 152 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 153         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 154 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 155 'help' => [ '[SUBCOMMAND]', 'show help' ],
 156
 157 # XXX do we need this?
 158 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 159
 160 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 161         'rewrite git history in an attempt to improve compression',
 162         'gc!' ],
 163
 164 # internal commands are prefixed with '_'
 165 '_complete' => [ '[...]', 'internal shell completion helper',
 166                 pass_through('everything') ],
 167 ); # @CMD
 168
 169 # switch descriptions, try to keep consistent across commands
 170 # $spec: Getopt::Long option specification
 171 # $spec => [@ALLOWED_VALUES (default is first), $description],
 172 # $spec => $description
 173 # "$SUB_COMMAND TAB $spec" => as above
 174 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 175                 'specify message input format' ];
 176 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 177
 178 my %OPTDESC = (
 179 'help|h' => 'show this built-in help',
 180 'quiet|q' => 'be quiet',
 181 'solve!' => 'do not attempt to reconstruct blobs from emails',
 182 'save-as=s' => ['NAME', 'save a search terms by given name'],
 183
 184 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 185
 186 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 187                 'deduplication strategy'],
 188 'show   thread|t' => 'display entire thread a message belongs to',
 189 'q      thread|t' =>
 190         'return all messages in the same thread as the actual match(es)',
 191 'augment|a' => 'augment --output destination instead of clobbering',
 192
 193 'output|o=s' => [ 'DEST',
 194         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 195 'mua-cmd|mua=s' => [ 'COMMAND',
 196         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 197
 198 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 199                         'message/object output format' ],
 200 'mark   format|f=s' => $stdin_formats,
 201 'forget format|f=s' => $stdin_formats,
 202 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 203                 'specify output format, default depends on --output'],
 204 'ls-query       format|f=s' => $ls_format,
 205 'ls-external    format|f=s' => $ls_format,
 206
 207 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 208 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 209
 210 'sort|s=s' => [ 'VAL|received,relevance,docid',
 211                 "order of results `--output'-dependent"],
 212 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 213
 214 'boost=i' => 'increase/decrease priority of results (default: 0)',
 215
 216 'local' => 'limit operations to the local filesystem',
 217 'local!' => 'exclude results from the local filesystem',
 218 'remote' => 'limit operations to those requiring network access',
 219 'remote!' => 'prevent operations requiring network access',
 220
 221 'mid=s' => 'specify the Message-ID of a message',
 222 'oid=s' => 'specify the git object ID of a message',
 223
 224 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 225 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 226 'include=s' => 'include mailboxes/newsgroups based on pattern',
 227
 228 'exact' => 'operate on exact header matches only',
 229 'exact!' => 'rely on content match instead of exact header matches',
 230
 231 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 232 'jobs:i' => 'set parallelism level',
 233
 234 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 235 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 236
 237 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 238 ); # %OPTDESC
 239
 240 my %CONFIG_KEYS = (
 241         'leistore.dir' => 'top-level storage location',
 242 );
 243
 244 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 245 sub x_it ($$) {
 246         my ($self, $code) = @_;
 247         # make sure client sees stdout before exit
 248         $self->{1}->autoflush(1) if $self->{1};
 249         if (my $sock = $self->{sock}) {
 250                 send($sock, "x_it $code", MSG_EOR);
 251         } elsif (!($code & 127)) { # oneshot, ignore signals
 252                 $quit->($code >> 8);
 253         }
 254 }
 255
 256 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 257
 258 sub out ($;@) { print { shift->{1} } @_ }
 259
 260 sub err ($;@) {
 261         my $self = shift;
 262         my $err = $self->{2} // *STDERR{IO};
 263         print $err @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 264 }
 265
 266 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 267
 268 sub fail ($$;$) {
 269         my ($self, $buf, $exit_code) = @_;
 270         err($self, $buf);
 271         x_it($self, ($exit_code // 1) << 8);
 272         undef;
 273 }
 274
 275 sub atfork_prepare_wq {
 276         my ($self, $wq) = @_;
 277         my $tcafc = $wq->{-ipc_atfork_child_close};
 278         push @$tcafc, @TO_CLOSE_ATFORK_CHILD;
 279         if (my $sock = $self->{sock}) {
 280                 push @$tcafc, @$self{qw(0 1 2)}, $sock;
 281         }
 282         for my $f (qw(lxs l2m)) {
 283                 my $ipc = $self->{$f} or next;
 284                 push @$tcafc, grep { defined }
 285                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 286         }
 287 }
 288
 289 # usage: my %sig = $lei->atfork_child_wq($wq);
 290 #        local @SIG{keys %sig} = values %sig;
 291 sub atfork_child_wq {
 292         my ($self, $wq) = @_;
 293         my ($sock, $l2m_wq_s1);
 294         (@$self{qw(0 1 2)}, $sock, $l2m_wq_s1) = delete(@$wq{0..4});
 295         $self->{sock} = $sock if -S $sock;
 296         $self->{l2m}->{-wq_s1} = $l2m_wq_s1 if $l2m_wq_s1 && -S $l2m_wq_s1;
 297         %PATH2CFG = ();
 298         $quit = \&CORE::exit;
 299         @TO_CLOSE_ATFORK_CHILD = ();
 300         (__WARN__ => sub { err($self, @_) },
 301         PIPE => sub {
 302                 $self->x_it(13); # SIGPIPE = 13
 303                 # we need to close explicitly to avoid Perl warning on SIGPIPE
 304                 close(delete $self->{1});
 305                 # regular files and /dev/null (-c) won't trigger SIGPIPE
 306                 close(delete $self->{2}) unless (-f $self->{2} || -c _);
 307                 syswrite($self->{0}, '!') unless $self->{sock}; # for eof_wait
 308                 die bless(\"$_[0]", 'PublicInbox::SIGPIPE'),
 309         });
 310 }
 311
 312 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 313 sub atfork_parent_wq {
 314         my ($self, $wq) = @_;
 315         my $env = delete $self->{env}; # env is inherited at fork
 316         my $ret = bless { %$self }, ref($self);
 317         if (my $dedupe = delete $ret->{dedupe}) {
 318                 $ret->{dedupe} = $wq->deep_clone($dedupe);
 319         }
 320         $self->{env} = $env;
 321         delete @$ret{qw(-lei_store cfg pgr lxs)}; # keep l2m
 322         my @io = delete @$ret{0..2};
 323         $io[3] = delete($ret->{sock}) // *STDERR{GLOB};
 324         my $l2m = $ret->{l2m};
 325         if ($l2m && $l2m != $wq) {
 326                 $io[4] = $l2m->{-wq_s1} if $l2m->{-wq_s1};
 327                 if (my @pids = $l2m->wq_close) {
 328                         $wq->{l2m_pids} = \@pids;
 329                 }
 330         }
 331         ($ret, @io);
 332 }
 333
 334 sub _help ($;$) {
 335         my ($self, $errmsg) = @_;
 336         my $cmd = $self->{cmd} // 'COMMAND';
 337         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 338         my @top = ($cmd, shift(@info) // ());
 339         my $cmd_desc = shift(@info);
 340         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 341         my @opt_desc;
 342         my $lpad = 2;
 343         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 344                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 345                 my $arg_vals = '';
 346                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 347
 348                 # lower-case is a keyword (e.g. `content', `oid'),
 349                 # ALL_CAPS is a string description (e.g. `PATH')
 350                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 351                         $desc .= "\ndefault: `$1'";
 352                 }
 353                 my (@vals, @s, @l);
 354                 my $x = $sw;
 355                 if ($x =~ s/!\z//) { # solve! => --no-solve
 356                         $x = "no-$x";
 357                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 358                         @vals = (' [', undef, ']');
 359                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 360                         @vals = (' ', undef);
 361                 } # else: no args $x = 'thread|t'
 362                 for (split(/\|/, $x)) { # help|h
 363                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 364                 }
 365                 if (!scalar(@vals)) { # no args 'thread|t'
 366                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 367                         $vals[1] = $1;
 368                 } else {
 369                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 370                 }
 371                 if ($arg_vals =~ /([,\|])/) {
 372                         my $sep = $1;
 373                         my @allow = split(/\Q$sep\E/, $arg_vals);
 374                         my $must = $sep eq '|' ? 'Must' : 'Can';
 375                         @allow = map { "`$_'" } @allow;
 376                         my $last = pop @allow;
 377                         $desc .= "\n$must be one of: " .
 378                                 join(', ', @allow) . " or $last";
 379                 }
 380                 my $lhs = join(', ', @s, @l) . join('', @vals);
 381                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 382                         $lhs =~ s/\A--/- , --/;
 383                 } else {
 384                         $lhs =~ s/\A--/    --/; # pad if no short options
 385                 }
 386                 $lpad = length($lhs) if length($lhs) > $lpad;
 387                 push @opt_desc, $lhs, $desc;
 388         }
 389         my $msg = $errmsg ? "E: $errmsg\n" : '';
 390         $msg .= <<EOF;
 391 usage: lei @top
 392   $cmd_desc
 393
 394 EOF
 395         $lpad += 2;
 396         local $Text::Wrap::columns = 78 - $lpad;
 397         my $padding = ' ' x ($lpad + 2);
 398         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 399                 $msg .= '  '.pack("A$lpad", $lhs);
 400                 $rhs = wrap('', '', $rhs);
 401                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 402                 $msg .= $rhs;
 403                 $msg .= "\n";
 404         }
 405         print { $self->{$errmsg ? 2 : 1} } $msg;
 406         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 407         undef;
 408 }
 409
 410 sub optparse ($$$) {
 411         my ($self, $cmd, $argv) = @_;
 412         $self->{cmd} = $cmd;
 413         $OPT = $self->{opt} = {};
 414         my $info = $CMD{$cmd} // [ '[...]' ];
 415         my ($proto, undef, @spec) = @$info;
 416         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 417         push @spec, qw(help|h);
 418         my $lone_dash;
 419         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 420                 $lone_dash = $spec[0];
 421                 $OPT->{$spec[0]} = \(my $var);
 422                 push @spec, '' => \$var;
 423         }
 424         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 425                 return _help($self, "bad arguments or options for $cmd");
 426         return _help($self) if $OPT->{help};
 427
 428         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 429
 430         # "-" aliases "stdin" or "clear"
 431         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 432
 433         my $i = 0;
 434         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 435         my ($err, $inf);
 436         my @args = split(/ /, $proto);
 437         for my $var (@args) {
 438                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 439                         $inf = defined($argv->[$i]) and last;
 440                         $var =~ s/\.\.\.\z//;
 441                         $err = "$var not supplied";
 442                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 443                         $argv->[$i++] // ($err = "$var not supplied");
 444                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 445                         $inf = 1;
 446                         last;
 447                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 448                         $i++;
 449                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 450                         my @or = split(/\|/, $var);
 451                         my $ok;
 452                         for my $o (@or) {
 453                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 454                                         $ok = defined($OPT->{$1});
 455                                         last;
 456                                 } elsif (defined($argv->[$i])) {
 457                                         $ok = 1;
 458                                         $i++;
 459                                         last;
 460                                 } # else continue looping
 461                         }
 462                         my $last = pop @or;
 463                         $err = join(', ', @or) . " or $last must be set";
 464                 } else {
 465                         warn "BUG: can't parse `$var' in $proto";
 466                 }
 467                 last if $err;
 468         }
 469         if (!$inf && scalar(@$argv) > scalar(@args)) {
 470                 $err //= 'too many arguments';
 471         }
 472         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 473 }
 474
 475 sub dispatch {
 476         my ($self, $cmd, @argv) = @_;
 477         local $current_lei = $self; # for __WARN__
 478         return _help($self, 'no command given') unless defined($cmd);
 479         my $func = "lei_$cmd";
 480         $func =~ tr/-/_/;
 481         if (my $cb = __PACKAGE__->can($func)) {
 482                 optparse($self, $cmd, \@argv) or return;
 483                 $cb->($self, @argv);
 484         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 485                 my $opt = {};
 486                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 487                         return _help($self, 'bad arguments or options');
 488                 _help($self);
 489         } else {
 490                 fail($self, "`$cmd' is not an lei command");
 491         }
 492 }
 493
 494 sub _lei_cfg ($;$) {
 495         my ($self, $creat) = @_;
 496         my $f = _config_path($self->{env});
 497         my @st = stat($f);
 498         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 499         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 500                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 501         }
 502         if (!@st) {
 503                 unless ($creat) {
 504                         delete $self->{cfg};
 505                         return;
 506                 }
 507                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 508                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 509                 open my $fh, '>>', $f or die "open($f): $!\n";
 510                 @st = stat($fh) or die "fstat($f): $!\n";
 511                 $cur_st = pack('dd', $st[10], $st[7]);
 512                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 513         }
 514         my $cfg = PublicInbox::Config::git_config_dump($f);
 515         $cfg->{-st} = $cur_st;
 516         $cfg->{'-f'} = $f;
 517         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 518 }
 519
 520 sub _lei_store ($;$) {
 521         my ($self, $creat) = @_;
 522         my $cfg = _lei_cfg($self, $creat);
 523         $cfg->{-lei_store} //= do {
 524                 require PublicInbox::LeiStore;
 525                 my $dir = $cfg->{'leistore.dir'};
 526                 $dir //= _store_path($self->{env}) if $creat;
 527                 return unless $dir;
 528                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 529         };
 530 }
 531
 532 sub lei_show {
 533         my ($self, @argv) = @_;
 534 }
 535
 536 sub lei_mark {
 537         my ($self, @argv) = @_;
 538 }
 539
 540 sub lei_config {
 541         my ($self, @argv) = @_;
 542         $self->{opt}->{'config-file'} and return fail $self,
 543                 "config file switches not supported by `lei config'";
 544         my $env = $self->{env};
 545         delete local $env->{GIT_CONFIG};
 546         my $cfg = _lei_cfg($self, 1);
 547         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 548         my %rdr = map { $_ => $self->{$_} } (0..2);
 549         run_die($cmd, $env, \%rdr);
 550 }
 551
 552 sub lei_init {
 553         my ($self, $dir) = @_;
 554         my $cfg = _lei_cfg($self, 1);
 555         my $cur = $cfg->{'leistore.dir'};
 556         my $env = $self->{env};
 557         $dir //= _store_path($env);
 558         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 559         my @cur = stat($cur) if defined($cur);
 560         $cur = File::Spec->canonpath($cur // $dir);
 561         my @dir = stat($dir);
 562         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 563         if (@cur) {
 564                 if ($cur eq $dir) {
 565                         _lei_store($self, 1)->done;
 566                         return qerr($self, $exists);
 567                 }
 568
 569                 # some folks like symlinks and bind mounts :P
 570                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 571                         lei_config($self, 'leistore.dir', $dir);
 572                         _lei_store($self, 1)->done;
 573                         return qerr($self, "$exists (as $cur)");
 574                 }
 575                 return fail($self, <<"");
 576 E: leistore.dir=$cur already initialized and it is not $dir
 577
 578         }
 579         lei_config($self, 'leistore.dir', $dir);
 580         _lei_store($self, 1)->done;
 581         $exists //= "I: leistore.dir=$dir newly initialized";
 582         return qerr($self, $exists);
 583 }
 584
 585 sub lei_daemon_pid { puts shift, $$ }
 586
 587 sub lei_daemon_kill {
 588         my ($self) = @_;
 589         my $sig = $self->{opt}->{signal} // 'TERM';
 590         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 591 }
 592
 593 sub lei_help { _help($_[0]) }
 594
 595 # Shell completion helper.  Used by lei-completion.bash and hopefully
 596 # other shells.  Try to do as much here as possible to avoid redundancy
 597 # and improve maintainability.
 598 sub lei__complete {
 599         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 600         shift @argv; # ignore "lei", the entire command is sent
 601         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 602         my $cmd = shift @argv;
 603         my $info = $CMD{$cmd} // do { # filter matching commands
 604                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 605                 return;
 606         };
 607         my ($proto, undef, @spec) = @$info;
 608         my $cur = pop @argv;
 609         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 610         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 611                 # gross special case since the only git-config options
 612                 # Consider moving to a table if we need more special cases
 613                 # we use Getopt::Long for are the ones we reject, so these
 614                 # are the ones we don't reject:
 615                 if ($cmd eq 'config') {
 616                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 617                         @spec = qw(add z|null get get-all unset unset-all
 618                                 replace-all get-urlmatch
 619                                 remove-section rename-section
 620                                 name-only list|l edit|e
 621                                 get-color-name get-colorbool);
 622                         # fall-through
 623                 }
 624                 # TODO: arg support
 625                 puts $self, grep(/$re/, map { # generate short/long names
 626                         my $eq = '';
 627                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 628                                 $eq = '=';
 629                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 630                         } else { # negation: solve! => no-solve|solve
 631                                 s/\A(.+)!\z/no-$1|$1/;
 632                         }
 633                         map {
 634                                 length > 1 ? "--$_$eq" : "-$_"
 635                         } split(/\|/, $_, -1) # help|h
 636                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 637         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 638                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 639         }
 640         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 641         # proto parsing.
 642 }
 643
 644 sub reap_exec { # dwaitpid callback
 645         my ($self, $pid) = @_;
 646         x_it($self, $?);
 647 }
 648
 649 sub lei_git { # support passing through random git commands
 650         my ($self, @argv) = @_;
 651         my %rdr = map { $_ => $self->{$_} } (0..2);
 652         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 653         dwaitpid($pid, \&reap_exec, $self);
 654 }
 655
 656 sub exec_buf ($$) {
 657         my ($argv, $env) = @_;
 658         my $argc = scalar @$argv;
 659         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 660         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 661         $buf;
 662 }
 663
 664 sub start_mua {
 665         my ($self, $sock) = @_;
 666         my $mua = $self->{opt}->{'mua-cmd'} // return;
 667         my $mfolder = $self->{ovv}->{dst};
 668         require Text::ParseWords;
 669         my $replaced;
 670         my @cmd = Text::ParseWords::shellwords($mua);
 671         # mutt uses '%f' for open-hook with compressed folders, so we use %f
 672         @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 673         push @cmd, $mfolder unless defined($replaced);
 674         $sock //= $self->{sock};
 675         if ($PublicInbox::DS::in_loop) { # lei(1) client process runs it
 676                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 677         } else { # oneshot
 678                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 679         }
 680 }
 681
 682 # caller needs to "-t $self->{1}" to check if tty
 683 sub start_pager {
 684         my ($self) = @_;
 685         my $env = $self->{env};
 686         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 687         chomp(my $pager = <$fh> // '');
 688         close($fh) or warn "`git var PAGER' error: \$?=$?";
 689         return if $pager eq 'cat' || $pager eq '';
 690         # TODO TIOCGWINSZ
 691         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 692         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 693         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 694         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 695         my $pgr = [ undef, @$rdr{1, 2}, $$ ];
 696         if (my $sock = $self->{sock}) { # lei(1) process runs it
 697                 delete @$new_env{keys %$env}; # only set iff unset
 698                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 699                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 700         } else {
 701                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 702         }
 703         $self->{1} = $wpager;
 704         $self->{2} = $wpager if -t $self->{2};
 705         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 706         $self->{pgr} = $pgr;
 707 }
 708
 709 sub stop_pager {
 710         my ($self) = @_;
 711         my $pgr = delete($self->{pgr}) or return;
 712         $self->{2} = $pgr->[2];
 713         # do not restore original stdout, just close it so we error out
 714         close(delete($self->{1})) if $self->{1};
 715         my $pid = $pgr->[0];
 716         dwaitpid($pid, undef, $self->{sock}) if $pid && $pgr->[3] == $$;
 717 }
 718
 719 sub accept_dispatch { # Listener {post_accept} callback
 720         my ($sock) = @_; # ignore other
 721         $sock->autoflush(1);
 722         my $self = bless { sock => $sock }, __PACKAGE__;
 723         vec(my $rvec = '', fileno($sock), 1) = 1;
 724         select($rvec, undef, undef, 1) or
 725                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 726         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 727         if (scalar(@fds) == 4) {
 728                 my $i = 0;
 729                 for my $rdr (qw(<&= >&= >&= <&=)) {
 730                         my $fd = shift(@fds);
 731                         open($self->{$i++}, $rdr, $fd) and next;
 732                         send($sock, "open($rdr$fd) (FD=$i): $!", MSG_EOR);
 733                 }
 734         } else {
 735                 return send($sock, "recv_cmd failed: $!", MSG_EOR);
 736         }
 737         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 738         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 739         # $buf = "$$\0$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 740         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 741                 return send($sock, 'request command truncated', MSG_EOR);
 742         my ($argc, @argv) = split(/\0/, $buf, -1);
 743         undef $buf;
 744         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 745         if (chdir(delete($self->{3}))) {
 746                 local %ENV = %env;
 747                 $self->{env} = \%env;
 748                 eval { dispatch($self, @argv) };
 749                 send($sock, $@, MSG_EOR) if $@;
 750         } else {
 751                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 752         }
 753 }
 754
 755 sub dclose {
 756         my ($self) = @_;
 757         delete $self->{lxs}; # stops LeiXSearch queries
 758         $self->close if $self->{sock}; # PublicInbox::DS::close
 759 }
 760
 761 # for long-running results
 762 sub event_step {
 763         my ($self) = @_;
 764         local %ENV = %{$self->{env}};
 765         my $sock = $self->{sock};
 766         eval {
 767                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 768                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 769                                 return if $! == EAGAIN;
 770                                 next if $! == EINTR;
 771                                 last if $! == ECONNRESET;
 772                                 die "recvmsg: $!";
 773                         }
 774                         for my $fd (@fds) {
 775                                 open my $rfh, '+<&=', $fd;
 776                         }
 777                         die "unrecognized client signal: $buf";
 778                 }
 779                 dclose($self);
 780         };
 781         if (my $err = $@) {
 782                 eval { $self->fail($err) };
 783                 dclose($self);
 784         }
 785 }
 786
 787 sub event_step_init {
 788         my ($self) = @_;
 789         if (my $sock = $self->{sock}) { # using DS->EventLoop
 790                 $sock->blocking(0);
 791                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 792         }
 793 }
 794
 795 sub noop {}
 796
 797 our $oldset; sub oldset { $oldset }
 798
 799 # lei(1) calls this when it can't connect
 800 sub lazy_start {
 801         my ($path, $errno, $narg) = @_;
 802         if ($errno == ECONNREFUSED) {
 803                 unlink($path) or die "unlink($path): $!";
 804         } elsif ($errno != ENOENT) {
 805                 $! = $errno; # allow interpolation to stringify in die
 806                 die "connect($path): $!";
 807         }
 808         umask(077) // die("umask(077): $!");
 809         socket(my $l, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 810         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 811         listen($l, 1024) or die "listen: $!";
 812         my @st = stat($path) or die "stat($path): $!";
 813         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 814         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 815         local $oldset = PublicInbox::DS::block_signals();
 816         if ($narg == 5) {
 817                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 818                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 819                         require PublicInbox::CmdIPC4;
 820                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 821                         PublicInbox::CmdIPC4->can('recv_cmd4');
 822                 };
 823         }
 824         $recv_cmd or die <<"";
 825 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 826
 827         require PublicInbox::Listener;
 828         require PublicInbox::EOFpipe;
 829         (-p STDOUT) or die "E: stdout must be a pipe\n";
 830         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 831         POSIX::setsid() > 0 or die "setsid: $!";
 832         my $pid = fork // die "fork: $!";
 833         return if $pid;
 834         $0 = "lei-daemon $path";
 835         local %PATH2CFG;
 836         local @TO_CLOSE_ATFORK_CHILD = ($l, $eof_w);
 837         $l->blocking(0);
 838         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 839         my $exit_code;
 840         local $quit = sub {
 841                 $exit_code //= shift;
 842                 my $listener = $l or exit($exit_code);
 843                 # closing eof_w triggers \&noop wakeup
 844                 $eof_w = $l = $path = undef;
 845                 $listener->close; # DS::close
 846                 PublicInbox::DS->SetLoopTimeout(1000);
 847         };
 848         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 849         undef $eof_r;
 850         my $sig = {
 851                 CHLD => \&PublicInbox::DS::enqueue_reap,
 852                 QUIT => $quit,
 853                 INT => $quit,
 854                 TERM => $quit,
 855                 HUP => \&noop,
 856                 USR1 => \&noop,
 857                 USR2 => \&noop,
 858         };
 859         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 860         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 861         undef $sig;
 862         local $SIG{PIPE} = 'IGNORE';
 863         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 864                 undef $sigfd;
 865                 PublicInbox::DS->SetLoopTimeout(5000);
 866         } else {
 867                 # wake up every second to accept signals if we don't
 868                 # have signalfd or IO::KQueue:
 869                 PublicInbox::DS::sig_setmask($oldset);
 870                 PublicInbox::DS->SetLoopTimeout(1000);
 871         }
 872         PublicInbox::DS->SetPostLoopCallback(sub {
 873                 my ($dmap, undef) = @_;
 874                 if (@st = defined($path) ? stat($path) : ()) {
 875                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 876                                 warn "$path dev/ino changed, quitting\n";
 877                                 $path = undef;
 878                         }
 879                 } elsif (defined($path)) {
 880                         warn "stat($path): $!, quitting ...\n";
 881                         undef $path; # don't unlink
 882                         $quit->();
 883                 }
 884                 return 1 if defined($path);
 885                 my $now = now();
 886                 my $n = 0;
 887                 for my $s (values %$dmap) {
 888                         $s->can('busy') or next;
 889                         if ($s->busy($now)) {
 890                                 ++$n;
 891                         } else {
 892                                 $s->close;
 893                         }
 894                 }
 895                 $n; # true: continue, false: stop
 896         });
 897
 898         # STDIN was redirected to /dev/null above, closing STDERR and
 899         # STDOUT will cause the calling `lei' client process to finish
 900         # reading the <$daemon> pipe.
 901         openlog($path, 'pid', 'user');
 902         local $SIG{__WARN__} = sub {
 903                 $current_lei ? err($current_lei, @_) : syslog('warning', "@_");
 904         };
 905         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 906                 syslog('crit', "$@") if $@;
 907         });
 908         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 909         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 910         # $daemon pipe to `lei' closed, main loop begins:
 911         PublicInbox::DS->EventLoop;
 912         @$on_destroy = (); # cancel on_destroy if we get here
 913         exit($exit_code // 0);
 914 }
 915
 916 # for users w/o Socket::Msghdr
 917 sub oneshot {
 918         my ($main_pkg) = @_;
 919         my $exit = $main_pkg->can('exit'); # caller may override exit()
 920         local $quit = $exit if $exit;
 921         local %PATH2CFG;
 922         umask(077) // die("umask(077): $!");
 923         dispatch((bless {
 924                 0 => *STDIN{GLOB},
 925                 1 => *STDOUT{GLOB},
 926                 2 => *STDERR{GLOB},
 927                 env => \%ENV
 928         }, __PACKAGE__), @ARGV);
 929 }
 930
 931 # ensures stdout hits the FS before sock disconnects so a client
 932 # can immediately reread it
 933 sub DESTROY {
 934         my ($self) = @_;
 935         $self->{1}->autoflush(1) if $self->{1};
 936         stop_pager($self);
 937         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
 938                 waitpid($mua_pid, 0);
 939         }
 940 }
 941
 942 1;