lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 chop($p) if substr($p, -1, 1) eq '/';
  74                 return $p;
  75         }
  76         my $pwd = $self->{env}->{PWD};
  77         my $cwd;
  78         if (defined $pwd) {
  79                 my $xcwd = $self->{3} //
  80                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  81                 if (my @st_pwd = stat($pwd)) {
  82                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  83                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  84                                 $self->{env}->{PWD} = $pwd = undef;
  85                 } else { # PWD was invalid
  86                         $self->{env}->{PWD} = $pwd = undef;
  87                 }
  88         }
  89         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  90         File::Spec->rel2abs($p, $pwd);
  91 }
  92
  93 # abs_path resolves symlinks in parent iff all parents exist
  94 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  95
  96 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  97         my ($self) = @_;
  98         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  99                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 100                 .'/lei');
 101 }
 102
 103 sub store_path ($) { share_path($_[0]) . '/store' }
 104
 105 sub _config_path ($) {
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 109                 .'/lei/config');
 110 }
 111
 112 sub cache_dir ($) {
 113         my ($self) = @_;
 114         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 115                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 116                 .'/lei');
 117 }
 118
 119 sub ale {
 120         my ($self) = @_;
 121         $self->{ale} //= do {
 122                 require PublicInbox::LeiALE;
 123                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 124         };
 125 }
 126
 127 sub index_opt {
 128         # TODO: drop underscore variants everywhere, they're undocumented
 129         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 130         max_size|max-size=s sequential_shard|sequential-shard
 131         batch_size|batch-size=s skip-docdata)
 132 }
 133
 134 my @c_opt = qw(c=s@ C=s@ quiet|q);
 135 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 136         import-remote! no-torsocks torsocks=s),
 137         PublicInbox::LeiQuery::curl_opt());
 138
 139 # we don't support -C as an alias for --find-copies since it's already
 140 # used for chdir
 141 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 142         output-indicator-context=s indent-heuristic!
 143         minimal patience histogram anchored=s@ diff-algorithm=s
 144         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 145         word-diff:s word-diff-regex=s color-words:s no-renames
 146         rename-empty! check ws-error-highlight=s full-index binary
 147         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 148         find-copies-harder irreversible-delete|D l=i diff-filter=s
 149         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 150         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 151         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 152         inter-hunk-context=i function-context|W exit-code ext-diff
 153         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 154         line-prefix=s);
 155
 156 # we generate shell completion + help using %CMD and %OPTDESC,
 157 # see lei__complete() and PublicInbox::LeiHelp
 158 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 159 our %CMD = ( # sorted in order of importance/use:
 160 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 161         'stdin|', # /|\z/ must be first for lone dash
 162         @lxs_opt,
 163         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 164         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 165         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 166         color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 167
 168 'up' => [ 'OUTPUT|--all', 'update saved search',
 169         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 170
 171 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 172         'stdin|', # /|\z/ must be first for lone dash
 173         # some of these options are ridiculous for lcat
 174         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 175         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 176         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 177         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 178
 179 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 180         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 181         @lxs_opt, @c_opt ],
 182
 183 'rediff' => [ '--stdin|LOCATION...',
 184                 'regenerate a diff with different options',
 185         'stdin|', # /|\z/ must be first for lone dash
 186         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 187         @diff_opt, @lxs_opt, @c_opt ],
 188
 189 'add-external' => [ 'LOCATION',
 190         'add/set priority of a publicinbox|extindex for extra matches',
 191         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 192         verbose|v+), @c_opt, index_opt(),
 193         PublicInbox::LeiQuery::curl_opt() ],
 194 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 195         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 196 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 197 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 198                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 199 'forget-external' => [ 'LOCATION...|--prune',
 200         'exclude further results from a publicinbox|extindex',
 201         qw(prune), @c_opt ],
 202
 203 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 204                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 205 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 206                 qw(verbose|v+), @c_opt ],
 207 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 208                         @c_opt ],
 209
 210 'plonk' => [ '--threads|--from=IDENT',
 211         'exclude mail matching From: or threads from non-Message-ID searches',
 212         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 213 'tag' => [ 'KEYWORDS...',
 214         'set/unset keywords and/or labels on message(s)',
 215         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 216         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 217         pass_through('-kw:foo for delete') ],
 218 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 219         "exclude message(s) on stdin from `q' search results",
 220         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 221
 222 'purge-mailsource' => [ 'LOCATION|--all',
 223         'remove imported messages from IMAP, Maildirs, and MH',
 224         qw(exact! all jobs:i indexed), @c_opt ],
 225
 226 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 227         qw(import! kw! interval=s recursive|r
 228         exclude=s include=s), @c_opt ],
 229 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 230                 qw(format|f=s z), @c_opt ],
 231 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 232 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 233 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 234         qw(prune), @c_opt ],
 235
 236 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 237         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 238         verbose|v+ incremental!),
 239          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 240          @c_opt ],
 241 'import' => [ 'LOCATION...|--stdin',
 242         'one-time import/update from URL or filesystem',
 243         qw(stdin| offset=i recursive|r exclude=s include|I=s
 244         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 245         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 246 'forget-mail-sync' => [ 'LOCATION...',
 247         'forget sync information for a mail folder', @c_opt ],
 248 'export-kw' => [ 'LOCATION...|--all',
 249         'one-time export of keywords of sync sources',
 250         qw(all:s mode=s), @c_opt ],
 251 'convert' => [ 'LOCATION...|--stdin',
 252         'one-time conversion from URL or filesystem to another format',
 253         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 254         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 255 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 256         "use a patch to generate a query for `lei q --stdin'",
 257         qw(stdin| want|w=s@ uri debug), @c_opt ],
 258 'config' => [ '[...]', sub {
 259                 'git-config(1) wrapper for '._config_path($_[0]);
 260         }, qw(config-file|system|global|file|f=s), # for conflict detection
 261          qw(c=s@ C=s@), pass_through('git config') ],
 262 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 263         qw(pretty ascii dir=s), @c_opt ],
 264
 265 'init' => [ '[DIRNAME]', sub {
 266         "initialize storage, default: ".store_path($_[0]);
 267         }, @c_opt ],
 268 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 269         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 270         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 271 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 272 'help' => [ '[SUBCOMMAND]', 'show help' ],
 273
 274 # XXX do we need this?
 275 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 276
 277 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 278         'rewrite git history in an attempt to improve compression',
 279         qw(gc!), @c_opt ],
 280
 281 # internal commands are prefixed with '_'
 282 '_complete' => [ '[...]', 'internal shell completion helper',
 283                 pass_through('everything') ],
 284 ); # @CMD
 285
 286 # switch descriptions, try to keep consistent across commands
 287 # $spec: Getopt::Long option specification
 288 # $spec => [@ALLOWED_VALUES (default is first), $description],
 289 # $spec => $description
 290 # "$SUB_COMMAND TAB $spec" => as above
 291 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 292                         'specify message input format' ];
 293 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 294
 295 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 296 my %OPTDESC = (
 297 'help|h' => 'show this built-in help',
 298 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 299 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 300 'quiet|q' => 'be quiet',
 301 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 302         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 303
 304 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 305 'globoff|g' => "do not match locations using '*?' wildcards ".
 306                 "and\xa0'[]'\x{a0}ranges",
 307 'invert-match|v' => 'select non-matching lines',
 308 'color!' => 'disable color (for --format=text)',
 309 'verbose|v+' => 'be more verbose',
 310 'external!' => 'do not use externals',
 311 'mail!' => 'do not look in mail storage for OID',
 312 'cwd!' => 'do not look in git repo of current working directory',
 313 'oid-a|A=s' => 'pre-image OID',
 314 'path-a|a=s' => 'pre-image pathname associated with OID',
 315 'path-b|b=s' => 'post-image pathname associated with OID',
 316 'git-dir=s@' => 'additional git repository to scan',
 317 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 318         "proxy for (e.g. `socks5h://0:9050')" ],
 319 'torsocks=s' => ['VAL|auto|no|yes',
 320                 'whether or not to wrap git and curl commands with torsocks'],
 321 'no-torsocks' => 'alias for --torsocks=no',
 322 'save' =>  "save a search for `lei up'",
 323 'import-remote!' => 'do not memoize remote messages into local store',
 324
 325 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 326
 327 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 328                 'deduplication strategy'],
 329 'threads|t+' =>
 330         'return all messages in the same threads as the actual match(es)',
 331
 332 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 333                 'search prefixes to extract (default: dfpost7)' ],
 334
 335 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 336         'run command(s) or perform ops when done writing to output ' .
 337         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 338         'nothing otherwise)' ],
 339
 340 'augment|a' => 'augment --output destination instead of clobbering',
 341
 342 'output|mfolder|o=s' => [ 'MFOLDER',
 343         "destination (e.g.\xa0`/path/to/Maildir', ".
 344         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 345 'mua=s' => [ 'CMD',
 346         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 347
 348 'inbox-version=i' => [ 'NUM|1|2',
 349                 'force a public-inbox version with --mirror'],
 350 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 351
 352 # public-inbox-index options
 353 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 354 'compact' => 'run compact index after mirroring',
 355 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 356         "indexlevel with --mirror (default: full)" ],
 357 'max_size|max-size=s' => [ 'SIZE',
 358         'do not index messages larger than SIZE (default: infinity)' ],
 359 'batch_size|batch-size=s' => [ 'SIZE',
 360         'flush changes to OS after given number of bytes (default: 1m)' ],
 361 'sequential_shard|sequential-shard' =>
 362         'index Xapian shards sequentially for slow storage',
 363 'skip-docdata' =>
 364         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 365
 366 'format|f=s     q' => [
 367         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 368                 'specify output format, default depends on --output'],
 369 'exclude=s@     q' => [ 'LOCATION',
 370                 'exclude specified external(s) from search' ],
 371 'include|I=s@   q' => [ 'LOCATION',
 372                 'include specified external(s) in search' ],
 373 'only=s@        q' => [ 'LOCATION',
 374                 'only use specified external(s) for search' ],
 375 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 376                 'control number of search and writer jobs' ],
 377 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 378
 379 'in-format|F=s' => $stdin_formats,
 380 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 381                         'listing output format' ],
 382 'l      ls-search' => 'long listing format',
 383 'format|f=s     ls-external' => $ls_format,
 384
 385 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 386 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 387
 388 'sort|s=s' => [ 'VAL|received|relevance|docid',
 389                 "order of results is `--output'-dependent"],
 390 'reverse|r' => 'reverse search results', # like sort(1)
 391
 392 'boost=i' => 'increase/decrease priority of results (default: 0)',
 393
 394 'local' => 'limit operations to the local filesystem',
 395 'local!' => 'exclude results from the local filesystem',
 396 'remote' => 'limit operations to those requiring network access',
 397 'remote!' => 'prevent operations requiring network access',
 398
 399 'all:s  up' => ['local', 'update all (local) saved searches' ],
 400
 401 'mid=s' => 'specify the Message-ID of a message',
 402 'oid=s' => 'specify the git object ID of a message',
 403
 404 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 405 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 406 'include=s' => 'include mailboxes/newsgroups based on pattern',
 407
 408 'exact' => 'operate on exact header matches only',
 409 'exact!' => 'rely on content match instead of exact header matches',
 410
 411 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 412
 413 'kw!' => 'disable/enable importing keywords (aka "flags")',
 414
 415 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 416 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 417
 418 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 419 ); # %OPTDESC
 420
 421 my %CONFIG_KEYS = (
 422         'leistore.dir' => 'top-level storage location',
 423 );
 424
 425 my @WQ_KEYS = qw(lxs l2m wq1); # internal workers
 426
 427 sub _drop_wq {
 428         my ($self) = @_;
 429         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 430                 if ($wq->wq_kill) {
 431                         $wq->wq_close(0, undef, $self);
 432                 } elsif ($wq->wq_kill_old) {
 433                         $wq->wq_wait_old(undef, $self);
 434                 }
 435                 $wq->DESTROY;
 436         }
 437 }
 438
 439 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 440 sub x_it ($$) {
 441         my ($self, $code) = @_;
 442         # make sure client sees stdout before exit
 443         $self->{1}->autoflush(1) if $self->{1};
 444         dump_and_clear_log();
 445         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 446                 send($s, "x_it $code", MSG_EOR);
 447         } elsif ($self->{oneshot}) {
 448                 # don't want to end up using $? from child processes
 449                 _drop_wq($self);
 450                 # cleanup anything that has tempfiles or open file handles
 451                 %PATH2CFG = ();
 452                 delete @$self{qw(ovv dedupe sto cfg)};
 453                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 454                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 455                         kill $signum, $$;
 456                         sleep(1) while 1; # wait for signal
 457                 } else {
 458                         $quit->($code >> 8);
 459                 }
 460         } # else ignore if client disconnected
 461 }
 462
 463 sub err ($;@) {
 464         my $self = shift;
 465         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 466         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 467         print $err @_, @eor and return;
 468         my $old_err = delete $self->{2};
 469         close($old_err) if $! == EPIPE && $old_err;
 470         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 471         print $err @_, @eor or print STDERR @_, @eor;
 472 }
 473
 474 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 475
 476 sub fail_handler ($;$$) {
 477         my ($lei, $code, $io) = @_;
 478         close($io) if $io; # needed to avoid warnings on SIGPIPE
 479         _drop_wq($lei);
 480         x_it($lei, $code // (1 << 8));
 481 }
 482
 483 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 484         fail_handler($_[0], 13, delete $_[0]->{1});
 485 }
 486
 487 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 488 sub sigint_reap {
 489         my ($pgid) = @_;
 490         dwaitpid($pgid) if kill('-INT', $pgid);
 491 }
 492
 493 sub fail ($$;$) {
 494         my ($self, $buf, $exit_code) = @_;
 495         err($self, $buf) if defined $buf;
 496         # calls fail_handler:
 497         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 498         x_it($self, ($exit_code // 1) << 8);
 499         undef;
 500 }
 501
 502 sub out ($;@) {
 503         my $self = shift;
 504         return if print { $self->{1} // return } @_; # likely
 505         return note_sigpipe($self, 1) if $! == EPIPE;
 506         my $err = "error writing to output: $!";
 507         delete $self->{1};
 508         fail($self, $err);
 509 }
 510
 511 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 512
 513 sub child_error { # passes non-fatal curl exit codes to user
 514         my ($self, $child_error, $msg) = @_; # child_error is $?
 515         $self->err($msg) if $msg;
 516         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 517                 # send to the parent lei-daemon or to lei(1) client
 518                 send($s, "child_error $child_error", MSG_EOR);
 519         } elsif (!$PublicInbox::DS::in_loop) {
 520                 $self->{child_error} = $child_error;
 521         } # else noop if client disconnected
 522 }
 523
 524 sub note_sigpipe { # triggers sigpipe_handler
 525         my ($self, $fd) = @_;
 526         close(delete($self->{$fd})); # explicit close silences Perl warning
 527         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 528         x_it($self, 13);
 529 }
 530
 531 sub _lei_atfork_child {
 532         my ($self, $persist) = @_;
 533         # we need to explicitly close things which are on stack
 534         if ($persist) {
 535                 chdir '/' or die "chdir(/): $!";
 536                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 537                 if (my $cfg = $self->{cfg}) {
 538                         delete $cfg->{-lei_store};
 539                 }
 540         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 541                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 542                 STDERR->autoflush(1);
 543         }
 544         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 545         if (my $op_c = delete $self->{pkt_op_c}) {
 546                 close(delete $op_c->{sock});
 547         }
 548         if (my $pgr = delete $self->{pgr}) {
 549                 close($_) for (@$pgr[1,2]);
 550         }
 551         close $listener if $listener;
 552         undef $listener;
 553         undef $dir_idle;
 554         %PATH2CFG = ();
 555         undef $errors_log;
 556         $quit = \&CORE::exit;
 557         $self->{-eml_noisy} or # only "lei import" sets this atm
 558                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 559         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 560 }
 561
 562 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 563         my ($self) = @_;
 564         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 565                 $op->close; # PublicInbox::PktOp::close
 566         }
 567         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 568         close $unclosed_after_die;
 569 }
 570
 571 sub pkt_op_pair {
 572         my ($self) = @_;
 573         require PublicInbox::OnDestroy;
 574         require PublicInbox::PktOp;
 575         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 576         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 577         $end;
 578 }
 579
 580 sub workers_start {
 581         my ($lei, $wq, $jobs, $ops) = @_;
 582         $ops = {
 583                 '!' => [ \&fail_handler, $lei ],
 584                 '|' => [ \&sigpipe_handler, $lei ],
 585                 'x_it' => [ \&x_it, $lei ],
 586                 'child_error' => [ \&child_error, $lei ],
 587                 ($ops ? %$ops : ()),
 588         };
 589         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 590         my $end = $lei->pkt_op_pair;
 591         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 592         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 593         delete $lei->{pkt_op_p};
 594         my $op_c = delete $lei->{pkt_op_c};
 595         @$end = ();
 596         $lei->event_step_init;
 597         ($op_c, $ops);
 598 }
 599
 600 sub _help {
 601         require PublicInbox::LeiHelp;
 602         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 603 }
 604
 605 sub optparse ($$$) {
 606         my ($self, $cmd, $argv) = @_;
 607         # allow _complete --help to complete, not show help
 608         return 1 if substr($cmd, 0, 1) eq '_';
 609         $self->{cmd} = $cmd;
 610         $OPT = $self->{opt} //= {};
 611         my $info = $CMD{$cmd} // [ '[...]' ];
 612         my ($proto, undef, @spec) = @$info;
 613         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 614         push @spec, qw(help|h);
 615         my $lone_dash;
 616         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 617                 $lone_dash = $spec[0];
 618                 $OPT->{$spec[0]} = \(my $var);
 619                 push @spec, '' => \$var;
 620         }
 621         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 622                 return _help($self, "bad arguments or options for $cmd");
 623         return _help($self) if $OPT->{help};
 624
 625         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 626
 627         # "-" aliases "stdin" or "clear"
 628         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 629
 630         my $i = 0;
 631         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 632         my ($err, $inf);
 633         my @args = split(/ /, $proto);
 634         for my $var (@args) {
 635                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 636                         $inf = defined($argv->[$i]) and last;
 637                         $var =~ s/\.\.\.\z//;
 638                         $err = "$var not supplied";
 639                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 640                         $argv->[$i++] // ($err = "$var not supplied");
 641                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 642                         $inf = 1;
 643                         last;
 644                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 645                         $i++;
 646                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 647                         $inf = 1 if index($var, '...') > 0;
 648                         my @or = split(/\|/, $var);
 649                         my $ok;
 650                         for my $o (@or) {
 651                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 652                                         $ok = defined($OPT->{$1});
 653                                         last if $ok;
 654                                 } elsif (defined($argv->[$i])) {
 655                                         $ok = 1;
 656                                         $i++;
 657                                         last;
 658                                 } # else continue looping
 659                         }
 660                         last if $ok;
 661                         my $last = pop @or;
 662                         $err = join(', ', @or) . " or $last must be set";
 663                 } else {
 664                         warn "BUG: can't parse `$var' in $proto";
 665                 }
 666                 last if $err;
 667         }
 668         if (!$inf && scalar(@$argv) > scalar(@args)) {
 669                 $err //= 'too many arguments';
 670         }
 671         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 672 }
 673
 674 sub _tmp_cfg { # for lei -c <name>=<value> ...
 675         my ($self) = @_;
 676         my $cfg = _lei_cfg($self, 1);
 677         require File::Temp;
 678         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 679         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 680         $ft->autoflush(1);
 681         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 682 [include]
 683         path = $cfg->{-f}
 684 EOM
 685         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 686         for (@{$self->{opt}->{c}}) {
 687                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 688 `-c $_' is not of the form -c <name>=<value>'
 689 EOM
 690                 my $name = $1;
 691                 my $value = $2 // 1;
 692                 _config($self, '--add', $name, $value);
 693                 if (defined(my $v = $tmp->{$name})) {
 694                         if (ref($v) eq 'ARRAY') {
 695                                 push @$v, $value;
 696                         } else {
 697                                 $tmp->{$name} = [ $v, $value ];
 698                         }
 699                 } else {
 700                         $tmp->{$name} = $value;
 701                 }
 702         }
 703 }
 704
 705 sub lazy_cb ($$$) {
 706         my ($self, $cmd, $pfx) = @_;
 707         my $ucmd = $cmd;
 708         $ucmd =~ tr/-/_/;
 709         my $cb;
 710         $cb = $self->can($pfx.$ucmd) and return $cb;
 711         my $base = $ucmd;
 712         $base =~ s/_([a-z])/\u$1/g;
 713         my $pkg = "PublicInbox::Lei\u$base";
 714         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 715                 $pkg->can($pfx.$ucmd) : undef;
 716 }
 717
 718 sub dispatch {
 719         my ($self, $cmd, @argv) = @_;
 720         local $current_lei = $self; # for __WARN__
 721         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 722         dump_and_clear_log("from previous run\n");
 723         return _help($self, 'no command given') unless defined($cmd);
 724         # do not support Getopt bundling for this
 725         while ($cmd eq '-C' || $cmd eq '-c') {
 726                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 727                                         '-C DIRECTORY' : '-c <name>=<value>');
 728                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 729                 $cmd = shift(@argv) // return _help($self, 'no command given');
 730         }
 731         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 732                 optparse($self, $cmd, \@argv) or return;
 733                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 734                 if (my $chdir = $self->{opt}->{C}) {
 735                         for my $d (@$chdir) {
 736                                 next if $d eq ''; # same as git(1)
 737                                 chdir $d or return fail($self, "cd $d: $!");
 738                         }
 739                         if (delete $self->{3}) { # update cwd for rel2abs
 740                                 opendir my $dh, '.' or
 741                                         return fail($self, "opendir . $!");
 742                                 $self->{3} = $dh;
 743                         }
 744                 }
 745                 $cb->($self, @argv);
 746         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 747                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 748                         or return _help($self, 'bad arguments or options');
 749                 _help($self);
 750         } else {
 751                 fail($self, "`$cmd' is not an lei command");
 752         }
 753 }
 754
 755 sub _lei_cfg ($;$) {
 756         my ($self, $creat) = @_;
 757         return $self->{cfg} if $self->{cfg};
 758         my $f = _config_path($self);
 759         my @st = stat($f);
 760         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 761         my ($sto, $sto_dir);
 762         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 763                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 764                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 765         }
 766         if (!@st) {
 767                 unless ($creat) {
 768                         delete $self->{cfg};
 769                         return bless {}, 'PublicInbox::Config';
 770                 }
 771                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 772                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 773                 open my $fh, '>>', $f or die "open($f): $!\n";
 774                 @st = stat($fh) or die "fstat($f): $!\n";
 775                 $cur_st = pack('dd', $st[10], $st[7]);
 776                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 777         }
 778         my $cfg = PublicInbox::Config->git_config_dump($f);
 779         $cfg->{-st} = $cur_st;
 780         $cfg->{'-f'} = $f;
 781         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 782                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 783                                                 store_path($self))) {
 784                 $cfg->{-lei_store} = $sto;
 785         }
 786         if (scalar(keys %PATH2CFG) > 5) {
 787                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 788                 for my $k (keys %PATH2CFG) {
 789                         delete($PATH2CFG{$k}) unless -f $k
 790                 }
 791         }
 792         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 793 }
 794
 795 sub _lei_store ($;$) {
 796         my ($self, $creat) = @_;
 797         my $cfg = _lei_cfg($self, $creat);
 798         $cfg->{-lei_store} //= do {
 799                 require PublicInbox::LeiStore;
 800                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 801                 return unless $creat || -d $dir;
 802                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 803         };
 804 }
 805
 806 sub _config {
 807         my ($self, @argv) = @_;
 808         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 809         my $cfg = _lei_cfg($self, 1);
 810         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 811         my %rdr = map { $_ => $self->{$_} } (0..2);
 812         waitpid(spawn($cmd, \%env, \%rdr), 0);
 813 }
 814
 815 sub lei_config {
 816         my ($self, @argv) = @_;
 817         $self->{opt}->{'config-file'} and return fail $self,
 818                 "config file switches not supported by `lei config'";
 819         _config(@_);
 820         x_it($self, $?) if $?;
 821 }
 822
 823 sub lei_daemon_pid { puts shift, $$ }
 824
 825 sub lei_daemon_kill {
 826         my ($self) = @_;
 827         my $sig = $self->{opt}->{signal} // 'TERM';
 828         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 829 }
 830
 831 # Shell completion helper.  Used by lei-completion.bash and hopefully
 832 # other shells.  Try to do as much here as possible to avoid redundancy
 833 # and improve maintainability.
 834 sub lei__complete {
 835         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 836         shift @argv; # ignore "lei", the entire command is sent
 837         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 838         my $cmd = shift @argv;
 839         my $info = $CMD{$cmd} // do { # filter matching commands
 840                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 841                 return;
 842         };
 843         my ($proto, undef, @spec) = @$info;
 844         my $cur = pop @argv;
 845         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 846         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 847                 # gross special case since the only git-config options
 848                 # Consider moving to a table if we need more special cases
 849                 # we use Getopt::Long for are the ones we reject, so these
 850                 # are the ones we don't reject:
 851                 if ($cmd eq 'config') {
 852                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 853                         @spec = qw(add z|null get get-all unset unset-all
 854                                 replace-all get-urlmatch
 855                                 remove-section rename-section
 856                                 name-only list|l edit|e
 857                                 get-color-name get-colorbool);
 858                         # fall-through
 859                 }
 860                 # generate short/long names from Getopt::Long specs
 861                 puts $self, grep(/$re/, qw(--help -h -C), map {
 862                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 863                         } elsif (s/\+\z//) { # verbose|v+
 864                         } elsif (s/!\z//) {
 865                                 # negation: mail! => no-mail|mail
 866                                 s/([\w\-]+)/$1|no-$1/g
 867                         }
 868                         map {
 869                                 my $x = length > 1 ? "--$_" : "-$_";
 870                                 $x eq $_cur ? () : $x;
 871                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 872                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 873         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 874                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 875         }
 876
 877         # switch args (e.g. lei q -f mbox<TAB>)
 878         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 879                 my $opt = quotemeta $1;
 880                 puts $self, map {
 881                         my $v = $OPTDESC{$_};
 882                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 883                         # get rid of ALL CAPS placeholder (e.g "OUT")
 884                         # (TODO: completion for external paths)
 885                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 886                         @v;
 887                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 888         }
 889         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 890                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 891         }
 892         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 893         # proto parsing.
 894 }
 895
 896 sub exec_buf ($$) {
 897         my ($argv, $env) = @_;
 898         my $argc = scalar @$argv;
 899         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 900         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 901         $buf;
 902 }
 903
 904 sub start_mua {
 905         my ($self) = @_;
 906         my $mua = $self->{opt}->{mua} // return;
 907         my $mfolder = $self->{ovv}->{dst};
 908         my (@cmd, $replaced);
 909         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 910                 @cmd = ($mua, '-f');
 911         # TODO: help wanted: other common FOSS MUAs
 912         } else {
 913                 require Text::ParseWords;
 914                 @cmd = Text::ParseWords::shellwords($mua);
 915                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 916                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 917         }
 918         push @cmd, $mfolder unless defined($replaced);
 919         if ($self->{sock}) { # lei(1) client process runs it
 920                 # restore terminal: echo $query | lei q -stdin --mua=...
 921                 my $io = [];
 922                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 923                 send_exec_cmd($self, $io, \@cmd, {});
 924         } elsif ($self->{oneshot}) {
 925                 my $pid = fork // die "fork: $!";
 926                 if ($pid > 0) { # original process
 927                         if ($self->{opt}->{stdin} && -t STDOUT) {
 928                                 open STDIN, '+<&', \*STDOUT or die "dup2: $!";
 929                         }
 930                         exec(@cmd);
 931                         warn "exec @cmd: $!\n";
 932                         POSIX::_exit(1);
 933                 }
 934                 POSIX::setsid() > 0 or die "setsid: $!";
 935         }
 936         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 937                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 938         }
 939         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 940         $self->{opt}->{quiet} = 1;
 941         delete $self->{-progress};
 942         delete $self->{opt}->{verbose};
 943 }
 944
 945 sub send_exec_cmd { # tell script/lei to execute a command
 946         my ($self, $io, $cmd, $env) = @_;
 947         my $sock = $self->{sock} // die 'lei client gone';
 948         my $fds = [ map { fileno($_) } @$io ];
 949         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 950 }
 951
 952 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 953         my ($self) = @_;
 954         my $alerts = $self->{opt}->{alert} // return;
 955         while (my $op = shift(@$alerts)) {
 956                 if ($op eq ':WINCH') {
 957                         # hit the process group that started the MUA
 958                         if ($self->{sock}) {
 959                                 send($self->{sock}, '-WINCH', MSG_EOR);
 960                         } elsif ($self->{oneshot}) {
 961                                 kill('-WINCH', $$);
 962                         }
 963                 } elsif ($op eq ':bell') {
 964                         out($self, "\a");
 965                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 966                         push @$alerts, split(/(?<!\\),/, $op);
 967                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 968                         my $cmd = $1; # run an arbitrary command
 969                         require Text::ParseWords;
 970                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 971                         if (my $s = $self->{sock}) {
 972                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 973                         } elsif ($self->{oneshot}) {
 974                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 975                         }
 976                 } else {
 977                         err($self, "W: unsupported --alert=$op"); # non-fatal
 978                 }
 979         }
 980 }
 981
 982 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 983 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 984
 985 # this also normalizes the path
 986 sub path_to_fd {
 987         my ($self, $path) = @_;
 988         $path = rel2abs($self, $path);
 989         $path =~ tr!/!/!s;
 990         $path_to_fd{$path} // (
 991                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 992                         fail($self, "cannot open $path from daemon") : -1
 993         );
 994 }
 995
 996 # caller needs to "-t $self->{1}" to check if tty
 997 sub start_pager {
 998         my ($self) = @_;
 999         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1000         chomp(my $pager = <$fh> // '');
1001         close($fh) or warn "`git var PAGER' error: \$?=$?";
1002         return if $pager eq 'cat' || $pager eq '';
1003         my $new_env = { LESS => 'FRX', LV => '-c' };
1004         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
1005         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1006         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1007         my $pgr = [ undef, @$rdr{1, 2} ];
1008         my $env = $self->{env};
1009         if ($self->{sock}) { # lei(1) process runs it
1010                 delete @$new_env{keys %$env}; # only set iff unset
1011                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1012         } elsif ($self->{oneshot}) {
1013                 my $cmd = [$pager];
1014                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
1015         } else {
1016                 die 'BUG: start_pager w/o socket';
1017         }
1018         $self->{1} = $wpager;
1019         $self->{2} = $wpager if -t $self->{2};
1020         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1021         $self->{pgr} = $pgr;
1022 }
1023
1024 sub stop_pager {
1025         my ($self) = @_;
1026         my $pgr = delete($self->{pgr}) or return;
1027         $self->{2} = $pgr->[2];
1028         # do not restore original stdout, just close it so we error out
1029         close(delete($self->{1})) if $self->{1};
1030 }
1031
1032 sub accept_dispatch { # Listener {post_accept} callback
1033         my ($sock) = @_; # ignore other
1034         $sock->autoflush(1);
1035         my $self = bless { sock => $sock }, __PACKAGE__;
1036         vec(my $rvec = '', fileno($sock), 1) = 1;
1037         select($rvec, undef, undef, 60) or
1038                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1039         # (4096 * 33) >MAX_ARG_STRLEN
1040         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1041         if (!defined($fds[0])) {
1042                 warn(my $msg = "recv_cmd failed: $!");
1043                 return send($sock, $msg, MSG_EOR);
1044         } else {
1045                 my $i = 0;
1046                 for my $fd (@fds) {
1047                         open($self->{$i++}, '+<&=', $fd) and next;
1048                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1049                 }
1050                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1051         }
1052         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1053         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1054         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1055                 return send($sock, 'request command truncated', MSG_EOR);
1056         my ($argc, @argv) = split(/\0/, $buf, -1);
1057         undef $buf;
1058         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1059         if (chdir($self->{3})) {
1060                 local %ENV = %env;
1061                 $self->{env} = \%env;
1062                 eval { dispatch($self, @argv) };
1063                 send($sock, $@, MSG_EOR) if $@;
1064         } else {
1065                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1066         }
1067 }
1068
1069 sub dclose {
1070         my ($self) = @_;
1071         delete $self->{-progress};
1072         _drop_wq($self);
1073         close(delete $self->{1}) if $self->{1}; # may reap_compress
1074         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1075 }
1076
1077 # for long-running results
1078 sub event_step {
1079         my ($self) = @_;
1080         local %ENV = %{$self->{env}};
1081         my $sock = $self->{sock};
1082         local $current_lei = $self;
1083         eval {
1084                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1085                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1086                                 return if $! == EAGAIN;
1087                                 next if $! == EINTR;
1088                                 last if $! == ECONNRESET;
1089                                 die "recvmsg: $!";
1090                         }
1091                         for my $fd (@fds) {
1092                                 open my $rfh, '+<&=', $fd;
1093                         }
1094                         die "unrecognized client signal: $buf";
1095                 }
1096                 dclose($self);
1097         };
1098         if (my $err = $@) {
1099                 eval { $self->fail($err) };
1100                 dclose($self);
1101         }
1102 }
1103
1104 sub event_step_init {
1105         my ($self) = @_;
1106         return if $self->{-event_init_done}++;
1107         if (my $sock = $self->{sock}) { # using DS->EventLoop
1108                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1109         }
1110 }
1111
1112 sub noop {}
1113
1114 sub oldset { $oldset }
1115
1116 sub dump_and_clear_log {
1117         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1118                 my @pfx = @_;
1119                 unshift(@pfx, "$errors_log ") if @pfx;
1120                 warn @pfx, do { local $/; <STDIN> };
1121                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1122         }
1123 }
1124
1125 # lei(1) calls this when it can't connect
1126 sub lazy_start {
1127         my ($path, $errno, $narg) = @_;
1128         local ($errors_log, $listener);
1129         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1130         $errors_log = "$sock_dir/errors.log";
1131         my $addr = pack_sockaddr_un($path);
1132         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1133         $lk->lock_acquire;
1134         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1135         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1136                 return if connect($listener, $addr); # another process won
1137                 if ($errno == ECONNREFUSED && -S $path) {
1138                         unlink($path) or die "unlink($path): $!";
1139                 }
1140         } else {
1141                 $! = $errno; # allow interpolation to stringify in die
1142                 die "connect($path): $!";
1143         }
1144         umask(077) // die("umask(077): $!");
1145         bind($listener, $addr) or die "bind($path): $!";
1146         listen($listener, 1024) or die "listen: $!";
1147         $lk->lock_release;
1148         undef $lk;
1149         my @st = stat($path) or die "stat($path): $!";
1150         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1151         local $oldset = PublicInbox::DS::block_signals();
1152         if ($narg == 5) {
1153                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1154                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1155                         require PublicInbox::CmdIPC4;
1156                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1157                         PublicInbox::CmdIPC4->can('recv_cmd4');
1158                 };
1159         }
1160         $recv_cmd or die <<"";
1161 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1162
1163         require PublicInbox::Listener;
1164         require PublicInbox::PktOp;
1165         (-p STDOUT) or die "E: stdout must be a pipe\n";
1166         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1167         STDIN->autoflush(1);
1168         dump_and_clear_log("from previous daemon process:\n");
1169         POSIX::setsid() > 0 or die "setsid: $!";
1170         my $pid = fork // die "fork: $!";
1171         return if $pid;
1172         $0 = "lei-daemon $path";
1173         local %PATH2CFG;
1174         $listener->blocking(0);
1175         my $exit_code;
1176         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1177         local $quit = do {
1178                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1179                 sub {
1180                         $exit_code //= shift;
1181                         my $lis = $pil or exit($exit_code);
1182                         # closing eof_p triggers \&noop wakeup
1183                         $listener = $eof_p = $pil = $path = undef;
1184                         $lis->close; # DS::close
1185                         PublicInbox::DS->SetLoopTimeout(1000);
1186                 };
1187         };
1188         my $sig = {
1189                 CHLD => \&PublicInbox::DS::enqueue_reap,
1190                 QUIT => $quit,
1191                 INT => $quit,
1192                 TERM => $quit,
1193                 HUP => \&noop,
1194                 USR1 => \&noop,
1195                 USR2 => \&noop,
1196         };
1197         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1198         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1199         undef $sig;
1200         local $SIG{PIPE} = 'IGNORE';
1201         require PublicInbox::DirIdle;
1202         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1203                 # just rely on wakeup ot hit PostLoopCallback set below
1204                 _dir_idle_handler(@_) if $_[0]->fullname ne $path;
1205         }, 1);
1206         if ($sigfd) {
1207                 undef $sigfd; # unref, already in DS::DescriptorMap
1208         } else {
1209                 # wake up every second to accept signals if we don't
1210                 # have signalfd or IO::KQueue:
1211                 PublicInbox::DS::sig_setmask($oldset);
1212                 PublicInbox::DS->SetLoopTimeout(1000);
1213         }
1214         PublicInbox::DS->SetPostLoopCallback(sub {
1215                 my ($dmap, undef) = @_;
1216                 if (@st = defined($path) ? stat($path) : ()) {
1217                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1218                                 warn "$path dev/ino changed, quitting\n";
1219                                 $path = undef;
1220                         }
1221                 } elsif (defined($path)) { # ENOENT is common
1222                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1223                         undef $path;
1224                         $quit->();
1225                 }
1226                 return 1 if defined($path);
1227                 my $now = now();
1228                 my $n = 0;
1229                 for my $s (values %$dmap) {
1230                         $s->can('busy') or next;
1231                         if ($s->busy($now)) {
1232                                 ++$n;
1233                         } else {
1234                                 $s->close;
1235                         }
1236                 }
1237                 $n; # true: continue, false: stop
1238         });
1239
1240         # STDIN was redirected to /dev/null above, closing STDERR and
1241         # STDOUT will cause the calling `lei' client process to finish
1242         # reading the <$daemon> pipe.
1243         local $SIG{__WARN__} = sub {
1244                 $current_lei ? err($current_lei, @_) : warn(
1245                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1246         };
1247         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1248         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1249         # $daemon pipe to `lei' closed, main loop begins:
1250         PublicInbox::DS->EventLoop;
1251         exit($exit_code // 0);
1252 }
1253
1254 sub busy { 1 } # prevent daemon-shutdown if client is connected
1255
1256 # for users w/o Socket::Msghdr installed or Inline::C enabled
1257 sub oneshot {
1258         my ($main_pkg) = @_;
1259         my $exit = $main_pkg->can('exit'); # caller may override exit()
1260         local $quit = $exit if $exit;
1261         local %PATH2CFG;
1262         umask(077) // die("umask(077): $!");
1263         my $self = bless { oneshot => 1, env => \%ENV }, __PACKAGE__;
1264         for (0..2) { open($self->{$_}, '+<&=', $_) or die "open fd=$_: $!" }
1265         dispatch($self, @ARGV);
1266         x_it($self, $self->{child_error}) if $self->{child_error};
1267 }
1268
1269 # ensures stdout hits the FS before sock disconnects so a client
1270 # can immediately reread it
1271 sub DESTROY {
1272         my ($self) = @_;
1273         $self->{1}->autoflush(1) if $self->{1};
1274         stop_pager($self);
1275         my $err = $?;
1276         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1277         waitpid($_, 0) for keys %$oneshot_pids;
1278         $? = $err if $err; # preserve ->fail or ->x_it code
1279 }
1280
1281 sub wq_done_wait { # dwaitpid callback
1282         my ($arg, $pid) = @_;
1283         my ($wq, $lei) = @$arg;
1284         my $err_type = $lei->{-err_type};
1285         $? and $lei->child_error($?,
1286                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1287         $lei->dclose;
1288 }
1289
1290 sub wq_eof { # EOF callback for main daemon
1291         my ($lei) = @_;
1292         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1293         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1294 }
1295
1296 1;