lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use POSIX ();
  17 use IO::Handle ();
  18 use Sys::Syslog qw(syslog openlog);
  19 use PublicInbox::Config;
  20 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::DS qw(now dwaitpid);
  23 use PublicInbox::Spawn qw(spawn run_die popen_rd);
  24 use PublicInbox::OnDestroy;
  25 use Text::Wrap qw(wrap);
  26 use File::Path qw(mkpath);
  27 use File::Spec;
  28 our $quit = \&CORE::exit;
  29 our $current_lei;
  30 my ($recv_cmd, $send_cmd);
  31 my $GLP = Getopt::Long::Parser->new;
  32 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  33 my $GLP_PASS = Getopt::Long::Parser->new;
  34 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  35
  36 our %PATH2CFG; # persistent for socket daemon
  37 our @TO_CLOSE_ATFORK_CHILD;
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub _store_path ($) {
  68         my ($env) = @_;
  69         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  70                 ($env->{HOME} // '/nonexistent').'/.local/share')
  71                 .'/lei/store', $env->{PWD});
  72 }
  73
  74 sub _config_path ($) {
  75         my ($env) = @_;
  76         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  77                 ($env->{HOME} // '/nonexistent').'/.config')
  78                 .'/lei/config', $env->{PWD});
  79 }
  80
  81 # TODO: generate shell completion + help using %CMD and %OPTDESC
  82 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  83 our %CMD = ( # sorted in order of importance/use:
  84 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  85         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  86         sort|s=s reverse|r offset=i remote local! external! pretty mua-cmd=s
  87         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  88
  89 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  90         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  91         pass_through('git show') ],
  92
  93 'add-external' => [ 'URL_OR_PATHNAME',
  94         'add/set priority of a publicinbox|extindex for extra matches',
  95         qw(boost=i quiet|q) ],
  96 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  97         qw(format|f=s z|0 local remote quiet|q) ],
  98 'forget-external' => [ '{URL_OR_PATHNAME|--prune}',
  99         'exclude further results from a publicinbox|extindex',
 100         qw(prune quiet|q) ],
 101
 102 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 103                 qw(name-only format|f=s z) ],
 104 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 105 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 106
 107 'plonk' => [ '--thread|--from=IDENT',
 108         'exclude mail matching From: or thread from non-Message-ID searches',
 109         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 110 'mark' => [ 'MESSAGE_FLAGS...',
 111         'set/unset flags on message(s) from stdin',
 112         qw(stdin| oid=s exact by-mid|mid:s) ],
 113 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 114         "exclude message(s) on stdin from `q' search results",
 115         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 116
 117 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 118         'remove imported messages from IMAP, Maildirs, and MH',
 119         qw(exact! all jobs:i indexed) ],
 120
 121 # code repos are used for `show' to solve blobs from patch mails
 122 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 123         qw(boost=i) ],
 124 'ls-coderepo' => [ '[FILTER_TERMS...]',
 125                 'list known code repos', qw(format|f=s z) ],
 126 'forget-coderepo' => [ 'PATHNAME',
 127         'stop using repo to solve blobs from patches',
 128         qw(prune) ],
 129
 130 'add-watch' => [ '[URL_OR_PATHNAME]',
 131                 'watch for new messages and flag changes',
 132         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 133 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 134                 qw(format|f=s z) ],
 135 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 136 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 137 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 138         qw(prune) ],
 139
 140 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 141         'one-shot import/update from URL or filesystem',
 142         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 143         ],
 144
 145 'config' => [ '[...]', sub {
 146                 'git-config(1) wrapper for '._config_path($_[0]);
 147         }, qw(config-file|system|global|file|f=s), # for conflict detection
 148         pass_through('git config') ],
 149 'init' => [ '[PATHNAME]', sub {
 150                 'initialize storage, default: '._store_path($_[0]);
 151         }, qw(quiet|q) ],
 152 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 153         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 154 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 155 'help' => [ '[SUBCOMMAND]', 'show help' ],
 156
 157 # XXX do we need this?
 158 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 159
 160 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 161         'rewrite git history in an attempt to improve compression',
 162         'gc!' ],
 163
 164 # internal commands are prefixed with '_'
 165 '_complete' => [ '[...]', 'internal shell completion helper',
 166                 pass_through('everything') ],
 167 ); # @CMD
 168
 169 # switch descriptions, try to keep consistent across commands
 170 # $spec: Getopt::Long option specification
 171 # $spec => [@ALLOWED_VALUES (default is first), $description],
 172 # $spec => $description
 173 # "$SUB_COMMAND TAB $spec" => as above
 174 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 175                 'specify message input format' ];
 176 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 177
 178 my %OPTDESC = (
 179 'help|h' => 'show this built-in help',
 180 'quiet|q' => 'be quiet',
 181 'solve!' => 'do not attempt to reconstruct blobs from emails',
 182 'save-as=s' => ['NAME', 'save a search terms by given name'],
 183
 184 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 185
 186 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 187                 'deduplication strategy'],
 188 'show   thread|t' => 'display entire thread a message belongs to',
 189 'q      thread|t' =>
 190         'return all messages in the same thread as the actual match(es)',
 191 'augment|a' => 'augment --output destination instead of clobbering',
 192
 193 'output|o=s' => [ 'DEST',
 194         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 195 'mua-cmd|mua=s' => [ 'COMMAND',
 196         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 197
 198 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 199                         'message/object output format' ],
 200 'mark   format|f=s' => $stdin_formats,
 201 'forget format|f=s' => $stdin_formats,
 202 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 203                 'specify output format, default depends on --output'],
 204 'ls-query       format|f=s' => $ls_format,
 205 'ls-external    format|f=s' => $ls_format,
 206
 207 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 208 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 209
 210 'sort|s=s' => [ 'VAL|received,relevance,docid',
 211                 "order of results `--output'-dependent"],
 212 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 213
 214 'boost=i' => 'increase/decrease priority of results (default: 0)',
 215
 216 'local' => 'limit operations to the local filesystem',
 217 'local!' => 'exclude results from the local filesystem',
 218 'remote' => 'limit operations to those requiring network access',
 219 'remote!' => 'prevent operations requiring network access',
 220
 221 'mid=s' => 'specify the Message-ID of a message',
 222 'oid=s' => 'specify the git object ID of a message',
 223
 224 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 225 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 226 'include=s' => 'include mailboxes/newsgroups based on pattern',
 227
 228 'exact' => 'operate on exact header matches only',
 229 'exact!' => 'rely on content match instead of exact header matches',
 230
 231 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 232 'jobs:i' => 'set parallelism level',
 233
 234 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 235 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 236
 237 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 238 ); # %OPTDESC
 239
 240 my %CONFIG_KEYS = (
 241         'leistore.dir' => 'top-level storage location',
 242 );
 243
 244 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 245 sub x_it ($$) {
 246         my ($self, $code) = @_;
 247         # make sure client sees stdout before exit
 248         $self->{1}->autoflush(1) if $self->{1};
 249         if (my $sock = $self->{sock}) {
 250                 send($sock, "x_it $code", MSG_EOR);
 251         } elsif (!($code & 127)) { # oneshot, ignore signals
 252                 $quit->($code >> 8);
 253         }
 254 }
 255
 256 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 257
 258 sub out ($;@) { print { shift->{1} } @_ }
 259
 260 sub err ($;@) {
 261         my $self = shift;
 262         my $err = $self->{2} // *STDERR{IO};
 263         print $err @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 264 }
 265
 266 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 267
 268 sub fail ($$;$) {
 269         my ($self, $buf, $exit_code) = @_;
 270         err($self, $buf);
 271         x_it($self, ($exit_code // 1) << 8);
 272         undef;
 273 }
 274
 275 sub atfork_prepare_wq {
 276         my ($self, $wq) = @_;
 277         my $tcafc = $wq->{-ipc_atfork_child_close};
 278         push @$tcafc, @TO_CLOSE_ATFORK_CHILD;
 279         if (my $sock = $self->{sock}) {
 280                 push @$tcafc, @$self{qw(0 1 2)}, $sock;
 281         }
 282         for my $f (qw(lxs l2m)) {
 283                 my $ipc = $self->{$f} or next;
 284                 push @$tcafc, grep { defined }
 285                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 286         }
 287 }
 288
 289 # usage: my %sig = $lei->atfork_child_wq($wq);
 290 #        local @SIG{keys %sig} = values %sig;
 291 sub atfork_child_wq {
 292         my ($self, $wq) = @_;
 293         my ($sock, $l2m_wq_s1);
 294         (@$self{qw(0 1 2)}, $sock, $l2m_wq_s1) = delete(@$wq{0..4});
 295         $self->{sock} = $sock if -S $sock;
 296         $self->{l2m}->{-wq_s1} = $l2m_wq_s1 if $l2m_wq_s1 && -S $l2m_wq_s1;
 297         %PATH2CFG = ();
 298         $quit = \&CORE::exit;
 299         @TO_CLOSE_ATFORK_CHILD = ();
 300         (__WARN__ => sub { err($self, @_) },
 301         PIPE => sub {
 302                 $self->x_it(13); # SIGPIPE = 13
 303                 # we need to close explicitly to avoid Perl warning on SIGPIPE
 304                 for my $i (1, 2) {
 305                         next unless $self->{$i} && (-p $self->{$i} || -S _);
 306                         close(delete $self->{$i});
 307                 }
 308                 # trigger the LeiXSearch $done OpPipe:
 309                 syswrite($self->{0}, '!') if $self->{0} && -p $self->{0};
 310                 $SIG{PIPE} = 'DEFAULT';
 311                 die bless(\"$_[0]", 'PublicInbox::SIGPIPE'),
 312         });
 313 }
 314
 315 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 316 sub atfork_parent_wq {
 317         my ($self, $wq) = @_;
 318         my $env = delete $self->{env}; # env is inherited at fork
 319         my $ret = bless { %$self }, ref($self);
 320         if (my $dedupe = delete $ret->{dedupe}) {
 321                 $ret->{dedupe} = $wq->deep_clone($dedupe);
 322         }
 323         $self->{env} = $env;
 324         delete @$ret{qw(-lei_store cfg pgr lxs)}; # keep l2m
 325         my @io = delete @$ret{0..2};
 326         $io[3] = delete($ret->{sock}) // *STDERR{GLOB};
 327         my $l2m = $ret->{l2m};
 328         if ($l2m && $l2m != $wq) { # $wq == lxs
 329                 $io[4] = $l2m->{-wq_s1} if $l2m->{-wq_s1};
 330                 if (my @pids = $l2m->wq_close) {
 331                         $wq->{l2m_pids} = \@pids;
 332                 }
 333         }
 334         ($ret, @io);
 335 }
 336
 337 sub _help ($;$) {
 338         my ($self, $errmsg) = @_;
 339         my $cmd = $self->{cmd} // 'COMMAND';
 340         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 341         my @top = ($cmd, shift(@info) // ());
 342         my $cmd_desc = shift(@info);
 343         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 344         my @opt_desc;
 345         my $lpad = 2;
 346         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 347                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 348                 my $arg_vals = '';
 349                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 350
 351                 # lower-case is a keyword (e.g. `content', `oid'),
 352                 # ALL_CAPS is a string description (e.g. `PATH')
 353                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 354                         $desc .= "\ndefault: `$1'";
 355                 }
 356                 my (@vals, @s, @l);
 357                 my $x = $sw;
 358                 if ($x =~ s/!\z//) { # solve! => --no-solve
 359                         $x = "no-$x";
 360                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 361                         @vals = (' [', undef, ']');
 362                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 363                         @vals = (' ', undef);
 364                 } # else: no args $x = 'thread|t'
 365                 for (split(/\|/, $x)) { # help|h
 366                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 367                 }
 368                 if (!scalar(@vals)) { # no args 'thread|t'
 369                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 370                         $vals[1] = $1;
 371                 } else {
 372                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 373                 }
 374                 if ($arg_vals =~ /([,\|])/) {
 375                         my $sep = $1;
 376                         my @allow = split(/\Q$sep\E/, $arg_vals);
 377                         my $must = $sep eq '|' ? 'Must' : 'Can';
 378                         @allow = map { "`$_'" } @allow;
 379                         my $last = pop @allow;
 380                         $desc .= "\n$must be one of: " .
 381                                 join(', ', @allow) . " or $last";
 382                 }
 383                 my $lhs = join(', ', @s, @l) . join('', @vals);
 384                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 385                         $lhs =~ s/\A--/- , --/;
 386                 } else {
 387                         $lhs =~ s/\A--/    --/; # pad if no short options
 388                 }
 389                 $lpad = length($lhs) if length($lhs) > $lpad;
 390                 push @opt_desc, $lhs, $desc;
 391         }
 392         my $msg = $errmsg ? "E: $errmsg\n" : '';
 393         $msg .= <<EOF;
 394 usage: lei @top
 395   $cmd_desc
 396
 397 EOF
 398         $lpad += 2;
 399         local $Text::Wrap::columns = 78 - $lpad;
 400         my $padding = ' ' x ($lpad + 2);
 401         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 402                 $msg .= '  '.pack("A$lpad", $lhs);
 403                 $rhs = wrap('', '', $rhs);
 404                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 405                 $msg .= $rhs;
 406                 $msg .= "\n";
 407         }
 408         print { $self->{$errmsg ? 2 : 1} } $msg;
 409         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 410         undef;
 411 }
 412
 413 sub optparse ($$$) {
 414         my ($self, $cmd, $argv) = @_;
 415         $self->{cmd} = $cmd;
 416         $OPT = $self->{opt} = {};
 417         my $info = $CMD{$cmd} // [ '[...]' ];
 418         my ($proto, undef, @spec) = @$info;
 419         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 420         push @spec, qw(help|h);
 421         my $lone_dash;
 422         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 423                 $lone_dash = $spec[0];
 424                 $OPT->{$spec[0]} = \(my $var);
 425                 push @spec, '' => \$var;
 426         }
 427         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 428                 return _help($self, "bad arguments or options for $cmd");
 429         return _help($self) if $OPT->{help};
 430
 431         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 432
 433         # "-" aliases "stdin" or "clear"
 434         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 435
 436         my $i = 0;
 437         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 438         my ($err, $inf);
 439         my @args = split(/ /, $proto);
 440         for my $var (@args) {
 441                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 442                         $inf = defined($argv->[$i]) and last;
 443                         $var =~ s/\.\.\.\z//;
 444                         $err = "$var not supplied";
 445                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 446                         $argv->[$i++] // ($err = "$var not supplied");
 447                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 448                         $inf = 1;
 449                         last;
 450                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 451                         $i++;
 452                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 453                         my @or = split(/\|/, $var);
 454                         my $ok;
 455                         for my $o (@or) {
 456                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 457                                         $ok = defined($OPT->{$1});
 458                                         last;
 459                                 } elsif (defined($argv->[$i])) {
 460                                         $ok = 1;
 461                                         $i++;
 462                                         last;
 463                                 } # else continue looping
 464                         }
 465                         my $last = pop @or;
 466                         $err = join(', ', @or) . " or $last must be set";
 467                 } else {
 468                         warn "BUG: can't parse `$var' in $proto";
 469                 }
 470                 last if $err;
 471         }
 472         if (!$inf && scalar(@$argv) > scalar(@args)) {
 473                 $err //= 'too many arguments';
 474         }
 475         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 476 }
 477
 478 sub dispatch {
 479         my ($self, $cmd, @argv) = @_;
 480         local $current_lei = $self; # for __WARN__
 481         return _help($self, 'no command given') unless defined($cmd);
 482         my $func = "lei_$cmd";
 483         $func =~ tr/-/_/;
 484         if (my $cb = __PACKAGE__->can($func)) {
 485                 optparse($self, $cmd, \@argv) or return;
 486                 $cb->($self, @argv);
 487         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 488                 my $opt = {};
 489                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 490                         return _help($self, 'bad arguments or options');
 491                 _help($self);
 492         } else {
 493                 fail($self, "`$cmd' is not an lei command");
 494         }
 495 }
 496
 497 sub _lei_cfg ($;$) {
 498         my ($self, $creat) = @_;
 499         my $f = _config_path($self->{env});
 500         my @st = stat($f);
 501         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 502         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 503                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 504         }
 505         if (!@st) {
 506                 unless ($creat) {
 507                         delete $self->{cfg};
 508                         return;
 509                 }
 510                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 511                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 512                 open my $fh, '>>', $f or die "open($f): $!\n";
 513                 @st = stat($fh) or die "fstat($f): $!\n";
 514                 $cur_st = pack('dd', $st[10], $st[7]);
 515                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 516         }
 517         my $cfg = PublicInbox::Config::git_config_dump($f);
 518         $cfg->{-st} = $cur_st;
 519         $cfg->{'-f'} = $f;
 520         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 521 }
 522
 523 sub _lei_store ($;$) {
 524         my ($self, $creat) = @_;
 525         my $cfg = _lei_cfg($self, $creat);
 526         $cfg->{-lei_store} //= do {
 527                 require PublicInbox::LeiStore;
 528                 my $dir = $cfg->{'leistore.dir'};
 529                 $dir //= _store_path($self->{env}) if $creat;
 530                 return unless $dir;
 531                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 532         };
 533 }
 534
 535 sub lei_show {
 536         my ($self, @argv) = @_;
 537 }
 538
 539 sub lei_mark {
 540         my ($self, @argv) = @_;
 541 }
 542
 543 sub lei_config {
 544         my ($self, @argv) = @_;
 545         $self->{opt}->{'config-file'} and return fail $self,
 546                 "config file switches not supported by `lei config'";
 547         my $env = $self->{env};
 548         delete local $env->{GIT_CONFIG};
 549         my $cfg = _lei_cfg($self, 1);
 550         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 551         my %rdr = map { $_ => $self->{$_} } (0..2);
 552         run_die($cmd, $env, \%rdr);
 553 }
 554
 555 sub lei_init {
 556         my ($self, $dir) = @_;
 557         my $cfg = _lei_cfg($self, 1);
 558         my $cur = $cfg->{'leistore.dir'};
 559         my $env = $self->{env};
 560         $dir //= _store_path($env);
 561         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 562         my @cur = stat($cur) if defined($cur);
 563         $cur = File::Spec->canonpath($cur // $dir);
 564         my @dir = stat($dir);
 565         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 566         if (@cur) {
 567                 if ($cur eq $dir) {
 568                         _lei_store($self, 1)->done;
 569                         return qerr($self, $exists);
 570                 }
 571
 572                 # some folks like symlinks and bind mounts :P
 573                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 574                         lei_config($self, 'leistore.dir', $dir);
 575                         _lei_store($self, 1)->done;
 576                         return qerr($self, "$exists (as $cur)");
 577                 }
 578                 return fail($self, <<"");
 579 E: leistore.dir=$cur already initialized and it is not $dir
 580
 581         }
 582         lei_config($self, 'leistore.dir', $dir);
 583         _lei_store($self, 1)->done;
 584         $exists //= "I: leistore.dir=$dir newly initialized";
 585         return qerr($self, $exists);
 586 }
 587
 588 sub lei_daemon_pid { puts shift, $$ }
 589
 590 sub lei_daemon_kill {
 591         my ($self) = @_;
 592         my $sig = $self->{opt}->{signal} // 'TERM';
 593         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 594 }
 595
 596 sub lei_help { _help($_[0]) }
 597
 598 # Shell completion helper.  Used by lei-completion.bash and hopefully
 599 # other shells.  Try to do as much here as possible to avoid redundancy
 600 # and improve maintainability.
 601 sub lei__complete {
 602         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 603         shift @argv; # ignore "lei", the entire command is sent
 604         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 605         my $cmd = shift @argv;
 606         my $info = $CMD{$cmd} // do { # filter matching commands
 607                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 608                 return;
 609         };
 610         my ($proto, undef, @spec) = @$info;
 611         my $cur = pop @argv;
 612         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 613         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 614                 # gross special case since the only git-config options
 615                 # Consider moving to a table if we need more special cases
 616                 # we use Getopt::Long for are the ones we reject, so these
 617                 # are the ones we don't reject:
 618                 if ($cmd eq 'config') {
 619                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 620                         @spec = qw(add z|null get get-all unset unset-all
 621                                 replace-all get-urlmatch
 622                                 remove-section rename-section
 623                                 name-only list|l edit|e
 624                                 get-color-name get-colorbool);
 625                         # fall-through
 626                 }
 627                 # TODO: arg support
 628                 puts $self, grep(/$re/, map { # generate short/long names
 629                         my $eq = '';
 630                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 631                                 $eq = '=';
 632                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 633                         } else { # negation: solve! => no-solve|solve
 634                                 s/\A(.+)!\z/no-$1|$1/;
 635                         }
 636                         map {
 637                                 length > 1 ? "--$_$eq" : "-$_"
 638                         } split(/\|/, $_, -1) # help|h
 639                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 640         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 641                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 642         }
 643         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 644         # proto parsing.
 645 }
 646
 647 sub reap_exec { # dwaitpid callback
 648         my ($self, $pid) = @_;
 649         x_it($self, $?);
 650 }
 651
 652 sub lei_git { # support passing through random git commands
 653         my ($self, @argv) = @_;
 654         my %rdr = map { $_ => $self->{$_} } (0..2);
 655         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 656         dwaitpid($pid, \&reap_exec, $self);
 657 }
 658
 659 sub exec_buf ($$) {
 660         my ($argv, $env) = @_;
 661         my $argc = scalar @$argv;
 662         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 663         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 664         $buf;
 665 }
 666
 667 sub start_mua {
 668         my ($self, $sock) = @_;
 669         my $mua = $self->{opt}->{'mua-cmd'} // return;
 670         my $mfolder = $self->{ovv}->{dst};
 671         require Text::ParseWords;
 672         my $replaced;
 673         my @cmd = Text::ParseWords::shellwords($mua);
 674         # mutt uses '%f' for open-hook with compressed folders, so we use %f
 675         @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 676         push @cmd, $mfolder unless defined($replaced);
 677         $sock //= $self->{sock};
 678         if ($sock) { # lei(1) client process runs it
 679                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 680         } else { # oneshot
 681                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 682         }
 683 }
 684
 685 # caller needs to "-t $self->{1}" to check if tty
 686 sub start_pager {
 687         my ($self) = @_;
 688         my $env = $self->{env};
 689         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 690         chomp(my $pager = <$fh> // '');
 691         close($fh) or warn "`git var PAGER' error: \$?=$?";
 692         return if $pager eq 'cat' || $pager eq '';
 693         # TODO TIOCGWINSZ
 694         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 695         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 696         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 697         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 698         my $pgr = [ undef, @$rdr{1, 2}, $$ ];
 699         if (my $sock = $self->{sock}) { # lei(1) process runs it
 700                 delete @$new_env{keys %$env}; # only set iff unset
 701                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 702                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 703         } else {
 704                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 705         }
 706         $self->{1} = $wpager;
 707         $self->{2} = $wpager if -t $self->{2};
 708         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 709         $self->{pgr} = $pgr;
 710 }
 711
 712 sub stop_pager {
 713         my ($self) = @_;
 714         my $pgr = delete($self->{pgr}) or return;
 715         $self->{2} = $pgr->[2];
 716         # do not restore original stdout, just close it so we error out
 717         close(delete($self->{1})) if $self->{1};
 718         my $pid = $pgr->[0];
 719         dwaitpid($pid, undef, $self->{sock}) if $pid && $pgr->[3] == $$;
 720 }
 721
 722 sub accept_dispatch { # Listener {post_accept} callback
 723         my ($sock) = @_; # ignore other
 724         $sock->autoflush(1);
 725         my $self = bless { sock => $sock }, __PACKAGE__;
 726         vec(my $rvec = '', fileno($sock), 1) = 1;
 727         select($rvec, undef, undef, 1) or
 728                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 729         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 730         if (scalar(@fds) == 4) {
 731                 my $i = 0;
 732                 for my $rdr (qw(<&= >&= >&= <&=)) {
 733                         my $fd = shift(@fds);
 734                         open($self->{$i++}, $rdr, $fd) and next;
 735                         send($sock, "open($rdr$fd) (FD=$i): $!", MSG_EOR);
 736                 }
 737         } else {
 738                 return send($sock, "recv_cmd failed: $!", MSG_EOR);
 739         }
 740         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 741         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 742         # $buf = "$$\0$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 743         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 744                 return send($sock, 'request command truncated', MSG_EOR);
 745         my ($argc, @argv) = split(/\0/, $buf, -1);
 746         undef $buf;
 747         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 748         if (chdir(delete($self->{3}))) {
 749                 local %ENV = %env;
 750                 $self->{env} = \%env;
 751                 eval { dispatch($self, @argv) };
 752                 send($sock, $@, MSG_EOR) if $@;
 753         } else {
 754                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 755         }
 756 }
 757
 758 sub dclose {
 759         my ($self) = @_;
 760         delete $self->{lxs}; # stops LeiXSearch queries
 761         $self->close if $self->{sock}; # PublicInbox::DS::close
 762 }
 763
 764 # for long-running results
 765 sub event_step {
 766         my ($self) = @_;
 767         local %ENV = %{$self->{env}};
 768         my $sock = $self->{sock};
 769         eval {
 770                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 771                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 772                                 return if $! == EAGAIN;
 773                                 next if $! == EINTR;
 774                                 last if $! == ECONNRESET;
 775                                 die "recvmsg: $!";
 776                         }
 777                         for my $fd (@fds) {
 778                                 open my $rfh, '+<&=', $fd;
 779                         }
 780                         die "unrecognized client signal: $buf";
 781                 }
 782                 dclose($self);
 783         };
 784         if (my $err = $@) {
 785                 eval { $self->fail($err) };
 786                 dclose($self);
 787         }
 788 }
 789
 790 sub event_step_init {
 791         my ($self) = @_;
 792         if (my $sock = $self->{sock}) { # using DS->EventLoop
 793                 $sock->blocking(0);
 794                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 795         }
 796 }
 797
 798 sub noop {}
 799
 800 our $oldset; sub oldset { $oldset }
 801
 802 # lei(1) calls this when it can't connect
 803 sub lazy_start {
 804         my ($path, $errno, $narg) = @_;
 805         if ($errno == ECONNREFUSED) {
 806                 unlink($path) or die "unlink($path): $!";
 807         } elsif ($errno != ENOENT) {
 808                 $! = $errno; # allow interpolation to stringify in die
 809                 die "connect($path): $!";
 810         }
 811         umask(077) // die("umask(077): $!");
 812         socket(my $l, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 813         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 814         listen($l, 1024) or die "listen: $!";
 815         my @st = stat($path) or die "stat($path): $!";
 816         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 817         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 818         local $oldset = PublicInbox::DS::block_signals();
 819         if ($narg == 5) {
 820                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 821                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 822                         require PublicInbox::CmdIPC4;
 823                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 824                         PublicInbox::CmdIPC4->can('recv_cmd4');
 825                 };
 826         }
 827         $recv_cmd or die <<"";
 828 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 829
 830         require PublicInbox::Listener;
 831         require PublicInbox::EOFpipe;
 832         (-p STDOUT) or die "E: stdout must be a pipe\n";
 833         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 834         POSIX::setsid() > 0 or die "setsid: $!";
 835         my $pid = fork // die "fork: $!";
 836         return if $pid;
 837         $0 = "lei-daemon $path";
 838         local %PATH2CFG;
 839         local @TO_CLOSE_ATFORK_CHILD = ($l, $eof_w);
 840         $l->blocking(0);
 841         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 842         my $exit_code;
 843         local $quit = sub {
 844                 $exit_code //= shift;
 845                 my $listener = $l or exit($exit_code);
 846                 # closing eof_w triggers \&noop wakeup
 847                 $eof_w = $l = $path = undef;
 848                 $listener->close; # DS::close
 849                 PublicInbox::DS->SetLoopTimeout(1000);
 850         };
 851         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 852         undef $eof_r;
 853         my $sig = {
 854                 CHLD => \&PublicInbox::DS::enqueue_reap,
 855                 QUIT => $quit,
 856                 INT => $quit,
 857                 TERM => $quit,
 858                 HUP => \&noop,
 859                 USR1 => \&noop,
 860                 USR2 => \&noop,
 861         };
 862         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 863         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 864         undef $sig;
 865         local $SIG{PIPE} = 'IGNORE';
 866         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 867                 undef $sigfd;
 868                 PublicInbox::DS->SetLoopTimeout(5000);
 869         } else {
 870                 # wake up every second to accept signals if we don't
 871                 # have signalfd or IO::KQueue:
 872                 PublicInbox::DS::sig_setmask($oldset);
 873                 PublicInbox::DS->SetLoopTimeout(1000);
 874         }
 875         PublicInbox::DS->SetPostLoopCallback(sub {
 876                 my ($dmap, undef) = @_;
 877                 if (@st = defined($path) ? stat($path) : ()) {
 878                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 879                                 warn "$path dev/ino changed, quitting\n";
 880                                 $path = undef;
 881                         }
 882                 } elsif (defined($path)) {
 883                         warn "stat($path): $!, quitting ...\n";
 884                         undef $path; # don't unlink
 885                         $quit->();
 886                 }
 887                 return 1 if defined($path);
 888                 my $now = now();
 889                 my $n = 0;
 890                 for my $s (values %$dmap) {
 891                         $s->can('busy') or next;
 892                         if ($s->busy($now)) {
 893                                 ++$n;
 894                         } else {
 895                                 $s->close;
 896                         }
 897                 }
 898                 $n; # true: continue, false: stop
 899         });
 900
 901         # STDIN was redirected to /dev/null above, closing STDERR and
 902         # STDOUT will cause the calling `lei' client process to finish
 903         # reading the <$daemon> pipe.
 904         openlog($path, 'pid', 'user');
 905         local $SIG{__WARN__} = sub {
 906                 $current_lei ? err($current_lei, @_) : syslog('warning', "@_");
 907         };
 908         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 909                 syslog('crit', "$@") if $@;
 910         });
 911         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 912         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 913         # $daemon pipe to `lei' closed, main loop begins:
 914         PublicInbox::DS->EventLoop;
 915         @$on_destroy = (); # cancel on_destroy if we get here
 916         exit($exit_code // 0);
 917 }
 918
 919 # for users w/o Socket::Msghdr
 920 sub oneshot {
 921         my ($main_pkg) = @_;
 922         my $exit = $main_pkg->can('exit'); # caller may override exit()
 923         local $quit = $exit if $exit;
 924         local %PATH2CFG;
 925         umask(077) // die("umask(077): $!");
 926         dispatch((bless {
 927                 0 => *STDIN{GLOB},
 928                 1 => *STDOUT{GLOB},
 929                 2 => *STDERR{GLOB},
 930                 env => \%ENV
 931         }, __PACKAGE__), @ARGV);
 932 }
 933
 934 # ensures stdout hits the FS before sock disconnects so a client
 935 # can immediately reread it
 936 sub DESTROY {
 937         my ($self) = @_;
 938         $self->{1}->autoflush(1) if $self->{1};
 939         stop_pager($self);
 940         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
 941                 waitpid($mua_pid, 0);
 942         }
 943 }
 944
 945 1;