lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use Time::HiRes qw(stat); # ctime comparisons for config cache
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log, $listener, $oldset);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub rel2abs ($$) {
  68         my ($self, $p) = @_;
  69         return $p if index($p, '/') == 0; # already absolute
  70         my $pwd = $self->{env}->{PWD};
  71         my $cwd;
  72         if (defined $pwd) {
  73                 my $xcwd = $self->{3} //
  74                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  75                 if (my @st_pwd = stat($pwd)) {
  76                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  77                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  78                                 $self->{env}->{PWD} = $pwd = undef;
  79                 } else { # PWD was invalid
  80                         $self->{env}->{PWD} = $pwd = undef;
  81                 }
  82         }
  83         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  84         File::Spec->rel2abs($p, $pwd);
  85 }
  86
  87 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  88         my ($self) = @_;
  89         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  90                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  91                 .'/lei');
  92 }
  93
  94 sub store_path ($) { share_path($_[0]) . '/store' }
  95
  96 sub _config_path ($) {
  97         my ($self) = @_;
  98         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
  99                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 100                 .'/lei/config');
 101 }
 102
 103 sub cache_dir ($) {
 104         my ($self) = @_;
 105         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 106                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 107                 .'/lei');
 108 }
 109
 110 sub ale {
 111         my ($self) = @_;
 112         $self->{ale} //= do {
 113                 require PublicInbox::LeiALE;
 114                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 115         };
 116 }
 117
 118 sub index_opt {
 119         # TODO: drop underscore variants everywhere, they're undocumented
 120         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 121         max_size|max-size=s sequential_shard|sequential-shard
 122         batch_size|batch-size=s skip-docdata)
 123 }
 124
 125 my @c_opt = qw(c=s@ C=s@ quiet|q);
 126 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 127         import-remote! no-torsocks torsocks=s),
 128         PublicInbox::LeiQuery::curl_opt());
 129
 130 # we generate shell completion + help using %CMD and %OPTDESC,
 131 # see lei__complete() and PublicInbox::LeiHelp
 132 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 133 our %CMD = ( # sorted in order of importance/use:
 134 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 135         'stdin|', # /|\z/ must be first for lone dash
 136         @lxs_opt,
 137         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 138         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 139         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+), @c_opt,
 140         opt_dash('limit|n=i', '[0-9]+') ],
 141 'up' => [ 'SEARCH_TERMS...', 'update saved search',
 142         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+), @c_opt ],
 143
 144 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 145         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 146         @lxs_opt, @c_opt ],
 147
 148 'add-external' => [ 'LOCATION',
 149         'add/set priority of a publicinbox|extindex for extra matches',
 150         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 151         verbose|v+), @c_opt, index_opt(),
 152         PublicInbox::LeiQuery::curl_opt() ],
 153 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 154         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 155 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 156 'forget-external' => [ 'LOCATION...|--prune',
 157         'exclude further results from a publicinbox|extindex',
 158         qw(prune), @c_opt ],
 159
 160 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 161                 qw(name-only format|f=s), @c_opt ],
 162 'rm-query' => [ 'QUERY_NAME', 'remove a saved search', @c_opt ],
 163 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search', @c_opt ],
 164
 165 'plonk' => [ '--threads|--from=IDENT',
 166         'exclude mail matching From: or threads from non-Message-ID searches',
 167         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 168 'tag' => [ 'KEYWORDS...',
 169         'set/unset keywords and/or labels on message(s)',
 170         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@), @c_opt,
 171         pass_through('-kw:foo for delete') ],
 172 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 173         "exclude message(s) on stdin from `q' search results",
 174         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 175
 176 'purge-mailsource' => [ 'LOCATION|--all',
 177         'remove imported messages from IMAP, Maildirs, and MH',
 178         qw(exact! all jobs:i indexed), @c_opt ],
 179
 180 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 181         qw(import! kw|keywords|flags! interval=s recursive|r
 182         exclude=s include=s), @c_opt ],
 183 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 184                 qw(format|f=s z), @c_opt ],
 185 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 186 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 187 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 188         qw(prune), @c_opt ],
 189
 190 'import' => [ 'LOCATION...|--stdin',
 191         'one-time import/update from URL or filesystem',
 192         qw(stdin| offset=i recursive|r exclude=s include|I=s
 193         lock=s@ in-format|F=s kw|keywords|flags! verbose|v+), @c_opt ],
 194 'convert' => [ 'LOCATION...|--stdin',
 195         'one-time conversion from URL or filesystem to another format',
 196         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s
 197         lock=s@ kw|keywords|flags!), @c_opt ],
 198 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 199         "use a patch to generate a query for `lei q --stdin'",
 200         qw(stdin| want|w=s@ uri debug), @c_opt ],
 201 'config' => [ '[...]', sub {
 202                 'git-config(1) wrapper for '._config_path($_[0]);
 203         }, qw(config-file|system|global|file|f=s), # for conflict detection
 204          qw(c=s@ C=s@), pass_through('git config') ],
 205 'init' => [ '[DIRNAME]', sub {
 206         "initialize storage, default: ".store_path($_[0]);
 207         }, @c_opt ],
 208 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 209         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 210         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 211 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 212 'help' => [ '[SUBCOMMAND]', 'show help' ],
 213
 214 # XXX do we need this?
 215 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 216
 217 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 218         'rewrite git history in an attempt to improve compression',
 219         qw(gc!), @c_opt ],
 220
 221 # internal commands are prefixed with '_'
 222 '_complete' => [ '[...]', 'internal shell completion helper',
 223                 pass_through('everything') ],
 224 ); # @CMD
 225
 226 # switch descriptions, try to keep consistent across commands
 227 # $spec: Getopt::Long option specification
 228 # $spec => [@ALLOWED_VALUES (default is first), $description],
 229 # $spec => $description
 230 # "$SUB_COMMAND TAB $spec" => as above
 231 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 232                         'specify message input format' ];
 233 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 234
 235 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 236 my %OPTDESC = (
 237 'help|h' => 'show this built-in help',
 238 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 239 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 240 'quiet|q' => 'be quiet',
 241 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 242         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 243
 244 'globoff|g' => "do not match locations using '*?' wildcards ".
 245                 "and\xa0'[]'\x{a0}ranges",
 246 'verbose|v+' => 'be more verbose',
 247 'external!' => 'do not use externals',
 248 'mail!' => 'do not look in mail storage for OID',
 249 'cwd!' => 'do not look in git repo of current working directory',
 250 'oid-a|A=s' => 'pre-image OID',
 251 'path-a|a=s' => 'pre-image pathname associated with OID',
 252 'path-b|b=s' => 'post-image pathname associated with OID',
 253 'git-dir=s@' => 'additional git repository to scan',
 254 'torsocks=s' => ['VAL|auto|no|yes',
 255                 'whether or not to wrap git and curl commands with torsocks'],
 256 'no-torsocks' => 'alias for --torsocks=no',
 257 'save' =>  "save a search for `lei up'",
 258 'import-remote!' => 'do not memoize remote messages into local store',
 259
 260 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 261
 262 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 263                 'deduplication strategy'],
 264 'threads|t+' =>
 265         'return all messages in the same threads as the actual match(es)',
 266
 267 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 268                 'search prefixes to extract (default: dfpost7)' ],
 269
 270 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 271         'run command(s) or perform ops when done writing to output ' .
 272         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 273         'nothing otherwise)' ],
 274
 275 'augment|a' => 'augment --output destination instead of clobbering',
 276
 277 'output|mfolder|o=s' => [ 'MFOLDER',
 278         "destination (e.g.\xa0`/path/to/Maildir', ".
 279         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 280 'mua=s' => [ 'CMD',
 281         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 282
 283 'inbox-version=i' => [ 'NUM|1|2',
 284                 'force a public-inbox version with --mirror'],
 285 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 286
 287 # public-inbox-index options
 288 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 289 'compact' => 'run compact index after mirroring',
 290 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 291         "indexlevel with --mirror (default: full)" ],
 292 'max_size|max-size=s' => [ 'SIZE',
 293         'do not index messages larger than SIZE (default: infinity)' ],
 294 'batch_size|batch-size=s' => [ 'SIZE',
 295         'flush changes to OS after given number of bytes (default: 1m)' ],
 296 'sequential_shard|sequential-shard' =>
 297         'index Xapian shards sequentially for slow storage',
 298 'skip-docdata' =>
 299         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 300
 301 'format|f=s     q' => [
 302         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 303                 'specify output format, default depends on --output'],
 304 'exclude=s@     q' => [ 'LOCATION',
 305                 'exclude specified external(s) from search' ],
 306 'include|I=s@   q' => [ 'LOCATION',
 307                 'include specified external(s) in search' ],
 308 'only=s@        q' => [ 'LOCATION',
 309                 'only use specified external(s) for search' ],
 310 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 311                 'control number of search and writer jobs' ],
 312 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 313
 314 'in-format|F=s' => $stdin_formats,
 315 'format|f=s     ls-query' => $ls_format,
 316 'format|f=s     ls-external' => $ls_format,
 317
 318 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 319 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 320
 321 'sort|s=s' => [ 'VAL|received|relevance|docid',
 322                 "order of results is `--output'-dependent"],
 323 'reverse|r' => 'reverse search results', # like sort(1)
 324
 325 'boost=i' => 'increase/decrease priority of results (default: 0)',
 326
 327 'local' => 'limit operations to the local filesystem',
 328 'local!' => 'exclude results from the local filesystem',
 329 'remote' => 'limit operations to those requiring network access',
 330 'remote!' => 'prevent operations requiring network access',
 331
 332 'mid=s' => 'specify the Message-ID of a message',
 333 'oid=s' => 'specify the git object ID of a message',
 334
 335 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 336 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 337 'include=s' => 'include mailboxes/newsgroups based on pattern',
 338
 339 'exact' => 'operate on exact header matches only',
 340 'exact!' => 'rely on content match instead of exact header matches',
 341
 342 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 343
 344 'kw|keywords|flags!' => 'disable/enable importing flags',
 345
 346 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 347 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 348
 349 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 350 ); # %OPTDESC
 351
 352 my %CONFIG_KEYS = (
 353         'leistore.dir' => 'top-level storage location',
 354 );
 355
 356 my @WQ_KEYS = qw(lxs l2m imp mrr cnv p2q tag sol); # internal workers
 357
 358 sub _drop_wq {
 359         my ($self) = @_;
 360         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) { $wq->DESTROY }
 361 }
 362
 363 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 364 sub x_it ($$) {
 365         my ($self, $code) = @_;
 366         # make sure client sees stdout before exit
 367         $self->{1}->autoflush(1) if $self->{1};
 368         dump_and_clear_log();
 369         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 370                 send($s, "x_it $code", MSG_EOR);
 371         } elsif ($self->{oneshot}) {
 372                 # don't want to end up using $? from child processes
 373                 _drop_wq($self);
 374                 # cleanup anything that has tempfiles or open file handles
 375                 %PATH2CFG = ();
 376                 delete @$self{qw(ovv dedupe sto cfg)};
 377                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 378                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 379                         kill $signum, $$;
 380                         sleep(1) while 1; # wait for signal
 381                 } else {
 382                         $quit->($code >> 8);
 383                 }
 384         } # else ignore if client disconnected
 385 }
 386
 387 sub err ($;@) {
 388         my $self = shift;
 389         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 390         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 391         print $err @_, @eor and return;
 392         my $old_err = delete $self->{2};
 393         close($old_err) if $! == EPIPE && $old_err;
 394         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 395         print $err @_, @eor or print STDERR @_, @eor;
 396 }
 397
 398 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 399
 400 sub fail_handler ($;$$) {
 401         my ($lei, $code, $io) = @_;
 402         close($io) if $io; # needed to avoid warnings on SIGPIPE
 403         _drop_wq($lei);
 404         x_it($lei, $code // (1 << 8));
 405 }
 406
 407 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 408         fail_handler($_[0], 13, delete $_[0]->{1});
 409 }
 410
 411 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 412 sub sigint_reap {
 413         my ($pgid) = @_;
 414         dwaitpid($pgid) if kill('-INT', $pgid);
 415 }
 416
 417 sub fail ($$;$) {
 418         my ($self, $buf, $exit_code) = @_;
 419         err($self, $buf) if defined $buf;
 420         # calls fail_handler:
 421         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 422         x_it($self, ($exit_code // 1) << 8);
 423         undef;
 424 }
 425
 426 sub out ($;@) {
 427         my $self = shift;
 428         return if print { $self->{1} // return } @_; # likely
 429         return note_sigpipe($self, 1) if $! == EPIPE;
 430         my $err = "error writing to output: $!";
 431         delete $self->{1};
 432         fail($self, $err);
 433 }
 434
 435 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 436
 437 sub child_error { # passes non-fatal curl exit codes to user
 438         my ($self, $child_error, $msg) = @_; # child_error is $?
 439         $self->err($msg) if $msg;
 440         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 441                 # send to the parent lei-daemon or to lei(1) client
 442                 send($s, "child_error $child_error", MSG_EOR);
 443         } elsif (!$PublicInbox::DS::in_loop) {
 444                 $self->{child_error} = $child_error;
 445         } # else noop if client disconnected
 446 }
 447
 448 sub note_sigpipe { # triggers sigpipe_handler
 449         my ($self, $fd) = @_;
 450         close(delete($self->{$fd})); # explicit close silences Perl warning
 451         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 452         x_it($self, 13);
 453 }
 454
 455 sub _lei_atfork_child {
 456         my ($self, $persist) = @_;
 457         # we need to explicitly close things which are on stack
 458         if ($persist) {
 459                 chdir '/' or die "chdir(/): $!";
 460                 my @io = delete @$self{qw(0 1 2 sock)};
 461                 unless ($self->{oneshot}) {
 462                         close($_) for @io;
 463                 }
 464                 if (my $cfg = $self->{cfg}) {
 465                         delete $cfg->{-lei_store};
 466                 }
 467         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 468                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 469         }
 470         for (delete @$self{qw(3 old_1 au_done)}) {
 471                 close($_) if defined($_);
 472         }
 473         if (my $op_c = delete $self->{pkt_op_c}) {
 474                 close(delete $op_c->{sock});
 475         }
 476         if (my $pgr = delete $self->{pgr}) {
 477                 close($_) for (@$pgr[1,2]);
 478         }
 479         close $listener if $listener;
 480         undef $listener;
 481         %PATH2CFG = ();
 482         undef $errors_log;
 483         $quit = \&CORE::exit;
 484         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 485 }
 486
 487 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 488         my ($self) = @_;
 489         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 490                 $op->close; # PublicInbox::PktOp::close
 491         }
 492         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 493         close $unclosed_after_die;
 494 }
 495
 496 sub pkt_op_pair {
 497         my ($self) = @_;
 498         require PublicInbox::OnDestroy;
 499         require PublicInbox::PktOp;
 500         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 501         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 502         $end;
 503 }
 504
 505 sub workers_start {
 506         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 507         $ops = {
 508                 '!' => [ \&fail_handler, $lei ],
 509                 '|' => [ \&sigpipe_handler, $lei ],
 510                 'x_it' => [ \&x_it, $lei ],
 511                 'child_error' => [ \&child_error, $lei ],
 512                 ($ops ? %$ops : ()),
 513         };
 514         $ops->{''} //= [ \&dclose, $lei ];
 515         my $end = $lei->pkt_op_pair;
 516         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 517         delete $lei->{pkt_op_p};
 518         my $op_c = delete $lei->{pkt_op_c};
 519         @$end = ();
 520         $lei->event_step_init;
 521         ($op_c, $ops);
 522 }
 523
 524 sub _help {
 525         require PublicInbox::LeiHelp;
 526         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 527 }
 528
 529 sub optparse ($$$) {
 530         my ($self, $cmd, $argv) = @_;
 531         # allow _complete --help to complete, not show help
 532         return 1 if substr($cmd, 0, 1) eq '_';
 533         $self->{cmd} = $cmd;
 534         $OPT = $self->{opt} //= {};
 535         my $info = $CMD{$cmd} // [ '[...]' ];
 536         my ($proto, undef, @spec) = @$info;
 537         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 538         push @spec, qw(help|h);
 539         my $lone_dash;
 540         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 541                 $lone_dash = $spec[0];
 542                 $OPT->{$spec[0]} = \(my $var);
 543                 push @spec, '' => \$var;
 544         }
 545         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 546                 return _help($self, "bad arguments or options for $cmd");
 547         return _help($self) if $OPT->{help};
 548
 549         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 550
 551         # "-" aliases "stdin" or "clear"
 552         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 553
 554         my $i = 0;
 555         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 556         my ($err, $inf);
 557         my @args = split(/ /, $proto);
 558         for my $var (@args) {
 559                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 560                         $inf = defined($argv->[$i]) and last;
 561                         $var =~ s/\.\.\.\z//;
 562                         $err = "$var not supplied";
 563                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 564                         $argv->[$i++] // ($err = "$var not supplied");
 565                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 566                         $inf = 1;
 567                         last;
 568                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 569                         $i++;
 570                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 571                         $inf = 1 if index($var, '...') > 0;
 572                         my @or = split(/\|/, $var);
 573                         my $ok;
 574                         for my $o (@or) {
 575                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 576                                         $ok = defined($OPT->{$1});
 577                                         last if $ok;
 578                                 } elsif (defined($argv->[$i])) {
 579                                         $ok = 1;
 580                                         $i++;
 581                                         last;
 582                                 } # else continue looping
 583                         }
 584                         last if $ok;
 585                         my $last = pop @or;
 586                         $err = join(', ', @or) . " or $last must be set";
 587                 } else {
 588                         warn "BUG: can't parse `$var' in $proto";
 589                 }
 590                 last if $err;
 591         }
 592         if (!$inf && scalar(@$argv) > scalar(@args)) {
 593                 $err //= 'too many arguments';
 594         }
 595         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 596 }
 597
 598 sub _tmp_cfg { # for lei -c <name>=<value> ...
 599         my ($self) = @_;
 600         my $cfg = _lei_cfg($self, 1);
 601         require File::Temp;
 602         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 603         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 604         $ft->autoflush(1);
 605         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 606 [include]
 607         path = $cfg->{-f}
 608 EOM
 609         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 610         for (@{$self->{opt}->{c}}) {
 611                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 612 `-c $_' is not of the form -c <name>=<value>'
 613 EOM
 614                 my $name = $1;
 615                 my $value = $2 // 1;
 616                 _config($self, '--add', $name, $value);
 617                 if (defined(my $v = $tmp->{$name})) {
 618                         if (ref($v) eq 'ARRAY') {
 619                                 push @$v, $value;
 620                         } else {
 621                                 $tmp->{$name} = [ $v, $value ];
 622                         }
 623                 } else {
 624                         $tmp->{$name} = $value;
 625                 }
 626         }
 627 }
 628
 629 sub lazy_cb ($$$) {
 630         my ($self, $cmd, $pfx) = @_;
 631         my $ucmd = $cmd;
 632         $ucmd =~ tr/-/_/;
 633         my $cb;
 634         $cb = $self->can($pfx.$ucmd) and return $cb;
 635         my $base = $ucmd;
 636         $base =~ s/_([a-z])/\u$1/g;
 637         my $pkg = "PublicInbox::Lei\u$base";
 638         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 639                 $pkg->can($pfx.$ucmd) : undef;
 640 }
 641
 642 sub dispatch {
 643         my ($self, $cmd, @argv) = @_;
 644         local $current_lei = $self; # for __WARN__
 645         dump_and_clear_log("from previous run\n");
 646         return _help($self, 'no command given') unless defined($cmd);
 647         # do not support Getopt bundling for this
 648         while ($cmd eq '-C' || $cmd eq '-c') {
 649                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 650                                         '-C DIRECTORY' : '-c <name>=<value>');
 651                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 652                 $cmd = shift(@argv) // return _help($self, 'no command given');
 653         }
 654         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 655                 optparse($self, $cmd, \@argv) or return;
 656                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 657                 if (my $chdir = $self->{opt}->{C}) {
 658                         for my $d (@$chdir) {
 659                                 next if $d eq ''; # same as git(1)
 660                                 chdir $d or return fail($self, "cd $d: $!");
 661                         }
 662                         if (delete $self->{3}) { # update cwd for rel2abs
 663                                 opendir my $dh, '.' or
 664                                         return fail($self, "opendir . $!");
 665                                 $self->{3} = $dh;
 666                         }
 667                 }
 668                 $cb->($self, @argv);
 669         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 670                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 671                         or return _help($self, 'bad arguments or options');
 672                 _help($self);
 673         } else {
 674                 fail($self, "`$cmd' is not an lei command");
 675         }
 676 }
 677
 678 sub _lei_cfg ($;$) {
 679         my ($self, $creat) = @_;
 680         return $self->{cfg} if $self->{cfg};
 681         my $f = _config_path($self);
 682         my @st = stat($f);
 683         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 684         my ($sto, $sto_dir);
 685         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 686                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 687                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 688         }
 689         if (!@st) {
 690                 unless ($creat) {
 691                         delete $self->{cfg};
 692                         return bless {}, 'PublicInbox::Config';
 693                 }
 694                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 695                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 696                 open my $fh, '>>', $f or die "open($f): $!\n";
 697                 @st = stat($fh) or die "fstat($f): $!\n";
 698                 $cur_st = pack('dd', $st[10], $st[7]);
 699                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 700         }
 701         my $cfg = PublicInbox::Config::git_config_dump($f);
 702         bless $cfg, 'PublicInbox::Config';
 703         $cfg->{-st} = $cur_st;
 704         $cfg->{'-f'} = $f;
 705         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 706                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 707                                                 store_path($self))) {
 708                 $cfg->{-lei_store} = $sto;
 709         }
 710         if (scalar(keys %PATH2CFG) > 5) {
 711                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 712                 for my $k (keys %PATH2CFG) {
 713                         delete($PATH2CFG{$k}) unless -f $k
 714                 }
 715         }
 716         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 717 }
 718
 719 sub _lei_store ($;$) {
 720         my ($self, $creat) = @_;
 721         my $cfg = _lei_cfg($self, $creat);
 722         $cfg->{-lei_store} //= do {
 723                 require PublicInbox::LeiStore;
 724                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 725                 return unless $creat || -d $dir;
 726                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 727         };
 728 }
 729
 730 sub _config {
 731         my ($self, @argv) = @_;
 732         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 733         my $cfg = _lei_cfg($self, 1);
 734         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 735         my %rdr = map { $_ => $self->{$_} } (0..2);
 736         waitpid(spawn($cmd, \%env, \%rdr), 0);
 737 }
 738
 739 sub lei_config {
 740         my ($self, @argv) = @_;
 741         $self->{opt}->{'config-file'} and return fail $self,
 742                 "config file switches not supported by `lei config'";
 743         _config(@_);
 744         x_it($self, $?) if $?;
 745 }
 746
 747 sub lei_daemon_pid { puts shift, $$ }
 748
 749 sub lei_daemon_kill {
 750         my ($self) = @_;
 751         my $sig = $self->{opt}->{signal} // 'TERM';
 752         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 753 }
 754
 755 # Shell completion helper.  Used by lei-completion.bash and hopefully
 756 # other shells.  Try to do as much here as possible to avoid redundancy
 757 # and improve maintainability.
 758 sub lei__complete {
 759         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 760         shift @argv; # ignore "lei", the entire command is sent
 761         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 762         my $cmd = shift @argv;
 763         my $info = $CMD{$cmd} // do { # filter matching commands
 764                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 765                 return;
 766         };
 767         my ($proto, undef, @spec) = @$info;
 768         my $cur = pop @argv;
 769         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 770         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 771                 # gross special case since the only git-config options
 772                 # Consider moving to a table if we need more special cases
 773                 # we use Getopt::Long for are the ones we reject, so these
 774                 # are the ones we don't reject:
 775                 if ($cmd eq 'config') {
 776                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 777                         @spec = qw(add z|null get get-all unset unset-all
 778                                 replace-all get-urlmatch
 779                                 remove-section rename-section
 780                                 name-only list|l edit|e
 781                                 get-color-name get-colorbool);
 782                         # fall-through
 783                 }
 784                 # generate short/long names from Getopt::Long specs
 785                 puts $self, grep(/$re/, qw(--help -h -C), map {
 786                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 787                         } elsif (s/\+\z//) { # verbose|v+
 788                         } elsif (s/!\z//) {
 789                                 # negation: mail! => no-mail|mail
 790                                 s/([\w\-]+)/$1|no-$1/g
 791                         }
 792                         map {
 793                                 my $x = length > 1 ? "--$_" : "-$_";
 794                                 $x eq $_cur ? () : $x;
 795                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 796                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 797         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 798                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 799         }
 800
 801         # switch args (e.g. lei q -f mbox<TAB>)
 802         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 803                 my $opt = quotemeta $1;
 804                 puts $self, map {
 805                         my $v = $OPTDESC{$_};
 806                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 807                         # get rid of ALL CAPS placeholder (e.g "OUT")
 808                         # (TODO: completion for external paths)
 809                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 810                         @v;
 811                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 812         }
 813         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 814                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 815         }
 816         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 817         # proto parsing.
 818 }
 819
 820 sub exec_buf ($$) {
 821         my ($argv, $env) = @_;
 822         my $argc = scalar @$argv;
 823         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 824         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 825         $buf;
 826 }
 827
 828 sub start_mua {
 829         my ($self) = @_;
 830         my $mua = $self->{opt}->{mua} // return;
 831         my $mfolder = $self->{ovv}->{dst};
 832         my (@cmd, $replaced);
 833         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 834                 @cmd = ($mua, '-f');
 835         # TODO: help wanted: other common FOSS MUAs
 836         } else {
 837                 require Text::ParseWords;
 838                 @cmd = Text::ParseWords::shellwords($mua);
 839                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 840                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 841         }
 842         push @cmd, $mfolder unless defined($replaced);
 843         if ($self->{sock}) { # lei(1) client process runs it
 844                 # restore terminal: echo $query | lei q -stdin --mua=...
 845                 my $io = [];
 846                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 847                 send_exec_cmd($self, $io, \@cmd, {});
 848         } elsif ($self->{oneshot}) {
 849                 my $pid = fork // die "fork: $!";
 850                 if ($pid > 0) { # original process
 851                         if ($self->{opt}->{stdin} && -t STDOUT) {
 852                                 open STDIN, '+<&', \*STDOUT or die "dup2: $!";
 853                         }
 854                         exec(@cmd);
 855                         warn "exec @cmd: $!\n";
 856                         POSIX::_exit(1);
 857                 }
 858                 POSIX::setsid() > 0 or die "setsid: $!";
 859         }
 860         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 861                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 862         }
 863         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 864         $self->{opt}->{quiet} = 1;
 865         delete $self->{-progress};
 866         delete $self->{opt}->{verbose};
 867 }
 868
 869 sub send_exec_cmd { # tell script/lei to execute a command
 870         my ($self, $io, $cmd, $env) = @_;
 871         my $sock = $self->{sock} // die 'lei client gone';
 872         my $fds = [ map { fileno($_) } @$io ];
 873         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 874 }
 875
 876 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 877         my ($self) = @_;
 878         my $alerts = $self->{opt}->{alert} // return;
 879         while (my $op = shift(@$alerts)) {
 880                 if ($op eq ':WINCH') {
 881                         # hit the process group that started the MUA
 882                         if ($self->{sock}) {
 883                                 send($self->{sock}, '-WINCH', MSG_EOR);
 884                         } elsif ($self->{oneshot}) {
 885                                 kill('-WINCH', $$);
 886                         }
 887                 } elsif ($op eq ':bell') {
 888                         out($self, "\a");
 889                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 890                         push @$alerts, split(/(?<!\\),/, $op);
 891                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 892                         my $cmd = $1; # run an arbitrary command
 893                         require Text::ParseWords;
 894                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 895                         if (my $s = $self->{sock}) {
 896                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 897                         } elsif ($self->{oneshot}) {
 898                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 899                         }
 900                 } else {
 901                         err($self, "W: unsupported --alert=$op"); # non-fatal
 902                 }
 903         }
 904 }
 905
 906 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 907 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 908
 909 # this also normalizes the path
 910 sub path_to_fd {
 911         my ($self, $path) = @_;
 912         $path = rel2abs($self, $path);
 913         $path =~ tr!/!/!s;
 914         $path_to_fd{$path} // (
 915                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 916                         fail($self, "cannot open $path from daemon") : -1
 917         );
 918 }
 919
 920 # caller needs to "-t $self->{1}" to check if tty
 921 sub start_pager {
 922         my ($self) = @_;
 923         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 924         chomp(my $pager = <$fh> // '');
 925         close($fh) or warn "`git var PAGER' error: \$?=$?";
 926         return if $pager eq 'cat' || $pager eq '';
 927         my $new_env = { LESS => 'FRX', LV => '-c' };
 928         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 929         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 930         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 931         my $pgr = [ undef, @$rdr{1, 2} ];
 932         my $env = $self->{env};
 933         if ($self->{sock}) { # lei(1) process runs it
 934                 delete @$new_env{keys %$env}; # only set iff unset
 935                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 936         } elsif ($self->{oneshot}) {
 937                 my $cmd = [$pager];
 938                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 939         } else {
 940                 die 'BUG: start_pager w/o socket';
 941         }
 942         $self->{1} = $wpager;
 943         $self->{2} = $wpager if -t $self->{2};
 944         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 945         $self->{pgr} = $pgr;
 946 }
 947
 948 sub stop_pager {
 949         my ($self) = @_;
 950         my $pgr = delete($self->{pgr}) or return;
 951         $self->{2} = $pgr->[2];
 952         # do not restore original stdout, just close it so we error out
 953         close(delete($self->{1})) if $self->{1};
 954 }
 955
 956 sub accept_dispatch { # Listener {post_accept} callback
 957         my ($sock) = @_; # ignore other
 958         $sock->autoflush(1);
 959         my $self = bless { sock => $sock }, __PACKAGE__;
 960         vec(my $rvec = '', fileno($sock), 1) = 1;
 961         select($rvec, undef, undef, 60) or
 962                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 963         # (4096 * 33) >MAX_ARG_STRLEN
 964         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
 965         if (!defined($fds[0])) {
 966                 warn(my $msg = "recv_cmd failed: $!");
 967                 return send($sock, $msg, MSG_EOR);
 968         } else {
 969                 my $i = 0;
 970                 for my $fd (@fds) {
 971                         open($self->{$i++}, '+<&=', $fd) and next;
 972                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 973                 }
 974                 return if scalar(@fds) != 4;
 975         }
 976         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 977         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 978         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 979         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 980                 return send($sock, 'request command truncated', MSG_EOR);
 981         my ($argc, @argv) = split(/\0/, $buf, -1);
 982         undef $buf;
 983         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 984         if (chdir($self->{3})) {
 985                 local %ENV = %env;
 986                 $self->{env} = \%env;
 987                 eval { dispatch($self, @argv) };
 988                 send($sock, $@, MSG_EOR) if $@;
 989         } else {
 990                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 991         }
 992 }
 993
 994 sub dclose {
 995         my ($self) = @_;
 996         delete $self->{-progress};
 997         _drop_wq($self);
 998         close(delete $self->{1}) if $self->{1}; # may reap_compress
 999         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1000 }
1001
1002 # for long-running results
1003 sub event_step {
1004         my ($self) = @_;
1005         local %ENV = %{$self->{env}};
1006         my $sock = $self->{sock};
1007         local $current_lei = $self;
1008         eval {
1009                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1010                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1011                                 return if $! == EAGAIN;
1012                                 next if $! == EINTR;
1013                                 last if $! == ECONNRESET;
1014                                 die "recvmsg: $!";
1015                         }
1016                         for my $fd (@fds) {
1017                                 open my $rfh, '+<&=', $fd;
1018                         }
1019                         die "unrecognized client signal: $buf";
1020                 }
1021                 dclose($self);
1022         };
1023         if (my $err = $@) {
1024                 eval { $self->fail($err) };
1025                 dclose($self);
1026         }
1027 }
1028
1029 sub event_step_init {
1030         my ($self) = @_;
1031         return if $self->{-event_init_done}++;
1032         if (my $sock = $self->{sock}) { # using DS->EventLoop
1033                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1034         }
1035 }
1036
1037 sub noop {}
1038
1039 sub oldset { $oldset }
1040
1041 sub dump_and_clear_log {
1042         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1043                 my @pfx = @_;
1044                 unshift(@pfx, "$errors_log ") if @pfx;
1045                 warn @pfx, do { local $/; <STDIN> };
1046                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1047         }
1048 }
1049
1050 # lei(1) calls this when it can't connect
1051 sub lazy_start {
1052         my ($path, $errno, $narg) = @_;
1053         local ($errors_log, $listener);
1054         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1055         $errors_log .= 'errors.log';
1056         my $addr = pack_sockaddr_un($path);
1057         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1058         $lk->lock_acquire;
1059         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1060         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1061                 return if connect($listener, $addr); # another process won
1062                 if ($errno == ECONNREFUSED && -S $path) {
1063                         unlink($path) or die "unlink($path): $!";
1064                 }
1065         } else {
1066                 $! = $errno; # allow interpolation to stringify in die
1067                 die "connect($path): $!";
1068         }
1069         umask(077) // die("umask(077): $!");
1070         bind($listener, $addr) or die "bind($path): $!";
1071         listen($listener, 1024) or die "listen: $!";
1072         $lk->lock_release;
1073         undef $lk;
1074         my @st = stat($path) or die "stat($path): $!";
1075         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1076         local $oldset = PublicInbox::DS::block_signals();
1077         if ($narg == 5) {
1078                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1079                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1080                         require PublicInbox::CmdIPC4;
1081                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1082                         PublicInbox::CmdIPC4->can('recv_cmd4');
1083                 };
1084         }
1085         $recv_cmd or die <<"";
1086 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1087
1088         require PublicInbox::Listener;
1089         require PublicInbox::EOFpipe;
1090         (-p STDOUT) or die "E: stdout must be a pipe\n";
1091         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1092         STDIN->autoflush(1);
1093         dump_and_clear_log("from previous daemon process:\n");
1094         POSIX::setsid() > 0 or die "setsid: $!";
1095         my $pid = fork // die "fork: $!";
1096         return if $pid;
1097         $0 = "lei-daemon $path";
1098         local %PATH2CFG;
1099         $listener->blocking(0);
1100         my $exit_code;
1101         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1102         local $quit = do {
1103                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1104                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1105                 sub {
1106                         $exit_code //= shift;
1107                         my $lis = $pil or exit($exit_code);
1108                         # closing eof_w triggers \&noop wakeup
1109                         $listener = $eof_w = $pil = $path = undef;
1110                         $lis->close; # DS::close
1111                         PublicInbox::DS->SetLoopTimeout(1000);
1112                 };
1113         };
1114         my $sig = {
1115                 CHLD => \&PublicInbox::DS::enqueue_reap,
1116                 QUIT => $quit,
1117                 INT => $quit,
1118                 TERM => $quit,
1119                 HUP => \&noop,
1120                 USR1 => \&noop,
1121                 USR2 => \&noop,
1122         };
1123         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1124         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1125         undef $sig;
1126         local $SIG{PIPE} = 'IGNORE';
1127         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1128                 undef $sigfd;
1129                 PublicInbox::DS->SetLoopTimeout(5000);
1130         } else {
1131                 # wake up every second to accept signals if we don't
1132                 # have signalfd or IO::KQueue:
1133                 PublicInbox::DS::sig_setmask($oldset);
1134                 PublicInbox::DS->SetLoopTimeout(1000);
1135         }
1136         PublicInbox::DS->SetPostLoopCallback(sub {
1137                 my ($dmap, undef) = @_;
1138                 if (@st = defined($path) ? stat($path) : ()) {
1139                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1140                                 warn "$path dev/ino changed, quitting\n";
1141                                 $path = undef;
1142                         }
1143                 } elsif (defined($path)) { # ENOENT is common
1144                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1145                         undef $path;
1146                         $quit->();
1147                 }
1148                 return 1 if defined($path);
1149                 my $now = now();
1150                 my $n = 0;
1151                 for my $s (values %$dmap) {
1152                         $s->can('busy') or next;
1153                         if ($s->busy($now)) {
1154                                 ++$n;
1155                         } else {
1156                                 $s->close;
1157                         }
1158                 }
1159                 $n; # true: continue, false: stop
1160         });
1161
1162         # STDIN was redirected to /dev/null above, closing STDERR and
1163         # STDOUT will cause the calling `lei' client process to finish
1164         # reading the <$daemon> pipe.
1165         local $SIG{__WARN__} = sub {
1166                 $current_lei ? err($current_lei, @_) : warn(
1167                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1168         };
1169         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1170         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1171         # $daemon pipe to `lei' closed, main loop begins:
1172         PublicInbox::DS->EventLoop;
1173         exit($exit_code // 0);
1174 }
1175
1176 sub busy { 1 } # prevent daemon-shutdown if client is connected
1177
1178 # for users w/o Socket::Msghdr installed or Inline::C enabled
1179 sub oneshot {
1180         my ($main_pkg) = @_;
1181         my $exit = $main_pkg->can('exit'); # caller may override exit()
1182         local $quit = $exit if $exit;
1183         local %PATH2CFG;
1184         umask(077) // die("umask(077): $!");
1185         my $self = bless {
1186                 oneshot => 1,
1187                 0 => *STDIN{GLOB},
1188                 1 => *STDOUT{GLOB},
1189                 2 => *STDERR{GLOB},
1190                 env => \%ENV
1191         }, __PACKAGE__;
1192         dispatch($self, @ARGV);
1193         x_it($self, $self->{child_error}) if $self->{child_error};
1194 }
1195
1196 # ensures stdout hits the FS before sock disconnects so a client
1197 # can immediately reread it
1198 sub DESTROY {
1199         my ($self) = @_;
1200         $self->{1}->autoflush(1) if $self->{1};
1201         stop_pager($self);
1202         my $err = $?;
1203         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1204         waitpid($_, 0) for keys %$oneshot_pids;
1205         $? = $err if $err; # preserve ->fail or ->x_it code
1206 }
1207
1208 1;