lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS);
  12 use Getopt::Long ();
  13 use Socket qw(AF_UNIX SOCK_STREAM pack_sockaddr_un);
  14 use Errno qw(EAGAIN ECONNREFUSED ENOENT);
  15 use POSIX ();
  16 use IO::Handle ();
  17 use Sys::Syslog qw(syslog openlog);
  18 use PublicInbox::Config;
  19 use PublicInbox::Syscall qw($SFD_NONBLOCK EPOLLIN EPOLLONESHOT);
  20 use PublicInbox::Sigfd;
  21 use PublicInbox::DS qw(now);
  22 use PublicInbox::Spawn qw(spawn);
  23 use PublicInbox::OnDestroy;
  24 use Text::Wrap qw(wrap);
  25 use File::Path qw(mkpath);
  26 use File::Spec;
  27 our $quit = \&CORE::exit;
  28 my $GLP = Getopt::Long::Parser->new;
  29 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  30 my $GLP_PASS = Getopt::Long::Parser->new;
  31 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  32
  33 our %PATH2CFG; # persistent for socket daemon
  34
  35 # TBD: this is a documentation mechanism to show a subcommand
  36 # (may) pass options through to another command:
  37 sub pass_through { $GLP_PASS }
  38
  39 sub _store_path ($) {
  40         my ($env) = @_;
  41         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  42                 ($env->{HOME} // '/nonexistent').'/.local/share')
  43                 .'/lei/store', $env->{PWD});
  44 }
  45
  46 sub _config_path ($) {
  47         my ($env) = @_;
  48         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  49                 ($env->{HOME} // '/nonexistent').'/.config')
  50                 .'/lei/config', $env->{PWD});
  51 }
  52
  53 # TODO: generate shell completion + help using %CMD and %OPTDESC
  54 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  55 our %CMD = ( # sorted in order of importance/use:
  56 'query' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  57         save-as=s output|o=s format|f=s dedupe|d=s thread|t augment|a
  58         limit|n=i sort|s=s@ reverse|r offset=i remote local! extinbox!
  59         since|after=s until|before=s) ],
  60
  61 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  62         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  63         pass_through('git show') ],
  64
  65 'add-extinbox' => [ 'URL_OR_PATHNAME',
  66         'add/set priority of a publicinbox|extindex for extra matches',
  67         qw(prio=i) ],
  68 'ls-extinbox' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  69         qw(format|f=s z local remote) ],
  70 'forget-extinbox' => [ '{URL_OR_PATHNAME|--prune}',
  71         'exclude further results from a publicinbox|extindex',
  72         qw(prune) ],
  73
  74 'ls-query' => [ '[FILTER...]', 'list saved search queries',
  75                 qw(name-only format|f=s z) ],
  76 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
  77 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
  78
  79 'plonk' => [ '--thread|--from=IDENT',
  80         'exclude mail matching From: or thread from non-Message-ID searches',
  81         qw(stdin| thread|t from|f=s mid=s oid=s) ],
  82 'mark' => [ 'MESSAGE_FLAGS...',
  83         'set/unset flags on message(s) from stdin',
  84         qw(stdin| oid=s exact by-mid|mid:s) ],
  85 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
  86         'exclude message(s) on stdin from query results',
  87         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
  88
  89 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
  90         'remove imported messages from IMAP, Maildirs, and MH',
  91         qw(exact! all jobs:i indexed) ],
  92
  93 # code repos are used for `show' to solve blobs from patch mails
  94 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
  95         qw(prio=i) ],
  96 'ls-coderepo' => [ '[FILTER_TERMS...]',
  97                 'list known code repos', qw(format|f=s z) ],
  98 'forget-coderepo' => [ 'PATHNAME',
  99         'stop using repo to solve blobs from patches',
 100         qw(prune) ],
 101
 102 'add-watch' => [ '[URL_OR_PATHNAME]',
 103                 'watch for new messages and flag changes',
 104         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 105 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 106                 qw(format|f=s z) ],
 107 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 108 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 109 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 110         qw(prune) ],
 111
 112 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 113         'one-shot import/update from URL or filesystem',
 114         qw(stdin| limit|n=i offset=i recursive|r exclude=s include=s !flags),
 115         ],
 116
 117 'config' => [ '[...]', sub {
 118                 'git-config(1) wrapper for '._config_path($_[0]);
 119         }, qw(config-file|system|global|file|f=s), # for conflict detection
 120         pass_through('git config') ],
 121 'init' => [ '[PATHNAME]', sub {
 122                 'initialize storage, default: '._store_path($_[0]);
 123         }, qw(quiet|q) ],
 124 'daemon-stop' => [ '', 'stop the lei-daemon' ],
 125 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 126 'daemon-env' => [ '[NAME=VALUE...]', 'set, unset, or show daemon environment',
 127         qw(clear| unset|u=s@ z|0) ],
 128 'help' => [ '[SUBCOMMAND]', 'show help' ],
 129
 130 # XXX do we need this?
 131 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 132
 133 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 134         'rewrite git history in an attempt to improve compression',
 135         'gc!' ]
 136 ); # @CMD
 137
 138 # switch descriptions, try to keep consistent across commands
 139 # $spec: Getopt::Long option specification
 140 # $spec => [@ALLOWED_VALUES (default is first), $description],
 141 # $spec => $description
 142 # "$SUB_COMMAND TAB $spec" => as above
 143 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 144                 'specify message input format' ];
 145 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 146
 147 my %OPTDESC = (
 148 'help|h' => 'show this built-in help',
 149 'quiet|q' => 'be quiet',
 150 'solve!' => 'do not attempt to reconstruct blobs from emails',
 151 'save-as=s' => ['NAME', 'save a search terms by given name'],
 152
 153 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 154
 155 'dedupe|d=s' => ['STRAT|content|oid|mid',
 156                 'deduplication strategy'],
 157 'show   thread|t' => 'display entire thread a message belongs to',
 158 'query  thread|t' =>
 159         'return all messages in the same thread as the actual match(es)',
 160 'augment|a' => 'augment --output destination instead of clobbering',
 161
 162 'output|o=s' => [ 'DEST',
 163         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 164
 165 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 166                         'message/object output format' ],
 167 'mark   format|f=s' => $stdin_formats,
 168 'forget format|f=s' => $stdin_formats,
 169 'query  format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid',
 170                 'specify output format, default depends on --output'],
 171 'ls-query       format|f=s' => $ls_format,
 172 'ls-extinbox    format|f=s' => $ls_format,
 173
 174 'limit|n=i' => ['NUM',
 175         'limit on number of matches (default: 10000)' ],
 176 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 177
 178 'sort|s=s@' => [ 'VAL|internaldate,date,relevance,docid',
 179                 "order of results `--output'-dependent"],
 180
 181 'prio=i' => 'priority of query source',
 182
 183 'local' => 'limit operations to the local filesystem',
 184 'local!' => 'exclude results from the local filesystem',
 185 'remote' => 'limit operations to those requiring network access',
 186 'remote!' => 'prevent operations requiring network access',
 187
 188 'mid=s' => 'specify the Message-ID of a message',
 189 'oid=s' => 'specify the git object ID of a message',
 190
 191 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 192 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 193 'include=s' => 'include mailboxes/newsgroups based on pattern',
 194
 195 'exact' => 'operate on exact header matches only',
 196 'exact!' => 'rely on content match instead of exact header matches',
 197
 198 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 199 'jobs:i' => 'set parallelism level',
 200
 201 # xargs, env, use "-0", git(1) uses "-z".  Should we support z|0 everywhere?
 202 'z' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 203 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 204
 205 # note: no "--ignore-environment" / "-i" support like env(1) since that
 206 # is one-shot and this is for a persistent daemon:
 207 'clear|' => 'clear the daemon environment',
 208 'unset|u=s@' => ['NAME',
 209         'unset matching NAME, may be specified multiple times'],
 210 ); # %OPTDESC
 211
 212 sub x_it ($$) { # pronounced "exit"
 213         my ($self, $code) = @_;
 214         if (my $sig = ($code & 127)) {
 215                 kill($sig, $self->{pid} // $$);
 216         } else {
 217                 $code >>= 8;
 218                 if (my $sock = $self->{sock}) {
 219                         say $sock "exit=$code";
 220                 } else { # for oneshot
 221                         $quit->($code);
 222                 }
 223         }
 224 }
 225
 226 sub emit {
 227         my ($self, $channel) = @_; # $buf = $_[2]
 228         print { $self->{$channel} } $_[2] or die "print FD[$channel]: $!";
 229 }
 230
 231 sub err {
 232         my ($self, $buf) = @_;
 233         $buf .= "\n" unless $buf =~ /\n\z/s;
 234         emit($self, 2, $buf);
 235 }
 236
 237 sub qerr { $_[0]->{opt}->{quiet} or err(@_) }
 238
 239 sub fail ($$;$) {
 240         my ($self, $buf, $exit_code) = @_;
 241         err($self, $buf);
 242         x_it($self, ($exit_code // 1) << 8);
 243         undef;
 244 }
 245
 246 sub _help ($;$) {
 247         my ($self, $errmsg) = @_;
 248         my $cmd = $self->{cmd} // 'COMMAND';
 249         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 250         my @top = ($cmd, shift(@info) // ());
 251         my $cmd_desc = shift(@info);
 252         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 253         my @opt_desc;
 254         my $lpad = 2;
 255         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 256                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 257                 my $arg_vals = '';
 258                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 259
 260                 # lower-case is a keyword (e.g. `content', `oid'),
 261                 # ALL_CAPS is a string description (e.g. `PATH')
 262                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 263                         $desc .= "\ndefault: `$1'";
 264                 }
 265                 my (@vals, @s, @l);
 266                 my $x = $sw;
 267                 if ($x =~ s/!\z//) { # solve! => --no-solve
 268                         $x = "no-$x";
 269                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 270                         @vals = (' [', undef, ']');
 271                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 272                         @vals = (' ', undef);
 273                 } # else: no args $x = 'thread|t'
 274                 for (split(/\|/, $x)) { # help|h
 275                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 276                 }
 277                 if (!scalar(@vals)) { # no args 'thread|t'
 278                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 279                         $vals[1] = $1;
 280                 } else {
 281                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 282                 }
 283                 if ($arg_vals =~ /([,\|])/) {
 284                         my $sep = $1;
 285                         my @allow = split(/\Q$sep\E/, $arg_vals);
 286                         my $must = $sep eq '|' ? 'Must' : 'Can';
 287                         @allow = map { "`$_'" } @allow;
 288                         my $last = pop @allow;
 289                         $desc .= "\n$must be one of: " .
 290                                 join(', ', @allow) . " or $last";
 291                 }
 292                 my $lhs = join(', ', @s, @l) . join('', @vals);
 293                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 294                         $lhs =~ s/\A--/- , --/;
 295                 } else {
 296                         $lhs =~ s/\A--/    --/; # pad if no short options
 297                 }
 298                 $lpad = length($lhs) if length($lhs) > $lpad;
 299                 push @opt_desc, $lhs, $desc;
 300         }
 301         my $msg = $errmsg ? "E: $errmsg\n" : '';
 302         $msg .= <<EOF;
 303 usage: lei @top
 304   $cmd_desc
 305
 306 EOF
 307         $lpad += 2;
 308         local $Text::Wrap::columns = 78 - $lpad;
 309         my $padding = ' ' x ($lpad + 2);
 310         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 311                 $msg .= '  '.pack("A$lpad", $lhs);
 312                 $rhs = wrap('', '', $rhs);
 313                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 314                 $msg .= $rhs;
 315                 $msg .= "\n";
 316         }
 317         my $channel = $errmsg ? 2 : 1;
 318         emit($self, $channel, $msg);
 319         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 320         undef;
 321 }
 322
 323 sub optparse ($$$) {
 324         my ($self, $cmd, $argv) = @_;
 325         $self->{cmd} = $cmd;
 326         my $opt = $self->{opt} = {};
 327         my $info = $CMD{$cmd} // [ '[...]' ];
 328         my ($proto, undef, @spec) = @$info;
 329         my $glp = ref($spec[-1]) ? pop(@spec) : $GLP; # or $GLP_PASS
 330         push @spec, qw(help|h);
 331         my $lone_dash;
 332         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 333                 $lone_dash = $spec[0];
 334                 $opt->{$spec[0]} = \(my $var);
 335                 push @spec, '' => \$var;
 336         }
 337         $glp->getoptionsfromarray($argv, $opt, @spec) or
 338                 return _help($self, "bad arguments or options for $cmd");
 339         return _help($self) if $opt->{help};
 340
 341         # "-" aliases "stdin" or "clear"
 342         $opt->{$lone_dash} = ${$opt->{$lone_dash}} if defined $lone_dash;
 343
 344         my $i = 0;
 345         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 346         my ($err, $inf);
 347         my @args = split(/ /, $proto);
 348         for my $var (@args) {
 349                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 350                         $inf = defined($argv->[$i]) and last;
 351                         $var =~ s/\.\.\.\z//;
 352                         $err = "$var not supplied";
 353                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 354                         $argv->[$i++] // ($err = "$var not supplied");
 355                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 356                         $inf = 1;
 357                         last;
 358                 } elsif ($var =~ /\A\[$POS_ARG\]\z/) { # one optional arg
 359                         $i++;
 360                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 361                         my @or = split(/\|/, $var);
 362                         my $ok;
 363                         for my $o (@or) {
 364                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 365                                         $ok = defined($opt->{$1});
 366                                         last;
 367                                 } elsif (defined($argv->[$i])) {
 368                                         $ok = 1;
 369                                         $i++;
 370                                         last;
 371                                 } # else continue looping
 372                         }
 373                         my $last = pop @or;
 374                         $err = join(', ', @or) . " or $last must be set";
 375                 } else {
 376                         warn "BUG: can't parse `$var' in $proto";
 377                 }
 378                 last if $err;
 379         }
 380         # warn "inf=$inf ".scalar(@$argv). ' '.scalar(@args)."\n";
 381         if (!$inf && scalar(@$argv) > scalar(@args)) {
 382                 $err //= 'too many arguments';
 383         }
 384         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 385 }
 386
 387 sub dispatch {
 388         my ($self, $cmd, @argv) = @_;
 389         local $SIG{__WARN__} = sub { err($self, "@_") };
 390         return _help($self, 'no command given') unless defined($cmd);
 391         my $func = "lei_$cmd";
 392         $func =~ tr/-/_/;
 393         if (my $cb = __PACKAGE__->can($func)) {
 394                 optparse($self, $cmd, \@argv) or return;
 395                 $cb->($self, @argv);
 396         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 397                 my $opt = {};
 398                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 399                         return _help($self, 'bad arguments or options');
 400                 _help($self);
 401         } else {
 402                 fail($self, "`$cmd' is not an lei command");
 403         }
 404 }
 405
 406 sub _lei_cfg ($;$) {
 407         my ($self, $creat) = @_;
 408         my $f = _config_path($self->{env});
 409         my @st = stat($f);
 410         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 411         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 412                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 413         }
 414         if (!@st) {
 415                 unless ($creat) {
 416                         delete $self->{cfg};
 417                         return;
 418                 }
 419                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 420                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 421                 open my $fh, '>>', $f or die "open($f): $!\n";
 422                 @st = stat($fh) or die "fstat($f): $!\n";
 423                 $cur_st = pack('dd', $st[10], $st[7]);
 424                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 425         }
 426         my $cfg = PublicInbox::Config::git_config_dump($f);
 427         $cfg->{-st} = $cur_st;
 428         $cfg->{'-f'} = $f;
 429         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 430 }
 431
 432 sub _lei_store ($;$) {
 433         my ($self, $creat) = @_;
 434         my $cfg = _lei_cfg($self, $creat);
 435         $cfg->{-lei_store} //= do {
 436                 require PublicInbox::LeiStore;
 437                 PublicInbox::SearchIdx::load_xapian_writable();
 438                 defined(my $dir = $cfg->{'leistore.dir'}) or return;
 439                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 440         };
 441 }
 442
 443 sub lei_show {
 444         my ($self, @argv) = @_;
 445 }
 446
 447 sub lei_query {
 448         my ($self, @argv) = @_;
 449 }
 450
 451 sub lei_mark {
 452         my ($self, @argv) = @_;
 453 }
 454
 455 sub lei_config {
 456         my ($self, @argv) = @_;
 457         $self->{opt}->{'config-file'} and return fail $self,
 458                 "config file switches not supported by `lei config'";
 459         my $env = $self->{env};
 460         delete local $env->{GIT_CONFIG};
 461         my $cfg = _lei_cfg($self, 1);
 462         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 463         my %rdr = map { $_ => $self->{$_} } (0..2);
 464         require PublicInbox::Import;
 465         PublicInbox::Import::run_die($cmd, $env, \%rdr);
 466 }
 467
 468 sub lei_init {
 469         my ($self, $dir) = @_;
 470         my $cfg = _lei_cfg($self, 1);
 471         my $cur = $cfg->{'leistore.dir'};
 472         my $env = $self->{env};
 473         $dir //= _store_path($env);
 474         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 475         my @cur = stat($cur) if defined($cur);
 476         $cur = File::Spec->canonpath($cur) if $cur;
 477         my @dir = stat($dir);
 478         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 479         if (@cur) {
 480                 if ($cur eq $dir) {
 481                         _lei_store($self, 1)->done;
 482                         return qerr($self, $exists);
 483                 }
 484
 485                 # some folks like symlinks and bind mounts :P
 486                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 487                         lei_config($self, 'leistore.dir', $dir);
 488                         _lei_store($self, 1)->done;
 489                         return qerr($self, "$exists (as $cur)");
 490                 }
 491                 return fail($self, <<"");
 492 E: leistore.dir=$cur already initialized and it is not $dir
 493
 494         }
 495         lei_config($self, 'leistore.dir', $dir);
 496         _lei_store($self, 1)->done;
 497         $exists //= "I: leistore.dir=$dir newly initialized";
 498         return qerr($self, $exists);
 499 }
 500
 501 sub lei_daemon_pid { emit($_[0], 1, "$$\n") }
 502
 503 sub lei_daemon_stop { $quit->(0) }
 504
 505 sub lei_daemon_env {
 506         my ($self, @argv) = @_;
 507         my $opt = $self->{opt};
 508         if (defined $opt->{clear}) {
 509                 %ENV = ();
 510         } elsif (my $u = $opt->{unset}) {
 511                 delete @ENV{@$u};
 512         }
 513         if (@argv) {
 514                 %ENV = (%ENV, map { split(/=/, $_, 2) } @argv);
 515         } elsif (!defined($opt->{clear}) && !$opt->{unset}) {
 516                 my $eor = $opt->{z} ? "\0" : "\n";
 517                 my $buf = '';
 518                 while (my ($k, $v) = each %ENV) { $buf .= "$k=$v$eor" }
 519                 emit($self, 1, $buf)
 520         }
 521 }
 522
 523 sub lei_help { _help($_[0]) }
 524
 525 sub reap_exec { # dwaitpid callback
 526         my ($self, $pid) = @_;
 527         x_it($self, $?);
 528 }
 529
 530 sub lei_git { # support passing through random git commands
 531         my ($self, @argv) = @_;
 532         my %rdr = map { $_ => $self->{$_} } (0..2);
 533         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 534         PublicInbox::DS::dwaitpid($pid, \&reap_exec, $self);
 535 }
 536
 537 sub accept_dispatch { # Listener {post_accept} callback
 538         my ($sock) = @_; # ignore other
 539         $sock->blocking(1);
 540         $sock->autoflush(1);
 541         my $self = bless { sock => $sock }, __PACKAGE__;
 542         vec(my $rin = '', fileno($sock), 1) = 1;
 543         # `say $sock' triggers "die" in lei(1)
 544         for my $i (0..2) {
 545                 if (select(my $rout = $rin, undef, undef, 1)) {
 546                         my $fd = IO::FDPass::recv(fileno($sock));
 547                         if ($fd >= 0) {
 548                                 my $rdr = ($fd == 0 ? '<&=' : '>&=');
 549                                 if (open(my $fh, $rdr, $fd)) {
 550                                         $self->{$i} = $fh;
 551                                 } else {
 552                                         say $sock "open($rdr$fd) (FD=$i): $!";
 553                                         return;
 554                                 }
 555                         } else {
 556                                 say $sock "recv FD=$i: $!";
 557                                 return;
 558                         }
 559                 } else {
 560                         say $sock "timed out waiting to recv FD=$i";
 561                         return;
 562                 }
 563         }
 564         # $ARGV_STR = join("]\0[", @ARGV);
 565         # $ENV_STR = join('', map { "$_=$ENV{$_}\0" } keys %ENV);
 566         # $line = "$$\0\0>$ARGV_STR\0\0>$ENV_STR\0\0";
 567         my ($client_pid, $argv, $env) = do {
 568                 local $/ = "\0\0\0"; # yes, 3 NULs at EOL, not 2
 569                 chomp(my $line = <$sock>);
 570                 split(/\0\0>/, $line, 3);
 571         };
 572         my %env = map { split(/=/, $_, 2) } split(/\0/, $env);
 573         if (chdir($env{PWD})) {
 574                 $self->{env} = \%env;
 575                 $self->{pid} = $client_pid;
 576                 eval { dispatch($self, split(/\]\0\[/, $argv)) };
 577                 say $sock $@ if $@;
 578         } else {
 579                 say $sock "chdir($env{PWD}): $!"; # implicit close
 580         }
 581 }
 582
 583 sub noop {}
 584
 585 # lei(1) calls this when it can't connect
 586 sub lazy_start {
 587         my ($path, $errno) = @_;
 588         if ($errno == ECONNREFUSED) {
 589                 unlink($path) or die "unlink($path): $!";
 590         } elsif ($errno != ENOENT) {
 591                 $! = $errno; # allow interpolation to stringify in die
 592                 die "connect($path): $!";
 593         }
 594         umask(077) // die("umask(077): $!");
 595         socket(my $l, AF_UNIX, SOCK_STREAM, 0) or die "socket: $!";
 596         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 597         listen($l, 1024) or die "listen: $!";
 598         my @st = stat($path) or die "stat($path): $!";
 599         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 600         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 601         my $oldset = PublicInbox::Sigfd::block_signals();
 602         require IO::FDPass;
 603         require PublicInbox::Listener;
 604         require PublicInbox::EOFpipe;
 605         (-p STDOUT && -p STDERR) or die "E: stdout+stderr must be pipes\n";
 606         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 607         POSIX::setsid() > 0 or die "setsid: $!";
 608         my $pid = fork // die "fork: $!";
 609         return if $pid;
 610         $0 = "lei-daemon $path";
 611         local %PATH2CFG;
 612         $_->blocking(0) for ($l, $eof_r, $eof_w);
 613         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 614         my $exit_code;
 615         local $quit = sub {
 616                 $exit_code //= shift;
 617                 my $listener = $l or exit($exit_code);
 618                 unlink($path) if defined($path);
 619                 # closing eof_w triggers \&noop wakeup
 620                 $eof_w = $l = $path = undef;
 621                 $listener->close; # DS::close
 622                 PublicInbox::DS->SetLoopTimeout(1000);
 623         };
 624         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 625         my $sig = {
 626                 CHLD => \&PublicInbox::DS::enqueue_reap,
 627                 QUIT => $quit,
 628                 INT => $quit,
 629                 TERM => $quit,
 630                 HUP => \&noop,
 631                 USR1 => \&noop,
 632                 USR2 => \&noop,
 633         };
 634         my $sigfd = PublicInbox::Sigfd->new($sig, $SFD_NONBLOCK);
 635         local %SIG = (%SIG, %$sig) if !$sigfd;
 636         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 637                 PublicInbox::DS->SetLoopTimeout(5000);
 638         } else {
 639                 # wake up every second to accept signals if we don't
 640                 # have signalfd or IO::KQueue:
 641                 PublicInbox::Sigfd::sig_setmask($oldset);
 642                 PublicInbox::DS->SetLoopTimeout(1000);
 643         }
 644         PublicInbox::DS->SetPostLoopCallback(sub {
 645                 my ($dmap, undef) = @_;
 646                 if (@st = defined($path) ? stat($path) : ()) {
 647                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 648                                 warn "$path dev/ino changed, quitting\n";
 649                                 $path = undef;
 650                         }
 651                 } elsif (defined($path)) {
 652                         warn "stat($path): $!, quitting ...\n";
 653                         undef $path; # don't unlink
 654                         $quit->();
 655                 }
 656                 return 1 if defined($path);
 657                 my $now = now();
 658                 my $n = 0;
 659                 for my $s (values %$dmap) {
 660                         $s->can('busy') or next;
 661                         if ($s->busy($now)) {
 662                                 ++$n;
 663                         } else {
 664                                 $s->close;
 665                         }
 666                 }
 667                 $n; # true: continue, false: stop
 668         });
 669
 670         # STDIN was redirected to /dev/null above, closing STDOUT and
 671         # STDERR will cause the calling `lei' client process to finish
 672         # reading <$daemon> pipe.
 673         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 674         openlog($path, 'pid', 'user');
 675         local $SIG{__WARN__} = sub { syslog('warning', "@_") };
 676         my $owner_pid = $$;
 677         my $on_destroy = PublicInbox::OnDestroy->new(sub {
 678                 syslog('crit', "$@") if $@ && $$ == $owner_pid;
 679         });
 680         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 681         # $daemon pipe to `lei' closed, main loop begins:
 682         PublicInbox::DS->EventLoop;
 683         @$on_destroy = (); # cancel on_destroy if we get here
 684         exit($exit_code // 0);
 685 }
 686
 687 # for users w/o IO::FDPass
 688 sub oneshot {
 689         my ($main_pkg) = @_;
 690         my $exit = $main_pkg->can('exit'); # caller may override exit()
 691         local $quit = $exit if $exit;
 692         local %PATH2CFG;
 693         umask(077) // die("umask(077): $!");
 694         dispatch((bless {
 695                 0 => *STDIN{IO},
 696                 1 => *STDOUT{IO},
 697                 2 => *STDERR{IO},
 698                 env => \%ENV
 699         }, __PACKAGE__), @ARGV);
 700 }
 701
 702 1;