lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 return $p;
  74         }
  75         my $pwd = $self->{env}->{PWD};
  76         my $cwd;
  77         if (defined $pwd) {
  78                 my $xcwd = $self->{3} //
  79                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  80                 if (my @st_pwd = stat($pwd)) {
  81                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  82                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  83                                 $self->{env}->{PWD} = $pwd = undef;
  84                 } else { # PWD was invalid
  85                         $self->{env}->{PWD} = $pwd = undef;
  86                 }
  87         }
  88         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  89         File::Spec->rel2abs($p, $pwd);
  90 }
  91
  92 # abs_path resolves symlinks in parent iff all parents exist
  93 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  94
  95 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  96         my ($self) = @_;
  97         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  98                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  99                 .'/lei');
 100 }
 101
 102 sub store_path ($) { share_path($_[0]) . '/store' }
 103
 104 sub _config_path ($) {
 105         my ($self) = @_;
 106         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 107                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 108                 .'/lei/config');
 109 }
 110
 111 sub cache_dir ($) {
 112         my ($self) = @_;
 113         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 114                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 115                 .'/lei');
 116 }
 117
 118 sub ale {
 119         my ($self) = @_;
 120         $self->{ale} //= do {
 121                 require PublicInbox::LeiALE;
 122                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 123         };
 124 }
 125
 126 sub index_opt {
 127         # TODO: drop underscore variants everywhere, they're undocumented
 128         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 129         max_size|max-size=s sequential_shard|sequential-shard
 130         batch_size|batch-size=s skip-docdata)
 131 }
 132
 133 my @c_opt = qw(c=s@ C=s@ quiet|q);
 134 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 135         import-remote! no-torsocks torsocks=s),
 136         PublicInbox::LeiQuery::curl_opt());
 137
 138 # we generate shell completion + help using %CMD and %OPTDESC,
 139 # see lei__complete() and PublicInbox::LeiHelp
 140 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 141 our %CMD = ( # sorted in order of importance/use:
 142 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 143         'stdin|', # /|\z/ must be first for lone dash
 144         @lxs_opt,
 145         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 146         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 147         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 148         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 149
 150 'up' => [ 'OUTPUT|--all', 'update saved search',
 151         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 152
 153 'lcat' => [ '--stdin|MSGID_OR_URL..', 'display local copy of message(s)',
 154         'stdin|', # /|\z/ must be first for lone dash
 155         # some of these options are ridiculous for lcat
 156         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 157         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 158         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 159         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 160
 161 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 162         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 163         @lxs_opt, @c_opt ],
 164
 165 'add-external' => [ 'LOCATION',
 166         'add/set priority of a publicinbox|extindex for extra matches',
 167         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 168         verbose|v+), @c_opt, index_opt(),
 169         PublicInbox::LeiQuery::curl_opt() ],
 170 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 171         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 172 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 173 'ls-sync' => [ '', 'list sync folders',
 174                 qw(z|0 z|0 globoff|g invert-match|v local remote), @c_opt ],
 175 'forget-external' => [ 'LOCATION...|--prune',
 176         'exclude further results from a publicinbox|extindex',
 177         qw(prune), @c_opt ],
 178
 179 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 180                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 181 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 182                 qw(verbose|v+), @c_opt ],
 183 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 184                         @c_opt ],
 185
 186 'plonk' => [ '--threads|--from=IDENT',
 187         'exclude mail matching From: or threads from non-Message-ID searches',
 188         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 189 'tag' => [ 'KEYWORDS...',
 190         'set/unset keywords and/or labels on message(s)',
 191         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 192         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 193         pass_through('-kw:foo for delete') ],
 194 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 195         "exclude message(s) on stdin from `q' search results",
 196         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 197
 198 'purge-mailsource' => [ 'LOCATION|--all',
 199         'remove imported messages from IMAP, Maildirs, and MH',
 200         qw(exact! all jobs:i indexed), @c_opt ],
 201
 202 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 203         qw(import! kw! interval=s recursive|r
 204         exclude=s include=s), @c_opt ],
 205 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 206                 qw(format|f=s z), @c_opt ],
 207 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 208 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 209 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 210         qw(prune), @c_opt ],
 211
 212 'import' => [ 'LOCATION...|--stdin',
 213         'one-time import/update from URL or filesystem',
 214         qw(stdin| offset=i recursive|r exclude=s include|I=s
 215         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 216         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 217 'convert' => [ 'LOCATION...|--stdin',
 218         'one-time conversion from URL or filesystem to another format',
 219         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 220         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 221 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 222         "use a patch to generate a query for `lei q --stdin'",
 223         qw(stdin| want|w=s@ uri debug), @c_opt ],
 224 'config' => [ '[...]', sub {
 225                 'git-config(1) wrapper for '._config_path($_[0]);
 226         }, qw(config-file|system|global|file|f=s), # for conflict detection
 227          qw(c=s@ C=s@), pass_through('git config') ],
 228 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 229         qw(pretty ascii dir=s), @c_opt ],
 230
 231 'init' => [ '[DIRNAME]', sub {
 232         "initialize storage, default: ".store_path($_[0]);
 233         }, @c_opt ],
 234 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 235         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 236         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 237 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 238 'help' => [ '[SUBCOMMAND]', 'show help' ],
 239
 240 # XXX do we need this?
 241 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 242
 243 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 244         'rewrite git history in an attempt to improve compression',
 245         qw(gc!), @c_opt ],
 246
 247 # internal commands are prefixed with '_'
 248 '_complete' => [ '[...]', 'internal shell completion helper',
 249                 pass_through('everything') ],
 250 ); # @CMD
 251
 252 # switch descriptions, try to keep consistent across commands
 253 # $spec: Getopt::Long option specification
 254 # $spec => [@ALLOWED_VALUES (default is first), $description],
 255 # $spec => $description
 256 # "$SUB_COMMAND TAB $spec" => as above
 257 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 258                         'specify message input format' ];
 259 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 260
 261 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 262 my %OPTDESC = (
 263 'help|h' => 'show this built-in help',
 264 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 265 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 266 'quiet|q' => 'be quiet',
 267 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 268         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 269
 270 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 271 'globoff|g' => "do not match locations using '*?' wildcards ".
 272                 "and\xa0'[]'\x{a0}ranges",
 273 'color!' => 'disable color (for --format=text)',
 274 'verbose|v+' => 'be more verbose',
 275 'external!' => 'do not use externals',
 276 'mail!' => 'do not look in mail storage for OID',
 277 'cwd!' => 'do not look in git repo of current working directory',
 278 'oid-a|A=s' => 'pre-image OID',
 279 'path-a|a=s' => 'pre-image pathname associated with OID',
 280 'path-b|b=s' => 'post-image pathname associated with OID',
 281 'git-dir=s@' => 'additional git repository to scan',
 282 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 283         "proxy for (e.g. `socks5h://0:9050')" ],
 284 'torsocks=s' => ['VAL|auto|no|yes',
 285                 'whether or not to wrap git and curl commands with torsocks'],
 286 'no-torsocks' => 'alias for --torsocks=no',
 287 'save' =>  "save a search for `lei up'",
 288 'import-remote!' => 'do not memoize remote messages into local store',
 289
 290 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 291
 292 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 293                 'deduplication strategy'],
 294 'threads|t+' =>
 295         'return all messages in the same threads as the actual match(es)',
 296
 297 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 298                 'search prefixes to extract (default: dfpost7)' ],
 299
 300 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 301         'run command(s) or perform ops when done writing to output ' .
 302         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 303         'nothing otherwise)' ],
 304
 305 'augment|a' => 'augment --output destination instead of clobbering',
 306
 307 'output|mfolder|o=s' => [ 'MFOLDER',
 308         "destination (e.g.\xa0`/path/to/Maildir', ".
 309         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 310 'mua=s' => [ 'CMD',
 311         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 312
 313 'inbox-version=i' => [ 'NUM|1|2',
 314                 'force a public-inbox version with --mirror'],
 315 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 316
 317 # public-inbox-index options
 318 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 319 'compact' => 'run compact index after mirroring',
 320 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 321         "indexlevel with --mirror (default: full)" ],
 322 'max_size|max-size=s' => [ 'SIZE',
 323         'do not index messages larger than SIZE (default: infinity)' ],
 324 'batch_size|batch-size=s' => [ 'SIZE',
 325         'flush changes to OS after given number of bytes (default: 1m)' ],
 326 'sequential_shard|sequential-shard' =>
 327         'index Xapian shards sequentially for slow storage',
 328 'skip-docdata' =>
 329         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 330
 331 'format|f=s     q' => [
 332         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 333                 'specify output format, default depends on --output'],
 334 'exclude=s@     q' => [ 'LOCATION',
 335                 'exclude specified external(s) from search' ],
 336 'include|I=s@   q' => [ 'LOCATION',
 337                 'include specified external(s) in search' ],
 338 'only=s@        q' => [ 'LOCATION',
 339                 'only use specified external(s) for search' ],
 340 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 341                 'control number of search and writer jobs' ],
 342 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 343
 344 'in-format|F=s' => $stdin_formats,
 345 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 346                         'listing output format' ],
 347 'l      ls-search' => 'long listing format',
 348 'format|f=s     ls-external' => $ls_format,
 349
 350 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 351 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 352
 353 'sort|s=s' => [ 'VAL|received|relevance|docid',
 354                 "order of results is `--output'-dependent"],
 355 'reverse|r' => 'reverse search results', # like sort(1)
 356
 357 'boost=i' => 'increase/decrease priority of results (default: 0)',
 358
 359 'local' => 'limit operations to the local filesystem',
 360 'local!' => 'exclude results from the local filesystem',
 361 'remote' => 'limit operations to those requiring network access',
 362 'remote!' => 'prevent operations requiring network access',
 363
 364 'all:s  up' => ['local', 'update all (local) saved searches' ],
 365
 366 'mid=s' => 'specify the Message-ID of a message',
 367 'oid=s' => 'specify the git object ID of a message',
 368
 369 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 370 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 371 'include=s' => 'include mailboxes/newsgroups based on pattern',
 372
 373 'exact' => 'operate on exact header matches only',
 374 'exact!' => 'rely on content match instead of exact header matches',
 375
 376 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 377
 378 'kw!' => 'disable/enable importing keywords (aka "flags")',
 379
 380 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 381 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 382
 383 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 384 ); # %OPTDESC
 385
 386 my %CONFIG_KEYS = (
 387         'leistore.dir' => 'top-level storage location',
 388 );
 389
 390 my @WQ_KEYS = qw(lxs l2m wq1); # internal workers
 391
 392 sub _drop_wq {
 393         my ($self) = @_;
 394         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 395                 if ($wq->wq_kill) {
 396                         $wq->wq_close(0, undef, $self);
 397                 } elsif ($wq->wq_kill_old) {
 398                         $wq->wq_wait_old(undef, $self);
 399                 }
 400                 $wq->DESTROY;
 401         }
 402 }
 403
 404 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 405 sub x_it ($$) {
 406         my ($self, $code) = @_;
 407         # make sure client sees stdout before exit
 408         $self->{1}->autoflush(1) if $self->{1};
 409         dump_and_clear_log();
 410         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 411                 send($s, "x_it $code", MSG_EOR);
 412         } elsif ($self->{oneshot}) {
 413                 # don't want to end up using $? from child processes
 414                 _drop_wq($self);
 415                 # cleanup anything that has tempfiles or open file handles
 416                 %PATH2CFG = ();
 417                 delete @$self{qw(ovv dedupe sto cfg)};
 418                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 419                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 420                         kill $signum, $$;
 421                         sleep(1) while 1; # wait for signal
 422                 } else {
 423                         $quit->($code >> 8);
 424                 }
 425         } # else ignore if client disconnected
 426 }
 427
 428 sub err ($;@) {
 429         my $self = shift;
 430         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 431         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 432         print $err @_, @eor and return;
 433         my $old_err = delete $self->{2};
 434         close($old_err) if $! == EPIPE && $old_err;
 435         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 436         print $err @_, @eor or print STDERR @_, @eor;
 437 }
 438
 439 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 440
 441 sub fail_handler ($;$$) {
 442         my ($lei, $code, $io) = @_;
 443         close($io) if $io; # needed to avoid warnings on SIGPIPE
 444         _drop_wq($lei);
 445         x_it($lei, $code // (1 << 8));
 446 }
 447
 448 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 449         fail_handler($_[0], 13, delete $_[0]->{1});
 450 }
 451
 452 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 453 sub sigint_reap {
 454         my ($pgid) = @_;
 455         dwaitpid($pgid) if kill('-INT', $pgid);
 456 }
 457
 458 sub fail ($$;$) {
 459         my ($self, $buf, $exit_code) = @_;
 460         err($self, $buf) if defined $buf;
 461         # calls fail_handler:
 462         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 463         x_it($self, ($exit_code // 1) << 8);
 464         undef;
 465 }
 466
 467 sub out ($;@) {
 468         my $self = shift;
 469         return if print { $self->{1} // return } @_; # likely
 470         return note_sigpipe($self, 1) if $! == EPIPE;
 471         my $err = "error writing to output: $!";
 472         delete $self->{1};
 473         fail($self, $err);
 474 }
 475
 476 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 477
 478 sub child_error { # passes non-fatal curl exit codes to user
 479         my ($self, $child_error, $msg) = @_; # child_error is $?
 480         $self->err($msg) if $msg;
 481         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 482                 # send to the parent lei-daemon or to lei(1) client
 483                 send($s, "child_error $child_error", MSG_EOR);
 484         } elsif (!$PublicInbox::DS::in_loop) {
 485                 $self->{child_error} = $child_error;
 486         } # else noop if client disconnected
 487 }
 488
 489 sub note_sigpipe { # triggers sigpipe_handler
 490         my ($self, $fd) = @_;
 491         close(delete($self->{$fd})); # explicit close silences Perl warning
 492         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 493         x_it($self, 13);
 494 }
 495
 496 sub _lei_atfork_child {
 497         my ($self, $persist) = @_;
 498         # we need to explicitly close things which are on stack
 499         if ($persist) {
 500                 chdir '/' or die "chdir(/): $!";
 501                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 502                 if (my $cfg = $self->{cfg}) {
 503                         delete $cfg->{-lei_store};
 504                 }
 505         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 506                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 507                 STDERR->autoflush(1);
 508         }
 509         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 510         if (my $op_c = delete $self->{pkt_op_c}) {
 511                 close(delete $op_c->{sock});
 512         }
 513         if (my $pgr = delete $self->{pgr}) {
 514                 close($_) for (@$pgr[1,2]);
 515         }
 516         close $listener if $listener;
 517         undef $listener;
 518         %PATH2CFG = ();
 519         undef $errors_log;
 520         $quit = \&CORE::exit;
 521         $self->{-eml_noisy} or # only "lei import" sets this atm
 522                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 523         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 524 }
 525
 526 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 527         my ($self) = @_;
 528         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 529                 $op->close; # PublicInbox::PktOp::close
 530         }
 531         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 532         close $unclosed_after_die;
 533 }
 534
 535 sub pkt_op_pair {
 536         my ($self) = @_;
 537         require PublicInbox::OnDestroy;
 538         require PublicInbox::PktOp;
 539         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 540         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 541         $end;
 542 }
 543
 544 sub workers_start {
 545         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 546         $ops = {
 547                 '!' => [ \&fail_handler, $lei ],
 548                 '|' => [ \&sigpipe_handler, $lei ],
 549                 'x_it' => [ \&x_it, $lei ],
 550                 'child_error' => [ \&child_error, $lei ],
 551                 ($ops ? %$ops : ()),
 552         };
 553         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 554         my $end = $lei->pkt_op_pair;
 555         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 556         delete $lei->{pkt_op_p};
 557         my $op_c = delete $lei->{pkt_op_c};
 558         @$end = ();
 559         $lei->event_step_init;
 560         ($op_c, $ops);
 561 }
 562
 563 sub _help {
 564         require PublicInbox::LeiHelp;
 565         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 566 }
 567
 568 sub optparse ($$$) {
 569         my ($self, $cmd, $argv) = @_;
 570         # allow _complete --help to complete, not show help
 571         return 1 if substr($cmd, 0, 1) eq '_';
 572         $self->{cmd} = $cmd;
 573         $OPT = $self->{opt} //= {};
 574         my $info = $CMD{$cmd} // [ '[...]' ];
 575         my ($proto, undef, @spec) = @$info;
 576         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 577         push @spec, qw(help|h);
 578         my $lone_dash;
 579         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 580                 $lone_dash = $spec[0];
 581                 $OPT->{$spec[0]} = \(my $var);
 582                 push @spec, '' => \$var;
 583         }
 584         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 585                 return _help($self, "bad arguments or options for $cmd");
 586         return _help($self) if $OPT->{help};
 587
 588         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 589
 590         # "-" aliases "stdin" or "clear"
 591         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 592
 593         my $i = 0;
 594         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 595         my ($err, $inf);
 596         my @args = split(/ /, $proto);
 597         for my $var (@args) {
 598                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 599                         $inf = defined($argv->[$i]) and last;
 600                         $var =~ s/\.\.\.\z//;
 601                         $err = "$var not supplied";
 602                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 603                         $argv->[$i++] // ($err = "$var not supplied");
 604                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 605                         $inf = 1;
 606                         last;
 607                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 608                         $i++;
 609                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 610                         $inf = 1 if index($var, '...') > 0;
 611                         my @or = split(/\|/, $var);
 612                         my $ok;
 613                         for my $o (@or) {
 614                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 615                                         $ok = defined($OPT->{$1});
 616                                         last if $ok;
 617                                 } elsif (defined($argv->[$i])) {
 618                                         $ok = 1;
 619                                         $i++;
 620                                         last;
 621                                 } # else continue looping
 622                         }
 623                         last if $ok;
 624                         my $last = pop @or;
 625                         $err = join(', ', @or) . " or $last must be set";
 626                 } else {
 627                         warn "BUG: can't parse `$var' in $proto";
 628                 }
 629                 last if $err;
 630         }
 631         if (!$inf && scalar(@$argv) > scalar(@args)) {
 632                 $err //= 'too many arguments';
 633         }
 634         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 635 }
 636
 637 sub _tmp_cfg { # for lei -c <name>=<value> ...
 638         my ($self) = @_;
 639         my $cfg = _lei_cfg($self, 1);
 640         require File::Temp;
 641         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 642         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 643         $ft->autoflush(1);
 644         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 645 [include]
 646         path = $cfg->{-f}
 647 EOM
 648         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 649         for (@{$self->{opt}->{c}}) {
 650                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 651 `-c $_' is not of the form -c <name>=<value>'
 652 EOM
 653                 my $name = $1;
 654                 my $value = $2 // 1;
 655                 _config($self, '--add', $name, $value);
 656                 if (defined(my $v = $tmp->{$name})) {
 657                         if (ref($v) eq 'ARRAY') {
 658                                 push @$v, $value;
 659                         } else {
 660                                 $tmp->{$name} = [ $v, $value ];
 661                         }
 662                 } else {
 663                         $tmp->{$name} = $value;
 664                 }
 665         }
 666 }
 667
 668 sub lazy_cb ($$$) {
 669         my ($self, $cmd, $pfx) = @_;
 670         my $ucmd = $cmd;
 671         $ucmd =~ tr/-/_/;
 672         my $cb;
 673         $cb = $self->can($pfx.$ucmd) and return $cb;
 674         my $base = $ucmd;
 675         $base =~ s/_([a-z])/\u$1/g;
 676         my $pkg = "PublicInbox::Lei\u$base";
 677         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 678                 $pkg->can($pfx.$ucmd) : undef;
 679 }
 680
 681 sub dispatch {
 682         my ($self, $cmd, @argv) = @_;
 683         local $current_lei = $self; # for __WARN__
 684         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 685         dump_and_clear_log("from previous run\n");
 686         return _help($self, 'no command given') unless defined($cmd);
 687         # do not support Getopt bundling for this
 688         while ($cmd eq '-C' || $cmd eq '-c') {
 689                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 690                                         '-C DIRECTORY' : '-c <name>=<value>');
 691                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 692                 $cmd = shift(@argv) // return _help($self, 'no command given');
 693         }
 694         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 695                 optparse($self, $cmd, \@argv) or return;
 696                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 697                 if (my $chdir = $self->{opt}->{C}) {
 698                         for my $d (@$chdir) {
 699                                 next if $d eq ''; # same as git(1)
 700                                 chdir $d or return fail($self, "cd $d: $!");
 701                         }
 702                         if (delete $self->{3}) { # update cwd for rel2abs
 703                                 opendir my $dh, '.' or
 704                                         return fail($self, "opendir . $!");
 705                                 $self->{3} = $dh;
 706                         }
 707                 }
 708                 $cb->($self, @argv);
 709         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 710                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 711                         or return _help($self, 'bad arguments or options');
 712                 _help($self);
 713         } else {
 714                 fail($self, "`$cmd' is not an lei command");
 715         }
 716 }
 717
 718 sub _lei_cfg ($;$) {
 719         my ($self, $creat) = @_;
 720         return $self->{cfg} if $self->{cfg};
 721         my $f = _config_path($self);
 722         my @st = stat($f);
 723         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 724         my ($sto, $sto_dir);
 725         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 726                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 727                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 728         }
 729         if (!@st) {
 730                 unless ($creat) {
 731                         delete $self->{cfg};
 732                         return bless {}, 'PublicInbox::Config';
 733                 }
 734                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 735                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 736                 open my $fh, '>>', $f or die "open($f): $!\n";
 737                 @st = stat($fh) or die "fstat($f): $!\n";
 738                 $cur_st = pack('dd', $st[10], $st[7]);
 739                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 740         }
 741         my $cfg = PublicInbox::Config->git_config_dump($f);
 742         $cfg->{-st} = $cur_st;
 743         $cfg->{'-f'} = $f;
 744         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 745                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 746                                                 store_path($self))) {
 747                 $cfg->{-lei_store} = $sto;
 748         }
 749         if (scalar(keys %PATH2CFG) > 5) {
 750                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 751                 for my $k (keys %PATH2CFG) {
 752                         delete($PATH2CFG{$k}) unless -f $k
 753                 }
 754         }
 755         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 756 }
 757
 758 sub _lei_store ($;$) {
 759         my ($self, $creat) = @_;
 760         my $cfg = _lei_cfg($self, $creat);
 761         $cfg->{-lei_store} //= do {
 762                 require PublicInbox::LeiStore;
 763                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 764                 return unless $creat || -d $dir;
 765                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 766         };
 767 }
 768
 769 sub _config {
 770         my ($self, @argv) = @_;
 771         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 772         my $cfg = _lei_cfg($self, 1);
 773         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 774         my %rdr = map { $_ => $self->{$_} } (0..2);
 775         waitpid(spawn($cmd, \%env, \%rdr), 0);
 776 }
 777
 778 sub lei_config {
 779         my ($self, @argv) = @_;
 780         $self->{opt}->{'config-file'} and return fail $self,
 781                 "config file switches not supported by `lei config'";
 782         _config(@_);
 783         x_it($self, $?) if $?;
 784 }
 785
 786 sub lei_daemon_pid { puts shift, $$ }
 787
 788 sub lei_daemon_kill {
 789         my ($self) = @_;
 790         my $sig = $self->{opt}->{signal} // 'TERM';
 791         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 792 }
 793
 794 # Shell completion helper.  Used by lei-completion.bash and hopefully
 795 # other shells.  Try to do as much here as possible to avoid redundancy
 796 # and improve maintainability.
 797 sub lei__complete {
 798         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 799         shift @argv; # ignore "lei", the entire command is sent
 800         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 801         my $cmd = shift @argv;
 802         my $info = $CMD{$cmd} // do { # filter matching commands
 803                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 804                 return;
 805         };
 806         my ($proto, undef, @spec) = @$info;
 807         my $cur = pop @argv;
 808         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 809         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 810                 # gross special case since the only git-config options
 811                 # Consider moving to a table if we need more special cases
 812                 # we use Getopt::Long for are the ones we reject, so these
 813                 # are the ones we don't reject:
 814                 if ($cmd eq 'config') {
 815                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 816                         @spec = qw(add z|null get get-all unset unset-all
 817                                 replace-all get-urlmatch
 818                                 remove-section rename-section
 819                                 name-only list|l edit|e
 820                                 get-color-name get-colorbool);
 821                         # fall-through
 822                 }
 823                 # generate short/long names from Getopt::Long specs
 824                 puts $self, grep(/$re/, qw(--help -h -C), map {
 825                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 826                         } elsif (s/\+\z//) { # verbose|v+
 827                         } elsif (s/!\z//) {
 828                                 # negation: mail! => no-mail|mail
 829                                 s/([\w\-]+)/$1|no-$1/g
 830                         }
 831                         map {
 832                                 my $x = length > 1 ? "--$_" : "-$_";
 833                                 $x eq $_cur ? () : $x;
 834                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 835                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 836         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 837                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 838         }
 839
 840         # switch args (e.g. lei q -f mbox<TAB>)
 841         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 842                 my $opt = quotemeta $1;
 843                 puts $self, map {
 844                         my $v = $OPTDESC{$_};
 845                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 846                         # get rid of ALL CAPS placeholder (e.g "OUT")
 847                         # (TODO: completion for external paths)
 848                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 849                         @v;
 850                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 851         }
 852         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 853                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 854         }
 855         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 856         # proto parsing.
 857 }
 858
 859 sub exec_buf ($$) {
 860         my ($argv, $env) = @_;
 861         my $argc = scalar @$argv;
 862         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 863         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 864         $buf;
 865 }
 866
 867 sub start_mua {
 868         my ($self) = @_;
 869         my $mua = $self->{opt}->{mua} // return;
 870         my $mfolder = $self->{ovv}->{dst};
 871         my (@cmd, $replaced);
 872         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 873                 @cmd = ($mua, '-f');
 874         # TODO: help wanted: other common FOSS MUAs
 875         } else {
 876                 require Text::ParseWords;
 877                 @cmd = Text::ParseWords::shellwords($mua);
 878                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 879                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 880         }
 881         push @cmd, $mfolder unless defined($replaced);
 882         if ($self->{sock}) { # lei(1) client process runs it
 883                 # restore terminal: echo $query | lei q -stdin --mua=...
 884                 my $io = [];
 885                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 886                 send_exec_cmd($self, $io, \@cmd, {});
 887         } elsif ($self->{oneshot}) {
 888                 my $pid = fork // die "fork: $!";
 889                 if ($pid > 0) { # original process
 890                         if ($self->{opt}->{stdin} && -t STDOUT) {
 891                                 open STDIN, '+<&', \*STDOUT or die "dup2: $!";
 892                         }
 893                         exec(@cmd);
 894                         warn "exec @cmd: $!\n";
 895                         POSIX::_exit(1);
 896                 }
 897                 POSIX::setsid() > 0 or die "setsid: $!";
 898         }
 899         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 900                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 901         }
 902         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 903         $self->{opt}->{quiet} = 1;
 904         delete $self->{-progress};
 905         delete $self->{opt}->{verbose};
 906 }
 907
 908 sub send_exec_cmd { # tell script/lei to execute a command
 909         my ($self, $io, $cmd, $env) = @_;
 910         my $sock = $self->{sock} // die 'lei client gone';
 911         my $fds = [ map { fileno($_) } @$io ];
 912         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 913 }
 914
 915 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 916         my ($self) = @_;
 917         my $alerts = $self->{opt}->{alert} // return;
 918         while (my $op = shift(@$alerts)) {
 919                 if ($op eq ':WINCH') {
 920                         # hit the process group that started the MUA
 921                         if ($self->{sock}) {
 922                                 send($self->{sock}, '-WINCH', MSG_EOR);
 923                         } elsif ($self->{oneshot}) {
 924                                 kill('-WINCH', $$);
 925                         }
 926                 } elsif ($op eq ':bell') {
 927                         out($self, "\a");
 928                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 929                         push @$alerts, split(/(?<!\\),/, $op);
 930                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 931                         my $cmd = $1; # run an arbitrary command
 932                         require Text::ParseWords;
 933                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 934                         if (my $s = $self->{sock}) {
 935                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 936                         } elsif ($self->{oneshot}) {
 937                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 938                         }
 939                 } else {
 940                         err($self, "W: unsupported --alert=$op"); # non-fatal
 941                 }
 942         }
 943 }
 944
 945 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 946 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 947
 948 # this also normalizes the path
 949 sub path_to_fd {
 950         my ($self, $path) = @_;
 951         $path = rel2abs($self, $path);
 952         $path =~ tr!/!/!s;
 953         $path_to_fd{$path} // (
 954                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 955                         fail($self, "cannot open $path from daemon") : -1
 956         );
 957 }
 958
 959 # caller needs to "-t $self->{1}" to check if tty
 960 sub start_pager {
 961         my ($self) = @_;
 962         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 963         chomp(my $pager = <$fh> // '');
 964         close($fh) or warn "`git var PAGER' error: \$?=$?";
 965         return if $pager eq 'cat' || $pager eq '';
 966         my $new_env = { LESS => 'FRX', LV => '-c' };
 967         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 968         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 969         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 970         my $pgr = [ undef, @$rdr{1, 2} ];
 971         my $env = $self->{env};
 972         if ($self->{sock}) { # lei(1) process runs it
 973                 delete @$new_env{keys %$env}; # only set iff unset
 974                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 975         } elsif ($self->{oneshot}) {
 976                 my $cmd = [$pager];
 977                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 978         } else {
 979                 die 'BUG: start_pager w/o socket';
 980         }
 981         $self->{1} = $wpager;
 982         $self->{2} = $wpager if -t $self->{2};
 983         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 984         $self->{pgr} = $pgr;
 985 }
 986
 987 sub stop_pager {
 988         my ($self) = @_;
 989         my $pgr = delete($self->{pgr}) or return;
 990         $self->{2} = $pgr->[2];
 991         # do not restore original stdout, just close it so we error out
 992         close(delete($self->{1})) if $self->{1};
 993 }
 994
 995 sub accept_dispatch { # Listener {post_accept} callback
 996         my ($sock) = @_; # ignore other
 997         $sock->autoflush(1);
 998         my $self = bless { sock => $sock }, __PACKAGE__;
 999         vec(my $rvec = '', fileno($sock), 1) = 1;
1000         select($rvec, undef, undef, 60) or
1001                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1002         # (4096 * 33) >MAX_ARG_STRLEN
1003         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1004         if (!defined($fds[0])) {
1005                 warn(my $msg = "recv_cmd failed: $!");
1006                 return send($sock, $msg, MSG_EOR);
1007         } else {
1008                 my $i = 0;
1009                 for my $fd (@fds) {
1010                         open($self->{$i++}, '+<&=', $fd) and next;
1011                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1012                 }
1013                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1014         }
1015         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1016         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1017         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1018                 return send($sock, 'request command truncated', MSG_EOR);
1019         my ($argc, @argv) = split(/\0/, $buf, -1);
1020         undef $buf;
1021         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1022         if (chdir($self->{3})) {
1023                 local %ENV = %env;
1024                 $self->{env} = \%env;
1025                 eval { dispatch($self, @argv) };
1026                 send($sock, $@, MSG_EOR) if $@;
1027         } else {
1028                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1029         }
1030 }
1031
1032 sub dclose {
1033         my ($self) = @_;
1034         delete $self->{-progress};
1035         _drop_wq($self);
1036         close(delete $self->{1}) if $self->{1}; # may reap_compress
1037         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1038 }
1039
1040 # for long-running results
1041 sub event_step {
1042         my ($self) = @_;
1043         local %ENV = %{$self->{env}};
1044         my $sock = $self->{sock};
1045         local $current_lei = $self;
1046         eval {
1047                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1048                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1049                                 return if $! == EAGAIN;
1050                                 next if $! == EINTR;
1051                                 last if $! == ECONNRESET;
1052                                 die "recvmsg: $!";
1053                         }
1054                         for my $fd (@fds) {
1055                                 open my $rfh, '+<&=', $fd;
1056                         }
1057                         die "unrecognized client signal: $buf";
1058                 }
1059                 dclose($self);
1060         };
1061         if (my $err = $@) {
1062                 eval { $self->fail($err) };
1063                 dclose($self);
1064         }
1065 }
1066
1067 sub event_step_init {
1068         my ($self) = @_;
1069         return if $self->{-event_init_done}++;
1070         if (my $sock = $self->{sock}) { # using DS->EventLoop
1071                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1072         }
1073 }
1074
1075 sub noop {}
1076
1077 sub oldset { $oldset }
1078
1079 sub dump_and_clear_log {
1080         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1081                 my @pfx = @_;
1082                 unshift(@pfx, "$errors_log ") if @pfx;
1083                 warn @pfx, do { local $/; <STDIN> };
1084                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1085         }
1086 }
1087
1088 # lei(1) calls this when it can't connect
1089 sub lazy_start {
1090         my ($path, $errno, $narg) = @_;
1091         local ($errors_log, $listener);
1092         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1093         $errors_log .= 'errors.log';
1094         my $addr = pack_sockaddr_un($path);
1095         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1096         $lk->lock_acquire;
1097         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1098         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1099                 return if connect($listener, $addr); # another process won
1100                 if ($errno == ECONNREFUSED && -S $path) {
1101                         unlink($path) or die "unlink($path): $!";
1102                 }
1103         } else {
1104                 $! = $errno; # allow interpolation to stringify in die
1105                 die "connect($path): $!";
1106         }
1107         umask(077) // die("umask(077): $!");
1108         bind($listener, $addr) or die "bind($path): $!";
1109         listen($listener, 1024) or die "listen: $!";
1110         $lk->lock_release;
1111         undef $lk;
1112         my @st = stat($path) or die "stat($path): $!";
1113         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1114         local $oldset = PublicInbox::DS::block_signals();
1115         if ($narg == 5) {
1116                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1117                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1118                         require PublicInbox::CmdIPC4;
1119                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1120                         PublicInbox::CmdIPC4->can('recv_cmd4');
1121                 };
1122         }
1123         $recv_cmd or die <<"";
1124 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1125
1126         require PublicInbox::Listener;
1127         require PublicInbox::EOFpipe;
1128         (-p STDOUT) or die "E: stdout must be a pipe\n";
1129         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1130         STDIN->autoflush(1);
1131         dump_and_clear_log("from previous daemon process:\n");
1132         POSIX::setsid() > 0 or die "setsid: $!";
1133         my $pid = fork // die "fork: $!";
1134         return if $pid;
1135         $0 = "lei-daemon $path";
1136         local %PATH2CFG;
1137         $listener->blocking(0);
1138         my $exit_code;
1139         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1140         local $quit = do {
1141                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1142                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1143                 sub {
1144                         $exit_code //= shift;
1145                         my $lis = $pil or exit($exit_code);
1146                         # closing eof_w triggers \&noop wakeup
1147                         $listener = $eof_w = $pil = $path = undef;
1148                         $lis->close; # DS::close
1149                         PublicInbox::DS->SetLoopTimeout(1000);
1150                 };
1151         };
1152         my $sig = {
1153                 CHLD => \&PublicInbox::DS::enqueue_reap,
1154                 QUIT => $quit,
1155                 INT => $quit,
1156                 TERM => $quit,
1157                 HUP => \&noop,
1158                 USR1 => \&noop,
1159                 USR2 => \&noop,
1160         };
1161         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1162         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1163         undef $sig;
1164         local $SIG{PIPE} = 'IGNORE';
1165         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1166                 undef $sigfd;
1167                 PublicInbox::DS->SetLoopTimeout(5000);
1168         } else {
1169                 # wake up every second to accept signals if we don't
1170                 # have signalfd or IO::KQueue:
1171                 PublicInbox::DS::sig_setmask($oldset);
1172                 PublicInbox::DS->SetLoopTimeout(1000);
1173         }
1174         PublicInbox::DS->SetPostLoopCallback(sub {
1175                 my ($dmap, undef) = @_;
1176                 if (@st = defined($path) ? stat($path) : ()) {
1177                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1178                                 warn "$path dev/ino changed, quitting\n";
1179                                 $path = undef;
1180                         }
1181                 } elsif (defined($path)) { # ENOENT is common
1182                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1183                         undef $path;
1184                         $quit->();
1185                 }
1186                 return 1 if defined($path);
1187                 my $now = now();
1188                 my $n = 0;
1189                 for my $s (values %$dmap) {
1190                         $s->can('busy') or next;
1191                         if ($s->busy($now)) {
1192                                 ++$n;
1193                         } else {
1194                                 $s->close;
1195                         }
1196                 }
1197                 $n; # true: continue, false: stop
1198         });
1199
1200         # STDIN was redirected to /dev/null above, closing STDERR and
1201         # STDOUT will cause the calling `lei' client process to finish
1202         # reading the <$daemon> pipe.
1203         local $SIG{__WARN__} = sub {
1204                 $current_lei ? err($current_lei, @_) : warn(
1205                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1206         };
1207         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1208         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1209         # $daemon pipe to `lei' closed, main loop begins:
1210         PublicInbox::DS->EventLoop;
1211         exit($exit_code // 0);
1212 }
1213
1214 sub busy { 1 } # prevent daemon-shutdown if client is connected
1215
1216 # for users w/o Socket::Msghdr installed or Inline::C enabled
1217 sub oneshot {
1218         my ($main_pkg) = @_;
1219         my $exit = $main_pkg->can('exit'); # caller may override exit()
1220         local $quit = $exit if $exit;
1221         local %PATH2CFG;
1222         umask(077) // die("umask(077): $!");
1223         my $self = bless { oneshot => 1, env => \%ENV }, __PACKAGE__;
1224         for (0..2) { open($self->{$_}, '+<&=', $_) or die "open fd=$_: $!" }
1225         dispatch($self, @ARGV);
1226         x_it($self, $self->{child_error}) if $self->{child_error};
1227 }
1228
1229 # ensures stdout hits the FS before sock disconnects so a client
1230 # can immediately reread it
1231 sub DESTROY {
1232         my ($self) = @_;
1233         $self->{1}->autoflush(1) if $self->{1};
1234         stop_pager($self);
1235         my $err = $?;
1236         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1237         waitpid($_, 0) for keys %$oneshot_pids;
1238         $? = $err if $err; # preserve ->fail or ->x_it code
1239 }
1240
1241 sub wq_done_wait { # dwaitpid callback
1242         my ($arg, $pid) = @_;
1243         my ($wq, $lei) = @$arg;
1244         my $err_type = $lei->{-err_type};
1245         $? and $lei->child_error($?,
1246                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1247         $lei->dclose;
1248 }
1249
1250 sub wq_eof { # EOF callback for main daemon
1251         my ($lei) = @_;
1252         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1253         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1254 }
1255
1256 1;