lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS);
  12 use Getopt::Long ();
  13 use Socket qw(AF_UNIX SOCK_STREAM pack_sockaddr_un);
  14 use Errno qw(EAGAIN ECONNREFUSED ENOENT);
  15 use POSIX ();
  16 use IO::Handle ();
  17 use Sys::Syslog qw(syslog openlog);
  18 use PublicInbox::Config;
  19 use PublicInbox::Syscall qw($SFD_NONBLOCK EPOLLIN EPOLLONESHOT);
  20 use PublicInbox::Sigfd;
  21 use PublicInbox::DS qw(now);
  22 use PublicInbox::Spawn qw(spawn);
  23 use PublicInbox::OnDestroy;
  24 use Text::Wrap qw(wrap);
  25 use File::Path qw(mkpath);
  26 use File::Spec;
  27 our $quit = \&CORE::exit;
  28 my $GLP = Getopt::Long::Parser->new;
  29 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  30 my $GLP_PASS = Getopt::Long::Parser->new;
  31 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  32
  33 our %PATH2CFG; # persistent for socket daemon
  34
  35 # TBD: this is a documentation mechanism to show a subcommand
  36 # (may) pass options through to another command:
  37 sub pass_through { $GLP_PASS }
  38
  39 sub _store_path ($) {
  40         my ($env) = @_;
  41         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  42                 ($env->{HOME} // '/nonexistent').'/.local/share')
  43                 .'/lei/store', $env->{PWD});
  44 }
  45
  46 sub _config_path ($) {
  47         my ($env) = @_;
  48         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  49                 ($env->{HOME} // '/nonexistent').'/.config')
  50                 .'/lei/config', $env->{PWD});
  51 }
  52
  53 # TODO: generate shell completion + help using %CMD and %OPTDESC
  54 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  55 our %CMD = ( # sorted in order of importance/use:
  56 'query' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  57         save-as=s output|o=s format|f=s dedupe|d=s thread|t augment|a
  58         limit|n=i sort|s=s@ reverse|r offset=i remote local! extinbox!
  59         since|after=s until|before=s) ],
  60
  61 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  62         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  63         pass_through('git show') ],
  64
  65 'add-extinbox' => [ 'URL_OR_PATHNAME',
  66         'add/set priority of a publicinbox|extindex for extra matches',
  67         qw(prio=i) ],
  68 'ls-extinbox' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  69         qw(format|f=s z local remote) ],
  70 'forget-extinbox' => [ '{URL_OR_PATHNAME|--prune}',
  71         'exclude further results from a publicinbox|extindex',
  72         qw(prune) ],
  73
  74 'ls-query' => [ '[FILTER...]', 'list saved search queries',
  75                 qw(name-only format|f=s z) ],
  76 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
  77 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
  78
  79 'plonk' => [ '--thread|--from=IDENT',
  80         'exclude mail matching From: or thread from non-Message-ID searches',
  81         qw(stdin| thread|t from|f=s mid=s oid=s) ],
  82 'mark' => [ 'MESSAGE_FLAGS...',
  83         'set/unset flags on message(s) from stdin',
  84         qw(stdin| oid=s exact by-mid|mid:s) ],
  85 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
  86         'exclude message(s) on stdin from query results',
  87         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
  88
  89 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
  90         'remove imported messages from IMAP, Maildirs, and MH',
  91         qw(exact! all jobs:i indexed) ],
  92
  93 # code repos are used for `show' to solve blobs from patch mails
  94 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
  95         qw(prio=i) ],
  96 'ls-coderepo' => [ '[FILTER_TERMS...]',
  97                 'list known code repos', qw(format|f=s z) ],
  98 'forget-coderepo' => [ 'PATHNAME',
  99         'stop using repo to solve blobs from patches',
 100         qw(prune) ],
 101
 102 'add-watch' => [ '[URL_OR_PATHNAME]',
 103                 'watch for new messages and flag changes',
 104         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 105 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 106                 qw(format|f=s z) ],
 107 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 108 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 109 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 110         qw(prune) ],
 111
 112 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 113         'one-shot import/update from URL or filesystem',
 114         qw(stdin| limit|n=i offset=i recursive|r exclude=s include=s !flags),
 115         ],
 116
 117 'config' => [ '[...]', sub {
 118                 'git-config(1) wrapper for '._config_path($_[0]);
 119         }, qw(config-file|system|global|file|f=s), # for conflict detection
 120         pass_through('git config') ],
 121 'init' => [ '[PATHNAME]', sub {
 122                 'initialize storage, default: '._store_path($_[0]);
 123         }, qw(quiet|q) ],
 124 'daemon-stop' => [ '', 'stop the lei-daemon' ],
 125 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 126 'daemon-env' => [ '[NAME=VALUE...]', 'set, unset, or show daemon environment',
 127         qw(clear| unset|u=s@ z|0) ],
 128 'help' => [ '[SUBCOMMAND]', 'show help' ],
 129
 130 # XXX do we need this?
 131 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 132
 133 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 134         'rewrite git history in an attempt to improve compression',
 135         'gc!' ],
 136
 137 # internal commands are prefixed with '_'
 138 '_complete' => [ '[...]', 'internal shell completion helper',
 139                 pass_through('everything') ],
 140 ); # @CMD
 141
 142 # switch descriptions, try to keep consistent across commands
 143 # $spec: Getopt::Long option specification
 144 # $spec => [@ALLOWED_VALUES (default is first), $description],
 145 # $spec => $description
 146 # "$SUB_COMMAND TAB $spec" => as above
 147 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 148                 'specify message input format' ];
 149 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 150
 151 my %OPTDESC = (
 152 'help|h' => 'show this built-in help',
 153 'quiet|q' => 'be quiet',
 154 'solve!' => 'do not attempt to reconstruct blobs from emails',
 155 'save-as=s' => ['NAME', 'save a search terms by given name'],
 156
 157 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 158
 159 'dedupe|d=s' => ['STRAT|content|oid|mid',
 160                 'deduplication strategy'],
 161 'show   thread|t' => 'display entire thread a message belongs to',
 162 'query  thread|t' =>
 163         'return all messages in the same thread as the actual match(es)',
 164 'augment|a' => 'augment --output destination instead of clobbering',
 165
 166 'output|o=s' => [ 'DEST',
 167         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 168
 169 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 170                         'message/object output format' ],
 171 'mark   format|f=s' => $stdin_formats,
 172 'forget format|f=s' => $stdin_formats,
 173 'query  format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid',
 174                 'specify output format, default depends on --output'],
 175 'ls-query       format|f=s' => $ls_format,
 176 'ls-extinbox    format|f=s' => $ls_format,
 177
 178 'limit|n=i' => ['NUM',
 179         'limit on number of matches (default: 10000)' ],
 180 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 181
 182 'sort|s=s@' => [ 'VAL|internaldate,date,relevance,docid',
 183                 "order of results `--output'-dependent"],
 184
 185 'prio=i' => 'priority of query source',
 186
 187 'local' => 'limit operations to the local filesystem',
 188 'local!' => 'exclude results from the local filesystem',
 189 'remote' => 'limit operations to those requiring network access',
 190 'remote!' => 'prevent operations requiring network access',
 191
 192 'mid=s' => 'specify the Message-ID of a message',
 193 'oid=s' => 'specify the git object ID of a message',
 194
 195 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 196 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 197 'include=s' => 'include mailboxes/newsgroups based on pattern',
 198
 199 'exact' => 'operate on exact header matches only',
 200 'exact!' => 'rely on content match instead of exact header matches',
 201
 202 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 203 'jobs:i' => 'set parallelism level',
 204
 205 # xargs, env, use "-0", git(1) uses "-z".  Should we support z|0 everywhere?
 206 'z' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 207 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 208
 209 # note: no "--ignore-environment" / "-i" support like env(1) since that
 210 # is one-shot and this is for a persistent daemon:
 211 'clear|' => 'clear the daemon environment',
 212 'unset|u=s@' => ['NAME',
 213         'unset matching NAME, may be specified multiple times'],
 214 ); # %OPTDESC
 215
 216 my %CONFIG_KEYS = (
 217         'leistore.dir' => 'top-level storage location',
 218 );
 219
 220 sub x_it ($$) { # pronounced "exit"
 221         my ($self, $code) = @_;
 222         if (my $sig = ($code & 127)) {
 223                 kill($sig, $self->{pid} // $$);
 224         } else {
 225                 $code >>= 8;
 226                 if (my $sock = $self->{sock}) {
 227                         say $sock "exit=$code";
 228                 } else { # for oneshot
 229                         $quit->($code);
 230                 }
 231         }
 232 }
 233
 234 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 235
 236 sub emit {
 237         my ($self, $channel) = @_; # $buf = $_[2]
 238         print { $self->{$channel} } $_[2] or die "print FD[$channel]: $!";
 239 }
 240
 241 sub err {
 242         my ($self, $buf) = @_;
 243         $buf .= "\n" unless $buf =~ /\n\z/s;
 244         emit($self, 2, $buf);
 245 }
 246
 247 sub qerr { $_[0]->{opt}->{quiet} or err(@_) }
 248
 249 sub fail ($$;$) {
 250         my ($self, $buf, $exit_code) = @_;
 251         err($self, $buf);
 252         x_it($self, ($exit_code // 1) << 8);
 253         undef;
 254 }
 255
 256 sub _help ($;$) {
 257         my ($self, $errmsg) = @_;
 258         my $cmd = $self->{cmd} // 'COMMAND';
 259         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 260         my @top = ($cmd, shift(@info) // ());
 261         my $cmd_desc = shift(@info);
 262         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 263         my @opt_desc;
 264         my $lpad = 2;
 265         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 266                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 267                 my $arg_vals = '';
 268                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 269
 270                 # lower-case is a keyword (e.g. `content', `oid'),
 271                 # ALL_CAPS is a string description (e.g. `PATH')
 272                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 273                         $desc .= "\ndefault: `$1'";
 274                 }
 275                 my (@vals, @s, @l);
 276                 my $x = $sw;
 277                 if ($x =~ s/!\z//) { # solve! => --no-solve
 278                         $x = "no-$x";
 279                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 280                         @vals = (' [', undef, ']');
 281                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 282                         @vals = (' ', undef);
 283                 } # else: no args $x = 'thread|t'
 284                 for (split(/\|/, $x)) { # help|h
 285                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 286                 }
 287                 if (!scalar(@vals)) { # no args 'thread|t'
 288                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 289                         $vals[1] = $1;
 290                 } else {
 291                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 292                 }
 293                 if ($arg_vals =~ /([,\|])/) {
 294                         my $sep = $1;
 295                         my @allow = split(/\Q$sep\E/, $arg_vals);
 296                         my $must = $sep eq '|' ? 'Must' : 'Can';
 297                         @allow = map { "`$_'" } @allow;
 298                         my $last = pop @allow;
 299                         $desc .= "\n$must be one of: " .
 300                                 join(', ', @allow) . " or $last";
 301                 }
 302                 my $lhs = join(', ', @s, @l) . join('', @vals);
 303                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 304                         $lhs =~ s/\A--/- , --/;
 305                 } else {
 306                         $lhs =~ s/\A--/    --/; # pad if no short options
 307                 }
 308                 $lpad = length($lhs) if length($lhs) > $lpad;
 309                 push @opt_desc, $lhs, $desc;
 310         }
 311         my $msg = $errmsg ? "E: $errmsg\n" : '';
 312         $msg .= <<EOF;
 313 usage: lei @top
 314   $cmd_desc
 315
 316 EOF
 317         $lpad += 2;
 318         local $Text::Wrap::columns = 78 - $lpad;
 319         my $padding = ' ' x ($lpad + 2);
 320         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 321                 $msg .= '  '.pack("A$lpad", $lhs);
 322                 $rhs = wrap('', '', $rhs);
 323                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 324                 $msg .= $rhs;
 325                 $msg .= "\n";
 326         }
 327         my $channel = $errmsg ? 2 : 1;
 328         emit($self, $channel, $msg);
 329         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 330         undef;
 331 }
 332
 333 sub optparse ($$$) {
 334         my ($self, $cmd, $argv) = @_;
 335         $self->{cmd} = $cmd;
 336         my $opt = $self->{opt} = {};
 337         my $info = $CMD{$cmd} // [ '[...]' ];
 338         my ($proto, undef, @spec) = @$info;
 339         my $glp = ref($spec[-1]) ? pop(@spec) : $GLP; # or $GLP_PASS
 340         push @spec, qw(help|h);
 341         my $lone_dash;
 342         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 343                 $lone_dash = $spec[0];
 344                 $opt->{$spec[0]} = \(my $var);
 345                 push @spec, '' => \$var;
 346         }
 347         $glp->getoptionsfromarray($argv, $opt, @spec) or
 348                 return _help($self, "bad arguments or options for $cmd");
 349         return _help($self) if $opt->{help};
 350
 351         # "-" aliases "stdin" or "clear"
 352         $opt->{$lone_dash} = ${$opt->{$lone_dash}} if defined $lone_dash;
 353
 354         my $i = 0;
 355         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 356         my ($err, $inf);
 357         my @args = split(/ /, $proto);
 358         for my $var (@args) {
 359                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 360                         $inf = defined($argv->[$i]) and last;
 361                         $var =~ s/\.\.\.\z//;
 362                         $err = "$var not supplied";
 363                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 364                         $argv->[$i++] // ($err = "$var not supplied");
 365                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 366                         $inf = 1;
 367                         last;
 368                 } elsif ($var =~ /\A\[$POS_ARG\]\z/) { # one optional arg
 369                         $i++;
 370                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 371                         my @or = split(/\|/, $var);
 372                         my $ok;
 373                         for my $o (@or) {
 374                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 375                                         $ok = defined($opt->{$1});
 376                                         last;
 377                                 } elsif (defined($argv->[$i])) {
 378                                         $ok = 1;
 379                                         $i++;
 380                                         last;
 381                                 } # else continue looping
 382                         }
 383                         my $last = pop @or;
 384                         $err = join(', ', @or) . " or $last must be set";
 385                 } else {
 386                         warn "BUG: can't parse `$var' in $proto";
 387                 }
 388                 last if $err;
 389         }
 390         # warn "inf=$inf ".scalar(@$argv). ' '.scalar(@args)."\n";
 391         if (!$inf && scalar(@$argv) > scalar(@args)) {
 392                 $err //= 'too many arguments';
 393         }
 394         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 395 }
 396
 397 sub dispatch {
 398         my ($self, $cmd, @argv) = @_;
 399         local $SIG{__WARN__} = sub { err($self, "@_") };
 400         return _help($self, 'no command given') unless defined($cmd);
 401         my $func = "lei_$cmd";
 402         $func =~ tr/-/_/;
 403         if (my $cb = __PACKAGE__->can($func)) {
 404                 optparse($self, $cmd, \@argv) or return;
 405                 $cb->($self, @argv);
 406         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 407                 my $opt = {};
 408                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 409                         return _help($self, 'bad arguments or options');
 410                 _help($self);
 411         } else {
 412                 fail($self, "`$cmd' is not an lei command");
 413         }
 414 }
 415
 416 sub _lei_cfg ($;$) {
 417         my ($self, $creat) = @_;
 418         my $f = _config_path($self->{env});
 419         my @st = stat($f);
 420         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 421         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 422                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 423         }
 424         if (!@st) {
 425                 unless ($creat) {
 426                         delete $self->{cfg};
 427                         return;
 428                 }
 429                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 430                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 431                 open my $fh, '>>', $f or die "open($f): $!\n";
 432                 @st = stat($fh) or die "fstat($f): $!\n";
 433                 $cur_st = pack('dd', $st[10], $st[7]);
 434                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 435         }
 436         my $cfg = PublicInbox::Config::git_config_dump($f);
 437         $cfg->{-st} = $cur_st;
 438         $cfg->{'-f'} = $f;
 439         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 440 }
 441
 442 sub _lei_store ($;$) {
 443         my ($self, $creat) = @_;
 444         my $cfg = _lei_cfg($self, $creat);
 445         $cfg->{-lei_store} //= do {
 446                 require PublicInbox::LeiStore;
 447                 PublicInbox::SearchIdx::load_xapian_writable();
 448                 defined(my $dir = $cfg->{'leistore.dir'}) or return;
 449                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 450         };
 451 }
 452
 453 sub lei_show {
 454         my ($self, @argv) = @_;
 455 }
 456
 457 sub lei_query {
 458         my ($self, @argv) = @_;
 459 }
 460
 461 sub lei_mark {
 462         my ($self, @argv) = @_;
 463 }
 464
 465 sub lei_config {
 466         my ($self, @argv) = @_;
 467         $self->{opt}->{'config-file'} and return fail $self,
 468                 "config file switches not supported by `lei config'";
 469         my $env = $self->{env};
 470         delete local $env->{GIT_CONFIG};
 471         my $cfg = _lei_cfg($self, 1);
 472         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 473         my %rdr = map { $_ => $self->{$_} } (0..2);
 474         require PublicInbox::Import;
 475         PublicInbox::Import::run_die($cmd, $env, \%rdr);
 476 }
 477
 478 sub lei_init {
 479         my ($self, $dir) = @_;
 480         my $cfg = _lei_cfg($self, 1);
 481         my $cur = $cfg->{'leistore.dir'};
 482         my $env = $self->{env};
 483         $dir //= _store_path($env);
 484         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 485         my @cur = stat($cur) if defined($cur);
 486         $cur = File::Spec->canonpath($cur) if $cur;
 487         my @dir = stat($dir);
 488         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 489         if (@cur) {
 490                 if ($cur eq $dir) {
 491                         _lei_store($self, 1)->done;
 492                         return qerr($self, $exists);
 493                 }
 494
 495                 # some folks like symlinks and bind mounts :P
 496                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 497                         lei_config($self, 'leistore.dir', $dir);
 498                         _lei_store($self, 1)->done;
 499                         return qerr($self, "$exists (as $cur)");
 500                 }
 501                 return fail($self, <<"");
 502 E: leistore.dir=$cur already initialized and it is not $dir
 503
 504         }
 505         lei_config($self, 'leistore.dir', $dir);
 506         _lei_store($self, 1)->done;
 507         $exists //= "I: leistore.dir=$dir newly initialized";
 508         return qerr($self, $exists);
 509 }
 510
 511 sub lei_daemon_pid { emit($_[0], 1, "$$\n") }
 512
 513 sub lei_daemon_stop { $quit->(0) }
 514
 515 sub lei_daemon_env {
 516         my ($self, @argv) = @_;
 517         my $opt = $self->{opt};
 518         if (defined $opt->{clear}) {
 519                 %ENV = ();
 520         } elsif (my $u = $opt->{unset}) {
 521                 delete @ENV{@$u};
 522         }
 523         if (@argv) {
 524                 %ENV = (%ENV, map { split(/=/, $_, 2) } @argv);
 525         } elsif (!defined($opt->{clear}) && !$opt->{unset}) {
 526                 my $eor = $opt->{z} ? "\0" : "\n";
 527                 my $buf = '';
 528                 while (my ($k, $v) = each %ENV) { $buf .= "$k=$v$eor" }
 529                 emit($self, 1, $buf)
 530         }
 531 }
 532
 533 sub lei_help { _help($_[0]) }
 534
 535 # Shell completion helper.  Used by lei-completion.bash and hopefully
 536 # other shells.  Try to do as much here as possible to avoid redundancy
 537 # and improve maintainability.
 538 sub lei__complete {
 539         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 540         shift @argv; # ignore "lei", the entire command is sent
 541         @argv or return puts $self, grep(!/^_/, keys %CMD);
 542         my $cmd = shift @argv;
 543         my $info = $CMD{$cmd} // do { # filter matching commands
 544                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 545                 return;
 546         };
 547         my ($proto, undef, @spec) = @$info;
 548         my $cur = pop @argv;
 549         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 550         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 551                 # gross special case since the only git-config options
 552                 # Consider moving to a table if we need more special cases
 553                 # we use Getopt::Long for are the ones we reject, so these
 554                 # are the ones we don't reject:
 555                 if ($cmd eq 'config') {
 556                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 557                         @spec = qw(add z|null get get-all unset unset-all
 558                                 replace-all get-urlmatch
 559                                 remove-section rename-section
 560                                 name-only list|l edit|e
 561                                 get-color-name get-colorbool);
 562                         # fall-through
 563                 }
 564                 # TODO: arg support
 565                 puts $self, grep(/$re/, map { # generate short/long names
 566                         my $eq = '';
 567                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 568                                 $eq = '=';
 569                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 570                         } else { # negation: solve! => no-solve|solve
 571                                 s/\A(.+)!\z/no-$1|$1/;
 572                         }
 573                         map {
 574                                 length > 1 ? "--$_$eq" : "-$_"
 575                         } split(/\|/, $_, -1) # help|h
 576                 } grep { !ref } @spec); # filter out $GLP_PASS ref
 577         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 578                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 579         }
 580         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 581         # proto parsing.
 582 }
 583
 584 sub reap_exec { # dwaitpid callback
 585         my ($self, $pid) = @_;
 586         x_it($self, $?);
 587 }
 588
 589 sub lei_git { # support passing through random git commands
 590         my ($self, @argv) = @_;
 591         my %rdr = map { $_ => $self->{$_} } (0..2);
 592         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 593         PublicInbox::DS::dwaitpid($pid, \&reap_exec, $self);
 594 }
 595
 596 sub accept_dispatch { # Listener {post_accept} callback
 597         my ($sock) = @_; # ignore other
 598         $sock->blocking(1);
 599         $sock->autoflush(1);
 600         my $self = bless { sock => $sock }, __PACKAGE__;
 601         vec(my $rin = '', fileno($sock), 1) = 1;
 602         # `say $sock' triggers "die" in lei(1)
 603         for my $i (0..2) {
 604                 if (select(my $rout = $rin, undef, undef, 1)) {
 605                         my $fd = IO::FDPass::recv(fileno($sock));
 606                         if ($fd >= 0) {
 607                                 my $rdr = ($fd == 0 ? '<&=' : '>&=');
 608                                 if (open(my $fh, $rdr, $fd)) {
 609                                         $self->{$i} = $fh;
 610                                 } else {
 611                                         say $sock "open($rdr$fd) (FD=$i): $!";
 612                                         return;
 613                                 }
 614                         } else {
 615                                 say $sock "recv FD=$i: $!";
 616                                 return;
 617                         }
 618                 } else {
 619                         say $sock "timed out waiting to recv FD=$i";
 620                         return;
 621                 }
 622         }
 623         # $ARGV_STR = join("]\0[", @ARGV);
 624         # $ENV_STR = join('', map { "$_=$ENV{$_}\0" } keys %ENV);
 625         # $line = "$$\0\0>$ARGV_STR\0\0>$ENV_STR\0\0";
 626         my ($client_pid, $argv, $env) = do {
 627                 local $/ = "\0\0\0"; # yes, 3 NULs at EOL, not 2
 628                 chomp(my $line = <$sock>);
 629                 split(/\0\0>/, $line, 3);
 630         };
 631         my %env = map { split(/=/, $_, 2) } split(/\0/, $env);
 632         if (chdir($env{PWD})) {
 633                 $self->{env} = \%env;
 634                 $self->{pid} = $client_pid;
 635                 eval { dispatch($self, split(/\]\0\[/, $argv)) };
 636                 say $sock $@ if $@;
 637         } else {
 638                 say $sock "chdir($env{PWD}): $!"; # implicit close
 639         }
 640 }
 641
 642 sub noop {}
 643
 644 # lei(1) calls this when it can't connect
 645 sub lazy_start {
 646         my ($path, $errno) = @_;
 647         if ($errno == ECONNREFUSED) {
 648                 unlink($path) or die "unlink($path): $!";
 649         } elsif ($errno != ENOENT) {
 650                 $! = $errno; # allow interpolation to stringify in die
 651                 die "connect($path): $!";
 652         }
 653         umask(077) // die("umask(077): $!");
 654         socket(my $l, AF_UNIX, SOCK_STREAM, 0) or die "socket: $!";
 655         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 656         listen($l, 1024) or die "listen: $!";
 657         my @st = stat($path) or die "stat($path): $!";
 658         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 659         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 660         my $oldset = PublicInbox::Sigfd::block_signals();
 661         require IO::FDPass;
 662         require PublicInbox::Listener;
 663         require PublicInbox::EOFpipe;
 664         (-p STDOUT && -p STDERR) or die "E: stdout+stderr must be pipes\n";
 665         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 666         POSIX::setsid() > 0 or die "setsid: $!";
 667         my $pid = fork // die "fork: $!";
 668         return if $pid;
 669         $0 = "lei-daemon $path";
 670         local %PATH2CFG;
 671         $_->blocking(0) for ($l, $eof_r, $eof_w);
 672         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 673         my $exit_code;
 674         local $quit = sub {
 675                 $exit_code //= shift;
 676                 my $listener = $l or exit($exit_code);
 677                 unlink($path) if defined($path);
 678                 # closing eof_w triggers \&noop wakeup
 679                 $eof_w = $l = $path = undef;
 680                 $listener->close; # DS::close
 681                 PublicInbox::DS->SetLoopTimeout(1000);
 682         };
 683         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 684         my $sig = {
 685                 CHLD => \&PublicInbox::DS::enqueue_reap,
 686                 QUIT => $quit,
 687                 INT => $quit,
 688                 TERM => $quit,
 689                 HUP => \&noop,
 690                 USR1 => \&noop,
 691                 USR2 => \&noop,
 692         };
 693         my $sigfd = PublicInbox::Sigfd->new($sig, $SFD_NONBLOCK);
 694         local %SIG = (%SIG, %$sig) if !$sigfd;
 695         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 696                 PublicInbox::DS->SetLoopTimeout(5000);
 697         } else {
 698                 # wake up every second to accept signals if we don't
 699                 # have signalfd or IO::KQueue:
 700                 PublicInbox::Sigfd::sig_setmask($oldset);
 701                 PublicInbox::DS->SetLoopTimeout(1000);
 702         }
 703         PublicInbox::DS->SetPostLoopCallback(sub {
 704                 my ($dmap, undef) = @_;
 705                 if (@st = defined($path) ? stat($path) : ()) {
 706                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 707                                 warn "$path dev/ino changed, quitting\n";
 708                                 $path = undef;
 709                         }
 710                 } elsif (defined($path)) {
 711                         warn "stat($path): $!, quitting ...\n";
 712                         undef $path; # don't unlink
 713                         $quit->();
 714                 }
 715                 return 1 if defined($path);
 716                 my $now = now();
 717                 my $n = 0;
 718                 for my $s (values %$dmap) {
 719                         $s->can('busy') or next;
 720                         if ($s->busy($now)) {
 721                                 ++$n;
 722                         } else {
 723                                 $s->close;
 724                         }
 725                 }
 726                 $n; # true: continue, false: stop
 727         });
 728
 729         # STDIN was redirected to /dev/null above, closing STDOUT and
 730         # STDERR will cause the calling `lei' client process to finish
 731         # reading <$daemon> pipe.
 732         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 733         openlog($path, 'pid', 'user');
 734         local $SIG{__WARN__} = sub { syslog('warning', "@_") };
 735         my $owner_pid = $$;
 736         my $on_destroy = PublicInbox::OnDestroy->new(sub {
 737                 syslog('crit', "$@") if $@ && $$ == $owner_pid;
 738         });
 739         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 740         # $daemon pipe to `lei' closed, main loop begins:
 741         PublicInbox::DS->EventLoop;
 742         @$on_destroy = (); # cancel on_destroy if we get here
 743         exit($exit_code // 0);
 744 }
 745
 746 # for users w/o IO::FDPass
 747 sub oneshot {
 748         my ($main_pkg) = @_;
 749         my $exit = $main_pkg->can('exit'); # caller may override exit()
 750         local $quit = $exit if $exit;
 751         local %PATH2CFG;
 752         umask(077) // die("umask(077): $!");
 753         dispatch((bless {
 754                 0 => *STDIN{IO},
 755                 1 => *STDOUT{IO},
 756                 2 => *STDERR{IO},
 757                 env => \%ENV
 758         }, __PACKAGE__), @ARGV);
 759 }
 760
 761 1;