lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 chop($p) if substr($p, -1, 1) eq '/';
  74                 return $p;
  75         }
  76         my $pwd = $self->{env}->{PWD};
  77         my $cwd;
  78         if (defined $pwd) {
  79                 my $xcwd = $self->{3} //
  80                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  81                 if (my @st_pwd = stat($pwd)) {
  82                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  83                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  84                                 $self->{env}->{PWD} = $pwd = undef;
  85                 } else { # PWD was invalid
  86                         $self->{env}->{PWD} = $pwd = undef;
  87                 }
  88         }
  89         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  90         File::Spec->rel2abs($p, $pwd);
  91 }
  92
  93 # abs_path resolves symlinks in parent iff all parents exist
  94 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  95
  96 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  97         my ($self) = @_;
  98         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  99                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 100                 .'/lei');
 101 }
 102
 103 sub store_path ($) { share_path($_[0]) . '/store' }
 104
 105 sub _config_path ($) {
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 109                 .'/lei/config');
 110 }
 111
 112 sub cache_dir ($) {
 113         my ($self) = @_;
 114         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 115                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 116                 .'/lei');
 117 }
 118
 119 sub ale {
 120         my ($self) = @_;
 121         $self->{ale} //= do {
 122                 require PublicInbox::LeiALE;
 123                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 124         };
 125 }
 126
 127 sub index_opt {
 128         # TODO: drop underscore variants everywhere, they're undocumented
 129         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 130         max_size|max-size=s sequential_shard|sequential-shard
 131         batch_size|batch-size=s skip-docdata)
 132 }
 133
 134 my @c_opt = qw(c=s@ C=s@ quiet|q);
 135 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 136         import-remote! no-torsocks torsocks=s),
 137         PublicInbox::LeiQuery::curl_opt());
 138
 139 # we don't support -C as an alias for --find-copies since it's already
 140 # used for chdir
 141 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 142         output-indicator-context=s indent-heuristic!
 143         minimal patience histogram anchored=s@ diff-algorithm=s
 144         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 145         word-diff:s word-diff-regex=s color-words:s no-renames
 146         rename-empty! check ws-error-highlight=s full-index binary
 147         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 148         find-copies-harder irreversible-delete|D l=i diff-filter=s
 149         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 150         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 151         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 152         inter-hunk-context=i function-context|W exit-code ext-diff
 153         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 154         line-prefix=s);
 155
 156 # we generate shell completion + help using %CMD and %OPTDESC,
 157 # see lei__complete() and PublicInbox::LeiHelp
 158 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 159 our %CMD = ( # sorted in order of importance/use:
 160 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 161         'stdin|', # /|\z/ must be first for lone dash
 162         @lxs_opt,
 163         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 164         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 165         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 166         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 167
 168 'up' => [ 'OUTPUT|--all', 'update saved search',
 169         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 170
 171 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 172         'stdin|', # /|\z/ must be first for lone dash
 173         # some of these options are ridiculous for lcat
 174         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 175         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 176         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 177         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 178
 179 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 180         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 181         @lxs_opt, @c_opt ],
 182
 183 'rediff' => [ '--stdin|LOCATION...',
 184                 'regenerate a diff with different options',
 185         'stdin|', # /|\z/ must be first for lone dash
 186         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 187         @diff_opt, @lxs_opt, @c_opt ],
 188
 189 'add-external' => [ 'LOCATION',
 190         'add/set priority of a publicinbox|extindex for extra matches',
 191         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 192         verbose|v+), @c_opt, index_opt(),
 193         PublicInbox::LeiQuery::curl_opt() ],
 194 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 195         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 196 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 197 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 198                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 199 'forget-external' => [ 'LOCATION...|--prune',
 200         'exclude further results from a publicinbox|extindex',
 201         qw(prune), @c_opt ],
 202
 203 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 204                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 205 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 206                 qw(verbose|v+), @c_opt ],
 207 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 208                         @c_opt ],
 209 'rm' => [ '--stdin|LOCATION...',
 210         'remove a message from the index and prevent reindexing',
 211         'stdin|', # /|\z/ must be first for lone dash
 212         @c_opt ],
 213 'plonk' => [ '--threads|--from=IDENT',
 214         'exclude mail matching From: or threads from non-Message-ID searches',
 215         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 216 'tag' => [ 'KEYWORDS...',
 217         'set/unset keywords and/or labels on message(s)',
 218         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 219         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 220         pass_through('-kw:foo for delete') ],
 221
 222 'purge-mailsource' => [ 'LOCATION|--all',
 223         'remove imported messages from IMAP, Maildirs, and MH',
 224         qw(exact! all jobs:i indexed), @c_opt ],
 225
 226 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 227         qw(import! kw! interval=s recursive|r
 228         exclude=s include=s), @c_opt ],
 229 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 230                 qw(format|f=s z), @c_opt ],
 231 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 232 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 233 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 234         qw(prune), @c_opt ],
 235
 236 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 237         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 238         verbose|v+ incremental!),
 239          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 240          @c_opt ],
 241 'import' => [ 'LOCATION...|--stdin',
 242         'one-time import/update from URL or filesystem',
 243         qw(stdin| offset=i recursive|r exclude=s include|I=s
 244         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 245         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 246 'forget-mail-sync' => [ 'LOCATION...',
 247         'forget sync information for a mail folder', @c_opt ],
 248 'export-kw' => [ 'LOCATION...|--all',
 249         'one-time export of keywords of sync sources',
 250         qw(all:s mode=s), @c_opt ],
 251 'convert' => [ 'LOCATION...|--stdin',
 252         'one-time conversion from URL or filesystem to another format',
 253         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 254         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 255 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 256         "use a patch to generate a query for `lei q --stdin'",
 257         qw(stdin| want|w=s@ uri debug), @c_opt ],
 258 'config' => [ '[...]', sub {
 259                 'git-config(1) wrapper for '._config_path($_[0]);
 260         }, qw(config-file|system|global|file|f=s), # for conflict detection
 261          qw(c=s@ C=s@), pass_through('git config') ],
 262 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 263         qw(pretty ascii dir=s), @c_opt ],
 264
 265 'init' => [ '[DIRNAME]', sub {
 266         "initialize storage, default: ".store_path($_[0]);
 267         }, @c_opt ],
 268 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 269         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 270         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 271 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 272 'help' => [ '[SUBCOMMAND]', 'show help' ],
 273
 274 # TODO
 275 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 276 #       'rewrite git history in an attempt to improve compression',
 277 #       qw(gc!), @c_opt ],
 278 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 279 #
 280 # internal commands are prefixed with '_'
 281 '_complete' => [ '[...]', 'internal shell completion helper',
 282                 pass_through('everything') ],
 283 ); # @CMD
 284
 285 # switch descriptions, try to keep consistent across commands
 286 # $spec: Getopt::Long option specification
 287 # $spec => [@ALLOWED_VALUES (default is first), $description],
 288 # $spec => $description
 289 # "$SUB_COMMAND TAB $spec" => as above
 290 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 291                         'specify message input format' ];
 292 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 293
 294 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 295 my %OPTDESC = (
 296 'help|h' => 'show this built-in help',
 297 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 298 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 299 'quiet|q' => 'be quiet',
 300 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 301         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 302
 303 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 304 'globoff|g' => "do not match locations using '*?' wildcards ".
 305                 "and\xa0'[]'\x{a0}ranges",
 306 'invert-match|v' => 'select non-matching lines',
 307 'color!' => 'disable color (for --format=text)',
 308 'verbose|v+' => 'be more verbose',
 309 'external!' => 'do not use externals',
 310 'mail!' => 'do not look in mail storage for OID',
 311 'cwd!' => 'do not look in git repo of current working directory',
 312 'oid-a|A=s' => 'pre-image OID',
 313 'path-a|a=s' => 'pre-image pathname associated with OID',
 314 'path-b|b=s' => 'post-image pathname associated with OID',
 315 'git-dir=s@' => 'additional git repository to scan',
 316 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 317         "proxy for (e.g. `socks5h://0:9050')" ],
 318 'torsocks=s' => ['VAL|auto|no|yes',
 319                 'whether or not to wrap git and curl commands with torsocks'],
 320 'no-torsocks' => 'alias for --torsocks=no',
 321 'save' =>  "save a search for `lei up'",
 322 'import-remote!' => 'do not memoize remote messages into local store',
 323
 324 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 325
 326 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 327                 'deduplication strategy'],
 328 'threads|t+' =>
 329         'return all messages in the same threads as the actual match(es)',
 330
 331 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 332                 'search prefixes to extract (default: dfpost7)' ],
 333
 334 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 335         'run command(s) or perform ops when done writing to output ' .
 336         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 337         'nothing otherwise)' ],
 338
 339 'augment|a' => 'augment --output destination instead of clobbering',
 340
 341 'output|mfolder|o=s' => [ 'MFOLDER',
 342         "destination (e.g.\xa0`/path/to/Maildir', ".
 343         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 344 'mua=s' => [ 'CMD',
 345         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 346
 347 'inbox-version=i' => [ 'NUM|1|2',
 348                 'force a public-inbox version with --mirror'],
 349 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 350
 351 # public-inbox-index options
 352 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 353 'compact' => 'run compact index after mirroring',
 354 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 355         "indexlevel with --mirror (default: full)" ],
 356 'max_size|max-size=s' => [ 'SIZE',
 357         'do not index messages larger than SIZE (default: infinity)' ],
 358 'batch_size|batch-size=s' => [ 'SIZE',
 359         'flush changes to OS after given number of bytes (default: 1m)' ],
 360 'sequential_shard|sequential-shard' =>
 361         'index Xapian shards sequentially for slow storage',
 362 'skip-docdata' =>
 363         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 364
 365 'format|f=s     q' => [
 366         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 367                 'specify output format, default depends on --output'],
 368 'exclude=s@     q' => [ 'LOCATION',
 369                 'exclude specified external(s) from search' ],
 370 'include|I=s@   q' => [ 'LOCATION',
 371                 'include specified external(s) in search' ],
 372 'only=s@        q' => [ 'LOCATION',
 373                 'only use specified external(s) for search' ],
 374 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 375                 'control number of search and writer jobs' ],
 376 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 377
 378 'in-format|F=s' => $stdin_formats,
 379 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 380                         'listing output format' ],
 381 'l      ls-search' => 'long listing format',
 382 'format|f=s     ls-external' => $ls_format,
 383
 384 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 385 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 386
 387 'sort|s=s' => [ 'VAL|received|relevance|docid',
 388                 "order of results is `--output'-dependent"],
 389 'reverse|r' => 'reverse search results', # like sort(1)
 390
 391 'boost=i' => 'increase/decrease priority of results (default: 0)',
 392
 393 'local' => 'limit operations to the local filesystem',
 394 'local!' => 'exclude results from the local filesystem',
 395 'remote' => 'limit operations to those requiring network access',
 396 'remote!' => 'prevent operations requiring network access',
 397
 398 'all:s  up' => ['local', 'update all (local) saved searches' ],
 399
 400 'mid=s' => 'specify the Message-ID of a message',
 401 'oid=s' => 'specify the git object ID of a message',
 402
 403 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 404 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 405 'include=s' => 'include mailboxes/newsgroups based on pattern',
 406
 407 'exact' => 'operate on exact header matches only',
 408 'exact!' => 'rely on content match instead of exact header matches',
 409
 410 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 411
 412 'kw!' => 'disable/enable importing keywords (aka "flags")',
 413
 414 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 415 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 416
 417 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 418 ); # %OPTDESC
 419
 420 my %CONFIG_KEYS = (
 421         'leistore.dir' => 'top-level storage location',
 422 );
 423
 424 my @WQ_KEYS = qw(lxs l2m wq1 ikw); # internal workers
 425
 426 sub _drop_wq {
 427         my ($self) = @_;
 428         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 429                 if ($wq->wq_kill) {
 430                         $wq->wq_close(0, undef, $self);
 431                 } elsif ($wq->wq_kill_old) {
 432                         $wq->wq_wait_old(undef, $self);
 433                 }
 434                 $wq->DESTROY;
 435         }
 436 }
 437
 438 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 439 sub x_it ($$) {
 440         my ($self, $code) = @_;
 441         # make sure client sees stdout before exit
 442         $self->{1}->autoflush(1) if $self->{1};
 443         dump_and_clear_log();
 444         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 445                 send($s, "x_it $code", MSG_EOR);
 446         } # else ignore if client disconnected
 447 }
 448
 449 sub err ($;@) {
 450         my $self = shift;
 451         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 452         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 453         print $err @_, @eor and return;
 454         my $old_err = delete $self->{2};
 455         close($old_err) if $! == EPIPE && $old_err;
 456         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 457         print $err @_, @eor or print STDERR @_, @eor;
 458 }
 459
 460 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 461
 462 sub fail_handler ($;$$) {
 463         my ($lei, $code, $io) = @_;
 464         close($io) if $io; # needed to avoid warnings on SIGPIPE
 465         _drop_wq($lei);
 466         x_it($lei, $code // (1 << 8));
 467 }
 468
 469 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 470         fail_handler($_[0], 13, delete $_[0]->{1});
 471 }
 472
 473 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 474 sub sigint_reap {
 475         my ($pgid) = @_;
 476         dwaitpid($pgid) if kill('-INT', $pgid);
 477 }
 478
 479 sub fail ($$;$) {
 480         my ($self, $buf, $exit_code) = @_;
 481         err($self, $buf) if defined $buf;
 482         # calls fail_handler:
 483         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 484         x_it($self, ($exit_code // 1) << 8);
 485         undef;
 486 }
 487
 488 sub out ($;@) {
 489         my $self = shift;
 490         return if print { $self->{1} // return } @_; # likely
 491         return note_sigpipe($self, 1) if $! == EPIPE;
 492         my $err = "error writing to output: $!";
 493         delete $self->{1};
 494         fail($self, $err);
 495 }
 496
 497 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 498
 499 sub child_error { # passes non-fatal curl exit codes to user
 500         my ($self, $child_error, $msg) = @_; # child_error is $?
 501         $self->err($msg) if $msg;
 502         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 503                 # send to the parent lei-daemon or to lei(1) client
 504                 send($s, "child_error $child_error", MSG_EOR);
 505         } elsif (!$PublicInbox::DS::in_loop) {
 506                 $self->{child_error} = $child_error;
 507         } # else noop if client disconnected
 508 }
 509
 510 sub note_sigpipe { # triggers sigpipe_handler
 511         my ($self, $fd) = @_;
 512         close(delete($self->{$fd})); # explicit close silences Perl warning
 513         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 514         x_it($self, 13);
 515 }
 516
 517 sub _lei_atfork_child {
 518         my ($self, $persist) = @_;
 519         # we need to explicitly close things which are on stack
 520         if ($persist) {
 521                 chdir '/' or die "chdir(/): $!";
 522                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 523                 if (my $cfg = $self->{cfg}) {
 524                         delete $cfg->{-lei_store};
 525                 }
 526         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 527                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 528                 STDERR->autoflush(1);
 529         }
 530         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 531         if (my $op_c = delete $self->{pkt_op_c}) {
 532                 close(delete $op_c->{sock});
 533         }
 534         if (my $pgr = delete $self->{pgr}) {
 535                 close($_) for (@$pgr[1,2]);
 536         }
 537         close $listener if $listener;
 538         undef $listener;
 539         undef $dir_idle;
 540         %PATH2CFG = ();
 541         undef $errors_log;
 542         $quit = \&CORE::exit;
 543         $self->{-eml_noisy} or # only "lei import" sets this atm
 544                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 545         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 546 }
 547
 548 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 549         my ($self) = @_;
 550         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 551                 $op->close; # PublicInbox::PktOp::close
 552         }
 553         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 554         close $unclosed_after_die;
 555 }
 556
 557 sub pkt_op_pair {
 558         my ($self) = @_;
 559         require PublicInbox::OnDestroy;
 560         require PublicInbox::PktOp;
 561         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 562         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 563         $end;
 564 }
 565
 566 sub workers_start {
 567         my ($lei, $wq, $jobs, $ops) = @_;
 568         $ops = {
 569                 '!' => [ \&fail_handler, $lei ],
 570                 '|' => [ \&sigpipe_handler, $lei ],
 571                 'x_it' => [ \&x_it, $lei ],
 572                 'child_error' => [ \&child_error, $lei ],
 573                 ($ops ? %$ops : ()),
 574         };
 575         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 576         my $end = $lei->pkt_op_pair;
 577         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 578         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 579         delete $lei->{pkt_op_p};
 580         my $op_c = delete $lei->{pkt_op_c};
 581         @$end = ();
 582         $lei->event_step_init;
 583         ($op_c, $ops);
 584 }
 585
 586 sub _help {
 587         require PublicInbox::LeiHelp;
 588         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 589 }
 590
 591 sub optparse ($$$) {
 592         my ($self, $cmd, $argv) = @_;
 593         # allow _complete --help to complete, not show help
 594         return 1 if substr($cmd, 0, 1) eq '_';
 595         $self->{cmd} = $cmd;
 596         $OPT = $self->{opt} //= {};
 597         my $info = $CMD{$cmd} // [ '[...]' ];
 598         my ($proto, undef, @spec) = @$info;
 599         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 600         push @spec, qw(help|h);
 601         my $lone_dash;
 602         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 603                 $lone_dash = $spec[0];
 604                 $OPT->{$spec[0]} = \(my $var);
 605                 push @spec, '' => \$var;
 606         }
 607         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 608                 return _help($self, "bad arguments or options for $cmd");
 609         return _help($self) if $OPT->{help};
 610
 611         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 612
 613         # "-" aliases "stdin" or "clear"
 614         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 615
 616         my $i = 0;
 617         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 618         my ($err, $inf);
 619         my @args = split(/ /, $proto);
 620         for my $var (@args) {
 621                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 622                         $inf = defined($argv->[$i]) and last;
 623                         $var =~ s/\.\.\.\z//;
 624                         $err = "$var not supplied";
 625                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 626                         $argv->[$i++] // ($err = "$var not supplied");
 627                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 628                         $inf = 1;
 629                         last;
 630                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 631                         $i++;
 632                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 633                         $inf = 1 if index($var, '...') > 0;
 634                         my @or = split(/\|/, $var);
 635                         my $ok;
 636                         for my $o (@or) {
 637                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 638                                         my $sw = $1;
 639                                         # assume pipe/regular file on stdin
 640                                         # w/o args means stdin
 641                                         if ($sw eq 'stdin' && !@$argv &&
 642                                                         (-p $self->{0} ||
 643                                                          -f _) && -r _) {
 644                                                 $OPT->{stdin} //= 1;
 645                                         }
 646                                         $ok = defined($OPT->{$sw});
 647                                         last if $ok;
 648                                 } elsif (defined($argv->[$i])) {
 649                                         $ok = 1;
 650                                         $i++;
 651                                         last;
 652                                 } # else continue looping
 653                         }
 654                         last if $ok;
 655                         my $last = pop @or;
 656                         $err = join(', ', @or) . " or $last must be set";
 657                 } else {
 658                         warn "BUG: can't parse `$var' in $proto";
 659                 }
 660                 last if $err;
 661         }
 662         if (!$inf && scalar(@$argv) > scalar(@args)) {
 663                 $err //= 'too many arguments';
 664         }
 665         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 666 }
 667
 668 sub _tmp_cfg { # for lei -c <name>=<value> ...
 669         my ($self) = @_;
 670         my $cfg = _lei_cfg($self, 1);
 671         require File::Temp;
 672         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 673         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 674         $ft->autoflush(1);
 675         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 676 [include]
 677         path = $cfg->{-f}
 678 EOM
 679         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 680         for (@{$self->{opt}->{c}}) {
 681                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 682 `-c $_' is not of the form -c <name>=<value>'
 683 EOM
 684                 my $name = $1;
 685                 my $value = $2 // 1;
 686                 _config($self, '--add', $name, $value);
 687                 if (defined(my $v = $tmp->{$name})) {
 688                         if (ref($v) eq 'ARRAY') {
 689                                 push @$v, $value;
 690                         } else {
 691                                 $tmp->{$name} = [ $v, $value ];
 692                         }
 693                 } else {
 694                         $tmp->{$name} = $value;
 695                 }
 696         }
 697 }
 698
 699 sub lazy_cb ($$$) {
 700         my ($self, $cmd, $pfx) = @_;
 701         my $ucmd = $cmd;
 702         $ucmd =~ tr/-/_/;
 703         my $cb;
 704         $cb = $self->can($pfx.$ucmd) and return $cb;
 705         my $base = $ucmd;
 706         $base =~ s/_([a-z])/\u$1/g;
 707         my $pkg = "PublicInbox::Lei\u$base";
 708         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 709                 $pkg->can($pfx.$ucmd) : undef;
 710 }
 711
 712 sub dispatch {
 713         my ($self, $cmd, @argv) = @_;
 714         local $current_lei = $self; # for __WARN__
 715         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 716         dump_and_clear_log("from previous run\n");
 717         return _help($self, 'no command given') unless defined($cmd);
 718         # do not support Getopt bundling for this
 719         while ($cmd eq '-C' || $cmd eq '-c') {
 720                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 721                                         '-C DIRECTORY' : '-c <name>=<value>');
 722                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 723                 $cmd = shift(@argv) // return _help($self, 'no command given');
 724         }
 725         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 726                 optparse($self, $cmd, \@argv) or return;
 727                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 728                 if (my $chdir = $self->{opt}->{C}) {
 729                         for my $d (@$chdir) {
 730                                 next if $d eq ''; # same as git(1)
 731                                 chdir $d or return fail($self, "cd $d: $!");
 732                         }
 733                         if (delete $self->{3}) { # update cwd for rel2abs
 734                                 opendir my $dh, '.' or
 735                                         return fail($self, "opendir . $!");
 736                                 $self->{3} = $dh;
 737                         }
 738                 }
 739                 $cb->($self, @argv);
 740         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 741                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 742                         or return _help($self, 'bad arguments or options');
 743                 _help($self);
 744         } else {
 745                 fail($self, "`$cmd' is not an lei command");
 746         }
 747 }
 748
 749 sub _lei_cfg ($;$) {
 750         my ($self, $creat) = @_;
 751         return $self->{cfg} if $self->{cfg};
 752         my $f = _config_path($self);
 753         my @st = stat($f);
 754         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 755         my ($sto, $sto_dir);
 756         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 757                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 758                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 759         }
 760         if (!@st) {
 761                 unless ($creat) {
 762                         delete $self->{cfg};
 763                         return bless {}, 'PublicInbox::Config';
 764                 }
 765                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 766                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 767                 open my $fh, '>>', $f or die "open($f): $!\n";
 768                 @st = stat($fh) or die "fstat($f): $!\n";
 769                 $cur_st = pack('dd', $st[10], $st[7]);
 770                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 771         }
 772         my $cfg = PublicInbox::Config->git_config_dump($f);
 773         $cfg->{-st} = $cur_st;
 774         $cfg->{'-f'} = $f;
 775         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 776                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 777                                                 store_path($self))) {
 778                 $cfg->{-lei_store} = $sto;
 779         }
 780         if (scalar(keys %PATH2CFG) > 5) {
 781                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 782                 for my $k (keys %PATH2CFG) {
 783                         delete($PATH2CFG{$k}) unless -f $k
 784                 }
 785         }
 786         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 787 }
 788
 789 sub _lei_store ($;$) {
 790         my ($self, $creat) = @_;
 791         my $cfg = _lei_cfg($self, $creat);
 792         $cfg->{-lei_store} //= do {
 793                 require PublicInbox::LeiStore;
 794                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 795                 return unless $creat || -d $dir;
 796                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 797         };
 798 }
 799
 800 sub _config {
 801         my ($self, @argv) = @_;
 802         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 803         my $cfg = _lei_cfg($self, 1);
 804         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 805         my %rdr = map { $_ => $self->{$_} } (0..2);
 806         waitpid(spawn($cmd, \%env, \%rdr), 0);
 807 }
 808
 809 sub lei_config {
 810         my ($self, @argv) = @_;
 811         $self->{opt}->{'config-file'} and return fail $self,
 812                 "config file switches not supported by `lei config'";
 813         _config(@_);
 814         x_it($self, $?) if $?;
 815 }
 816
 817 sub lei_daemon_pid { puts shift, $$ }
 818
 819 sub lei_daemon_kill {
 820         my ($self) = @_;
 821         my $sig = $self->{opt}->{signal} // 'TERM';
 822         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 823 }
 824
 825 # Shell completion helper.  Used by lei-completion.bash and hopefully
 826 # other shells.  Try to do as much here as possible to avoid redundancy
 827 # and improve maintainability.
 828 sub lei__complete {
 829         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 830         shift @argv; # ignore "lei", the entire command is sent
 831         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 832         my $cmd = shift @argv;
 833         my $info = $CMD{$cmd} // do { # filter matching commands
 834                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 835                 return;
 836         };
 837         my ($proto, undef, @spec) = @$info;
 838         my $cur = pop @argv;
 839         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 840         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 841                 # gross special case since the only git-config options
 842                 # Consider moving to a table if we need more special cases
 843                 # we use Getopt::Long for are the ones we reject, so these
 844                 # are the ones we don't reject:
 845                 if ($cmd eq 'config') {
 846                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 847                         @spec = qw(add z|null get get-all unset unset-all
 848                                 replace-all get-urlmatch
 849                                 remove-section rename-section
 850                                 name-only list|l edit|e
 851                                 get-color-name get-colorbool);
 852                         # fall-through
 853                 }
 854                 # generate short/long names from Getopt::Long specs
 855                 puts $self, grep(/$re/, qw(--help -h -C), map {
 856                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 857                         } elsif (s/\+\z//) { # verbose|v+
 858                         } elsif (s/!\z//) {
 859                                 # negation: mail! => no-mail|mail
 860                                 s/([\w\-]+)/$1|no-$1/g
 861                         }
 862                         map {
 863                                 my $x = length > 1 ? "--$_" : "-$_";
 864                                 $x eq $_cur ? () : $x;
 865                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 866                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 867         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 868                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 869         }
 870
 871         # switch args (e.g. lei q -f mbox<TAB>)
 872         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 873                 my $opt = quotemeta $1;
 874                 puts $self, map {
 875                         my $v = $OPTDESC{$_};
 876                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 877                         # get rid of ALL CAPS placeholder (e.g "OUT")
 878                         # (TODO: completion for external paths)
 879                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 880                         @v;
 881                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 882         }
 883         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 884                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 885         }
 886         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 887         # proto parsing.
 888 }
 889
 890 sub exec_buf ($$) {
 891         my ($argv, $env) = @_;
 892         my $argc = scalar @$argv;
 893         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 894         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 895         $buf;
 896 }
 897
 898 sub start_mua {
 899         my ($self) = @_;
 900         my $mua = $self->{opt}->{mua} // return;
 901         my $mfolder = $self->{ovv}->{dst};
 902         my (@cmd, $replaced);
 903         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 904                 @cmd = ($mua, '-f');
 905         # TODO: help wanted: other common FOSS MUAs
 906         } else {
 907                 require Text::ParseWords;
 908                 @cmd = Text::ParseWords::shellwords($mua);
 909                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 910                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 911         }
 912         push @cmd, $mfolder unless defined($replaced);
 913         if ($self->{sock}) { # lei(1) client process runs it
 914                 # restore terminal: echo $query | lei q --stdin --mua=...
 915                 my $io = [];
 916                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 917                 send_exec_cmd($self, $io, \@cmd, {});
 918         }
 919         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 920                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 921         }
 922         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 923         $self->{opt}->{quiet} = 1;
 924         delete $self->{-progress};
 925         delete $self->{opt}->{verbose};
 926 }
 927
 928 sub send_exec_cmd { # tell script/lei to execute a command
 929         my ($self, $io, $cmd, $env) = @_;
 930         my $sock = $self->{sock} // die 'lei client gone';
 931         my $fds = [ map { fileno($_) } @$io ];
 932         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 933 }
 934
 935 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 936         my ($self) = @_;
 937         my $alerts = $self->{opt}->{alert} // return;
 938         my $sock = $self->{sock};
 939         while (my $op = shift(@$alerts)) {
 940                 if ($op eq ':WINCH') {
 941                         # hit the process group that started the MUA
 942                         send($sock, '-WINCH', MSG_EOR) if $sock;
 943                 } elsif ($op eq ':bell') {
 944                         out($self, "\a");
 945                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 946                         push @$alerts, split(/(?<!\\),/, $op);
 947                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 948                         my $cmd = $1; # run an arbitrary command
 949                         require Text::ParseWords;
 950                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 951                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
 952                 } else {
 953                         err($self, "W: unsupported --alert=$op"); # non-fatal
 954                 }
 955         }
 956 }
 957
 958 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 959 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 960
 961 # this also normalizes the path
 962 sub path_to_fd {
 963         my ($self, $path) = @_;
 964         $path = rel2abs($self, $path);
 965         $path =~ tr!/!/!s;
 966         $path_to_fd{$path} // (
 967                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 968                         fail($self, "cannot open $path from daemon") : -1
 969         );
 970 }
 971
 972 # caller needs to "-t $self->{1}" to check if tty
 973 sub start_pager {
 974         my ($self) = @_;
 975         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 976         chomp(my $pager = <$fh> // '');
 977         close($fh) or warn "`git var PAGER' error: \$?=$?";
 978         return if $pager eq 'cat' || $pager eq '';
 979         my $new_env = { LESS => 'FRX', LV => '-c' };
 980         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 981         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 982         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 983         my $pgr = [ undef, @$rdr{1, 2} ];
 984         my $env = $self->{env};
 985         if ($self->{sock}) { # lei(1) process runs it
 986                 delete @$new_env{keys %$env}; # only set iff unset
 987                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 988         } else {
 989                 die 'BUG: start_pager w/o socket';
 990         }
 991         $self->{1} = $wpager;
 992         $self->{2} = $wpager if -t $self->{2};
 993         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 994         $self->{pgr} = $pgr;
 995 }
 996
 997 sub stop_pager {
 998         my ($self) = @_;
 999         my $pgr = delete($self->{pgr}) or return;
1000         $self->{2} = $pgr->[2];
1001         # do not restore original stdout, just close it so we error out
1002         close(delete($self->{1})) if $self->{1};
1003 }
1004
1005 sub accept_dispatch { # Listener {post_accept} callback
1006         my ($sock) = @_; # ignore other
1007         $sock->autoflush(1);
1008         my $self = bless { sock => $sock }, __PACKAGE__;
1009         vec(my $rvec = '', fileno($sock), 1) = 1;
1010         select($rvec, undef, undef, 60) or
1011                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1012         # (4096 * 33) >MAX_ARG_STRLEN
1013         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1014         if (!defined($fds[0])) {
1015                 warn(my $msg = "recv_cmd failed: $!");
1016                 return send($sock, $msg, MSG_EOR);
1017         } else {
1018                 my $i = 0;
1019                 for my $fd (@fds) {
1020                         open($self->{$i++}, '+<&=', $fd) and next;
1021                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1022                 }
1023                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1024         }
1025         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1026         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1027         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1028                 return send($sock, 'request command truncated', MSG_EOR);
1029         my ($argc, @argv) = split(/\0/, $buf, -1);
1030         undef $buf;
1031         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1032         if (chdir($self->{3})) {
1033                 local %ENV = %env;
1034                 $self->{env} = \%env;
1035                 eval { dispatch($self, @argv) };
1036                 send($sock, $@, MSG_EOR) if $@;
1037         } else {
1038                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1039         }
1040 }
1041
1042 sub dclose {
1043         my ($self) = @_;
1044         delete $self->{-progress};
1045         _drop_wq($self);
1046         close(delete $self->{1}) if $self->{1}; # may reap_compress
1047         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1048 }
1049
1050 # for long-running results
1051 sub event_step {
1052         my ($self) = @_;
1053         local %ENV = %{$self->{env}};
1054         my $sock = $self->{sock};
1055         local $current_lei = $self;
1056         eval {
1057                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1058                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1059                                 return if $! == EAGAIN;
1060                                 next if $! == EINTR;
1061                                 last if $! == ECONNRESET;
1062                                 die "recvmsg: $!";
1063                         }
1064                         for my $fd (@fds) {
1065                                 open my $rfh, '+<&=', $fd;
1066                         }
1067                         die "unrecognized client signal: $buf";
1068                 }
1069                 dclose($self);
1070         };
1071         if (my $err = $@) {
1072                 eval { $self->fail($err) };
1073                 dclose($self);
1074         }
1075 }
1076
1077 sub event_step_init {
1078         my ($self) = @_;
1079         return if $self->{-event_init_done}++;
1080         if (my $sock = $self->{sock}) { # using DS->EventLoop
1081                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1082         }
1083 }
1084
1085 sub noop {}
1086
1087 sub oldset { $oldset }
1088
1089 sub dump_and_clear_log {
1090         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1091                 my @pfx = @_;
1092                 unshift(@pfx, "$errors_log ") if @pfx;
1093                 warn @pfx, do { local $/; <STDIN> };
1094                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1095         }
1096 }
1097
1098 # lei(1) calls this when it can't connect
1099 sub lazy_start {
1100         my ($path, $errno, $narg) = @_;
1101         local ($errors_log, $listener);
1102         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1103         $errors_log = "$sock_dir/errors.log";
1104         my $addr = pack_sockaddr_un($path);
1105         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1106         $lk->lock_acquire;
1107         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1108         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1109                 return if connect($listener, $addr); # another process won
1110                 if ($errno == ECONNREFUSED && -S $path) {
1111                         unlink($path) or die "unlink($path): $!";
1112                 }
1113         } else {
1114                 $! = $errno; # allow interpolation to stringify in die
1115                 die "connect($path): $!";
1116         }
1117         umask(077) // die("umask(077): $!");
1118         bind($listener, $addr) or die "bind($path): $!";
1119         listen($listener, 1024) or die "listen: $!";
1120         $lk->lock_release;
1121         undef $lk;
1122         my @st = stat($path) or die "stat($path): $!";
1123         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1124         local $oldset = PublicInbox::DS::block_signals();
1125         if ($narg == 5) {
1126                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1127                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1128                         require PublicInbox::CmdIPC4;
1129                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1130                         PublicInbox::CmdIPC4->can('recv_cmd4');
1131                 };
1132         }
1133         $recv_cmd or die <<"";
1134 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1135
1136         require PublicInbox::Listener;
1137         require PublicInbox::PktOp;
1138         (-p STDOUT) or die "E: stdout must be a pipe\n";
1139         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1140         STDIN->autoflush(1);
1141         dump_and_clear_log("from previous daemon process:\n");
1142         POSIX::setsid() > 0 or die "setsid: $!";
1143         my $pid = fork // die "fork: $!";
1144         return if $pid;
1145         $0 = "lei-daemon $path";
1146         local %PATH2CFG;
1147         $listener->blocking(0);
1148         my $exit_code;
1149         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1150         local $quit = do {
1151                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1152                 sub {
1153                         $exit_code //= shift;
1154                         my $lis = $pil or exit($exit_code);
1155                         # closing eof_p triggers \&noop wakeup
1156                         $listener = $eof_p = $pil = $path = undef;
1157                         $lis->close; # DS::close
1158                         PublicInbox::DS->SetLoopTimeout(1000);
1159                 };
1160         };
1161         my $sig = {
1162                 CHLD => \&PublicInbox::DS::enqueue_reap,
1163                 QUIT => $quit,
1164                 INT => $quit,
1165                 TERM => $quit,
1166                 HUP => \&noop,
1167                 USR1 => \&noop,
1168                 USR2 => \&noop,
1169         };
1170         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1171         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1172         undef $sig;
1173         local $SIG{PIPE} = 'IGNORE';
1174         require PublicInbox::DirIdle;
1175         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1176                 # just rely on wakeup ot hit PostLoopCallback set below
1177                 _dir_idle_handler(@_) if $_[0]->fullname ne $path;
1178         }, 1);
1179         if ($sigfd) {
1180                 undef $sigfd; # unref, already in DS::DescriptorMap
1181         } else {
1182                 # wake up every second to accept signals if we don't
1183                 # have signalfd or IO::KQueue:
1184                 PublicInbox::DS::sig_setmask($oldset);
1185                 PublicInbox::DS->SetLoopTimeout(1000);
1186         }
1187         PublicInbox::DS->SetPostLoopCallback(sub {
1188                 my ($dmap, undef) = @_;
1189                 if (@st = defined($path) ? stat($path) : ()) {
1190                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1191                                 warn "$path dev/ino changed, quitting\n";
1192                                 $path = undef;
1193                         }
1194                 } elsif (defined($path)) { # ENOENT is common
1195                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1196                         undef $path;
1197                         $quit->();
1198                 }
1199                 return 1 if defined($path);
1200                 my $now = now();
1201                 my $n = 0;
1202                 for my $s (values %$dmap) {
1203                         $s->can('busy') or next;
1204                         if ($s->busy($now)) {
1205                                 ++$n;
1206                         } else {
1207                                 $s->close;
1208                         }
1209                 }
1210                 $n; # true: continue, false: stop
1211         });
1212
1213         # STDIN was redirected to /dev/null above, closing STDERR and
1214         # STDOUT will cause the calling `lei' client process to finish
1215         # reading the <$daemon> pipe.
1216         local $SIG{__WARN__} = sub {
1217                 $current_lei ? err($current_lei, @_) : warn(
1218                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1219         };
1220         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1221         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1222         # $daemon pipe to `lei' closed, main loop begins:
1223         PublicInbox::DS->EventLoop;
1224         exit($exit_code // 0);
1225 }
1226
1227 sub busy { 1 } # prevent daemon-shutdown if client is connected
1228
1229 # ensures stdout hits the FS before sock disconnects so a client
1230 # can immediately reread it
1231 sub DESTROY {
1232         my ($self) = @_;
1233         $self->{1}->autoflush(1) if $self->{1};
1234         stop_pager($self);
1235         # preserve $? for ->fail or ->x_it code
1236 }
1237
1238 sub wq_done_wait { # dwaitpid callback
1239         my ($arg, $pid) = @_;
1240         my ($wq, $lei) = @$arg;
1241         my $err_type = $lei->{-err_type};
1242         $? and $lei->child_error($?,
1243                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1244         $lei->dclose;
1245 }
1246
1247 sub fchdir {
1248         my ($lei) = @_;
1249         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1250         chdir($dh) || $lei->fail("fchdir: $!");
1251 }
1252
1253 sub wq_eof { # EOF callback for main daemon
1254         my ($lei) = @_;
1255         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1256         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1257 }
1258
1259 1;