lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal);
  12 use Getopt::Long ();
  13 use Socket qw(AF_UNIX SOCK_STREAM pack_sockaddr_un);
  14 use Errno qw(EAGAIN ECONNREFUSED ENOENT);
  15 use POSIX ();
  16 use IO::Handle ();
  17 use Sys::Syslog qw(syslog openlog);
  18 use PublicInbox::Config;
  19 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLONESHOT);
  20 use PublicInbox::Sigfd;
  21 use PublicInbox::DS qw(now dwaitpid);
  22 use PublicInbox::Spawn qw(spawn run_die);
  23 use PublicInbox::OnDestroy;
  24 use Text::Wrap qw(wrap);
  25 use File::Path qw(mkpath);
  26 use File::Spec;
  27 our $quit = \&CORE::exit;
  28 my $recv_fd;
  29 my $GLP = Getopt::Long::Parser->new;
  30 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  31 my $GLP_PASS = Getopt::Long::Parser->new;
  32 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  33
  34 our %PATH2CFG; # persistent for socket daemon
  35
  36 # TBD: this is a documentation mechanism to show a subcommand
  37 # (may) pass options through to another command:
  38 sub pass_through { $GLP_PASS }
  39
  40 my $OPT;
  41 sub opt_dash {
  42         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  43         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  44         my $cb = sub { # Getopt::Long "<>" catch-all handler
  45                 my ($arg) = @_;
  46                 if ($arg =~ /\A-($re_str)\z/) {
  47                         $OPT->{$key} = $1;
  48                 } else {
  49                         die "bad argument for --$key: $arg\n";
  50                 }
  51         };
  52         ($spec, '<>' => $cb, $GLP_PASS)
  53 }
  54
  55 sub _store_path ($) {
  56         my ($env) = @_;
  57         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  58                 ($env->{HOME} // '/nonexistent').'/.local/share')
  59                 .'/lei/store', $env->{PWD});
  60 }
  61
  62 sub _config_path ($) {
  63         my ($env) = @_;
  64         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  65                 ($env->{HOME} // '/nonexistent').'/.config')
  66                 .'/lei/config', $env->{PWD});
  67 }
  68
  69 # TODO: generate shell completion + help using %CMD and %OPTDESC
  70 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  71 our %CMD = ( # sorted in order of importance/use:
  72 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  73         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  74         sort|s=s@ reverse|r offset=i remote local! external!
  75         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  76
  77 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  78         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  79         pass_through('git show') ],
  80
  81 'add-external' => [ 'URL_OR_PATHNAME',
  82         'add/set priority of a publicinbox|extindex for extra matches',
  83         qw(boost=i quiet|q) ],
  84 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  85         qw(format|f=s z|0 local remote quiet|q) ],
  86 'forget-external' => [ '{URL_OR_PATHNAME|--prune}',
  87         'exclude further results from a publicinbox|extindex',
  88         qw(prune quiet|q) ],
  89
  90 'ls-query' => [ '[FILTER...]', 'list saved search queries',
  91                 qw(name-only format|f=s z) ],
  92 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
  93 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
  94
  95 'plonk' => [ '--thread|--from=IDENT',
  96         'exclude mail matching From: or thread from non-Message-ID searches',
  97         qw(stdin| thread|t from|f=s mid=s oid=s) ],
  98 'mark' => [ 'MESSAGE_FLAGS...',
  99         'set/unset flags on message(s) from stdin',
 100         qw(stdin| oid=s exact by-mid|mid:s) ],
 101 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 102         "exclude message(s) on stdin from `q' search results",
 103         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 104
 105 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 106         'remove imported messages from IMAP, Maildirs, and MH',
 107         qw(exact! all jobs:i indexed) ],
 108
 109 # code repos are used for `show' to solve blobs from patch mails
 110 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 111         qw(boost=i) ],
 112 'ls-coderepo' => [ '[FILTER_TERMS...]',
 113                 'list known code repos', qw(format|f=s z) ],
 114 'forget-coderepo' => [ 'PATHNAME',
 115         'stop using repo to solve blobs from patches',
 116         qw(prune) ],
 117
 118 'add-watch' => [ '[URL_OR_PATHNAME]',
 119                 'watch for new messages and flag changes',
 120         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 121 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 122                 qw(format|f=s z) ],
 123 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 124 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 125 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 126         qw(prune) ],
 127
 128 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 129         'one-shot import/update from URL or filesystem',
 130         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 131         ],
 132
 133 'config' => [ '[...]', sub {
 134                 'git-config(1) wrapper for '._config_path($_[0]);
 135         }, qw(config-file|system|global|file|f=s), # for conflict detection
 136         pass_through('git config') ],
 137 'init' => [ '[PATHNAME]', sub {
 138                 'initialize storage, default: '._store_path($_[0]);
 139         }, qw(quiet|q) ],
 140 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 141         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 142 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 143 'daemon-env' => [ '[NAME=VALUE...]', 'set, unset, or show daemon environment',
 144         qw(clear| unset|u=s@ z|0) ],
 145 'help' => [ '[SUBCOMMAND]', 'show help' ],
 146
 147 # XXX do we need this?
 148 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 149
 150 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 151         'rewrite git history in an attempt to improve compression',
 152         'gc!' ],
 153
 154 # internal commands are prefixed with '_'
 155 '_complete' => [ '[...]', 'internal shell completion helper',
 156                 pass_through('everything') ],
 157 ); # @CMD
 158
 159 # switch descriptions, try to keep consistent across commands
 160 # $spec: Getopt::Long option specification
 161 # $spec => [@ALLOWED_VALUES (default is first), $description],
 162 # $spec => $description
 163 # "$SUB_COMMAND TAB $spec" => as above
 164 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 165                 'specify message input format' ];
 166 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 167
 168 my %OPTDESC = (
 169 'help|h' => 'show this built-in help',
 170 'quiet|q' => 'be quiet',
 171 'solve!' => 'do not attempt to reconstruct blobs from emails',
 172 'save-as=s' => ['NAME', 'save a search terms by given name'],
 173
 174 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 175
 176 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 177                 'deduplication strategy'],
 178 'show   thread|t' => 'display entire thread a message belongs to',
 179 'q      thread|t' =>
 180         'return all messages in the same thread as the actual match(es)',
 181 'augment|a' => 'augment --output destination instead of clobbering',
 182
 183 'output|o=s' => [ 'DEST',
 184         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 185
 186 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 187                         'message/object output format' ],
 188 'mark   format|f=s' => $stdin_formats,
 189 'forget format|f=s' => $stdin_formats,
 190 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 191                 'specify output format, default depends on --output'],
 192 'ls-query       format|f=s' => $ls_format,
 193 'ls-external    format|f=s' => $ls_format,
 194
 195 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 196 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 197
 198 'sort|s=s@' => [ 'VAL|internaldate,date,relevance,docid',
 199                 "order of results `--output'-dependent"],
 200
 201 'boost=i' => 'increase/decrease priority of results (default: 0)',
 202
 203 'local' => 'limit operations to the local filesystem',
 204 'local!' => 'exclude results from the local filesystem',
 205 'remote' => 'limit operations to those requiring network access',
 206 'remote!' => 'prevent operations requiring network access',
 207
 208 'mid=s' => 'specify the Message-ID of a message',
 209 'oid=s' => 'specify the git object ID of a message',
 210
 211 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 212 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 213 'include=s' => 'include mailboxes/newsgroups based on pattern',
 214
 215 'exact' => 'operate on exact header matches only',
 216 'exact!' => 'rely on content match instead of exact header matches',
 217
 218 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 219 'jobs:i' => 'set parallelism level',
 220
 221 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 222 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 223
 224 # note: no "--ignore-environment" / "-i" support like env(1) since that
 225 # is one-shot and this is for a persistent daemon:
 226 'clear|' => 'clear the daemon environment',
 227 'unset|u=s@' => ['NAME',
 228         'unset matching NAME, may be specified multiple times'],
 229
 230 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 231 ); # %OPTDESC
 232
 233 my %CONFIG_KEYS = (
 234         'leistore.dir' => 'top-level storage location',
 235 );
 236
 237 sub x_it ($$) { # pronounced "exit"
 238         my ($self, $code) = @_;
 239         if (my $sig = ($code & 127)) {
 240                 kill($sig, $self->{pid} // $$);
 241         } else {
 242                 $code >>= 8;
 243                 if (my $sock = $self->{sock}) {
 244                         say $sock "exit=$code";
 245                 } else { # for oneshot
 246                         $quit->($code);
 247                 }
 248         }
 249 }
 250
 251 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 252
 253 sub out ($;@) { print { shift->{1} } @_ }
 254
 255 sub err ($;@) {
 256         print { shift->{2} } @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 257 }
 258
 259 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 260
 261 sub fail ($$;$) {
 262         my ($self, $buf, $exit_code) = @_;
 263         err($self, $buf);
 264         x_it($self, ($exit_code // 1) << 8);
 265         undef;
 266 }
 267
 268 sub _help ($;$) {
 269         my ($self, $errmsg) = @_;
 270         my $cmd = $self->{cmd} // 'COMMAND';
 271         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 272         my @top = ($cmd, shift(@info) // ());
 273         my $cmd_desc = shift(@info);
 274         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 275         my @opt_desc;
 276         my $lpad = 2;
 277         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 278                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 279                 my $arg_vals = '';
 280                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 281
 282                 # lower-case is a keyword (e.g. `content', `oid'),
 283                 # ALL_CAPS is a string description (e.g. `PATH')
 284                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 285                         $desc .= "\ndefault: `$1'";
 286                 }
 287                 my (@vals, @s, @l);
 288                 my $x = $sw;
 289                 if ($x =~ s/!\z//) { # solve! => --no-solve
 290                         $x = "no-$x";
 291                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 292                         @vals = (' [', undef, ']');
 293                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 294                         @vals = (' ', undef);
 295                 } # else: no args $x = 'thread|t'
 296                 for (split(/\|/, $x)) { # help|h
 297                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 298                 }
 299                 if (!scalar(@vals)) { # no args 'thread|t'
 300                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 301                         $vals[1] = $1;
 302                 } else {
 303                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 304                 }
 305                 if ($arg_vals =~ /([,\|])/) {
 306                         my $sep = $1;
 307                         my @allow = split(/\Q$sep\E/, $arg_vals);
 308                         my $must = $sep eq '|' ? 'Must' : 'Can';
 309                         @allow = map { "`$_'" } @allow;
 310                         my $last = pop @allow;
 311                         $desc .= "\n$must be one of: " .
 312                                 join(', ', @allow) . " or $last";
 313                 }
 314                 my $lhs = join(', ', @s, @l) . join('', @vals);
 315                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 316                         $lhs =~ s/\A--/- , --/;
 317                 } else {
 318                         $lhs =~ s/\A--/    --/; # pad if no short options
 319                 }
 320                 $lpad = length($lhs) if length($lhs) > $lpad;
 321                 push @opt_desc, $lhs, $desc;
 322         }
 323         my $msg = $errmsg ? "E: $errmsg\n" : '';
 324         $msg .= <<EOF;
 325 usage: lei @top
 326   $cmd_desc
 327
 328 EOF
 329         $lpad += 2;
 330         local $Text::Wrap::columns = 78 - $lpad;
 331         my $padding = ' ' x ($lpad + 2);
 332         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 333                 $msg .= '  '.pack("A$lpad", $lhs);
 334                 $rhs = wrap('', '', $rhs);
 335                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 336                 $msg .= $rhs;
 337                 $msg .= "\n";
 338         }
 339         print { $self->{$errmsg ? 2 : 1} } $msg;
 340         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 341         undef;
 342 }
 343
 344 sub optparse ($$$) {
 345         my ($self, $cmd, $argv) = @_;
 346         $self->{cmd} = $cmd;
 347         $OPT = $self->{opt} = {};
 348         my $info = $CMD{$cmd} // [ '[...]' ];
 349         my ($proto, undef, @spec) = @$info;
 350         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 351         push @spec, qw(help|h);
 352         my $lone_dash;
 353         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 354                 $lone_dash = $spec[0];
 355                 $OPT->{$spec[0]} = \(my $var);
 356                 push @spec, '' => \$var;
 357         }
 358         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 359                 return _help($self, "bad arguments or options for $cmd");
 360         return _help($self) if $OPT->{help};
 361
 362         # "-" aliases "stdin" or "clear"
 363         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 364
 365         my $i = 0;
 366         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 367         my ($err, $inf);
 368         my @args = split(/ /, $proto);
 369         for my $var (@args) {
 370                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 371                         $inf = defined($argv->[$i]) and last;
 372                         $var =~ s/\.\.\.\z//;
 373                         $err = "$var not supplied";
 374                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 375                         $argv->[$i++] // ($err = "$var not supplied");
 376                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 377                         $inf = 1;
 378                         last;
 379                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 380                         $i++;
 381                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 382                         my @or = split(/\|/, $var);
 383                         my $ok;
 384                         for my $o (@or) {
 385                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 386                                         $ok = defined($OPT->{$1});
 387                                         last;
 388                                 } elsif (defined($argv->[$i])) {
 389                                         $ok = 1;
 390                                         $i++;
 391                                         last;
 392                                 } # else continue looping
 393                         }
 394                         my $last = pop @or;
 395                         $err = join(', ', @or) . " or $last must be set";
 396                 } else {
 397                         warn "BUG: can't parse `$var' in $proto";
 398                 }
 399                 last if $err;
 400         }
 401         if (!$inf && scalar(@$argv) > scalar(@args)) {
 402                 $err //= 'too many arguments';
 403         }
 404         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 405 }
 406
 407 sub dispatch {
 408         my ($self, $cmd, @argv) = @_;
 409         local $SIG{__WARN__} = sub { err($self, @_) };
 410         return _help($self, 'no command given') unless defined($cmd);
 411         my $func = "lei_$cmd";
 412         $func =~ tr/-/_/;
 413         if (my $cb = __PACKAGE__->can($func)) {
 414                 optparse($self, $cmd, \@argv) or return;
 415                 $cb->($self, @argv);
 416         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 417                 my $opt = {};
 418                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 419                         return _help($self, 'bad arguments or options');
 420                 _help($self);
 421         } else {
 422                 fail($self, "`$cmd' is not an lei command");
 423         }
 424 }
 425
 426 sub _lei_cfg ($;$) {
 427         my ($self, $creat) = @_;
 428         my $f = _config_path($self->{env});
 429         my @st = stat($f);
 430         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 431         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 432                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 433         }
 434         if (!@st) {
 435                 unless ($creat) {
 436                         delete $self->{cfg};
 437                         return;
 438                 }
 439                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 440                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 441                 open my $fh, '>>', $f or die "open($f): $!\n";
 442                 @st = stat($fh) or die "fstat($f): $!\n";
 443                 $cur_st = pack('dd', $st[10], $st[7]);
 444                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 445         }
 446         my $cfg = PublicInbox::Config::git_config_dump($f);
 447         $cfg->{-st} = $cur_st;
 448         $cfg->{'-f'} = $f;
 449         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 450 }
 451
 452 sub _lei_store ($;$) {
 453         my ($self, $creat) = @_;
 454         my $cfg = _lei_cfg($self, $creat);
 455         $cfg->{-lei_store} //= do {
 456                 require PublicInbox::LeiStore;
 457                 my $dir = $cfg->{'leistore.dir'};
 458                 $dir //= _store_path($self->{env}) if $creat;
 459                 return unless $dir;
 460                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 461         };
 462 }
 463
 464 sub lei_show {
 465         my ($self, @argv) = @_;
 466 }
 467
 468 sub lei_query {
 469         my ($self, @argv) = @_;
 470 }
 471
 472 sub lei_mark {
 473         my ($self, @argv) = @_;
 474 }
 475
 476 sub lei_config {
 477         my ($self, @argv) = @_;
 478         $self->{opt}->{'config-file'} and return fail $self,
 479                 "config file switches not supported by `lei config'";
 480         my $env = $self->{env};
 481         delete local $env->{GIT_CONFIG};
 482         my $cfg = _lei_cfg($self, 1);
 483         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 484         my %rdr = map { $_ => $self->{$_} } (0..2);
 485         run_die($cmd, $env, \%rdr);
 486 }
 487
 488 sub lei_init {
 489         my ($self, $dir) = @_;
 490         my $cfg = _lei_cfg($self, 1);
 491         my $cur = $cfg->{'leistore.dir'};
 492         my $env = $self->{env};
 493         $dir //= _store_path($env);
 494         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 495         my @cur = stat($cur) if defined($cur);
 496         $cur = File::Spec->canonpath($cur) if $cur;
 497         my @dir = stat($dir);
 498         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 499         if (@cur) {
 500                 if ($cur eq $dir) {
 501                         _lei_store($self, 1)->done;
 502                         return qerr($self, $exists);
 503                 }
 504
 505                 # some folks like symlinks and bind mounts :P
 506                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 507                         lei_config($self, 'leistore.dir', $dir);
 508                         _lei_store($self, 1)->done;
 509                         return qerr($self, "$exists (as $cur)");
 510                 }
 511                 return fail($self, <<"");
 512 E: leistore.dir=$cur already initialized and it is not $dir
 513
 514         }
 515         lei_config($self, 'leistore.dir', $dir);
 516         _lei_store($self, 1)->done;
 517         $exists //= "I: leistore.dir=$dir newly initialized";
 518         return qerr($self, $exists);
 519 }
 520
 521 sub lei_daemon_pid { puts shift, $$ }
 522
 523 sub lei_daemon_kill {
 524         my ($self) = @_;
 525         my $sig = $self->{opt}->{signal} // 'TERM';
 526         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 527 }
 528
 529 sub lei_daemon_env {
 530         my ($self, @argv) = @_;
 531         my $opt = $self->{opt};
 532         if (defined $opt->{clear}) {
 533                 %ENV = ();
 534         } elsif (my $u = $opt->{unset}) {
 535                 delete @ENV{@$u};
 536         }
 537         if (@argv) {
 538                 %ENV = (%ENV, map { split(/=/, $_, 2) } @argv);
 539         } elsif (!defined($opt->{clear}) && !$opt->{unset}) {
 540                 my $eor = $opt->{z} ? "\0" : "\n";
 541                 my $buf = '';
 542                 while (my ($k, $v) = each %ENV) { $buf .= "$k=$v$eor" }
 543                 out $self, $buf;
 544         }
 545 }
 546
 547 sub lei_help { _help($_[0]) }
 548
 549 # Shell completion helper.  Used by lei-completion.bash and hopefully
 550 # other shells.  Try to do as much here as possible to avoid redundancy
 551 # and improve maintainability.
 552 sub lei__complete {
 553         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 554         shift @argv; # ignore "lei", the entire command is sent
 555         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 556         my $cmd = shift @argv;
 557         my $info = $CMD{$cmd} // do { # filter matching commands
 558                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 559                 return;
 560         };
 561         my ($proto, undef, @spec) = @$info;
 562         my $cur = pop @argv;
 563         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 564         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 565                 # gross special case since the only git-config options
 566                 # Consider moving to a table if we need more special cases
 567                 # we use Getopt::Long for are the ones we reject, so these
 568                 # are the ones we don't reject:
 569                 if ($cmd eq 'config') {
 570                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 571                         @spec = qw(add z|null get get-all unset unset-all
 572                                 replace-all get-urlmatch
 573                                 remove-section rename-section
 574                                 name-only list|l edit|e
 575                                 get-color-name get-colorbool);
 576                         # fall-through
 577                 }
 578                 # TODO: arg support
 579                 puts $self, grep(/$re/, map { # generate short/long names
 580                         my $eq = '';
 581                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 582                                 $eq = '=';
 583                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 584                         } else { # negation: solve! => no-solve|solve
 585                                 s/\A(.+)!\z/no-$1|$1/;
 586                         }
 587                         map {
 588                                 length > 1 ? "--$_$eq" : "-$_"
 589                         } split(/\|/, $_, -1) # help|h
 590                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 591         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 592                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 593         }
 594         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 595         # proto parsing.
 596 }
 597
 598 sub reap_exec { # dwaitpid callback
 599         my ($self, $pid) = @_;
 600         x_it($self, $?);
 601 }
 602
 603 sub lei_git { # support passing through random git commands
 604         my ($self, @argv) = @_;
 605         my %rdr = map { $_ => $self->{$_} } (0..2);
 606         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 607         dwaitpid($pid, \&reap_exec, $self);
 608 }
 609
 610 sub accept_dispatch { # Listener {post_accept} callback
 611         my ($sock) = @_; # ignore other
 612         $sock->blocking(1);
 613         $sock->autoflush(1);
 614         my $self = bless { sock => $sock }, __PACKAGE__;
 615         vec(my $rin = '', fileno($sock), 1) = 1;
 616         # `say $sock' triggers "die" in lei(1)
 617         for my $i (0..2) {
 618                 if (select(my $rout = $rin, undef, undef, 1)) {
 619                         my $fd = $recv_fd->(fileno($sock));
 620                         if ($fd >= 0) {
 621                                 my $rdr = ($fd == 0 ? '<&=' : '>&=');
 622                                 if (open(my $fh, $rdr, $fd)) {
 623                                         $self->{$i} = $fh;
 624                                 } else {
 625                                         say $sock "open($rdr$fd) (FD=$i): $!";
 626                                         return;
 627                                 }
 628                         } else {
 629                                 say $sock "recv FD=$i: $!";
 630                                 return;
 631                         }
 632                 } else {
 633                         say $sock "timed out waiting to recv FD=$i";
 634                         return;
 635                 }
 636         }
 637         # $ARGV_STR = join("]\0[", @ARGV);
 638         # $ENV_STR = join('', map { "$_=$ENV{$_}\0" } keys %ENV);
 639         # $line = "$$\0\0>$ARGV_STR\0\0>$ENV_STR\0\0";
 640         my ($client_pid, $argv, $env) = do {
 641                 local $/ = "\0\0\0"; # yes, 3 NULs at EOL, not 2
 642                 chomp(my $line = <$sock>);
 643                 split(/\0\0>/, $line, 3);
 644         };
 645         my %env = map { split(/=/, $_, 2) } split(/\0/, $env);
 646         if (chdir($env{PWD})) {
 647                 $self->{env} = \%env;
 648                 $self->{pid} = $client_pid;
 649                 eval { dispatch($self, split(/\]\0\[/, $argv)) };
 650                 say $sock $@ if $@;
 651         } else {
 652                 say $sock "chdir($env{PWD}): $!"; # implicit close
 653         }
 654 }
 655
 656 sub noop {}
 657
 658 # lei(1) calls this when it can't connect
 659 sub lazy_start {
 660         my ($path, $errno) = @_;
 661         if ($errno == ECONNREFUSED) {
 662                 unlink($path) or die "unlink($path): $!";
 663         } elsif ($errno != ENOENT) {
 664                 $! = $errno; # allow interpolation to stringify in die
 665                 die "connect($path): $!";
 666         }
 667         umask(077) // die("umask(077): $!");
 668         socket(my $l, AF_UNIX, SOCK_STREAM, 0) or die "socket: $!";
 669         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 670         listen($l, 1024) or die "listen: $!";
 671         my @st = stat($path) or die "stat($path): $!";
 672         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 673         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 674         my $oldset = PublicInbox::Sigfd::block_signals();
 675         $recv_fd = PublicInbox::Spawn->can('recv_fd') or die
 676                 "Inline::C not installed/configured or IO::FDPass missing\n";
 677         require PublicInbox::Listener;
 678         require PublicInbox::EOFpipe;
 679         (-p STDOUT) or die "E: stdout must be a pipe\n";
 680         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 681         POSIX::setsid() > 0 or die "setsid: $!";
 682         my $pid = fork // die "fork: $!";
 683         return if $pid;
 684         $0 = "lei-daemon $path";
 685         local %PATH2CFG;
 686         $_->blocking(0) for ($l, $eof_r, $eof_w);
 687         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 688         my $exit_code;
 689         local $quit = sub {
 690                 $exit_code //= shift;
 691                 my $listener = $l or exit($exit_code);
 692                 unlink($path) if defined($path);
 693                 # closing eof_w triggers \&noop wakeup
 694                 $eof_w = $l = $path = undef;
 695                 $listener->close; # DS::close
 696                 PublicInbox::DS->SetLoopTimeout(1000);
 697         };
 698         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 699         my $sig = {
 700                 CHLD => \&PublicInbox::DS::enqueue_reap,
 701                 QUIT => $quit,
 702                 INT => $quit,
 703                 TERM => $quit,
 704                 HUP => \&noop,
 705                 USR1 => \&noop,
 706                 USR2 => \&noop,
 707         };
 708         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 709         local %SIG = (%SIG, %$sig) if !$sigfd;
 710         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 711                 PublicInbox::DS->SetLoopTimeout(5000);
 712         } else {
 713                 # wake up every second to accept signals if we don't
 714                 # have signalfd or IO::KQueue:
 715                 PublicInbox::Sigfd::sig_setmask($oldset);
 716                 PublicInbox::DS->SetLoopTimeout(1000);
 717         }
 718         PublicInbox::DS->SetPostLoopCallback(sub {
 719                 my ($dmap, undef) = @_;
 720                 if (@st = defined($path) ? stat($path) : ()) {
 721                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 722                                 warn "$path dev/ino changed, quitting\n";
 723                                 $path = undef;
 724                         }
 725                 } elsif (defined($path)) {
 726                         warn "stat($path): $!, quitting ...\n";
 727                         undef $path; # don't unlink
 728                         $quit->();
 729                 }
 730                 return 1 if defined($path);
 731                 my $now = now();
 732                 my $n = 0;
 733                 for my $s (values %$dmap) {
 734                         $s->can('busy') or next;
 735                         if ($s->busy($now)) {
 736                                 ++$n;
 737                         } else {
 738                                 $s->close;
 739                         }
 740                 }
 741                 $n; # true: continue, false: stop
 742         });
 743
 744         # STDIN was redirected to /dev/null above, closing STDERR and
 745         # STDOUT will cause the calling `lei' client process to finish
 746         # reading the <$daemon> pipe.
 747         openlog($path, 'pid', 'user');
 748         local $SIG{__WARN__} = sub { syslog('warning', "@_") };
 749         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 750                 syslog('crit', "$@") if $@;
 751         });
 752         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 753         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 754         # $daemon pipe to `lei' closed, main loop begins:
 755         PublicInbox::DS->EventLoop;
 756         @$on_destroy = (); # cancel on_destroy if we get here
 757         exit($exit_code // 0);
 758 }
 759
 760 # for users w/o IO::FDPass
 761 sub oneshot {
 762         my ($main_pkg) = @_;
 763         my $exit = $main_pkg->can('exit'); # caller may override exit()
 764         local $quit = $exit if $exit;
 765         local %PATH2CFG;
 766         umask(077) // die("umask(077): $!");
 767         dispatch((bless {
 768                 0 => *STDIN{IO},
 769                 1 => *STDOUT{IO},
 770                 2 => *STDERR{IO},
 771                 env => \%ENV
 772         }, __PACKAGE__), @ARGV);
 773 }
 774
 775 1;