lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal);
  12 use Getopt::Long ();
  13 use Socket qw(AF_UNIX SOCK_STREAM pack_sockaddr_un);
  14 use Errno qw(EAGAIN ECONNREFUSED ENOENT);
  15 use POSIX ();
  16 use IO::Handle ();
  17 use Sys::Syslog qw(syslog openlog);
  18 use PublicInbox::Config;
  19 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLONESHOT);
  20 use PublicInbox::Sigfd;
  21 use PublicInbox::DS qw(now dwaitpid);
  22 use PublicInbox::Spawn qw(spawn run_die);
  23 use PublicInbox::OnDestroy;
  24 use Text::Wrap qw(wrap);
  25 use File::Path qw(mkpath);
  26 use File::Spec;
  27 our $quit = \&CORE::exit;
  28 my $recv_3fds;
  29 my $GLP = Getopt::Long::Parser->new;
  30 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  31 my $GLP_PASS = Getopt::Long::Parser->new;
  32 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  33
  34 our %PATH2CFG; # persistent for socket daemon
  35
  36 # TBD: this is a documentation mechanism to show a subcommand
  37 # (may) pass options through to another command:
  38 sub pass_through { $GLP_PASS }
  39
  40 my $OPT;
  41 sub opt_dash {
  42         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  43         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  44         my $cb = sub { # Getopt::Long "<>" catch-all handler
  45                 my ($arg) = @_;
  46                 if ($arg =~ /\A-($re_str)\z/) {
  47                         $OPT->{$key} = $1;
  48                 } else {
  49                         die "bad argument for --$key: $arg\n";
  50                 }
  51         };
  52         ($spec, '<>' => $cb, $GLP_PASS)
  53 }
  54
  55 sub _store_path ($) {
  56         my ($env) = @_;
  57         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  58                 ($env->{HOME} // '/nonexistent').'/.local/share')
  59                 .'/lei/store', $env->{PWD});
  60 }
  61
  62 sub _config_path ($) {
  63         my ($env) = @_;
  64         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  65                 ($env->{HOME} // '/nonexistent').'/.config')
  66                 .'/lei/config', $env->{PWD});
  67 }
  68
  69 # TODO: generate shell completion + help using %CMD and %OPTDESC
  70 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  71 our %CMD = ( # sorted in order of importance/use:
  72 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  73         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  74         sort|s=s@ reverse|r offset=i remote local! external!
  75         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  76
  77 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  78         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  79         pass_through('git show') ],
  80
  81 'add-external' => [ 'URL_OR_PATHNAME',
  82         'add/set priority of a publicinbox|extindex for extra matches',
  83         qw(boost=i quiet|q) ],
  84 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  85         qw(format|f=s z|0 local remote quiet|q) ],
  86 'forget-external' => [ '{URL_OR_PATHNAME|--prune}',
  87         'exclude further results from a publicinbox|extindex',
  88         qw(prune quiet|q) ],
  89
  90 'ls-query' => [ '[FILTER...]', 'list saved search queries',
  91                 qw(name-only format|f=s z) ],
  92 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
  93 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
  94
  95 'plonk' => [ '--thread|--from=IDENT',
  96         'exclude mail matching From: or thread from non-Message-ID searches',
  97         qw(stdin| thread|t from|f=s mid=s oid=s) ],
  98 'mark' => [ 'MESSAGE_FLAGS...',
  99         'set/unset flags on message(s) from stdin',
 100         qw(stdin| oid=s exact by-mid|mid:s) ],
 101 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 102         "exclude message(s) on stdin from `q' search results",
 103         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 104
 105 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 106         'remove imported messages from IMAP, Maildirs, and MH',
 107         qw(exact! all jobs:i indexed) ],
 108
 109 # code repos are used for `show' to solve blobs from patch mails
 110 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 111         qw(boost=i) ],
 112 'ls-coderepo' => [ '[FILTER_TERMS...]',
 113                 'list known code repos', qw(format|f=s z) ],
 114 'forget-coderepo' => [ 'PATHNAME',
 115         'stop using repo to solve blobs from patches',
 116         qw(prune) ],
 117
 118 'add-watch' => [ '[URL_OR_PATHNAME]',
 119                 'watch for new messages and flag changes',
 120         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 121 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 122                 qw(format|f=s z) ],
 123 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 124 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 125 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 126         qw(prune) ],
 127
 128 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 129         'one-shot import/update from URL or filesystem',
 130         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 131         ],
 132
 133 'config' => [ '[...]', sub {
 134                 'git-config(1) wrapper for '._config_path($_[0]);
 135         }, qw(config-file|system|global|file|f=s), # for conflict detection
 136         pass_through('git config') ],
 137 'init' => [ '[PATHNAME]', sub {
 138                 'initialize storage, default: '._store_path($_[0]);
 139         }, qw(quiet|q) ],
 140 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 141         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 142 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 143 'daemon-env' => [ '[NAME=VALUE...]', 'set, unset, or show daemon environment',
 144         qw(clear| unset|u=s@ z|0) ],
 145 'help' => [ '[SUBCOMMAND]', 'show help' ],
 146
 147 # XXX do we need this?
 148 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 149
 150 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 151         'rewrite git history in an attempt to improve compression',
 152         'gc!' ],
 153
 154 # internal commands are prefixed with '_'
 155 '_complete' => [ '[...]', 'internal shell completion helper',
 156                 pass_through('everything') ],
 157 ); # @CMD
 158
 159 # switch descriptions, try to keep consistent across commands
 160 # $spec: Getopt::Long option specification
 161 # $spec => [@ALLOWED_VALUES (default is first), $description],
 162 # $spec => $description
 163 # "$SUB_COMMAND TAB $spec" => as above
 164 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 165                 'specify message input format' ];
 166 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 167
 168 my %OPTDESC = (
 169 'help|h' => 'show this built-in help',
 170 'quiet|q' => 'be quiet',
 171 'solve!' => 'do not attempt to reconstruct blobs from emails',
 172 'save-as=s' => ['NAME', 'save a search terms by given name'],
 173
 174 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 175
 176 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 177                 'deduplication strategy'],
 178 'show   thread|t' => 'display entire thread a message belongs to',
 179 'q      thread|t' =>
 180         'return all messages in the same thread as the actual match(es)',
 181 'augment|a' => 'augment --output destination instead of clobbering',
 182
 183 'output|o=s' => [ 'DEST',
 184         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 185
 186 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 187                         'message/object output format' ],
 188 'mark   format|f=s' => $stdin_formats,
 189 'forget format|f=s' => $stdin_formats,
 190 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 191                 'specify output format, default depends on --output'],
 192 'ls-query       format|f=s' => $ls_format,
 193 'ls-external    format|f=s' => $ls_format,
 194
 195 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 196 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 197
 198 'sort|s=s@' => [ 'VAL|internaldate,date,relevance,docid',
 199                 "order of results `--output'-dependent"],
 200
 201 'boost=i' => 'increase/decrease priority of results (default: 0)',
 202
 203 'local' => 'limit operations to the local filesystem',
 204 'local!' => 'exclude results from the local filesystem',
 205 'remote' => 'limit operations to those requiring network access',
 206 'remote!' => 'prevent operations requiring network access',
 207
 208 'mid=s' => 'specify the Message-ID of a message',
 209 'oid=s' => 'specify the git object ID of a message',
 210
 211 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 212 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 213 'include=s' => 'include mailboxes/newsgroups based on pattern',
 214
 215 'exact' => 'operate on exact header matches only',
 216 'exact!' => 'rely on content match instead of exact header matches',
 217
 218 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 219 'jobs:i' => 'set parallelism level',
 220
 221 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 222 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 223
 224 # note: no "--ignore-environment" / "-i" support like env(1) since that
 225 # is one-shot and this is for a persistent daemon:
 226 'clear|' => 'clear the daemon environment',
 227 'unset|u=s@' => ['NAME',
 228         'unset matching NAME, may be specified multiple times'],
 229
 230 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 231 ); # %OPTDESC
 232
 233 my %CONFIG_KEYS = (
 234         'leistore.dir' => 'top-level storage location',
 235 );
 236
 237 sub x_it ($$) { # pronounced "exit"
 238         my ($self, $code) = @_;
 239         $self->{1}->autoflush(1); # make sure client sees stdout before exit
 240         if (my $sig = ($code & 127)) {
 241                 kill($sig, $self->{pid} // $$);
 242         } else {
 243                 $code >>= 8;
 244                 if (my $sock = $self->{sock}) {
 245                         say $sock "exit=$code";
 246                 } else { # for oneshot
 247                         $quit->($code);
 248                 }
 249         }
 250 }
 251
 252 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 253
 254 sub out ($;@) { print { shift->{1} } @_ }
 255
 256 sub err ($;@) {
 257         print { shift->{2} } @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 258 }
 259
 260 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 261
 262 sub fail ($$;$) {
 263         my ($self, $buf, $exit_code) = @_;
 264         err($self, $buf);
 265         x_it($self, ($exit_code // 1) << 8);
 266         undef;
 267 }
 268
 269 sub _help ($;$) {
 270         my ($self, $errmsg) = @_;
 271         my $cmd = $self->{cmd} // 'COMMAND';
 272         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 273         my @top = ($cmd, shift(@info) // ());
 274         my $cmd_desc = shift(@info);
 275         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 276         my @opt_desc;
 277         my $lpad = 2;
 278         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 279                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 280                 my $arg_vals = '';
 281                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 282
 283                 # lower-case is a keyword (e.g. `content', `oid'),
 284                 # ALL_CAPS is a string description (e.g. `PATH')
 285                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 286                         $desc .= "\ndefault: `$1'";
 287                 }
 288                 my (@vals, @s, @l);
 289                 my $x = $sw;
 290                 if ($x =~ s/!\z//) { # solve! => --no-solve
 291                         $x = "no-$x";
 292                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 293                         @vals = (' [', undef, ']');
 294                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 295                         @vals = (' ', undef);
 296                 } # else: no args $x = 'thread|t'
 297                 for (split(/\|/, $x)) { # help|h
 298                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 299                 }
 300                 if (!scalar(@vals)) { # no args 'thread|t'
 301                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 302                         $vals[1] = $1;
 303                 } else {
 304                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 305                 }
 306                 if ($arg_vals =~ /([,\|])/) {
 307                         my $sep = $1;
 308                         my @allow = split(/\Q$sep\E/, $arg_vals);
 309                         my $must = $sep eq '|' ? 'Must' : 'Can';
 310                         @allow = map { "`$_'" } @allow;
 311                         my $last = pop @allow;
 312                         $desc .= "\n$must be one of: " .
 313                                 join(', ', @allow) . " or $last";
 314                 }
 315                 my $lhs = join(', ', @s, @l) . join('', @vals);
 316                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 317                         $lhs =~ s/\A--/- , --/;
 318                 } else {
 319                         $lhs =~ s/\A--/    --/; # pad if no short options
 320                 }
 321                 $lpad = length($lhs) if length($lhs) > $lpad;
 322                 push @opt_desc, $lhs, $desc;
 323         }
 324         my $msg = $errmsg ? "E: $errmsg\n" : '';
 325         $msg .= <<EOF;
 326 usage: lei @top
 327   $cmd_desc
 328
 329 EOF
 330         $lpad += 2;
 331         local $Text::Wrap::columns = 78 - $lpad;
 332         my $padding = ' ' x ($lpad + 2);
 333         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 334                 $msg .= '  '.pack("A$lpad", $lhs);
 335                 $rhs = wrap('', '', $rhs);
 336                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 337                 $msg .= $rhs;
 338                 $msg .= "\n";
 339         }
 340         print { $self->{$errmsg ? 2 : 1} } $msg;
 341         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 342         undef;
 343 }
 344
 345 sub optparse ($$$) {
 346         my ($self, $cmd, $argv) = @_;
 347         $self->{cmd} = $cmd;
 348         $OPT = $self->{opt} = {};
 349         my $info = $CMD{$cmd} // [ '[...]' ];
 350         my ($proto, undef, @spec) = @$info;
 351         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 352         push @spec, qw(help|h);
 353         my $lone_dash;
 354         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 355                 $lone_dash = $spec[0];
 356                 $OPT->{$spec[0]} = \(my $var);
 357                 push @spec, '' => \$var;
 358         }
 359         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 360                 return _help($self, "bad arguments or options for $cmd");
 361         return _help($self) if $OPT->{help};
 362
 363         # "-" aliases "stdin" or "clear"
 364         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 365
 366         my $i = 0;
 367         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 368         my ($err, $inf);
 369         my @args = split(/ /, $proto);
 370         for my $var (@args) {
 371                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 372                         $inf = defined($argv->[$i]) and last;
 373                         $var =~ s/\.\.\.\z//;
 374                         $err = "$var not supplied";
 375                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 376                         $argv->[$i++] // ($err = "$var not supplied");
 377                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 378                         $inf = 1;
 379                         last;
 380                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 381                         $i++;
 382                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 383                         my @or = split(/\|/, $var);
 384                         my $ok;
 385                         for my $o (@or) {
 386                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 387                                         $ok = defined($OPT->{$1});
 388                                         last;
 389                                 } elsif (defined($argv->[$i])) {
 390                                         $ok = 1;
 391                                         $i++;
 392                                         last;
 393                                 } # else continue looping
 394                         }
 395                         my $last = pop @or;
 396                         $err = join(', ', @or) . " or $last must be set";
 397                 } else {
 398                         warn "BUG: can't parse `$var' in $proto";
 399                 }
 400                 last if $err;
 401         }
 402         if (!$inf && scalar(@$argv) > scalar(@args)) {
 403                 $err //= 'too many arguments';
 404         }
 405         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 406 }
 407
 408 sub dispatch {
 409         my ($self, $cmd, @argv) = @_;
 410         local $SIG{__WARN__} = sub { err($self, @_) };
 411         return _help($self, 'no command given') unless defined($cmd);
 412         my $func = "lei_$cmd";
 413         $func =~ tr/-/_/;
 414         if (my $cb = __PACKAGE__->can($func)) {
 415                 optparse($self, $cmd, \@argv) or return;
 416                 $cb->($self, @argv);
 417         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 418                 my $opt = {};
 419                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 420                         return _help($self, 'bad arguments or options');
 421                 _help($self);
 422         } else {
 423                 fail($self, "`$cmd' is not an lei command");
 424         }
 425 }
 426
 427 sub _lei_cfg ($;$) {
 428         my ($self, $creat) = @_;
 429         my $f = _config_path($self->{env});
 430         my @st = stat($f);
 431         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 432         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 433                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 434         }
 435         if (!@st) {
 436                 unless ($creat) {
 437                         delete $self->{cfg};
 438                         return;
 439                 }
 440                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 441                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 442                 open my $fh, '>>', $f or die "open($f): $!\n";
 443                 @st = stat($fh) or die "fstat($f): $!\n";
 444                 $cur_st = pack('dd', $st[10], $st[7]);
 445                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 446         }
 447         my $cfg = PublicInbox::Config::git_config_dump($f);
 448         $cfg->{-st} = $cur_st;
 449         $cfg->{'-f'} = $f;
 450         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 451 }
 452
 453 sub _lei_store ($;$) {
 454         my ($self, $creat) = @_;
 455         my $cfg = _lei_cfg($self, $creat);
 456         $cfg->{-lei_store} //= do {
 457                 require PublicInbox::LeiStore;
 458                 my $dir = $cfg->{'leistore.dir'};
 459                 $dir //= _store_path($self->{env}) if $creat;
 460                 return unless $dir;
 461                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 462         };
 463 }
 464
 465 sub lei_show {
 466         my ($self, @argv) = @_;
 467 }
 468
 469 sub lei_query {
 470         my ($self, @argv) = @_;
 471 }
 472
 473 sub lei_mark {
 474         my ($self, @argv) = @_;
 475 }
 476
 477 sub lei_config {
 478         my ($self, @argv) = @_;
 479         $self->{opt}->{'config-file'} and return fail $self,
 480                 "config file switches not supported by `lei config'";
 481         my $env = $self->{env};
 482         delete local $env->{GIT_CONFIG};
 483         my $cfg = _lei_cfg($self, 1);
 484         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 485         my %rdr = map { $_ => $self->{$_} } (0..2);
 486         run_die($cmd, $env, \%rdr);
 487 }
 488
 489 sub lei_init {
 490         my ($self, $dir) = @_;
 491         my $cfg = _lei_cfg($self, 1);
 492         my $cur = $cfg->{'leistore.dir'};
 493         my $env = $self->{env};
 494         $dir //= _store_path($env);
 495         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 496         my @cur = stat($cur) if defined($cur);
 497         $cur = File::Spec->canonpath($cur) if $cur;
 498         my @dir = stat($dir);
 499         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 500         if (@cur) {
 501                 if ($cur eq $dir) {
 502                         _lei_store($self, 1)->done;
 503                         return qerr($self, $exists);
 504                 }
 505
 506                 # some folks like symlinks and bind mounts :P
 507                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 508                         lei_config($self, 'leistore.dir', $dir);
 509                         _lei_store($self, 1)->done;
 510                         return qerr($self, "$exists (as $cur)");
 511                 }
 512                 return fail($self, <<"");
 513 E: leistore.dir=$cur already initialized and it is not $dir
 514
 515         }
 516         lei_config($self, 'leistore.dir', $dir);
 517         _lei_store($self, 1)->done;
 518         $exists //= "I: leistore.dir=$dir newly initialized";
 519         return qerr($self, $exists);
 520 }
 521
 522 sub lei_daemon_pid { puts shift, $$ }
 523
 524 sub lei_daemon_kill {
 525         my ($self) = @_;
 526         my $sig = $self->{opt}->{signal} // 'TERM';
 527         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 528 }
 529
 530 sub lei_daemon_env {
 531         my ($self, @argv) = @_;
 532         my $opt = $self->{opt};
 533         if (defined $opt->{clear}) {
 534                 %ENV = ();
 535         } elsif (my $u = $opt->{unset}) {
 536                 delete @ENV{@$u};
 537         }
 538         if (@argv) {
 539                 %ENV = (%ENV, map { split(/=/, $_, 2) } @argv);
 540         } elsif (!defined($opt->{clear}) && !$opt->{unset}) {
 541                 my $eor = $opt->{z} ? "\0" : "\n";
 542                 my $buf = '';
 543                 while (my ($k, $v) = each %ENV) { $buf .= "$k=$v$eor" }
 544                 out $self, $buf;
 545         }
 546 }
 547
 548 sub lei_help { _help($_[0]) }
 549
 550 # Shell completion helper.  Used by lei-completion.bash and hopefully
 551 # other shells.  Try to do as much here as possible to avoid redundancy
 552 # and improve maintainability.
 553 sub lei__complete {
 554         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 555         shift @argv; # ignore "lei", the entire command is sent
 556         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 557         my $cmd = shift @argv;
 558         my $info = $CMD{$cmd} // do { # filter matching commands
 559                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 560                 return;
 561         };
 562         my ($proto, undef, @spec) = @$info;
 563         my $cur = pop @argv;
 564         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 565         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 566                 # gross special case since the only git-config options
 567                 # Consider moving to a table if we need more special cases
 568                 # we use Getopt::Long for are the ones we reject, so these
 569                 # are the ones we don't reject:
 570                 if ($cmd eq 'config') {
 571                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 572                         @spec = qw(add z|null get get-all unset unset-all
 573                                 replace-all get-urlmatch
 574                                 remove-section rename-section
 575                                 name-only list|l edit|e
 576                                 get-color-name get-colorbool);
 577                         # fall-through
 578                 }
 579                 # TODO: arg support
 580                 puts $self, grep(/$re/, map { # generate short/long names
 581                         my $eq = '';
 582                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 583                                 $eq = '=';
 584                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 585                         } else { # negation: solve! => no-solve|solve
 586                                 s/\A(.+)!\z/no-$1|$1/;
 587                         }
 588                         map {
 589                                 length > 1 ? "--$_$eq" : "-$_"
 590                         } split(/\|/, $_, -1) # help|h
 591                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 592         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 593                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 594         }
 595         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 596         # proto parsing.
 597 }
 598
 599 sub reap_exec { # dwaitpid callback
 600         my ($self, $pid) = @_;
 601         x_it($self, $?);
 602 }
 603
 604 sub lei_git { # support passing through random git commands
 605         my ($self, @argv) = @_;
 606         my %rdr = map { $_ => $self->{$_} } (0..2);
 607         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 608         dwaitpid($pid, \&reap_exec, $self);
 609 }
 610
 611 sub accept_dispatch { # Listener {post_accept} callback
 612         my ($sock) = @_; # ignore other
 613         $sock->blocking(1);
 614         $sock->autoflush(1);
 615         my $self = bless { sock => $sock }, __PACKAGE__;
 616         vec(my $rin = '', fileno($sock), 1) = 1;
 617         # `say $sock' triggers "die" in lei(1)
 618         if (select(my $rout = $rin, undef, undef, 1)) {
 619                 my @fds = $recv_3fds->(fileno($sock));
 620                 if (scalar(@fds) == 3) {
 621                         my $i = 0;
 622                         for my $rdr (qw(<&= >&= >&=)) {
 623                                 my $fd = shift(@fds);
 624                                 if (open(my $fh, $rdr, $fd)) {
 625                                         $self->{$i++} = $fh;
 626                                 }  else {
 627                                         say $sock "open($rdr$fd) (FD=$i): $!";
 628                                         return;
 629                                 }
 630                         }
 631                 } else {
 632                         say $sock "recv_3fds failed: $!";
 633                         return;
 634                 }
 635         } else {
 636                 say $sock "timed out waiting to recv FDs";
 637                 return;
 638         }
 639         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 640         # $ARGV_STR = join("]\0[", @ARGV);
 641         # $ENV_STR = join('', map { "$_=$ENV{$_}\0" } keys %ENV);
 642         # $line = "$$\0\0>$ARGV_STR\0\0>$ENV_STR\0\0";
 643         my ($client_pid, $argv, $env) = do {
 644                 local $/ = "\0\0\0"; # yes, 3 NULs at EOL, not 2
 645                 chomp(my $line = <$sock>);
 646                 split(/\0\0>/, $line, 3);
 647         };
 648         my %env = map { split(/=/, $_, 2) } split(/\0/, $env);
 649         if (chdir($env{PWD})) {
 650                 $self->{env} = \%env;
 651                 $self->{pid} = $client_pid;
 652                 eval { dispatch($self, split(/\]\0\[/, $argv)) };
 653                 say $sock $@ if $@;
 654         } else {
 655                 say $sock "chdir($env{PWD}): $!"; # implicit close
 656         }
 657 }
 658
 659 sub noop {}
 660
 661 # lei(1) calls this when it can't connect
 662 sub lazy_start {
 663         my ($path, $errno, $nfd) = @_;
 664         if ($errno == ECONNREFUSED) {
 665                 unlink($path) or die "unlink($path): $!";
 666         } elsif ($errno != ENOENT) {
 667                 $! = $errno; # allow interpolation to stringify in die
 668                 die "connect($path): $!";
 669         }
 670         umask(077) // die("umask(077): $!");
 671         socket(my $l, AF_UNIX, SOCK_STREAM, 0) or die "socket: $!";
 672         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 673         listen($l, 1024) or die "listen: $!";
 674         my @st = stat($path) or die "stat($path): $!";
 675         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 676         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 677         my $oldset = PublicInbox::Sigfd::block_signals();
 678         if ($nfd == 1) {
 679                 require IO::FDPass;
 680                 $recv_3fds = sub { map { IO::FDPass::recv($_[0]) } (0..2) };
 681         } elsif ($nfd == 3) {
 682                 $recv_3fds = PublicInbox::Spawn->can('recv_3fds');
 683         }
 684         $recv_3fds or die
 685                 "IO::FDPass missing or Inline::C not installed/configured\n";
 686         require PublicInbox::Listener;
 687         require PublicInbox::EOFpipe;
 688         (-p STDOUT) or die "E: stdout must be a pipe\n";
 689         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 690         POSIX::setsid() > 0 or die "setsid: $!";
 691         my $pid = fork // die "fork: $!";
 692         return if $pid;
 693         $0 = "lei-daemon $path";
 694         local %PATH2CFG;
 695         $_->blocking(0) for ($l, $eof_r, $eof_w);
 696         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 697         my $exit_code;
 698         local $quit = sub {
 699                 $exit_code //= shift;
 700                 my $listener = $l or exit($exit_code);
 701                 unlink($path) if defined($path);
 702                 # closing eof_w triggers \&noop wakeup
 703                 $eof_w = $l = $path = undef;
 704                 $listener->close; # DS::close
 705                 PublicInbox::DS->SetLoopTimeout(1000);
 706         };
 707         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 708         my $sig = {
 709                 CHLD => \&PublicInbox::DS::enqueue_reap,
 710                 QUIT => $quit,
 711                 INT => $quit,
 712                 TERM => $quit,
 713                 HUP => \&noop,
 714                 USR1 => \&noop,
 715                 USR2 => \&noop,
 716         };
 717         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 718         local %SIG = (%SIG, %$sig) if !$sigfd;
 719         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 720                 PublicInbox::DS->SetLoopTimeout(5000);
 721         } else {
 722                 # wake up every second to accept signals if we don't
 723                 # have signalfd or IO::KQueue:
 724                 PublicInbox::Sigfd::sig_setmask($oldset);
 725                 PublicInbox::DS->SetLoopTimeout(1000);
 726         }
 727         PublicInbox::DS->SetPostLoopCallback(sub {
 728                 my ($dmap, undef) = @_;
 729                 if (@st = defined($path) ? stat($path) : ()) {
 730                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 731                                 warn "$path dev/ino changed, quitting\n";
 732                                 $path = undef;
 733                         }
 734                 } elsif (defined($path)) {
 735                         warn "stat($path): $!, quitting ...\n";
 736                         undef $path; # don't unlink
 737                         $quit->();
 738                 }
 739                 return 1 if defined($path);
 740                 my $now = now();
 741                 my $n = 0;
 742                 for my $s (values %$dmap) {
 743                         $s->can('busy') or next;
 744                         if ($s->busy($now)) {
 745                                 ++$n;
 746                         } else {
 747                                 $s->close;
 748                         }
 749                 }
 750                 $n; # true: continue, false: stop
 751         });
 752
 753         # STDIN was redirected to /dev/null above, closing STDERR and
 754         # STDOUT will cause the calling `lei' client process to finish
 755         # reading the <$daemon> pipe.
 756         openlog($path, 'pid', 'user');
 757         local $SIG{__WARN__} = sub { syslog('warning', "@_") };
 758         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 759                 syslog('crit', "$@") if $@;
 760         });
 761         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 762         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 763         # $daemon pipe to `lei' closed, main loop begins:
 764         PublicInbox::DS->EventLoop;
 765         @$on_destroy = (); # cancel on_destroy if we get here
 766         exit($exit_code // 0);
 767 }
 768
 769 # for users w/o IO::FDPass
 770 sub oneshot {
 771         my ($main_pkg) = @_;
 772         my $exit = $main_pkg->can('exit'); # caller may override exit()
 773         local $quit = $exit if $exit;
 774         local %PATH2CFG;
 775         umask(077) // die("umask(077): $!");
 776         dispatch((bless {
 777                 0 => *STDIN{IO},
 778                 1 => *STDOUT{IO},
 779                 2 => *STDERR{IO},
 780                 env => \%ENV
 781         }, __PACKAGE__), @ARGV);
 782 }
 783
 784 # ensures stdout hits the FS before sock disconnects so a client
 785 # can immediately reread it
 786 sub DESTROY { $_[0]->{1}->autoflush(1) }
 787
 788 1;