lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use Time::HiRes qw(stat); # ctime comparisons for config cache
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log, $listener, $oldset);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub rel2abs ($$) {
  68         my ($self, $p) = @_;
  69         return $p if index($p, '/') == 0; # already absolute
  70         my $pwd = $self->{env}->{PWD};
  71         if (defined $pwd) {
  72                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  73                 if (my @st_pwd = stat($pwd)) {
  74                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  75                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  76                                 $self->{env}->{PWD} = $pwd = $cwd;
  77                 } else { # PWD was invalid
  78                         delete $self->{env}->{PWD};
  79                         undef $pwd;
  80                 }
  81         }
  82         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  83         File::Spec->rel2abs($p, $pwd);
  84 }
  85
  86 sub store_path ($) {
  87         my ($self) = @_;
  88         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  89                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  90                 .'/lei/store');
  91 }
  92
  93 sub _config_path ($) {
  94         my ($self) = @_;
  95         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  96                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  97                 .'/lei/config');
  98 }
  99
 100 sub cache_dir ($) {
 101         my ($self) = @_;
 102         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 103                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 104                 .'/lei');
 105 }
 106
 107 sub ale {
 108         my ($self) = @_;
 109         $self->{ale} //= do {
 110                 require PublicInbox::LeiALE;
 111                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 112         };
 113 }
 114
 115 sub index_opt {
 116         # TODO: drop underscore variants everywhere, they're undocumented
 117         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 118         max_size|max-size=s sequential_shard|sequential-shard
 119         batch_size|batch-size=s skip-docdata)
 120 }
 121
 122 my @c_opt = qw(c=s@ C=s@ quiet|q);
 123 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 124         import-remote! no-torsocks torsocks=s),
 125         PublicInbox::LeiQuery::curl_opt());
 126
 127 # we generate shell completion + help using %CMD and %OPTDESC,
 128 # see lei__complete() and PublicInbox::LeiHelp
 129 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 130 our %CMD = ( # sorted in order of importance/use:
 131 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 132         'stdin|', # /|\z/ must be first for lone dash
 133         @lxs_opt,
 134         qw(save-as=s output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 135         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 136         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+), @c_opt,
 137         opt_dash('limit|n=i', '[0-9]+') ],
 138
 139 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 140         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 141         @lxs_opt, @c_opt ],
 142
 143 'add-external' => [ 'LOCATION',
 144         'add/set priority of a publicinbox|extindex for extra matches',
 145         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 146         verbose|v+), @c_opt, index_opt(),
 147         PublicInbox::LeiQuery::curl_opt() ],
 148 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 149         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 150 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 151 'forget-external' => [ 'LOCATION...|--prune',
 152         'exclude further results from a publicinbox|extindex',
 153         qw(prune), @c_opt ],
 154
 155 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 156                 qw(name-only format|f=s), @c_opt ],
 157 'rm-query' => [ 'QUERY_NAME', 'remove a saved search', @c_opt ],
 158 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search', @c_opt ],
 159
 160 'plonk' => [ '--threads|--from=IDENT',
 161         'exclude mail matching From: or threads from non-Message-ID searches',
 162         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 163 'mark' => [ 'KEYWORDS...',
 164         'set/unset keywords on message(s)',
 165         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@), @c_opt,
 166         pass_through('-kw:foo for delete') ],
 167 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 168         "exclude message(s) on stdin from `q' search results",
 169         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 170
 171 'purge-mailsource' => [ 'LOCATION|--all',
 172         'remove imported messages from IMAP, Maildirs, and MH',
 173         qw(exact! all jobs:i indexed), @c_opt ],
 174
 175 # code repos are used for `show' to solve blobs from patch mails
 176 'add-coderepo' => [ 'DIRNAME', 'add or set priority of a git code repo',
 177         qw(boost=i), @c_opt ],
 178 'ls-coderepo' => [ '[FILTER_TERMS...]',
 179                 'list known code repos', qw(format|f=s z), @c_opt ],
 180 'forget-coderepo' => [ 'DIRNAME',
 181         'stop using repo to solve blobs from patches',
 182         qw(prune), @c_opt ],
 183
 184 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 185         qw(import! kw|keywords|flags! interval=s recursive|r
 186         exclude=s include=s), @c_opt ],
 187 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 188                 qw(format|f=s z), @c_opt ],
 189 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 190 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 191 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 192         qw(prune), @c_opt ],
 193
 194 'import' => [ 'LOCATION...|--stdin',
 195         'one-time import/update from URL or filesystem',
 196         qw(stdin| offset=i recursive|r exclude=s include|I=s
 197         lock=s@ in-format|F=s kw|keywords|flags! verbose|v+), @c_opt ],
 198 'convert' => [ 'LOCATION...|--stdin',
 199         'one-time conversion from URL or filesystem to another format',
 200         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s
 201         lock=s@ kw|keywords|flags!), @c_opt ],
 202 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 203         "use a patch to generate a query for `lei q --stdin'",
 204         qw(stdin| want|w=s@ uri debug), @c_opt ],
 205 'config' => [ '[...]', sub {
 206                 'git-config(1) wrapper for '._config_path($_[0]);
 207         }, qw(config-file|system|global|file|f=s), # for conflict detection
 208          qw(c=s@ C=s@), pass_through('git config') ],
 209 'init' => [ '[DIRNAME]', sub {
 210         "initialize storage, default: ".store_path($_[0]);
 211         }, @c_opt ],
 212 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 213         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 214         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 215 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 216 'help' => [ '[SUBCOMMAND]', 'show help' ],
 217
 218 # XXX do we need this?
 219 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 220
 221 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 222         'rewrite git history in an attempt to improve compression',
 223         qw(gc!), @c_opt ],
 224
 225 # internal commands are prefixed with '_'
 226 '_complete' => [ '[...]', 'internal shell completion helper',
 227                 pass_through('everything') ],
 228 ); # @CMD
 229
 230 # switch descriptions, try to keep consistent across commands
 231 # $spec: Getopt::Long option specification
 232 # $spec => [@ALLOWED_VALUES (default is first), $description],
 233 # $spec => $description
 234 # "$SUB_COMMAND TAB $spec" => as above
 235 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 236                         'specify message input format' ];
 237 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 238
 239 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 240 my %OPTDESC = (
 241 'help|h' => 'show this built-in help',
 242 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 243 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 244 'quiet|q' => 'be quiet',
 245 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 246         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 247
 248 'globoff|g' => "do not match locations using '*?' wildcards ".
 249                 "and\xa0'[]'\x{a0}ranges",
 250 'verbose|v+' => 'be more verbose',
 251 'external!' => 'do not use externals',
 252 'mail!' => 'do not look in mail storage for OID',
 253 'cwd!' => 'do not look in git repo of current working directory',
 254 'oid-a|A=s' => 'pre-image OID',
 255 'path-a|a=s' => 'pre-image pathname associated with OID',
 256 'path-b|b=s' => 'post-image pathname associated with OID',
 257 'git-dir=s@' => 'additional git repository to scan',
 258 'torsocks=s' => ['VAL|auto|no|yes',
 259                 'whether or not to wrap git and curl commands with torsocks'],
 260 'no-torsocks' => 'alias for --torsocks=no',
 261 'save-as=s' => ['NAME', 'save a search terms by given name'],
 262 'import-remote!' => 'do not memoize remote messages into local store',
 263
 264 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 265
 266 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 267                 'deduplication strategy'],
 268 'threads|t+' =>
 269         'return all messages in the same threads as the actual match(es)',
 270
 271 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 272                 'search prefixes to extract (default: dfpost7)' ],
 273
 274 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 275         'run command(s) or perform ops when done writing to output ' .
 276         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 277         'nothing otherwise)' ],
 278
 279 'augment|a' => 'augment --output destination instead of clobbering',
 280
 281 'output|mfolder|o=s' => [ 'MFOLDER',
 282         "destination (e.g.\xa0`/path/to/Maildir', ".
 283         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 284 'mua=s' => [ 'CMD',
 285         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 286
 287 'inbox-version=i' => [ 'NUM|1|2',
 288                 'force a public-inbox version with --mirror'],
 289 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 290
 291 # public-inbox-index options
 292 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 293 'compact' => 'run compact index after mirroring',
 294 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 295         "indexlevel with --mirror (default: full)" ],
 296 'max_size|max-size=s' => [ 'SIZE',
 297         'do not index messages larger than SIZE (default: infinity)' ],
 298 'batch_size|batch-size=s' => [ 'SIZE',
 299         'flush changes to OS after given number of bytes (default: 1m)' ],
 300 'sequential_shard|sequential-shard' =>
 301         'index Xapian shards sequentially for slow storage',
 302 'skip-docdata' =>
 303         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 304
 305 'format|f=s     q' => [
 306         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 307                 'specify output format, default depends on --output'],
 308 'exclude=s@     q' => [ 'LOCATION',
 309                 'exclude specified external(s) from search' ],
 310 'include|I=s@   q' => [ 'LOCATION',
 311                 'include specified external(s) in search' ],
 312 'only=s@        q' => [ 'LOCATION',
 313                 'only use specified external(s) for search' ],
 314 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 315                 'control number of search and writer jobs' ],
 316 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 317
 318 'in-format|F=s' => $stdin_formats,
 319 'format|f=s     ls-query' => $ls_format,
 320 'format|f=s     ls-external' => $ls_format,
 321
 322 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 323 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 324
 325 'sort|s=s' => [ 'VAL|received|relevance|docid',
 326                 "order of results is `--output'-dependent"],
 327 'reverse|r' => 'reverse search results', # like sort(1)
 328
 329 'boost=i' => 'increase/decrease priority of results (default: 0)',
 330
 331 'local' => 'limit operations to the local filesystem',
 332 'local!' => 'exclude results from the local filesystem',
 333 'remote' => 'limit operations to those requiring network access',
 334 'remote!' => 'prevent operations requiring network access',
 335
 336 'mid=s' => 'specify the Message-ID of a message',
 337 'oid=s' => 'specify the git object ID of a message',
 338
 339 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 340 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 341 'include=s' => 'include mailboxes/newsgroups based on pattern',
 342
 343 'exact' => 'operate on exact header matches only',
 344 'exact!' => 'rely on content match instead of exact header matches',
 345
 346 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 347
 348 'kw|keywords|flags!' => 'disable/enable importing flags',
 349
 350 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 351 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 352
 353 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 354 ); # %OPTDESC
 355
 356 my %CONFIG_KEYS = (
 357         'leistore.dir' => 'top-level storage location',
 358 );
 359
 360 my @WQ_KEYS = qw(lxs l2m imp mrr cnv p2q mark sol); # internal workers
 361
 362 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 363 sub x_it ($$) {
 364         my ($self, $code) = @_;
 365         # make sure client sees stdout before exit
 366         $self->{1}->autoflush(1) if $self->{1};
 367         dump_and_clear_log();
 368         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 369                 send($s, "x_it $code", MSG_EOR);
 370         } elsif ($self->{oneshot}) {
 371                 # don't want to end up using $? from child processes
 372                 for my $f (@WQ_KEYS) {
 373                         my $wq = delete $self->{$f} or next;
 374                         $wq->DESTROY;
 375                 }
 376                 # cleanup anything that has tempfiles or open file handles
 377                 %PATH2CFG = ();
 378                 delete @$self{qw(ovv dedupe sto cfg)};
 379                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 380                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 381                         kill $signum, $$;
 382                         sleep(1) while 1; # wait for signal
 383                 } else {
 384                         $quit->($code >> 8);
 385                 }
 386         } # else ignore if client disconnected
 387 }
 388
 389 sub err ($;@) {
 390         my $self = shift;
 391         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 392         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 393         print $err @_, @eor and return;
 394         my $old_err = delete $self->{2};
 395         close($old_err) if $! == EPIPE && $old_err;
 396         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 397         print $err @_, @eor or print STDERR @_, @eor;
 398 }
 399
 400 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 401
 402 sub fail_handler ($;$$) {
 403         my ($lei, $code, $io) = @_;
 404         for my $f (@WQ_KEYS) {
 405                 my $wq = delete $lei->{$f} or next;
 406                 $wq->wq_wait_old(undef, $lei) if $wq->wq_kill_old; # lei-daemon
 407         }
 408         close($io) if $io; # needed to avoid warnings on SIGPIPE
 409         x_it($lei, $code // (1 << 8));
 410 }
 411
 412 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 413         fail_handler($_[0], 13, delete $_[0]->{1});
 414 }
 415
 416 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 417 sub sigint_reap {
 418         my ($pgid) = @_;
 419         dwaitpid($pgid) if kill('-INT', $pgid);
 420 }
 421
 422 sub fail ($$;$) {
 423         my ($self, $buf, $exit_code) = @_;
 424         err($self, $buf) if defined $buf;
 425         # calls fail_handler:
 426         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 427         x_it($self, ($exit_code // 1) << 8);
 428         undef;
 429 }
 430
 431 sub out ($;@) {
 432         my $self = shift;
 433         return if print { $self->{1} // return } @_; # likely
 434         return note_sigpipe($self, 1) if $! == EPIPE;
 435         my $err = "error writing to output: $!";
 436         delete $self->{1};
 437         fail($self, $err);
 438 }
 439
 440 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 441
 442 sub child_error { # passes non-fatal curl exit codes to user
 443         my ($self, $child_error, $msg) = @_; # child_error is $?
 444         $self->err($msg) if $msg;
 445         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 446                 # send to the parent lei-daemon or to lei(1) client
 447                 send($s, "child_error $child_error", MSG_EOR);
 448         } elsif (!$PublicInbox::DS::in_loop) {
 449                 $self->{child_error} = $child_error;
 450         } # else noop if client disconnected
 451 }
 452
 453 sub note_sigpipe { # triggers sigpipe_handler
 454         my ($self, $fd) = @_;
 455         close(delete($self->{$fd})); # explicit close silences Perl warning
 456         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 457         x_it($self, 13);
 458 }
 459
 460 sub _lei_atfork_child {
 461         my ($self, $persist) = @_;
 462         # we need to explicitly close things which are on stack
 463         if ($persist) {
 464                 chdir '/' or die "chdir(/): $!";
 465                 my @io = delete @$self{qw(0 1 2 sock)};
 466                 unless ($self->{oneshot}) {
 467                         close($_) for @io;
 468                 }
 469                 if (my $cfg = $self->{cfg}) {
 470                         delete $cfg->{-lei_store};
 471                 }
 472         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 473                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 474         }
 475         for (delete @$self{qw(3 old_1 au_done)}) {
 476                 close($_) if defined($_);
 477         }
 478         if (my $op_c = delete $self->{pkt_op_c}) {
 479                 close(delete $op_c->{sock});
 480         }
 481         if (my $pgr = delete $self->{pgr}) {
 482                 close($_) for (@$pgr[1,2]);
 483         }
 484         close $listener if $listener;
 485         undef $listener;
 486         %PATH2CFG = ();
 487         undef $errors_log;
 488         $quit = \&CORE::exit;
 489         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 490 }
 491
 492 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 493         my ($self) = @_;
 494         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 495                 $op->close; # PublicInbox::PktOp::close
 496         }
 497         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 498         close $unclosed_after_die;
 499 }
 500
 501 sub pkt_op_pair {
 502         my ($self) = @_;
 503         require PublicInbox::OnDestroy;
 504         require PublicInbox::PktOp;
 505         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 506         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 507         $end;
 508 }
 509
 510 sub workers_start {
 511         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 512         $ops = {
 513                 '!' => [ \&fail_handler, $lei ],
 514                 '|' => [ \&sigpipe_handler, $lei ],
 515                 'x_it' => [ \&x_it, $lei ],
 516                 'child_error' => [ \&child_error, $lei ],
 517                 ($ops ? %$ops : ()),
 518         };
 519         $ops->{''} //= [ \&dclose, $lei ];
 520         my $end = $lei->pkt_op_pair;
 521         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 522         delete $lei->{pkt_op_p};
 523         my $op_c = delete $lei->{pkt_op_c};
 524         @$end = ();
 525         $lei->event_step_init;
 526         ($op_c, $ops);
 527 }
 528
 529 sub _help {
 530         require PublicInbox::LeiHelp;
 531         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 532 }
 533
 534 sub optparse ($$$) {
 535         my ($self, $cmd, $argv) = @_;
 536         # allow _complete --help to complete, not show help
 537         return 1 if substr($cmd, 0, 1) eq '_';
 538         $self->{cmd} = $cmd;
 539         $OPT = $self->{opt} //= {};
 540         my $info = $CMD{$cmd} // [ '[...]' ];
 541         my ($proto, undef, @spec) = @$info;
 542         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 543         push @spec, qw(help|h);
 544         my $lone_dash;
 545         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 546                 $lone_dash = $spec[0];
 547                 $OPT->{$spec[0]} = \(my $var);
 548                 push @spec, '' => \$var;
 549         }
 550         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 551                 return _help($self, "bad arguments or options for $cmd");
 552         return _help($self) if $OPT->{help};
 553
 554         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 555
 556         # "-" aliases "stdin" or "clear"
 557         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 558
 559         my $i = 0;
 560         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 561         my ($err, $inf);
 562         my @args = split(/ /, $proto);
 563         for my $var (@args) {
 564                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 565                         $inf = defined($argv->[$i]) and last;
 566                         $var =~ s/\.\.\.\z//;
 567                         $err = "$var not supplied";
 568                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 569                         $argv->[$i++] // ($err = "$var not supplied");
 570                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 571                         $inf = 1;
 572                         last;
 573                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 574                         $i++;
 575                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 576                         $inf = 1 if index($var, '...') > 0;
 577                         my @or = split(/\|/, $var);
 578                         my $ok;
 579                         for my $o (@or) {
 580                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 581                                         $ok = defined($OPT->{$1});
 582                                         last if $ok;
 583                                 } elsif (defined($argv->[$i])) {
 584                                         $ok = 1;
 585                                         $i++;
 586                                         last;
 587                                 } # else continue looping
 588                         }
 589                         last if $ok;
 590                         my $last = pop @or;
 591                         $err = join(', ', @or) . " or $last must be set";
 592                 } else {
 593                         warn "BUG: can't parse `$var' in $proto";
 594                 }
 595                 last if $err;
 596         }
 597         if (!$inf && scalar(@$argv) > scalar(@args)) {
 598                 $err //= 'too many arguments';
 599         }
 600         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 601 }
 602
 603 sub _tmp_cfg { # for lei -c <name>=<value> ...
 604         my ($self) = @_;
 605         my $cfg = _lei_cfg($self, 1);
 606         require File::Temp;
 607         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 608         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 609         $ft->autoflush(1);
 610         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 611 [include]
 612         path = $cfg->{-f}
 613 EOM
 614         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 615         for (@{$self->{opt}->{c}}) {
 616                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 617 `-c $_' is not of the form -c <name>=<value>'
 618 EOM
 619                 my $name = $1;
 620                 my $value = $2 // 1;
 621                 _config($self, '--add', $name, $value);
 622                 if (defined(my $v = $tmp->{$name})) {
 623                         if (ref($v) eq 'ARRAY') {
 624                                 push @$v, $value;
 625                         } else {
 626                                 $tmp->{$name} = [ $v, $value ];
 627                         }
 628                 } else {
 629                         $tmp->{$name} = $value;
 630                 }
 631         }
 632 }
 633
 634 sub lazy_cb ($$$) {
 635         my ($self, $cmd, $pfx) = @_;
 636         my $ucmd = $cmd;
 637         $ucmd =~ tr/-/_/;
 638         my $cb;
 639         $cb = $self->can($pfx.$ucmd) and return $cb;
 640         my $base = $ucmd;
 641         $base =~ s/_([a-z])/\u$1/g;
 642         my $pkg = "PublicInbox::Lei\u$base";
 643         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 644                 $pkg->can($pfx.$ucmd) : undef;
 645 }
 646
 647 sub dispatch {
 648         my ($self, $cmd, @argv) = @_;
 649         local $current_lei = $self; # for __WARN__
 650         dump_and_clear_log("from previous run\n");
 651         return _help($self, 'no command given') unless defined($cmd);
 652         # do not support Getopt bundling for this
 653         while ($cmd eq '-C' || $cmd eq '-c') {
 654                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 655                                         '-C DIRECTORY' : '-c <name>=<value>');
 656                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 657                 $cmd = shift(@argv) // return _help($self, 'no command given');
 658         }
 659         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 660                 optparse($self, $cmd, \@argv) or return;
 661                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 662                 if (my $chdir = $self->{opt}->{C}) {
 663                         for my $d (@$chdir) {
 664                                 next if $d eq ''; # same as git(1)
 665                                 chdir $d or return fail($self, "cd $d: $!");
 666                         }
 667                         if (delete $self->{3}) { # update cwd for rel2abs
 668                                 opendir my $dh, '.' or
 669                                         return fail($self, "opendir . $!");
 670                                 $self->{3} = $dh;
 671                         }
 672                 }
 673                 $cb->($self, @argv);
 674         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 675                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 676                         or return _help($self, 'bad arguments or options');
 677                 _help($self);
 678         } else {
 679                 fail($self, "`$cmd' is not an lei command");
 680         }
 681 }
 682
 683 sub _lei_cfg ($;$) {
 684         my ($self, $creat) = @_;
 685         return $self->{cfg} if $self->{cfg};
 686         my $f = _config_path($self);
 687         my @st = stat($f);
 688         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 689         my ($sto, $sto_dir);
 690         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 691                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 692                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 693         }
 694         if (!@st) {
 695                 unless ($creat) {
 696                         delete $self->{cfg};
 697                         return bless {}, 'PublicInbox::Config';
 698                 }
 699                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 700                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 701                 open my $fh, '>>', $f or die "open($f): $!\n";
 702                 @st = stat($fh) or die "fstat($f): $!\n";
 703                 $cur_st = pack('dd', $st[10], $st[7]);
 704                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 705         }
 706         my $cfg = PublicInbox::Config::git_config_dump($f);
 707         bless $cfg, 'PublicInbox::Config';
 708         $cfg->{-st} = $cur_st;
 709         $cfg->{'-f'} = $f;
 710         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 711                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 712                                                 store_path($self))) {
 713                 $cfg->{-lei_store} = $sto;
 714         }
 715         if (scalar(keys %PATH2CFG) > 5) {
 716                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 717                 for my $k (keys %PATH2CFG) {
 718                         delete($PATH2CFG{$k}) unless -f $k
 719                 }
 720         }
 721         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 722 }
 723
 724 sub _lei_store ($;$) {
 725         my ($self, $creat) = @_;
 726         my $cfg = _lei_cfg($self, $creat);
 727         $cfg->{-lei_store} //= do {
 728                 require PublicInbox::LeiStore;
 729                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 730                 return unless $creat || -d $dir;
 731                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 732         };
 733 }
 734
 735 sub _config {
 736         my ($self, @argv) = @_;
 737         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 738         my $cfg = _lei_cfg($self, 1);
 739         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 740         my %rdr = map { $_ => $self->{$_} } (0..2);
 741         waitpid(spawn($cmd, \%env, \%rdr), 0);
 742 }
 743
 744 sub lei_config {
 745         my ($self, @argv) = @_;
 746         $self->{opt}->{'config-file'} and return fail $self,
 747                 "config file switches not supported by `lei config'";
 748         _config(@_);
 749         x_it($self, $?) if $?;
 750 }
 751
 752 sub lei_daemon_pid { puts shift, $$ }
 753
 754 sub lei_daemon_kill {
 755         my ($self) = @_;
 756         my $sig = $self->{opt}->{signal} // 'TERM';
 757         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 758 }
 759
 760 # Shell completion helper.  Used by lei-completion.bash and hopefully
 761 # other shells.  Try to do as much here as possible to avoid redundancy
 762 # and improve maintainability.
 763 sub lei__complete {
 764         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 765         shift @argv; # ignore "lei", the entire command is sent
 766         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 767         my $cmd = shift @argv;
 768         my $info = $CMD{$cmd} // do { # filter matching commands
 769                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 770                 return;
 771         };
 772         my ($proto, undef, @spec) = @$info;
 773         my $cur = pop @argv;
 774         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 775         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 776                 # gross special case since the only git-config options
 777                 # Consider moving to a table if we need more special cases
 778                 # we use Getopt::Long for are the ones we reject, so these
 779                 # are the ones we don't reject:
 780                 if ($cmd eq 'config') {
 781                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 782                         @spec = qw(add z|null get get-all unset unset-all
 783                                 replace-all get-urlmatch
 784                                 remove-section rename-section
 785                                 name-only list|l edit|e
 786                                 get-color-name get-colorbool);
 787                         # fall-through
 788                 }
 789                 # generate short/long names from Getopt::Long specs
 790                 puts $self, grep(/$re/, qw(--help -h -C), map {
 791                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 792                         } elsif (s/\+\z//) { # verbose|v+
 793                         } elsif (s/!\z//) {
 794                                 # negation: mail! => no-mail|mail
 795                                 s/([\w\-]+)/$1|no-$1/g
 796                         }
 797                         map {
 798                                 my $x = length > 1 ? "--$_" : "-$_";
 799                                 $x eq $_cur ? () : $x;
 800                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 801                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 802         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 803                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 804         }
 805
 806         # switch args (e.g. lei q -f mbox<TAB>)
 807         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 808                 my $opt = quotemeta $1;
 809                 puts $self, map {
 810                         my $v = $OPTDESC{$_};
 811                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 812                         # get rid of ALL CAPS placeholder (e.g "OUT")
 813                         # (TODO: completion for external paths)
 814                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 815                         @v;
 816                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 817         }
 818         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 819                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 820         }
 821         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 822         # proto parsing.
 823 }
 824
 825 sub exec_buf ($$) {
 826         my ($argv, $env) = @_;
 827         my $argc = scalar @$argv;
 828         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 829         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 830         $buf;
 831 }
 832
 833 sub start_mua {
 834         my ($self) = @_;
 835         my $mua = $self->{opt}->{mua} // return;
 836         my $mfolder = $self->{ovv}->{dst};
 837         my (@cmd, $replaced);
 838         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 839                 @cmd = ($mua, '-f');
 840         # TODO: help wanted: other common FOSS MUAs
 841         } else {
 842                 require Text::ParseWords;
 843                 @cmd = Text::ParseWords::shellwords($mua);
 844                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 845                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 846         }
 847         push @cmd, $mfolder unless defined($replaced);
 848         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 849                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 850         } elsif ($self->{oneshot}) {
 851                 $self->{"pid.$self.$$"}->{spawn(\@cmd)} = \@cmd;
 852         }
 853         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 854                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 855         }
 856         $self->{opt}->{quiet} = 1;
 857         delete $self->{-progress};
 858         delete $self->{opt}->{verbose};
 859 }
 860
 861 sub send_exec_cmd { # tell script/lei to execute a command
 862         my ($self, $io, $cmd, $env) = @_;
 863         my $sock = $self->{sock} // die 'lei client gone';
 864         my $fds = [ map { fileno($_) } @$io ];
 865         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 866 }
 867
 868 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 869         my ($self) = @_;
 870         my $alerts = $self->{opt}->{alert} // return;
 871         while (my $op = shift(@$alerts)) {
 872                 if ($op eq ':WINCH') {
 873                         # hit the process group that started the MUA
 874                         if ($self->{sock}) {
 875                                 send($self->{sock}, '-WINCH', MSG_EOR);
 876                         } elsif ($self->{oneshot}) {
 877                                 kill('-WINCH', $$);
 878                         }
 879                 } elsif ($op eq ':bell') {
 880                         out($self, "\a");
 881                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 882                         push @$alerts, split(/(?<!\\),/, $op);
 883                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 884                         my $cmd = $1; # run an arbitrary command
 885                         require Text::ParseWords;
 886                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 887                         if (my $s = $self->{sock}) {
 888                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 889                         } elsif ($self->{oneshot}) {
 890                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 891                         }
 892                 } else {
 893                         err($self, "W: unsupported --alert=$op"); # non-fatal
 894                 }
 895         }
 896 }
 897
 898 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 899 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 900
 901 # this also normalizes the path
 902 sub path_to_fd {
 903         my ($self, $path) = @_;
 904         $path = rel2abs($self, $path);
 905         $path =~ tr!/!/!s;
 906         $path_to_fd{$path} // (
 907                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 908                         fail($self, "cannot open $path from daemon") : -1
 909         );
 910 }
 911
 912 # caller needs to "-t $self->{1}" to check if tty
 913 sub start_pager {
 914         my ($self) = @_;
 915         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 916         chomp(my $pager = <$fh> // '');
 917         close($fh) or warn "`git var PAGER' error: \$?=$?";
 918         return if $pager eq 'cat' || $pager eq '';
 919         my $new_env = { LESS => 'FRX', LV => '-c' };
 920         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 921         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 922         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 923         my $pgr = [ undef, @$rdr{1, 2} ];
 924         my $env = $self->{env};
 925         if ($self->{sock}) { # lei(1) process runs it
 926                 delete @$new_env{keys %$env}; # only set iff unset
 927                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 928         } elsif ($self->{oneshot}) {
 929                 my $cmd = [$pager];
 930                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 931         } else {
 932                 die 'BUG: start_pager w/o socket';
 933         }
 934         $self->{1} = $wpager;
 935         $self->{2} = $wpager if -t $self->{2};
 936         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 937         $self->{pgr} = $pgr;
 938 }
 939
 940 sub stop_pager {
 941         my ($self) = @_;
 942         my $pgr = delete($self->{pgr}) or return;
 943         $self->{2} = $pgr->[2];
 944         # do not restore original stdout, just close it so we error out
 945         close(delete($self->{1})) if $self->{1};
 946 }
 947
 948 sub accept_dispatch { # Listener {post_accept} callback
 949         my ($sock) = @_; # ignore other
 950         $sock->autoflush(1);
 951         my $self = bless { sock => $sock }, __PACKAGE__;
 952         vec(my $rvec = '', fileno($sock), 1) = 1;
 953         select($rvec, undef, undef, 60) or
 954                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 955         # (4096 * 33) >MAX_ARG_STRLEN
 956         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
 957         if (!defined($fds[0])) {
 958                 warn(my $msg = "recv_cmd failed: $!");
 959                 return send($sock, $msg, MSG_EOR);
 960         } else {
 961                 my $i = 0;
 962                 for my $fd (@fds) {
 963                         open($self->{$i++}, '+<&=', $fd) and next;
 964                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 965                 }
 966                 return if scalar(@fds) != 4;
 967         }
 968         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 969         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 970         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 971         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 972                 return send($sock, 'request command truncated', MSG_EOR);
 973         my ($argc, @argv) = split(/\0/, $buf, -1);
 974         undef $buf;
 975         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 976         if (chdir($self->{3})) {
 977                 local %ENV = %env;
 978                 $self->{env} = \%env;
 979                 eval { dispatch($self, @argv) };
 980                 send($sock, $@, MSG_EOR) if $@;
 981         } else {
 982                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 983         }
 984 }
 985
 986 sub dclose {
 987         my ($self) = @_;
 988         delete $self->{-progress};
 989         for my $f (@WQ_KEYS) {
 990                 my $wq = delete $self->{$f} or next;
 991                 if ($wq->wq_kill) {
 992                         $wq->wq_close(0, undef, $self);
 993                 } elsif ($wq->wq_kill_old) {
 994                         $wq->wq_wait_old(undef, $self);
 995                 }
 996         }
 997         close(delete $self->{1}) if $self->{1}; # may reap_compress
 998         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
 999 }
1000
1001 # for long-running results
1002 sub event_step {
1003         my ($self) = @_;
1004         local %ENV = %{$self->{env}};
1005         my $sock = $self->{sock};
1006         local $current_lei = $self;
1007         eval {
1008                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1009                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1010                                 return if $! == EAGAIN;
1011                                 next if $! == EINTR;
1012                                 last if $! == ECONNRESET;
1013                                 die "recvmsg: $!";
1014                         }
1015                         for my $fd (@fds) {
1016                                 open my $rfh, '+<&=', $fd;
1017                         }
1018                         die "unrecognized client signal: $buf";
1019                 }
1020                 dclose($self);
1021         };
1022         if (my $err = $@) {
1023                 eval { $self->fail($err) };
1024                 dclose($self);
1025         }
1026 }
1027
1028 sub event_step_init {
1029         my ($self) = @_;
1030         return if $self->{-event_init_done}++;
1031         if (my $sock = $self->{sock}) { # using DS->EventLoop
1032                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1033         }
1034 }
1035
1036 sub noop {}
1037
1038 sub oldset { $oldset }
1039
1040 sub dump_and_clear_log {
1041         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1042                 my @pfx = @_;
1043                 unshift(@pfx, "$errors_log ") if @pfx;
1044                 warn @pfx, do { local $/; <STDIN> };
1045                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1046         }
1047 }
1048
1049 # lei(1) calls this when it can't connect
1050 sub lazy_start {
1051         my ($path, $errno, $narg) = @_;
1052         local ($errors_log, $listener);
1053         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1054         $errors_log .= 'errors.log';
1055         my $addr = pack_sockaddr_un($path);
1056         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1057         $lk->lock_acquire;
1058         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1059         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1060                 return if connect($listener, $addr); # another process won
1061                 if ($errno == ECONNREFUSED && -S $path) {
1062                         unlink($path) or die "unlink($path): $!";
1063                 }
1064         } else {
1065                 $! = $errno; # allow interpolation to stringify in die
1066                 die "connect($path): $!";
1067         }
1068         umask(077) // die("umask(077): $!");
1069         bind($listener, $addr) or die "bind($path): $!";
1070         listen($listener, 1024) or die "listen: $!";
1071         $lk->lock_release;
1072         undef $lk;
1073         my @st = stat($path) or die "stat($path): $!";
1074         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1075         local $oldset = PublicInbox::DS::block_signals();
1076         if ($narg == 5) {
1077                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1078                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1079                         require PublicInbox::CmdIPC4;
1080                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1081                         PublicInbox::CmdIPC4->can('recv_cmd4');
1082                 };
1083         }
1084         $recv_cmd or die <<"";
1085 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1086
1087         require PublicInbox::Listener;
1088         require PublicInbox::EOFpipe;
1089         (-p STDOUT) or die "E: stdout must be a pipe\n";
1090         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1091         STDIN->autoflush(1);
1092         dump_and_clear_log("from previous daemon process:\n");
1093         POSIX::setsid() > 0 or die "setsid: $!";
1094         my $pid = fork // die "fork: $!";
1095         return if $pid;
1096         $0 = "lei-daemon $path";
1097         local %PATH2CFG;
1098         $listener->blocking(0);
1099         my $exit_code;
1100         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1101         local $quit = do {
1102                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1103                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1104                 sub {
1105                         $exit_code //= shift;
1106                         my $lis = $pil or exit($exit_code);
1107                         # closing eof_w triggers \&noop wakeup
1108                         $listener = $eof_w = $pil = $path = undef;
1109                         $lis->close; # DS::close
1110                         PublicInbox::DS->SetLoopTimeout(1000);
1111                 };
1112         };
1113         my $sig = {
1114                 CHLD => \&PublicInbox::DS::enqueue_reap,
1115                 QUIT => $quit,
1116                 INT => $quit,
1117                 TERM => $quit,
1118                 HUP => \&noop,
1119                 USR1 => \&noop,
1120                 USR2 => \&noop,
1121         };
1122         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1123         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1124         undef $sig;
1125         local $SIG{PIPE} = 'IGNORE';
1126         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1127                 undef $sigfd;
1128                 PublicInbox::DS->SetLoopTimeout(5000);
1129         } else {
1130                 # wake up every second to accept signals if we don't
1131                 # have signalfd or IO::KQueue:
1132                 PublicInbox::DS::sig_setmask($oldset);
1133                 PublicInbox::DS->SetLoopTimeout(1000);
1134         }
1135         PublicInbox::DS->SetPostLoopCallback(sub {
1136                 my ($dmap, undef) = @_;
1137                 if (@st = defined($path) ? stat($path) : ()) {
1138                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1139                                 warn "$path dev/ino changed, quitting\n";
1140                                 $path = undef;
1141                         }
1142                 } elsif (defined($path)) { # ENOENT is common
1143                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1144                         undef $path;
1145                         $quit->();
1146                 }
1147                 return 1 if defined($path);
1148                 my $now = now();
1149                 my $n = 0;
1150                 for my $s (values %$dmap) {
1151                         $s->can('busy') or next;
1152                         if ($s->busy($now)) {
1153                                 ++$n;
1154                         } else {
1155                                 $s->close;
1156                         }
1157                 }
1158                 $n; # true: continue, false: stop
1159         });
1160
1161         # STDIN was redirected to /dev/null above, closing STDERR and
1162         # STDOUT will cause the calling `lei' client process to finish
1163         # reading the <$daemon> pipe.
1164         local $SIG{__WARN__} = sub {
1165                 $current_lei ? err($current_lei, @_) : warn(
1166                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1167         };
1168         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1169         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1170         # $daemon pipe to `lei' closed, main loop begins:
1171         PublicInbox::DS->EventLoop;
1172         exit($exit_code // 0);
1173 }
1174
1175 sub busy { 1 } # prevent daemon-shutdown if client is connected
1176
1177 # for users w/o Socket::Msghdr installed or Inline::C enabled
1178 sub oneshot {
1179         my ($main_pkg) = @_;
1180         my $exit = $main_pkg->can('exit'); # caller may override exit()
1181         local $quit = $exit if $exit;
1182         local %PATH2CFG;
1183         umask(077) // die("umask(077): $!");
1184         my $self = bless {
1185                 oneshot => 1,
1186                 0 => *STDIN{GLOB},
1187                 1 => *STDOUT{GLOB},
1188                 2 => *STDERR{GLOB},
1189                 env => \%ENV
1190         }, __PACKAGE__;
1191         dispatch($self, @ARGV);
1192         x_it($self, $self->{child_error}) if $self->{child_error};
1193 }
1194
1195 # ensures stdout hits the FS before sock disconnects so a client
1196 # can immediately reread it
1197 sub DESTROY {
1198         my ($self) = @_;
1199         $self->{1}->autoflush(1) if $self->{1};
1200         stop_pager($self);
1201         my $err = $?;
1202         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1203         waitpid($_, 0) for keys %$oneshot_pids;
1204         $? = $err if $err; # preserve ->fail or ->x_it code
1205 }
1206
1207 1;