lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EPIPE EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use Cwd qw(getcwd);
  17 use POSIX qw(strftime);
  18 use IO::Handle ();
  19 use Fcntl qw(SEEK_SET);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn popen_rd);
  25 use PublicInbox::Lock;
  26 use PublicInbox::Eml;
  27 use PublicInbox::Import;
  28 use PublicInbox::ContentHash qw(git_sha);
  29 use Time::HiRes qw(stat); # ctime comparisons for config cache
  30 use File::Path qw(mkpath);
  31 use File::Spec;
  32 use Sys::Syslog qw(openlog syslog closelog);
  33 our $quit = \&CORE::exit;
  34 our ($current_lei, $errors_log, $listener, $oldset, $dir_idle,
  35         $recv_cmd, $send_cmd);
  36 my $GLP = Getopt::Long::Parser->new;
  37 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  38 my $GLP_PASS = Getopt::Long::Parser->new;
  39 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  40
  41 our %PATH2CFG; # persistent for socket daemon
  42 our $MDIR2CFGPATH; # /path/to/maildir => { /path/to/config => [ ino watches ] }
  43
  44 # TBD: this is a documentation mechanism to show a subcommand
  45 # (may) pass options through to another command:
  46 sub pass_through { $GLP_PASS }
  47
  48 my $OPT;
  49 sub opt_dash ($$) {
  50         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  51         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  52         my $cb = sub { # Getopt::Long "<>" catch-all handler
  53                 my ($arg) = @_;
  54                 if ($arg =~ /\A-($re_str)\z/) {
  55                         $OPT->{$key} = $1;
  56                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  57                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  58                 # lone (single) dash is handled elsewhere
  59                 } elsif (substr($arg, 0, 1) eq '-') {
  60                         if ($OPT->{'--'}) {
  61                                 push @{$OPT->{-argv}}, $arg;
  62                         } else {
  63                                 die "bad argument: $arg\n";
  64                         }
  65                 } else {
  66                         push @{$OPT->{-argv}}, $arg;
  67                 }
  68         };
  69         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  70 }
  71
  72 # rel2abs preserves symlinks in parent, unlike abs_path
  73 sub rel2abs {
  74         my ($self, $p) = @_;
  75         if (index($p, '/') == 0) { # already absolute
  76                 $p =~ tr!/!/!s; # squeeze redundant slashes
  77                 chop($p) if substr($p, -1, 1) eq '/';
  78                 return $p;
  79         }
  80         my $pwd = $self->{env}->{PWD};
  81         my $cwd;
  82         if (defined $pwd) {
  83                 my $xcwd = $self->{3} //
  84                         ($cwd = getcwd() // die "getcwd(PWD=$pwd): $!");
  85                 if (my @st_pwd = stat($pwd)) {
  86                         my @st_cwd = stat($xcwd) or die "stat($xcwd): $!";
  87                         "@st_pwd[1,0]" eq "@st_cwd[1,0]" or
  88                                 $self->{env}->{PWD} = $pwd = undef;
  89                 } else { # PWD was invalid
  90                         $self->{env}->{PWD} = $pwd = undef;
  91                 }
  92         }
  93         $pwd //= $self->{env}->{PWD} = $cwd // getcwd() // die "getcwd: $!";
  94         File::Spec->rel2abs($p, $pwd);
  95 }
  96
  97 # abs_path resolves symlinks in parent iff all parents exist
  98 sub abs_path { Cwd::abs_path($_[1]) // rel2abs(@_) }
  99
 100 sub canonpath_harder {
 101         my $p = $_[-1]; # $_[0] may be self
 102         $p = File::Spec->canonpath($p);
 103         $p =~ m!(?:/*|\A)\.\.(?:/*|\z)! && -e $p ? Cwd::abs_path($p) : $p;
 104 }
 105
 106 sub share_path ($) { # $HOME/.local/share/lei/$FOO
 107         my ($self) = @_;
 108         rel2abs($self, ($self->{env}->{XDG_DATA_HOME} //
 109                 ($self->{env}->{HOME} // '/nonexistent').'/.local/share')
 110                 .'/lei');
 111 }
 112
 113 sub store_path ($) { share_path($_[0]) . '/store' }
 114
 115 sub _config_path ($) {
 116         my ($self) = @_;
 117         rel2abs($self, ($self->{env}->{XDG_CONFIG_HOME} //
 118                 ($self->{env}->{HOME} // '/nonexistent').'/.config')
 119                 .'/lei/config');
 120 }
 121
 122 sub cache_dir ($) {
 123         my ($self) = @_;
 124         rel2abs($self, ($self->{env}->{XDG_CACHE_HOME} //
 125                 ($self->{env}->{HOME} // '/nonexistent').'/.cache')
 126                 .'/lei');
 127 }
 128
 129 sub url_folder_cache {
 130         my ($self) = @_;
 131         require PublicInbox::SharedKV; # URI => updated_at_sec_
 132         PublicInbox::SharedKV->new(cache_dir($self).'/uri_folder');
 133 }
 134
 135 sub ale {
 136         my ($self) = @_;
 137         $self->{ale} //= do {
 138                 require PublicInbox::LeiALE;
 139                 $self->_lei_cfg(1)->{ale} //= PublicInbox::LeiALE->new($self);
 140         };
 141 }
 142
 143 sub index_opt {
 144         # TODO: drop underscore variants everywhere, they're undocumented
 145         qw(fsync|sync! jobs|j=i indexlevel|L=s compact
 146         max_size|max-size=s sequential-shard
 147         batch_size|batch-size=s skip-docdata)
 148 }
 149
 150 my @c_opt = qw(c=s@ C=s@ quiet|q);
 151 my @net_opt = (qw(no-torsocks torsocks=s), PublicInbox::LeiQuery::curl_opt());
 152 my @lxs_opt = qw(remote! local! external! include|I=s@ exclude=s@ only=s@
 153         import-remote!);
 154
 155 # we don't support -C as an alias for --find-copies since it's already
 156 # used for chdir
 157 our @diff_opt = qw(unified|U=i output-indicator-new=s output-indicator-old=s
 158         output-indicator-context=s indent-heuristic!
 159         minimal patience histogram anchored=s@ diff-algorithm=s
 160         color-moved:s color-moved-ws=s no-color-moved no-color-moved-ws
 161         word-diff:s word-diff-regex=s color-words:s no-renames
 162         rename-empty! check ws-error-highlight=s full-index binary
 163         abbrev:i break-rewrites|B:s find-renames|M:s find-copies:s
 164         find-copies-harder irreversible-delete|D l=i diff-filter=s
 165         S=s G=s find-object=s pickaxe-all pickaxe-regex O=s R
 166         relative:s text|a ignore-cr-at-eol ignore-space-at-eol
 167         ignore-space-change|b ignore-all-space|w ignore-blank-lines
 168         inter-hunk-context=i function-context|W exit-code ext-diff
 169         no-ext-diff textconv! src-prefix=s dst-prefix=s no-prefix
 170         line-prefix=s);
 171
 172 # we generate shell completion + help using %CMD and %OPTDESC,
 173 # see lei__complete() and PublicInbox::LeiHelp
 174 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
 175 our %CMD = ( # sorted in order of importance/use:
 176 'q' => [ '--stdin|SEARCH_TERMS...', 'search for messages matching terms',
 177         'stdin|', # /|\z/ must be first for lone dash
 178         @lxs_opt, @net_opt,
 179         qw(save! output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 180         sort|s=s reverse|r offset=i pretty jobs|j=s globoff|g augment|a
 181         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 182         shared color! mail-sync!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 183
 184 'up' => [ 'OUTPUT...|--all', 'update saved search',
 185         qw(jobs|j=s lock=s@ alert=s@ mua=s verbose|v+
 186         remote-fudge-time=s all:s), @c_opt ],
 187
 188 'lcat' => [ '--stdin|MSGID_OR_URL...', 'display local copy of message(s)',
 189         'stdin|', # /|\z/ must be first for lone dash
 190         # some of these options are ridiculous for lcat
 191         @lxs_opt, @net_opt,
 192         qw(output|mfolder|o=s format|f=s dedupe|d=s threads|t+
 193         sort|s=s reverse|r offset=i jobs|j=s globoff|g augment|a
 194         import-before! lock=s@ rsyncable alert=s@ mua=s verbose|v+
 195         color!), @c_opt, opt_dash('limit|n=i', '[0-9]+') ],
 196
 197 'blob' => [ 'OID', 'show a git blob, reconstructing from mail if necessary',
 198         qw(git-dir=s@ cwd! verbose|v+ mail! oid-a|A=s path-a|a=s path-b|b=s),
 199         @lxs_opt, @net_opt, @c_opt ],
 200
 201 'rediff' => [ '--stdin|LOCATION...',
 202                 'regenerate a diff with different options',
 203         'stdin|', # /|\z/ must be first for lone dash
 204         qw(git-dir=s@ cwd! verbose|v+ color:s no-color),
 205         @diff_opt, @lxs_opt, @net_opt, @c_opt ],
 206
 207 'add-external' => [ 'LOCATION',
 208         'add/set priority of a publicinbox|extindex for extra matches',
 209         qw(boost=i mirror=s inbox-version=i verbose|v+),
 210         @c_opt, index_opt(), @net_opt ],
 211 'ls-external' => [ '[FILTER]', 'list publicinbox|extindex locations',
 212         qw(format|f=s z|0 globoff|g invert-match|v local remote), @c_opt ],
 213 'ls-label' => [ '', 'list labels', qw(z|0 stats:s), @c_opt ],
 214 'ls-mail-sync' => [ '[FILTER]', 'list mail sync folders',
 215                 qw(z|0 globoff|g invert-match|v local remote), @c_opt ],
 216 'ls-mail-source' => [ 'URL', 'list IMAP or NNTP mail source folders',
 217                 qw(z|0 ascii l pretty url), @c_opt ],
 218 'forget-external' => [ 'LOCATION...|--prune',
 219         'exclude further results from a publicinbox|extindex',
 220         qw(prune), @c_opt ],
 221
 222 'ls-search' => [ '[PREFIX]', 'list saved search queries',
 223                 qw(format|f=s pretty l ascii z|0), @c_opt ],
 224 'forget-search' => [ 'OUTPUT', 'forget a saved search',
 225                 qw(verbose|v+), @c_opt ],
 226 'edit-search' => [ 'OUTPUT', "edit saved search via `git config --edit'",
 227                         @c_opt ],
 228 'rm' => [ '--stdin|LOCATION...',
 229         'remove a message from the index and prevent reindexing',
 230         'stdin|', # /|\z/ must be first for lone dash
 231         qw(in-format|F=s lock=s@), @net_opt, @c_opt ],
 232 'plonk' => [ '--threads|--from=IDENT',
 233         'exclude mail matching From: or threads from non-Message-ID searches',
 234         qw(stdin| threads|t from|f=s mid=s oid=s), @c_opt ],
 235 'tag' => [ 'KEYWORDS...',
 236         'set/unset keywords and/or labels on message(s)',
 237         qw(stdin| in-format|F=s input|i=s@ oid=s@ mid=s@),
 238         @net_opt, @c_opt, pass_through('-kw:foo for delete') ],
 239
 240 'purge-mailsource' => [ 'LOCATION|--all',
 241         'remove imported messages from IMAP, Maildirs, and MH',
 242         qw(exact! all jobs:i indexed), @c_opt ],
 243
 244 'add-watch' => [ 'LOCATION...', 'watch for new messages and flag changes',
 245         qw(poll-interval=s state=s recursive|r), @c_opt ],
 246 'rm-watch' => [ 'LOCATION...', 'remove specified watch(es)',
 247         qw(recursive|r), @c_opt ],
 248 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 249                 qw(l z|0), @c_opt ],
 250 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 251 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote), @c_opt ],
 252 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 253         qw(prune), @c_opt ],
 254
 255 'index' => [ 'LOCATION...', 'one-time index from URL or filesystem',
 256         qw(in-format|F=s kw! offset=i recursive|r exclude=s include|I=s
 257         verbose|v+ incremental!), @net_opt, # mainly for --proxy=
 258          @c_opt ],
 259 'import' => [ 'LOCATION...|--stdin',
 260         'one-time import/update from URL or filesystem',
 261         qw(stdin| offset=i recursive|r exclude=s include|I=s new-only
 262         lock=s@ in-format|F=s kw! verbose|v+ incremental! mail-sync!),
 263         @net_opt, @c_opt ],
 264 'forget-mail-sync' => [ 'LOCATION...',
 265         'forget sync information for a mail folder', @c_opt ],
 266 'refresh-mail-sync' => [ 'LOCATION...|--all',
 267         'prune dangling sync data for a mail folder', 'all:s', @c_opt ],
 268 'export-kw' => [ 'LOCATION...|--all',
 269         'one-time export of keywords of sync sources',
 270         qw(all:s mode=s), @net_opt, @c_opt ],
 271 'convert' => [ 'LOCATION...|--stdin',
 272         'one-time conversion from URL or filesystem to another format',
 273         qw(stdin| in-format|F=s out-format|f=s output|mfolder|o=s lock=s@ kw!),
 274         @net_opt, @c_opt ],
 275 'p2q' => [ 'FILE|COMMIT_OID|--stdin',
 276         "use a patch to generate a query for `lei q --stdin'",
 277         qw(stdin| want|w=s@ uri debug), @c_opt ],
 278 'config' => [ '[...]', sub {
 279                 'git-config(1) wrapper for '._config_path($_[0]);
 280         }, qw(config-file|system|global|file|f=s), # for conflict detection
 281          qw(edit|e c=s@ C=s@), pass_through('git config') ],
 282 'inspect' => [ 'ITEMS...|--stdin', 'inspect lei/store and/or local external',
 283         qw(stdin| pretty ascii dir=s), @c_opt ],
 284
 285 'init' => [ '[DIRNAME]', sub {
 286         "initialize storage, default: ".store_path($_[0]);
 287         }, @c_opt ],
 288 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 289         # "-C DIR" conflicts with -CHLD, here, and chdir makes no sense, here
 290         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 291 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 292 'help' => [ '[SUBCOMMAND]', 'show help' ],
 293
 294 # TODO
 295 #'reorder-local-store-and-break-history' => [ '[REFNAME]',
 296 #       'rewrite git history in an attempt to improve compression',
 297 #       qw(gc!), @c_opt ],
 298 #'fuse-mount' => [ 'PATHNAME', 'expose lei/store as Maildir(s)', @c_opt ],
 299 #
 300 # internal commands are prefixed with '_'
 301 '_complete' => [ '[...]', 'internal shell completion helper',
 302                 pass_through('everything') ],
 303 ); # @CMD
 304
 305 # switch descriptions, try to keep consistent across commands
 306 # $spec: Getopt::Long option specification
 307 # $spec => [@ALLOWED_VALUES (default is first), $description],
 308 # $spec => $description
 309 # "$SUB_COMMAND TAB $spec" => as above
 310 my $stdin_formats = [ 'MAIL_FORMAT|eml|mboxrd|mboxcl2|mboxcl|mboxo',
 311                         'specify message input format' ];
 312 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 313
 314 # we use \x{a0} (non-breaking SP) to avoid wrapping in PublicInbox::LeiHelp
 315 my %OPTDESC = (
 316 'help|h' => 'show this built-in help',
 317 'c=s@' => [ 'NAME=VALUE', 'set config option' ],
 318 'C=s@' => [ 'DIR', 'chdir to specify to directory' ],
 319 'quiet|q' => 'be quiet',
 320 'lock=s@' => [ 'METHOD|dotlock|fcntl|flock|none',
 321         'mbox(5) locking method(s) to use (default: fcntl,dotlock)' ],
 322
 323 'incremental!   import' => 'import already seen IMAP and NNTP articles',
 324 'globoff|g' => "do not match locations using '*?' wildcards ".
 325                 "and\xa0'[]'\x{a0}ranges",
 326 'invert-match|v' => 'select non-matching lines',
 327 'color!' => 'disable color (for --format=text)',
 328 'verbose|v+' => 'be more verbose',
 329 'external!' => 'do not use externals',
 330 'mail!' => 'do not look in mail storage for OID',
 331 'cwd!' => 'do not look in git repo of current working directory',
 332 'oid-a|A=s' => 'pre-image OID',
 333 'path-a|a=s' => 'pre-image pathname associated with OID',
 334 'path-b|b=s' => 'post-image pathname associated with OID',
 335 'git-dir=s@' => 'additional git repository to scan',
 336 'dir=s  inspect' => 'specify a inboxdir, extindex topdir or Xapian shard',
 337 'proxy=s' => [ 'PROTO://HOST[:PORT]', # shared with curl(1)
 338         "proxy for (e.g. `socks5h://0:9050')" ],
 339 'torsocks=s' => ['VAL|auto|no|yes',
 340                 'whether or not to wrap git and curl commands with torsocks'],
 341 'no-torsocks' => 'alias for --torsocks=no',
 342 'save!' =>  "do not save a search for `lei up'",
 343 'import-remote!' => 'do not memoize remote messages into local store',
 344
 345 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 346
 347 'dedupe|d=s' => ['STRATEGY|content|oid|mid|none',
 348                 'deduplication strategy'],
 349 'threads|t+' =>
 350         'return all messages in the same threads as the actual match(es)',
 351
 352 'want|w=s@' => [ 'PREFIX|dfpost|dfn', # common ones in help...
 353                 'search prefixes to extract (default: dfpost7)' ],
 354
 355 'alert=s@' => ['CMD,:WINCH,:bell,<any command>',
 356         'run command(s) or perform ops when done writing to output ' .
 357         '(default: ":WINCH,:bell" with --mua and Maildir/IMAP output, ' .
 358         'nothing otherwise)' ],
 359
 360 'augment|a' => 'augment --output destination instead of clobbering',
 361
 362 'output|mfolder|o=s' => [ 'MFOLDER',
 363         "destination (e.g.\xa0`/path/to/Maildir', ".
 364         "or\xa0`-'\x{a0}for\x{a0}stdout)" ],
 365 'mua=s' => [ 'CMD',
 366         "MUA to run on --output Maildir or mbox (e.g.\xa0`mutt\xa0-f\xa0%f')" ],
 367 'new-only       import' => 'only import new messages from IMAP source',
 368
 369 'inbox-version=i' => [ 'NUM|1|2',
 370                 'force a public-inbox version with --mirror'],
 371 'mirror=s' => [ 'URL', 'mirror a public-inbox'],
 372
 373 # public-inbox-index options
 374 'fsync!' => 'speed up indexing after --mirror, risk index corruption',
 375 'compact' => 'run compact index after mirroring',
 376 'indexlevel|L=s' => [ 'LEVEL|full|medium|basic',
 377         "indexlevel with --mirror (default: full)" ],
 378 'max_size|max-size=s' => [ 'SIZE',
 379         'do not index messages larger than SIZE (default: infinity)' ],
 380 'batch_size|batch-size=s' => [ 'SIZE',
 381         'flush changes to OS after given number of bytes (default: 1m)' ],
 382 'sequential-shard' =>
 383         'index Xapian shards sequentially for slow storage',
 384 'skip-docdata' =>
 385         'drop compatibility w/ public-inbox <1.6 to save ~1.5% space',
 386
 387 'format|f=s     q' => [
 388         'OUT|maildir|mboxrd|mboxcl2|mboxcl|mboxo|html|json|jsonl|concatjson',
 389                 'specify output format, default depends on --output'],
 390 'exclude=s@     q' => [ 'LOCATION',
 391                 'exclude specified external(s) from search' ],
 392 'include|I=s@   q' => [ 'LOCATION',
 393                 'include specified external(s) in search' ],
 394 'only=s@        q' => [ 'LOCATION',
 395                 'only use specified external(s) for search' ],
 396 'jobs=s q' => [ '[SEARCH_JOBS][,WRITER_JOBS]',
 397                 'control number of search and writer jobs' ],
 398 'jobs|j=i       add-external' => 'set parallelism when indexing after --mirror',
 399
 400 'in-format|F=s' => $stdin_formats,
 401 'format|f=s     ls-search' => ['OUT|json|jsonl|concatjson',
 402                         'listing output format' ],
 403 'l      ls-search' => 'long listing format',
 404 'l      ls-watch' => 'long listing format',
 405 'l      ls-mail-source' => 'long listing format',
 406 'url    ls-mail-source' => 'show full URL of newsgroup or IMAP folder',
 407 'format|f=s     ls-external' => $ls_format,
 408
 409 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 410 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 411
 412 'sort|s=s' => [ 'VAL|received|relevance|docid',
 413                 "order of results is `--output'-dependent"],
 414 'reverse|r' => 'reverse search results', # like sort(1)
 415
 416 'boost=i' => 'increase/decrease priority of results (default: 0)',
 417
 418 'local' => 'limit operations to the local filesystem',
 419 'local!' => 'exclude results from the local filesystem',
 420 'remote' => 'limit operations to those requiring network access',
 421 'remote!' => 'prevent operations requiring network access',
 422
 423 'all:s  up' => ['local|remote', 'update all remote or local saved searches' ],
 424 'remote-fudge-time=s' => [ 'INTERVAL',
 425         'look for mail INTERVAL older than the last successful query' ],
 426
 427 'mid=s' => 'specify the Message-ID of a message',
 428 'oid=s' => 'specify the git object ID of a message',
 429
 430 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 431 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 432 'include=s' => 'include mailboxes/newsgroups based on pattern',
 433
 434 'exact' => 'operate on exact header matches only',
 435 'exact!' => 'rely on content match instead of exact header matches',
 436
 437 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 438
 439 'kw!' => 'disable/enable importing keywords (aka "flags")',
 440
 441 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 442 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 443
 444 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 445 ); # %OPTDESC
 446
 447 my %CONFIG_KEYS = (
 448         'leistore.dir' => 'top-level storage location',
 449 );
 450
 451 my @WQ_KEYS = qw(lxs l2m ikw pmd wq1 lne); # internal workers
 452
 453 sub _drop_wq {
 454         my ($self) = @_;
 455         for my $wq (grep(defined, delete(@$self{@WQ_KEYS}))) {
 456                 if ($wq->wq_kill) {
 457                         $wq->wq_close(0, undef, $self);
 458                 } elsif ($wq->wq_kill_old) {
 459                         $wq->wq_wait_old(undef, $self);
 460                 }
 461                 $wq->DESTROY;
 462         }
 463 }
 464
 465 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 466 sub x_it ($$) {
 467         my ($self, $code) = @_;
 468         # make sure client sees stdout before exit
 469         $self->{1}->autoflush(1) if $self->{1};
 470         stop_pager($self);
 471         if ($self->{pkt_op_p}) { # worker => lei-daemon
 472                 $self->{pkt_op_p}->pkt_do('x_it', $code);
 473         } elsif ($self->{sock}) { # lei->daemon => lei(1) client
 474                 send($self->{sock}, "x_it $code", MSG_EOR);
 475         } elsif ($quit == \&CORE::exit) { # an admin (one-shot) command
 476                 exit($code >> 8);
 477         } # else ignore if client disconnected
 478 }
 479
 480 sub err ($;@) {
 481         my $self = shift;
 482         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 483         my @eor = (substr($_[-1]//'', -1, 1) eq "\n" ? () : ("\n"));
 484         print $err @_, @eor and return;
 485         my $old_err = delete $self->{2};
 486         close($old_err) if $! == EPIPE && $old_err;
 487         $err = $self->{2} = ($self->{pgr} // [])->[2] // *STDERR{GLOB};
 488         print $err @_, @eor or print STDERR @_, @eor;
 489 }
 490
 491 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 492
 493 sub qfin { # show message on finalization (LeiFinmsg)
 494         my ($lei, $msg) = @_;
 495         return if $lei->{opt}->{quiet};
 496         $lei->{fmsg} ? push(@{$lei->{fmsg}}, "$msg\n") : qerr($lei, $msg);
 497 }
 498
 499 sub fail_handler ($;$$) {
 500         my ($lei, $code, $io) = @_;
 501         close($io) if $io; # needed to avoid warnings on SIGPIPE
 502         _drop_wq($lei);
 503         x_it($lei, $code // (1 << 8));
 504 }
 505
 506 sub sigpipe_handler { # handles SIGPIPE from @WQ_KEYS workers
 507         fail_handler($_[0], 13, delete $_[0]->{1});
 508 }
 509
 510 # PublicInbox::OnDestroy callback for SIGINT to take out the entire pgid
 511 sub sigint_reap {
 512         my ($pgid) = @_;
 513         dwaitpid($pgid) if kill('-INT', $pgid);
 514 }
 515
 516 sub fail ($$;$) {
 517         my ($self, $buf, $exit_code) = @_;
 518         $self->{failed}++;
 519         err($self, $buf) if defined $buf;
 520         # calls fail_handler
 521         $self->{pkt_op_p}->pkt_do('!') if $self->{pkt_op_p};
 522         x_it($self, ($exit_code // 1) << 8);
 523         undef;
 524 }
 525
 526 sub out ($;@) {
 527         my $self = shift;
 528         return if print { $self->{1} // return } @_; # likely
 529         return note_sigpipe($self, 1) if $! == EPIPE;
 530         my $err = "error writing to output: $!";
 531         delete $self->{1};
 532         fail($self, $err);
 533 }
 534
 535 sub puts ($;@) { out(shift, map { "$_\n" } @_) }
 536
 537 sub child_error { # passes non-fatal curl exit codes to user
 538         my ($self, $child_error, $msg) = @_; # child_error is $?
 539         $child_error ||= 1 << 8;
 540         $self->err($msg) if $msg;
 541         if ($self->{pkt_op_p}) { # to top lei-daemon
 542                 $self->{pkt_op_p}->pkt_do('child_error', $child_error);
 543         } elsif ($self->{sock}) { # to lei(1) client
 544                 send($self->{sock}, "child_error $child_error", MSG_EOR);
 545         } else { # non-lei admin command
 546                 $self->{child_error} ||= $child_error;
 547         } # else noop if client disconnected
 548 }
 549
 550 sub note_sigpipe { # triggers sigpipe_handler
 551         my ($self, $fd) = @_;
 552         close(delete($self->{$fd})); # explicit close silences Perl warning
 553         $self->{pkt_op_p}->pkt_do('|') if $self->{pkt_op_p};
 554         x_it($self, 13);
 555 }
 556
 557 sub _lei_atfork_child {
 558         my ($self, $persist) = @_;
 559         # we need to explicitly close things which are on stack
 560         if ($persist) {
 561                 chdir '/' or die "chdir(/): $!";
 562                 close($_) for (grep(defined, delete @$self{qw(0 1 2 sock)}));
 563                 if (my $cfg = $self->{cfg}) {
 564                         delete @$cfg{qw(-lei_store -watches -lei_note_event)};
 565                 }
 566         } else { # worker, Net::NNTP (Net::Cmd) uses STDERR directly
 567                 open STDERR, '+>&='.fileno($self->{2}) or warn "open $!";
 568                 STDERR->autoflush(1);
 569         }
 570         close($_) for (grep(defined, delete @$self{qw(3 old_1 au_done)}));
 571         if (my $op_c = delete $self->{pkt_op_c}) {
 572                 close(delete $op_c->{sock});
 573         }
 574         if (my $pgr = delete $self->{pgr}) {
 575                 close($_) for (@$pgr[1,2]);
 576         }
 577         close $listener if $listener;
 578         undef $listener;
 579         $dir_idle->force_close if $dir_idle;
 580         %PATH2CFG = ();
 581         $MDIR2CFGPATH = {};
 582         eval 'no warnings; undef $PublicInbox::LeiNoteEvent::to_flush';
 583         undef $errors_log;
 584         $quit = \&CORE::exit;
 585         $self->{-eml_noisy} or # only "lei import" sets this atm
 586                 $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 587         $current_lei = $persist ? undef : $self; # for SIG{__WARN__}
 588 }
 589
 590 sub _delete_pkt_op { # OnDestroy callback to prevent leaks on die
 591         my ($self) = @_;
 592         if (my $op = delete $self->{pkt_op_c}) { # in case of die
 593                 $op->close; # PublicInbox::PktOp::close
 594         }
 595         my $pkt_op_p = delete($self->{pkt_op_p}) or return;
 596         close $pkt_op_p->{op_p};
 597 }
 598
 599 sub pkt_op_pair {
 600         my ($self) = @_;
 601         require PublicInbox::OnDestroy;
 602         require PublicInbox::PktOp;
 603         my $end = PublicInbox::OnDestroy->new($$, \&_delete_pkt_op, $self);
 604         @$self{qw(pkt_op_c pkt_op_p)} = PublicInbox::PktOp->pair;
 605         $end;
 606 }
 607
 608 sub incr {
 609         my ($self, $field, $nr) = @_;
 610         $self->{counters}->{$field} += $nr;
 611 }
 612
 613 sub pkt_ops {
 614         my ($lei, $ops) = @_;
 615         $ops->{'!'} = [ \&fail_handler, $lei ];
 616         $ops->{'|'} = [ \&sigpipe_handler, $lei ];
 617         $ops->{x_it} = [ \&x_it, $lei ];
 618         $ops->{child_error} = [ \&child_error, $lei ];
 619         $ops->{incr} = [ \&incr, $lei ];
 620         $ops;
 621 }
 622
 623 sub workers_start {
 624         my ($lei, $wq, $jobs, $ops, $flds) = @_;
 625         $ops = pkt_ops($lei, { ($ops ? %$ops : ()) });
 626         $ops->{''} //= [ $wq->can('_lei_wq_eof') || \&wq_eof, $lei ];
 627         my $end = $lei->pkt_op_pair;
 628         my $ident = $wq->{-wq_ident} // "lei-$lei->{cmd} worker";
 629         $flds->{lei} = $lei;
 630         $wq->wq_workers_start($ident, $jobs, $lei->oldset, $flds);
 631         delete $lei->{pkt_op_p};
 632         my $op_c = delete $lei->{pkt_op_c};
 633         @$end = ();
 634         $lei->event_step_init;
 635         ($op_c, $ops);
 636 }
 637
 638 # call this when we're ready to wait on events and yield to other clients
 639 sub wait_wq_events {
 640         my ($lei, $op_c, $ops) = @_;
 641         for my $wq (grep(defined, @$lei{qw(ikw pmd)})) { # auxiliary WQs
 642                 $wq->wq_close(1);
 643         }
 644         $op_c->{ops} = $ops;
 645 }
 646
 647 sub _help {
 648         require PublicInbox::LeiHelp;
 649         PublicInbox::LeiHelp::call($_[0], $_[1], \%CMD, \%OPTDESC);
 650 }
 651
 652 sub optparse ($$$) {
 653         my ($self, $cmd, $argv) = @_;
 654         # allow _complete --help to complete, not show help
 655         return 1 if substr($cmd, 0, 1) eq '_';
 656         $self->{cmd} = $cmd;
 657         $OPT = $self->{opt} //= {};
 658         my $info = $CMD{$cmd} // [ '[...]' ];
 659         my ($proto, undef, @spec) = @$info;
 660         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 661         push @spec, qw(help|h);
 662         my $lone_dash;
 663         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 664                 $lone_dash = $spec[0];
 665                 $OPT->{$spec[0]} = \(my $var);
 666                 push @spec, '' => \$var;
 667         }
 668         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 669                 return _help($self, "bad arguments or options for $cmd");
 670         return _help($self) if $OPT->{help};
 671
 672         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 673
 674         # "-" aliases "stdin" or "clear"
 675         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 676
 677         my $i = 0;
 678         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 679         my ($err, $inf);
 680         my @args = split(/ /, $proto);
 681         for my $var (@args) {
 682                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 683                         $inf = defined($argv->[$i]) and last;
 684                         $var =~ s/\.\.\.\z//;
 685                         $err = "$var not supplied";
 686                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 687                         $argv->[$i++] // ($err = "$var not supplied");
 688                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 689                         $inf = 1;
 690                         last;
 691                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 692                         $i++;
 693                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 694                         $inf = 1 if index($var, '...') > 0;
 695                         my @or = split(/\|/, $var);
 696                         my $ok;
 697                         for my $o (@or) {
 698                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 699                                         my $sw = $1;
 700                                         # assume pipe/regular file on stdin
 701                                         # w/o args means stdin
 702                                         if ($sw eq 'stdin' && !@$argv &&
 703                                                         (-p $self->{0} ||
 704                                                          -f _) && -r _) {
 705                                                 $OPT->{stdin} //= 1;
 706                                         }
 707                                         $ok = defined($OPT->{$sw});
 708                                         last if $ok;
 709                                 } elsif (defined($argv->[$i])) {
 710                                         $ok = 1;
 711                                         $i++;
 712                                         last;
 713                                 } # else continue looping
 714                         }
 715                         last if $ok;
 716                         my $last = pop @or;
 717                         $err = join(', ', @or) . " or $last must be set";
 718                 } else {
 719                         warn "BUG: can't parse `$var' in $proto";
 720                 }
 721                 last if $err;
 722         }
 723         if (!$inf && scalar(@$argv) > scalar(@args)) {
 724                 $err //= 'too many arguments';
 725         }
 726         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 727 }
 728
 729 sub _tmp_cfg { # for lei -c <name>=<value> ...
 730         my ($self) = @_;
 731         my $cfg = _lei_cfg($self, 1);
 732         require File::Temp;
 733         my $ft = File::Temp->new(TEMPLATE => 'lei_cfg-XXXX', TMPDIR => 1);
 734         my $tmp = { '-f' => $ft->filename, -tmp => $ft };
 735         $ft->autoflush(1);
 736         print $ft <<EOM or return fail($self, "$tmp->{-f}: $!");
 737 [include]
 738         path = $cfg->{-f}
 739 EOM
 740         $tmp = $self->{cfg} = bless { %$cfg, %$tmp }, ref($cfg);
 741         for (@{$self->{opt}->{c}}) {
 742                 /\A([^=\.]+\.[^=]+)(?:=(.*))?\z/ or return fail($self, <<EOM);
 743 `-c $_' is not of the form -c <name>=<value>'
 744 EOM
 745                 my $name = $1;
 746                 my $value = $2 // 1;
 747                 _config($self, '--add', $name, $value);
 748                 if (defined(my $v = $tmp->{$name})) {
 749                         if (ref($v) eq 'ARRAY') {
 750                                 push @$v, $value;
 751                         } else {
 752                                 $tmp->{$name} = [ $v, $value ];
 753                         }
 754                 } else {
 755                         $tmp->{$name} = $value;
 756                 }
 757         }
 758 }
 759
 760 sub lazy_cb ($$$) {
 761         my ($self, $cmd, $pfx) = @_;
 762         my $ucmd = $cmd;
 763         $ucmd =~ tr/-/_/;
 764         my $cb;
 765         $cb = $self->can($pfx.$ucmd) and return $cb;
 766         my $base = $ucmd;
 767         $base =~ s/_([a-z])/\u$1/g;
 768         my $pkg = "PublicInbox::Lei\u$base";
 769         ($INC{"PublicInbox/Lei\u$base.pm"} // eval("require $pkg")) ?
 770                 $pkg->can($pfx.$ucmd) : undef;
 771 }
 772
 773 sub dispatch {
 774         my ($self, $cmd, @argv) = @_;
 775         fchdir($self) or return;
 776         local %ENV = %{$self->{env}};
 777         local $current_lei = $self; # for __WARN__
 778         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 779         return _help($self, 'no command given') unless defined($cmd);
 780         # do not support Getopt bundling for this
 781         while ($cmd eq '-C' || $cmd eq '-c') {
 782                 my $v = shift(@argv) // return fail($self, $cmd eq '-C' ?
 783                                         '-C DIRECTORY' : '-c <name>=<value>');
 784                 push @{$self->{opt}->{substr($cmd, 1, 1)}}, $v;
 785                 $cmd = shift(@argv) // return _help($self, 'no command given');
 786         }
 787         if (my $cb = lazy_cb(__PACKAGE__, $cmd, 'lei_')) {
 788                 optparse($self, $cmd, \@argv) or return;
 789                 $self->{opt}->{c} and (_tmp_cfg($self) // return);
 790                 if (my $chdir = $self->{opt}->{C}) {
 791                         for my $d (@$chdir) {
 792                                 next if $d eq ''; # same as git(1)
 793                                 chdir $d or return fail($self, "cd $d: $!");
 794                         }
 795                         open $self->{3}, '.' or return fail($self, "open . $!");
 796                 }
 797                 $cb->($self, @argv);
 798         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 799                 $GLP->getoptionsfromarray([$cmd, @argv], {}, qw(help|h C=s@))
 800                         or return _help($self, 'bad arguments or options');
 801                 _help($self);
 802         } else {
 803                 fail($self, "`$cmd' is not an lei command");
 804         }
 805 }
 806
 807 sub _lei_cfg ($;$) {
 808         my ($self, $creat) = @_;
 809         return $self->{cfg} if $self->{cfg};
 810         my $f = _config_path($self);
 811         my @st = stat($f);
 812         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 813         my ($sto, $sto_dir, $watches, $lne);
 814         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 815                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 816                 ($sto, $sto_dir, $watches, $lne) =
 817                                 @$cfg{qw(-lei_store leistore.dir -watches
 818                                         -lei_note_event)};
 819         }
 820         if (!@st) {
 821                 unless ($creat) {
 822                         delete $self->{cfg};
 823                         return bless {}, 'PublicInbox::Config';
 824                 }
 825                 my ($cfg_dir) = ($f =~ m!(.*?/)[^/]+\z!);
 826                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 827                 open my $fh, '>>', $f or die "open($f): $!\n";
 828                 @st = stat($fh) or die "fstat($f): $!\n";
 829                 $cur_st = pack('dd', $st[10], $st[7]);
 830                 qerr($self, "# $f created") if $self->{cmd} ne 'config';
 831         }
 832         my $cfg = PublicInbox::Config->git_config_dump($f, $self->{2});
 833         $cfg->{-st} = $cur_st;
 834         $cfg->{'-f'} = $f;
 835         if ($sto && canonpath_harder($sto_dir // store_path($self))
 836                         eq canonpath_harder($cfg->{'leistore.dir'} //
 837                                                 store_path($self))) {
 838                 $cfg->{-lei_store} = $sto;
 839                 $cfg->{-lei_note_event} = $lne;
 840                 $cfg->{-watches} = $watches if $watches;
 841         }
 842         if (scalar(keys %PATH2CFG) > 5) {
 843                 # FIXME: use inotify/EVFILT_VNODE to detect unlinked configs
 844                 for my $k (keys %PATH2CFG) {
 845                         delete($PATH2CFG{$k}) unless -f $k
 846                 }
 847         }
 848         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 849         refresh_watches($self);
 850         $cfg;
 851 }
 852
 853 sub _lei_store ($;$) {
 854         my ($self, $creat) = @_;
 855         my $cfg = _lei_cfg($self, $creat) // return;
 856         $cfg->{-lei_store} //= do {
 857                 require PublicInbox::LeiStore;
 858                 my $dir = $cfg->{'leistore.dir'} // store_path($self);
 859                 return unless $creat || -d $dir;
 860                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 861         };
 862 }
 863
 864 sub _config {
 865         my ($self, @argv) = @_;
 866         my %env = (%{$self->{env}}, GIT_CONFIG => undef);
 867         my $cfg = _lei_cfg($self, 1);
 868         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 869         my %rdr = map { $_ => $self->{$_} } (0..2);
 870         waitpid(spawn($cmd, \%env, \%rdr), 0);
 871 }
 872
 873 sub lei_daemon_pid { puts shift, $$ }
 874
 875 sub lei_daemon_kill {
 876         my ($self) = @_;
 877         my $sig = $self->{opt}->{signal} // 'TERM';
 878         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 879 }
 880
 881 # Shell completion helper.  Used by lei-completion.bash and hopefully
 882 # other shells.  Try to do as much here as possible to avoid redundancy
 883 # and improve maintainability.
 884 sub lei__complete {
 885         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 886         shift @argv; # ignore "lei", the entire command is sent
 887         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h -C);
 888         my $cmd = shift @argv;
 889         my $info = $CMD{$cmd} // do { # filter matching commands
 890                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 891                 return;
 892         };
 893         my ($proto, undef, @spec) = @$info;
 894         my $cur = pop @argv;
 895         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 896         if (substr(my $_cur = $cur // '-', 0, 1) eq '-') { # --switches
 897                 # gross special case since the only git-config options
 898                 # Consider moving to a table if we need more special cases
 899                 # we use Getopt::Long for are the ones we reject, so these
 900                 # are the ones we don't reject:
 901                 if ($cmd eq 'config') {
 902                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 903                         @spec = qw(add z|null get get-all unset unset-all
 904                                 replace-all get-urlmatch
 905                                 remove-section rename-section
 906                                 name-only list|l edit|e
 907                                 get-color-name get-colorbool);
 908                         # fall-through
 909                 }
 910                 # generate short/long names from Getopt::Long specs
 911                 puts $self, grep(/$re/, qw(--help -h -C), map {
 912                         if (s/[:=].+\z//) { # req/optional args, e.g output|o=i
 913                         } elsif (s/\+\z//) { # verbose|v+
 914                         } elsif (s/!\z//) {
 915                                 # negation: mail! => no-mail|mail
 916                                 s/([\w\-]+)/$1|no-$1/g
 917                         }
 918                         map {
 919                                 my $x = length > 1 ? "--$_" : "-$_";
 920                                 $x eq $_cur ? () : $x;
 921                         } grep(!/_/, split(/\|/, $_, -1)) # help|h
 922                 } grep { $OPTDESC{"$_\t$cmd"} || $OPTDESC{$_} } @spec);
 923         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 924                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 925         }
 926
 927         # switch args (e.g. lei q -f mbox<TAB>)
 928         if (($argv[-1] // $cur // '') =~ /\A--?([\w\-]+)\z/) {
 929                 my $opt = quotemeta $1;
 930                 puts $self, map {
 931                         my $v = $OPTDESC{$_};
 932                         my @v = ref($v) ? split(/\|/, $v->[0]) : ();
 933                         # get rid of ALL CAPS placeholder (e.g "OUT")
 934                         # (TODO: completion for external paths)
 935                         shift(@v) if scalar(@v) && uc($v[0]) eq $v[0];
 936                         @v;
 937                 } grep(/\A(?:[\w-]+\|)*$opt\b.*?(?:\t$cmd)?\z/, keys %OPTDESC);
 938         }
 939         if (my $cb = lazy_cb($self, $cmd, '_complete_')) {
 940                 puts $self, $cb->($self, @argv, $cur ? ($cur) : ());
 941         }
 942         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 943         # proto parsing.
 944 }
 945
 946 sub exec_buf ($$) {
 947         my ($argv, $env) = @_;
 948         my $argc = scalar @$argv;
 949         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 950         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 951         $buf;
 952 }
 953
 954 sub start_mua {
 955         my ($self) = @_;
 956         if ($self->{ovv}->{fmt} =~ /\A(?:maildir)\z/) { # TODO: IMAP
 957                 refresh_watches($self);
 958         }
 959         my $mua = $self->{opt}->{mua} // return;
 960         my $mfolder = $self->{ovv}->{dst};
 961         my (@cmd, $replaced);
 962         if ($mua =~ /\A(?:mutt|mailx|mail|neomutt)\z/) {
 963                 @cmd = ($mua, '-f');
 964         # TODO: help wanted: other common FOSS MUAs
 965         } else {
 966                 require Text::ParseWords;
 967                 @cmd = Text::ParseWords::shellwords($mua);
 968                 # mutt uses '%f' for open-hook with compressed mbox, we follow
 969                 @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 970         }
 971         push @cmd, $mfolder unless defined($replaced);
 972         if ($self->{sock}) { # lei(1) client process runs it
 973                 # restore terminal: echo $query | lei q --stdin --mua=...
 974                 my $io = [];
 975                 $io->[0] = $self->{1} if $self->{opt}->{stdin} && -t $self->{1};
 976                 send_exec_cmd($self, $io, \@cmd, {});
 977         }
 978         if ($self->{lxs} && $self->{au_done}) { # kick wait_startq
 979                 syswrite($self->{au_done}, 'q' x ($self->{lxs}->{jobs} // 0));
 980         }
 981         return unless -t $self->{2}; # XXX how to determine non-TUI MUAs?
 982         $self->{opt}->{quiet} = 1;
 983         delete $self->{-progress};
 984         delete $self->{opt}->{verbose};
 985 }
 986
 987 sub send_exec_cmd { # tell script/lei to execute a command
 988         my ($self, $io, $cmd, $env) = @_;
 989         my $sock = $self->{sock} // die 'lei client gone';
 990         my $fds = [ map { fileno($_) } @$io ];
 991         $send_cmd->($sock, $fds, exec_buf($cmd, $env), MSG_EOR);
 992 }
 993
 994 sub poke_mua { # forces terminal MUAs to wake up and hopefully notice new mail
 995         my ($self) = @_;
 996         my $alerts = $self->{opt}->{alert} // return;
 997         my $sock = $self->{sock};
 998         while (my $op = shift(@$alerts)) {
 999                 if ($op eq ':WINCH') {
1000                         # hit the process group that started the MUA
1001                         send($sock, '-WINCH', MSG_EOR) if $sock;
1002                 } elsif ($op eq ':bell') {
1003                         out($self, "\a");
1004                 } elsif ($op =~ /(?<!\\),/) { # bare ',' (not ',,')
1005                         push @$alerts, split(/(?<!\\),/, $op);
1006                 } elsif ($op =~ m!\A([/a-z0-9A-Z].+)!) {
1007                         my $cmd = $1; # run an arbitrary command
1008                         require Text::ParseWords;
1009                         $cmd = [ Text::ParseWords::shellwords($cmd) ];
1010                         send($sock, exec_buf($cmd, {}), MSG_EOR) if $sock;
1011                 } else {
1012                         err($self, "W: unsupported --alert=$op"); # non-fatal
1013                 }
1014         }
1015 }
1016
1017 my %path_to_fd = ('/dev/stdin' => 0, '/dev/stdout' => 1, '/dev/stderr' => 2);
1018 $path_to_fd{"/dev/fd/$_"} = $_ for (0..2);
1019
1020 # this also normalizes the path
1021 sub path_to_fd {
1022         my ($self, $path) = @_;
1023         $path = rel2abs($self, $path);
1024         $path =~ tr!/!/!s;
1025         $path_to_fd{$path} // (
1026                 ($path =~ m!\A/(?:dev|proc/self)/fd/[0-9]+\z!) ?
1027                         fail($self, "cannot open $path from daemon") : -1
1028         );
1029 }
1030
1031 # caller needs to "-t $self->{1}" to check if tty
1032 sub start_pager {
1033         my ($self, $new_env) = @_;
1034         my $fh = popen_rd([qw(git var GIT_PAGER)]);
1035         chomp(my $pager = <$fh> // '');
1036         close($fh) or warn "`git var PAGER' error: \$?=$?";
1037         return if $pager eq 'cat' || $pager eq '';
1038         $new_env //= {};
1039         $new_env->{LESS} //= 'FRX';
1040         $new_env->{LV} //= '-c';
1041         $new_env->{MORE} = $new_env->{LESS} if $^O eq 'freebsd';
1042         pipe(my ($r, $wpager)) or return warn "pipe: $!";
1043         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
1044         my $pgr = [ undef, @$rdr{1, 2} ];
1045         my $env = $self->{env};
1046         if ($self->{sock}) { # lei(1) process runs it
1047                 delete @$new_env{keys %$env}; # only set iff unset
1048                 send_exec_cmd($self, [ @$rdr{0..2} ], [$pager], $new_env);
1049         } else {
1050                 die 'BUG: start_pager w/o socket';
1051         }
1052         $self->{1} = $wpager;
1053         $self->{2} = $wpager if -t $self->{2};
1054         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
1055         $self->{pgr} = $pgr;
1056 }
1057
1058 # display a message for user before spawning full-screen $VISUAL
1059 sub pgr_err {
1060         my ($self, @msg) = @_;
1061         return $self->err(@msg) unless $self->{sock} && -t $self->{2};
1062         start_pager($self, { LESS => 'RX' }); # no 'F' so we prompt
1063         print { $self->{2} } @msg;
1064         $self->{2}->autoflush(1);
1065         stop_pager($self);
1066         send($self->{sock}, 'wait', MSG_EOR); # wait for user to quit pager
1067 }
1068
1069 sub stop_pager {
1070         my ($self) = @_;
1071         my $pgr = delete($self->{pgr}) or return;
1072         $self->{2} = $pgr->[2];
1073         close(delete($self->{1})) if $self->{1};
1074         $self->{1} = $pgr->[1];
1075 }
1076
1077 sub accept_dispatch { # Listener {post_accept} callback
1078         my ($sock) = @_; # ignore other
1079         $sock->autoflush(1);
1080         my $self = bless { sock => $sock }, __PACKAGE__;
1081         vec(my $rvec = '', fileno($sock), 1) = 1;
1082         select($rvec, undef, undef, 60) or
1083                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
1084         # (4096 * 33) >MAX_ARG_STRLEN
1085         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33) or return; # EOF
1086         if (!defined($fds[0])) {
1087                 warn(my $msg = "recv_cmd failed: $!");
1088                 return send($sock, $msg, MSG_EOR);
1089         } else {
1090                 my $i = 0;
1091                 for my $fd (@fds) {
1092                         open($self->{$i++}, '+<&=', $fd) and next;
1093                         send($sock, "open(+<&=$fd) (FD=$i): $!", MSG_EOR);
1094                 }
1095                 $i == 4 or return send($sock, 'not enough FDs='.($i-1), MSG_EOR)
1096         }
1097         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
1098         # $buf = "$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
1099         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
1100                 return send($sock, 'request command truncated', MSG_EOR);
1101         my ($argc, @argv) = split(/\0/, $buf, -1);
1102         undef $buf;
1103         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
1104         $self->{env} = \%env;
1105         eval { dispatch($self, @argv) };
1106         send($sock, $@, MSG_EOR) if $@;
1107 }
1108
1109 sub dclose {
1110         my ($self) = @_;
1111         delete $self->{-progress};
1112         _drop_wq($self) if $self->{failed};
1113         $self->close if $self->{-event_init_done}; # PublicInbox::DS::close
1114 }
1115
1116 # for long-running results
1117 sub event_step {
1118         my ($self) = @_;
1119         local %ENV = %{$self->{env}};
1120         local $current_lei = $self;
1121         eval {
1122                 my $buf;
1123                 while (my @fds = $recv_cmd->($self->{sock}, $buf, 4096)) {
1124                         if (scalar(@fds) == 1 && !defined($fds[0])) {
1125                                 return if $! == EAGAIN;
1126                                 next if $! == EINTR;
1127                                 last if $! == ECONNRESET;
1128                                 die "recvmsg: $!";
1129                         }
1130                         for (@fds) { open my $rfh, '+<&=', $_ }
1131                 }
1132                 if ($buf eq '') {
1133                         _drop_wq($self); # EOF, client disconnected
1134                         dclose($self);
1135                 } elsif ($buf =~ /\A(STOP|CONT)\z/) {
1136                         for my $wq (grep(defined, @$self{@WQ_KEYS})) {
1137                                 $wq->wq_kill($buf) or $wq->wq_kill_old($buf);
1138                         }
1139                 } else {
1140                         die "unrecognized client signal: $buf";
1141                 }
1142         };
1143         if (my $err = $@) {
1144                 eval { $self->fail($err) };
1145                 dclose($self);
1146         }
1147 }
1148
1149 sub event_step_init {
1150         my ($self) = @_;
1151         my $sock = $self->{sock} or return;
1152         $self->{-event_init_done} //= do { # persist til $ops done
1153                 $sock->blocking(0);
1154                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
1155                 $sock;
1156         };
1157 }
1158
1159 sub noop {}
1160
1161 sub oldset { $oldset }
1162
1163 sub dump_and_clear_log {
1164         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
1165                 openlog('lei-daemon', 'pid,nowait,nofatal,ndelay', 'user');
1166                 chomp(my @lines = <STDIN>);
1167                 truncate(STDIN, 0) or
1168                         syslog('warning', "ftruncate (%s): %m", $errors_log);
1169                 for my $l (@lines) { syslog('warning', '%s', $l) }
1170                 closelog(); # don't share across fork
1171         }
1172 }
1173
1174 sub cfg2lei ($) {
1175         my ($cfg) = @_;
1176         my $lei = bless { env => { %{$cfg->{-env}} } }, __PACKAGE__;
1177         open($lei->{0}, '<&', \*STDIN) or die "dup 0: $!";
1178         open($lei->{1}, '>>&', \*STDOUT) or die "dup 1: $!";
1179         open($lei->{2}, '>>&', \*STDERR) or die "dup 2: $!";
1180         open($lei->{3}, '/') or die "open /: $!";
1181         my ($x, $y);
1182         socketpair($x, $y, AF_UNIX, SOCK_SEQPACKET, 0) or die "socketpair: $!";
1183         $lei->{sock} = $x;
1184         require PublicInbox::LeiSelfSocket;
1185         PublicInbox::LeiSelfSocket->new($y); # adds to event loop
1186         $lei;
1187 }
1188
1189 sub dir_idle_handler ($) { # PublicInbox::DirIdle callback
1190         my ($ev) = @_; # Linux::Inotify2::Event or duck type
1191         my $fn = $ev->fullname;
1192         if ($fn =~ m!\A(.+)/(new|cur)/([^/]+)\z!) { # Maildir file
1193                 my ($mdir, $nc, $bn) = ($1, $2, $3);
1194                 $nc = '' if $ev->IN_DELETE;
1195                 for my $f (keys %{$MDIR2CFGPATH->{$mdir} // {}}) {
1196                         my $cfg = $PATH2CFG{$f} // next;
1197                         eval {
1198                                 my $lei = cfg2lei($cfg);
1199                                 $lei->dispatch('note-event',
1200                                                 "maildir:$mdir", $nc, $bn, $fn);
1201                         };
1202                         warn "E: note-event $f: $@\n" if $@;
1203                 }
1204         }
1205         if ($ev->can('cancel') && ($ev->IN_IGNORE || $ev->IN_UNMOUNT)) {
1206                 $ev->cancel;
1207         }
1208         if ($fn =~ m!\A(.+)/(?:new|cur)\z! && !-e $fn) {
1209                 delete $MDIR2CFGPATH->{$1};
1210         }
1211         if (!-e $fn) { # config file or Maildir gone
1212                 for my $cfgpaths (values %$MDIR2CFGPATH) {
1213                         delete $cfgpaths->{$fn};
1214                 }
1215                 delete $PATH2CFG{$fn};
1216         }
1217 }
1218
1219 # lei(1) calls this when it can't connect
1220 sub lazy_start {
1221         my ($path, $errno, $narg) = @_;
1222         local ($errors_log, $listener);
1223         my ($sock_dir) = ($path =~ m!\A(.+?)/[^/]+\z!);
1224         $errors_log = "$sock_dir/errors.log";
1225         my $addr = pack_sockaddr_un($path);
1226         my $lk = bless { lock_path => $errors_log }, 'PublicInbox::Lock';
1227         umask(077) // die("umask(077): $!");
1228         $lk->lock_acquire;
1229         socket($listener, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
1230         if ($errno == ECONNREFUSED || $errno == ENOENT) {
1231                 return if connect($listener, $addr); # another process won
1232                 if ($errno == ECONNREFUSED && -S $path) {
1233                         unlink($path) or die "unlink($path): $!";
1234                 }
1235         } else {
1236                 $! = $errno; # allow interpolation to stringify in die
1237                 die "connect($path): $!";
1238         }
1239         bind($listener, $addr) or die "bind($path): $!";
1240         $lk->lock_release;
1241         undef $lk;
1242         my @st = stat($path) or die "stat($path): $!";
1243         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
1244         local $oldset = PublicInbox::DS::block_signals();
1245         if ($narg == 5) {
1246                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
1247                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
1248                         require PublicInbox::CmdIPC4;
1249                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
1250                         PublicInbox::CmdIPC4->can('recv_cmd4');
1251                 };
1252         }
1253         $recv_cmd or die <<"";
1254 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
1255
1256         require PublicInbox::Listener;
1257         require PublicInbox::PktOp;
1258         (-p STDOUT) or die "E: stdout must be a pipe\n";
1259         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
1260         STDIN->autoflush(1);
1261         dump_and_clear_log();
1262         POSIX::setsid() > 0 or die "setsid: $!";
1263         my $pid = fork // die "fork: $!";
1264         return if $pid;
1265         $0 = "lei-daemon $path";
1266         local %PATH2CFG;
1267         local $MDIR2CFGPATH;
1268         $listener->blocking(0);
1269         my $exit_code;
1270         my $pil = PublicInbox::Listener->new($listener, \&accept_dispatch);
1271         local $quit = do {
1272                 my (undef, $eof_p) = PublicInbox::PktOp->pair;
1273                 sub {
1274                         $exit_code //= shift;
1275                         eval 'PublicInbox::LeiNoteEvent::flush_task()';
1276                         my $lis = $pil or exit($exit_code);
1277                         # closing eof_p triggers \&noop wakeup
1278                         $listener = $eof_p = $pil = $path = undef;
1279                         $lis->close; # DS::close
1280                         PublicInbox::DS->SetLoopTimeout(1000);
1281                 };
1282         };
1283         my $sig = {
1284                 CHLD => \&PublicInbox::DS::enqueue_reap,
1285                 QUIT => $quit,
1286                 INT => $quit,
1287                 TERM => $quit,
1288                 HUP => \&noop,
1289                 USR1 => \&noop,
1290                 USR2 => \&noop,
1291         };
1292         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
1293         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
1294         undef $sig;
1295         local $SIG{PIPE} = 'IGNORE';
1296         require PublicInbox::DirIdle;
1297         local $dir_idle = PublicInbox::DirIdle->new([$sock_dir], sub {
1298                 # just rely on wakeup to hit PostLoopCallback set below
1299                 dir_idle_handler($_[0]) if $_[0]->fullname ne $path;
1300         }, 1);
1301         if ($sigfd) {
1302                 undef $sigfd; # unref, already in DS::DescriptorMap
1303         } else {
1304                 # wake up every second to accept signals if we don't
1305                 # have signalfd or IO::KQueue:
1306                 PublicInbox::DS::sig_setmask($oldset);
1307                 PublicInbox::DS->SetLoopTimeout(1000);
1308         }
1309         PublicInbox::DS->SetPostLoopCallback(sub {
1310                 my ($dmap, undef) = @_;
1311                 if (@st = defined($path) ? stat($path) : ()) {
1312                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
1313                                 warn "$path dev/ino changed, quitting\n";
1314                                 $path = undef;
1315                         }
1316                 } elsif (defined($path)) { # ENOENT is common
1317                         warn "stat($path): $!, quitting ...\n" if $! != ENOENT;
1318                         undef $path;
1319                         $quit->();
1320                 }
1321                 return 1 if defined($path);
1322                 my $now = now();
1323                 my $n = 0;
1324                 for my $s (values %$dmap) {
1325                         $s->can('busy') or next;
1326                         if ($s->busy($now)) {
1327                                 ++$n;
1328                         } else {
1329                                 $s->close;
1330                         }
1331                 }
1332                 $n; # true: continue, false: stop
1333         });
1334
1335         # STDIN was redirected to /dev/null above, closing STDERR and
1336         # STDOUT will cause the calling `lei' client process to finish
1337         # reading the <$daemon> pipe.
1338         local $SIG{__WARN__} = sub {
1339                 $current_lei ? err($current_lei, @_) : warn(
1340                   strftime('%Y-%m-%dT%H:%M:%SZ', gmtime(time))," $$ ", @_);
1341         };
1342         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
1343         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
1344         # $daemon pipe to `lei' closed, main loop begins:
1345         eval { PublicInbox::DS->EventLoop };
1346         warn "event loop error: $@\n" if $@;
1347         dump_and_clear_log();
1348         exit($exit_code // 0);
1349 }
1350
1351 sub busy { 1 } # prevent daemon-shutdown if client is connected
1352
1353 # ensures stdout hits the FS before sock disconnects so a client
1354 # can immediately reread it
1355 sub DESTROY {
1356         my ($self) = @_;
1357         if (my $counters = delete $self->{counters}) {
1358                 for my $k (sort keys %$counters) {
1359                         my $nr = $counters->{$k};
1360                         $self->child_error(0, "$nr $k messages");
1361                 }
1362         }
1363         $self->{1}->autoflush(1) if $self->{1};
1364         stop_pager($self);
1365         dump_and_clear_log();
1366         # preserve $? for ->fail or ->x_it code
1367 }
1368
1369 sub wq_done_wait { # dwaitpid callback
1370         my ($arg, $pid) = @_;
1371         my ($wq, $lei) = @$arg;
1372         my $err_type = $lei->{-err_type};
1373         $? and $lei->child_error($?,
1374                         $err_type ? "$err_type errors during $lei->{cmd}" : ());
1375         $lei->dclose;
1376 }
1377
1378 sub fchdir {
1379         my ($lei) = @_;
1380         my $dh = $lei->{3} // die 'BUG: lei->{3} (CWD) gone';
1381         chdir($dh) || $lei->fail("fchdir: $!");
1382 }
1383
1384 sub wq_eof { # EOF callback for main daemon
1385         my ($lei) = @_;
1386         my $wq1 = delete $lei->{wq1} // return $lei->fail; # already failed
1387         $wq1->wq_wait_old(\&wq_done_wait, $lei);
1388 }
1389
1390 sub watch_state_ok ($) {
1391         my ($state) = $_[-1]; # $_[0] may be $self
1392         $state =~ /\Apause|(?:import|index|tag)-(?:ro|rw)\z/;
1393 }
1394
1395 sub cancel_maildir_watch ($$) {
1396         my ($d, $cfg_f) = @_;
1397         my $w = delete $MDIR2CFGPATH->{$d}->{$cfg_f};
1398         scalar(keys %{$MDIR2CFGPATH->{$d}}) or
1399                 delete $MDIR2CFGPATH->{$d};
1400         for my $x (@{$w // []}) { $x->cancel }
1401 }
1402
1403 sub add_maildir_watch ($$) {
1404         my ($d, $cfg_f) = @_;
1405         if (!exists($MDIR2CFGPATH->{$d}->{$cfg_f})) {
1406                 my @w = $dir_idle->add_watches(["$d/cur", "$d/new"], 1);
1407                 push @{$MDIR2CFGPATH->{$d}->{$cfg_f}}, @w if @w;
1408         }
1409 }
1410
1411 sub refresh_watches {
1412         my ($lei) = @_;
1413         my $cfg = _lei_cfg($lei) or return;
1414         my $old = $cfg->{-watches};
1415         my $watches = $cfg->{-watches} //= {};
1416         my %seen;
1417         my $cfg_f = $cfg->{'-f'};
1418         for my $w (grep(/\Awatch\..+\.state\z/, keys %$cfg)) {
1419                 my $url = substr($w, length('watch.'), -length('.state'));
1420                 require PublicInbox::LeiWatch;
1421                 $watches->{$url} //= PublicInbox::LeiWatch->new($url);
1422                 $seen{$url} = undef;
1423                 my $state = $cfg->get_1("watch.$url", 'state');
1424                 if (!watch_state_ok($state)) {
1425                         $lei->err("watch.$url.state=$state not supported");
1426                         next;
1427                 }
1428                 if ($url =~ /\Amaildir:(.+)/i) {
1429                         my $d = canonpath_harder($1);
1430                         if ($state eq 'pause') {
1431                                 cancel_maildir_watch($d, $cfg_f);
1432                         } else {
1433                                 add_maildir_watch($d, $cfg_f);
1434                         }
1435                 } else { # TODO: imap/nntp/jmap
1436                         $lei->child_error(0, "E: watch $url not supported, yet")
1437                 }
1438         }
1439
1440         # add all known Maildir folders as implicit watches
1441         my $lms = $lei->lms;
1442         if ($lms) {
1443                 $lms->lms_write_prepare;
1444                 for my $d ($lms->folders('maildir:')) {
1445                         substr($d, 0, length('maildir:')) = '';
1446
1447                         # fixup old bugs while we're iterating:
1448                         my $cd = canonpath_harder($d);
1449                         my $f = "maildir:$cd";
1450                         $lms->rename_folder("maildir:$d", $f) if $d ne $cd;
1451                         next if $watches->{$f}; # may be set to pause
1452                         require PublicInbox::LeiWatch;
1453                         $watches->{$f} = PublicInbox::LeiWatch->new($f);
1454                         $seen{$f} = undef;
1455                         add_maildir_watch($cd, $cfg_f);
1456                 }
1457         }
1458         if ($old) { # cull old non-existent entries
1459                 for my $url (keys %$old) {
1460                         next if exists $seen{$url};
1461                         delete $old->{$url};
1462                         if ($url =~ /\Amaildir:(.+)/i) {
1463                                 my $d = canonpath_harder($1);
1464                                 cancel_maildir_watch($d, $cfg_f);
1465                         } else { # TODO: imap/nntp/jmap
1466                                 $lei->child_error(0, "E: watch $url TODO");
1467                         }
1468                 }
1469         }
1470         if (scalar keys %$watches) {
1471                 $cfg->{-env} //= { %{$lei->{env}}, PWD => '/' }; # for cfg2lei
1472         } else {
1473                 delete $cfg->{-watches};
1474         }
1475 }
1476
1477 # TODO: support SHA-256
1478 sub git_oid {
1479         my $eml = $_[-1];
1480         $eml->header_set($_) for @PublicInbox::Import::UNWANTED_HEADERS;
1481         git_sha(1, $eml);
1482 }
1483
1484 sub lms {
1485         my ($lei, $rw) = @_;
1486         my $sto = $lei->{sto} // _lei_store($lei) // return;
1487         require PublicInbox::LeiMailSync;
1488         my $f = "$sto->{priv_eidx}->{topdir}/mail_sync.sqlite3";
1489         (-f $f || $rw) ? PublicInbox::LeiMailSync->new($f) : undef;
1490 }
1491
1492 sub sto_done_request {
1493         my ($lei, $sock) = @_;
1494         eval {
1495                 if ($sock //= $lei->{sock}) { # issue, async wait
1496                         $lei->{sto}->wq_io_do('done', [ $sock ]);
1497                 } else { # forcibly wait
1498                         my $wait = $lei->{sto}->wq_do('done');
1499                 }
1500         };
1501         $lei->err($@) if $@;
1502 }
1503
1504 sub cfg_dump ($$) {
1505         my ($lei, $f) = @_;
1506         my $ret = eval { PublicInbox::Config->git_config_dump($f, $lei->{2}) };
1507         return $ret if !$@;
1508         $lei->err($@);
1509         undef;
1510 }
1511
1512 1;