lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use Time::HiRes qw(stat); # ctime comparisons for config cache
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log, $listener, $oldset);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub rel2abs ($$) {
  68         my ($self, $p) = @_;
  69         return $p if index($p, '/') == 0; # already absolute
  70         my $pwd = $self->{env}->{PWD};
  71         if (defined $pwd) {
  72                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  73                 if (my @st_pwd = stat($pwd)) {
  74                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  75                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  76                                 $self->{env}->{PWD} = $pwd = $cwd;
  77                 } else { # PWD was invalid
  78                         delete $self->{env}->{PWD};
  79                         undef $pwd;
  80                 }
  81         }
  82         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  83         File::Spec->rel2abs($p, $pwd);
  84 }
  85
  86 sub store_path ($) {
  87         my ($self) = @_;
  88         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  89                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  90                 .'/lei/store');
  91 }
  92
  93 sub _config_path ($) {
  94         my ($self) = @_;
  95         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  96                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  97                 .'/lei/config');
  98 }
  99
 100 sub cache_dir ($) {
 101         my ($self) = @_;
 102         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 103                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 104                 .'/lei');
 105 }
 106
 107 sub ale {
 108         my ($self) = @_;
 109         $self->{ale} //= do {
 110                 require PublicInbox::LeiALE;
 111                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 112         };
 113 }
 114
 115 sub index_opt {
 116         # TODO: drop underscore variants everywhere, they're undocumented
 117         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 118         max_size|max-size=s sequential_shard|sequential-shard
 119         batch_size|batch-size=s skip-docdata)
 120 }
 121
 122 my @c_opt = qw(c=s@ C=s@ quiet|q);
 123 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 124         import-remote! no-torsocks torsocks=s),
 125         PublicInbox::LeiQuery::curl_opt());
 126
 127 # we generate shell completion + help using %CMD and %OPTDESC,
 128 # see lei__complete() and PublicInbox::LeiHelp
 129 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 130 our %CMD = ( # sorted in order of importance/use:
 131 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 132         'stdin|', # /|\z/ must be first for lone dash
 133         @lxs_opt,
 134         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 135         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 136         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+), @c_opt,
 137         opt_dash('limit|n=i', '[0-9]+') ],
 138 'up' => [ 'SEARCH_TERMS...', 'update saved search',
 139         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+), @c_opt ],
 140
 141 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 142         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 143         @lxs_opt, @c_opt ],
 144
 145 'add-external' => [ 'LOCATION',
 146         'add/set priority of a publicinbox|extindex for extra matches',
 147         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 148         verbose|v+), @c_opt, index_opt(),
 149         PublicInbox::LeiQuery::curl_opt() ],
 150 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 151         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 152 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 153 'forget-external' => [ 'LOCATION...|--prune',
 154         'exclude further results from a publicinbox|extindex',
 155         qw(prune), @c_opt ],
 156
 157 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 158                 qw(name-only format|f=s), @c_opt ],
 159 'rm-query' => [ 'QUERY_NAME', 'remove a saved search', @c_opt ],
 160 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search', @c_opt ],
 161
 162 'plonk' => [ '--threads|--from=IDENT',
 163         'exclude mail matching From: or threads from non-Message-ID searches',
 164         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 165 'tag' => [ 'KEYWORDS...',
 166         'set/unset keywords and/or labels on message(s)',
 167         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@), @c_opt,
 168         pass_through('-kw:foo for delete') ],
 169 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 170         "exclude message(s) on stdin from `q' search results",
 171         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 172
 173 'purge-mailsource' => [ 'LOCATION|--all',
 174         'remove imported messages from IMAP, Maildirs, and MH',
 175         qw(exact! all jobs:i indexed), @c_opt ],
 176
 177 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 178         qw(import! kw|keywords|flags! interval=s recursive|r
 179         exclude=s include=s), @c_opt ],
 180 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 181                 qw(format|f=s z), @c_opt ],
 182 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 183 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 184 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 185         qw(prune), @c_opt ],
 186
 187 'import' => [ 'LOCATION...|--stdin',
 188         'one-time import/update from URL or filesystem',
 189         qw(stdin| offset=i recursive|r exclude=s include|I=s
 190         lock=s@ in-format|F=s kw|keywords|flags! verbose|v+), @c_opt ],
 191 'convert' => [ 'LOCATION...|--stdin',
 192         'one-time conversion from URL or filesystem to another format',
 193         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s
 194         lock=s@ kw|keywords|flags!), @c_opt ],
 195 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 196         "use a patch to generate a query for `lei q --stdin'",
 197         qw(stdin| want|w=s@ uri debug), @c_opt ],
 198 'config' => [ '[...]', sub {
 199                 'git-config(1) wrapper for '._config_path($_[0]);
 200         }, qw(config-file|system|global|file|f=s), # for conflict detection
 201          qw(c=s@ C=s@), pass_through('git config') ],
 202 'init' => [ '[DIRNAME]', sub {
 203         "initialize storage, default: ".store_path($_[0]);
 204         }, @c_opt ],
 205 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 206         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 207         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 208 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 209 'help' => [ '[SUBCOMMAND]', 'show help' ],
 210
 211 # XXX do we need this?
 212 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 213
 214 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 215         'rewrite git history in an attempt to improve compression',
 216         qw(gc!), @c_opt ],
 217
 218 # internal commands are prefixed with '_'
 219 '_complete' => [ '[...]', 'internal shell completion helper',
 220                 pass_through('everything') ],
 221 ); # @CMD
 222
 223 # switch descriptions, try to keep consistent across commands
 224 # $spec: Getopt::Long option specification
 225 # $spec => [@ALLOWED_VALUES (default is first), $description],
 226 # $spec => $description
 227 # "$SUB_COMMAND TAB $spec" => as above
 228 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 229                         'specify message input format' ];
 230 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 231
 232 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 233 my %OPTDESC = (
 234 'help|h' => 'show this built-in help',
 235 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 236 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 237 'quiet|q' => 'be quiet',
 238 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 239         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 240
 241 'globoff|g' => "do not match locations using '*?' wildcards ".
 242                 "and\xa0'[]'\x{a0}ranges",
 243 'verbose|v+' => 'be more verbose',
 244 'external!' => 'do not use externals',
 245 'mail!' => 'do not look in mail storage for OID',
 246 'cwd!' => 'do not look in git repo of current working directory',
 247 'oid-a|A=s' => 'pre-image OID',
 248 'path-a|a=s' => 'pre-image pathname associated with OID',
 249 'path-b|b=s' => 'post-image pathname associated with OID',
 250 'git-dir=s@' => 'additional git repository to scan',
 251 'torsocks=s' => ['VAL|auto|no|yes',
 252                 'whether or not to wrap git and curl commands with torsocks'],
 253 'no-torsocks' => 'alias for --torsocks=no',
 254 'save' =>  "save a search for `lei up'",
 255 'import-remote!' => 'do not memoize remote messages into local store',
 256
 257 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 258
 259 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 260                 'deduplication strategy'],
 261 'threads|t+' =>
 262         'return all messages in the same threads as the actual match(es)',
 263
 264 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 265                 'search prefixes to extract (default: dfpost7)' ],
 266
 267 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 268         'run command(s) or perform ops when done writing to output ' .
 269         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 270         'nothing otherwise)' ],
 271
 272 'augment|a' => 'augment --output destination instead of clobbering',
 273
 274 'output|mfolder|o=s' => [ 'MFOLDER',
 275         "destination (e.g.\xa0`/path/to/Maildir', ".
 276         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 277 'mua=s' => [ 'CMD',
 278         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 279
 280 'inbox-version=i' => [ 'NUM|1|2',
 281                 'force a public-inbox version with --mirror'],
 282 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 283
 284 # public-inbox-index options
 285 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 286 'compact' => 'run compact index after mirroring',
 287 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 288         "indexlevel with --mirror (default: full)" ],
 289 'max_size|max-size=s' => [ 'SIZE',
 290         'do not index messages larger than SIZE (default: infinity)' ],
 291 'batch_size|batch-size=s' => [ 'SIZE',
 292         'flush changes to OS after given number of bytes (default: 1m)' ],
 293 'sequential_shard|sequential-shard' =>
 294         'index Xapian shards sequentially for slow storage',
 295 'skip-docdata' =>
 296         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 297
 298 'format|f=s     q' => [
 299         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 300                 'specify output format, default depends on --output'],
 301 'exclude=s@     q' => [ 'LOCATION',
 302                 'exclude specified external(s) from search' ],
 303 'include|I=s@   q' => [ 'LOCATION',
 304                 'include specified external(s) in search' ],
 305 'only=s@        q' => [ 'LOCATION',
 306                 'only use specified external(s) for search' ],
 307 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 308                 'control number of search and writer jobs' ],
 309 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 310
 311 'in-format|F=s' => $stdin_formats,
 312 'format|f=s     ls-query' => $ls_format,
 313 'format|f=s     ls-external' => $ls_format,
 314
 315 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 316 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 317
 318 'sort|s=s' => [ 'VAL|received|relevance|docid',
 319                 "order of results is `--output'-dependent"],
 320 'reverse|r' => 'reverse search results', # like sort(1)
 321
 322 'boost=i' => 'increase/decrease priority of results (default: 0)',
 323
 324 'local' => 'limit operations to the local filesystem',
 325 'local!' => 'exclude results from the local filesystem',
 326 'remote' => 'limit operations to those requiring network access',
 327 'remote!' => 'prevent operations requiring network access',
 328
 329 'mid=s' => 'specify the Message-ID of a message',
 330 'oid=s' => 'specify the git object ID of a message',
 331
 332 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 333 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 334 'include=s' => 'include mailboxes/newsgroups based on pattern',
 335
 336 'exact' => 'operate on exact header matches only',
 337 'exact!' => 'rely on content match instead of exact header matches',
 338
 339 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 340
 341 'kw|keywords|flags!' => 'disable/enable importing flags',
 342
 343 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 344 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 345
 346 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 347 ); # %OPTDESC
 348
 349 my %CONFIG_KEYS = (
 350         'leistore.dir' => 'top-level storage location',
 351 );
 352
 353 my @WQ_KEYS = qw(lxs l2m imp mrr cnv p2q tag sol); # internal workers
 354
 355 sub _drop_wq {
 356         my ($self) = @_;
 357         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) { $wq->DESTROY }
 358 }
 359
 360 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 361 sub x_it ($$) {
 362         my ($self, $code) = @_;
 363         # make sure client sees stdout before exit
 364         $self->{1}->autoflush(1) if $self->{1};
 365         dump_and_clear_log();
 366         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 367                 send($s, "x_it $code", MSG_EOR);
 368         } elsif ($self->{oneshot}) {
 369                 # don't want to end up using $? from child processes
 370                 _drop_wq($self);
 371                 # cleanup anything that has tempfiles or open file handles
 372                 %PATH2CFG = ();
 373                 delete @$self{qw(ovv dedupe sto cfg)};
 374                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 375                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 376                         kill $signum, $$;
 377                         sleep(1) while 1; # wait for signal
 378                 } else {
 379                         $quit->($code >> 8);
 380                 }
 381         } # else ignore if client disconnected
 382 }
 383
 384 sub err ($;@) {
 385         my $self = shift;
 386         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 387         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 388         print $err @_, @eor and return;
 389         my $old_err = delete $self->{2};
 390         close($old_err) if $! == EPIPE && $old_err;
 391         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 392         print $err @_, @eor or print STDERR @_, @eor;
 393 }
 394
 395 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 396
 397 sub fail_handler ($;$$) {
 398         my ($lei, $code, $io) = @_;
 399         close($io) if $io; # needed to avoid warnings on SIGPIPE
 400         _drop_wq($lei);
 401         x_it($lei, $code // (1 << 8));
 402 }
 403
 404 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 405         fail_handler($_[0], 13, delete $_[0]->{1});
 406 }
 407
 408 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 409 sub sigint_reap {
 410         my ($pgid) = @_;
 411         dwaitpid($pgid) if kill('-INT', $pgid);
 412 }
 413
 414 sub fail ($$;$) {
 415         my ($self, $buf, $exit_code) = @_;
 416         err($self, $buf) if defined $buf;
 417         # calls fail_handler:
 418         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 419         x_it($self, ($exit_code // 1) << 8);
 420         undef;
 421 }
 422
 423 sub out ($;@) {
 424         my $self = shift;
 425         return if print { $self->{1} // return } @_; # likely
 426         return note_sigpipe($self, 1) if $! == EPIPE;
 427         my $err = "error writing to output: $!";
 428         delete $self->{1};
 429         fail($self, $err);
 430 }
 431
 432 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 433
 434 sub child_error { # passes non-fatal curl exit codes to user
 435         my ($self, $child_error, $msg) = @_; # child_error is $?
 436         $self->err($msg) if $msg;
 437         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 438                 # send to the parent lei-daemon or to lei(1) client
 439                 send($s, "child_error $child_error", MSG_EOR);
 440         } elsif (!$PublicInbox::DS::in_loop) {
 441                 $self->{child_error} = $child_error;
 442         } # else noop if client disconnected
 443 }
 444
 445 sub note_sigpipe { # triggers sigpipe_handler
 446         my ($self, $fd) = @_;
 447         close(delete($self->{$fd})); # explicit close silences Perl warning
 448         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 449         x_it($self, 13);
 450 }
 451
 452 sub _lei_atfork_child {
 453         my ($self, $persist) = @_;
 454         # we need to explicitly close things which are on stack
 455         if ($persist) {
 456                 chdir '/' or die "chdir(/): $!";
 457                 my @io = delete @$self{qw(0 1 2 sock)};
 458                 unless ($self->{oneshot}) {
 459                         close($_) for @io;
 460                 }
 461                 if (my $cfg = $self->{cfg}) {
 462                         delete $cfg->{-lei_store};
 463                 }
 464         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 465                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 466         }
 467         for (delete @$self{qw(3 old_1 au_done)}) {
 468                 close($_) if defined($_);
 469         }
 470         if (my $op_c = delete $self->{pkt_op_c}) {
 471                 close(delete $op_c->{sock});
 472         }
 473         if (my $pgr = delete $self->{pgr}) {
 474                 close($_) for (@$pgr[1,2]);
 475         }
 476         close $listener if $listener;
 477         undef $listener;
 478         %PATH2CFG = ();
 479         undef $errors_log;
 480         $quit = \&CORE::exit;
 481         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 482 }
 483
 484 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 485         my ($self) = @_;
 486         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 487                 $op->close; # PublicInbox::PktOp::close
 488         }
 489         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 490         close $unclosed_after_die;
 491 }
 492
 493 sub pkt_op_pair {
 494         my ($self) = @_;
 495         require PublicInbox::OnDestroy;
 496         require PublicInbox::PktOp;
 497         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 498         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 499         $end;
 500 }
 501
 502 sub workers_start {
 503         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 504         $ops = {
 505                 '!' => [ \&fail_handler, $lei ],
 506                 '|' => [ \&sigpipe_handler, $lei ],
 507                 'x_it' => [ \&x_it, $lei ],
 508                 'child_error' => [ \&child_error, $lei ],
 509                 ($ops ? %$ops : ()),
 510         };
 511         $ops->{''} //= [ \&dclose, $lei ];
 512         my $end = $lei->pkt_op_pair;
 513         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 514         delete $lei->{pkt_op_p};
 515         my $op_c = delete $lei->{pkt_op_c};
 516         @$end = ();
 517         $lei->event_step_init;
 518         ($op_c, $ops);
 519 }
 520
 521 sub _help {
 522         require PublicInbox::LeiHelp;
 523         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 524 }
 525
 526 sub optparse ($$$) {
 527         my ($self, $cmd, $argv) = @_;
 528         # allow _complete --help to complete, not show help
 529         return 1 if substr($cmd, 0, 1) eq '_';
 530         $self->{cmd} = $cmd;
 531         $OPT = $self->{opt} //= {};
 532         my $info = $CMD{$cmd} // [ '[...]' ];
 533         my ($proto, undef, @spec) = @$info;
 534         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 535         push @spec, qw(help|h);
 536         my $lone_dash;
 537         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 538                 $lone_dash = $spec[0];
 539                 $OPT->{$spec[0]} = \(my $var);
 540                 push @spec, '' => \$var;
 541         }
 542         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 543                 return _help($self, "bad arguments or options for $cmd");
 544         return _help($self) if $OPT->{help};
 545
 546         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 547
 548         # "-" aliases "stdin" or "clear"
 549         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 550
 551         my $i = 0;
 552         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 553         my ($err, $inf);
 554         my @args = split(/ /, $proto);
 555         for my $var (@args) {
 556                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 557                         $inf = defined($argv->[$i]) and last;
 558                         $var =~ s/\.\.\.\z//;
 559                         $err = "$var not supplied";
 560                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 561                         $argv->[$i++] // ($err = "$var not supplied");
 562                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 563                         $inf = 1;
 564                         last;
 565                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 566                         $i++;
 567                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 568                         $inf = 1 if index($var, '...') > 0;
 569                         my @or = split(/\|/, $var);
 570                         my $ok;
 571                         for my $o (@or) {
 572                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 573                                         $ok = defined($OPT->{$1});
 574                                         last if $ok;
 575                                 } elsif (defined($argv->[$i])) {
 576                                         $ok = 1;
 577                                         $i++;
 578                                         last;
 579                                 } # else continue looping
 580                         }
 581                         last if $ok;
 582                         my $last = pop @or;
 583                         $err = join(', ', @or) . " or $last must be set";
 584                 } else {
 585                         warn "BUG: can't parse `$var' in $proto";
 586                 }
 587                 last if $err;
 588         }
 589         if (!$inf && scalar(@$argv) > scalar(@args)) {
 590                 $err //= 'too many arguments';
 591         }
 592         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 593 }
 594
 595 sub _tmp_cfg { # for lei -c <name>=<value> ...
 596         my ($self) = @_;
 597         my $cfg = _lei_cfg($self, 1);
 598         require File::Temp;
 599         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 600         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 601         $ft->autoflush(1);
 602         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 603 [include]
 604         path = $cfg->{-f}
 605 EOM
 606         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 607         for (@{$self->{opt}->{c}}) {
 608                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 609 `-c $_' is not of the form -c <name>=<value>'
 610 EOM
 611                 my $name = $1;
 612                 my $value = $2 // 1;
 613                 _config($self, '--add', $name, $value);
 614                 if (defined(my $v = $tmp->{$name})) {
 615                         if (ref($v) eq 'ARRAY') {
 616                                 push @$v, $value;
 617                         } else {
 618                                 $tmp->{$name} = [ $v, $value ];
 619                         }
 620                 } else {
 621                         $tmp->{$name} = $value;
 622                 }
 623         }
 624 }
 625
 626 sub lazy_cb ($$$) {
 627         my ($self, $cmd, $pfx) = @_;
 628         my $ucmd = $cmd;
 629         $ucmd =~ tr/-/_/;
 630         my $cb;
 631         $cb = $self->can($pfx.$ucmd) and return $cb;
 632         my $base = $ucmd;
 633         $base =~ s/_([a-z])/\u$1/g;
 634         my $pkg = "PublicInbox::Lei\u$base";
 635         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 636                 $pkg->can($pfx.$ucmd) : undef;
 637 }
 638
 639 sub dispatch {
 640         my ($self, $cmd, @argv) = @_;
 641         local $current_lei = $self; # for __WARN__
 642         dump_and_clear_log("from previous run\n");
 643         return _help($self, 'no command given') unless defined($cmd);
 644         # do not support Getopt bundling for this
 645         while ($cmd eq '-C' || $cmd eq '-c') {
 646                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 647                                         '-C DIRECTORY' : '-c <name>=<value>');
 648                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 649                 $cmd = shift(@argv) // return _help($self, 'no command given');
 650         }
 651         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 652                 optparse($self, $cmd, \@argv) or return;
 653                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 654                 if (my $chdir = $self->{opt}->{C}) {
 655                         for my $d (@$chdir) {
 656                                 next if $d eq ''; # same as git(1)
 657                                 chdir $d or return fail($self, "cd $d: $!");
 658                         }
 659                         if (delete $self->{3}) { # update cwd for rel2abs
 660                                 opendir my $dh, '.' or
 661                                         return fail($self, "opendir . $!");
 662                                 $self->{3} = $dh;
 663                         }
 664                 }
 665                 $cb->($self, @argv);
 666         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 667                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 668                         or return _help($self, 'bad arguments or options');
 669                 _help($self);
 670         } else {
 671                 fail($self, "`$cmd' is not an lei command");
 672         }
 673 }
 674
 675 sub _lei_cfg ($;$) {
 676         my ($self, $creat) = @_;
 677         return $self->{cfg} if $self->{cfg};
 678         my $f = _config_path($self);
 679         my @st = stat($f);
 680         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 681         my ($sto, $sto_dir);
 682         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 683                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 684                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 685         }
 686         if (!@st) {
 687                 unless ($creat) {
 688                         delete $self->{cfg};
 689                         return bless {}, 'PublicInbox::Config';
 690                 }
 691                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 692                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 693                 open my $fh, '>>', $f or die "open($f): $!\n";
 694                 @st = stat($fh) or die "fstat($f): $!\n";
 695                 $cur_st = pack('dd', $st[10], $st[7]);
 696                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 697         }
 698         my $cfg = PublicInbox::Config::git_config_dump($f);
 699         bless $cfg, 'PublicInbox::Config';
 700         $cfg->{-st} = $cur_st;
 701         $cfg->{'-f'} = $f;
 702         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 703                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 704                                                 store_path($self))) {
 705                 $cfg->{-lei_store} = $sto;
 706         }
 707         if (scalar(keys %PATH2CFG) > 5) {
 708                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 709                 for my $k (keys %PATH2CFG) {
 710                         delete($PATH2CFG{$k}) unless -f $k
 711                 }
 712         }
 713         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 714 }
 715
 716 sub _lei_store ($;$) {
 717         my ($self, $creat) = @_;
 718         my $cfg = _lei_cfg($self, $creat);
 719         $cfg->{-lei_store} //= do {
 720                 require PublicInbox::LeiStore;
 721                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 722                 return unless $creat || -d $dir;
 723                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 724         };
 725 }
 726
 727 sub _config {
 728         my ($self, @argv) = @_;
 729         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 730         my $cfg = _lei_cfg($self, 1);
 731         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 732         my %rdr = map { $_ => $self->{$_} } (0..2);
 733         waitpid(spawn($cmd, \%env, \%rdr), 0);
 734 }
 735
 736 sub lei_config {
 737         my ($self, @argv) = @_;
 738         $self->{opt}->{'config-file'} and return fail $self,
 739                 "config file switches not supported by `lei config'";
 740         _config(@_);
 741         x_it($self, $?) if $?;
 742 }
 743
 744 sub lei_daemon_pid { puts shift, $$ }
 745
 746 sub lei_daemon_kill {
 747         my ($self) = @_;
 748         my $sig = $self->{opt}->{signal} // 'TERM';
 749         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 750 }
 751
 752 # Shell completion helper.  Used by lei-completion.bash and hopefully
 753 # other shells.  Try to do as much here as possible to avoid redundancy
 754 # and improve maintainability.
 755 sub lei__complete {
 756         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 757         shift @argv; # ignore "lei", the entire command is sent
 758         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 759         my $cmd = shift @argv;
 760         my $info = $CMD{$cmd} // do { # filter matching commands
 761                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 762                 return;
 763         };
 764         my ($proto, undef, @spec) = @$info;
 765         my $cur = pop @argv;
 766         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 767         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 768                 # gross special case since the only git-config options
 769                 # Consider moving to a table if we need more special cases
 770                 # we use Getopt::Long for are the ones we reject, so these
 771                 # are the ones we don't reject:
 772                 if ($cmd eq 'config') {
 773                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 774                         @spec = qw(add z|null get get-all unset unset-all
 775                                 replace-all get-urlmatch
 776                                 remove-section rename-section
 777                                 name-only list|l edit|e
 778                                 get-color-name get-colorbool);
 779                         # fall-through
 780                 }
 781                 # generate short/long names from Getopt::Long specs
 782                 puts $self, grep(/$re/, qw(--help -h -C), map {
 783                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 784                         } elsif (s/\+\z//) { # verbose|v+
 785                         } elsif (s/!\z//) {
 786                                 # negation: mail! => no-mail|mail
 787                                 s/([\w\-]+)/$1|no-$1/g
 788                         }
 789                         map {
 790                                 my $x = length > 1 ? "--$_" : "-$_";
 791                                 $x eq $_cur ? () : $x;
 792                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 793                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 794         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 795                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 796         }
 797
 798         # switch args (e.g. lei q -f mbox<TAB>)
 799         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 800                 my $opt = quotemeta $1;
 801                 puts $self, map {
 802                         my $v = $OPTDESC{$_};
 803                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 804                         # get rid of ALL CAPS placeholder (e.g "OUT")
 805                         # (TODO: completion for external paths)
 806                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 807                         @v;
 808                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 809         }
 810         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 811                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 812         }
 813         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 814         # proto parsing.
 815 }
 816
 817 sub exec_buf ($$) {
 818         my ($argv, $env) = @_;
 819         my $argc = scalar @$argv;
 820         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 821         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 822         $buf;
 823 }
 824
 825 sub start_mua {
 826         my ($self) = @_;
 827         my $mua = $self->{opt}->{mua} // return;
 828         my $mfolder = $self->{ovv}->{dst};
 829         my (@cmd, $replaced);
 830         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 831                 @cmd = ($mua, '-f');
 832         # TODO: help wanted: other common FOSS MUAs
 833         } else {
 834                 require Text::ParseWords;
 835                 @cmd = Text::ParseWords::shellwords($mua);
 836                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 837                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 838         }
 839         push @cmd, $mfolder unless defined($replaced);
 840         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 841                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 842         } elsif ($self->{oneshot}) {
 843                 my $pid = fork // die "fork: $!";
 844                 if ($pid > 0) { # original process
 845                         exec(@cmd);
 846                         warn "exec @cmd: $!\n";
 847                         POSIX::_exit(1);
 848                 }
 849                 POSIX::setsid() > 0 or die "setsid: $!";
 850         }
 851         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 852                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 853         }
 854         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 855         $self->{opt}->{quiet} = 1;
 856         delete $self->{-progress};
 857         delete $self->{opt}->{verbose};
 858 }
 859
 860 sub send_exec_cmd { # tell script/lei to execute a command
 861         my ($self, $io, $cmd, $env) = @_;
 862         my $sock = $self->{sock} // die 'lei client gone';
 863         my $fds = [ map { fileno($_) } @$io ];
 864         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 865 }
 866
 867 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 868         my ($self) = @_;
 869         my $alerts = $self->{opt}->{alert} // return;
 870         while (my $op = shift(@$alerts)) {
 871                 if ($op eq ':WINCH') {
 872                         # hit the process group that started the MUA
 873                         if ($self->{sock}) {
 874                                 send($self->{sock}, '-WINCH', MSG_EOR);
 875                         } elsif ($self->{oneshot}) {
 876                                 kill('-WINCH', $$);
 877                         }
 878                 } elsif ($op eq ':bell') {
 879                         out($self, "\a");
 880                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 881                         push @$alerts, split(/(?<!\\),/, $op);
 882                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 883                         my $cmd = $1; # run an arbitrary command
 884                         require Text::ParseWords;
 885                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 886                         if (my $s = $self->{sock}) {
 887                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 888                         } elsif ($self->{oneshot}) {
 889                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 890                         }
 891                 } else {
 892                         err($self, "W: unsupported --alert=$op"); # non-fatal
 893                 }
 894         }
 895 }
 896
 897 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 898 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 899
 900 # this also normalizes the path
 901 sub path_to_fd {
 902         my ($self, $path) = @_;
 903         $path = rel2abs($self, $path);
 904         $path =~ tr!/!/!s;
 905         $path_to_fd{$path} // (
 906                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 907                         fail($self, "cannot open $path from daemon") : -1
 908         );
 909 }
 910
 911 # caller needs to "-t $self->{1}" to check if tty
 912 sub start_pager {
 913         my ($self) = @_;
 914         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 915         chomp(my $pager = <$fh> // '');
 916         close($fh) or warn "`git var PAGER' error: \$?=$?";
 917         return if $pager eq 'cat' || $pager eq '';
 918         my $new_env = { LESS => 'FRX', LV => '-c' };
 919         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 920         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 921         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 922         my $pgr = [ undef, @$rdr{1, 2} ];
 923         my $env = $self->{env};
 924         if ($self->{sock}) { # lei(1) process runs it
 925                 delete @$new_env{keys %$env}; # only set iff unset
 926                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 927         } elsif ($self->{oneshot}) {
 928                 my $cmd = [$pager];
 929                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 930         } else {
 931                 die 'BUG: start_pager w/o socket';
 932         }
 933         $self->{1} = $wpager;
 934         $self->{2} = $wpager if -t $self->{2};
 935         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 936         $self->{pgr} = $pgr;
 937 }
 938
 939 sub stop_pager {
 940         my ($self) = @_;
 941         my $pgr = delete($self->{pgr}) or return;
 942         $self->{2} = $pgr->[2];
 943         # do not restore original stdout, just close it so we error out
 944         close(delete($self->{1})) if $self->{1};
 945 }
 946
 947 sub accept_dispatch { # Listener {post_accept} callback
 948         my ($sock) = @_; # ignore other
 949         $sock->autoflush(1);
 950         my $self = bless { sock => $sock }, __PACKAGE__;
 951         vec(my $rvec = '', fileno($sock), 1) = 1;
 952         select($rvec, undef, undef, 60) or
 953                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 954         # (4096 * 33) >MAX_ARG_STRLEN
 955         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
 956         if (!defined($fds[0])) {
 957                 warn(my $msg = "recv_cmd failed: $!");
 958                 return send($sock, $msg, MSG_EOR);
 959         } else {
 960                 my $i = 0;
 961                 for my $fd (@fds) {
 962                         open($self->{$i++}, '+<&=', $fd) and next;
 963                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 964                 }
 965                 return if scalar(@fds) != 4;
 966         }
 967         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 968         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 969         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 970         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 971                 return send($sock, 'request command truncated', MSG_EOR);
 972         my ($argc, @argv) = split(/\0/, $buf, -1);
 973         undef $buf;
 974         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 975         if (chdir($self->{3})) {
 976                 local %ENV = %env;
 977                 $self->{env} = \%env;
 978                 eval { dispatch($self, @argv) };
 979                 send($sock, $@, MSG_EOR) if $@;
 980         } else {
 981                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 982         }
 983 }
 984
 985 sub dclose {
 986         my ($self) = @_;
 987         delete $self->{-progress};
 988         _drop_wq($self);
 989         close(delete $self->{1}) if $self->{1}; # may reap_compress
 990         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
 991 }
 992
 993 # for long-running results
 994 sub event_step {
 995         my ($self) = @_;
 996         local %ENV = %{$self->{env}};
 997         my $sock = $self->{sock};
 998         local $current_lei = $self;
 999         eval {
1000                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1001                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1002                                 return if $! == EAGAIN;
1003                                 next if $! == EINTR;
1004                                 last if $! == ECONNRESET;
1005                                 die "recvmsg: $!";
1006                         }
1007                         for my $fd (@fds) {
1008                                 open my $rfh, '+<&=', $fd;
1009                         }
1010                         die "unrecognized client signal: $buf";
1011                 }
1012                 dclose($self);
1013         };
1014         if (my $err = $@) {
1015                 eval { $self->fail($err) };
1016                 dclose($self);
1017         }
1018 }
1019
1020 sub event_step_init {
1021         my ($self) = @_;
1022         return if $self->{-event_init_done}++;
1023         if (my $sock = $self->{sock}) { # using DS->EventLoop
1024                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1025         }
1026 }
1027
1028 sub noop {}
1029
1030 sub oldset { $oldset }
1031
1032 sub dump_and_clear_log {
1033         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1034                 my @pfx = @_;
1035                 unshift(@pfx, "$errors_log ") if @pfx;
1036                 warn @pfx, do { local $/; <STDIN> };
1037                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1038         }
1039 }
1040
1041 # lei(1) calls this when it can't connect
1042 sub lazy_start {
1043         my ($path, $errno, $narg) = @_;
1044         local ($errors_log, $listener);
1045         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1046         $errors_log .= 'errors.log';
1047         my $addr = pack_sockaddr_un($path);
1048         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1049         $lk->lock_acquire;
1050         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1051         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1052                 return if connect($listener, $addr); # another process won
1053                 if ($errno == ECONNREFUSED && -S $path) {
1054                         unlink($path) or die "unlink($path): $!";
1055                 }
1056         } else {
1057                 $! = $errno; # allow interpolation to stringify in die
1058                 die "connect($path): $!";
1059         }
1060         umask(077) // die("umask(077): $!");
1061         bind($listener, $addr) or die "bind($path): $!";
1062         listen($listener, 1024) or die "listen: $!";
1063         $lk->lock_release;
1064         undef $lk;
1065         my @st = stat($path) or die "stat($path): $!";
1066         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1067         local $oldset = PublicInbox::DS::block_signals();
1068         if ($narg == 5) {
1069                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1070                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1071                         require PublicInbox::CmdIPC4;
1072                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1073                         PublicInbox::CmdIPC4->can('recv_cmd4');
1074                 };
1075         }
1076         $recv_cmd or die <<"";
1077 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1078
1079         require PublicInbox::Listener;
1080         require PublicInbox::EOFpipe;
1081         (-p STDOUT) or die "E: stdout must be a pipe\n";
1082         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1083         STDIN->autoflush(1);
1084         dump_and_clear_log("from previous daemon process:\n");
1085         POSIX::setsid() > 0 or die "setsid: $!";
1086         my $pid = fork // die "fork: $!";
1087         return if $pid;
1088         $0 = "lei-daemon $path";
1089         local %PATH2CFG;
1090         $listener->blocking(0);
1091         my $exit_code;
1092         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1093         local $quit = do {
1094                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1095                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1096                 sub {
1097                         $exit_code //= shift;
1098                         my $lis = $pil or exit($exit_code);
1099                         # closing eof_w triggers \&noop wakeup
1100                         $listener = $eof_w = $pil = $path = undef;
1101                         $lis->close; # DS::close
1102                         PublicInbox::DS->SetLoopTimeout(1000);
1103                 };
1104         };
1105         my $sig = {
1106                 CHLD => \&PublicInbox::DS::enqueue_reap,
1107                 QUIT => $quit,
1108                 INT => $quit,
1109                 TERM => $quit,
1110                 HUP => \&noop,
1111                 USR1 => \&noop,
1112                 USR2 => \&noop,
1113         };
1114         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1115         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1116         undef $sig;
1117         local $SIG{PIPE} = 'IGNORE';
1118         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1119                 undef $sigfd;
1120                 PublicInbox::DS->SetLoopTimeout(5000);
1121         } else {
1122                 # wake up every second to accept signals if we don't
1123                 # have signalfd or IO::KQueue:
1124                 PublicInbox::DS::sig_setmask($oldset);
1125                 PublicInbox::DS->SetLoopTimeout(1000);
1126         }
1127         PublicInbox::DS->SetPostLoopCallback(sub {
1128                 my ($dmap, undef) = @_;
1129                 if (@st = defined($path) ? stat($path) : ()) {
1130                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1131                                 warn "$path dev/ino changed, quitting\n";
1132                                 $path = undef;
1133                         }
1134                 } elsif (defined($path)) { # ENOENT is common
1135                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1136                         undef $path;
1137                         $quit->();
1138                 }
1139                 return 1 if defined($path);
1140                 my $now = now();
1141                 my $n = 0;
1142                 for my $s (values %$dmap) {
1143                         $s->can('busy') or next;
1144                         if ($s->busy($now)) {
1145                                 ++$n;
1146                         } else {
1147                                 $s->close;
1148                         }
1149                 }
1150                 $n; # true: continue, false: stop
1151         });
1152
1153         # STDIN was redirected to /dev/null above, closing STDERR and
1154         # STDOUT will cause the calling `lei' client process to finish
1155         # reading the <$daemon> pipe.
1156         local $SIG{__WARN__} = sub {
1157                 $current_lei ? err($current_lei, @_) : warn(
1158                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1159         };
1160         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1161         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1162         # $daemon pipe to `lei' closed, main loop begins:
1163         PublicInbox::DS->EventLoop;
1164         exit($exit_code // 0);
1165 }
1166
1167 sub busy { 1 } # prevent daemon-shutdown if client is connected
1168
1169 # for users w/o Socket::Msghdr installed or Inline::C enabled
1170 sub oneshot {
1171         my ($main_pkg) = @_;
1172         my $exit = $main_pkg->can('exit'); # caller may override exit()
1173         local $quit = $exit if $exit;
1174         local %PATH2CFG;
1175         umask(077) // die("umask(077): $!");
1176         my $self = bless {
1177                 oneshot => 1,
1178                 0 => *STDIN{GLOB},
1179                 1 => *STDOUT{GLOB},
1180                 2 => *STDERR{GLOB},
1181                 env => \%ENV
1182         }, __PACKAGE__;
1183         dispatch($self, @ARGV);
1184         x_it($self, $self->{child_error}) if $self->{child_error};
1185 }
1186
1187 # ensures stdout hits the FS before sock disconnects so a client
1188 # can immediately reread it
1189 sub DESTROY {
1190         my ($self) = @_;
1191         $self->{1}->autoflush(1) if $self->{1};
1192         stop_pager($self);
1193         my $err = $?;
1194         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1195         waitpid($_, 0) for keys %$oneshot_pids;
1196         $? = $err if $err; # preserve ->fail or ->x_it code
1197 }
1198
1199 1;