lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use Time::HiRes qw(stat); # ctime comparisons for config cache
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log, $listener, $oldset);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub rel2abs ($$) {
  68         my ($self, $p) = @_;
  69         return $p if index($p, '/') == 0; # already absolute
  70         my $pwd = $self->{env}->{PWD};
  71         if (defined $pwd) {
  72                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  73                 if (my @st_pwd = stat($pwd)) {
  74                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  75                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  76                                 $self->{env}->{PWD} = $pwd = $cwd;
  77                 } else { # PWD was invalid
  78                         delete $self->{env}->{PWD};
  79                         undef $pwd;
  80                 }
  81         }
  82         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  83         File::Spec->rel2abs($p, $pwd);
  84 }
  85
  86 sub store_path ($) {
  87         my ($self) = @_;
  88         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  89                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  90                 .'/lei/store');
  91 }
  92
  93 sub _config_path ($) {
  94         my ($self) = @_;
  95         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  96                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  97                 .'/lei/config');
  98 }
  99
 100 sub cache_dir ($) {
 101         my ($self) = @_;
 102         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 103                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 104                 .'/lei');
 105 }
 106
 107 sub ale {
 108         my ($self) = @_;
 109         $self->{ale} //= do {
 110                 require PublicInbox::LeiALE;
 111                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 112         };
 113 }
 114
 115 sub index_opt {
 116         # TODO: drop underscore variants everywhere, they're undocumented
 117         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 118         max_size|max-size=s sequential_shard|sequential-shard
 119         batch_size|batch-size=s skip-docdata)
 120 }
 121
 122 my @c_opt = qw(c=s@ C=s@ quiet|q);
 123 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 124         import-remote! no-torsocks torsocks=s),
 125         PublicInbox::LeiQuery::curl_opt());
 126
 127 # we generate shell completion + help using %CMD and %OPTDESC,
 128 # see lei__complete() and PublicInbox::LeiHelp
 129 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 130 our %CMD = ( # sorted in order of importance/use:
 131 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 132         'stdin|', # /|\z/ must be first for lone dash
 133         @lxs_opt,
 134         qw(save-as=s output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 135         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 136         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+), @c_opt,
 137         opt_dash('limit|n=i', '[0-9]+') ],
 138
 139 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 140         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 141         @lxs_opt, @c_opt ],
 142
 143 'add-external' => [ 'LOCATION',
 144         'add/set priority of a publicinbox|extindex for extra matches',
 145         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 146         verbose|v+), @c_opt, index_opt(),
 147         PublicInbox::LeiQuery::curl_opt() ],
 148 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 149         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 150 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 151 'forget-external' => [ 'LOCATION...|--prune',
 152         'exclude further results from a publicinbox|extindex',
 153         qw(prune), @c_opt ],
 154
 155 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 156                 qw(name-only format|f=s), @c_opt ],
 157 'rm-query' => [ 'QUERY_NAME', 'remove a saved search', @c_opt ],
 158 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search', @c_opt ],
 159
 160 'plonk' => [ '--threads|--from=IDENT',
 161         'exclude mail matching From: or threads from non-Message-ID searches',
 162         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 163 'tag' => [ 'KEYWORDS...',
 164         'set/unset keywords and/or labels on message(s)',
 165         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@), @c_opt,
 166         pass_through('-kw:foo for delete') ],
 167 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 168         "exclude message(s) on stdin from `q' search results",
 169         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 170
 171 'purge-mailsource' => [ 'LOCATION|--all',
 172         'remove imported messages from IMAP, Maildirs, and MH',
 173         qw(exact! all jobs:i indexed), @c_opt ],
 174
 175 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 176         qw(import! kw|keywords|flags! interval=s recursive|r
 177         exclude=s include=s), @c_opt ],
 178 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 179                 qw(format|f=s z), @c_opt ],
 180 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 181 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 182 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 183         qw(prune), @c_opt ],
 184
 185 'import' => [ 'LOCATION...|--stdin',
 186         'one-time import/update from URL or filesystem',
 187         qw(stdin| offset=i recursive|r exclude=s include|I=s
 188         lock=s@ in-format|F=s kw|keywords|flags! verbose|v+), @c_opt ],
 189 'convert' => [ 'LOCATION...|--stdin',
 190         'one-time conversion from URL or filesystem to another format',
 191         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s
 192         lock=s@ kw|keywords|flags!), @c_opt ],
 193 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 194         "use a patch to generate a query for `lei q --stdin'",
 195         qw(stdin| want|w=s@ uri debug), @c_opt ],
 196 'config' => [ '[...]', sub {
 197                 'git-config(1) wrapper for '._config_path($_[0]);
 198         }, qw(config-file|system|global|file|f=s), # for conflict detection
 199          qw(c=s@ C=s@), pass_through('git config') ],
 200 'init' => [ '[DIRNAME]', sub {
 201         "initialize storage, default: ".store_path($_[0]);
 202         }, @c_opt ],
 203 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 204         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 205         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 206 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 207 'help' => [ '[SUBCOMMAND]', 'show help' ],
 208
 209 # XXX do we need this?
 210 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 211
 212 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 213         'rewrite git history in an attempt to improve compression',
 214         qw(gc!), @c_opt ],
 215
 216 # internal commands are prefixed with '_'
 217 '_complete' => [ '[...]', 'internal shell completion helper',
 218                 pass_through('everything') ],
 219 ); # @CMD
 220
 221 # switch descriptions, try to keep consistent across commands
 222 # $spec: Getopt::Long option specification
 223 # $spec => [@ALLOWED_VALUES (default is first), $description],
 224 # $spec => $description
 225 # "$SUB_COMMAND TAB $spec" => as above
 226 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 227                         'specify message input format' ];
 228 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 229
 230 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 231 my %OPTDESC = (
 232 'help|h' => 'show this built-in help',
 233 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 234 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 235 'quiet|q' => 'be quiet',
 236 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 237         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 238
 239 'globoff|g' => "do not match locations using '*?' wildcards ".
 240                 "and\xa0'[]'\x{a0}ranges",
 241 'verbose|v+' => 'be more verbose',
 242 'external!' => 'do not use externals',
 243 'mail!' => 'do not look in mail storage for OID',
 244 'cwd!' => 'do not look in git repo of current working directory',
 245 'oid-a|A=s' => 'pre-image OID',
 246 'path-a|a=s' => 'pre-image pathname associated with OID',
 247 'path-b|b=s' => 'post-image pathname associated with OID',
 248 'git-dir=s@' => 'additional git repository to scan',
 249 'torsocks=s' => ['VAL|auto|no|yes',
 250                 'whether or not to wrap git and curl commands with torsocks'],
 251 'no-torsocks' => 'alias for --torsocks=no',
 252 'save-as=s' => ['NAME', 'save a search terms by given name'],
 253 'import-remote!' => 'do not memoize remote messages into local store',
 254
 255 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 256
 257 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 258                 'deduplication strategy'],
 259 'threads|t+' =>
 260         'return all messages in the same threads as the actual match(es)',
 261
 262 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 263                 'search prefixes to extract (default: dfpost7)' ],
 264
 265 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 266         'run command(s) or perform ops when done writing to output ' .
 267         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 268         'nothing otherwise)' ],
 269
 270 'augment|a' => 'augment --output destination instead of clobbering',
 271
 272 'output|mfolder|o=s' => [ 'MFOLDER',
 273         "destination (e.g.\xa0`/path/to/Maildir', ".
 274         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 275 'mua=s' => [ 'CMD',
 276         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 277
 278 'inbox-version=i' => [ 'NUM|1|2',
 279                 'force a public-inbox version with --mirror'],
 280 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 281
 282 # public-inbox-index options
 283 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 284 'compact' => 'run compact index after mirroring',
 285 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 286         "indexlevel with --mirror (default: full)" ],
 287 'max_size|max-size=s' => [ 'SIZE',
 288         'do not index messages larger than SIZE (default: infinity)' ],
 289 'batch_size|batch-size=s' => [ 'SIZE',
 290         'flush changes to OS after given number of bytes (default: 1m)' ],
 291 'sequential_shard|sequential-shard' =>
 292         'index Xapian shards sequentially for slow storage',
 293 'skip-docdata' =>
 294         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 295
 296 'format|f=s     q' => [
 297         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 298                 'specify output format, default depends on --output'],
 299 'exclude=s@     q' => [ 'LOCATION',
 300                 'exclude specified external(s) from search' ],
 301 'include|I=s@   q' => [ 'LOCATION',
 302                 'include specified external(s) in search' ],
 303 'only=s@        q' => [ 'LOCATION',
 304                 'only use specified external(s) for search' ],
 305 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 306                 'control number of search and writer jobs' ],
 307 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 308
 309 'in-format|F=s' => $stdin_formats,
 310 'format|f=s     ls-query' => $ls_format,
 311 'format|f=s     ls-external' => $ls_format,
 312
 313 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 314 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 315
 316 'sort|s=s' => [ 'VAL|received|relevance|docid',
 317                 "order of results is `--output'-dependent"],
 318 'reverse|r' => 'reverse search results', # like sort(1)
 319
 320 'boost=i' => 'increase/decrease priority of results (default: 0)',
 321
 322 'local' => 'limit operations to the local filesystem',
 323 'local!' => 'exclude results from the local filesystem',
 324 'remote' => 'limit operations to those requiring network access',
 325 'remote!' => 'prevent operations requiring network access',
 326
 327 'mid=s' => 'specify the Message-ID of a message',
 328 'oid=s' => 'specify the git object ID of a message',
 329
 330 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 331 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 332 'include=s' => 'include mailboxes/newsgroups based on pattern',
 333
 334 'exact' => 'operate on exact header matches only',
 335 'exact!' => 'rely on content match instead of exact header matches',
 336
 337 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 338
 339 'kw|keywords|flags!' => 'disable/enable importing flags',
 340
 341 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 342 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 343
 344 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 345 ); # %OPTDESC
 346
 347 my %CONFIG_KEYS = (
 348         'leistore.dir' => 'top-level storage location',
 349 );
 350
 351 my @WQ_KEYS = qw(lxs l2m imp mrr cnv p2q tag sol); # internal workers
 352
 353 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 354 sub x_it ($$) {
 355         my ($self, $code) = @_;
 356         # make sure client sees stdout before exit
 357         $self->{1}->autoflush(1) if $self->{1};
 358         dump_and_clear_log();
 359         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 360                 send($s, "x_it $code", MSG_EOR);
 361         } elsif ($self->{oneshot}) {
 362                 # don't want to end up using $? from child processes
 363                 for my $f (@WQ_KEYS) {
 364                         my $wq = delete $self->{$f} or next;
 365                         $wq->DESTROY;
 366                 }
 367                 # cleanup anything that has tempfiles or open file handles
 368                 %PATH2CFG = ();
 369                 delete @$self{qw(ovv dedupe sto cfg)};
 370                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 371                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 372                         kill $signum, $$;
 373                         sleep(1) while 1; # wait for signal
 374                 } else {
 375                         $quit->($code >> 8);
 376                 }
 377         } # else ignore if client disconnected
 378 }
 379
 380 sub err ($;@) {
 381         my $self = shift;
 382         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 383         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 384         print $err @_, @eor and return;
 385         my $old_err = delete $self->{2};
 386         close($old_err) if $! == EPIPE && $old_err;
 387         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 388         print $err @_, @eor or print STDERR @_, @eor;
 389 }
 390
 391 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 392
 393 sub fail_handler ($;$$) {
 394         my ($lei, $code, $io) = @_;
 395         for my $f (@WQ_KEYS) {
 396                 my $wq = delete $lei->{$f} or next;
 397                 $wq->wq_wait_old(undef, $lei) if $wq->wq_kill_old; # lei-daemon
 398         }
 399         close($io) if $io; # needed to avoid warnings on SIGPIPE
 400         x_it($lei, $code // (1 << 8));
 401 }
 402
 403 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 404         fail_handler($_[0], 13, delete $_[0]->{1});
 405 }
 406
 407 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 408 sub sigint_reap {
 409         my ($pgid) = @_;
 410         dwaitpid($pgid) if kill('-INT', $pgid);
 411 }
 412
 413 sub fail ($$;$) {
 414         my ($self, $buf, $exit_code) = @_;
 415         err($self, $buf) if defined $buf;
 416         # calls fail_handler:
 417         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 418         x_it($self, ($exit_code // 1) << 8);
 419         undef;
 420 }
 421
 422 sub out ($;@) {
 423         my $self = shift;
 424         return if print { $self->{1} // return } @_; # likely
 425         return note_sigpipe($self, 1) if $! == EPIPE;
 426         my $err = "error writing to output: $!";
 427         delete $self->{1};
 428         fail($self, $err);
 429 }
 430
 431 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 432
 433 sub child_error { # passes non-fatal curl exit codes to user
 434         my ($self, $child_error, $msg) = @_; # child_error is $?
 435         $self->err($msg) if $msg;
 436         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 437                 # send to the parent lei-daemon or to lei(1) client
 438                 send($s, "child_error $child_error", MSG_EOR);
 439         } elsif (!$PublicInbox::DS::in_loop) {
 440                 $self->{child_error} = $child_error;
 441         } # else noop if client disconnected
 442 }
 443
 444 sub note_sigpipe { # triggers sigpipe_handler
 445         my ($self, $fd) = @_;
 446         close(delete($self->{$fd})); # explicit close silences Perl warning
 447         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 448         x_it($self, 13);
 449 }
 450
 451 sub _lei_atfork_child {
 452         my ($self, $persist) = @_;
 453         # we need to explicitly close things which are on stack
 454         if ($persist) {
 455                 chdir '/' or die "chdir(/): $!";
 456                 my @io = delete @$self{qw(0 1 2 sock)};
 457                 unless ($self->{oneshot}) {
 458                         close($_) for @io;
 459                 }
 460                 if (my $cfg = $self->{cfg}) {
 461                         delete $cfg->{-lei_store};
 462                 }
 463         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 464                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 465         }
 466         for (delete @$self{qw(3 old_1 au_done)}) {
 467                 close($_) if defined($_);
 468         }
 469         if (my $op_c = delete $self->{pkt_op_c}) {
 470                 close(delete $op_c->{sock});
 471         }
 472         if (my $pgr = delete $self->{pgr}) {
 473                 close($_) for (@$pgr[1,2]);
 474         }
 475         close $listener if $listener;
 476         undef $listener;
 477         %PATH2CFG = ();
 478         undef $errors_log;
 479         $quit = \&CORE::exit;
 480         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 481 }
 482
 483 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 484         my ($self) = @_;
 485         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 486                 $op->close; # PublicInbox::PktOp::close
 487         }
 488         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 489         close $unclosed_after_die;
 490 }
 491
 492 sub pkt_op_pair {
 493         my ($self) = @_;
 494         require PublicInbox::OnDestroy;
 495         require PublicInbox::PktOp;
 496         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 497         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 498         $end;
 499 }
 500
 501 sub workers_start {
 502         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 503         $ops = {
 504                 '!' => [ \&fail_handler, $lei ],
 505                 '|' => [ \&sigpipe_handler, $lei ],
 506                 'x_it' => [ \&x_it, $lei ],
 507                 'child_error' => [ \&child_error, $lei ],
 508                 ($ops ? %$ops : ()),
 509         };
 510         $ops->{''} //= [ \&dclose, $lei ];
 511         my $end = $lei->pkt_op_pair;
 512         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 513         delete $lei->{pkt_op_p};
 514         my $op_c = delete $lei->{pkt_op_c};
 515         @$end = ();
 516         $lei->event_step_init;
 517         ($op_c, $ops);
 518 }
 519
 520 sub _help {
 521         require PublicInbox::LeiHelp;
 522         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 523 }
 524
 525 sub optparse ($$$) {
 526         my ($self, $cmd, $argv) = @_;
 527         # allow _complete --help to complete, not show help
 528         return 1 if substr($cmd, 0, 1) eq '_';
 529         $self->{cmd} = $cmd;
 530         $OPT = $self->{opt} //= {};
 531         my $info = $CMD{$cmd} // [ '[...]' ];
 532         my ($proto, undef, @spec) = @$info;
 533         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 534         push @spec, qw(help|h);
 535         my $lone_dash;
 536         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 537                 $lone_dash = $spec[0];
 538                 $OPT->{$spec[0]} = \(my $var);
 539                 push @spec, '' => \$var;
 540         }
 541         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 542                 return _help($self, "bad arguments or options for $cmd");
 543         return _help($self) if $OPT->{help};
 544
 545         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 546
 547         # "-" aliases "stdin" or "clear"
 548         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 549
 550         my $i = 0;
 551         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 552         my ($err, $inf);
 553         my @args = split(/ /, $proto);
 554         for my $var (@args) {
 555                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 556                         $inf = defined($argv->[$i]) and last;
 557                         $var =~ s/\.\.\.\z//;
 558                         $err = "$var not supplied";
 559                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 560                         $argv->[$i++] // ($err = "$var not supplied");
 561                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 562                         $inf = 1;
 563                         last;
 564                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 565                         $i++;
 566                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 567                         $inf = 1 if index($var, '...') > 0;
 568                         my @or = split(/\|/, $var);
 569                         my $ok;
 570                         for my $o (@or) {
 571                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 572                                         $ok = defined($OPT->{$1});
 573                                         last if $ok;
 574                                 } elsif (defined($argv->[$i])) {
 575                                         $ok = 1;
 576                                         $i++;
 577                                         last;
 578                                 } # else continue looping
 579                         }
 580                         last if $ok;
 581                         my $last = pop @or;
 582                         $err = join(', ', @or) . " or $last must be set";
 583                 } else {
 584                         warn "BUG: can't parse `$var' in $proto";
 585                 }
 586                 last if $err;
 587         }
 588         if (!$inf && scalar(@$argv) > scalar(@args)) {
 589                 $err //= 'too many arguments';
 590         }
 591         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 592 }
 593
 594 sub _tmp_cfg { # for lei -c <name>=<value> ...
 595         my ($self) = @_;
 596         my $cfg = _lei_cfg($self, 1);
 597         require File::Temp;
 598         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 599         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 600         $ft->autoflush(1);
 601         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 602 [include]
 603         path = $cfg->{-f}
 604 EOM
 605         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 606         for (@{$self->{opt}->{c}}) {
 607                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 608 `-c $_' is not of the form -c <name>=<value>'
 609 EOM
 610                 my $name = $1;
 611                 my $value = $2 // 1;
 612                 _config($self, '--add', $name, $value);
 613                 if (defined(my $v = $tmp->{$name})) {
 614                         if (ref($v) eq 'ARRAY') {
 615                                 push @$v, $value;
 616                         } else {
 617                                 $tmp->{$name} = [ $v, $value ];
 618                         }
 619                 } else {
 620                         $tmp->{$name} = $value;
 621                 }
 622         }
 623 }
 624
 625 sub lazy_cb ($$$) {
 626         my ($self, $cmd, $pfx) = @_;
 627         my $ucmd = $cmd;
 628         $ucmd =~ tr/-/_/;
 629         my $cb;
 630         $cb = $self->can($pfx.$ucmd) and return $cb;
 631         my $base = $ucmd;
 632         $base =~ s/_([a-z])/\u$1/g;
 633         my $pkg = "PublicInbox::Lei\u$base";
 634         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 635                 $pkg->can($pfx.$ucmd) : undef;
 636 }
 637
 638 sub dispatch {
 639         my ($self, $cmd, @argv) = @_;
 640         local $current_lei = $self; # for __WARN__
 641         dump_and_clear_log("from previous run\n");
 642         return _help($self, 'no command given') unless defined($cmd);
 643         # do not support Getopt bundling for this
 644         while ($cmd eq '-C' || $cmd eq '-c') {
 645                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 646                                         '-C DIRECTORY' : '-c <name>=<value>');
 647                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 648                 $cmd = shift(@argv) // return _help($self, 'no command given');
 649         }
 650         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 651                 optparse($self, $cmd, \@argv) or return;
 652                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 653                 if (my $chdir = $self->{opt}->{C}) {
 654                         for my $d (@$chdir) {
 655                                 next if $d eq ''; # same as git(1)
 656                                 chdir $d or return fail($self, "cd $d: $!");
 657                         }
 658                         if (delete $self->{3}) { # update cwd for rel2abs
 659                                 opendir my $dh, '.' or
 660                                         return fail($self, "opendir . $!");
 661                                 $self->{3} = $dh;
 662                         }
 663                 }
 664                 $cb->($self, @argv);
 665         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 666                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 667                         or return _help($self, 'bad arguments or options');
 668                 _help($self);
 669         } else {
 670                 fail($self, "`$cmd' is not an lei command");
 671         }
 672 }
 673
 674 sub _lei_cfg ($;$) {
 675         my ($self, $creat) = @_;
 676         return $self->{cfg} if $self->{cfg};
 677         my $f = _config_path($self);
 678         my @st = stat($f);
 679         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 680         my ($sto, $sto_dir);
 681         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 682                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 683                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 684         }
 685         if (!@st) {
 686                 unless ($creat) {
 687                         delete $self->{cfg};
 688                         return bless {}, 'PublicInbox::Config';
 689                 }
 690                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 691                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 692                 open my $fh, '>>', $f or die "open($f): $!\n";
 693                 @st = stat($fh) or die "fstat($f): $!\n";
 694                 $cur_st = pack('dd', $st[10], $st[7]);
 695                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 696         }
 697         my $cfg = PublicInbox::Config::git_config_dump($f);
 698         bless $cfg, 'PublicInbox::Config';
 699         $cfg->{-st} = $cur_st;
 700         $cfg->{'-f'} = $f;
 701         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 702                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 703                                                 store_path($self))) {
 704                 $cfg->{-lei_store} = $sto;
 705         }
 706         if (scalar(keys %PATH2CFG) > 5) {
 707                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 708                 for my $k (keys %PATH2CFG) {
 709                         delete($PATH2CFG{$k}) unless -f $k
 710                 }
 711         }
 712         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 713 }
 714
 715 sub _lei_store ($;$) {
 716         my ($self, $creat) = @_;
 717         my $cfg = _lei_cfg($self, $creat);
 718         $cfg->{-lei_store} //= do {
 719                 require PublicInbox::LeiStore;
 720                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 721                 return unless $creat || -d $dir;
 722                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 723         };
 724 }
 725
 726 sub _config {
 727         my ($self, @argv) = @_;
 728         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 729         my $cfg = _lei_cfg($self, 1);
 730         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 731         my %rdr = map { $_ => $self->{$_} } (0..2);
 732         waitpid(spawn($cmd, \%env, \%rdr), 0);
 733 }
 734
 735 sub lei_config {
 736         my ($self, @argv) = @_;
 737         $self->{opt}->{'config-file'} and return fail $self,
 738                 "config file switches not supported by `lei config'";
 739         _config(@_);
 740         x_it($self, $?) if $?;
 741 }
 742
 743 sub lei_daemon_pid { puts shift, $$ }
 744
 745 sub lei_daemon_kill {
 746         my ($self) = @_;
 747         my $sig = $self->{opt}->{signal} // 'TERM';
 748         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 749 }
 750
 751 # Shell completion helper.  Used by lei-completion.bash and hopefully
 752 # other shells.  Try to do as much here as possible to avoid redundancy
 753 # and improve maintainability.
 754 sub lei__complete {
 755         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 756         shift @argv; # ignore "lei", the entire command is sent
 757         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 758         my $cmd = shift @argv;
 759         my $info = $CMD{$cmd} // do { # filter matching commands
 760                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 761                 return;
 762         };
 763         my ($proto, undef, @spec) = @$info;
 764         my $cur = pop @argv;
 765         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 766         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 767                 # gross special case since the only git-config options
 768                 # Consider moving to a table if we need more special cases
 769                 # we use Getopt::Long for are the ones we reject, so these
 770                 # are the ones we don't reject:
 771                 if ($cmd eq 'config') {
 772                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 773                         @spec = qw(add z|null get get-all unset unset-all
 774                                 replace-all get-urlmatch
 775                                 remove-section rename-section
 776                                 name-only list|l edit|e
 777                                 get-color-name get-colorbool);
 778                         # fall-through
 779                 }
 780                 # generate short/long names from Getopt::Long specs
 781                 puts $self, grep(/$re/, qw(--help -h -C), map {
 782                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 783                         } elsif (s/\+\z//) { # verbose|v+
 784                         } elsif (s/!\z//) {
 785                                 # negation: mail! => no-mail|mail
 786                                 s/([\w\-]+)/$1|no-$1/g
 787                         }
 788                         map {
 789                                 my $x = length > 1 ? "--$_" : "-$_";
 790                                 $x eq $_cur ? () : $x;
 791                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 792                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 793         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 794                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 795         }
 796
 797         # switch args (e.g. lei q -f mbox<TAB>)
 798         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 799                 my $opt = quotemeta $1;
 800                 puts $self, map {
 801                         my $v = $OPTDESC{$_};
 802                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 803                         # get rid of ALL CAPS placeholder (e.g "OUT")
 804                         # (TODO: completion for external paths)
 805                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 806                         @v;
 807                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 808         }
 809         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 810                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 811         }
 812         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 813         # proto parsing.
 814 }
 815
 816 sub exec_buf ($$) {
 817         my ($argv, $env) = @_;
 818         my $argc = scalar @$argv;
 819         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 820         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 821         $buf;
 822 }
 823
 824 sub start_mua {
 825         my ($self) = @_;
 826         my $mua = $self->{opt}->{mua} // return;
 827         my $mfolder = $self->{ovv}->{dst};
 828         my (@cmd, $replaced);
 829         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 830                 @cmd = ($mua, '-f');
 831         # TODO: help wanted: other common FOSS MUAs
 832         } else {
 833                 require Text::ParseWords;
 834                 @cmd = Text::ParseWords::shellwords($mua);
 835                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 836                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 837         }
 838         push @cmd, $mfolder unless defined($replaced);
 839         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 840                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 841         } elsif ($self->{oneshot}) {
 842                 $self->{"pid.$self.$$"}->{spawn(\@cmd)} = \@cmd;
 843         }
 844         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 845                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 846         }
 847         $self->{opt}->{quiet} = 1;
 848         delete $self->{-progress};
 849         delete $self->{opt}->{verbose};
 850 }
 851
 852 sub send_exec_cmd { # tell script/lei to execute a command
 853         my ($self, $io, $cmd, $env) = @_;
 854         my $sock = $self->{sock} // die 'lei client gone';
 855         my $fds = [ map { fileno($_) } @$io ];
 856         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 857 }
 858
 859 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 860         my ($self) = @_;
 861         my $alerts = $self->{opt}->{alert} // return;
 862         while (my $op = shift(@$alerts)) {
 863                 if ($op eq ':WINCH') {
 864                         # hit the process group that started the MUA
 865                         if ($self->{sock}) {
 866                                 send($self->{sock}, '-WINCH', MSG_EOR);
 867                         } elsif ($self->{oneshot}) {
 868                                 kill('-WINCH', $$);
 869                         }
 870                 } elsif ($op eq ':bell') {
 871                         out($self, "\a");
 872                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 873                         push @$alerts, split(/(?<!\\),/, $op);
 874                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 875                         my $cmd = $1; # run an arbitrary command
 876                         require Text::ParseWords;
 877                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 878                         if (my $s = $self->{sock}) {
 879                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 880                         } elsif ($self->{oneshot}) {
 881                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 882                         }
 883                 } else {
 884                         err($self, "W: unsupported --alert=$op"); # non-fatal
 885                 }
 886         }
 887 }
 888
 889 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 890 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 891
 892 # this also normalizes the path
 893 sub path_to_fd {
 894         my ($self, $path) = @_;
 895         $path = rel2abs($self, $path);
 896         $path =~ tr!/!/!s;
 897         $path_to_fd{$path} // (
 898                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 899                         fail($self, "cannot open $path from daemon") : -1
 900         );
 901 }
 902
 903 # caller needs to "-t $self->{1}" to check if tty
 904 sub start_pager {
 905         my ($self) = @_;
 906         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 907         chomp(my $pager = <$fh> // '');
 908         close($fh) or warn "`git var PAGER' error: \$?=$?";
 909         return if $pager eq 'cat' || $pager eq '';
 910         my $new_env = { LESS => 'FRX', LV => '-c' };
 911         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 912         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 913         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 914         my $pgr = [ undef, @$rdr{1, 2} ];
 915         my $env = $self->{env};
 916         if ($self->{sock}) { # lei(1) process runs it
 917                 delete @$new_env{keys %$env}; # only set iff unset
 918                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 919         } elsif ($self->{oneshot}) {
 920                 my $cmd = [$pager];
 921                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 922         } else {
 923                 die 'BUG: start_pager w/o socket';
 924         }
 925         $self->{1} = $wpager;
 926         $self->{2} = $wpager if -t $self->{2};
 927         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 928         $self->{pgr} = $pgr;
 929 }
 930
 931 sub stop_pager {
 932         my ($self) = @_;
 933         my $pgr = delete($self->{pgr}) or return;
 934         $self->{2} = $pgr->[2];
 935         # do not restore original stdout, just close it so we error out
 936         close(delete($self->{1})) if $self->{1};
 937 }
 938
 939 sub accept_dispatch { # Listener {post_accept} callback
 940         my ($sock) = @_; # ignore other
 941         $sock->autoflush(1);
 942         my $self = bless { sock => $sock }, __PACKAGE__;
 943         vec(my $rvec = '', fileno($sock), 1) = 1;
 944         select($rvec, undef, undef, 60) or
 945                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 946         # (4096 * 33) >MAX_ARG_STRLEN
 947         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
 948         if (!defined($fds[0])) {
 949                 warn(my $msg = "recv_cmd failed: $!");
 950                 return send($sock, $msg, MSG_EOR);
 951         } else {
 952                 my $i = 0;
 953                 for my $fd (@fds) {
 954                         open($self->{$i++}, '+<&=', $fd) and next;
 955                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 956                 }
 957                 return if scalar(@fds) != 4;
 958         }
 959         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 960         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 961         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 962         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 963                 return send($sock, 'request command truncated', MSG_EOR);
 964         my ($argc, @argv) = split(/\0/, $buf, -1);
 965         undef $buf;
 966         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 967         if (chdir($self->{3})) {
 968                 local %ENV = %env;
 969                 $self->{env} = \%env;
 970                 eval { dispatch($self, @argv) };
 971                 send($sock, $@, MSG_EOR) if $@;
 972         } else {
 973                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 974         }
 975 }
 976
 977 sub dclose {
 978         my ($self) = @_;
 979         delete $self->{-progress};
 980         for my $f (@WQ_KEYS) {
 981                 my $wq = delete $self->{$f} or next;
 982                 if ($wq->wq_kill) {
 983                         $wq->wq_close(0, undef, $self);
 984                 } elsif ($wq->wq_kill_old) {
 985                         $wq->wq_wait_old(undef, $self);
 986                 }
 987         }
 988         close(delete $self->{1}) if $self->{1}; # may reap_compress
 989         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
 990 }
 991
 992 # for long-running results
 993 sub event_step {
 994         my ($self) = @_;
 995         local %ENV = %{$self->{env}};
 996         my $sock = $self->{sock};
 997         local $current_lei = $self;
 998         eval {
 999                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1000                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1001                                 return if $! == EAGAIN;
1002                                 next if $! == EINTR;
1003                                 last if $! == ECONNRESET;
1004                                 die "recvmsg: $!";
1005                         }
1006                         for my $fd (@fds) {
1007                                 open my $rfh, '+<&=', $fd;
1008                         }
1009                         die "unrecognized client signal: $buf";
1010                 }
1011                 dclose($self);
1012         };
1013         if (my $err = $@) {
1014                 eval { $self->fail($err) };
1015                 dclose($self);
1016         }
1017 }
1018
1019 sub event_step_init {
1020         my ($self) = @_;
1021         return if $self->{-event_init_done}++;
1022         if (my $sock = $self->{sock}) { # using DS->EventLoop
1023                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1024         }
1025 }
1026
1027 sub noop {}
1028
1029 sub oldset { $oldset }
1030
1031 sub dump_and_clear_log {
1032         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1033                 my @pfx = @_;
1034                 unshift(@pfx, "$errors_log ") if @pfx;
1035                 warn @pfx, do { local $/; <STDIN> };
1036                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1037         }
1038 }
1039
1040 # lei(1) calls this when it can't connect
1041 sub lazy_start {
1042         my ($path, $errno, $narg) = @_;
1043         local ($errors_log, $listener);
1044         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1045         $errors_log .= 'errors.log';
1046         my $addr = pack_sockaddr_un($path);
1047         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1048         $lk->lock_acquire;
1049         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1050         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1051                 return if connect($listener, $addr); # another process won
1052                 if ($errno == ECONNREFUSED && -S $path) {
1053                         unlink($path) or die "unlink($path): $!";
1054                 }
1055         } else {
1056                 $! = $errno; # allow interpolation to stringify in die
1057                 die "connect($path): $!";
1058         }
1059         umask(077) // die("umask(077): $!");
1060         bind($listener, $addr) or die "bind($path): $!";
1061         listen($listener, 1024) or die "listen: $!";
1062         $lk->lock_release;
1063         undef $lk;
1064         my @st = stat($path) or die "stat($path): $!";
1065         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1066         local $oldset = PublicInbox::DS::block_signals();
1067         if ($narg == 5) {
1068                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1069                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1070                         require PublicInbox::CmdIPC4;
1071                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1072                         PublicInbox::CmdIPC4->can('recv_cmd4');
1073                 };
1074         }
1075         $recv_cmd or die <<"";
1076 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1077
1078         require PublicInbox::Listener;
1079         require PublicInbox::EOFpipe;
1080         (-p STDOUT) or die "E: stdout must be a pipe\n";
1081         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1082         STDIN->autoflush(1);
1083         dump_and_clear_log("from previous daemon process:\n");
1084         POSIX::setsid() > 0 or die "setsid: $!";
1085         my $pid = fork // die "fork: $!";
1086         return if $pid;
1087         $0 = "lei-daemon $path";
1088         local %PATH2CFG;
1089         $listener->blocking(0);
1090         my $exit_code;
1091         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1092         local $quit = do {
1093                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1094                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1095                 sub {
1096                         $exit_code //= shift;
1097                         my $lis = $pil or exit($exit_code);
1098                         # closing eof_w triggers \&noop wakeup
1099                         $listener = $eof_w = $pil = $path = undef;
1100                         $lis->close; # DS::close
1101                         PublicInbox::DS->SetLoopTimeout(1000);
1102                 };
1103         };
1104         my $sig = {
1105                 CHLD => \&PublicInbox::DS::enqueue_reap,
1106                 QUIT => $quit,
1107                 INT => $quit,
1108                 TERM => $quit,
1109                 HUP => \&noop,
1110                 USR1 => \&noop,
1111                 USR2 => \&noop,
1112         };
1113         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1114         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1115         undef $sig;
1116         local $SIG{PIPE} = 'IGNORE';
1117         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1118                 undef $sigfd;
1119                 PublicInbox::DS->SetLoopTimeout(5000);
1120         } else {
1121                 # wake up every second to accept signals if we don't
1122                 # have signalfd or IO::KQueue:
1123                 PublicInbox::DS::sig_setmask($oldset);
1124                 PublicInbox::DS->SetLoopTimeout(1000);
1125         }
1126         PublicInbox::DS->SetPostLoopCallback(sub {
1127                 my ($dmap, undef) = @_;
1128                 if (@st = defined($path) ? stat($path) : ()) {
1129                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1130                                 warn "$path dev/ino changed, quitting\n";
1131                                 $path = undef;
1132                         }
1133                 } elsif (defined($path)) { # ENOENT is common
1134                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1135                         undef $path;
1136                         $quit->();
1137                 }
1138                 return 1 if defined($path);
1139                 my $now = now();
1140                 my $n = 0;
1141                 for my $s (values %$dmap) {
1142                         $s->can('busy') or next;
1143                         if ($s->busy($now)) {
1144                                 ++$n;
1145                         } else {
1146                                 $s->close;
1147                         }
1148                 }
1149                 $n; # true: continue, false: stop
1150         });
1151
1152         # STDIN was redirected to /dev/null above, closing STDERR and
1153         # STDOUT will cause the calling `lei' client process to finish
1154         # reading the <$daemon> pipe.
1155         local $SIG{__WARN__} = sub {
1156                 $current_lei ? err($current_lei, @_) : warn(
1157                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1158         };
1159         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1160         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1161         # $daemon pipe to `lei' closed, main loop begins:
1162         PublicInbox::DS->EventLoop;
1163         exit($exit_code // 0);
1164 }
1165
1166 sub busy { 1 } # prevent daemon-shutdown if client is connected
1167
1168 # for users w/o Socket::Msghdr installed or Inline::C enabled
1169 sub oneshot {
1170         my ($main_pkg) = @_;
1171         my $exit = $main_pkg->can('exit'); # caller may override exit()
1172         local $quit = $exit if $exit;
1173         local %PATH2CFG;
1174         umask(077) // die("umask(077): $!");
1175         my $self = bless {
1176                 oneshot => 1,
1177                 0 => *STDIN{GLOB},
1178                 1 => *STDOUT{GLOB},
1179                 2 => *STDERR{GLOB},
1180                 env => \%ENV
1181         }, __PACKAGE__;
1182         dispatch($self, @ARGV);
1183         x_it($self, $self->{child_error}) if $self->{child_error};
1184 }
1185
1186 # ensures stdout hits the FS before sock disconnects so a client
1187 # can immediately reread it
1188 sub DESTROY {
1189         my ($self) = @_;
1190         $self->{1}->autoflush(1) if $self->{1};
1191         stop_pager($self);
1192         my $err = $?;
1193         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1194         waitpid($_, 0) for keys %$oneshot_pids;
1195         $? = $err if $err; # preserve ->fail or ->x_it code
1196 }
1197
1198 1;