lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use POSIX ();
  17 use IO::Handle ();
  18 use Sys::Syslog qw(syslog openlog);
  19 use PublicInbox::Config;
  20 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  21 use PublicInbox::Sigfd;
  22 use PublicInbox::DS qw(now dwaitpid);
  23 use PublicInbox::Spawn qw(spawn run_die popen_rd);
  24 use PublicInbox::OnDestroy;
  25 use Text::Wrap qw(wrap);
  26 use File::Path qw(mkpath);
  27 use File::Spec;
  28 our $quit = \&CORE::exit;
  29 our $current_lei;
  30 my ($recv_cmd, $send_cmd);
  31 my $GLP = Getopt::Long::Parser->new;
  32 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  33 my $GLP_PASS = Getopt::Long::Parser->new;
  34 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  35
  36 our %PATH2CFG; # persistent for socket daemon
  37 our @TO_CLOSE_ATFORK_CHILD;
  38
  39 # TBD: this is a documentation mechanism to show a subcommand
  40 # (may) pass options through to another command:
  41 sub pass_through { $GLP_PASS }
  42
  43 my $OPT;
  44 sub opt_dash ($$) {
  45         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  46         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  47         my $cb = sub { # Getopt::Long "<>" catch-all handler
  48                 my ($arg) = @_;
  49                 if ($arg =~ /\A-($re_str)\z/) {
  50                         $OPT->{$key} = $1;
  51                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  52                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  53                 # lone (single) dash is handled elsewhere
  54                 } elsif (substr($arg, 0, 1) eq '-') {
  55                         if ($OPT->{'--'}) {
  56                                 push @{$OPT->{-argv}}, $arg;
  57                         } else {
  58                                 die "bad argument: $arg\n";
  59                         }
  60                 } else {
  61                         push @{$OPT->{-argv}}, $arg;
  62                 }
  63         };
  64         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  65 }
  66
  67 sub _store_path ($) {
  68         my ($env) = @_;
  69         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  70                 ($env->{HOME} // '/nonexistent').'/.local/share')
  71                 .'/lei/store', $env->{PWD});
  72 }
  73
  74 sub _config_path ($) {
  75         my ($env) = @_;
  76         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  77                 ($env->{HOME} // '/nonexistent').'/.config')
  78                 .'/lei/config', $env->{PWD});
  79 }
  80
  81 # TODO: generate shell completion + help using %CMD and %OPTDESC
  82 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  83 our %CMD = ( # sorted in order of importance/use:
  84 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  85         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  86         sort|s=s reverse|r offset=i remote local! external! pretty mua-cmd=s
  87         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  88
  89 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  90         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  91         pass_through('git show') ],
  92
  93 'add-external' => [ 'URL_OR_PATHNAME',
  94         'add/set priority of a publicinbox|extindex for extra matches',
  95         qw(boost=i quiet|q) ],
  96 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  97         qw(format|f=s z|0 local remote quiet|q) ],
  98 'forget-external' => [ '{URL_OR_PATHNAME|--prune}',
  99         'exclude further results from a publicinbox|extindex',
 100         qw(prune quiet|q) ],
 101
 102 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 103                 qw(name-only format|f=s z) ],
 104 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 105 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 106
 107 'plonk' => [ '--thread|--from=IDENT',
 108         'exclude mail matching From: or thread from non-Message-ID searches',
 109         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 110 'mark' => [ 'MESSAGE_FLAGS...',
 111         'set/unset flags on message(s) from stdin',
 112         qw(stdin| oid=s exact by-mid|mid:s) ],
 113 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 114         "exclude message(s) on stdin from `q' search results",
 115         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 116
 117 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 118         'remove imported messages from IMAP, Maildirs, and MH',
 119         qw(exact! all jobs:i indexed) ],
 120
 121 # code repos are used for `show' to solve blobs from patch mails
 122 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 123         qw(boost=i) ],
 124 'ls-coderepo' => [ '[FILTER_TERMS...]',
 125                 'list known code repos', qw(format|f=s z) ],
 126 'forget-coderepo' => [ 'PATHNAME',
 127         'stop using repo to solve blobs from patches',
 128         qw(prune) ],
 129
 130 'add-watch' => [ '[URL_OR_PATHNAME]',
 131                 'watch for new messages and flag changes',
 132         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 133 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 134                 qw(format|f=s z) ],
 135 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 136 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 137 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 138         qw(prune) ],
 139
 140 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 141         'one-shot import/update from URL or filesystem',
 142         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 143         ],
 144
 145 'config' => [ '[...]', sub {
 146                 'git-config(1) wrapper for '._config_path($_[0]);
 147         }, qw(config-file|system|global|file|f=s), # for conflict detection
 148         pass_through('git config') ],
 149 'init' => [ '[PATHNAME]', sub {
 150                 'initialize storage, default: '._store_path($_[0]);
 151         }, qw(quiet|q) ],
 152 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 153         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 154 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 155 'help' => [ '[SUBCOMMAND]', 'show help' ],
 156
 157 # XXX do we need this?
 158 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 159
 160 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 161         'rewrite git history in an attempt to improve compression',
 162         'gc!' ],
 163
 164 # internal commands are prefixed with '_'
 165 '_complete' => [ '[...]', 'internal shell completion helper',
 166                 pass_through('everything') ],
 167 ); # @CMD
 168
 169 # switch descriptions, try to keep consistent across commands
 170 # $spec: Getopt::Long option specification
 171 # $spec => [@ALLOWED_VALUES (default is first), $description],
 172 # $spec => $description
 173 # "$SUB_COMMAND TAB $spec" => as above
 174 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 175                 'specify message input format' ];
 176 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 177
 178 my %OPTDESC = (
 179 'help|h' => 'show this built-in help',
 180 'quiet|q' => 'be quiet',
 181 'solve!' => 'do not attempt to reconstruct blobs from emails',
 182 'save-as=s' => ['NAME', 'save a search terms by given name'],
 183
 184 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 185
 186 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 187                 'deduplication strategy'],
 188 'show   thread|t' => 'display entire thread a message belongs to',
 189 'q      thread|t' =>
 190         'return all messages in the same thread as the actual match(es)',
 191 'augment|a' => 'augment --output destination instead of clobbering',
 192
 193 'output|o=s' => [ 'DEST',
 194         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 195 'mua-cmd|mua=s' => [ 'COMMAND',
 196         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 197
 198 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 199                         'message/object output format' ],
 200 'mark   format|f=s' => $stdin_formats,
 201 'forget format|f=s' => $stdin_formats,
 202 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 203                 'specify output format, default depends on --output'],
 204 'ls-query       format|f=s' => $ls_format,
 205 'ls-external    format|f=s' => $ls_format,
 206
 207 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 208 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 209
 210 'sort|s=s' => [ 'VAL|received,relevance,docid',
 211                 "order of results `--output'-dependent"],
 212 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 213
 214 'boost=i' => 'increase/decrease priority of results (default: 0)',
 215
 216 'local' => 'limit operations to the local filesystem',
 217 'local!' => 'exclude results from the local filesystem',
 218 'remote' => 'limit operations to those requiring network access',
 219 'remote!' => 'prevent operations requiring network access',
 220
 221 'mid=s' => 'specify the Message-ID of a message',
 222 'oid=s' => 'specify the git object ID of a message',
 223
 224 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 225 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 226 'include=s' => 'include mailboxes/newsgroups based on pattern',
 227
 228 'exact' => 'operate on exact header matches only',
 229 'exact!' => 'rely on content match instead of exact header matches',
 230
 231 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 232 'jobs:i' => 'set parallelism level',
 233
 234 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 235 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 236
 237 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 238 ); # %OPTDESC
 239
 240 my %CONFIG_KEYS = (
 241         'leistore.dir' => 'top-level storage location',
 242 );
 243
 244 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 245 sub x_it ($$) {
 246         my ($self, $code) = @_;
 247         # make sure client sees stdout before exit
 248         $self->{1}->autoflush(1) if $self->{1};
 249         if (my $sock = $self->{sock}) {
 250                 send($sock, "x_it $code", MSG_EOR);
 251         } elsif (!($code & 127)) { # oneshot, ignore signals
 252                 # don't want to end up using $? from child processes
 253                 for my $f (qw(lxs l2m)) {
 254                         my $wq = delete $self->{$f} or next;
 255                         $wq->DESTROY;
 256                 }
 257                 $quit->($code >> 8);
 258         }
 259 }
 260
 261 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 262
 263 sub out ($;@) { print { shift->{1} } @_ }
 264
 265 sub err ($;@) {
 266         my $self = shift;
 267         my $err = $self->{2} // *STDERR{IO};
 268         print $err @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 269 }
 270
 271 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 272
 273 sub fail ($$;$) {
 274         my ($self, $buf, $exit_code) = @_;
 275         err($self, $buf);
 276         x_it($self, ($exit_code // 1) << 8);
 277         undef;
 278 }
 279
 280 sub atfork_prepare_wq {
 281         my ($self, $wq) = @_;
 282         my $tcafc = $wq->{-ipc_atfork_child_close};
 283         push @$tcafc, @TO_CLOSE_ATFORK_CHILD;
 284         if (my $sock = $self->{sock}) {
 285                 push @$tcafc, @$self{qw(0 1 2)}, $sock;
 286         }
 287         for my $f (qw(lxs l2m)) {
 288                 my $ipc = $self->{$f} or next;
 289                 push @$tcafc, grep { defined }
 290                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 291         }
 292 }
 293
 294 # usage: my %sig = $lei->atfork_child_wq($wq);
 295 #        local @SIG{keys %sig} = values %sig;
 296 sub atfork_child_wq {
 297         my ($self, $wq) = @_;
 298         my ($sock, $l2m_wq_s1);
 299         (@$self{qw(0 1 2)}, $sock, $l2m_wq_s1) = delete(@$wq{0..4});
 300         $self->{sock} = $sock if -S $sock;
 301         $self->{l2m}->{-wq_s1} = $l2m_wq_s1 if $l2m_wq_s1 && -S $l2m_wq_s1;
 302         %PATH2CFG = ();
 303         $quit = \&CORE::exit;
 304         @TO_CLOSE_ATFORK_CHILD = ();
 305         (__WARN__ => sub { err($self, @_) },
 306         PIPE => sub {
 307                 $self->x_it(13); # SIGPIPE = 13
 308                 # we need to close explicitly to avoid Perl warning on SIGPIPE
 309                 for my $i (1, 2) {
 310                         next unless $self->{$i} && (-p $self->{$i} || -S _);
 311                         close(delete $self->{$i});
 312                 }
 313                 # trigger the LeiXSearch $done OpPipe:
 314                 syswrite($self->{0}, '!') if $self->{0} && -p $self->{0};
 315                 $SIG{PIPE} = 'DEFAULT';
 316                 die bless(\"$_[0]", 'PublicInbox::SIGPIPE'),
 317         });
 318 }
 319
 320 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 321 sub atfork_parent_wq {
 322         my ($self, $wq) = @_;
 323         my $env = delete $self->{env}; # env is inherited at fork
 324         my $ret = bless { %$self }, ref($self);
 325         if (my $dedupe = delete $ret->{dedupe}) {
 326                 $ret->{dedupe} = $wq->deep_clone($dedupe);
 327         }
 328         $self->{env} = $env;
 329         delete @$ret{qw(-lei_store cfg pgr lxs)}; # keep l2m
 330         my @io = delete @$ret{0..2};
 331         $io[3] = delete($ret->{sock}) // *STDERR{GLOB};
 332         my $l2m = $ret->{l2m};
 333         if ($l2m && $l2m != $wq) { # $wq == lxs
 334                 $io[4] = $l2m->{-wq_s1} if $l2m->{-wq_s1};
 335                 if (my @pids = $l2m->wq_close) {
 336                         $wq->{l2m_pids} = \@pids;
 337                 }
 338         }
 339         ($ret, @io);
 340 }
 341
 342 sub _help ($;$) {
 343         my ($self, $errmsg) = @_;
 344         my $cmd = $self->{cmd} // 'COMMAND';
 345         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 346         my @top = ($cmd, shift(@info) // ());
 347         my $cmd_desc = shift(@info);
 348         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 349         my @opt_desc;
 350         my $lpad = 2;
 351         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 352                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 353                 my $arg_vals = '';
 354                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 355
 356                 # lower-case is a keyword (e.g. `content', `oid'),
 357                 # ALL_CAPS is a string description (e.g. `PATH')
 358                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 359                         $desc .= "\ndefault: `$1'";
 360                 }
 361                 my (@vals, @s, @l);
 362                 my $x = $sw;
 363                 if ($x =~ s/!\z//) { # solve! => --no-solve
 364                         $x = "no-$x";
 365                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 366                         @vals = (' [', undef, ']');
 367                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 368                         @vals = (' ', undef);
 369                 } # else: no args $x = 'thread|t'
 370                 for (split(/\|/, $x)) { # help|h
 371                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 372                 }
 373                 if (!scalar(@vals)) { # no args 'thread|t'
 374                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 375                         $vals[1] = $1;
 376                 } else {
 377                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 378                 }
 379                 if ($arg_vals =~ /([,\|])/) {
 380                         my $sep = $1;
 381                         my @allow = split(/\Q$sep\E/, $arg_vals);
 382                         my $must = $sep eq '|' ? 'Must' : 'Can';
 383                         @allow = map { "`$_'" } @allow;
 384                         my $last = pop @allow;
 385                         $desc .= "\n$must be one of: " .
 386                                 join(', ', @allow) . " or $last";
 387                 }
 388                 my $lhs = join(', ', @s, @l) . join('', @vals);
 389                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 390                         $lhs =~ s/\A--/- , --/;
 391                 } else {
 392                         $lhs =~ s/\A--/    --/; # pad if no short options
 393                 }
 394                 $lpad = length($lhs) if length($lhs) > $lpad;
 395                 push @opt_desc, $lhs, $desc;
 396         }
 397         my $msg = $errmsg ? "E: $errmsg\n" : '';
 398         $msg .= <<EOF;
 399 usage: lei @top
 400   $cmd_desc
 401
 402 EOF
 403         $lpad += 2;
 404         local $Text::Wrap::columns = 78 - $lpad;
 405         my $padding = ' ' x ($lpad + 2);
 406         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 407                 $msg .= '  '.pack("A$lpad", $lhs);
 408                 $rhs = wrap('', '', $rhs);
 409                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 410                 $msg .= $rhs;
 411                 $msg .= "\n";
 412         }
 413         print { $self->{$errmsg ? 2 : 1} } $msg;
 414         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 415         undef;
 416 }
 417
 418 sub optparse ($$$) {
 419         my ($self, $cmd, $argv) = @_;
 420         $self->{cmd} = $cmd;
 421         $OPT = $self->{opt} = {};
 422         my $info = $CMD{$cmd} // [ '[...]' ];
 423         my ($proto, undef, @spec) = @$info;
 424         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 425         push @spec, qw(help|h);
 426         my $lone_dash;
 427         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 428                 $lone_dash = $spec[0];
 429                 $OPT->{$spec[0]} = \(my $var);
 430                 push @spec, '' => \$var;
 431         }
 432         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 433                 return _help($self, "bad arguments or options for $cmd");
 434         return _help($self) if $OPT->{help};
 435
 436         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 437
 438         # "-" aliases "stdin" or "clear"
 439         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 440
 441         my $i = 0;
 442         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 443         my ($err, $inf);
 444         my @args = split(/ /, $proto);
 445         for my $var (@args) {
 446                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 447                         $inf = defined($argv->[$i]) and last;
 448                         $var =~ s/\.\.\.\z//;
 449                         $err = "$var not supplied";
 450                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 451                         $argv->[$i++] // ($err = "$var not supplied");
 452                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 453                         $inf = 1;
 454                         last;
 455                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 456                         $i++;
 457                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 458                         my @or = split(/\|/, $var);
 459                         my $ok;
 460                         for my $o (@or) {
 461                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 462                                         $ok = defined($OPT->{$1});
 463                                         last;
 464                                 } elsif (defined($argv->[$i])) {
 465                                         $ok = 1;
 466                                         $i++;
 467                                         last;
 468                                 } # else continue looping
 469                         }
 470                         my $last = pop @or;
 471                         $err = join(', ', @or) . " or $last must be set";
 472                 } else {
 473                         warn "BUG: can't parse `$var' in $proto";
 474                 }
 475                 last if $err;
 476         }
 477         if (!$inf && scalar(@$argv) > scalar(@args)) {
 478                 $err //= 'too many arguments';
 479         }
 480         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 481 }
 482
 483 sub dispatch {
 484         my ($self, $cmd, @argv) = @_;
 485         local $current_lei = $self; # for __WARN__
 486         return _help($self, 'no command given') unless defined($cmd);
 487         my $func = "lei_$cmd";
 488         $func =~ tr/-/_/;
 489         if (my $cb = __PACKAGE__->can($func)) {
 490                 optparse($self, $cmd, \@argv) or return;
 491                 $cb->($self, @argv);
 492         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 493                 my $opt = {};
 494                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 495                         return _help($self, 'bad arguments or options');
 496                 _help($self);
 497         } else {
 498                 fail($self, "`$cmd' is not an lei command");
 499         }
 500 }
 501
 502 sub _lei_cfg ($;$) {
 503         my ($self, $creat) = @_;
 504         my $f = _config_path($self->{env});
 505         my @st = stat($f);
 506         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 507         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 508                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 509         }
 510         if (!@st) {
 511                 unless ($creat) {
 512                         delete $self->{cfg};
 513                         return;
 514                 }
 515                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 516                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 517                 open my $fh, '>>', $f or die "open($f): $!\n";
 518                 @st = stat($fh) or die "fstat($f): $!\n";
 519                 $cur_st = pack('dd', $st[10], $st[7]);
 520                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 521         }
 522         my $cfg = PublicInbox::Config::git_config_dump($f);
 523         $cfg->{-st} = $cur_st;
 524         $cfg->{'-f'} = $f;
 525         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 526 }
 527
 528 sub _lei_store ($;$) {
 529         my ($self, $creat) = @_;
 530         my $cfg = _lei_cfg($self, $creat);
 531         $cfg->{-lei_store} //= do {
 532                 require PublicInbox::LeiStore;
 533                 my $dir = $cfg->{'leistore.dir'};
 534                 $dir //= _store_path($self->{env}) if $creat;
 535                 return unless $dir;
 536                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 537         };
 538 }
 539
 540 sub lei_show {
 541         my ($self, @argv) = @_;
 542 }
 543
 544 sub lei_mark {
 545         my ($self, @argv) = @_;
 546 }
 547
 548 sub lei_config {
 549         my ($self, @argv) = @_;
 550         $self->{opt}->{'config-file'} and return fail $self,
 551                 "config file switches not supported by `lei config'";
 552         my $env = $self->{env};
 553         delete local $env->{GIT_CONFIG};
 554         my $cfg = _lei_cfg($self, 1);
 555         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 556         my %rdr = map { $_ => $self->{$_} } (0..2);
 557         run_die($cmd, $env, \%rdr);
 558 }
 559
 560 sub lei_init {
 561         my ($self, $dir) = @_;
 562         my $cfg = _lei_cfg($self, 1);
 563         my $cur = $cfg->{'leistore.dir'};
 564         my $env = $self->{env};
 565         $dir //= _store_path($env);
 566         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 567         my @cur = stat($cur) if defined($cur);
 568         $cur = File::Spec->canonpath($cur // $dir);
 569         my @dir = stat($dir);
 570         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 571         if (@cur) {
 572                 if ($cur eq $dir) {
 573                         _lei_store($self, 1)->done;
 574                         return qerr($self, $exists);
 575                 }
 576
 577                 # some folks like symlinks and bind mounts :P
 578                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 579                         lei_config($self, 'leistore.dir', $dir);
 580                         _lei_store($self, 1)->done;
 581                         return qerr($self, "$exists (as $cur)");
 582                 }
 583                 return fail($self, <<"");
 584 E: leistore.dir=$cur already initialized and it is not $dir
 585
 586         }
 587         lei_config($self, 'leistore.dir', $dir);
 588         _lei_store($self, 1)->done;
 589         $exists //= "I: leistore.dir=$dir newly initialized";
 590         return qerr($self, $exists);
 591 }
 592
 593 sub lei_daemon_pid { puts shift, $$ }
 594
 595 sub lei_daemon_kill {
 596         my ($self) = @_;
 597         my $sig = $self->{opt}->{signal} // 'TERM';
 598         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 599 }
 600
 601 sub lei_help { _help($_[0]) }
 602
 603 # Shell completion helper.  Used by lei-completion.bash and hopefully
 604 # other shells.  Try to do as much here as possible to avoid redundancy
 605 # and improve maintainability.
 606 sub lei__complete {
 607         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 608         shift @argv; # ignore "lei", the entire command is sent
 609         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 610         my $cmd = shift @argv;
 611         my $info = $CMD{$cmd} // do { # filter matching commands
 612                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 613                 return;
 614         };
 615         my ($proto, undef, @spec) = @$info;
 616         my $cur = pop @argv;
 617         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 618         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 619                 # gross special case since the only git-config options
 620                 # Consider moving to a table if we need more special cases
 621                 # we use Getopt::Long for are the ones we reject, so these
 622                 # are the ones we don't reject:
 623                 if ($cmd eq 'config') {
 624                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 625                         @spec = qw(add z|null get get-all unset unset-all
 626                                 replace-all get-urlmatch
 627                                 remove-section rename-section
 628                                 name-only list|l edit|e
 629                                 get-color-name get-colorbool);
 630                         # fall-through
 631                 }
 632                 # TODO: arg support
 633                 puts $self, grep(/$re/, map { # generate short/long names
 634                         my $eq = '';
 635                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 636                                 $eq = '=';
 637                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 638                         } else { # negation: solve! => no-solve|solve
 639                                 s/\A(.+)!\z/no-$1|$1/;
 640                         }
 641                         map {
 642                                 length > 1 ? "--$_$eq" : "-$_"
 643                         } split(/\|/, $_, -1) # help|h
 644                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 645         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 646                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 647         }
 648         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 649         # proto parsing.
 650 }
 651
 652 sub reap_exec { # dwaitpid callback
 653         my ($self, $pid) = @_;
 654         x_it($self, $?);
 655 }
 656
 657 sub lei_git { # support passing through random git commands
 658         my ($self, @argv) = @_;
 659         my %rdr = map { $_ => $self->{$_} } (0..2);
 660         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 661         dwaitpid($pid, \&reap_exec, $self);
 662 }
 663
 664 sub exec_buf ($$) {
 665         my ($argv, $env) = @_;
 666         my $argc = scalar @$argv;
 667         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 668         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 669         $buf;
 670 }
 671
 672 sub start_mua {
 673         my ($self, $sock) = @_;
 674         my $mua = $self->{opt}->{'mua-cmd'} // return;
 675         my $mfolder = $self->{ovv}->{dst};
 676         require Text::ParseWords;
 677         my $replaced;
 678         my @cmd = Text::ParseWords::shellwords($mua);
 679         # mutt uses '%f' for open-hook with compressed folders, so we use %f
 680         @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 681         push @cmd, $mfolder unless defined($replaced);
 682         $sock //= $self->{sock};
 683         if ($sock) { # lei(1) client process runs it
 684                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 685         } else { # oneshot
 686                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 687         }
 688 }
 689
 690 # caller needs to "-t $self->{1}" to check if tty
 691 sub start_pager {
 692         my ($self) = @_;
 693         my $env = $self->{env};
 694         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 695         chomp(my $pager = <$fh> // '');
 696         close($fh) or warn "`git var PAGER' error: \$?=$?";
 697         return if $pager eq 'cat' || $pager eq '';
 698         # TODO TIOCGWINSZ
 699         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 700         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 701         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 702         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 703         my $pgr = [ undef, @$rdr{1, 2}, $$ ];
 704         if (my $sock = $self->{sock}) { # lei(1) process runs it
 705                 delete @$new_env{keys %$env}; # only set iff unset
 706                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 707                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 708         } else {
 709                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 710         }
 711         $self->{1} = $wpager;
 712         $self->{2} = $wpager if -t $self->{2};
 713         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 714         $self->{pgr} = $pgr;
 715 }
 716
 717 sub stop_pager {
 718         my ($self) = @_;
 719         my $pgr = delete($self->{pgr}) or return;
 720         $self->{2} = $pgr->[2];
 721         # do not restore original stdout, just close it so we error out
 722         close(delete($self->{1})) if $self->{1};
 723         my $pid = $pgr->[0];
 724         dwaitpid($pid, undef, $self->{sock}) if $pid && $pgr->[3] == $$;
 725 }
 726
 727 sub accept_dispatch { # Listener {post_accept} callback
 728         my ($sock) = @_; # ignore other
 729         $sock->autoflush(1);
 730         my $self = bless { sock => $sock }, __PACKAGE__;
 731         vec(my $rvec = '', fileno($sock), 1) = 1;
 732         select($rvec, undef, undef, 1) or
 733                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 734         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 735         if (scalar(@fds) == 4) {
 736                 my $i = 0;
 737                 for my $rdr (qw(<&= >&= >&= <&=)) {
 738                         my $fd = shift(@fds);
 739                         open($self->{$i++}, $rdr, $fd) and next;
 740                         send($sock, "open($rdr$fd) (FD=$i): $!", MSG_EOR);
 741                 }
 742         } else {
 743                 return send($sock, "recv_cmd failed: $!", MSG_EOR);
 744         }
 745         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 746         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 747         # $buf = "$$\0$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 748         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 749                 return send($sock, 'request command truncated', MSG_EOR);
 750         my ($argc, @argv) = split(/\0/, $buf, -1);
 751         undef $buf;
 752         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 753         if (chdir(delete($self->{3}))) {
 754                 local %ENV = %env;
 755                 $self->{env} = \%env;
 756                 eval { dispatch($self, @argv) };
 757                 send($sock, $@, MSG_EOR) if $@;
 758         } else {
 759                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 760         }
 761 }
 762
 763 sub dclose {
 764         my ($self) = @_;
 765         delete $self->{lxs}; # stops LeiXSearch queries
 766         close(delete $self->{1}) if $self->{1}; # may reap_compress
 767         $self->close if $self->{sock}; # PublicInbox::DS::close
 768 }
 769
 770 # for long-running results
 771 sub event_step {
 772         my ($self) = @_;
 773         local %ENV = %{$self->{env}};
 774         my $sock = $self->{sock};
 775         eval {
 776                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 777                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 778                                 return if $! == EAGAIN;
 779                                 next if $! == EINTR;
 780                                 last if $! == ECONNRESET;
 781                                 die "recvmsg: $!";
 782                         }
 783                         for my $fd (@fds) {
 784                                 open my $rfh, '+<&=', $fd;
 785                         }
 786                         die "unrecognized client signal: $buf";
 787                 }
 788                 dclose($self);
 789         };
 790         if (my $err = $@) {
 791                 eval { $self->fail($err) };
 792                 dclose($self);
 793         }
 794 }
 795
 796 sub event_step_init {
 797         my ($self) = @_;
 798         if (my $sock = $self->{sock}) { # using DS->EventLoop
 799                 $sock->blocking(0);
 800                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 801         }
 802 }
 803
 804 sub noop {}
 805
 806 our $oldset; sub oldset { $oldset }
 807
 808 # lei(1) calls this when it can't connect
 809 sub lazy_start {
 810         my ($path, $errno, $narg) = @_;
 811         if ($errno == ECONNREFUSED) {
 812                 unlink($path) or die "unlink($path): $!";
 813         } elsif ($errno != ENOENT) {
 814                 $! = $errno; # allow interpolation to stringify in die
 815                 die "connect($path): $!";
 816         }
 817         umask(077) // die("umask(077): $!");
 818         socket(my $l, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 819         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 820         listen($l, 1024) or die "listen: $!";
 821         my @st = stat($path) or die "stat($path): $!";
 822         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 823         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 824         local $oldset = PublicInbox::DS::block_signals();
 825         if ($narg == 5) {
 826                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 827                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 828                         require PublicInbox::CmdIPC4;
 829                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 830                         PublicInbox::CmdIPC4->can('recv_cmd4');
 831                 };
 832         }
 833         $recv_cmd or die <<"";
 834 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 835
 836         require PublicInbox::Listener;
 837         require PublicInbox::EOFpipe;
 838         (-p STDOUT) or die "E: stdout must be a pipe\n";
 839         my ($err) = ($path =~ m!\A(.+?/)[^/]+\z!);
 840         $err .= 'errors.log';
 841         open(STDIN, '+>>', $err) or die "open($err): $!";
 842         POSIX::setsid() > 0 or die "setsid: $!";
 843         my $pid = fork // die "fork: $!";
 844         return if $pid;
 845         $0 = "lei-daemon $path";
 846         local %PATH2CFG;
 847         local @TO_CLOSE_ATFORK_CHILD = ($l, $eof_w);
 848         $l->blocking(0);
 849         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 850         my $exit_code;
 851         local $quit = sub {
 852                 $exit_code //= shift;
 853                 my $listener = $l or exit($exit_code);
 854                 # closing eof_w triggers \&noop wakeup
 855                 $eof_w = $l = $path = undef;
 856                 $listener->close; # DS::close
 857                 PublicInbox::DS->SetLoopTimeout(1000);
 858         };
 859         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 860         undef $eof_r;
 861         my $sig = {
 862                 CHLD => \&PublicInbox::DS::enqueue_reap,
 863                 QUIT => $quit,
 864                 INT => $quit,
 865                 TERM => $quit,
 866                 HUP => \&noop,
 867                 USR1 => \&noop,
 868                 USR2 => \&noop,
 869         };
 870         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 871         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 872         undef $sig;
 873         local $SIG{PIPE} = 'IGNORE';
 874         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 875                 undef $sigfd;
 876                 PublicInbox::DS->SetLoopTimeout(5000);
 877         } else {
 878                 # wake up every second to accept signals if we don't
 879                 # have signalfd or IO::KQueue:
 880                 PublicInbox::DS::sig_setmask($oldset);
 881                 PublicInbox::DS->SetLoopTimeout(1000);
 882         }
 883         PublicInbox::DS->SetPostLoopCallback(sub {
 884                 my ($dmap, undef) = @_;
 885                 if (@st = defined($path) ? stat($path) : ()) {
 886                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 887                                 warn "$path dev/ino changed, quitting\n";
 888                                 $path = undef;
 889                         }
 890                 } elsif (defined($path)) {
 891                         warn "stat($path): $!, quitting ...\n";
 892                         undef $path; # don't unlink
 893                         $quit->();
 894                 }
 895                 return 1 if defined($path);
 896                 my $now = now();
 897                 my $n = 0;
 898                 for my $s (values %$dmap) {
 899                         $s->can('busy') or next;
 900                         if ($s->busy($now)) {
 901                                 ++$n;
 902                         } else {
 903                                 $s->close;
 904                         }
 905                 }
 906                 $n; # true: continue, false: stop
 907         });
 908
 909         # STDIN was redirected to /dev/null above, closing STDERR and
 910         # STDOUT will cause the calling `lei' client process to finish
 911         # reading the <$daemon> pipe.
 912         openlog($path, 'pid', 'user');
 913         local $SIG{__WARN__} = sub {
 914                 $current_lei ? err($current_lei, @_) : syslog('warning', "@_");
 915         };
 916         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 917                 syslog('crit', "$@") if $@;
 918         });
 919         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 920         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 921         # $daemon pipe to `lei' closed, main loop begins:
 922         PublicInbox::DS->EventLoop;
 923         @$on_destroy = (); # cancel on_destroy if we get here
 924         exit($exit_code // 0);
 925 }
 926
 927 # for users w/o Socket::Msghdr
 928 sub oneshot {
 929         my ($main_pkg) = @_;
 930         my $exit = $main_pkg->can('exit'); # caller may override exit()
 931         local $quit = $exit if $exit;
 932         local %PATH2CFG;
 933         umask(077) // die("umask(077): $!");
 934         dispatch((bless {
 935                 0 => *STDIN{GLOB},
 936                 1 => *STDOUT{GLOB},
 937                 2 => *STDERR{GLOB},
 938                 env => \%ENV
 939         }, __PACKAGE__), @ARGV);
 940 }
 941
 942 # ensures stdout hits the FS before sock disconnects so a client
 943 # can immediately reread it
 944 sub DESTROY {
 945         my ($self) = @_;
 946         $self->{1}->autoflush(1) if $self->{1};
 947         stop_pager($self);
 948         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
 949                 waitpid($mua_pid, 0);
 950         }
 951 }
 952
 953 1;