lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(EPOLLIN);
  22 use PublicInbox::DS qw(dwaitpid);
  23 use PublicInbox::Spawn qw(spawn popen_rd);
  24 use PublicInbox::Lock;
  25 use PublicInbox::Eml;
  26 use PublicInbox::Import;
  27 use PublicInbox::ContentHash qw(git_sha);
  28 use Time::HiRes qw(stat); # ctime comparisons for config cache
  29 use File::Path qw(mkpath);
  30 use File::Spec;
  31 use Sys::Syslog qw(openlog syslog closelog);
  32 our $quit = \&CORE::exit;
  33 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle,
  34         $recv_cmd, $send_cmd);
  35 my $GLP = Getopt::Long::Parser->new;
  36 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  37 my $GLP_PASS = Getopt::Long::Parser->new;
  38 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  39
  40 our %PATH2CFG; # persistent for socket daemon
  41 our $MDIR2CFGPATH; # /path/to/maildir => { /path/to/config => [ ino watches ] }
  42
  43 # TBD: this is a documentation mechanism to show a subcommand
  44 # (may) pass options through to another command:
  45 sub pass_through { $GLP_PASS }
  46
  47 my $OPT;
  48 sub opt_dash ($$) {
  49         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  50         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  51         my $cb = sub { # Getopt::Long "<>" catch-all handler
  52                 my ($arg) = @_;
  53                 if ($arg =~ /\A-($re_str)\z/) {
  54                         $OPT->{$key} = $1;
  55                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  56                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  57                 # lone (single) dash is handled elsewhere
  58                 } elsif (substr($arg, 0, 1) eq '-') {
  59                         if ($OPT->{'--'}) {
  60                                 push @{$OPT->{-argv}}, $arg;
  61                         } else {
  62                                 die "bad argument: $arg\n";
  63                         }
  64                 } else {
  65                         push @{$OPT->{-argv}}, $arg;
  66                 }
  67         };
  68         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  69 }
  70
  71 # rel2abs preserves symlinks in parent, unlike abs_path
  72 sub rel2abs {
  73         my ($self, $p) = @_;
  74         if (index($p, '/') == 0) { # already absolute
  75                 $p =~ tr!/!/!s; # squeeze redundant slashes
  76                 chop($p) if substr($p, -1, 1) eq '/';
  77                 return $p;
  78         }
  79         my $pwd = $self->{env}->{PWD};
  80         if (defined $pwd) {
  81                 if (my @st_pwd = stat($pwd)) {
  82                         my @st_cwd = stat($self->{3}) or die "stat({3}): $!";
  83                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  84                                 $self->{env}->{PWD} = $pwd = undef;
  85                 } else { # PWD was invalid
  86                         $self->{env}->{PWD} = $pwd = undef;
  87                 }
  88         }
  89         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd: $!";
  90         File::Spec->rel2abs($p, $pwd);
  91 }
  92
  93 # abs_path resolves symlinks in parent iff all parents exist
  94 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  95
  96 sub canonpath_harder {
  97         my $p = $_[-1]; # $_[0] may be self
  98         $p = File::Spec->canonpath($p);
  99         $p =~ m!(?:/*|\A)\.\.(?:/*|\z)! && -e $p ? Cwd::abs_path($p) : $p;
 100 }
 101
 102 sub share_path ($) { # $HOME/.local/share/lei/$FOO
 103         my ($self) = @_;
 104         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
 105                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 106                 .'/lei');
 107 }
 108
 109 sub store_path ($) { share_path($_[0]) . '/store' }
 110
 111 sub _config_path ($) {
 112         my ($self) = @_;
 113         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 114                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 115                 .'/lei/config');
 116 }
 117
 118 sub cache_dir ($) {
 119         my ($self) = @_;
 120         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 121                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 122                 .'/lei');
 123 }
 124
 125 sub url_folder_cache {
 126         my ($self) = @_;
 127         require PublicInbox::SharedKV; # URI => updated_at_sec_
 128         PublicInbox::SharedKV->new(cache_dir($self).'/uri_folder');
 129 }
 130
 131 sub ale {
 132         my ($self) = @_;
 133         $self->{ale} //= do {
 134                 require PublicInbox::LeiALE;
 135                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 136         };
 137 }
 138
 139 sub index_opt {
 140         # TODO: drop underscore variants everywhere, they're undocumented
 141         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 142         max_size|max-size=s sequential-shard
 143         batch_size|batch-size=s skip-docdata)
 144 }
 145
 146 my @c_opt = qw(c=s@ C=s@ quiet|q);
 147 my @net_opt = (qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt());
 148 my @lxs_opt = qw(remote! local! external! include|I=s@ exclude=s@ only|O=s@
 149         import-remote!);
 150
 151 # we don't support -C as an alias for --find-copies since it's already
 152 # used for chdir
 153 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 154         output-indicator-context=s indent-heuristic!
 155         minimal patience histogram anchored=s@ diff-algorithm=s
 156         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 157         word-diff:s word-diff-regex=s color-words:s no-renames
 158         rename-empty! check ws-error-highlight=s full-index binary
 159         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 160         find-copies-harder irreversible-delete|D l=i diff-filter=s
 161         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 162         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 163         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 164         inter-hunk-context=i function-context|W exit-code ext-diff
 165         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 166         line-prefix=s);
 167
 168 # we generate shell completion + help using %CMD and %OPTDESC,
 169 # see lei__complete() and PublicInbox::LeiHelp
 170 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 171 our %CMD = ( # sorted in order of importance/use:
 172 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 173         'stdin|', # /|\z/ must be first for lone dash
 174         @lxs_opt, @net_opt,
 175         qw(save! output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 176         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 177         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 178         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 179
 180 'up' => [ 'OUTPUT...|--all', 'update saved search',
 181         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ exclude=s@
 182         remote-fudge-time=s all:s remote! local! external!), @c_opt ],
 183
 184 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 185         'stdin|', # /|\z/ must be first for lone dash
 186         # some of these options are ridiculous for lcat
 187         @lxs_opt, @net_opt,
 188         qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 189         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 190         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 191         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 192
 193 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 194         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 195         @lxs_opt, @net_opt, @c_opt ],
 196
 197 'rediff' => [ '--stdin|LOCATION...',
 198                 'regenerate a diff with different options',
 199         'stdin|', # /|\z/ must be first for lone dash
 200         qw(git-dir=s@ cwd! verbose|v+ color:s no-color drq:1 dequote-only:1),
 201         @diff_opt, @lxs_opt, @net_opt, @c_opt ],
 202
 203 'mail-diff' => [ '--stdin|LOCATION...', 'diff the contents of emails',
 204         'stdin|', # /|\z/ must be first for lone dash
 205         qw(verbose|v+ color:s no-color raw-header),
 206         @diff_opt, @net_opt, @c_opt ],
 207
 208 'add-external' => [ 'LOCATION',
 209         'add/set priority of a publicinbox|extindex for extra matches',
 210         qw(boost=i mirror=s inbox-version=i epoch=s verbose|v+),
 211         @c_opt, index_opt(), @net_opt ],
 212 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 213         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 214 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 215 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 216                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 217 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 218                 qw(z|0 ascii l pretty url), @c_opt ],
 219 'forget-external' => [ 'LOCATION...|--prune',
 220         'exclude further results from a publicinbox|extindex',
 221         qw(prune), @c_opt ],
 222
 223 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 224                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 225 'forget-search' => [ 'OUTPUT...', 'forget a saved search',
 226                 qw(verbose|v+), @c_opt ],
 227 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 228                         @c_opt ],
 229 'rm' => [ '--stdin|LOCATION...',
 230         'remove a message from the index and prevent reindexing',
 231         'stdin|', # /|\z/ must be first for lone dash
 232         qw(in-format|F=s lock=s@), @net_opt, @c_opt ],
 233 'plonk' => [ '--threads|--from=IDENT',
 234         'exclude mail matching From: or threads from non-Message-ID searches',
 235         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 236 'tag' => [ 'KEYWORDS...',
 237         'set/unset keywords and/or labels on message(s)',
 238         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 239         @net_opt, @c_opt, pass_through('-kw:foo for delete') ],
 240
 241 'purge-mailsource' => [ 'LOCATION|--all',
 242         'remove imported messages from IMAP, Maildirs, and MH',
 243         qw(exact! all jobs:i indexed), @c_opt ],
 244
 245 'add-watch' => [ 'LOCATION...', 'watch for new messages and flag changes',
 246         qw(poll-interval=s state=s recursive|r), @c_opt ],
 247 'rm-watch' => [ 'LOCATION...', 'remove specified watch(es)',
 248         qw(recursive|r), @c_opt ],
 249 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 250                 qw(l z|0), @c_opt ],
 251 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 252 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 253 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 254         qw(prune), @c_opt ],
 255
 256 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 257         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 258         verbose|v+ incremental!), @net_opt, # mainly for --proxy=
 259          @c_opt ],
 260 'import' => [ 'LOCATION...|--stdin',
 261         'one-time import/update from URL or filesystem',
 262         qw(stdin| offset=i recursive|r exclude=s include|I=s new-only
 263         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 264         @net_opt, @c_opt ],
 265 'forget-mail-sync' => [ 'LOCATION...',
 266         'forget sync information for a mail folder', @c_opt ],
 267 'refresh-mail-sync' => [ 'LOCATION...|--all',
 268         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 269 'export-kw' => [ 'LOCATION...|--all',
 270         'one-time export of keywords of sync sources',
 271         qw(all:s mode=s), @net_opt, @c_opt ],
 272 'convert' => [ 'LOCATION...|--stdin',
 273         'one-time conversion from URL or filesystem to another format',
 274         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 275         @net_opt, @c_opt ],
 276 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 277         "use a patch to generate a query for `lei q --stdin'",
 278         qw(stdin| want|w=s@ uri debug), @c_opt ],
 279 'config' => [ '[...]', sub {
 280                 'git-config(1) wrapper for '._config_path($_[0]);
 281         }, qw(config-file|system|global|file|f=s), # for conflict detection
 282          qw(edit|e c=s@ C=s@), pass_through('git config') ],
 283 'inspect' => [ 'ITEMS...|--stdin', 'inspect lei/store and/or local external',
 284         qw(stdin| pretty ascii dir|d=s), @c_opt ],
 285
 286 'init' => [ '[DIRNAME]', sub {
 287         "initialize storage, default: ".store_path($_[0]);
 288         }, @c_opt ],
 289 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 290         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 291         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 292 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 293 'help' => [ '[SUBCOMMAND]', 'show help' ],
 294
 295 # TODO
 296 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 297 #       'rewrite git history in an attempt to improve compression',
 298 #       qw(gc!), @c_opt ],
 299 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 300 #
 301 # internal commands are prefixed with '_'
 302 '_complete' => [ '[...]', 'internal shell completion helper',
 303                 pass_through('everything') ],
 304 ); # @CMD
 305
 306 # switch descriptions, try to keep consistent across commands
 307 # $spec: Getopt::Long option specification
 308 # $spec => [@ALLOWED_VALUES (default is first), $description],
 309 # $spec => $description
 310 # "$SUB_COMMAND TAB $spec" => as above
 311 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 312                         'specify message input format' ];
 313 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 314
 315 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 316 my %OPTDESC = (
 317 'help|h' => 'show this built-in help',
 318 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 319 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 320 'quiet|q' => 'be quiet',
 321 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 322         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 323
 324 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 325 'globoff|g' => "do not match locations using '*?' wildcards ".
 326                 "and\xa0'[]'\x{a0}ranges",
 327 'invert-match|v' => 'select non-matching lines',
 328 'color!' => 'disable color (for --format=text)',
 329 'verbose|v+' => 'be more verbose',
 330 'external!' => 'do not use externals',
 331 'mail!' => 'do not look in mail storage for OID',
 332 'cwd!' => 'do not look in git repo of current working directory',
 333 'oid-a|A=s' => 'pre-image OID',
 334 'path-a|a=s' => 'pre-image pathname associated with OID',
 335 'path-b|b=s' => 'post-image pathname associated with OID',
 336 'git-dir=s@' => 'additional git repository to scan',
 337 'dir|d=s        inspect' =>
 338         'specify a inboxdir, extindex topdir or Xapian shard',
 339 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 340         "proxy for (e.g. `socks5h://0:9050')" ],
 341 'torsocks=s' => ['VAL|auto|no|yes',
 342                 'whether or not to wrap git and curl commands with torsocks'],
 343 'no-torsocks' => 'alias for --torsocks=no',
 344 'save!' =>  "do not save a search for `lei up'",
 345 'import-remote!' => 'do not memoize remote messages into local store',
 346
 347 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 348
 349 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 350                 'deduplication strategy'],
 351 'threads|t+' =>
 352         'return all messages in the same threads as the actual match(es)',
 353
 354 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 355                 'search prefixes to extract (default: dfpost7)' ],
 356
 357 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 358         'run command(s) or perform ops when done writing to output ' .
 359         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 360         'nothing otherwise)' ],
 361
 362 'augment|a' => 'augment --output destination instead of clobbering',
 363
 364 'output|mfolder|o=s' => [ 'MFOLDER',
 365         "destination (e.g.\xa0`/path/to/Maildir', ".
 366         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 367 'mua=s' => [ 'CMD',
 368         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 369 'new-only       import' => 'only import new messages from IMAP source',
 370
 371 'inbox-version=i' => [ 'NUM|1|2',
 372                 'force a public-inbox version with --mirror'],
 373 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 374
 375 # public-inbox-index options
 376 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 377 'compact' => 'run compact index after mirroring',
 378 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 379         "indexlevel with --mirror (default: full)" ],
 380 'max_size|max-size=s' => [ 'SIZE',
 381         'do not index messages larger than SIZE (default: infinity)' ],
 382 'batch_size|batch-size=s' => [ 'SIZE',
 383         'flush changes to OS after given number of bytes (default: 1m)' ],
 384 'sequential-shard' =>
 385         'index Xapian shards sequentially for slow storage',
 386 'skip-docdata' =>
 387         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 388
 389 'format|f=s     q' => [
 390         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 391                 'specify output format, default depends on --output'],
 392 'exclude=s@     q' => [ 'LOCATION',
 393                 'exclude specified external(s) from search' ],
 394 'include|I=s@   q' => [ 'LOCATION',
 395                 'include specified external(s) in search' ],
 396 'only|O=s@      q' => [ 'LOCATION',
 397                 'only use specified external(s) for search' ],
 398 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 399                 'control number of search and writer jobs' ],
 400 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 401
 402 'in-format|F=s' => $stdin_formats,
 403 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 404                         'listing output format' ],
 405 'l      ls-search' => 'long listing format',
 406 'l      ls-watch' => 'long listing format',
 407 'l      ls-mail-source' => 'long listing format',
 408 'url    ls-mail-source' => 'show full URL of newsgroup or IMAP folder',
 409 'format|f=s     ls-external' => $ls_format,
 410
 411 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 412 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 413
 414 'sort|s=s' => [ 'VAL|received|relevance|docid',
 415                 "order of results is `--output'-dependent"],
 416 'reverse|r' => 'reverse search results', # like sort(1)
 417
 418 'boost=i' => 'increase/decrease priority of results (default: 0)',
 419
 420 'local' => 'limit operations to the local filesystem',
 421 'local!' => 'exclude results from the local filesystem',
 422 'remote' => 'limit operations to those requiring network access',
 423 'remote!' => 'prevent operations requiring network access',
 424
 425 # up, refresh-mail-sync, export-kw
 426 'all:s' => ['TYPE|local|remote', 'all remote or local folders' ],
 427
 428 'remote-fudge-time=s' => [ 'INTERVAL',
 429         'look for mail INTERVAL older than the last successful query' ],
 430
 431 'mid=s' => 'specify the Message-ID of a message',
 432 'oid=s' => 'specify the git object ID of a message',
 433
 434 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 435 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 436 'include=s' => 'include mailboxes/newsgroups based on pattern',
 437
 438 'exact' => 'operate on exact header matches only',
 439 'exact!' => 'rely on content match instead of exact header matches',
 440
 441 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 442
 443 'kw!' => 'disable/enable importing keywords (aka "flags")',
 444
 445 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 446 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 447
 448 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 449 ); # %OPTDESC
 450
 451 my %CONFIG_KEYS = (
 452         'leistore.dir' => 'top-level storage location',
 453 );
 454
 455 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1 lne v2w); # internal workers
 456
 457 sub _drop_wq {
 458         my ($self) = @_;
 459         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 460                 $wq->wq_kill('-TERM');
 461                 $wq->DESTROY;
 462         }
 463 }
 464
 465 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 466 sub x_it ($$) {
 467         my ($self, $code) = @_;
 468         local $current_lei = $self;
 469         # make sure client sees stdout before exit
 470         $self->{1}->autoflush(1) if $self->{1};
 471         stop_pager($self);
 472         if ($self->{pkt_op_p}) { # worker => lei-daemon
 473                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 474         } elsif ($self->{sock}) { # lei->daemon => lei(1) client
 475                 send($self->{sock}, "x_it $code", MSG_EOR);
 476         } elsif ($quit == \&CORE::exit) { # an admin (one-shot) command
 477                 exit($code >> 8);
 478         } # else ignore if client disconnected
 479 }
 480
 481 sub err ($;@) {
 482         my $self = shift;
 483         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 484         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 485         print $err @_, @eor and return;
 486         my $old_err = delete $self->{2};
 487         close($old_err) if $! == EPIPE && $old_err;
 488         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 489         print $err @_, @eor or print STDERR @_, @eor;
 490 }
 491
 492 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 493
 494 sub qfin { # show message on finalization (LeiFinmsg)
 495         my ($lei, $msg) = @_;
 496         return if $lei->{opt}->{quiet};
 497         $lei->{fmsg} ? push(@{$lei->{fmsg}}, "$msg\n") : qerr($lei, $msg);
 498 }
 499
 500 sub fail_handler ($;$$) {
 501         my ($lei, $code, $io) = @_;
 502         local $current_lei = $lei;
 503         close($io) if $io; # needed to avoid warnings on SIGPIPE
 504         _drop_wq($lei);
 505         x_it($lei, $code // (1 << 8));
 506 }
 507
 508 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 509         fail_handler($_[0], 13, delete $_[0]->{1});
 510 }
 511
 512 sub fail ($$;$) {
 513         my ($self, $msg, $exit_code) = @_;
 514         local $current_lei = $self;
 515         $self->{failed}++;
 516         warn(substr($msg, -1, 1) eq "\n" ? $msg : "$msg\n") if defined $msg;
 517         $self->{pkt_op_p}->pkt_do('fail_handler') if $self->{pkt_op_p};
 518         x_it($self, ($exit_code // 1) << 8);
 519         undef;
 520 }
 521
 522 sub out ($;@) {
 523         my $self = shift;
 524         return if print { $self->{1} // return } @_; # likely
 525         return note_sigpipe($self, 1) if $! == EPIPE;
 526         my $err = "error writing to output: $!";
 527         delete $self->{1};
 528         fail($self, $err);
 529 }
 530
 531 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 532
 533 sub child_error { # passes non-fatal curl exit codes to user
 534         my ($self, $child_error, $msg) = @_; # child_error is $?
 535         local $current_lei = $self;
 536         $child_error ||= 1 << 8;
 537         warn(substr($msg, -1, 1) eq "\n" ? $msg : "$msg\n") if defined $msg;
 538         if ($self->{pkt_op_p}) { # to top lei-daemon
 539                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 540         } elsif ($self->{sock}) { # to lei(1) client
 541                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 542         } else { # non-lei admin command
 543                 $self->{child_error} ||= $child_error;
 544         } # else noop if client disconnected
 545 }
 546
 547 sub note_sigpipe { # triggers sigpipe_handler
 548         my ($self, $fd) = @_;
 549         close(delete($self->{$fd})); # explicit close silences Perl warning
 550         $self->{pkt_op_p}->pkt_do('sigpipe_handler') if $self->{pkt_op_p};
 551         x_it($self, 13);
 552 }
 553
 554 sub _lei_atfork_child {
 555         my ($self, $persist) = @_;
 556         # we need to explicitly close things which are on stack
 557         if ($persist) {
 558                 open $self->{3}, '<', '/' or die "open(/) $!";
 559                 fchdir($self);
 560                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 561                 if (my $cfg = $self->{cfg}) {
 562                         delete @$cfg{qw(-lei_store -watches -lei_note_event)};
 563                 }
 564         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 565                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 566                 STDERR->autoflush(1);
 567                 POSIX::setpgid(0, $$) // die "setpgid(0, $$): $!";
 568         }
 569         close($_) for (grep(defined, delete @$self{qw(old_1 au_done)}));
 570         delete $self->{-socks};
 571         if (my $op_c = delete $self->{pkt_op_c}) {
 572                 close(delete $op_c->{sock});
 573         }
 574         if (my $pgr = delete $self->{pgr}) {
 575                 close($_) for (@$pgr[1,2]);
 576         }
 577         close $listener if $listener;
 578         undef $listener;
 579         $dir_idle->force_close if $dir_idle;
 580         undef $dir_idle;
 581         %PATH2CFG = ();
 582         $MDIR2CFGPATH = {};
 583         eval 'no warnings; undef $PublicInbox::LeiNoteEvent::to_flush';
 584         undef $errors_log;
 585         $quit = \&CORE::exit;
 586         if (!$self->{-eml_noisy}) { # only "lei import" sets this atm
 587                 my $cb = $SIG{__WARN__} // \&CORE::warn;
 588                 $SIG{__WARN__} = sub {
 589                         $cb->(@_) unless PublicInbox::Eml::warn_ignore(@_)
 590                 };
 591         }
 592         $SIG{TERM} = sub { exit(128 + 15) };
 593         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 594 }
 595
 596 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 597         my ($self) = @_;
 598         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 599                 $op->close; # PublicInbox::PktOp::close
 600         }
 601         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 602         close $pkt_op_p->{op_p};
 603 }
 604
 605 sub pkt_op_pair {
 606         my ($self) = @_;
 607         require PublicInbox::OnDestroy;
 608         require PublicInbox::PktOp;
 609         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 610         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 611         $end;
 612 }
 613
 614 sub incr {
 615         my ($self, $field, $nr) = @_;
 616         $self->{counters}->{$field} += $nr;
 617 }
 618
 619 sub pkt_ops {
 620         my ($lei, $ops) = @_;
 621         $ops->{fail_handler} = [ $lei ];
 622         $ops->{sigpipe_handler} = [ $lei ];
 623         $ops->{x_it} = [ $lei ];
 624         $ops->{child_error} = [ $lei ];
 625         $ops->{incr} = [ $lei ];
 626         $ops;
 627 }
 628
 629 sub workers_start {
 630         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 631         $ops = pkt_ops($lei, { ($ops ? %$ops : ()) });
 632         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 633         my $end = $lei->pkt_op_pair;
 634         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 635         $flds->{lei} = $lei;
 636         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 637         delete $lei->{pkt_op_p};
 638         my $op_c = delete $lei->{pkt_op_c};
 639         @$end = ();
 640         $lei->event_step_init;
 641         $wq->wq_wait_async($wq->can('_wq_done_wait') // \&wq_done_wait, $lei);
 642         ($op_c, $ops);
 643 }
 644
 645 # call this when we're ready to wait on events and yield to other clients
 646 sub wait_wq_events {
 647         my ($lei, $op_c, $ops) = @_;
 648         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 649                 $wq->wq_close;
 650         }
 651         $op_c->{ops} = $ops;
 652 }
 653
 654 sub _help {
 655         require PublicInbox::LeiHelp;
 656         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 657 }
 658
 659 sub optparse ($$$) {
 660         my ($self, $cmd, $argv) = @_;
 661         # allow _complete --help to complete, not show help
 662         return 1 if substr($cmd, 0, 1) eq '_';
 663         $self->{cmd} = $cmd;
 664         $OPT = $self->{opt} //= {};
 665         my $info = $CMD{$cmd} // [ '[...]' ];
 666         my ($proto, undef, @spec) = @$info;
 667         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 668         push @spec, qw(help|h);
 669         my $lone_dash;
 670         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 671                 $lone_dash = $spec[0];
 672                 $OPT->{$spec[0]} = \(my $var);
 673                 push @spec, '' => \$var;
 674         }
 675         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 676                 return _help($self, "bad arguments or options for $cmd");
 677         return _help($self) if $OPT->{help};
 678
 679         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 680
 681         # "-" aliases "stdin" or "clear"
 682         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 683
 684         my $i = 0;
 685         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 686         my ($err, $inf);
 687         my @args = split(/ /, $proto);
 688         for my $var (@args) {
 689                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 690                         $inf = defined($argv->[$i]) and last;
 691                         $var =~ s/\.\.\.\z//;
 692                         $err = "$var not supplied";
 693                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 694                         $argv->[$i++] // ($err = "$var not supplied");
 695                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 696                         $inf = 1;
 697                         last;
 698                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 699                         $i++;
 700                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 701                         $inf = 1 if index($var, '...') > 0;
 702                         my @or = split(/\|/, $var);
 703                         my $ok;
 704                         for my $o (@or) {
 705                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 706                                         my $sw = $1;
 707                                         # assume pipe/regular file on stdin
 708                                         # w/o args means stdin
 709                                         if ($sw eq 'stdin' && !@$argv &&
 710                                                         (-p $self->{0} ||
 711                                                          -f _) && -r _) {
 712                                                 $OPT->{stdin} //= 1;
 713                                         }
 714                                         $ok = defined($OPT->{$sw});
 715                                         last if $ok;
 716                                 } elsif (defined($argv->[$i])) {
 717                                         $ok = 1;
 718                                         $i++;
 719                                         last;
 720                                 } # else continue looping
 721                         }
 722                         last if $ok;
 723                         my $last = pop @or;
 724                         $err = join(', ', @or) . " or $last must be set";
 725                 } else {
 726                         warn "BUG: can't parse `$var' in $proto";
 727                 }
 728                 last if $err;
 729         }
 730         if (!$inf && scalar(@$argv) > scalar(@args)) {
 731                 $err //= 'too many arguments';
 732         }
 733         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 734 }
 735
 736 sub _tmp_cfg { # for lei -c <name>=<value> ...
 737         my ($self) = @_;
 738         my $cfg = _lei_cfg($self, 1);
 739         require File::Temp;
 740         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 741         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 742         $ft->autoflush(1);
 743         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 744 [include]
 745         path = $cfg->{-f}
 746 EOM
 747         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 748         for (@{$self->{opt}->{c}}) {
 749                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 750 `-c $_' is not of the form -c <name>=<value>'
 751 EOM
 752                 my $name = $1;
 753                 my $value = $2 // 1;
 754                 _config($self, '--add', $name, $value);
 755                 if (defined(my $v = $tmp->{$name})) {
 756                         if (ref($v) eq 'ARRAY') {
 757                                 push @$v, $value;
 758                         } else {
 759                                 $tmp->{$name} = [ $v, $value ];
 760                         }
 761                 } else {
 762                         $tmp->{$name} = $value;
 763                 }
 764         }
 765 }
 766
 767 sub lazy_cb ($$$) {
 768         my ($self, $cmd, $pfx) = @_;
 769         my $ucmd = $cmd;
 770         $ucmd =~ tr/-/_/;
 771         my $cb;
 772         $cb = $self->can($pfx.$ucmd) and return $cb;
 773         my $base = $ucmd;
 774         $base =~ s/_([a-z])/\u$1/g;
 775         my $pkg = "PublicInbox::Lei\u$base";
 776         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 777                 $pkg->can($pfx.$ucmd) : undef;
 778 }
 779
 780 sub dispatch {
 781         my ($self, $cmd, @argv) = @_;
 782         fchdir($self);
 783         local %ENV = %{$self->{env}};
 784         local $current_lei = $self; # for __WARN__
 785         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 786         return _help($self, 'no command given') unless defined($cmd);
 787         # do not support Getopt bundling for this
 788         while ($cmd eq '-C' || $cmd eq '-c') {
 789                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 790                                         '-C DIRECTORY' : '-c <name>=<value>');
 791                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 792                 $cmd = shift(@argv) // return _help($self, 'no command given');
 793         }
 794         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 795                 optparse($self, $cmd, \@argv) or return;
 796                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 797                 if (my $chdir = $self->{opt}->{C}) {
 798                         for my $d (@$chdir) {
 799                                 next if $d eq ''; # same as git(1)
 800                                 chdir $d or return fail($self, "cd $d: $!");
 801                         }
 802                         open $self->{3}, '.' or return fail($self, "open . $!");
 803                 }
 804                 $cb->($self, @argv);
 805         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 806                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 807                         or return _help($self, 'bad arguments or options');
 808                 _help($self);
 809         } else {
 810                 fail($self, "`$cmd' is not an lei command");
 811         }
 812 }
 813
 814 sub _lei_cfg ($;$) {
 815         my ($self, $creat) = @_;
 816         return $self->{cfg} if $self->{cfg};
 817         my $f = _config_path($self);
 818         my @st = stat($f);
 819         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 820         my ($sto, $sto_dir, $watches, $lne);
 821         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 822                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 823                 ($sto, $sto_dir, $watches, $lne) =
 824                                 @$cfg{qw(-lei_store leistore.dir -watches
 825                                         -lei_note_event)};
 826         }
 827         if (!@st) {
 828                 unless ($creat) {
 829                         delete $self->{cfg};
 830                         return bless {}, 'PublicInbox::Config';
 831                 }
 832                 my ($cfg_dir) = ($f =~ m!(.*?/)[^/]+\z!);
 833                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 834                 open my $fh, '>>', $f or die "open($f): $!\n";
 835                 @st = stat($fh) or die "fstat($f): $!\n";
 836                 $cur_st = pack('dd', $st[10], $st[7]);
 837                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 838         }
 839         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{2});
 840         $cfg->{-st} = $cur_st;
 841         $cfg->{'-f'} = $f;
 842         if ($sto && canonpath_harder($sto_dir // store_path($self))
 843                         eq canonpath_harder($cfg->{'leistore.dir'} //
 844                                                 store_path($self))) {
 845                 $cfg->{-lei_store} = $sto;
 846                 $cfg->{-lei_note_event} = $lne;
 847                 $cfg->{-watches} = $watches if $watches;
 848         }
 849         if (scalar(keys %PATH2CFG) > 5) {
 850                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 851                 delete(@PATH2CFG{grep(!-f, keys %PATH2CFG)});
 852         }
 853         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 854         refresh_watches($self);
 855         $cfg;
 856 }
 857
 858 sub _lei_store ($;$) {
 859         my ($self, $creat) = @_;
 860         my $cfg = _lei_cfg($self, $creat) // return;
 861         $cfg->{-lei_store} //= do {
 862                 require PublicInbox::LeiStore;
 863                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 864                 return unless $creat || -d $dir;
 865                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 866         };
 867 }
 868
 869 sub _config {
 870         my ($self, @argv) = @_;
 871         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 872         my $cfg = _lei_cfg($self, 1);
 873         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 874         my %rdr = map { $_ => $self->{$_} } (0..2);
 875         waitpid(spawn($cmd, \%env, \%rdr), 0);
 876 }
 877
 878 sub lei_daemon_pid { puts shift, $$ }
 879
 880 sub lei_daemon_kill {
 881         my ($self) = @_;
 882         my $sig = $self->{opt}->{signal} // 'TERM';
 883         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 884 }
 885
 886 # Shell completion helper.  Used by lei-completion.bash and hopefully
 887 # other shells.  Try to do as much here as possible to avoid redundancy
 888 # and improve maintainability.
 889 sub lei__complete {
 890         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 891         shift @argv; # ignore "lei", the entire command is sent
 892         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 893         my $cmd = shift @argv;
 894         my $info = $CMD{$cmd} // do { # filter matching commands
 895                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 896                 return;
 897         };
 898         my ($proto, undef, @spec) = @$info;
 899         my $cur = pop @argv;
 900         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 901         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 902                 # gross special case since the only git-config options
 903                 # Consider moving to a table if we need more special cases
 904                 # we use Getopt::Long for are the ones we reject, so these
 905                 # are the ones we don't reject:
 906                 if ($cmd eq 'config') {
 907                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 908                         @spec = qw(add z|null get get-all unset unset-all
 909                                 replace-all get-urlmatch
 910                                 remove-section rename-section
 911                                 name-only list|l edit|e
 912                                 get-color-name get-colorbool);
 913                         # fall-through
 914                 }
 915                 # generate short/long names from Getopt::Long specs
 916                 puts $self, grep(/$re/, qw(--help -h -C), map {
 917                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 918                         } elsif (s/\+\z//) { # verbose|v+
 919                         } elsif (s/!\z//) {
 920                                 # negation: mail! => no-mail|mail
 921                                 s/([\w\-]+)/$1|no-$1/g
 922                         }
 923                         map {
 924                                 my $x = length > 1 ? "--$_" : "-$_";
 925                                 $x eq $_cur ? () : $x;
 926                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 927                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 928         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 929                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 930         }
 931
 932         # switch args (e.g. lei q -f mbox<TAB>)
 933         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 934                 my $opt = quotemeta $1;
 935                 puts $self, map {
 936                         my $v = $OPTDESC{$_};
 937                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 938                         # get rid of ALL CAPS placeholder (e.g "OUT")
 939                         # (TODO: completion for external paths)
 940                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 941                         @v;
 942                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 943         }
 944         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 945                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 946         }
 947         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 948         # proto parsing.
 949 }
 950
 951 sub exec_buf ($$) {
 952         my ($argv, $env) = @_;
 953         my $argc = scalar @$argv;
 954         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 955         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 956         $buf;
 957 }
 958
 959 sub start_mua {
 960         my ($self) = @_;
 961         if ($self->{ovv}->{fmt} =~ /\A(?:maildir)\z/) { # TODO: IMAP
 962                 refresh_watches($self);
 963         }
 964         my $mua = $self->{opt}->{mua} // return;
 965         my $mfolder = $self->{ovv}->{dst};
 966         my (@cmd, $replaced);
 967         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 968                 @cmd = ($mua, '-f');
 969         # TODO: help wanted: other common FOSS MUAs
 970         } else {
 971                 require Text::ParseWords;
 972                 @cmd = Text::ParseWords::shellwords($mua);
 973                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 974                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 975         }
 976         push @cmd, $mfolder unless defined($replaced);
 977         if ($self->{sock}) { # lei(1) client process runs it
 978                 # restore terminal: echo $query | lei q --stdin --mua=...
 979                 my $io = [];
 980                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 981                 send_exec_cmd($self, $io, \@cmd, {});
 982         }
 983         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 984                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 985         }
 986         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 987         $self->{opt}->{quiet} = 1;
 988         delete $self->{-progress};
 989         delete $self->{opt}->{verbose};
 990 }
 991
 992 sub send_exec_cmd { # tell script/lei to execute a command
 993         my ($self, $io, $cmd, $env) = @_;
 994         my $sock = $self->{sock} // die 'lei client gone';
 995         my $fds = [ map { fileno($_) } @$io ];
 996         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 997 }
 998
 999 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
1000         my ($self) = @_;
1001         my $alerts = $self->{opt}->{alert} // return;
1002         my $sock = $self->{sock};
1003         while (my $op = shift(@$alerts)) {
1004                 if ($op eq ':WINCH') {
1005                         # hit the process group that started the MUA
1006                         send($sock, '-WINCH', MSG_EOR) if $sock;
1007                 } elsif ($op eq ':bell') {
1008                         out($self, "\a");
1009                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
1010                         push @$alerts, split(/(?<!\\),/, $op);
1011                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
1012                         my $cmd = $1; # run an arbitrary command
1013                         require Text::ParseWords;
1014                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
1015                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
1016                 } else {
1017                         warn("W: unsupported --alert=$op\n"); # non-fatal
1018                 }
1019         }
1020 }
1021
1022 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
1023 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
1024
1025 # this also normalizes the path
1026 sub path_to_fd {
1027         my ($self, $path) = @_;
1028         $path = rel2abs($self, $path);
1029         $path =~ tr!/!/!s;
1030         $path_to_fd{$path} // (
1031                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
1032                         fail($self, "cannot open $path from daemon") : -1
1033         );
1034 }
1035
1036 # caller needs to "-t $self->{1}" to check if tty
1037 sub start_pager {
1038         my ($self, $new_env) = @_;
1039         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1040         chomp(my $pager = <$fh> // '');
1041         close($fh) or warn "`git var PAGER' error: \$?=$?";
1042         return if $pager eq 'cat' || $pager eq '';
1043         $new_env //= {};
1044         $new_env->{LESS} //= 'FRX';
1045         $new_env->{LV} //= '-c';
1046         $new_env->{MORE} = $new_env->{LESS} if $^O eq 'freebsd';
1047         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1048         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1049         my $pgr = [ undef, @$rdr{1, 2} ];
1050         my $env = $self->{env};
1051         if ($self->{sock}) { # lei(1) process runs it
1052                 delete @$new_env{keys %$env}; # only set iff unset
1053                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1054         } else {
1055                 die 'BUG: start_pager w/o socket';
1056         }
1057         $self->{1} = $wpager;
1058         $self->{2} = $wpager if -t $self->{2};
1059         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1060         $self->{pgr} = $pgr;
1061 }
1062
1063 # display a message for user before spawning full-screen $VISUAL
1064 sub pgr_err {
1065         my ($self, @msg) = @_;
1066         return warn(@msg) unless $self->{sock} && -t $self->{2};
1067         start_pager($self, { LESS => 'RX' }); # no 'F' so we prompt
1068         print { $self->{2} } @msg;
1069         $self->{2}->autoflush(1);
1070         stop_pager($self);
1071         send($self->{sock}, 'wait', MSG_EOR); # wait for user to quit pager
1072 }
1073
1074 sub stop_pager {
1075         my ($self) = @_;
1076         my $pgr = delete($self->{pgr}) or return;
1077         $self->{2} = $pgr->[2];
1078         close(delete($self->{1})) if $self->{1};
1079         $self->{1} = $pgr->[1];
1080 }
1081
1082 sub accept_dispatch { # Listener {post_accept} callback
1083         my ($sock) = @_; # ignore other
1084         $sock->autoflush(1);
1085         my $self = bless { sock => $sock }, __PACKAGE__;
1086         vec(my $rvec = '', fileno($sock), 1) = 1;
1087         select($rvec, undef, undef, 60) or
1088                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1089         # (4096 * 33) >MAX_ARG_STRLEN
1090         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1091         if (!defined($fds[0])) {
1092                 warn(my $msg = "recv_cmd failed: $!");
1093                 return send($sock, $msg, MSG_EOR);
1094         } else {
1095                 my $i = 0;
1096                 for my $fd (@fds) {
1097                         open($self->{$i++}, '+<&=', $fd) and next;
1098                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1099                 }
1100                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1101         }
1102         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1103         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1104         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1105                 return send($sock, 'request command truncated', MSG_EOR);
1106         my ($argc, @argv) = split(/\0/, $buf, -1);
1107         undef $buf;
1108         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1109         $self->{env} = \%env;
1110         eval { dispatch($self, @argv) };
1111         $self->fail($@) if $@;
1112 }
1113
1114 sub dclose {
1115         my ($self) = @_;
1116         local $current_lei = $self;
1117         delete $self->{-progress};
1118         _drop_wq($self) if $self->{failed};
1119         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1120 }
1121
1122 # for long-running results
1123 sub event_step {
1124         my ($self) = @_;
1125         local %ENV = %{$self->{env}};
1126         local $current_lei = $self;
1127         eval {
1128                 my @fds = $recv_cmd->($self->{sock}, my $buf, 4096);
1129                 if (scalar(@fds) == 1 && !defined($fds[0])) {
1130                         return if $! == EAGAIN;
1131                         die "recvmsg: $!" if $! != ECONNRESET;
1132                 }
1133                 for (@fds) { open my $rfh, '+<&=', $_ }
1134                 if ($buf eq '') {
1135                         _drop_wq($self); # EOF, client disconnected
1136                         dclose($self);
1137                         $buf = 'TERM';
1138                 }
1139                 if ($buf =~ /\A(?:STOP|CONT|TERM)\z/) {
1140                         my $sig = "-$buf";
1141                         for my $wq (grep(defined, @$self{@WQ_KEYS})) {
1142                                 $wq->wq_kill($sig);
1143                         }
1144                 } else {
1145                         die "unrecognized client signal: $buf";
1146                 }
1147                 my $s = $self->{-socks} // []; # lei up --all
1148                 @$s = grep { send($_, $buf, MSG_EOR) } @$s;
1149         };
1150         if (my $err = $@) {
1151                 eval { $self->fail($err) };
1152                 dclose($self);
1153         }
1154 }
1155
1156 sub event_step_init {
1157         my ($self) = @_;
1158         my $sock = $self->{sock} or return;
1159         $self->{-event_init_done} //= do { # persist til $ops done
1160                 $sock->blocking(0);
1161                 $self->SUPER::new($sock, EPOLLIN);
1162                 $sock;
1163         };
1164 }
1165
1166 sub noop {}
1167
1168 sub oldset { $oldset }
1169
1170 sub dump_and_clear_log {
1171         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1172                 openlog('lei-daemon', 'pid,nowait,nofatal,ndelay', 'user');
1173                 chomp(my @lines = <STDIN>);
1174                 truncate(STDIN, 0) or
1175                         syslog('warning', "ftruncate (%s): %m", $errors_log);
1176                 for my $l (@lines) { syslog('warning', '%s', $l) }
1177                 closelog(); # don't share across fork
1178         }
1179 }
1180
1181 sub cfg2lei ($) {
1182         my ($cfg) = @_;
1183         my $lei = bless { env => { %{$cfg->{-env}} } }, __PACKAGE__;
1184         open($lei->{0}, '<&', \*STDIN) or die "dup 0: $!";
1185         open($lei->{1}, '>>&', \*STDOUT) or die "dup 1: $!";
1186         open($lei->{2}, '>>&', \*STDERR) or die "dup 2: $!";
1187         open($lei->{3}, '<', '/') or die "open /: $!";
1188         my ($x, $y);
1189         socketpair($x, $y, AF_UNIX, SOCK_SEQPACKET, 0) or die "socketpair: $!";
1190         $lei->{sock} = $x;
1191         require PublicInbox::LeiSelfSocket;
1192         PublicInbox::LeiSelfSocket->new($y); # adds to event loop
1193         $lei;
1194 }
1195
1196 sub dir_idle_handler ($) { # PublicInbox::DirIdle callback
1197         my ($ev) = @_; # Linux::Inotify2::Event or duck type
1198         my $fn = $ev->fullname;
1199         if ($fn =~ m!\A(.+)/(new|cur)/([^/]+)\z!) { # Maildir file
1200                 my ($mdir, $nc, $bn) = ($1, $2, $3);
1201                 $nc = '' if $ev->IN_DELETE || $ev->IN_MOVED_FROM;
1202                 for my $f (keys %{$MDIR2CFGPATH->{$mdir} // {}}) {
1203                         my $cfg = $PATH2CFG{$f} // next;
1204                         eval {
1205                                 my $lei = cfg2lei($cfg);
1206                                 $lei->dispatch('note-event',
1207                                                 "maildir:$mdir", $nc, $bn, $fn);
1208                         };
1209                         warn "E: note-event $f: $@\n" if $@;
1210                 }
1211         }
1212         if ($ev->can('cancel') && ($ev->IN_IGNORE || $ev->IN_UNMOUNT)) {
1213                 $ev->cancel;
1214         }
1215         if ($fn =~ m!\A(.+)/(?:new|cur)\z! && !-e $fn) {
1216                 delete $MDIR2CFGPATH->{$1};
1217         }
1218         if (!-e $fn) { # config file or Maildir gone
1219                 for my $cfgpaths (values %$MDIR2CFGPATH) {
1220                         delete $cfgpaths->{$fn};
1221                 }
1222                 delete $PATH2CFG{$fn};
1223         }
1224 }
1225
1226 # lei(1) calls this when it can't connect
1227 sub lazy_start {
1228         my ($path, $errno, $narg) = @_;
1229         local ($errors_log, $listener);
1230         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1231         $errors_log = "$sock_dir/errors.log";
1232         my $addr = pack_sockaddr_un($path);
1233         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1234         umask(077) // die("umask(077): $!");
1235         $lk->lock_acquire;
1236         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1237         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1238                 return if connect($listener, $addr); # another process won
1239                 if ($errno == ECONNREFUSED && -S $path) {
1240                         unlink($path) or die "unlink($path): $!";
1241                 }
1242         } else {
1243                 $! = $errno; # allow interpolation to stringify in die
1244                 die "connect($path): $!";
1245         }
1246         bind($listener, $addr) or die "bind($path): $!";
1247         $lk->lock_release;
1248         undef $lk;
1249         my @st = stat($path) or die "stat($path): $!";
1250         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1251         local $oldset = PublicInbox::DS::block_signals();
1252         if ($narg == 5) {
1253                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1254                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1255                         require PublicInbox::CmdIPC4;
1256                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1257                         PublicInbox::CmdIPC4->can('recv_cmd4');
1258                 };
1259         }
1260         $recv_cmd or die <<"";
1261 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1262
1263         require PublicInbox::Listener;
1264         require PublicInbox::PktOp;
1265         (-p STDOUT) or die "E: stdout must be a pipe\n";
1266         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1267         STDIN->autoflush(1);
1268         dump_and_clear_log();
1269         POSIX::setsid() > 0 or die "setsid: $!";
1270         my $pid = fork // die "fork: $!";
1271         return if $pid;
1272         $0 = "lei-daemon $path";
1273         local %PATH2CFG;
1274         local $MDIR2CFGPATH;
1275         $listener->blocking(0);
1276         my $exit_code;
1277         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1278         local $quit = do {
1279                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1280                 sub {
1281                         $exit_code //= shift;
1282                         eval 'PublicInbox::LeiNoteEvent::flush_task()';
1283                         my $lis = $pil or exit($exit_code);
1284                         # closing eof_p triggers \&noop wakeup
1285                         $listener = $eof_p = $pil = $path = undef;
1286                         $lis->close; # DS::close
1287                         PublicInbox::DS->SetLoopTimeout(1000);
1288                 };
1289         };
1290         my $sig = {
1291                 CHLD => \&PublicInbox::DS::enqueue_reap,
1292                 QUIT => $quit,
1293                 INT => $quit,
1294                 TERM => $quit,
1295                 HUP => \&noop,
1296                 USR1 => \&noop,
1297                 USR2 => \&noop,
1298         };
1299         require PublicInbox::DirIdle;
1300         local $dir_idle = PublicInbox::DirIdle->new(sub {
1301                 # just rely on wakeup to hit PostLoopCallback set below
1302                 dir_idle_handler($_[0]) if $_[0]->fullname ne $path;
1303         });
1304         $dir_idle->add_watches([$sock_dir]);
1305         PublicInbox::DS->SetPostLoopCallback(sub {
1306                 my ($dmap, undef) = @_;
1307                 if (@st = defined($path) ? stat($path) : ()) {
1308                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1309                                 warn "$path dev/ino changed, quitting\n";
1310                                 $path = undef;
1311                         }
1312                 } elsif (defined($path)) { # ENOENT is common
1313                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1314                         undef $path;
1315                         $quit->();
1316                 }
1317                 return 1 if defined($path);
1318                 my $n = 0;
1319                 for my $s (values %$dmap) {
1320                         $s->can('busy') or next;
1321                         if ($s->busy) {
1322                                 ++$n;
1323                         } else {
1324                                 $s->close;
1325                         }
1326                 }
1327                 $n; # true: continue, false: stop
1328         });
1329
1330         # STDIN was redirected to /dev/null above, closing STDERR and
1331         # STDOUT will cause the calling `lei' client process to finish
1332         # reading the <$daemon> pipe.
1333         local $SIG{__WARN__} = sub {
1334                 $current_lei ? err($current_lei, @_) : warn(
1335                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1336         };
1337         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1338         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1339         # $daemon pipe to `lei' closed, main loop begins:
1340         eval { PublicInbox::DS::event_loop($sig, $oldset) };
1341         warn "event loop error: $@\n" if $@;
1342         # exit() may trigger waitpid via various DESTROY, ensure interruptible
1343         PublicInbox::DS::sig_setmask($oldset);
1344         dump_and_clear_log();
1345         exit($exit_code // 0);
1346 }
1347
1348 sub busy { 1 } # prevent daemon-shutdown if client is connected
1349
1350 # ensures stdout hits the FS before sock disconnects so a client
1351 # can immediately reread it
1352 sub DESTROY {
1353         my ($self) = @_;
1354         if (my $counters = delete $self->{counters}) {
1355                 for my $k (sort keys %$counters) {
1356                         my $nr = $counters->{$k};
1357                         $self->child_error(0, "$nr $k messages");
1358                 }
1359         }
1360         $self->{1}->autoflush(1) if $self->{1};
1361         stop_pager($self);
1362         dump_and_clear_log();
1363         # preserve $? for ->fail or ->x_it code
1364 }
1365
1366 sub wq_done_wait { # dwaitpid callback
1367         my ($arg, $pid) = @_;
1368         my ($wq, $lei) = @$arg;
1369         local $current_lei = $lei;
1370         my $err_type = $lei->{-err_type};
1371         $? and $lei->child_error($?,
1372                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1373         $lei->dclose;
1374 }
1375
1376 sub fchdir {
1377         my ($lei) = @_;
1378         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1379         chdir($dh) || die "fchdir: $!";
1380 }
1381
1382 sub wq_eof { # EOF callback for main daemon
1383         my ($lei) = @_;
1384         local $current_lei = $lei;
1385         delete $lei->{wq1} // return $lei->fail; # already failed
1386 }
1387
1388 sub watch_state_ok ($) {
1389         my ($state) = $_[-1]; # $_[0] may be $self
1390         $state =~ /\Apause|(?:import|index|tag)-(?:ro|rw)\z/;
1391 }
1392
1393 sub cancel_maildir_watch ($$) {
1394         my ($d, $cfg_f) = @_;
1395         my $w = delete $MDIR2CFGPATH->{$d}->{$cfg_f};
1396         scalar(keys %{$MDIR2CFGPATH->{$d}}) or
1397                 delete $MDIR2CFGPATH->{$d};
1398         for my $x (@{$w // []}) { $x->cancel }
1399 }
1400
1401 sub add_maildir_watch ($$) {
1402         my ($d, $cfg_f) = @_;
1403         if (!exists($MDIR2CFGPATH->{$d}->{$cfg_f})) {
1404                 my @w = $dir_idle->add_watches(["$d/cur", "$d/new"], 1);
1405                 push @{$MDIR2CFGPATH->{$d}->{$cfg_f}}, @w if @w;
1406         }
1407 }
1408
1409 sub refresh_watches {
1410         my ($lei) = @_;
1411         $dir_idle or return;
1412         my $cfg = _lei_cfg($lei) or return;
1413         my $old = $cfg->{-watches};
1414         my $watches = $cfg->{-watches} //= {};
1415         my %seen;
1416         my $cfg_f = $cfg->{'-f'};
1417         for my $w (grep(/\Awatch\..+\.state\z/, keys %$cfg)) {
1418                 my $url = substr($w, length('watch.'), -length('.state'));
1419                 require PublicInbox::LeiWatch;
1420                 $watches->{$url} //= PublicInbox::LeiWatch->new($url);
1421                 $seen{$url} = undef;
1422                 my $state = $cfg->get_1("watch.$url.state");
1423                 if (!watch_state_ok($state)) {
1424                         warn("watch.$url.state=$state not supported\n");
1425                         next;
1426                 }
1427                 if ($url =~ /\Amaildir:(.+)/i) {
1428                         my $d = canonpath_harder($1);
1429                         if ($state eq 'pause') {
1430                                 cancel_maildir_watch($d, $cfg_f);
1431                         } else {
1432                                 add_maildir_watch($d, $cfg_f);
1433                         }
1434                 } else { # TODO: imap/nntp/jmap
1435                         $lei->child_error(0, "E: watch $url not supported, yet")
1436                 }
1437         }
1438
1439         # add all known Maildir folders as implicit watches
1440         my $lms = $lei->lms;
1441         if ($lms) {
1442                 $lms->lms_write_prepare;
1443                 for my $d ($lms->folders('maildir:')) {
1444                         substr($d, 0, length('maildir:')) = '';
1445
1446                         # fixup old bugs while we're iterating:
1447                         my $cd = canonpath_harder($d);
1448                         my $f = "maildir:$cd";
1449                         $lms->rename_folder("maildir:$d", $f) if $d ne $cd;
1450                         next if $watches->{$f}; # may be set to pause
1451                         require PublicInbox::LeiWatch;
1452                         $watches->{$f} = PublicInbox::LeiWatch->new($f);
1453                         $seen{$f} = undef;
1454                         add_maildir_watch($cd, $cfg_f);
1455                 }
1456         }
1457         if ($old) { # cull old non-existent entries
1458                 for my $url (keys %$old) {
1459                         next if exists $seen{$url};
1460                         delete $old->{$url};
1461                         if ($url =~ /\Amaildir:(.+)/i) {
1462                                 my $d = canonpath_harder($1);
1463                                 cancel_maildir_watch($d, $cfg_f);
1464                         } else { # TODO: imap/nntp/jmap
1465                                 $lei->child_error(0, "E: watch $url TODO");
1466                         }
1467                 }
1468         }
1469         if (scalar keys %$watches) {
1470                 $cfg->{-env} //= { %{$lei->{env}}, PWD => '/' }; # for cfg2lei
1471         } else {
1472                 delete $cfg->{-watches};
1473         }
1474 }
1475
1476 # TODO: support SHA-256
1477 sub git_oid {
1478         my $eml = $_[-1];
1479         $eml->header_set($_) for @PublicInbox::Import::UNWANTED_HEADERS;
1480         git_sha(1, $eml);
1481 }
1482
1483 sub lms {
1484         my ($lei, $rw) = @_;
1485         my $sto = $lei->{sto} // _lei_store($lei) // return;
1486         require PublicInbox::LeiMailSync;
1487         my $f = "$sto->{priv_eidx}->{topdir}/mail_sync.sqlite3";
1488         (-f $f || $rw) ? PublicInbox::LeiMailSync->new($f) : undef;
1489 }
1490
1491 sub sto_done_request {
1492         my ($lei, $sock) = @_;
1493         local $current_lei = $lei;
1494         eval {
1495                 if ($sock //= $lei->{sock}) { # issue, async wait
1496                         $lei->{sto}->wq_io_do('done', [ $sock ]);
1497                 } else { # forcibly wait
1498                         my $wait = $lei->{sto}->wq_do('done');
1499                 }
1500         };
1501         warn($@) if $@;
1502 }
1503
1504 sub cfg_dump ($$) {
1505         my ($lei, $f) = @_;
1506         my $ret = eval { PublicInbox::Config->git_config_dump($f, $lei->{2}) };
1507         return $ret if !$@;
1508         warn($@);
1509         undef;
1510 }
1511
1512 sub request_umask {
1513         my ($lei) = @_;
1514         my $s = $lei->{sock} // return;
1515         send($s, 'umask', MSG_EOR) // die "send: $!";
1516         vec(my $rvec = '', fileno($s), 1) = 1;
1517         select($rvec, undef, undef, 2) or die 'timeout waiting for umask';
1518         recv($s, my $v, 5, 0) // die "recv: $!";
1519         (my $u, $lei->{client_umask}) = unpack('AV', $v);
1520         $u eq 'u' or warn "E: recv $v has no umask";
1521 }
1522
1523 1;