lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use Time::HiRes qw(stat); # ctime comparisons for config cache
  28 use File::Path qw(mkpath);
  29 use File::Spec;
  30 our $quit = \&CORE::exit;
  31 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle);
  32 my ($recv_cmd, $send_cmd);
  33 my $GLP = Getopt::Long::Parser->new;
  34 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  35 my $GLP_PASS = Getopt::Long::Parser->new;
  36 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  37
  38 our %PATH2CFG; # persistent for socket daemon
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 # rel2abs preserves symlinks in parent, unlike abs_path
  69 sub rel2abs {
  70         my ($self, $p) = @_;
  71         if (index($p, '/') == 0) { # already absolute
  72                 $p =~ tr!/!/!s; # squeeze redundant slashes
  73                 chop($p) if substr($p, -1, 1) eq '/';
  74                 return $p;
  75         }
  76         my $pwd = $self->{env}->{PWD};
  77         my $cwd;
  78         if (defined $pwd) {
  79                 my $xcwd = $self->{3} //
  80                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  81                 if (my @st_pwd = stat($pwd)) {
  82                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  83                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  84                                 $self->{env}->{PWD} = $pwd = undef;
  85                 } else { # PWD was invalid
  86                         $self->{env}->{PWD} = $pwd = undef;
  87                 }
  88         }
  89         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  90         File::Spec->rel2abs($p, $pwd);
  91 }
  92
  93 # abs_path resolves symlinks in parent iff all parents exist
  94 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  95
  96 sub share_path ($) { # $HOME/.local/share/lei/$FOO
  97         my ($self) = @_;
  98         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
  99                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 100                 .'/lei');
 101 }
 102
 103 sub store_path ($) { share_path($_[0]) . '/store' }
 104
 105 sub _config_path ($) {
 106         my ($self) = @_;
 107         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 108                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 109                 .'/lei/config');
 110 }
 111
 112 sub cache_dir ($) {
 113         my ($self) = @_;
 114         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 115                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 116                 .'/lei');
 117 }
 118
 119 sub ale {
 120         my ($self) = @_;
 121         $self->{ale} //= do {
 122                 require PublicInbox::LeiALE;
 123                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 124         };
 125 }
 126
 127 sub index_opt {
 128         # TODO: drop underscore variants everywhere, they're undocumented
 129         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 130         max_size|max-size=s sequential_shard|sequential-shard
 131         batch_size|batch-size=s skip-docdata)
 132 }
 133
 134 my @c_opt = qw(c=s@ C=s@ quiet|q);
 135 my @lxs_opt = (qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 136         import-remote! no-torsocks torsocks=s),
 137         PublicInbox::LeiQuery::curl_opt());
 138
 139 # we don't support -C as an alias for --find-copies since it's already
 140 # used for chdir
 141 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 142         output-indicator-context=s indent-heuristic!
 143         minimal patience histogram anchored=s@ diff-algorithm=s
 144         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 145         word-diff:s word-diff-regex=s color-words:s no-renames
 146         rename-empty! check ws-error-highlight=s full-index binary
 147         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 148         find-copies-harder irreversible-delete|D l=i diff-filter=s
 149         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 150         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 151         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 152         inter-hunk-context=i function-context|W exit-code ext-diff
 153         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 154         line-prefix=s);
 155
 156 # we generate shell completion + help using %CMD and %OPTDESC,
 157 # see lei__complete() and PublicInbox::LeiHelp
 158 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 159 our %CMD = ( # sorted in order of importance/use:
 160 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 161         'stdin|', # /|\z/ must be first for lone dash
 162         @lxs_opt,
 163         qw(save output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 164         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 165         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 166         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 167
 168 'up' => [ 'OUTPUT|--all', 'update saved search',
 169         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+ all:s), @c_opt ],
 170
 171 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 172         'stdin|', # /|\z/ must be first for lone dash
 173         # some of these options are ridiculous for lcat
 174         @lxs_opt, qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 175         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 176         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 177         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 178
 179 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 180         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 181         @lxs_opt, @c_opt ],
 182
 183 'rediff' => [ '--stdin|LOCATION...',
 184                 'regenerate a diff with different options',
 185         'stdin|', # /|\z/ must be first for lone dash
 186         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 187         @diff_opt, @lxs_opt, @c_opt ],
 188
 189 'add-external' => [ 'LOCATION',
 190         'add/set priority of a publicinbox|extindex for extra matches',
 191         qw(boost=i mirror=s no-torsocks torsocks=s inbox-version=i
 192         verbose|v+), @c_opt, index_opt(),
 193         PublicInbox::LeiQuery::curl_opt() ],
 194 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 195         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 196 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 197 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 198                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 199 'forget-external' => [ 'LOCATION...|--prune',
 200         'exclude further results from a publicinbox|extindex',
 201         qw(prune), @c_opt ],
 202
 203 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 204                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 205 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 206                 qw(verbose|v+), @c_opt ],
 207 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 208                         @c_opt ],
 209 'rm' => [ '--stdin|LOCATION...',
 210         'remove a message from the index and prevent reindexing',
 211         'stdin|', # /|\z/ must be first for lone dash
 212         @c_opt ],
 213 'plonk' => [ '--threads|--from=IDENT',
 214         'exclude mail matching From: or threads from non-Message-ID searches',
 215         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 216 'tag' => [ 'KEYWORDS...',
 217         'set/unset keywords and/or labels on message(s)',
 218         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 219         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt,
 220         pass_through('-kw:foo for delete') ],
 221
 222 'purge-mailsource' => [ 'LOCATION|--all',
 223         'remove imported messages from IMAP, Maildirs, and MH',
 224         qw(exact! all jobs:i indexed), @c_opt ],
 225
 226 'add-watch' => [ 'LOCATION', 'watch for new messages and flag changes',
 227         qw(import! kw! interval=s recursive|r
 228         exclude=s include=s), @c_opt ],
 229 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 230                 qw(format|f=s z), @c_opt ],
 231 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 232 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 233 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 234         qw(prune), @c_opt ],
 235
 236 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 237         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 238         verbose|v+ incremental!),
 239          PublicInbox::LeiQuery::curl_opt(), # mainly for --proxy=
 240          @c_opt ],
 241 'import' => [ 'LOCATION...|--stdin',
 242         'one-time import/update from URL or filesystem',
 243         qw(stdin| offset=i recursive|r exclude=s include|I=s
 244         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 245         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 246 'forget-mail-sync' => [ 'LOCATION...',
 247         'forget sync information for a mail folder', @c_opt ],
 248 'export-kw' => [ 'LOCATION...|--all',
 249         'one-time export of keywords of sync sources',
 250         qw(all:s mode=s), @c_opt ],
 251 'convert' => [ 'LOCATION...|--stdin',
 252         'one-time conversion from URL or filesystem to another format',
 253         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 254         qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt(), @c_opt ],
 255 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 256         "use a patch to generate a query for `lei q --stdin'",
 257         qw(stdin| want|w=s@ uri debug), @c_opt ],
 258 'config' => [ '[...]', sub {
 259                 'git-config(1) wrapper for '._config_path($_[0]);
 260         }, qw(config-file|system|global|file|f=s), # for conflict detection
 261          qw(c=s@ C=s@), pass_through('git config') ],
 262 'inspect' => [ 'ITEMS...', 'inspect lei/store and/or local external',
 263         qw(pretty ascii dir=s), @c_opt ],
 264
 265 'init' => [ '[DIRNAME]', sub {
 266         "initialize storage, default: ".store_path($_[0]);
 267         }, @c_opt ],
 268 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 269         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 270         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 271 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 272 'help' => [ '[SUBCOMMAND]', 'show help' ],
 273
 274 # TODO
 275 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 276 #       'rewrite git history in an attempt to improve compression',
 277 #       qw(gc!), @c_opt ],
 278 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 279 #
 280 # internal commands are prefixed with '_'
 281 '_complete' => [ '[...]', 'internal shell completion helper',
 282                 pass_through('everything') ],
 283 ); # @CMD
 284
 285 # switch descriptions, try to keep consistent across commands
 286 # $spec: Getopt::Long option specification
 287 # $spec => [@ALLOWED_VALUES (default is first), $description],
 288 # $spec => $description
 289 # "$SUB_COMMAND TAB $spec" => as above
 290 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 291                         'specify message input format' ];
 292 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 293
 294 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 295 my %OPTDESC = (
 296 'help|h' => 'show this built-in help',
 297 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 298 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 299 'quiet|q' => 'be quiet',
 300 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 301         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 302
 303 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 304 'globoff|g' => "do not match locations using '*?' wildcards ".
 305                 "and\xa0'[]'\x{a0}ranges",
 306 'invert-match|v' => 'select non-matching lines',
 307 'color!' => 'disable color (for --format=text)',
 308 'verbose|v+' => 'be more verbose',
 309 'external!' => 'do not use externals',
 310 'mail!' => 'do not look in mail storage for OID',
 311 'cwd!' => 'do not look in git repo of current working directory',
 312 'oid-a|A=s' => 'pre-image OID',
 313 'path-a|a=s' => 'pre-image pathname associated with OID',
 314 'path-b|b=s' => 'post-image pathname associated with OID',
 315 'git-dir=s@' => 'additional git repository to scan',
 316 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 317         "proxy for (e.g. `socks5h://0:9050')" ],
 318 'torsocks=s' => ['VAL|auto|no|yes',
 319                 'whether or not to wrap git and curl commands with torsocks'],
 320 'no-torsocks' => 'alias for --torsocks=no',
 321 'save' =>  "save a search for `lei up'",
 322 'import-remote!' => 'do not memoize remote messages into local store',
 323
 324 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 325
 326 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 327                 'deduplication strategy'],
 328 'threads|t+' =>
 329         'return all messages in the same threads as the actual match(es)',
 330
 331 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 332                 'search prefixes to extract (default: dfpost7)' ],
 333
 334 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 335         'run command(s) or perform ops when done writing to output ' .
 336         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 337         'nothing otherwise)' ],
 338
 339 'augment|a' => 'augment --output destination instead of clobbering',
 340
 341 'output|mfolder|o=s' => [ 'MFOLDER',
 342         "destination (e.g.\xa0`/path/to/Maildir', ".
 343         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 344 'mua=s' => [ 'CMD',
 345         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 346
 347 'inbox-version=i' => [ 'NUM|1|2',
 348                 'force a public-inbox version with --mirror'],
 349 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 350
 351 # public-inbox-index options
 352 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 353 'compact' => 'run compact index after mirroring',
 354 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 355         "indexlevel with --mirror (default: full)" ],
 356 'max_size|max-size=s' => [ 'SIZE',
 357         'do not index messages larger than SIZE (default: infinity)' ],
 358 'batch_size|batch-size=s' => [ 'SIZE',
 359         'flush changes to OS after given number of bytes (default: 1m)' ],
 360 'sequential_shard|sequential-shard' =>
 361         'index Xapian shards sequentially for slow storage',
 362 'skip-docdata' =>
 363         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 364
 365 'format|f=s     q' => [
 366         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 367                 'specify output format, default depends on --output'],
 368 'exclude=s@     q' => [ 'LOCATION',
 369                 'exclude specified external(s) from search' ],
 370 'include|I=s@   q' => [ 'LOCATION',
 371                 'include specified external(s) in search' ],
 372 'only=s@        q' => [ 'LOCATION',
 373                 'only use specified external(s) for search' ],
 374 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 375                 'control number of search and writer jobs' ],
 376 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 377
 378 'in-format|F=s' => $stdin_formats,
 379 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 380                         'listing output format' ],
 381 'l      ls-search' => 'long listing format',
 382 'format|f=s     ls-external' => $ls_format,
 383
 384 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 385 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 386
 387 'sort|s=s' => [ 'VAL|received|relevance|docid',
 388                 "order of results is `--output'-dependent"],
 389 'reverse|r' => 'reverse search results', # like sort(1)
 390
 391 'boost=i' => 'increase/decrease priority of results (default: 0)',
 392
 393 'local' => 'limit operations to the local filesystem',
 394 'local!' => 'exclude results from the local filesystem',
 395 'remote' => 'limit operations to those requiring network access',
 396 'remote!' => 'prevent operations requiring network access',
 397
 398 'all:s  up' => ['local', 'update all (local) saved searches' ],
 399
 400 'mid=s' => 'specify the Message-ID of a message',
 401 'oid=s' => 'specify the git object ID of a message',
 402
 403 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 404 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 405 'include=s' => 'include mailboxes/newsgroups based on pattern',
 406
 407 'exact' => 'operate on exact header matches only',
 408 'exact!' => 'rely on content match instead of exact header matches',
 409
 410 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 411
 412 'kw!' => 'disable/enable importing keywords (aka "flags")',
 413
 414 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 415 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 416
 417 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 418 ); # %OPTDESC
 419
 420 my %CONFIG_KEYS = (
 421         'leistore.dir' => 'top-level storage location',
 422 );
 423
 424 my @WQ_KEYS = qw(lxs l2m wq1 ikw); # internal workers
 425
 426 sub _drop_wq {
 427         my ($self) = @_;
 428         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 429                 if ($wq->wq_kill) {
 430                         $wq->wq_close(0, undef, $self);
 431                 } elsif ($wq->wq_kill_old) {
 432                         $wq->wq_wait_old(undef, $self);
 433                 }
 434                 $wq->DESTROY;
 435         }
 436 }
 437
 438 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 439 sub x_it ($$) {
 440         my ($self, $code) = @_;
 441         # make sure client sees stdout before exit
 442         $self->{1}->autoflush(1) if $self->{1};
 443         dump_and_clear_log();
 444         if ($self->{pkt_op_p}) { # to top lei-daemon
 445                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 446         } elsif ($self->{sock}) { # to lei(1) client
 447                 send($self->{sock}, "x_it $code", MSG_EOR);
 448         } # else ignore if client disconnected
 449 }
 450
 451 sub err ($;@) {
 452         my $self = shift;
 453         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 454         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 455         print $err @_, @eor and return;
 456         my $old_err = delete $self->{2};
 457         close($old_err) if $! == EPIPE && $old_err;
 458         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 459         print $err @_, @eor or print STDERR @_, @eor;
 460 }
 461
 462 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 463
 464 sub fail_handler ($;$$) {
 465         my ($lei, $code, $io) = @_;
 466         close($io) if $io; # needed to avoid warnings on SIGPIPE
 467         _drop_wq($lei);
 468         x_it($lei, $code // (1 << 8));
 469 }
 470
 471 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 472         fail_handler($_[0], 13, delete $_[0]->{1});
 473 }
 474
 475 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 476 sub sigint_reap {
 477         my ($pgid) = @_;
 478         dwaitpid($pgid) if kill('-INT', $pgid);
 479 }
 480
 481 sub fail ($$;$) {
 482         my ($self, $buf, $exit_code) = @_;
 483         $self->{failed}++;
 484         err($self, $buf) if defined $buf;
 485         # calls fail_handler:
 486         $self->{pkt_op_p}->pkt_do('!') if $self->{pkt_op_p};
 487         x_it($self, ($exit_code // 1) << 8);
 488         undef;
 489 }
 490
 491 sub out ($;@) {
 492         my $self = shift;
 493         return if print { $self->{1} // return } @_; # likely
 494         return note_sigpipe($self, 1) if $! == EPIPE;
 495         my $err = "error writing to output: $!";
 496         delete $self->{1};
 497         fail($self, $err);
 498 }
 499
 500 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 501
 502 sub child_error { # passes non-fatal curl exit codes to user
 503         my ($self, $child_error, $msg) = @_; # child_error is $?
 504         $self->err($msg) if $msg;
 505         if ($self->{pkt_op_p}) { # to top lei-daemon
 506                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 507         } elsif ($self->{sock}) { # to lei(1) client
 508                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 509         } # else noop if client disconnected
 510 }
 511
 512 sub note_sigpipe { # triggers sigpipe_handler
 513         my ($self, $fd) = @_;
 514         close(delete($self->{$fd})); # explicit close silences Perl warning
 515         $self->{pkt_op_p}->pkt_do('|') if $self->{pkt_op_p};
 516         x_it($self, 13);
 517 }
 518
 519 sub _lei_atfork_child {
 520         my ($self, $persist) = @_;
 521         # we need to explicitly close things which are on stack
 522         if ($persist) {
 523                 chdir '/' or die "chdir(/): $!";
 524                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 525                 if (my $cfg = $self->{cfg}) {
 526                         delete $cfg->{-lei_store};
 527                 }
 528         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 529                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 530                 STDERR->autoflush(1);
 531         }
 532         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 533         if (my $op_c = delete $self->{pkt_op_c}) {
 534                 close(delete $op_c->{sock});
 535         }
 536         if (my $pgr = delete $self->{pgr}) {
 537                 close($_) for (@$pgr[1,2]);
 538         }
 539         close $listener if $listener;
 540         undef $listener;
 541         undef $dir_idle;
 542         %PATH2CFG = ();
 543         undef $errors_log;
 544         $quit = \&CORE::exit;
 545         $self->{-eml_noisy} or # only "lei import" sets this atm
 546                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 547         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 548 }
 549
 550 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 551         my ($self) = @_;
 552         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 553                 $op->close; # PublicInbox::PktOp::close
 554         }
 555         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 556         close $pkt_op_p->{op_p};
 557 }
 558
 559 sub pkt_op_pair {
 560         my ($self) = @_;
 561         require PublicInbox::OnDestroy;
 562         require PublicInbox::PktOp;
 563         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 564         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 565         $end;
 566 }
 567
 568 sub workers_start {
 569         my ($lei, $wq, $jobs, $ops) = @_;
 570         $ops = {
 571                 '!' => [ \&fail_handler, $lei ],
 572                 '|' => [ \&sigpipe_handler, $lei ],
 573                 'x_it' => [ \&x_it, $lei ],
 574                 'child_error' => [ \&child_error, $lei ],
 575                 ($ops ? %$ops : ()),
 576         };
 577         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 578         my $end = $lei->pkt_op_pair;
 579         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 580         $wq->wq_workers_start($ident, $jobs, $lei->oldset, { lei => $lei });
 581         delete $lei->{pkt_op_p};
 582         my $op_c = delete $lei->{pkt_op_c};
 583         # {-lei_sock} persists script/lei process until ops->{''} EOF callback
 584         $op_c->{-lei_sock} = $lei->{sock};
 585         @$end = ();
 586         $lei->event_step_init;
 587         ($op_c, $ops);
 588 }
 589
 590 sub _help {
 591         require PublicInbox::LeiHelp;
 592         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 593 }
 594
 595 sub optparse ($$$) {
 596         my ($self, $cmd, $argv) = @_;
 597         # allow _complete --help to complete, not show help
 598         return 1 if substr($cmd, 0, 1) eq '_';
 599         $self->{cmd} = $cmd;
 600         $OPT = $self->{opt} //= {};
 601         my $info = $CMD{$cmd} // [ '[...]' ];
 602         my ($proto, undef, @spec) = @$info;
 603         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 604         push @spec, qw(help|h);
 605         my $lone_dash;
 606         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 607                 $lone_dash = $spec[0];
 608                 $OPT->{$spec[0]} = \(my $var);
 609                 push @spec, '' => \$var;
 610         }
 611         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 612                 return _help($self, "bad arguments or options for $cmd");
 613         return _help($self) if $OPT->{help};
 614
 615         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 616
 617         # "-" aliases "stdin" or "clear"
 618         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 619
 620         my $i = 0;
 621         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 622         my ($err, $inf);
 623         my @args = split(/ /, $proto);
 624         for my $var (@args) {
 625                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 626                         $inf = defined($argv->[$i]) and last;
 627                         $var =~ s/\.\.\.\z//;
 628                         $err = "$var not supplied";
 629                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 630                         $argv->[$i++] // ($err = "$var not supplied");
 631                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 632                         $inf = 1;
 633                         last;
 634                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 635                         $i++;
 636                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 637                         $inf = 1 if index($var, '...') > 0;
 638                         my @or = split(/\|/, $var);
 639                         my $ok;
 640                         for my $o (@or) {
 641                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 642                                         my $sw = $1;
 643                                         # assume pipe/regular file on stdin
 644                                         # w/o args means stdin
 645                                         if ($sw eq 'stdin' && !@$argv &&
 646                                                         (-p $self->{0} ||
 647                                                          -f _) && -r _) {
 648                                                 $OPT->{stdin} //= 1;
 649                                         }
 650                                         $ok = defined($OPT->{$sw});
 651                                         last if $ok;
 652                                 } elsif (defined($argv->[$i])) {
 653                                         $ok = 1;
 654                                         $i++;
 655                                         last;
 656                                 } # else continue looping
 657                         }
 658                         last if $ok;
 659                         my $last = pop @or;
 660                         $err = join(', ', @or) . " or $last must be set";
 661                 } else {
 662                         warn "BUG: can't parse `$var' in $proto";
 663                 }
 664                 last if $err;
 665         }
 666         if (!$inf && scalar(@$argv) > scalar(@args)) {
 667                 $err //= 'too many arguments';
 668         }
 669         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 670 }
 671
 672 sub _tmp_cfg { # for lei -c <name>=<value> ...
 673         my ($self) = @_;
 674         my $cfg = _lei_cfg($self, 1);
 675         require File::Temp;
 676         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 677         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 678         $ft->autoflush(1);
 679         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 680 [include]
 681         path = $cfg->{-f}
 682 EOM
 683         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 684         for (@{$self->{opt}->{c}}) {
 685                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 686 `-c $_' is not of the form -c <name>=<value>'
 687 EOM
 688                 my $name = $1;
 689                 my $value = $2 // 1;
 690                 _config($self, '--add', $name, $value);
 691                 if (defined(my $v = $tmp->{$name})) {
 692                         if (ref($v) eq 'ARRAY') {
 693                                 push @$v, $value;
 694                         } else {
 695                                 $tmp->{$name} = [ $v, $value ];
 696                         }
 697                 } else {
 698                         $tmp->{$name} = $value;
 699                 }
 700         }
 701 }
 702
 703 sub lazy_cb ($$$) {
 704         my ($self, $cmd, $pfx) = @_;
 705         my $ucmd = $cmd;
 706         $ucmd =~ tr/-/_/;
 707         my $cb;
 708         $cb = $self->can($pfx.$ucmd) and return $cb;
 709         my $base = $ucmd;
 710         $base =~ s/_([a-z])/\u$1/g;
 711         my $pkg = "PublicInbox::Lei\u$base";
 712         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 713                 $pkg->can($pfx.$ucmd) : undef;
 714 }
 715
 716 sub dispatch {
 717         my ($self, $cmd, @argv) = @_;
 718         local $current_lei = $self; # for __WARN__
 719         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 720         dump_and_clear_log("from previous run\n");
 721         return _help($self, 'no command given') unless defined($cmd);
 722         # do not support Getopt bundling for this
 723         while ($cmd eq '-C' || $cmd eq '-c') {
 724                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 725                                         '-C DIRECTORY' : '-c <name>=<value>');
 726                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 727                 $cmd = shift(@argv) // return _help($self, 'no command given');
 728         }
 729         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 730                 optparse($self, $cmd, \@argv) or return;
 731                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 732                 if (my $chdir = $self->{opt}->{C}) {
 733                         for my $d (@$chdir) {
 734                                 next if $d eq ''; # same as git(1)
 735                                 chdir $d or return fail($self, "cd $d: $!");
 736                         }
 737                         if (delete $self->{3}) { # update cwd for rel2abs
 738                                 opendir my $dh, '.' or
 739                                         return fail($self, "opendir . $!");
 740                                 $self->{3} = $dh;
 741                         }
 742                 }
 743                 $cb->($self, @argv);
 744         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 745                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 746                         or return _help($self, 'bad arguments or options');
 747                 _help($self);
 748         } else {
 749                 fail($self, "`$cmd' is not an lei command");
 750         }
 751 }
 752
 753 sub _lei_cfg ($;$) {
 754         my ($self, $creat) = @_;
 755         return $self->{cfg} if $self->{cfg};
 756         my $f = _config_path($self);
 757         my @st = stat($f);
 758         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 759         my ($sto, $sto_dir);
 760         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 761                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 762                 ($sto, $sto_dir) = @$cfg{qw(-lei_store leistore.dir)};
 763         }
 764         if (!@st) {
 765                 unless ($creat) {
 766                         delete $self->{cfg};
 767                         return bless {}, 'PublicInbox::Config';
 768                 }
 769                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 770                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 771                 open my $fh, '>>', $f or die "open($f): $!\n";
 772                 @st = stat($fh) or die "fstat($f): $!\n";
 773                 $cur_st = pack('dd', $st[10], $st[7]);
 774                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 775         }
 776         my $cfg = PublicInbox::Config->git_config_dump($f);
 777         $cfg->{-st} = $cur_st;
 778         $cfg->{'-f'} = $f;
 779         if ($sto && File::Spec->canonpath($sto_dir // store_path($self))
 780                         eq File::Spec->canonpath($cfg->{'leistore.dir'} //
 781                                                 store_path($self))) {
 782                 $cfg->{-lei_store} = $sto;
 783         }
 784         if (scalar(keys %PATH2CFG) > 5) {
 785                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 786                 for my $k (keys %PATH2CFG) {
 787                         delete($PATH2CFG{$k}) unless -f $k
 788                 }
 789         }
 790         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 791 }
 792
 793 sub _lei_store ($;$) {
 794         my ($self, $creat) = @_;
 795         my $cfg = _lei_cfg($self, $creat);
 796         $cfg->{-lei_store} //= do {
 797                 require PublicInbox::LeiStore;
 798                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 799                 return unless $creat || -d $dir;
 800                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 801         };
 802 }
 803
 804 sub _config {
 805         my ($self, @argv) = @_;
 806         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 807         my $cfg = _lei_cfg($self, 1);
 808         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 809         my %rdr = map { $_ => $self->{$_} } (0..2);
 810         waitpid(spawn($cmd, \%env, \%rdr), 0);
 811 }
 812
 813 sub lei_config {
 814         my ($self, @argv) = @_;
 815         $self->{opt}->{'config-file'} and return fail $self,
 816                 "config file switches not supported by `lei config'";
 817         _config(@_);
 818         x_it($self, $?) if $?;
 819 }
 820
 821 sub lei_daemon_pid { puts shift, $$ }
 822
 823 sub lei_daemon_kill {
 824         my ($self) = @_;
 825         my $sig = $self->{opt}->{signal} // 'TERM';
 826         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 827 }
 828
 829 # Shell completion helper.  Used by lei-completion.bash and hopefully
 830 # other shells.  Try to do as much here as possible to avoid redundancy
 831 # and improve maintainability.
 832 sub lei__complete {
 833         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 834         shift @argv; # ignore "lei", the entire command is sent
 835         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 836         my $cmd = shift @argv;
 837         my $info = $CMD{$cmd} // do { # filter matching commands
 838                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 839                 return;
 840         };
 841         my ($proto, undef, @spec) = @$info;
 842         my $cur = pop @argv;
 843         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 844         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 845                 # gross special case since the only git-config options
 846                 # Consider moving to a table if we need more special cases
 847                 # we use Getopt::Long for are the ones we reject, so these
 848                 # are the ones we don't reject:
 849                 if ($cmd eq 'config') {
 850                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 851                         @spec = qw(add z|null get get-all unset unset-all
 852                                 replace-all get-urlmatch
 853                                 remove-section rename-section
 854                                 name-only list|l edit|e
 855                                 get-color-name get-colorbool);
 856                         # fall-through
 857                 }
 858                 # generate short/long names from Getopt::Long specs
 859                 puts $self, grep(/$re/, qw(--help -h -C), map {
 860                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 861                         } elsif (s/\+\z//) { # verbose|v+
 862                         } elsif (s/!\z//) {
 863                                 # negation: mail! => no-mail|mail
 864                                 s/([\w\-]+)/$1|no-$1/g
 865                         }
 866                         map {
 867                                 my $x = length > 1 ? "--$_" : "-$_";
 868                                 $x eq $_cur ? () : $x;
 869                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 870                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 871         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 872                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 873         }
 874
 875         # switch args (e.g. lei q -f mbox<TAB>)
 876         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 877                 my $opt = quotemeta $1;
 878                 puts $self, map {
 879                         my $v = $OPTDESC{$_};
 880                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 881                         # get rid of ALL CAPS placeholder (e.g "OUT")
 882                         # (TODO: completion for external paths)
 883                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 884                         @v;
 885                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 886         }
 887         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 888                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 889         }
 890         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 891         # proto parsing.
 892 }
 893
 894 sub exec_buf ($$) {
 895         my ($argv, $env) = @_;
 896         my $argc = scalar @$argv;
 897         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 898         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 899         $buf;
 900 }
 901
 902 sub start_mua {
 903         my ($self) = @_;
 904         my $mua = $self->{opt}->{mua} // return;
 905         my $mfolder = $self->{ovv}->{dst};
 906         my (@cmd, $replaced);
 907         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 908                 @cmd = ($mua, '-f');
 909         # TODO: help wanted: other common FOSS MUAs
 910         } else {
 911                 require Text::ParseWords;
 912                 @cmd = Text::ParseWords::shellwords($mua);
 913                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 914                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 915         }
 916         push @cmd, $mfolder unless defined($replaced);
 917         if ($self->{sock}) { # lei(1) client process runs it
 918                 # restore terminal: echo $query | lei q --stdin --mua=...
 919                 my $io = [];
 920                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 921                 send_exec_cmd($self, $io, \@cmd, {});
 922         }
 923         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 924                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 925         }
 926         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 927         $self->{opt}->{quiet} = 1;
 928         delete $self->{-progress};
 929         delete $self->{opt}->{verbose};
 930 }
 931
 932 sub send_exec_cmd { # tell script/lei to execute a command
 933         my ($self, $io, $cmd, $env) = @_;
 934         my $sock = $self->{sock} // die 'lei client gone';
 935         my $fds = [ map { fileno($_) } @$io ];
 936         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 937 }
 938
 939 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 940         my ($self) = @_;
 941         my $alerts = $self->{opt}->{alert} // return;
 942         my $sock = $self->{sock};
 943         while (my $op = shift(@$alerts)) {
 944                 if ($op eq ':WINCH') {
 945                         # hit the process group that started the MUA
 946                         send($sock, '-WINCH', MSG_EOR) if $sock;
 947                 } elsif ($op eq ':bell') {
 948                         out($self, "\a");
 949                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
 950                         push @$alerts, split(/(?<!\\),/, $op);
 951                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
 952                         my $cmd = $1; # run an arbitrary command
 953                         require Text::ParseWords;
 954                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
 955                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
 956                 } else {
 957                         err($self, "W: unsupported --alert=$op"); # non-fatal
 958                 }
 959         }
 960 }
 961
 962 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
 963 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
 964
 965 # this also normalizes the path
 966 sub path_to_fd {
 967         my ($self, $path) = @_;
 968         $path = rel2abs($self, $path);
 969         $path =~ tr!/!/!s;
 970         $path_to_fd{$path} // (
 971                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
 972                         fail($self, "cannot open $path from daemon") : -1
 973         );
 974 }
 975
 976 # caller needs to "-t $self->{1}" to check if tty
 977 sub start_pager {
 978         my ($self) = @_;
 979         my $fh = popen_rd([qw(git var GIT_PAGER)]);
 980         chomp(my $pager = <$fh> // '');
 981         close($fh) or warn "`git var PAGER' error: \$?=$?";
 982         return if $pager eq 'cat' || $pager eq '';
 983         my $new_env = { LESS => 'FRX', LV => '-c' };
 984         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 985         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 986         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 987         my $pgr = [ undef, @$rdr{1, 2} ];
 988         my $env = $self->{env};
 989         if ($self->{sock}) { # lei(1) process runs it
 990                 delete @$new_env{keys %$env}; # only set iff unset
 991                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
 992         } else {
 993                 die 'BUG: start_pager w/o socket';
 994         }
 995         $self->{1} = $wpager;
 996         $self->{2} = $wpager if -t $self->{2};
 997         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 998         $self->{pgr} = $pgr;
 999 }
1000
1001 sub stop_pager {
1002         my ($self) = @_;
1003         my $pgr = delete($self->{pgr}) or return;
1004         $self->{2} = $pgr->[2];
1005         # do not restore original stdout, just close it so we error out
1006         close(delete($self->{1})) if $self->{1};
1007 }
1008
1009 sub accept_dispatch { # Listener {post_accept} callback
1010         my ($sock) = @_; # ignore other
1011         $sock->autoflush(1);
1012         my $self = bless { sock => $sock }, __PACKAGE__;
1013         vec(my $rvec = '', fileno($sock), 1) = 1;
1014         select($rvec, undef, undef, 60) or
1015                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1016         # (4096 * 33) >MAX_ARG_STRLEN
1017         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1018         if (!defined($fds[0])) {
1019                 warn(my $msg = "recv_cmd failed: $!");
1020                 return send($sock, $msg, MSG_EOR);
1021         } else {
1022                 my $i = 0;
1023                 for my $fd (@fds) {
1024                         open($self->{$i++}, '+<&=', $fd) and next;
1025                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1026                 }
1027                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1028         }
1029         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1030         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1031         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1032                 return send($sock, 'request command truncated', MSG_EOR);
1033         my ($argc, @argv) = split(/\0/, $buf, -1);
1034         undef $buf;
1035         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1036         if (chdir($self->{3})) {
1037                 local %ENV = %env;
1038                 $self->{env} = \%env;
1039                 eval { dispatch($self, @argv) };
1040                 send($sock, $@, MSG_EOR) if $@;
1041         } else {
1042                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
1043         }
1044 }
1045
1046 sub dclose {
1047         my ($self) = @_;
1048         delete $self->{-progress};
1049         _drop_wq($self) if $self->{failed};
1050         close(delete $self->{1}) if $self->{1}; # may reap_compress
1051         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1052 }
1053
1054 # for long-running results
1055 sub event_step {
1056         my ($self) = @_;
1057         local %ENV = %{$self->{env}};
1058         my $sock = $self->{sock};
1059         local $current_lei = $self;
1060         eval {
1061                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
1062                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1063                                 return if $! == EAGAIN;
1064                                 next if $! == EINTR;
1065                                 last if $! == ECONNRESET;
1066                                 die "recvmsg: $!";
1067                         }
1068                         for my $fd (@fds) {
1069                                 open my $rfh, '+<&=', $fd;
1070                         }
1071                         die "unrecognized client signal: $buf";
1072                 }
1073                 dclose($self);
1074         };
1075         if (my $err = $@) {
1076                 eval { $self->fail($err) };
1077                 dclose($self);
1078         }
1079 }
1080
1081 sub event_step_init {
1082         my ($self) = @_;
1083         return if $self->{-event_init_done}++;
1084         if (my $sock = $self->{sock}) { # using DS->EventLoop
1085                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1086         }
1087 }
1088
1089 sub noop {}
1090
1091 sub oldset { $oldset }
1092
1093 sub dump_and_clear_log {
1094         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1095                 my @pfx = @_;
1096                 unshift(@pfx, "$errors_log ") if @pfx;
1097                 warn @pfx, do { local $/; <STDIN> };
1098                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
1099         }
1100 }
1101
1102 # lei(1) calls this when it can't connect
1103 sub lazy_start {
1104         my ($path, $errno, $narg) = @_;
1105         local ($errors_log, $listener);
1106         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1107         $errors_log = "$sock_dir/errors.log";
1108         my $addr = pack_sockaddr_un($path);
1109         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1110         $lk->lock_acquire;
1111         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1112         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1113                 return if connect($listener, $addr); # another process won
1114                 if ($errno == ECONNREFUSED && -S $path) {
1115                         unlink($path) or die "unlink($path): $!";
1116                 }
1117         } else {
1118                 $! = $errno; # allow interpolation to stringify in die
1119                 die "connect($path): $!";
1120         }
1121         umask(077) // die("umask(077): $!");
1122         bind($listener, $addr) or die "bind($path): $!";
1123         listen($listener, 1024) or die "listen: $!";
1124         $lk->lock_release;
1125         undef $lk;
1126         my @st = stat($path) or die "stat($path): $!";
1127         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1128         local $oldset = PublicInbox::DS::block_signals();
1129         if ($narg == 5) {
1130                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1131                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1132                         require PublicInbox::CmdIPC4;
1133                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1134                         PublicInbox::CmdIPC4->can('recv_cmd4');
1135                 };
1136         }
1137         $recv_cmd or die <<"";
1138 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1139
1140         require PublicInbox::Listener;
1141         require PublicInbox::PktOp;
1142         (-p STDOUT) or die "E: stdout must be a pipe\n";
1143         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1144         STDIN->autoflush(1);
1145         dump_and_clear_log("from previous daemon process:\n");
1146         POSIX::setsid() > 0 or die "setsid: $!";
1147         my $pid = fork // die "fork: $!";
1148         return if $pid;
1149         $0 = "lei-daemon $path";
1150         local %PATH2CFG;
1151         $listener->blocking(0);
1152         my $exit_code;
1153         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1154         local $quit = do {
1155                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1156                 sub {
1157                         $exit_code //= shift;
1158                         my $lis = $pil or exit($exit_code);
1159                         # closing eof_p triggers \&noop wakeup
1160                         $listener = $eof_p = $pil = $path = undef;
1161                         $lis->close; # DS::close
1162                         PublicInbox::DS->SetLoopTimeout(1000);
1163                 };
1164         };
1165         my $sig = {
1166                 CHLD => \&PublicInbox::DS::enqueue_reap,
1167                 QUIT => $quit,
1168                 INT => $quit,
1169                 TERM => $quit,
1170                 HUP => \&noop,
1171                 USR1 => \&noop,
1172                 USR2 => \&noop,
1173         };
1174         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1175         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1176         undef $sig;
1177         local $SIG{PIPE} = 'IGNORE';
1178         require PublicInbox::DirIdle;
1179         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1180                 # just rely on wakeup ot hit PostLoopCallback set below
1181                 _dir_idle_handler(@_) if $_[0]->fullname ne $path;
1182         }, 1);
1183         if ($sigfd) {
1184                 undef $sigfd; # unref, already in DS::DescriptorMap
1185         } else {
1186                 # wake up every second to accept signals if we don't
1187                 # have signalfd or IO::KQueue:
1188                 PublicInbox::DS::sig_setmask($oldset);
1189                 PublicInbox::DS->SetLoopTimeout(1000);
1190         }
1191         PublicInbox::DS->SetPostLoopCallback(sub {
1192                 my ($dmap, undef) = @_;
1193                 if (@st = defined($path) ? stat($path) : ()) {
1194                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1195                                 warn "$path dev/ino changed, quitting\n";
1196                                 $path = undef;
1197                         }
1198                 } elsif (defined($path)) { # ENOENT is common
1199                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1200                         undef $path;
1201                         $quit->();
1202                 }
1203                 return 1 if defined($path);
1204                 my $now = now();
1205                 my $n = 0;
1206                 for my $s (values %$dmap) {
1207                         $s->can('busy') or next;
1208                         if ($s->busy($now)) {
1209                                 ++$n;
1210                         } else {
1211                                 $s->close;
1212                         }
1213                 }
1214                 $n; # true: continue, false: stop
1215         });
1216
1217         # STDIN was redirected to /dev/null above, closing STDERR and
1218         # STDOUT will cause the calling `lei' client process to finish
1219         # reading the <$daemon> pipe.
1220         local $SIG{__WARN__} = sub {
1221                 $current_lei ? err($current_lei, @_) : warn(
1222                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1223         };
1224         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1225         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1226         # $daemon pipe to `lei' closed, main loop begins:
1227         PublicInbox::DS->EventLoop;
1228         exit($exit_code // 0);
1229 }
1230
1231 sub busy { 1 } # prevent daemon-shutdown if client is connected
1232
1233 # ensures stdout hits the FS before sock disconnects so a client
1234 # can immediately reread it
1235 sub DESTROY {
1236         my ($self) = @_;
1237         $self->{1}->autoflush(1) if $self->{1};
1238         stop_pager($self);
1239         # preserve $? for ->fail or ->x_it code
1240 }
1241
1242 sub wq_done_wait { # dwaitpid callback
1243         my ($arg, $pid) = @_;
1244         my ($wq, $lei) = @$arg;
1245         my $err_type = $lei->{-err_type};
1246         $? and $lei->child_error($?,
1247                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1248         $lei->dclose;
1249 }
1250
1251 sub fchdir {
1252         my ($lei) = @_;
1253         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1254         chdir($dh) || $lei->fail("fchdir: $!");
1255 }
1256
1257 sub wq_eof { # EOF callback for main daemon
1258         my ($lei) = @_;
1259         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1260         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1261 }
1262
1263 1;