lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_STREAM pack_sockaddr_un);
  15 use Errno qw(EAGAIN ECONNREFUSED ENOENT);
  16 use POSIX ();
  17 use IO::Handle ();
  18 use Sys::Syslog qw(syslog openlog);
  19 use PublicInbox::Config;
  20 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLONESHOT);
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::DS qw(now dwaitpid);
  23 use PublicInbox::Spawn qw(spawn run_die popen_rd);
  24 use PublicInbox::OnDestroy;
  25 use Text::Wrap qw(wrap);
  26 use File::Path qw(mkpath);
  27 use File::Spec;
  28 our $quit = \&CORE::exit;
  29 my ($recv_cmd, $send_cmd);
  30 my $GLP = Getopt::Long::Parser->new;
  31 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  32 my $GLP_PASS = Getopt::Long::Parser->new;
  33 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  34
  35 our %PATH2CFG; # persistent for socket daemon
  36 our @TO_CLOSE_ATFORK_CHILD;
  37
  38 # TBD: this is a documentation mechanism to show a subcommand
  39 # (may) pass options through to another command:
  40 sub pass_through { $GLP_PASS }
  41
  42 my $OPT;
  43 sub opt_dash ($$) {
  44         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  45         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  46         my $cb = sub { # Getopt::Long "<>" catch-all handler
  47                 my ($arg) = @_;
  48                 if ($arg =~ /\A-($re_str)\z/) {
  49                         $OPT->{$key} = $1;
  50                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  51                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  52                 # lone (single) dash is handled elsewhere
  53                 } elsif (substr($arg, 0, 1) eq '-') {
  54                         if ($OPT->{'--'}) {
  55                                 push @{$OPT->{-argv}}, $arg;
  56                         } else {
  57                                 die "bad argument: $arg\n";
  58                         }
  59                 } else {
  60                         push @{$OPT->{-argv}}, $arg;
  61                 }
  62         };
  63         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  64 }
  65
  66 sub _store_path ($) {
  67         my ($env) = @_;
  68         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  69                 ($env->{HOME} // '/nonexistent').'/.local/share')
  70                 .'/lei/store', $env->{PWD});
  71 }
  72
  73 sub _config_path ($) {
  74         my ($env) = @_;
  75         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  76                 ($env->{HOME} // '/nonexistent').'/.config')
  77                 .'/lei/config', $env->{PWD});
  78 }
  79
  80 # TODO: generate shell completion + help using %CMD and %OPTDESC
  81 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  82 our %CMD = ( # sorted in order of importance/use:
  83 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  84         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  85         sort|s=s reverse|r offset=i remote local! external! pretty
  86         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  87
  88 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  89         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  90         pass_through('git show') ],
  91
  92 'add-external' => [ 'URL_OR_PATHNAME',
  93         'add/set priority of a publicinbox|extindex for extra matches',
  94         qw(boost=i quiet|q) ],
  95 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  96         qw(format|f=s z|0 local remote quiet|q) ],
  97 'forget-external' => [ '{URL_OR_PATHNAME|--prune}',
  98         'exclude further results from a publicinbox|extindex',
  99         qw(prune quiet|q) ],
 100
 101 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 102                 qw(name-only format|f=s z) ],
 103 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 104 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 105
 106 'plonk' => [ '--thread|--from=IDENT',
 107         'exclude mail matching From: or thread from non-Message-ID searches',
 108         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 109 'mark' => [ 'MESSAGE_FLAGS...',
 110         'set/unset flags on message(s) from stdin',
 111         qw(stdin| oid=s exact by-mid|mid:s) ],
 112 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 113         "exclude message(s) on stdin from `q' search results",
 114         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 115
 116 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 117         'remove imported messages from IMAP, Maildirs, and MH',
 118         qw(exact! all jobs:i indexed) ],
 119
 120 # code repos are used for `show' to solve blobs from patch mails
 121 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 122         qw(boost=i) ],
 123 'ls-coderepo' => [ '[FILTER_TERMS...]',
 124                 'list known code repos', qw(format|f=s z) ],
 125 'forget-coderepo' => [ 'PATHNAME',
 126         'stop using repo to solve blobs from patches',
 127         qw(prune) ],
 128
 129 'add-watch' => [ '[URL_OR_PATHNAME]',
 130                 'watch for new messages and flag changes',
 131         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 132 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 133                 qw(format|f=s z) ],
 134 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 135 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 136 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 137         qw(prune) ],
 138
 139 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 140         'one-shot import/update from URL or filesystem',
 141         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 142         ],
 143
 144 'config' => [ '[...]', sub {
 145                 'git-config(1) wrapper for '._config_path($_[0]);
 146         }, qw(config-file|system|global|file|f=s), # for conflict detection
 147         pass_through('git config') ],
 148 'init' => [ '[PATHNAME]', sub {
 149                 'initialize storage, default: '._store_path($_[0]);
 150         }, qw(quiet|q) ],
 151 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 152         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 153 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 154 'help' => [ '[SUBCOMMAND]', 'show help' ],
 155
 156 # XXX do we need this?
 157 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 158
 159 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 160         'rewrite git history in an attempt to improve compression',
 161         'gc!' ],
 162
 163 # internal commands are prefixed with '_'
 164 '_complete' => [ '[...]', 'internal shell completion helper',
 165                 pass_through('everything') ],
 166 ); # @CMD
 167
 168 # switch descriptions, try to keep consistent across commands
 169 # $spec: Getopt::Long option specification
 170 # $spec => [@ALLOWED_VALUES (default is first), $description],
 171 # $spec => $description
 172 # "$SUB_COMMAND TAB $spec" => as above
 173 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 174                 'specify message input format' ];
 175 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 176
 177 my %OPTDESC = (
 178 'help|h' => 'show this built-in help',
 179 'quiet|q' => 'be quiet',
 180 'solve!' => 'do not attempt to reconstruct blobs from emails',
 181 'save-as=s' => ['NAME', 'save a search terms by given name'],
 182
 183 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 184
 185 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 186                 'deduplication strategy'],
 187 'show   thread|t' => 'display entire thread a message belongs to',
 188 'q      thread|t' =>
 189         'return all messages in the same thread as the actual match(es)',
 190 'augment|a' => 'augment --output destination instead of clobbering',
 191
 192 'output|o=s' => [ 'DEST',
 193         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 194
 195 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 196                         'message/object output format' ],
 197 'mark   format|f=s' => $stdin_formats,
 198 'forget format|f=s' => $stdin_formats,
 199 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 200                 'specify output format, default depends on --output'],
 201 'ls-query       format|f=s' => $ls_format,
 202 'ls-external    format|f=s' => $ls_format,
 203
 204 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 205 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 206
 207 'sort|s=s' => [ 'VAL|received,relevance,docid',
 208                 "order of results `--output'-dependent"],
 209 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 210
 211 'boost=i' => 'increase/decrease priority of results (default: 0)',
 212
 213 'local' => 'limit operations to the local filesystem',
 214 'local!' => 'exclude results from the local filesystem',
 215 'remote' => 'limit operations to those requiring network access',
 216 'remote!' => 'prevent operations requiring network access',
 217
 218 'mid=s' => 'specify the Message-ID of a message',
 219 'oid=s' => 'specify the git object ID of a message',
 220
 221 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 222 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 223 'include=s' => 'include mailboxes/newsgroups based on pattern',
 224
 225 'exact' => 'operate on exact header matches only',
 226 'exact!' => 'rely on content match instead of exact header matches',
 227
 228 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 229 'jobs:i' => 'set parallelism level',
 230
 231 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 232 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 233
 234 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 235 ); # %OPTDESC
 236
 237 my %CONFIG_KEYS = (
 238         'leistore.dir' => 'top-level storage location',
 239 );
 240
 241 sub x_it ($$) { # pronounced "exit"
 242         my ($self, $code) = @_;
 243         $self->{1}->autoflush(1); # make sure client sees stdout before exit
 244         my $sig = ($code & 127);
 245         $code >>= 8 unless $sig;
 246         if (my $sock = $self->{sock}) {
 247                 my $fds = [ map { fileno($_) } @$self{0..2} ];
 248                 $send_cmd->($sock, $fds, "exit=$code\n", 0);
 249         } else { # for oneshot
 250                 $quit->($code);
 251         }
 252 }
 253
 254 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 255
 256 sub out ($;@) { print { shift->{1} } @_ }
 257
 258 sub err ($;@) {
 259         print { shift->{2} } @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 260 }
 261
 262 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 263
 264 sub fail ($$;$) {
 265         my ($self, $buf, $exit_code) = @_;
 266         err($self, $buf);
 267         x_it($self, ($exit_code // 1) << 8);
 268         undef;
 269 }
 270
 271 sub atfork_prepare_wq {
 272         my ($self, $wq) = @_;
 273         push @{$wq->{-ipc_atfork_child_close}}, @TO_CLOSE_ATFORK_CHILD,
 274                                 grep { defined } @$self{qw(0 1 2 sock)}
 275 }
 276
 277 # usage: local %SIG = (%SIG, $lei->atfork_child_wq($wq));
 278 sub atfork_child_wq {
 279         my ($self, $wq) = @_;
 280         return () if $self->{0}; # did not fork
 281         $self->{$_} = $wq->{$_} for (0..2);
 282         $self->{sock} = $wq->{3} // die 'BUG: no {sock}'; # may be undef
 283         my $oldpipe = $SIG{PIPE};
 284         %PATH2CFG = ();
 285         @TO_CLOSE_ATFORK_CHILD = ();
 286         (
 287                 __WARN__ => sub { err($self, @_) },
 288                 PIPE => sub {
 289                         $self->x_it(141);
 290                         $oldpipe->() if ref($oldpipe) eq 'CODE';
 291                 }
 292         );
 293 }
 294
 295 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 296 sub atfork_parent_wq {
 297         my ($self, $wq) = @_;
 298         if ($wq->wq_workers) {
 299                 my $env = delete $self->{env}; # env is inherited at fork
 300                 my $ret = bless { %$self }, ref($self);
 301                 $self->{env} = $env;
 302                 delete @$ret{qw(-lei_store cfg pgr)};
 303                 ($ret, delete @$ret{qw(0 1 2 sock)});
 304         } else {
 305                 ($self, @$self{qw(0 1 2 sock)});
 306         }
 307 }
 308
 309 sub _help ($;$) {
 310         my ($self, $errmsg) = @_;
 311         my $cmd = $self->{cmd} // 'COMMAND';
 312         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 313         my @top = ($cmd, shift(@info) // ());
 314         my $cmd_desc = shift(@info);
 315         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 316         my @opt_desc;
 317         my $lpad = 2;
 318         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 319                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 320                 my $arg_vals = '';
 321                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 322
 323                 # lower-case is a keyword (e.g. `content', `oid'),
 324                 # ALL_CAPS is a string description (e.g. `PATH')
 325                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 326                         $desc .= "\ndefault: `$1'";
 327                 }
 328                 my (@vals, @s, @l);
 329                 my $x = $sw;
 330                 if ($x =~ s/!\z//) { # solve! => --no-solve
 331                         $x = "no-$x";
 332                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 333                         @vals = (' [', undef, ']');
 334                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 335                         @vals = (' ', undef);
 336                 } # else: no args $x = 'thread|t'
 337                 for (split(/\|/, $x)) { # help|h
 338                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 339                 }
 340                 if (!scalar(@vals)) { # no args 'thread|t'
 341                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 342                         $vals[1] = $1;
 343                 } else {
 344                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 345                 }
 346                 if ($arg_vals =~ /([,\|])/) {
 347                         my $sep = $1;
 348                         my @allow = split(/\Q$sep\E/, $arg_vals);
 349                         my $must = $sep eq '|' ? 'Must' : 'Can';
 350                         @allow = map { "`$_'" } @allow;
 351                         my $last = pop @allow;
 352                         $desc .= "\n$must be one of: " .
 353                                 join(', ', @allow) . " or $last";
 354                 }
 355                 my $lhs = join(', ', @s, @l) . join('', @vals);
 356                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 357                         $lhs =~ s/\A--/- , --/;
 358                 } else {
 359                         $lhs =~ s/\A--/    --/; # pad if no short options
 360                 }
 361                 $lpad = length($lhs) if length($lhs) > $lpad;
 362                 push @opt_desc, $lhs, $desc;
 363         }
 364         my $msg = $errmsg ? "E: $errmsg\n" : '';
 365         $msg .= <<EOF;
 366 usage: lei @top
 367   $cmd_desc
 368
 369 EOF
 370         $lpad += 2;
 371         local $Text::Wrap::columns = 78 - $lpad;
 372         my $padding = ' ' x ($lpad + 2);
 373         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 374                 $msg .= '  '.pack("A$lpad", $lhs);
 375                 $rhs = wrap('', '', $rhs);
 376                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 377                 $msg .= $rhs;
 378                 $msg .= "\n";
 379         }
 380         print { $self->{$errmsg ? 2 : 1} } $msg;
 381         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 382         undef;
 383 }
 384
 385 sub optparse ($$$) {
 386         my ($self, $cmd, $argv) = @_;
 387         $self->{cmd} = $cmd;
 388         $OPT = $self->{opt} = {};
 389         my $info = $CMD{$cmd} // [ '[...]' ];
 390         my ($proto, undef, @spec) = @$info;
 391         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 392         push @spec, qw(help|h);
 393         my $lone_dash;
 394         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 395                 $lone_dash = $spec[0];
 396                 $OPT->{$spec[0]} = \(my $var);
 397                 push @spec, '' => \$var;
 398         }
 399         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 400                 return _help($self, "bad arguments or options for $cmd");
 401         return _help($self) if $OPT->{help};
 402
 403         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 404
 405         # "-" aliases "stdin" or "clear"
 406         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 407
 408         my $i = 0;
 409         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 410         my ($err, $inf);
 411         my @args = split(/ /, $proto);
 412         for my $var (@args) {
 413                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 414                         $inf = defined($argv->[$i]) and last;
 415                         $var =~ s/\.\.\.\z//;
 416                         $err = "$var not supplied";
 417                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 418                         $argv->[$i++] // ($err = "$var not supplied");
 419                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 420                         $inf = 1;
 421                         last;
 422                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 423                         $i++;
 424                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 425                         my @or = split(/\|/, $var);
 426                         my $ok;
 427                         for my $o (@or) {
 428                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 429                                         $ok = defined($OPT->{$1});
 430                                         last;
 431                                 } elsif (defined($argv->[$i])) {
 432                                         $ok = 1;
 433                                         $i++;
 434                                         last;
 435                                 } # else continue looping
 436                         }
 437                         my $last = pop @or;
 438                         $err = join(', ', @or) . " or $last must be set";
 439                 } else {
 440                         warn "BUG: can't parse `$var' in $proto";
 441                 }
 442                 last if $err;
 443         }
 444         if (!$inf && scalar(@$argv) > scalar(@args)) {
 445                 $err //= 'too many arguments';
 446         }
 447         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 448 }
 449
 450 sub dispatch {
 451         my ($self, $cmd, @argv) = @_;
 452         local $SIG{__WARN__} = sub { err($self, @_) };
 453         return _help($self, 'no command given') unless defined($cmd);
 454         my $func = "lei_$cmd";
 455         $func =~ tr/-/_/;
 456         if (my $cb = __PACKAGE__->can($func)) {
 457                 optparse($self, $cmd, \@argv) or return;
 458                 $cb->($self, @argv);
 459         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 460                 my $opt = {};
 461                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 462                         return _help($self, 'bad arguments or options');
 463                 _help($self);
 464         } else {
 465                 fail($self, "`$cmd' is not an lei command");
 466         }
 467 }
 468
 469 sub _lei_cfg ($;$) {
 470         my ($self, $creat) = @_;
 471         my $f = _config_path($self->{env});
 472         my @st = stat($f);
 473         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 474         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 475                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 476         }
 477         if (!@st) {
 478                 unless ($creat) {
 479                         delete $self->{cfg};
 480                         return;
 481                 }
 482                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 483                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 484                 open my $fh, '>>', $f or die "open($f): $!\n";
 485                 @st = stat($fh) or die "fstat($f): $!\n";
 486                 $cur_st = pack('dd', $st[10], $st[7]);
 487                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 488         }
 489         my $cfg = PublicInbox::Config::git_config_dump($f);
 490         $cfg->{-st} = $cur_st;
 491         $cfg->{'-f'} = $f;
 492         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 493 }
 494
 495 sub _lei_store ($;$) {
 496         my ($self, $creat) = @_;
 497         my $cfg = _lei_cfg($self, $creat);
 498         $cfg->{-lei_store} //= do {
 499                 require PublicInbox::LeiStore;
 500                 my $dir = $cfg->{'leistore.dir'};
 501                 $dir //= _store_path($self->{env}) if $creat;
 502                 return unless $dir;
 503                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 504         };
 505 }
 506
 507 sub lei_show {
 508         my ($self, @argv) = @_;
 509 }
 510
 511 sub lei_mark {
 512         my ($self, @argv) = @_;
 513 }
 514
 515 sub lei_config {
 516         my ($self, @argv) = @_;
 517         $self->{opt}->{'config-file'} and return fail $self,
 518                 "config file switches not supported by `lei config'";
 519         my $env = $self->{env};
 520         delete local $env->{GIT_CONFIG};
 521         my $cfg = _lei_cfg($self, 1);
 522         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 523         my %rdr = map { $_ => $self->{$_} } (0..2);
 524         run_die($cmd, $env, \%rdr);
 525 }
 526
 527 sub lei_init {
 528         my ($self, $dir) = @_;
 529         my $cfg = _lei_cfg($self, 1);
 530         my $cur = $cfg->{'leistore.dir'};
 531         my $env = $self->{env};
 532         $dir //= _store_path($env);
 533         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 534         my @cur = stat($cur) if defined($cur);
 535         $cur = File::Spec->canonpath($cur // $dir);
 536         my @dir = stat($dir);
 537         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 538         if (@cur) {
 539                 if ($cur eq $dir) {
 540                         _lei_store($self, 1)->done;
 541                         return qerr($self, $exists);
 542                 }
 543
 544                 # some folks like symlinks and bind mounts :P
 545                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 546                         lei_config($self, 'leistore.dir', $dir);
 547                         _lei_store($self, 1)->done;
 548                         return qerr($self, "$exists (as $cur)");
 549                 }
 550                 return fail($self, <<"");
 551 E: leistore.dir=$cur already initialized and it is not $dir
 552
 553         }
 554         lei_config($self, 'leistore.dir', $dir);
 555         _lei_store($self, 1)->done;
 556         $exists //= "I: leistore.dir=$dir newly initialized";
 557         return qerr($self, $exists);
 558 }
 559
 560 sub lei_daemon_pid { puts shift, $$ }
 561
 562 sub lei_daemon_kill {
 563         my ($self) = @_;
 564         my $sig = $self->{opt}->{signal} // 'TERM';
 565         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 566 }
 567
 568 sub lei_help { _help($_[0]) }
 569
 570 # Shell completion helper.  Used by lei-completion.bash and hopefully
 571 # other shells.  Try to do as much here as possible to avoid redundancy
 572 # and improve maintainability.
 573 sub lei__complete {
 574         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 575         shift @argv; # ignore "lei", the entire command is sent
 576         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 577         my $cmd = shift @argv;
 578         my $info = $CMD{$cmd} // do { # filter matching commands
 579                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 580                 return;
 581         };
 582         my ($proto, undef, @spec) = @$info;
 583         my $cur = pop @argv;
 584         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 585         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 586                 # gross special case since the only git-config options
 587                 # Consider moving to a table if we need more special cases
 588                 # we use Getopt::Long for are the ones we reject, so these
 589                 # are the ones we don't reject:
 590                 if ($cmd eq 'config') {
 591                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 592                         @spec = qw(add z|null get get-all unset unset-all
 593                                 replace-all get-urlmatch
 594                                 remove-section rename-section
 595                                 name-only list|l edit|e
 596                                 get-color-name get-colorbool);
 597                         # fall-through
 598                 }
 599                 # TODO: arg support
 600                 puts $self, grep(/$re/, map { # generate short/long names
 601                         my $eq = '';
 602                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 603                                 $eq = '=';
 604                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 605                         } else { # negation: solve! => no-solve|solve
 606                                 s/\A(.+)!\z/no-$1|$1/;
 607                         }
 608                         map {
 609                                 length > 1 ? "--$_$eq" : "-$_"
 610                         } split(/\|/, $_, -1) # help|h
 611                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 612         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 613                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 614         }
 615         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 616         # proto parsing.
 617 }
 618
 619 sub reap_exec { # dwaitpid callback
 620         my ($self, $pid) = @_;
 621         x_it($self, $?);
 622 }
 623
 624 sub lei_git { # support passing through random git commands
 625         my ($self, @argv) = @_;
 626         my %rdr = map { $_ => $self->{$_} } (0..2);
 627         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 628         dwaitpid($pid, \&reap_exec, $self);
 629 }
 630
 631 # caller needs to "-t $self->{1}" to check if tty
 632 sub start_pager {
 633         my ($self) = @_;
 634         my $env = $self->{env};
 635         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 636         chomp(my $pager = <$fh> // '');
 637         close($fh) or warn "`git var PAGER' error: \$?=$?";
 638         return if $pager eq 'cat' || $pager eq '';
 639         # TODO TIOCGWINSZ
 640         my %new_env = (LESS => 'FRX', LV => '-c', COLUMNS => 80);
 641         $new_env{MORE} = 'FRX' if $^O eq 'freebsd';
 642         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 643         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 644         my $pgr = [ undef, @$rdr{1, 2} ];
 645         if (my $sock = $self->{sock}) { # lei(1) process runs it
 646                 delete @new_env{keys %$env}; # only set iff unset
 647                 my $buf = "exec 1\0".$pager;
 648                 while (my ($k, $v) = each %new_env) { $buf .= "\0$k=$v" };
 649                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 650                 $send_cmd->($sock, $fds, $buf .= "\n", 0);
 651         } else {
 652                 $pgr->[0] = spawn([$pager], $env, $rdr);
 653         }
 654         $self->{1} = $wpager;
 655         $self->{2} = $wpager if -t $self->{2};
 656         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 657         $self->{pgr} = $pgr;
 658 }
 659
 660 sub stop_pager {
 661         my ($self) = @_;
 662         my $pgr = delete($self->{pgr}) or return;
 663         my $pid = $pgr->[0];
 664         close $self->{1};
 665         # {2} may not be redirected
 666         $self->{1} = $pgr->[1];
 667         $self->{2} = $pgr->[2];
 668         dwaitpid($pid, undef, $self->{sock}) if $pid;
 669 }
 670
 671 sub accept_dispatch { # Listener {post_accept} callback
 672         my ($sock) = @_; # ignore other
 673         $sock->blocking(1);
 674         $sock->autoflush(1);
 675         my $self = bless { sock => $sock }, __PACKAGE__;
 676         vec(my $rin = '', fileno($sock), 1) = 1;
 677         # `say $sock' triggers "die" in lei(1)
 678         my $buf;
 679         if (select(my $rout = $rin, undef, undef, 1)) {
 680                 my @fds = $recv_cmd->($sock, $buf, 4096 * 33); # >MAX_ARG_STRLEN
 681                 if (scalar(@fds) == 3) {
 682                         my $i = 0;
 683                         for my $rdr (qw(<&= >&= >&=)) {
 684                                 my $fd = shift(@fds);
 685                                 if (open(my $fh, $rdr, $fd)) {
 686                                         $self->{$i++} = $fh;
 687                                 }  else {
 688                                         say $sock "open($rdr$fd) (FD=$i): $!";
 689                                         return;
 690                                 }
 691                         }
 692                 } else {
 693                         say $sock "recv_cmd failed: $!";
 694                         return;
 695                 }
 696         } else {
 697                 say $sock "timed out waiting to recv FDs";
 698                 return;
 699         }
 700         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 701         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 702         # $buf = "$$\0$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 703         if (substr($buf, -2, 2, '') ne "\0\0") { # s/\0\0\z//
 704                 say $sock "request command truncated";
 705                 return;
 706         }
 707         my ($argc, @argv) = split(/\0/, $buf, -1);
 708         undef $buf;
 709         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 710         if (chdir($env{PWD})) {
 711                 local %ENV = %env;
 712                 $self->{env} = \%env;
 713                 eval { dispatch($self, @argv) };
 714                 say $sock $@ if $@;
 715         } else {
 716                 say $sock "chdir($env{PWD}): $!"; # implicit close
 717         }
 718 }
 719
 720 # for long-running results
 721 sub event_step {
 722         my ($self) = @_;
 723         local %ENV = %{$self->{env}};
 724         eval {}; # TODO
 725         if ($@) {
 726                 say { $self->{sock} } $@;
 727                 $self->close; # PublicInbox::DS::close
 728         }
 729 }
 730
 731 sub noop {}
 732
 733 our $oldset; sub oldset { $oldset }
 734
 735 # lei(1) calls this when it can't connect
 736 sub lazy_start {
 737         my ($path, $errno, $nfd) = @_;
 738         if ($errno == ECONNREFUSED) {
 739                 unlink($path) or die "unlink($path): $!";
 740         } elsif ($errno != ENOENT) {
 741                 $! = $errno; # allow interpolation to stringify in die
 742                 die "connect($path): $!";
 743         }
 744         umask(077) // die("umask(077): $!");
 745         socket(my $l, AF_UNIX, SOCK_STREAM, 0) or die "socket: $!";
 746         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 747         listen($l, 1024) or die "listen: $!";
 748         my @st = stat($path) or die "stat($path): $!";
 749         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 750         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 751         local $oldset = PublicInbox::DS::block_signals();
 752         if ($nfd == 4) {
 753                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 754                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 755                         require PublicInbox::CmdIPC4;
 756                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 757                         PublicInbox::CmdIPC4->can('recv_cmd4');
 758                 };
 759         }
 760         $recv_cmd or die <<"";
 761 (Socket::MsgHdr || Inline::C) missing/unconfigured (nfd=$nfd);
 762
 763         require PublicInbox::Listener;
 764         require PublicInbox::EOFpipe;
 765         (-p STDOUT) or die "E: stdout must be a pipe\n";
 766         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 767         POSIX::setsid() > 0 or die "setsid: $!";
 768         my $pid = fork // die "fork: $!";
 769         return if $pid;
 770         $0 = "lei-daemon $path";
 771         local %PATH2CFG;
 772         local @TO_CLOSE_ATFORK_CHILD = ($l, $eof_r, $eof_w);
 773         $_->blocking(0) for ($l, $eof_r, $eof_w);
 774         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 775         my $exit_code;
 776         local $quit = sub {
 777                 $exit_code //= shift;
 778                 my $listener = $l or exit($exit_code);
 779                 unlink($path) if defined($path);
 780                 # closing eof_w triggers \&noop wakeup
 781                 $eof_w = $l = $path = undef;
 782                 $listener->close; # DS::close
 783                 PublicInbox::DS->SetLoopTimeout(1000);
 784         };
 785         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 786         my $sig = {
 787                 CHLD => \&PublicInbox::DS::enqueue_reap,
 788                 QUIT => $quit,
 789                 INT => $quit,
 790                 TERM => $quit,
 791                 HUP => \&noop,
 792                 USR1 => \&noop,
 793                 USR2 => \&noop,
 794         };
 795         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 796         local %SIG = (%SIG, %$sig) if !$sigfd;
 797         local $SIG{PIPE} = 'IGNORE';
 798         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 799                 push @TO_CLOSE_ATFORK_CHILD, $sigfd->{sock};
 800                 PublicInbox::DS->SetLoopTimeout(5000);
 801         } else {
 802                 # wake up every second to accept signals if we don't
 803                 # have signalfd or IO::KQueue:
 804                 PublicInbox::DS::sig_setmask($oldset);
 805                 PublicInbox::DS->SetLoopTimeout(1000);
 806         }
 807         PublicInbox::DS->SetPostLoopCallback(sub {
 808                 my ($dmap, undef) = @_;
 809                 if (@st = defined($path) ? stat($path) : ()) {
 810                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 811                                 warn "$path dev/ino changed, quitting\n";
 812                                 $path = undef;
 813                         }
 814                 } elsif (defined($path)) {
 815                         warn "stat($path): $!, quitting ...\n";
 816                         undef $path; # don't unlink
 817                         $quit->();
 818                 }
 819                 return 1 if defined($path);
 820                 my $now = now();
 821                 my $n = 0;
 822                 for my $s (values %$dmap) {
 823                         $s->can('busy') or next;
 824                         if ($s->busy($now)) {
 825                                 ++$n;
 826                         } else {
 827                                 $s->close;
 828                         }
 829                 }
 830                 $n; # true: continue, false: stop
 831         });
 832
 833         # STDIN was redirected to /dev/null above, closing STDERR and
 834         # STDOUT will cause the calling `lei' client process to finish
 835         # reading the <$daemon> pipe.
 836         openlog($path, 'pid', 'user');
 837         local $SIG{__WARN__} = sub { syslog('warning', "@_") };
 838         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 839                 syslog('crit', "$@") if $@;
 840         });
 841         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 842         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 843         # $daemon pipe to `lei' closed, main loop begins:
 844         PublicInbox::DS->EventLoop;
 845         @$on_destroy = (); # cancel on_destroy if we get here
 846         exit($exit_code // 0);
 847 }
 848
 849 # for users w/o Socket::Msghdr
 850 sub oneshot {
 851         my ($main_pkg) = @_;
 852         my $exit = $main_pkg->can('exit'); # caller may override exit()
 853         local $quit = $exit if $exit;
 854         local %PATH2CFG;
 855         umask(077) // die("umask(077): $!");
 856         local $SIG{PIPE} = sub { die(bless(\"$_[0]", 'PublicInbox::SIGPIPE')) };
 857         eval {
 858                 my $self = bless {
 859                         0 => *STDIN{GLOB},
 860                         1 => *STDOUT{GLOB},
 861                         2 => *STDERR{GLOB},
 862                         env => \%ENV
 863                 }, __PACKAGE__;
 864                 dispatch($self, @ARGV);
 865         };
 866         die $@ if $@ && ref($@) ne 'PublicInbox::SIGPIPE';
 867 }
 868
 869 # ensures stdout hits the FS before sock disconnects so a client
 870 # can immediately reread it
 871 sub DESTROY {
 872         my ($self) = @_;
 873         $self->{1}->autoflush(1);
 874         stop_pager($self);
 875 }
 876
 877 1;