lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use Time::HiRes qw(stat); # ctime comparisons for config cache
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log, $listener, $oldset);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub rel2abs ($$) {
  68         my ($self, $p) = @_;
  69         return $p if index($p, '/') == 0; # already absolute
  70         my $pwd = $self->{env}->{PWD};
  71         if (defined $pwd) {
  72                 my $cwd = $self->{3} // getcwd() // die "getcwd(PWD=$pwd): $!";
  73                 if (my @st_pwd = stat($pwd)) {
  74                         my @st_cwd = stat($cwd) or die "stat($cwd): $!";
  75                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  76                                 $self->{env}->{PWD} = $pwd = $cwd;
  77                 } else { # PWD was invalid
  78                         delete $self->{env}->{PWD};
  79                         undef $pwd;
  80                 }
  81         }
  82         $pwd //= $self->{env}->{PWD} = getcwd() // die "getcwd(PWD=$pwd): $!";
  83         File::Spec->rel2abs($p, $pwd);
  84 }
  85
  86 sub store_path ($) {
  87         my ($self) = @_;
  88         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  89                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  90                 .'/lei/store');
  91 }
  92
  93 sub _config_path ($) {
  94         my ($self) = @_;
  95         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  96                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
  97                 .'/lei/config');
  98 }
  99
 100 sub cache_dir ($) {
 101         my ($self) = @_;
 102         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 103                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 104                 .'/lei');
 105 }
 106
 107 sub ale {
 108         my ($self) = @_;
 109         $self->{ale} //= do {
 110                 require PublicInbox::LeiALE;
 111                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 112         };
 113 }
 114
 115 sub index_opt {
 116         # TODO: drop underscore variants everywhere, they're undocumented
 117         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 118         max_size|max-size=s sequential_shard|sequential-shard
 119         batch_size|batch-size=s skip-docdata)
 120 }
 121
 122 my @c_opt = qw(c=s@ C=s@ quiet|q);
 123
 124 # we generate shell completion + help using %CMD and %OPTDESC,
 125 # see lei__complete() and PublicInbox::LeiHelp
 126 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 127 our %CMD = ( # sorted in order of importance/use:
 128 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 129         'stdin|', # /|\z/ must be first for lone dash
 130         qw(save-as=s output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 131         sort|s=s reverse|r offset=i remote! local! external! pretty
 132         include|I=s@ exclude=s@ only=s@ jobs|j=s globoff|g augment|a
 133         import-remote! import-before! lock=s@ rsyncable
 134         alert=s@ mua=s no-torsocks torsocks=s verbose|v+), @c_opt,
 135         PublicInbox::LeiQuery::curl_opt(), opt_dash('limit|n=i', '[0-9]+') ],
 136
 137 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
 138         qw(type=s solve! format|f=s dedupe|d=s threads|t remote local!
 139         verbose|v+), @c_opt, pass_through('git show') ],
 140
 141 'add-external' => [ 'LOCATION',
 142         'add/set priority of a publicinbox|extindex for extra matches',
 143         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 144         verbose|v+), @c_opt, index_opt(),
 145         PublicInbox::LeiQuery::curl_opt() ],
 146 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 147         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 148 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 149 'forget-external' => [ 'LOCATION...|--prune',
 150         'exclude further results from a publicinbox|extindex',
 151         qw(prune), @c_opt ],
 152
 153 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 154                 qw(name-only format|f=s), @c_opt ],
 155 'rm-query' => [ 'QUERY_NAME', 'remove a saved search', @c_opt ],
 156 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search', @c_opt ],
 157
 158 'plonk' => [ '--threads|--from=IDENT',
 159         'exclude mail matching From: or threads from non-Message-ID searches',
 160         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 161 'mark' => [ 'KEYWORDS...',
 162         'set/unset keywords on message(s)',
 163         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@), @c_opt,
 164         pass_through('-kw:foo for delete') ],
 165 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 166         "exclude message(s) on stdin from `q' search results",
 167         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 168
 169 'purge-mailsource' => [ 'LOCATION|--all',
 170         'remove imported messages from IMAP, Maildirs, and MH',
 171         qw(exact! all jobs:i indexed), @c_opt ],
 172
 173 # code repos are used for `show' to solve blobs from patch mails
 174 'add-coderepo' => [ 'DIRNAME', 'add or set priority of a git code repo',
 175         qw(boost=i), @c_opt ],
 176 'ls-coderepo' => [ '[FILTER_TERMS...]',
 177                 'list known code repos', qw(format|f=s z), @c_opt ],
 178 'forget-coderepo' => [ 'DIRNAME',
 179         'stop using repo to solve blobs from patches',
 180         qw(prune), @c_opt ],
 181
 182 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 183         qw(import! kw|keywords|flags! interval=s recursive|r
 184         exclude=s include=s), @c_opt ],
 185 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 186                 qw(format|f=s z), @c_opt ],
 187 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 188 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 189 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 190         qw(prune), @c_opt ],
 191
 192 'import' => [ 'LOCATION...|--stdin',
 193         'one-time import/update from URL or filesystem',
 194         qw(stdin| offset=i recursive|r exclude=s include|I=s
 195         lock=s@ in-format|F=s kw|keywords|flags! verbose|v+), @c_opt ],
 196 'convert' => [ 'LOCATION...|--stdin',
 197         'one-time conversion from URL or filesystem to another format',
 198         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s
 199         lock=s@ kw|keywords|flags!), @c_opt ],
 200 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 201         "use a patch to generate a query for `lei q --stdin'",
 202         qw(stdin| want|w=s@ uri debug), @c_opt ],
 203 'config' => [ '[...]', sub {
 204                 'git-config(1) wrapper for '._config_path($_[0]);
 205         }, qw(config-file|system|global|file|f=s), # for conflict detection
 206          qw(c=s@ C=s@), pass_through('git config') ],
 207 'init' => [ '[DIRNAME]', sub {
 208         "initialize storage, default: ".store_path($_[0]);
 209         }, @c_opt ],
 210 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 211         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 212         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 213 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 214 'help' => [ '[SUBCOMMAND]', 'show help' ],
 215
 216 # XXX do we need this?
 217 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 218
 219 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 220         'rewrite git history in an attempt to improve compression',
 221         qw(gc!), @c_opt ],
 222
 223 # internal commands are prefixed with '_'
 224 '_complete' => [ '[...]', 'internal shell completion helper',
 225                 pass_through('everything') ],
 226 ); # @CMD
 227
 228 # switch descriptions, try to keep consistent across commands
 229 # $spec: Getopt::Long option specification
 230 # $spec => [@ALLOWED_VALUES (default is first), $description],
 231 # $spec => $description
 232 # "$SUB_COMMAND TAB $spec" => as above
 233 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 234                         'specify message input format' ];
 235 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 236
 237 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 238 my %OPTDESC = (
 239 'help|h' => 'show this built-in help',
 240 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 241 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 242 'quiet|q' => 'be quiet',
 243 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 244         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 245
 246 'globoff|g' => "do not match locations using '*?' wildcards ".
 247                 "and\xa0'[]'\x{a0}ranges",
 248 'verbose|v+' => 'be more verbose',
 249 'external!' => 'do not use externals',
 250 'solve!' => 'do not attempt to reconstruct blobs from emails',
 251 'torsocks=s' => ['VAL|auto|no|yes',
 252                 'whether or not to wrap git and curl commands with torsocks'],
 253 'no-torsocks' => 'alias for --torsocks=no',
 254 'save-as=s' => ['NAME', 'save a search terms by given name'],
 255 'import-remote!' => 'do not memoize remote messages into local store',
 256
 257 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 258
 259 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 260                 'deduplication strategy'],
 261 'threads|t+' =>
 262         'return all messages in the same threads as the actual match(es)',
 263
 264 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 265                 'search prefixes to extract (default: dfpost7)' ],
 266
 267 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 268         'run command(s) or perform ops when done writing to output ' .
 269         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 270         'nothing otherwise)' ],
 271
 272 'augment|a' => 'augment --output destination instead of clobbering',
 273
 274 'output|mfolder|o=s' => [ 'MFOLDER',
 275         "destination (e.g.\xa0`/path/to/Maildir', ".
 276         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 277 'mua=s' => [ 'CMD',
 278         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 279
 280 'inbox-version=i' => [ 'NUM|1|2',
 281                 'force a public-inbox version with --mirror'],
 282 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 283
 284 # public-inbox-index options
 285 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 286 'compact' => 'run compact index after mirroring',
 287 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 288         "indexlevel with --mirror (default: full)" ],
 289 'max_size|max-size=s' => [ 'SIZE',
 290         'do not index messages larger than SIZE (default: infinity)' ],
 291 'batch_size|batch-size=s' => [ 'SIZE',
 292         'flush changes to OS after given number of bytes (default: 1m)' ],
 293 'sequential_shard|sequential-shard' =>
 294         'index Xapian shards sequentially for slow storage',
 295 'skip-docdata' =>
 296         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 297
 298 'format|f=s     q' => [
 299         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 300                 'specify output format, default depends on --output'],
 301 'exclude=s@     q' => [ 'LOCATION',
 302                 'exclude specified external(s) from search' ],
 303 'include|I=s@   q' => [ 'LOCATION',
 304                 'include specified external(s) in search' ],
 305 'only=s@        q' => [ 'LOCATION',
 306                 'only use specified external(s) for search' ],
 307 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 308                 'control number of search and writer jobs' ],
 309 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 310
 311 'in-format|F=s' => $stdin_formats,
 312 'format|f=s     ls-query' => $ls_format,
 313 'format|f=s     ls-external' => $ls_format,
 314
 315 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 316 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 317
 318 'sort|s=s' => [ 'VAL|received|relevance|docid',
 319                 "order of results is `--output'-dependent"],
 320 'reverse|r' => 'reverse search results', # like sort(1)
 321
 322 'boost=i' => 'increase/decrease priority of results (default: 0)',
 323
 324 'local' => 'limit operations to the local filesystem',
 325 'local!' => 'exclude results from the local filesystem',
 326 'remote' => 'limit operations to those requiring network access',
 327 'remote!' => 'prevent operations requiring network access',
 328
 329 'mid=s' => 'specify the Message-ID of a message',
 330 'oid=s' => 'specify the git object ID of a message',
 331
 332 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 333 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 334 'include=s' => 'include mailboxes/newsgroups based on pattern',
 335
 336 'exact' => 'operate on exact header matches only',
 337 'exact!' => 'rely on content match instead of exact header matches',
 338
 339 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 340
 341 'kw|keywords|flags!' => 'disable/enable importing flags',
 342
 343 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 344 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 345
 346 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 347 ); # %OPTDESC
 348
 349 my %CONFIG_KEYS = (
 350         'leistore.dir' => 'top-level storage location',
 351 );
 352
 353 my @WQ_KEYS = qw(lxs l2m imp mrr cnv p2q mark); # internal workers
 354
 355 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 356 sub x_it ($$) {
 357         my ($self, $code) = @_;
 358         # make sure client sees stdout before exit
 359         $self->{1}->autoflush(1) if $self->{1};
 360         dump_and_clear_log();
 361         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 362                 send($s, "x_it $code", MSG_EOR);
 363         } elsif ($self->{oneshot}) {
 364                 # don't want to end up using $? from child processes
 365                 for my $f (@WQ_KEYS) {
 366                         my $wq = delete $self->{$f} or next;
 367                         $wq->DESTROY;
 368                 }
 369                 # cleanup anything that has tempfiles or open file handles
 370                 %PATH2CFG = ();
 371                 delete @$self{qw(ovv dedupe sto cfg)};
 372                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 373                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 374                         kill $signum, $$;
 375                         sleep(1) while 1; # wait for signal
 376                 } else {
 377                         $quit->($code >> 8);
 378                 }
 379         } # else ignore if client disconnected
 380 }
 381
 382 sub err ($;@) {
 383         my $self = shift;
 384         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 385         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 386         print $err @_, @eor and return;
 387         my $old_err = delete $self->{2};
 388         close($old_err) if $! == EPIPE && $old_err;
 389         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 390         print $err @_, @eor or print STDERR @_, @eor;
 391 }
 392
 393 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 394
 395 sub fail_handler ($;$$) {
 396         my ($lei, $code, $io) = @_;
 397         for my $f (@WQ_KEYS) {
 398                 my $wq = delete $lei->{$f} or next;
 399                 $wq->wq_wait_old(undef, $lei) if $wq->wq_kill_old; # lei-daemon
 400         }
 401         close($io) if $io; # needed to avoid warnings on SIGPIPE
 402         x_it($lei, $code // (1 << 8));
 403 }
 404
 405 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 406         fail_handler($_[0], 13, delete $_[0]->{1});
 407 }
 408
 409 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 410 sub sigint_reap {
 411         my ($pgid) = @_;
 412         dwaitpid($pgid) if kill('-INT', $pgid);
 413 }
 414
 415 sub fail ($$;$) {
 416         my ($self, $buf, $exit_code) = @_;
 417         err($self, $buf) if defined $buf;
 418         # calls fail_handler:
 419         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 420         x_it($self, ($exit_code // 1) << 8);
 421         undef;
 422 }
 423
 424 sub out ($;@) {
 425         my $self = shift;
 426         return if print { $self->{1} // return } @_; # likely
 427         return note_sigpipe($self, 1) if $! == EPIPE;
 428         my $err = "error writing to output: $!";
 429         delete $self->{1};
 430         fail($self, $err);
 431 }
 432
 433 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 434
 435 sub child_error { # passes non-fatal curl exit codes to user
 436         my ($self, $child_error, $msg) = @_; # child_error is $?
 437         $self->err($msg) if $msg;
 438         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 439                 # send to the parent lei-daemon or to lei(1) client
 440                 send($s, "child_error $child_error", MSG_EOR);
 441         } elsif (!$PublicInbox::DS::in_loop) {
 442                 $self->{child_error} = $child_error;
 443         } # else noop if client disconnected
 444 }
 445
 446 sub note_sigpipe { # triggers sigpipe_handler
 447         my ($self, $fd) = @_;
 448         close(delete($self->{$fd})); # explicit close silences Perl warning
 449         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 450         x_it($self, 13);
 451 }
 452
 453 sub _lei_atfork_child {
 454         my ($self, $persist) = @_;
 455         # we need to explicitly close things which are on stack
 456         if ($persist) {
 457                 chdir '/' or die "chdir(/): $!";
 458                 my @io = delete @$self{qw(0 1 2 sock)};
 459                 unless ($self->{oneshot}) {
 460                         close($_) for @io;
 461                 }
 462                 if (my $cfg = $self->{cfg}) {
 463                         delete $cfg->{-lei_store};
 464                 }
 465         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 466                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 467         }
 468         for (delete @$self{qw(3 old_1 au_done)}) {
 469                 close($_) if defined($_);
 470         }
 471         if (my $op_c = delete $self->{pkt_op_c}) {
 472                 close(delete $op_c->{sock});
 473         }
 474         if (my $pgr = delete $self->{pgr}) {
 475                 close($_) for (@$pgr[1,2]);
 476         }
 477         close $listener if $listener;
 478         undef $listener;
 479         %PATH2CFG = ();
 480         undef $errors_log;
 481         $quit = \&CORE::exit;
 482         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 483 }
 484
 485 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 486         my ($self) = @_;
 487         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 488                 $op->close; # PublicInbox::PktOp::close
 489         }
 490         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 491         close $unclosed_after_die;
 492 }
 493
 494 sub pkt_op_pair {
 495         my ($self, $ops) = @_;
 496         require PublicInbox::OnDestroy;
 497         require PublicInbox::PktOp;
 498         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 499         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair($ops);
 500         $end;
 501 }
 502
 503 sub workers_start {
 504         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 505         $ops = {
 506                 '!' => [ \&fail_handler, $lei ],
 507                 '|' => [ \&sigpipe_handler, $lei ],
 508                 'x_it' => [ \&x_it, $lei ],
 509                 'child_error' => [ \&child_error, $lei ],
 510                 ($ops ? %$ops : ()),
 511         };
 512         $ops->{''} //= [ \&dclose, $lei ];
 513         my $end = $lei->pkt_op_pair($ops);
 514         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 515         delete $lei->{pkt_op_p};
 516         my $op = delete $lei->{pkt_op_c};
 517         @$end = ();
 518         $lei->event_step_init;
 519         # oneshot needs $op, daemon-mode uses DS->EventLoop to handle $op
 520         $lei->{oneshot} ? $op : undef;
 521 }
 522
 523 sub _help {
 524         require PublicInbox::LeiHelp;
 525         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 526 }
 527
 528 sub optparse ($$$) {
 529         my ($self, $cmd, $argv) = @_;
 530         # allow _complete --help to complete, not show help
 531         return 1 if substr($cmd, 0, 1) eq '_';
 532         $self->{cmd} = $cmd;
 533         $OPT = $self->{opt} //= {};
 534         my $info = $CMD{$cmd} // [ '[...]' ];
 535         my ($proto, undef, @spec) = @$info;
 536         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 537         push @spec, qw(help|h);
 538         my $lone_dash;
 539         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 540                 $lone_dash = $spec[0];
 541                 $OPT->{$spec[0]} = \(my $var);
 542                 push @spec, '' => \$var;
 543         }
 544         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 545                 return _help($self, "bad arguments or options for $cmd");
 546         return _help($self) if $OPT->{help};
 547
 548         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 549
 550         # "-" aliases "stdin" or "clear"
 551         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 552
 553         my $i = 0;
 554         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 555         my ($err, $inf);
 556         my @args = split(/ /, $proto);
 557         for my $var (@args) {
 558                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 559                         $inf = defined($argv->[$i]) and last;
 560                         $var =~ s/\.\.\.\z//;
 561                         $err = "$var not supplied";
 562                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 563                         $argv->[$i++] // ($err = "$var not supplied");
 564                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 565                         $inf = 1;
 566                         last;
 567                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 568                         $i++;
 569                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 570                         $inf = 1 if index($var, '...') > 0;
 571                         my @or = split(/\|/, $var);
 572                         my $ok;
 573                         for my $o (@or) {
 574                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 575                                         $ok = defined($OPT->{$1});
 576                                         last if $ok;
 577                                 } elsif (defined($argv->[$i])) {
 578                                         $ok = 1;
 579                                         $i++;
 580                                         last;
 581                                 } # else continue looping
 582                         }
 583                         last if $ok;
 584                         my $last = pop @or;
 585                         $err = join(', ', @or) . " or $last must be set";
 586                 } else {
 587                         warn "BUG: can't parse `$var' in $proto";
 588                 }
 589                 last if $err;
 590         }
 591         if (!$inf && scalar(@$argv) > scalar(@args)) {
 592                 $err //= 'too many arguments';
 593         }
 594         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 595 }
 596
 597 sub _tmp_cfg { # for lei -c <name>=<value> ...
 598         my ($self) = @_;
 599         my $cfg = _lei_cfg($self, 1);
 600         require File::Temp;
 601         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 602         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 603         $ft->autoflush(1);
 604         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 605 [include]
 606         path = $cfg->{-f}
 607 EOM
 608         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 609         for (@{$self->{opt}->{c}}) {
 610                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 611 `-c $_' is not of the form -c <name>=<value>'
 612 EOM
 613                 my $name = $1;
 614                 my $value = $2 // 1;
 615                 _config($self, '--add', $name, $value);
 616                 if (defined(my $v = $tmp->{$name})) {
 617                         if (ref($v) eq 'ARRAY') {
 618                                 push @$v, $value;
 619                         } else {
 620                                 $tmp->{$name} = [ $v, $value ];
 621                         }
 622                 } else {
 623                         $tmp->{$name} = $value;
 624                 }
 625         }
 626 }
 627
 628 sub lazy_cb ($$$) {
 629         my ($self, $cmd, $pfx) = @_;
 630         my $ucmd = $cmd;
 631         $ucmd =~ tr/-/_/;
 632         my $cb;
 633         $cb = $self->can($pfx.$ucmd) and return $cb;
 634         my $base = $ucmd;
 635         $base =~ s/_([a-z])/\u$1/g;
 636         my $pkg = "PublicInbox::Lei\u$base";
 637         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 638                 $pkg->can($pfx.$ucmd) : undef;
 639 }
 640
 641 sub dispatch {
 642         my ($self, $cmd, @argv) = @_;
 643         local $current_lei = $self; # for __WARN__
 644         dump_and_clear_log("from previous run\n");
 645         return _help($self, 'no command given') unless defined($cmd);
 646         # do not support Getopt bundling for this
 647         while ($cmd eq '-C' || $cmd eq '-c') {
 648                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 649                                         '-C DIRECTORY' : '-c <name>=<value>');
 650                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 651                 $cmd = shift(@argv) // return _help($self, 'no command given');
 652         }
 653         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 654                 optparse($self, $cmd, \@argv) or return;
 655                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 656                 if (my $chdir = $self->{opt}->{C}) {
 657                         for my $d (@$chdir) {
 658                                 next if $d eq ''; # same as git(1)
 659                                 chdir $d or return fail($self, "cd $d: $!");
 660                         }
 661                         if (delete $self->{3}) { # update cwd for rel2abs
 662                                 opendir my $dh, '.' or
 663                                         return fail($self, "opendir . $!");
 664                                 $self->{3} = $dh;
 665                         }
 666                 }
 667                 $cb->($self, @argv);
 668         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 669                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 670                         or return _help($self, 'bad arguments or options');
 671                 _help($self);
 672         } else {
 673                 fail($self, "`$cmd' is not an lei command");
 674         }
 675 }
 676
 677 sub _lei_cfg ($;$) {
 678         my ($self, $creat) = @_;
 679         return $self->{cfg} if $self->{cfg};
 680         my $f = _config_path($self);
 681         my @st = stat($f);
 682         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 683         my ($sto, $sto_dir);
 684         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 685                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 686                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 687         }
 688         if (!@st) {
 689                 unless ($creat) {
 690                         delete $self->{cfg};
 691                         return bless {}, 'PublicInbox::Config';
 692                 }
 693                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 694                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 695                 open my $fh, '>>', $f or die "open($f): $!\n";
 696                 @st = stat($fh) or die "fstat($f): $!\n";
 697                 $cur_st = pack('dd', $st[10], $st[7]);
 698                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 699         }
 700         my $cfg = PublicInbox::Config::git_config_dump($f);
 701         bless $cfg, 'PublicInbox::Config';
 702         $cfg->{-st} = $cur_st;
 703         $cfg->{'-f'} = $f;
 704         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 705                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 706                                                 store_path($self))) {
 707                 $cfg->{-lei_store} = $sto;
 708         }
 709         if (scalar(keys %PATH2CFG) > 5) {
 710                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 711                 for my $k (keys %PATH2CFG) {
 712                         delete($PATH2CFG{$k}) unless -f $k
 713                 }
 714         }
 715         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 716 }
 717
 718 sub _lei_store ($;$) {
 719         my ($self, $creat) = @_;
 720         my $cfg = _lei_cfg($self, $creat);
 721         $cfg->{-lei_store} //= do {
 722                 require PublicInbox::LeiStore;
 723                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 724                 return unless $creat || -d $dir;
 725                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 726         };
 727 }
 728
 729 sub lei_show {
 730         my ($self, @argv) = @_;
 731 }
 732
 733 sub _config {
 734         my ($self, @argv) = @_;
 735         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 736         my $cfg = _lei_cfg($self, 1);
 737         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 738         my %rdr = map { $_ => $self->{$_} } (0..2);
 739         waitpid(spawn($cmd, \%env, \%rdr), 0);
 740 }
 741
 742 sub lei_config {
 743         my ($self, @argv) = @_;
 744         $self->{opt}->{'config-file'} and return fail $self,
 745                 "config file switches not supported by `lei config'";
 746         _config(@_);
 747         x_it($self, $?) if $?;
 748 }
 749
 750 sub lei_init {
 751         my ($self, $dir) = @_;
 752         my $cfg = _lei_cfg($self, 1);
 753         my $cur = $cfg->{'leistore.dir'};
 754         $dir //= store_path($self);
 755         $dir = rel2abs($self, $dir);
 756         my @cur = stat($cur) if defined($cur);
 757         $cur = File::Spec->canonpath($cur // $dir);
 758         my @dir = stat($dir);
 759         my $exists = "# leistore.dir=$cur already initialized" if @dir;
 760         if (@cur) {
 761                 if ($cur eq $dir) {
 762                         _lei_store($self, 1)->done;
 763                         return qerr($self, $exists);
 764                 }
 765
 766                 # some folks like symlinks and bind mounts :P
 767                 if (@dir && "@cur[1,0]" eq "@dir[1,0]") {
 768                         lei_config($self, 'leistore.dir', $dir);
 769                         _lei_store($self, 1)->done;
 770                         return qerr($self, "$exists (as $cur)");
 771                 }
 772                 return fail($self, <<"");
 773 E: leistore.dir=$cur already initialized and it is not $dir
 774
 775         }
 776         lei_config($self, 'leistore.dir', $dir);
 777         _lei_store($self, 1)->done;
 778         $exists //= "# leistore.dir=$dir newly initialized";
 779         return qerr($self, $exists);
 780 }
 781
 782 sub lei_daemon_pid { puts shift, $$ }
 783
 784 sub lei_daemon_kill {
 785         my ($self) = @_;
 786         my $sig = $self->{opt}->{signal} // 'TERM';
 787         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 788 }
 789
 790 # Shell completion helper.  Used by lei-completion.bash and hopefully
 791 # other shells.  Try to do as much here as possible to avoid redundancy
 792 # and improve maintainability.
 793 sub lei__complete {
 794         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 795         shift @argv; # ignore "lei", the entire command is sent
 796         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 797         my $cmd = shift @argv;
 798         my $info = $CMD{$cmd} // do { # filter matching commands
 799                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 800                 return;
 801         };
 802         my ($proto, undef, @spec) = @$info;
 803         my $cur = pop @argv;
 804         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 805         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 806                 # gross special case since the only git-config options
 807                 # Consider moving to a table if we need more special cases
 808                 # we use Getopt::Long for are the ones we reject, so these
 809                 # are the ones we don't reject:
 810                 if ($cmd eq 'config') {
 811                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 812                         @spec = qw(add z|null get get-all unset unset-all
 813                                 replace-all get-urlmatch
 814                                 remove-section rename-section
 815                                 name-only list|l edit|e
 816                                 get-color-name get-colorbool);
 817                         # fall-through
 818                 }
 819                 # generate short/long names from Getopt::Long specs
 820                 puts $self, grep(/$re/, qw(--help -h -C), map {
 821                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 822                         } elsif (s/\+\z//) { # verbose|v+
 823                         } elsif (s/!\z//) {
 824                                 # negation: solve! => no-solve|solve
 825                                 s/([\w\-]+)/$1|no-$1/g
 826                         }
 827                         map {
 828                                 my $x = length > 1 ? "--$_" : "-$_";
 829                                 $x eq $_cur ? () : $x;
 830                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 831                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 832         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 833                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 834         }
 835
 836         # switch args (e.g. lei q -f mbox<TAB>)
 837         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 838                 my $opt = quotemeta $1;
 839                 puts $self, map {
 840                         my $v = $OPTDESC{$_};
 841                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 842                         # get rid of ALL CAPS placeholder (e.g "OUT")
 843                         # (TODO: completion for external paths)
 844                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 845                         @v;
 846                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 847         }
 848         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 849                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 850         }
 851         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 852         # proto parsing.
 853 }
 854
 855 sub exec_buf ($$) {
 856         my ($argv, $env) = @_;
 857         my $argc = scalar @$argv;
 858         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 859         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 860         $buf;
 861 }
 862
 863 sub start_mua {
 864         my ($self) = @_;
 865         my $mua = $self->{opt}->{mua} // return;
 866         my $mfolder = $self->{ovv}->{dst};
 867         my (@cmd, $replaced);
 868         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 869                 @cmd = ($mua, '-f');
 870         # TODO: help wanted: other common FOSS MUAs
 871         } else {
 872                 require Text::ParseWords;
 873                 @cmd = Text::ParseWords::shellwords($mua);
 874                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 875                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 876         }
 877         push @cmd, $mfolder unless defined($replaced);
 878         if (my $sock = $self->{sock}) { # lei(1) client process runs it
 879                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 880         } elsif ($self->{oneshot}) {
 881                 $self->{"pid.$self.$$"}->{spawn(\@cmd)} = \@cmd;
 882         }
 883         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 884                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 885         }
 886         $self->{opt}->{quiet} = 1;
 887         delete $self->{-progress};
 888         delete $self->{opt}->{verbose};
 889 }
 890
 891 sub send_exec_cmd { # tell script/lei to execute a command
 892         my ($self, $io, $cmd, $env) = @_;
 893         my $sock = $self->{sock} // die 'lei client gone';
 894         my $fds = [ map { fileno($_) } @$io ];
 895         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 896 }
 897
 898 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 899         my ($self) = @_;
 900         my $alerts = $self->{opt}->{alert} // return;
 901         while (my $op = shift(@$alerts)) {
 902                 if ($op eq ':WINCH') {
 903                         # hit the process group that started the MUA
 904                         if ($self->{sock}) {
 905                                 send($self->{sock}, '-WINCH', MSG_EOR);
 906                         } elsif ($self->{oneshot}) {
 907                                 kill('-WINCH', $$);
 908                         }
 909                 } elsif ($op eq ':bell') {
 910                         out($self, "\a");
 911                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 912                         push @$alerts, split(/(?<!\\),/, $op);
 913                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 914                         my $cmd = $1; # run an arbitrary command
 915                         require Text::ParseWords;
 916                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 917                         if (my $s = $self->{sock}) {
 918                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 919                         } elsif ($self->{oneshot}) {
 920                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 921                         }
 922                 } else {
 923                         err($self, "W: unsupported --alert=$op"); # non-fatal
 924                 }
 925         }
 926 }
 927
 928 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 929 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 930
 931 # this also normalizes the path
 932 sub path_to_fd {
 933         my ($self, $path) = @_;
 934         $path = rel2abs($self, $path);
 935         $path =~ tr!/!/!s;
 936         $path_to_fd{$path} // (
 937                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 938                         fail($self, "cannot open $path from daemon") : -1
 939         );
 940 }
 941
 942 # caller needs to "-t $self->{1}" to check if tty
 943 sub start_pager {
 944         my ($self) = @_;
 945         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 946         chomp(my $pager = <$fh> // '');
 947         close($fh) or warn "`git var PAGER' error: \$?=$?";
 948         return if $pager eq 'cat' || $pager eq '';
 949         my $new_env = { LESS => 'FRX', LV => '-c' };
 950         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 951         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 952         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 953         my $pgr = [ undef, @$rdr{1, 2} ];
 954         my $env = $self->{env};
 955         if ($self->{sock}) { # lei(1) process runs it
 956                 delete @$new_env{keys %$env}; # only set iff unset
 957                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 958         } elsif ($self->{oneshot}) {
 959                 my $cmd = [$pager];
 960                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 961         } else {
 962                 die 'BUG: start_pager w/o socket';
 963         }
 964         $self->{1} = $wpager;
 965         $self->{2} = $wpager if -t $self->{2};
 966         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 967         $self->{pgr} = $pgr;
 968 }
 969
 970 sub stop_pager {
 971         my ($self) = @_;
 972         my $pgr = delete($self->{pgr}) or return;
 973         $self->{2} = $pgr->[2];
 974         # do not restore original stdout, just close it so we error out
 975         close(delete($self->{1})) if $self->{1};
 976 }
 977
 978 sub accept_dispatch { # Listener {post_accept} callback
 979         my ($sock) = @_; # ignore other
 980         $sock->autoflush(1);
 981         my $self = bless { sock => $sock }, __PACKAGE__;
 982         vec(my $rvec = '', fileno($sock), 1) = 1;
 983         select($rvec, undef, undef, 60) or
 984                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 985         # (4096 * 33) >MAX_ARG_STRLEN
 986         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
 987         if (!defined($fds[0])) {
 988                 warn(my $msg = "recv_cmd failed: $!");
 989                 return send($sock, $msg, MSG_EOR);
 990         } else {
 991                 my $i = 0;
 992                 for my $fd (@fds) {
 993                         open($self->{$i++}, '+<&=', $fd) and next;
 994                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 995                 }
 996                 return if scalar(@fds) != 4;
 997         }
 998         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 999         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1000         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1001         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1002                 return send($sock, 'request command truncated', MSG_EOR);
1003         my ($argc, @argv) = split(/\0/, $buf, -1);
1004         undef $buf;
1005         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1006         if (chdir($self->{3})) {
1007                 local %ENV = %env;
1008                 $self->{env} = \%env;
1009                 eval { dispatch($self, @argv) };
1010                 send($sock, $@, MSG_EOR) if $@;
1011         } else {
1012                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1013         }
1014 }
1015
1016 sub dclose {
1017         my ($self) = @_;
1018         delete $self->{-progress};
1019         for my $f (@WQ_KEYS) {
1020                 my $wq = delete $self->{$f} or next;
1021                 if ($wq->wq_kill) {
1022                         $wq->wq_close(0, undef, $self);
1023                 } elsif ($wq->wq_kill_old) {
1024                         $wq->wq_wait_old(undef, $self);
1025                 }
1026         }
1027         close(delete $self->{1}) if $self->{1}; # may reap_compress
1028         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1029 }
1030
1031 # for long-running results
1032 sub event_step {
1033         my ($self) = @_;
1034         local %ENV = %{$self->{env}};
1035         my $sock = $self->{sock};
1036         local $current_lei = $self;
1037         eval {
1038                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1039                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1040                                 return if $! == EAGAIN;
1041                                 next if $! == EINTR;
1042                                 last if $! == ECONNRESET;
1043                                 die "recvmsg: $!";
1044                         }
1045                         for my $fd (@fds) {
1046                                 open my $rfh, '+<&=', $fd;
1047                         }
1048                         die "unrecognized client signal: $buf";
1049                 }
1050                 dclose($self);
1051         };
1052         if (my $err = $@) {
1053                 eval { $self->fail($err) };
1054                 dclose($self);
1055         }
1056 }
1057
1058 sub event_step_init {
1059         my ($self) = @_;
1060         return if $self->{-event_init_done}++;
1061         if (my $sock = $self->{sock}) { # using DS->EventLoop
1062                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1063         }
1064 }
1065
1066 sub noop {}
1067
1068 sub oldset { $oldset }
1069
1070 sub dump_and_clear_log {
1071         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1072                 my @pfx = @_;
1073                 unshift(@pfx, "$errors_log ") if @pfx;
1074                 warn @pfx, do { local $/; <STDIN> };
1075                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1076         }
1077 }
1078
1079 # lei(1) calls this when it can't connect
1080 sub lazy_start {
1081         my ($path, $errno, $narg) = @_;
1082         local ($errors_log, $listener);
1083         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1084         $errors_log .= 'errors.log';
1085         my $addr = pack_sockaddr_un($path);
1086         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1087         $lk->lock_acquire;
1088         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1089         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1090                 return if connect($listener, $addr); # another process won
1091                 if ($errno == ECONNREFUSED && -S $path) {
1092                         unlink($path) or die "unlink($path): $!";
1093                 }
1094         } else {
1095                 $! = $errno; # allow interpolation to stringify in die
1096                 die "connect($path): $!";
1097         }
1098         umask(077) // die("umask(077): $!");
1099         bind($listener, $addr) or die "bind($path): $!";
1100         listen($listener, 1024) or die "listen: $!";
1101         $lk->lock_release;
1102         undef $lk;
1103         my @st = stat($path) or die "stat($path): $!";
1104         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1105         local $oldset = PublicInbox::DS::block_signals();
1106         if ($narg == 5) {
1107                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1108                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1109                         require PublicInbox::CmdIPC4;
1110                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1111                         PublicInbox::CmdIPC4->can('recv_cmd4');
1112                 };
1113         }
1114         $recv_cmd or die <<"";
1115 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1116
1117         require PublicInbox::Listener;
1118         require PublicInbox::EOFpipe;
1119         (-p STDOUT) or die "E: stdout must be a pipe\n";
1120         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1121         STDIN->autoflush(1);
1122         dump_and_clear_log("from previous daemon process:\n");
1123         POSIX::setsid() > 0 or die "setsid: $!";
1124         my $pid = fork // die "fork: $!";
1125         return if $pid;
1126         $0 = "lei-daemon $path";
1127         local %PATH2CFG;
1128         $listener->blocking(0);
1129         my $exit_code;
1130         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1131         local $quit = do {
1132                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1133                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1134                 sub {
1135                         $exit_code //= shift;
1136                         my $lis = $pil or exit($exit_code);
1137                         # closing eof_w triggers \&noop wakeup
1138                         $listener = $eof_w = $pil = $path = undef;
1139                         $lis->close; # DS::close
1140                         PublicInbox::DS->SetLoopTimeout(1000);
1141                 };
1142         };
1143         my $sig = {
1144                 CHLD => \&PublicInbox::DS::enqueue_reap,
1145                 QUIT => $quit,
1146                 INT => $quit,
1147                 TERM => $quit,
1148                 HUP => \&noop,
1149                 USR1 => \&noop,
1150                 USR2 => \&noop,
1151         };
1152         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1153         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1154         undef $sig;
1155         local $SIG{PIPE} = 'IGNORE';
1156         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1157                 undef $sigfd;
1158                 PublicInbox::DS->SetLoopTimeout(5000);
1159         } else {
1160                 # wake up every second to accept signals if we don't
1161                 # have signalfd or IO::KQueue:
1162                 PublicInbox::DS::sig_setmask($oldset);
1163                 PublicInbox::DS->SetLoopTimeout(1000);
1164         }
1165         PublicInbox::DS->SetPostLoopCallback(sub {
1166                 my ($dmap, undef) = @_;
1167                 if (@st = defined($path) ? stat($path) : ()) {
1168                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1169                                 warn "$path dev/ino changed, quitting\n";
1170                                 $path = undef;
1171                         }
1172                 } elsif (defined($path)) { # ENOENT is common
1173                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1174                         undef $path;
1175                         $quit->();
1176                 }
1177                 return 1 if defined($path);
1178                 my $now = now();
1179                 my $n = 0;
1180                 for my $s (values %$dmap) {
1181                         $s->can('busy') or next;
1182                         if ($s->busy($now)) {
1183                                 ++$n;
1184                         } else {
1185                                 $s->close;
1186                         }
1187                 }
1188                 $n; # true: continue, false: stop
1189         });
1190
1191         # STDIN was redirected to /dev/null above, closing STDERR and
1192         # STDOUT will cause the calling `lei' client process to finish
1193         # reading the <$daemon> pipe.
1194         local $SIG{__WARN__} = sub {
1195                 $current_lei ? err($current_lei, @_) : warn(
1196                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1197         };
1198         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1199         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1200         # $daemon pipe to `lei' closed, main loop begins:
1201         PublicInbox::DS->EventLoop;
1202         exit($exit_code // 0);
1203 }
1204
1205 sub busy { 1 } # prevent daemon-shutdown if client is connected
1206
1207 # for users w/o Socket::Msghdr installed or Inline::C enabled
1208 sub oneshot {
1209         my ($main_pkg) = @_;
1210         my $exit = $main_pkg->can('exit'); # caller may override exit()
1211         local $quit = $exit if $exit;
1212         local %PATH2CFG;
1213         umask(077) // die("umask(077): $!");
1214         my $self = bless {
1215                 oneshot => 1,
1216                 0 => *STDIN{GLOB},
1217                 1 => *STDOUT{GLOB},
1218                 2 => *STDERR{GLOB},
1219                 env => \%ENV
1220         }, __PACKAGE__;
1221         dispatch($self, @ARGV);
1222         x_it($self, $self->{child_error}) if $self->{child_error};
1223 }
1224
1225 # ensures stdout hits the FS before sock disconnects so a client
1226 # can immediately reread it
1227 sub DESTROY {
1228         my ($self) = @_;
1229         $self->{1}->autoflush(1) if $self->{1};
1230         stop_pager($self);
1231         my $err = $?;
1232         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1233         waitpid($_, 0) for keys %$oneshot_pids;
1234         $? = $err if $err; # preserve ->fail or ->x_it code
1235 }
1236
1237 1;