lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 return $p;
  74         }
  75         my $pwd = $self->{env}->{PWD};
  76         my $cwd;
  77         if (defined $pwd) {
  78                 my $xcwd = $self->{3} //
  79                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  80                 if (my @st_pwd = stat($pwd)) {
  81                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  82                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  83                                 $self->{env}->{PWD} = $pwd = undef;
  84                 } else { # PWD was invalid
  85                         $self->{env}->{PWD} = $pwd = undef;
  86                 }
  87         }
  88         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  89         File::Spec->rel2abs($p, $pwd);
  90 }
  91
  92 # abs_path resolves symlinks in parent iff all parents exist
  93 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  94
  95 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  96         my ($self) = @_;
  97         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  98                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
  99                 .'/lei');
 100 }
 101
 102 sub store_path ($) { share_path($_[0]) . '/store' }
 103
 104 sub _config_path ($) {
 105         my ($self) = @_;
 106         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 107                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 108                 .'/lei/config');
 109 }
 110
 111 sub cache_dir ($) {
 112         my ($self) = @_;
 113         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 114                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 115                 .'/lei');
 116 }
 117
 118 sub ale {
 119         my ($self) = @_;
 120         $self->{ale} //= do {
 121                 require PublicInbox::LeiALE;
 122                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 123         };
 124 }
 125
 126 sub index_opt {
 127         # TODO: drop underscore variants everywhere, they're undocumented
 128         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 129         max_size|max-size=s sequential_shard|sequential-shard
 130         batch_size|batch-size=s skip-docdata)
 131 }
 132
 133 my @c_opt = qw(c=s@ C=s@ quiet|q);
 134 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 135         import-remote! no-torsocks torsocks=s),
 136         PublicInbox::LeiQuery::curl_opt());
 137
 138 # we generate shell completion + help using %CMD and %OPTDESC,
 139 # see lei__complete() and PublicInbox::LeiHelp
 140 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 141 our %CMD = ( # sorted in order of importance/use:
 142 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 143         'stdin|', # /|\z/ must be first for lone dash
 144         @lxs_opt,
 145         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 146         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 147         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 148         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 149
 150 'up' => [ 'OUTPUT|--all', 'update saved search',
 151         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 152
 153 'lcat' => [ '--stdin|MSGID_OR_URL..', 'display local copy of message(s)',
 154         'stdin|', # /|\z/ must be first for lone dash
 155         # some of these options are ridiculous for lcat
 156         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 157         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 158         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 159         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 160
 161 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 162         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 163         @lxs_opt, @c_opt ],
 164
 165 'add-external' => [ 'LOCATION',
 166         'add/set priority of a publicinbox|extindex for extra matches',
 167         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 168         verbose|v+), @c_opt, index_opt(),
 169         PublicInbox::LeiQuery::curl_opt() ],
 170 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 171         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 172 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 173 'ls-sync' => [ '', 'list sync folders',
 174                 qw(z|0 z|0 globoff|g invert-match|v local remote), @c_opt ],
 175 'forget-external' => [ 'LOCATION...|--prune',
 176         'exclude further results from a publicinbox|extindex',
 177         qw(prune), @c_opt ],
 178
 179 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 180                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 181 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 182                 qw(verbose|v+), @c_opt ],
 183 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 184                         @c_opt ],
 185
 186 'plonk' => [ '--threads|--from=IDENT',
 187         'exclude mail matching From: or threads from non-Message-ID searches',
 188         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 189 'tag' => [ 'KEYWORDS...',
 190         'set/unset keywords and/or labels on message(s)',
 191         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@), @c_opt,
 192         pass_through('-kw:foo for delete') ],
 193 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 194         "exclude message(s) on stdin from `q' search results",
 195         qw(stdin| oid=s exact by-mid|mid:s), @c_opt ],
 196
 197 'purge-mailsource' => [ 'LOCATION|--all',
 198         'remove imported messages from IMAP, Maildirs, and MH',
 199         qw(exact! all jobs:i indexed), @c_opt ],
 200
 201 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 202         qw(import! kw! interval=s recursive|r
 203         exclude=s include=s), @c_opt ],
 204 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 205                 qw(format|f=s z), @c_opt ],
 206 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 207 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 208 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 209         qw(prune), @c_opt ],
 210
 211 'import' => [ 'LOCATION...|--stdin',
 212         'one-time import/update from URL or filesystem',
 213         qw(stdin| offset=i recursive|r exclude=s include|I=s
 214         lock=s@ in-format|F=s kw! verbose|v+ incremental! sync!), @c_opt ],
 215 'convert' => [ 'LOCATION...|--stdin',
 216         'one-time conversion from URL or filesystem to another format',
 217         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s
 218         lock=s@ kw!), @c_opt ],
 219 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 220         "use a patch to generate a query for `lei q --stdin'",
 221         qw(stdin| want|w=s@ uri debug), @c_opt ],
 222 'config' => [ '[...]', sub {
 223                 'git-config(1) wrapper for '._config_path($_[0]);
 224         }, qw(config-file|system|global|file|f=s), # for conflict detection
 225          qw(c=s@ C=s@), pass_through('git config') ],
 226 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 227         qw(pretty ascii dir=s), @c_opt ],
 228
 229 'init' => [ '[DIRNAME]', sub {
 230         "initialize storage, default: ".store_path($_[0]);
 231         }, @c_opt ],
 232 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 233         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 234         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 235 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 236 'help' => [ '[SUBCOMMAND]', 'show help' ],
 237
 238 # XXX do we need this?
 239 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 240
 241 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 242         'rewrite git history in an attempt to improve compression',
 243         qw(gc!), @c_opt ],
 244
 245 # internal commands are prefixed with '_'
 246 '_complete' => [ '[...]', 'internal shell completion helper',
 247                 pass_through('everything') ],
 248 ); # @CMD
 249
 250 # switch descriptions, try to keep consistent across commands
 251 # $spec: Getopt::Long option specification
 252 # $spec => [@ALLOWED_VALUES (default is first), $description],
 253 # $spec => $description
 254 # "$SUB_COMMAND TAB $spec" => as above
 255 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 256                         'specify message input format' ];
 257 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 258
 259 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 260 my %OPTDESC = (
 261 'help|h' => 'show this built-in help',
 262 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 263 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 264 'quiet|q' => 'be quiet',
 265 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 266         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 267
 268 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 269 'globoff|g' => "do not match locations using '*?' wildcards ".
 270                 "and\xa0'[]'\x{a0}ranges",
 271 'color!' => 'disable color (for --format=text)',
 272 'verbose|v+' => 'be more verbose',
 273 'external!' => 'do not use externals',
 274 'mail!' => 'do not look in mail storage for OID',
 275 'cwd!' => 'do not look in git repo of current working directory',
 276 'oid-a|A=s' => 'pre-image OID',
 277 'path-a|a=s' => 'pre-image pathname associated with OID',
 278 'path-b|b=s' => 'post-image pathname associated with OID',
 279 'git-dir=s@' => 'additional git repository to scan',
 280 'torsocks=s' => ['VAL|auto|no|yes',
 281                 'whether or not to wrap git and curl commands with torsocks'],
 282 'no-torsocks' => 'alias for --torsocks=no',
 283 'save' =>  "save a search for `lei up'",
 284 'import-remote!' => 'do not memoize remote messages into local store',
 285
 286 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 287
 288 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 289                 'deduplication strategy'],
 290 'threads|t+' =>
 291         'return all messages in the same threads as the actual match(es)',
 292
 293 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 294                 'search prefixes to extract (default: dfpost7)' ],
 295
 296 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 297         'run command(s) or perform ops when done writing to output ' .
 298         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 299         'nothing otherwise)' ],
 300
 301 'augment|a' => 'augment --output destination instead of clobbering',
 302
 303 'output|mfolder|o=s' => [ 'MFOLDER',
 304         "destination (e.g.\xa0`/path/to/Maildir', ".
 305         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 306 'mua=s' => [ 'CMD',
 307         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 308
 309 'inbox-version=i' => [ 'NUM|1|2',
 310                 'force a public-inbox version with --mirror'],
 311 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 312
 313 # public-inbox-index options
 314 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 315 'compact' => 'run compact index after mirroring',
 316 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 317         "indexlevel with --mirror (default: full)" ],
 318 'max_size|max-size=s' => [ 'SIZE',
 319         'do not index messages larger than SIZE (default: infinity)' ],
 320 'batch_size|batch-size=s' => [ 'SIZE',
 321         'flush changes to OS after given number of bytes (default: 1m)' ],
 322 'sequential_shard|sequential-shard' =>
 323         'index Xapian shards sequentially for slow storage',
 324 'skip-docdata' =>
 325         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 326
 327 'format|f=s     q' => [
 328         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 329                 'specify output format, default depends on --output'],
 330 'exclude=s@     q' => [ 'LOCATION',
 331                 'exclude specified external(s) from search' ],
 332 'include|I=s@   q' => [ 'LOCATION',
 333                 'include specified external(s) in search' ],
 334 'only=s@        q' => [ 'LOCATION',
 335                 'only use specified external(s) for search' ],
 336 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 337                 'control number of search and writer jobs' ],
 338 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 339
 340 'in-format|F=s' => $stdin_formats,
 341 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 342                         'listing output format' ],
 343 'l      ls-search' => 'long listing format',
 344 'format|f=s     ls-external' => $ls_format,
 345
 346 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 347 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 348
 349 'sort|s=s' => [ 'VAL|received|relevance|docid',
 350                 "order of results is `--output'-dependent"],
 351 'reverse|r' => 'reverse search results', # like sort(1)
 352
 353 'boost=i' => 'increase/decrease priority of results (default: 0)',
 354
 355 'local' => 'limit operations to the local filesystem',
 356 'local!' => 'exclude results from the local filesystem',
 357 'remote' => 'limit operations to those requiring network access',
 358 'remote!' => 'prevent operations requiring network access',
 359
 360 'all:s  up' => ['local', 'update all (local) saved searches' ],
 361
 362 'mid=s' => 'specify the Message-ID of a message',
 363 'oid=s' => 'specify the git object ID of a message',
 364
 365 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 366 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 367 'include=s' => 'include mailboxes/newsgroups based on pattern',
 368
 369 'exact' => 'operate on exact header matches only',
 370 'exact!' => 'rely on content match instead of exact header matches',
 371
 372 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 373
 374 'kw!' => 'disable/enable importing keywords (aka "flags")',
 375
 376 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 377 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 378
 379 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 380 ); # %OPTDESC
 381
 382 my %CONFIG_KEYS = (
 383         'leistore.dir' => 'top-level storage location',
 384 );
 385
 386 my @WQ_KEYS = qw(lxs l2m wq1); # internal workers
 387
 388 sub _drop_wq {
 389         my ($self) = @_;
 390         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) { $wq->DESTROY }
 391 }
 392
 393 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 394 sub x_it ($$) {
 395         my ($self, $code) = @_;
 396         # make sure client sees stdout before exit
 397         $self->{1}->autoflush(1) if $self->{1};
 398         dump_and_clear_log();
 399         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 400                 send($s, "x_it $code", MSG_EOR);
 401         } elsif ($self->{oneshot}) {
 402                 # don't want to end up using $? from child processes
 403                 _drop_wq($self);
 404                 # cleanup anything that has tempfiles or open file handles
 405                 %PATH2CFG = ();
 406                 delete @$self{qw(ovv dedupe sto cfg)};
 407                 if (my $signum = ($code & 127)) { # usually SIGPIPE (13)
 408                         $SIG{PIPE} = 'DEFAULT'; # $SIG{$signum} doesn't work
 409                         kill $signum, $$;
 410                         sleep(1) while 1; # wait for signal
 411                 } else {
 412                         $quit->($code >> 8);
 413                 }
 414         } # else ignore if client disconnected
 415 }
 416
 417 sub err ($;@) {
 418         my $self = shift;
 419         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 420         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 421         print $err @_, @eor and return;
 422         my $old_err = delete $self->{2};
 423         close($old_err) if $! == EPIPE && $old_err;
 424         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 425         print $err @_, @eor or print STDERR @_, @eor;
 426 }
 427
 428 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 429
 430 sub fail_handler ($;$$) {
 431         my ($lei, $code, $io) = @_;
 432         close($io) if $io; # needed to avoid warnings on SIGPIPE
 433         _drop_wq($lei);
 434         x_it($lei, $code // (1 << 8));
 435 }
 436
 437 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 438         fail_handler($_[0], 13, delete $_[0]->{1});
 439 }
 440
 441 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 442 sub sigint_reap {
 443         my ($pgid) = @_;
 444         dwaitpid($pgid) if kill('-INT', $pgid);
 445 }
 446
 447 sub fail ($$;$) {
 448         my ($self, $buf, $exit_code) = @_;
 449         err($self, $buf) if defined $buf;
 450         # calls fail_handler:
 451         send($self->{pkt_op_p}, '!', MSG_EOR) if $self->{pkt_op_p};
 452         x_it($self, ($exit_code // 1) << 8);
 453         undef;
 454 }
 455
 456 sub out ($;@) {
 457         my $self = shift;
 458         return if print { $self->{1} // return } @_; # likely
 459         return note_sigpipe($self, 1) if $! == EPIPE;
 460         my $err = "error writing to output: $!";
 461         delete $self->{1};
 462         fail($self, $err);
 463 }
 464
 465 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 466
 467 sub child_error { # passes non-fatal curl exit codes to user
 468         my ($self, $child_error, $msg) = @_; # child_error is $?
 469         $self->err($msg) if $msg;
 470         if (my $s = $self->{pkt_op_p} // $self->{sock}) {
 471                 # send to the parent lei-daemon or to lei(1) client
 472                 send($s, "child_error $child_error", MSG_EOR);
 473         } elsif (!$PublicInbox::DS::in_loop) {
 474                 $self->{child_error} = $child_error;
 475         } # else noop if client disconnected
 476 }
 477
 478 sub note_sigpipe { # triggers sigpipe_handler
 479         my ($self, $fd) = @_;
 480         close(delete($self->{$fd})); # explicit close silences Perl warning
 481         send($self->{pkt_op_p}, '|', MSG_EOR) if $self->{pkt_op_p};
 482         x_it($self, 13);
 483 }
 484
 485 sub _lei_atfork_child {
 486         my ($self, $persist) = @_;
 487         # we need to explicitly close things which are on stack
 488         if ($persist) {
 489                 chdir '/' or die "chdir(/): $!";
 490                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 491                 if (my $cfg = $self->{cfg}) {
 492                         delete $cfg->{-lei_store};
 493                 }
 494         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 495                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 496         }
 497         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 498         if (my $op_c = delete $self->{pkt_op_c}) {
 499                 close(delete $op_c->{sock});
 500         }
 501         if (my $pgr = delete $self->{pgr}) {
 502                 close($_) for (@$pgr[1,2]);
 503         }
 504         close $listener if $listener;
 505         undef $listener;
 506         %PATH2CFG = ();
 507         undef $errors_log;
 508         $quit = \&CORE::exit;
 509         $self->{-eml_noisy} or # only "lei import" sets this atm
 510                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 511         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 512 }
 513
 514 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 515         my ($self) = @_;
 516         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 517                 $op->close; # PublicInbox::PktOp::close
 518         }
 519         my $unclosed_after_die = delete($self->{pkt_op_p}) or return;
 520         close $unclosed_after_die;
 521 }
 522
 523 sub pkt_op_pair {
 524         my ($self) = @_;
 525         require PublicInbox::OnDestroy;
 526         require PublicInbox::PktOp;
 527         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 528         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 529         $end;
 530 }
 531
 532 sub workers_start {
 533         my ($lei, $wq, $ident, $jobs, $ops) = @_;
 534         $ops = {
 535                 '!' => [ \&fail_handler, $lei ],
 536                 '|' => [ \&sigpipe_handler, $lei ],
 537                 'x_it' => [ \&x_it, $lei ],
 538                 'child_error' => [ \&child_error, $lei ],
 539                 ($ops ? %$ops : ()),
 540         };
 541         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 542         my $end = $lei->pkt_op_pair;
 543         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 544         delete $lei->{pkt_op_p};
 545         my $op_c = delete $lei->{pkt_op_c};
 546         @$end = ();
 547         $lei->event_step_init;
 548         ($op_c, $ops);
 549 }
 550
 551 sub _help {
 552         require PublicInbox::LeiHelp;
 553         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 554 }
 555
 556 sub optparse ($$$) {
 557         my ($self, $cmd, $argv) = @_;
 558         # allow _complete --help to complete, not show help
 559         return 1 if substr($cmd, 0, 1) eq '_';
 560         $self->{cmd} = $cmd;
 561         $OPT = $self->{opt} //= {};
 562         my $info = $CMD{$cmd} // [ '[...]' ];
 563         my ($proto, undef, @spec) = @$info;
 564         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 565         push @spec, qw(help|h);
 566         my $lone_dash;
 567         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 568                 $lone_dash = $spec[0];
 569                 $OPT->{$spec[0]} = \(my $var);
 570                 push @spec, '' => \$var;
 571         }
 572         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 573                 return _help($self, "bad arguments or options for $cmd");
 574         return _help($self) if $OPT->{help};
 575
 576         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 577
 578         # "-" aliases "stdin" or "clear"
 579         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 580
 581         my $i = 0;
 582         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 583         my ($err, $inf);
 584         my @args = split(/ /, $proto);
 585         for my $var (@args) {
 586                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 587                         $inf = defined($argv->[$i]) and last;
 588                         $var =~ s/\.\.\.\z//;
 589                         $err = "$var not supplied";
 590                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 591                         $argv->[$i++] // ($err = "$var not supplied");
 592                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 593                         $inf = 1;
 594                         last;
 595                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 596                         $i++;
 597                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 598                         $inf = 1 if index($var, '...') > 0;
 599                         my @or = split(/\|/, $var);
 600                         my $ok;
 601                         for my $o (@or) {
 602                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 603                                         $ok = defined($OPT->{$1});
 604                                         last if $ok;
 605                                 } elsif (defined($argv->[$i])) {
 606                                         $ok = 1;
 607                                         $i++;
 608                                         last;
 609                                 } # else continue looping
 610                         }
 611                         last if $ok;
 612                         my $last = pop @or;
 613                         $err = join(', ', @or) . " or $last must be set";
 614                 } else {
 615                         warn "BUG: can't parse `$var' in $proto";
 616                 }
 617                 last if $err;
 618         }
 619         if (!$inf && scalar(@$argv) > scalar(@args)) {
 620                 $err //= 'too many arguments';
 621         }
 622         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 623 }
 624
 625 sub _tmp_cfg { # for lei -c <name>=<value> ...
 626         my ($self) = @_;
 627         my $cfg = _lei_cfg($self, 1);
 628         require File::Temp;
 629         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 630         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 631         $ft->autoflush(1);
 632         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 633 [include]
 634         path = $cfg->{-f}
 635 EOM
 636         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 637         for (@{$self->{opt}->{c}}) {
 638                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 639 `-c $_' is not of the form -c <name>=<value>'
 640 EOM
 641                 my $name = $1;
 642                 my $value = $2 // 1;
 643                 _config($self, '--add', $name, $value);
 644                 if (defined(my $v = $tmp->{$name})) {
 645                         if (ref($v) eq 'ARRAY') {
 646                                 push @$v, $value;
 647                         } else {
 648                                 $tmp->{$name} = [ $v, $value ];
 649                         }
 650                 } else {
 651                         $tmp->{$name} = $value;
 652                 }
 653         }
 654 }
 655
 656 sub lazy_cb ($$$) {
 657         my ($self, $cmd, $pfx) = @_;
 658         my $ucmd = $cmd;
 659         $ucmd =~ tr/-/_/;
 660         my $cb;
 661         $cb = $self->can($pfx.$ucmd) and return $cb;
 662         my $base = $ucmd;
 663         $base =~ s/_([a-z])/\u$1/g;
 664         my $pkg = "PublicInbox::Lei\u$base";
 665         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 666                 $pkg->can($pfx.$ucmd) : undef;
 667 }
 668
 669 sub dispatch {
 670         my ($self, $cmd, @argv) = @_;
 671         local $current_lei = $self; # for __WARN__
 672         dump_and_clear_log("from previous run\n");
 673         return _help($self, 'no command given') unless defined($cmd);
 674         # do not support Getopt bundling for this
 675         while ($cmd eq '-C' || $cmd eq '-c') {
 676                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 677                                         '-C DIRECTORY' : '-c <name>=<value>');
 678                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 679                 $cmd = shift(@argv) // return _help($self, 'no command given');
 680         }
 681         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 682                 optparse($self, $cmd, \@argv) or return;
 683                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 684                 if (my $chdir = $self->{opt}->{C}) {
 685                         for my $d (@$chdir) {
 686                                 next if $d eq ''; # same as git(1)
 687                                 chdir $d or return fail($self, "cd $d: $!");
 688                         }
 689                         if (delete $self->{3}) { # update cwd for rel2abs
 690                                 opendir my $dh, '.' or
 691                                         return fail($self, "opendir . $!");
 692                                 $self->{3} = $dh;
 693                         }
 694                 }
 695                 $cb->($self, @argv);
 696         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 697                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 698                         or return _help($self, 'bad arguments or options');
 699                 _help($self);
 700         } else {
 701                 fail($self, "`$cmd' is not an lei command");
 702         }
 703 }
 704
 705 sub _lei_cfg ($;$) {
 706         my ($self, $creat) = @_;
 707         return $self->{cfg} if $self->{cfg};
 708         my $f = _config_path($self);
 709         my @st = stat($f);
 710         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 711         my ($sto, $sto_dir);
 712         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 713                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 714                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 715         }
 716         if (!@st) {
 717                 unless ($creat) {
 718                         delete $self->{cfg};
 719                         return bless {}, 'PublicInbox::Config';
 720                 }
 721                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 722                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 723                 open my $fh, '>>', $f or die "open($f): $!\n";
 724                 @st = stat($fh) or die "fstat($f): $!\n";
 725                 $cur_st = pack('dd', $st[10], $st[7]);
 726                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 727         }
 728         my $cfg = PublicInbox::Config->git_config_dump($f);
 729         $cfg->{-st} = $cur_st;
 730         $cfg->{'-f'} = $f;
 731         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 732                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 733                                                 store_path($self))) {
 734                 $cfg->{-lei_store} = $sto;
 735         }
 736         if (scalar(keys %PATH2CFG) > 5) {
 737                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 738                 for my $k (keys %PATH2CFG) {
 739                         delete($PATH2CFG{$k}) unless -f $k
 740                 }
 741         }
 742         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 743 }
 744
 745 sub _lei_store ($;$) {
 746         my ($self, $creat) = @_;
 747         my $cfg = _lei_cfg($self, $creat);
 748         $cfg->{-lei_store} //= do {
 749                 require PublicInbox::LeiStore;
 750                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 751                 return unless $creat || -d $dir;
 752                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 753         };
 754 }
 755
 756 sub _config {
 757         my ($self, @argv) = @_;
 758         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 759         my $cfg = _lei_cfg($self, 1);
 760         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 761         my %rdr = map { $_ => $self->{$_} } (0..2);
 762         waitpid(spawn($cmd, \%env, \%rdr), 0);
 763 }
 764
 765 sub lei_config {
 766         my ($self, @argv) = @_;
 767         $self->{opt}->{'config-file'} and return fail $self,
 768                 "config file switches not supported by `lei config'";
 769         _config(@_);
 770         x_it($self, $?) if $?;
 771 }
 772
 773 sub lei_daemon_pid { puts shift, $$ }
 774
 775 sub lei_daemon_kill {
 776         my ($self) = @_;
 777         my $sig = $self->{opt}->{signal} // 'TERM';
 778         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 779 }
 780
 781 # Shell completion helper.  Used by lei-completion.bash and hopefully
 782 # other shells.  Try to do as much here as possible to avoid redundancy
 783 # and improve maintainability.
 784 sub lei__complete {
 785         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 786         shift @argv; # ignore "lei", the entire command is sent
 787         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 788         my $cmd = shift @argv;
 789         my $info = $CMD{$cmd} // do { # filter matching commands
 790                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 791                 return;
 792         };
 793         my ($proto, undef, @spec) = @$info;
 794         my $cur = pop @argv;
 795         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 796         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 797                 # gross special case since the only git-config options
 798                 # Consider moving to a table if we need more special cases
 799                 # we use Getopt::Long for are the ones we reject, so these
 800                 # are the ones we don't reject:
 801                 if ($cmd eq 'config') {
 802                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 803                         @spec = qw(add z|null get get-all unset unset-all
 804                                 replace-all get-urlmatch
 805                                 remove-section rename-section
 806                                 name-only list|l edit|e
 807                                 get-color-name get-colorbool);
 808                         # fall-through
 809                 }
 810                 # generate short/long names from Getopt::Long specs
 811                 puts $self, grep(/$re/, qw(--help -h -C), map {
 812                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 813                         } elsif (s/\+\z//) { # verbose|v+
 814                         } elsif (s/!\z//) {
 815                                 # negation: mail! => no-mail|mail
 816                                 s/([\w\-]+)/$1|no-$1/g
 817                         }
 818                         map {
 819                                 my $x = length > 1 ? "--$_" : "-$_";
 820                                 $x eq $_cur ? () : $x;
 821                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 822                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 823         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 824                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 825         }
 826
 827         # switch args (e.g. lei q -f mbox<TAB>)
 828         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 829                 my $opt = quotemeta $1;
 830                 puts $self, map {
 831                         my $v = $OPTDESC{$_};
 832                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 833                         # get rid of ALL CAPS placeholder (e.g "OUT")
 834                         # (TODO: completion for external paths)
 835                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 836                         @v;
 837                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 838         }
 839         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 840                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 841         }
 842         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 843         # proto parsing.
 844 }
 845
 846 sub exec_buf ($$) {
 847         my ($argv, $env) = @_;
 848         my $argc = scalar @$argv;
 849         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 850         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 851         $buf;
 852 }
 853
 854 sub start_mua {
 855         my ($self) = @_;
 856         my $mua = $self->{opt}->{mua} // return;
 857         my $mfolder = $self->{ovv}->{dst};
 858         my (@cmd, $replaced);
 859         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 860                 @cmd = ($mua, '-f');
 861         # TODO: help wanted: other common FOSS MUAs
 862         } else {
 863                 require Text::ParseWords;
 864                 @cmd = Text::ParseWords::shellwords($mua);
 865                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 866                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 867         }
 868         push @cmd, $mfolder unless defined($replaced);
 869         if ($self->{sock}) { # lei(1) client process runs it
 870                 # restore terminal: echo $query | lei q -stdin --mua=...
 871                 my $io = [];
 872                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 873                 send_exec_cmd($self, $io, \@cmd, {});
 874         } elsif ($self->{oneshot}) {
 875                 my $pid = fork // die "fork: $!";
 876                 if ($pid > 0) { # original process
 877                         if ($self->{opt}->{stdin} && -t STDOUT) {
 878                                 open STDIN, '+<&', \*STDOUT or die "dup2: $!";
 879                         }
 880                         exec(@cmd);
 881                         warn "exec @cmd: $!\n";
 882                         POSIX::_exit(1);
 883                 }
 884                 POSIX::setsid() > 0 or die "setsid: $!";
 885         }
 886         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 887                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 888         }
 889         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 890         $self->{opt}->{quiet} = 1;
 891         delete $self->{-progress};
 892         delete $self->{opt}->{verbose};
 893 }
 894
 895 sub send_exec_cmd { # tell script/lei to execute a command
 896         my ($self, $io, $cmd, $env) = @_;
 897         my $sock = $self->{sock} // die 'lei client gone';
 898         my $fds = [ map { fileno($_) } @$io ];
 899         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 900 }
 901
 902 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 903         my ($self) = @_;
 904         my $alerts = $self->{opt}->{alert} // return;
 905         while (my $op = shift(@$alerts)) {
 906                 if ($op eq ':WINCH') {
 907                         # hit the process group that started the MUA
 908                         if ($self->{sock}) {
 909                                 send($self->{sock}, '-WINCH', MSG_EOR);
 910                         } elsif ($self->{oneshot}) {
 911                                 kill('-WINCH', $$);
 912                         }
 913                 } elsif ($op eq ':bell') {
 914                         out($self, "\a");
 915                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 916                         push @$alerts, split(/(?<!\\),/, $op);
 917                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 918                         my $cmd = $1; # run an arbitrary command
 919                         require Text::ParseWords;
 920                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 921                         if (my $s = $self->{sock}) {
 922                                 send($s, exec_buf($cmd, {}), MSG_EOR);
 923                         } elsif ($self->{oneshot}) {
 924                                 $self->{"pid.$self.$$"}->{spawn($cmd)} = $cmd;
 925                         }
 926                 } else {
 927                         err($self, "W: unsupported --alert=$op"); # non-fatal
 928                 }
 929         }
 930 }
 931
 932 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 933 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 934
 935 # this also normalizes the path
 936 sub path_to_fd {
 937         my ($self, $path) = @_;
 938         $path = rel2abs($self, $path);
 939         $path =~ tr!/!/!s;
 940         $path_to_fd{$path} // (
 941                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 942                         fail($self, "cannot open $path from daemon") : -1
 943         );
 944 }
 945
 946 # caller needs to "-t $self->{1}" to check if tty
 947 sub start_pager {
 948         my ($self) = @_;
 949         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 950         chomp(my $pager = <$fh> // '');
 951         close($fh) or warn "`git var PAGER' error: \$?=$?";
 952         return if $pager eq 'cat' || $pager eq '';
 953         my $new_env = { LESS => 'FRX', LV => '-c' };
 954         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 955         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 956         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 957         my $pgr = [ undef, @$rdr{1, 2} ];
 958         my $env = $self->{env};
 959         if ($self->{sock}) { # lei(1) process runs it
 960                 delete @$new_env{keys %$env}; # only set iff unset
 961                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 962         } elsif ($self->{oneshot}) {
 963                 my $cmd = [$pager];
 964                 $self->{"pid.$self.$$"}->{spawn($cmd, $new_env, $rdr)} = $cmd;
 965         } else {
 966                 die 'BUG: start_pager w/o socket';
 967         }
 968         $self->{1} = $wpager;
 969         $self->{2} = $wpager if -t $self->{2};
 970         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 971         $self->{pgr} = $pgr;
 972 }
 973
 974 sub stop_pager {
 975         my ($self) = @_;
 976         my $pgr = delete($self->{pgr}) or return;
 977         $self->{2} = $pgr->[2];
 978         # do not restore original stdout, just close it so we error out
 979         close(delete($self->{1})) if $self->{1};
 980 }
 981
 982 sub accept_dispatch { # Listener {post_accept} callback
 983         my ($sock) = @_; # ignore other
 984         $sock->autoflush(1);
 985         my $self = bless { sock => $sock }, __PACKAGE__;
 986         vec(my $rvec = '', fileno($sock), 1) = 1;
 987         select($rvec, undef, undef, 60) or
 988                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 989         # (4096 * 33) >MAX_ARG_STRLEN
 990         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
 991         if (!defined($fds[0])) {
 992                 warn(my $msg = "recv_cmd failed: $!");
 993                 return send($sock, $msg, MSG_EOR);
 994         } else {
 995                 my $i = 0;
 996                 for my $fd (@fds) {
 997                         open($self->{$i++}, '+<&=', $fd) and next;
 998                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
 999                 }
1000                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1001         }
1002         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
1003         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1004         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1005         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1006                 return send($sock, 'request command truncated', MSG_EOR);
1007         my ($argc, @argv) = split(/\0/, $buf, -1);
1008         undef $buf;
1009         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1010         if (chdir($self->{3})) {
1011                 local %ENV = %env;
1012                 $self->{env} = \%env;
1013                 eval { dispatch($self, @argv) };
1014                 send($sock, $@, MSG_EOR) if $@;
1015         } else {
1016                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1017         }
1018 }
1019
1020 sub dclose {
1021         my ($self) = @_;
1022         delete $self->{-progress};
1023         _drop_wq($self);
1024         close(delete $self->{1}) if $self->{1}; # may reap_compress
1025         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1026 }
1027
1028 # for long-running results
1029 sub event_step {
1030         my ($self) = @_;
1031         local %ENV = %{$self->{env}};
1032         my $sock = $self->{sock};
1033         local $current_lei = $self;
1034         eval {
1035                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1036                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1037                                 return if $! == EAGAIN;
1038                                 next if $! == EINTR;
1039                                 last if $! == ECONNRESET;
1040                                 die "recvmsg: $!";
1041                         }
1042                         for my $fd (@fds) {
1043                                 open my $rfh, '+<&=', $fd;
1044                         }
1045                         die "unrecognized client signal: $buf";
1046                 }
1047                 dclose($self);
1048         };
1049         if (my $err = $@) {
1050                 eval { $self->fail($err) };
1051                 dclose($self);
1052         }
1053 }
1054
1055 sub event_step_init {
1056         my ($self) = @_;
1057         return if $self->{-event_init_done}++;
1058         if (my $sock = $self->{sock}) { # using DS->EventLoop
1059                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1060         }
1061 }
1062
1063 sub noop {}
1064
1065 sub oldset { $oldset }
1066
1067 sub dump_and_clear_log {
1068         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1069                 my @pfx = @_;
1070                 unshift(@pfx, "$errors_log ") if @pfx;
1071                 warn @pfx, do { local $/; <STDIN> };
1072                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1073         }
1074 }
1075
1076 # lei(1) calls this when it can't connect
1077 sub lazy_start {
1078         my ($path, $errno, $narg) = @_;
1079         local ($errors_log, $listener);
1080         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
1081         $errors_log .= 'errors.log';
1082         my $addr = pack_sockaddr_un($path);
1083         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1084         $lk->lock_acquire;
1085         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1086         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1087                 return if connect($listener, $addr); # another process won
1088                 if ($errno == ECONNREFUSED && -S $path) {
1089                         unlink($path) or die "unlink($path): $!";
1090                 }
1091         } else {
1092                 $! = $errno; # allow interpolation to stringify in die
1093                 die "connect($path): $!";
1094         }
1095         umask(077) // die("umask(077): $!");
1096         bind($listener, $addr) or die "bind($path): $!";
1097         listen($listener, 1024) or die "listen: $!";
1098         $lk->lock_release;
1099         undef $lk;
1100         my @st = stat($path) or die "stat($path): $!";
1101         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1102         local $oldset = PublicInbox::DS::block_signals();
1103         if ($narg == 5) {
1104                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1105                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1106                         require PublicInbox::CmdIPC4;
1107                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1108                         PublicInbox::CmdIPC4->can('recv_cmd4');
1109                 };
1110         }
1111         $recv_cmd or die <<"";
1112 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1113
1114         require PublicInbox::Listener;
1115         require PublicInbox::EOFpipe;
1116         (-p STDOUT) or die "E: stdout must be a pipe\n";
1117         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1118         STDIN->autoflush(1);
1119         dump_and_clear_log("from previous daemon process:\n");
1120         POSIX::setsid() > 0 or die "setsid: $!";
1121         my $pid = fork // die "fork: $!";
1122         return if $pid;
1123         $0 = "lei-daemon $path";
1124         local %PATH2CFG;
1125         $listener->blocking(0);
1126         my $exit_code;
1127         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1128         local $quit = do {
1129                 pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
1130                 PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
1131                 sub {
1132                         $exit_code //= shift;
1133                         my $lis = $pil or exit($exit_code);
1134                         # closing eof_w triggers \&noop wakeup
1135                         $listener = $eof_w = $pil = $path = undef;
1136                         $lis->close; # DS::close
1137                         PublicInbox::DS->SetLoopTimeout(1000);
1138                 };
1139         };
1140         my $sig = {
1141                 CHLD => \&PublicInbox::DS::enqueue_reap,
1142                 QUIT => $quit,
1143                 INT => $quit,
1144                 TERM => $quit,
1145                 HUP => \&noop,
1146                 USR1 => \&noop,
1147                 USR2 => \&noop,
1148         };
1149         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1150         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1151         undef $sig;
1152         local $SIG{PIPE} = 'IGNORE';
1153         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
1154                 undef $sigfd;
1155                 PublicInbox::DS->SetLoopTimeout(5000);
1156         } else {
1157                 # wake up every second to accept signals if we don't
1158                 # have signalfd or IO::KQueue:
1159                 PublicInbox::DS::sig_setmask($oldset);
1160                 PublicInbox::DS->SetLoopTimeout(1000);
1161         }
1162         PublicInbox::DS->SetPostLoopCallback(sub {
1163                 my ($dmap, undef) = @_;
1164                 if (@st = defined($path) ? stat($path) : ()) {
1165                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1166                                 warn "$path dev/ino changed, quitting\n";
1167                                 $path = undef;
1168                         }
1169                 } elsif (defined($path)) { # ENOENT is common
1170                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1171                         undef $path;
1172                         $quit->();
1173                 }
1174                 return 1 if defined($path);
1175                 my $now = now();
1176                 my $n = 0;
1177                 for my $s (values %$dmap) {
1178                         $s->can('busy') or next;
1179                         if ($s->busy($now)) {
1180                                 ++$n;
1181                         } else {
1182                                 $s->close;
1183                         }
1184                 }
1185                 $n; # true: continue, false: stop
1186         });
1187
1188         # STDIN was redirected to /dev/null above, closing STDERR and
1189         # STDOUT will cause the calling `lei' client process to finish
1190         # reading the <$daemon> pipe.
1191         local $SIG{__WARN__} = sub {
1192                 $current_lei ? err($current_lei, @_) : warn(
1193                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1194         };
1195         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1196         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1197         # $daemon pipe to `lei' closed, main loop begins:
1198         PublicInbox::DS->EventLoop;
1199         exit($exit_code // 0);
1200 }
1201
1202 sub busy { 1 } # prevent daemon-shutdown if client is connected
1203
1204 # for users w/o Socket::Msghdr installed or Inline::C enabled
1205 sub oneshot {
1206         my ($main_pkg) = @_;
1207         my $exit = $main_pkg->can('exit'); # caller may override exit()
1208         local $quit = $exit if $exit;
1209         local %PATH2CFG;
1210         umask(077) // die("umask(077): $!");
1211         my $self = bless { oneshot => 1, env => \%ENV }, __PACKAGE__;
1212         for (0..2) { open($self->{$_}, '+<&=', $_) or die "open fd=$_: $!" }
1213         dispatch($self, @ARGV);
1214         x_it($self, $self->{child_error}) if $self->{child_error};
1215 }
1216
1217 # ensures stdout hits the FS before sock disconnects so a client
1218 # can immediately reread it
1219 sub DESTROY {
1220         my ($self) = @_;
1221         $self->{1}->autoflush(1) if $self->{1};
1222         stop_pager($self);
1223         my $err = $?;
1224         my $oneshot_pids = delete $self->{"pid.$self.$$"} or return;
1225         waitpid($_, 0) for keys %$oneshot_pids;
1226         $? = $err if $err; # preserve ->fail or ->x_it code
1227 }
1228
1229 sub wq_done_wait { # dwaitpid callback
1230         my ($arg, $pid) = @_;
1231         my ($wq, $lei) = @$arg;
1232         my $err_type = $lei->{-err_type};
1233         $? and $lei->child_error($?,
1234                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1235         $lei->dclose;
1236 }
1237
1238 sub wq_eof { # EOF callback for main daemon
1239         my ($lei) = @_;
1240         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1241         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1242 }
1243
1244 1;