lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal
  12         PublicInbox::LeiQuery);
  13 use Getopt::Long ();
  14 use Socket qw(AF_UNIX SOCK_SEQPACKET MSG_EOR pack_sockaddr_un);
  15 use Errno qw(EAGAIN EINTR ECONNREFUSED ENOENT ECONNRESET);
  16 use POSIX ();
  17 use IO::Handle ();
  18 use Fcntl qw(SEEK_SET);
  19 use Sys::Syslog qw(syslog openlog);
  20 use PublicInbox::Config;
  21 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLET);
  22 use PublicInbox::Sigfd;
  23 use PublicInbox::DS qw(now dwaitpid);
  24 use PublicInbox::Spawn qw(spawn run_die popen_rd);
  25 use PublicInbox::OnDestroy;
  26 use Text::Wrap qw(wrap);
  27 use File::Path qw(mkpath);
  28 use File::Spec;
  29 our $quit = \&CORE::exit;
  30 our ($current_lei, $errors_log);
  31 my ($recv_cmd, $send_cmd);
  32 my $GLP = Getopt::Long::Parser->new;
  33 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  34 my $GLP_PASS = Getopt::Long::Parser->new;
  35 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  36
  37 our %PATH2CFG; # persistent for socket daemon
  38 our @TO_CLOSE_ATFORK_CHILD;
  39
  40 # TBD: this is a documentation mechanism to show a subcommand
  41 # (may) pass options through to another command:
  42 sub pass_through { $GLP_PASS }
  43
  44 my $OPT;
  45 sub opt_dash ($$) {
  46         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  47         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  48         my $cb = sub { # Getopt::Long "<>" catch-all handler
  49                 my ($arg) = @_;
  50                 if ($arg =~ /\A-($re_str)\z/) {
  51                         $OPT->{$key} = $1;
  52                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  53                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  54                 # lone (single) dash is handled elsewhere
  55                 } elsif (substr($arg, 0, 1) eq '-') {
  56                         if ($OPT->{'--'}) {
  57                                 push @{$OPT->{-argv}}, $arg;
  58                         } else {
  59                                 die "bad argument: $arg\n";
  60                         }
  61                 } else {
  62                         push @{$OPT->{-argv}}, $arg;
  63                 }
  64         };
  65         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  66 }
  67
  68 sub _store_path ($) {
  69         my ($env) = @_;
  70         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  71                 ($env->{HOME} // '/nonexistent').'/.local/share')
  72                 .'/lei/store', $env->{PWD});
  73 }
  74
  75 sub _config_path ($) {
  76         my ($env) = @_;
  77         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  78                 ($env->{HOME} // '/nonexistent').'/.config')
  79                 .'/lei/config', $env->{PWD});
  80 }
  81
  82 # TODO: generate shell completion + help using %CMD and %OPTDESC
  83 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  84 our %CMD = ( # sorted in order of importance/use:
  85 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  86         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  87         sort|s=s reverse|r offset=i remote local! external! pretty mua-cmd=s
  88         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  89
  90 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  91         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  92         pass_through('git show') ],
  93
  94 'add-external' => [ 'URL_OR_PATHNAME',
  95         'add/set priority of a publicinbox|extindex for extra matches',
  96         qw(boost=i quiet|q) ],
  97 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  98         qw(format|f=s z|0 local remote quiet|q) ],
  99 'forget-external' => [ '{URL_OR_PATHNAME|--prune}',
 100         'exclude further results from a publicinbox|extindex',
 101         qw(prune quiet|q) ],
 102
 103 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 104                 qw(name-only format|f=s z) ],
 105 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 106 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 107
 108 'plonk' => [ '--thread|--from=IDENT',
 109         'exclude mail matching From: or thread from non-Message-ID searches',
 110         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 111 'mark' => [ 'MESSAGE_FLAGS...',
 112         'set/unset flags on message(s) from stdin',
 113         qw(stdin| oid=s exact by-mid|mid:s) ],
 114 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 115         "exclude message(s) on stdin from `q' search results",
 116         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 117
 118 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 119         'remove imported messages from IMAP, Maildirs, and MH',
 120         qw(exact! all jobs:i indexed) ],
 121
 122 # code repos are used for `show' to solve blobs from patch mails
 123 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 124         qw(boost=i) ],
 125 'ls-coderepo' => [ '[FILTER_TERMS...]',
 126                 'list known code repos', qw(format|f=s z) ],
 127 'forget-coderepo' => [ 'PATHNAME',
 128         'stop using repo to solve blobs from patches',
 129         qw(prune) ],
 130
 131 'add-watch' => [ '[URL_OR_PATHNAME]',
 132                 'watch for new messages and flag changes',
 133         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 134 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 135                 qw(format|f=s z) ],
 136 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 137 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 138 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 139         qw(prune) ],
 140
 141 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 142         'one-shot import/update from URL or filesystem',
 143         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 144         ],
 145
 146 'config' => [ '[...]', sub {
 147                 'git-config(1) wrapper for '._config_path($_[0]);
 148         }, qw(config-file|system|global|file|f=s), # for conflict detection
 149         pass_through('git config') ],
 150 'init' => [ '[PATHNAME]', sub {
 151                 'initialize storage, default: '._store_path($_[0]);
 152         }, qw(quiet|q) ],
 153 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 154         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 155 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 156 'help' => [ '[SUBCOMMAND]', 'show help' ],
 157
 158 # XXX do we need this?
 159 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 160
 161 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 162         'rewrite git history in an attempt to improve compression',
 163         'gc!' ],
 164
 165 # internal commands are prefixed with '_'
 166 '_complete' => [ '[...]', 'internal shell completion helper',
 167                 pass_through('everything') ],
 168 ); # @CMD
 169
 170 # switch descriptions, try to keep consistent across commands
 171 # $spec: Getopt::Long option specification
 172 # $spec => [@ALLOWED_VALUES (default is first), $description],
 173 # $spec => $description
 174 # "$SUB_COMMAND TAB $spec" => as above
 175 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 176                 'specify message input format' ];
 177 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 178
 179 my %OPTDESC = (
 180 'help|h' => 'show this built-in help',
 181 'quiet|q' => 'be quiet',
 182 'solve!' => 'do not attempt to reconstruct blobs from emails',
 183 'save-as=s' => ['NAME', 'save a search terms by given name'],
 184
 185 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 186
 187 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 188                 'deduplication strategy'],
 189 'show   thread|t' => 'display entire thread a message belongs to',
 190 'q      thread|t' =>
 191         'return all messages in the same thread as the actual match(es)',
 192 'augment|a' => 'augment --output destination instead of clobbering',
 193
 194 'output|o=s' => [ 'DEST',
 195         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 196 'mua-cmd|mua=s' => [ 'COMMAND',
 197         "MUA to run on --output Maildir or mbox (e.g. `mutt -f %f'" ],
 198
 199 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 200                         'message/object output format' ],
 201 'mark   format|f=s' => $stdin_formats,
 202 'forget format|f=s' => $stdin_formats,
 203 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 204                 'specify output format, default depends on --output'],
 205 'ls-query       format|f=s' => $ls_format,
 206 'ls-external    format|f=s' => $ls_format,
 207
 208 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 209 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 210
 211 'sort|s=s' => [ 'VAL|received,relevance,docid',
 212                 "order of results `--output'-dependent"],
 213 'reverse|r' => [ 'reverse search results' ], # like sort(1)
 214
 215 'boost=i' => 'increase/decrease priority of results (default: 0)',
 216
 217 'local' => 'limit operations to the local filesystem',
 218 'local!' => 'exclude results from the local filesystem',
 219 'remote' => 'limit operations to those requiring network access',
 220 'remote!' => 'prevent operations requiring network access',
 221
 222 'mid=s' => 'specify the Message-ID of a message',
 223 'oid=s' => 'specify the git object ID of a message',
 224
 225 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 226 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 227 'include=s' => 'include mailboxes/newsgroups based on pattern',
 228
 229 'exact' => 'operate on exact header matches only',
 230 'exact!' => 'rely on content match instead of exact header matches',
 231
 232 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 233 'jobs:i' => 'set parallelism level',
 234
 235 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 236 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 237
 238 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 239 ); # %OPTDESC
 240
 241 my %CONFIG_KEYS = (
 242         'leistore.dir' => 'top-level storage location',
 243 );
 244
 245 # pronounced "exit": x_it(1 << 8) => exit(1); x_it(13) => SIGPIPE
 246 sub x_it ($$) {
 247         my ($self, $code) = @_;
 248         # make sure client sees stdout before exit
 249         $self->{1}->autoflush(1) if $self->{1};
 250         dump_and_clear_log();
 251         if (my $sock = $self->{sock}) {
 252                 send($sock, "x_it $code", MSG_EOR);
 253         } elsif (!($code & 127)) { # oneshot, ignore signals
 254                 # don't want to end up using $? from child processes
 255                 for my $f (qw(lxs l2m)) {
 256                         my $wq = delete $self->{$f} or next;
 257                         $wq->DESTROY;
 258                 }
 259                 $quit->($code >> 8);
 260         }
 261 }
 262
 263 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 264
 265 sub out ($;@) { print { shift->{1} } @_ }
 266
 267 sub err ($;@) {
 268         my $self = shift;
 269         my $err = $self->{2} // ($self->{pgr} // [])->[2] // *STDERR{IO};
 270         print $err @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 271 }
 272
 273 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 274
 275 sub fail ($$;$) {
 276         my ($self, $buf, $exit_code) = @_;
 277         err($self, $buf);
 278         x_it($self, ($exit_code // 1) << 8);
 279         undef;
 280 }
 281
 282 sub atfork_prepare_wq {
 283         my ($self, $wq) = @_;
 284         my $tcafc = $wq->{-ipc_atfork_child_close};
 285         push @$tcafc, @TO_CLOSE_ATFORK_CHILD;
 286         if (my $sock = $self->{sock}) {
 287                 push @$tcafc, @$self{qw(0 1 2)}, $sock;
 288         }
 289         for my $f (qw(lxs l2m)) {
 290                 my $ipc = $self->{$f} or next;
 291                 push @$tcafc, grep { defined }
 292                                 @$ipc{qw(-wq_s1 -wq_s2 -ipc_req -ipc_res)};
 293         }
 294 }
 295
 296 # usage: my %sig = $lei->atfork_child_wq($wq);
 297 #        local @SIG{keys %sig} = values %sig;
 298 sub atfork_child_wq {
 299         my ($self, $wq) = @_;
 300         my ($sock, $l2m_wq_s1);
 301         (@$self{qw(0 1 2)}, $sock, $l2m_wq_s1) = delete(@$wq{0..4});
 302         $self->{sock} = $sock if -S $sock;
 303         $self->{l2m}->{-wq_s1} = $l2m_wq_s1 if $l2m_wq_s1 && -S $l2m_wq_s1;
 304         %PATH2CFG = ();
 305         undef $errors_log;
 306         $quit = \&CORE::exit;
 307         @TO_CLOSE_ATFORK_CHILD = ();
 308         (__WARN__ => sub { err($self, @_) },
 309         PIPE => sub {
 310                 $self->x_it(13); # SIGPIPE = 13
 311                 # we need to close explicitly to avoid Perl warning on SIGPIPE
 312                 for my $i (1, 2) {
 313                         next unless $self->{$i} && (-p $self->{$i} || -S _);
 314                         close(delete $self->{$i});
 315                 }
 316                 # trigger the LeiXSearch $done OpPipe:
 317                 syswrite($self->{0}, '!') if $self->{0} && -p $self->{0};
 318                 $SIG{PIPE} = 'DEFAULT';
 319                 die bless(\"$_[0]", 'PublicInbox::SIGPIPE'),
 320         });
 321 }
 322
 323 # usage: ($lei, @io) = $lei->atfork_parent_wq($wq);
 324 sub atfork_parent_wq {
 325         my ($self, $wq) = @_;
 326         my $env = delete $self->{env}; # env is inherited at fork
 327         my $ret = bless { %$self }, ref($self);
 328         if (my $dedupe = delete $ret->{dedupe}) {
 329                 $ret->{dedupe} = $wq->deep_clone($dedupe);
 330         }
 331         $self->{env} = $env;
 332         delete @$ret{qw(-lei_store cfg pgr lxs)}; # keep l2m
 333         my @io = delete @$ret{0..2};
 334         $io[3] = delete($ret->{sock}) // *STDERR{GLOB};
 335         my $l2m = $ret->{l2m};
 336         if ($l2m && $l2m != $wq) { # $wq == lxs
 337                 $io[4] = $l2m->{-wq_s1} if $l2m->{-wq_s1};
 338                 if (my @pids = $l2m->wq_close) {
 339                         $wq->{l2m_pids} = \@pids;
 340                 }
 341         }
 342         ($ret, @io);
 343 }
 344
 345 sub _help ($;$) {
 346         my ($self, $errmsg) = @_;
 347         my $cmd = $self->{cmd} // 'COMMAND';
 348         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 349         my @top = ($cmd, shift(@info) // ());
 350         my $cmd_desc = shift(@info);
 351         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 352         my @opt_desc;
 353         my $lpad = 2;
 354         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 355                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 356                 my $arg_vals = '';
 357                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 358
 359                 # lower-case is a keyword (e.g. `content', `oid'),
 360                 # ALL_CAPS is a string description (e.g. `PATH')
 361                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 362                         $desc .= "\ndefault: `$1'";
 363                 }
 364                 my (@vals, @s, @l);
 365                 my $x = $sw;
 366                 if ($x =~ s/!\z//) { # solve! => --no-solve
 367                         $x = "no-$x";
 368                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 369                         @vals = (' [', undef, ']');
 370                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 371                         @vals = (' ', undef);
 372                 } # else: no args $x = 'thread|t'
 373                 for (split(/\|/, $x)) { # help|h
 374                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 375                 }
 376                 if (!scalar(@vals)) { # no args 'thread|t'
 377                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 378                         $vals[1] = $1;
 379                 } else {
 380                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 381                 }
 382                 if ($arg_vals =~ /([,\|])/) {
 383                         my $sep = $1;
 384                         my @allow = split(/\Q$sep\E/, $arg_vals);
 385                         my $must = $sep eq '|' ? 'Must' : 'Can';
 386                         @allow = map { "`$_'" } @allow;
 387                         my $last = pop @allow;
 388                         $desc .= "\n$must be one of: " .
 389                                 join(', ', @allow) . " or $last";
 390                 }
 391                 my $lhs = join(', ', @s, @l) . join('', @vals);
 392                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 393                         $lhs =~ s/\A--/- , --/;
 394                 } else {
 395                         $lhs =~ s/\A--/    --/; # pad if no short options
 396                 }
 397                 $lpad = length($lhs) if length($lhs) > $lpad;
 398                 push @opt_desc, $lhs, $desc;
 399         }
 400         my $msg = $errmsg ? "E: $errmsg\n" : '';
 401         $msg .= <<EOF;
 402 usage: lei @top
 403   $cmd_desc
 404
 405 EOF
 406         $lpad += 2;
 407         local $Text::Wrap::columns = 78 - $lpad;
 408         my $padding = ' ' x ($lpad + 2);
 409         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 410                 $msg .= '  '.pack("A$lpad", $lhs);
 411                 $rhs = wrap('', '', $rhs);
 412                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 413                 $msg .= $rhs;
 414                 $msg .= "\n";
 415         }
 416         print { $self->{$errmsg ? 2 : 1} } $msg;
 417         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 418         undef;
 419 }
 420
 421 sub optparse ($$$) {
 422         my ($self, $cmd, $argv) = @_;
 423         $self->{cmd} = $cmd;
 424         $OPT = $self->{opt} = {};
 425         my $info = $CMD{$cmd} // [ '[...]' ];
 426         my ($proto, undef, @spec) = @$info;
 427         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 428         push @spec, qw(help|h);
 429         my $lone_dash;
 430         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 431                 $lone_dash = $spec[0];
 432                 $OPT->{$spec[0]} = \(my $var);
 433                 push @spec, '' => \$var;
 434         }
 435         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 436                 return _help($self, "bad arguments or options for $cmd");
 437         return _help($self) if $OPT->{help};
 438
 439         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 440
 441         # "-" aliases "stdin" or "clear"
 442         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 443
 444         my $i = 0;
 445         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 446         my ($err, $inf);
 447         my @args = split(/ /, $proto);
 448         for my $var (@args) {
 449                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 450                         $inf = defined($argv->[$i]) and last;
 451                         $var =~ s/\.\.\.\z//;
 452                         $err = "$var not supplied";
 453                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 454                         $argv->[$i++] // ($err = "$var not supplied");
 455                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 456                         $inf = 1;
 457                         last;
 458                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 459                         $i++;
 460                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 461                         my @or = split(/\|/, $var);
 462                         my $ok;
 463                         for my $o (@or) {
 464                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 465                                         $ok = defined($OPT->{$1});
 466                                         last;
 467                                 } elsif (defined($argv->[$i])) {
 468                                         $ok = 1;
 469                                         $i++;
 470                                         last;
 471                                 } # else continue looping
 472                         }
 473                         my $last = pop @or;
 474                         $err = join(', ', @or) . " or $last must be set";
 475                 } else {
 476                         warn "BUG: can't parse `$var' in $proto";
 477                 }
 478                 last if $err;
 479         }
 480         if (!$inf && scalar(@$argv) > scalar(@args)) {
 481                 $err //= 'too many arguments';
 482         }
 483         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 484 }
 485
 486 sub dispatch {
 487         my ($self, $cmd, @argv) = @_;
 488         local $current_lei = $self; # for __WARN__
 489         dump_and_clear_log("from previous run\n");
 490         return _help($self, 'no command given') unless defined($cmd);
 491         my $func = "lei_$cmd";
 492         $func =~ tr/-/_/;
 493         if (my $cb = __PACKAGE__->can($func)) {
 494                 optparse($self, $cmd, \@argv) or return;
 495                 $cb->($self, @argv);
 496         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 497                 my $opt = {};
 498                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 499                         return _help($self, 'bad arguments or options');
 500                 _help($self);
 501         } else {
 502                 fail($self, "`$cmd' is not an lei command");
 503         }
 504 }
 505
 506 sub _lei_cfg ($;$) {
 507         my ($self, $creat) = @_;
 508         my $f = _config_path($self->{env});
 509         my @st = stat($f);
 510         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 511         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 512                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 513         }
 514         if (!@st) {
 515                 unless ($creat) {
 516                         delete $self->{cfg};
 517                         return;
 518                 }
 519                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 520                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 521                 open my $fh, '>>', $f or die "open($f): $!\n";
 522                 @st = stat($fh) or die "fstat($f): $!\n";
 523                 $cur_st = pack('dd', $st[10], $st[7]);
 524                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 525         }
 526         my $cfg = PublicInbox::Config::git_config_dump($f);
 527         $cfg->{-st} = $cur_st;
 528         $cfg->{'-f'} = $f;
 529         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 530 }
 531
 532 sub _lei_store ($;$) {
 533         my ($self, $creat) = @_;
 534         my $cfg = _lei_cfg($self, $creat);
 535         $cfg->{-lei_store} //= do {
 536                 require PublicInbox::LeiStore;
 537                 my $dir = $cfg->{'leistore.dir'};
 538                 $dir //= _store_path($self->{env}) if $creat;
 539                 return unless $dir;
 540                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 541         };
 542 }
 543
 544 sub lei_show {
 545         my ($self, @argv) = @_;
 546 }
 547
 548 sub lei_mark {
 549         my ($self, @argv) = @_;
 550 }
 551
 552 sub lei_config {
 553         my ($self, @argv) = @_;
 554         $self->{opt}->{'config-file'} and return fail $self,
 555                 "config file switches not supported by `lei config'";
 556         my $env = $self->{env};
 557         delete local $env->{GIT_CONFIG};
 558         my $cfg = _lei_cfg($self, 1);
 559         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 560         my %rdr = map { $_ => $self->{$_} } (0..2);
 561         run_die($cmd, $env, \%rdr);
 562 }
 563
 564 sub lei_init {
 565         my ($self, $dir) = @_;
 566         my $cfg = _lei_cfg($self, 1);
 567         my $cur = $cfg->{'leistore.dir'};
 568         my $env = $self->{env};
 569         $dir //= _store_path($env);
 570         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 571         my @cur = stat($cur) if defined($cur);
 572         $cur = File::Spec->canonpath($cur // $dir);
 573         my @dir = stat($dir);
 574         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 575         if (@cur) {
 576                 if ($cur eq $dir) {
 577                         _lei_store($self, 1)->done;
 578                         return qerr($self, $exists);
 579                 }
 580
 581                 # some folks like symlinks and bind mounts :P
 582                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 583                         lei_config($self, 'leistore.dir', $dir);
 584                         _lei_store($self, 1)->done;
 585                         return qerr($self, "$exists (as $cur)");
 586                 }
 587                 return fail($self, <<"");
 588 E: leistore.dir=$cur already initialized and it is not $dir
 589
 590         }
 591         lei_config($self, 'leistore.dir', $dir);
 592         _lei_store($self, 1)->done;
 593         $exists //= "I: leistore.dir=$dir newly initialized";
 594         return qerr($self, $exists);
 595 }
 596
 597 sub lei_daemon_pid { puts shift, $$ }
 598
 599 sub lei_daemon_kill {
 600         my ($self) = @_;
 601         my $sig = $self->{opt}->{signal} // 'TERM';
 602         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 603 }
 604
 605 sub lei_help { _help($_[0]) }
 606
 607 # Shell completion helper.  Used by lei-completion.bash and hopefully
 608 # other shells.  Try to do as much here as possible to avoid redundancy
 609 # and improve maintainability.
 610 sub lei__complete {
 611         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 612         shift @argv; # ignore "lei", the entire command is sent
 613         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 614         my $cmd = shift @argv;
 615         my $info = $CMD{$cmd} // do { # filter matching commands
 616                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 617                 return;
 618         };
 619         my ($proto, undef, @spec) = @$info;
 620         my $cur = pop @argv;
 621         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 622         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 623                 # gross special case since the only git-config options
 624                 # Consider moving to a table if we need more special cases
 625                 # we use Getopt::Long for are the ones we reject, so these
 626                 # are the ones we don't reject:
 627                 if ($cmd eq 'config') {
 628                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 629                         @spec = qw(add z|null get get-all unset unset-all
 630                                 replace-all get-urlmatch
 631                                 remove-section rename-section
 632                                 name-only list|l edit|e
 633                                 get-color-name get-colorbool);
 634                         # fall-through
 635                 }
 636                 # TODO: arg support
 637                 puts $self, grep(/$re/, map { # generate short/long names
 638                         my $eq = '';
 639                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 640                                 $eq = '=';
 641                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 642                         } else { # negation: solve! => no-solve|solve
 643                                 s/\A(.+)!\z/no-$1|$1/;
 644                         }
 645                         map {
 646                                 length > 1 ? "--$_$eq" : "-$_"
 647                         } split(/\|/, $_, -1) # help|h
 648                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 649         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 650                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 651         }
 652         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 653         # proto parsing.
 654 }
 655
 656 sub reap_exec { # dwaitpid callback
 657         my ($self, $pid) = @_;
 658         x_it($self, $?);
 659 }
 660
 661 sub lei_git { # support passing through random git commands
 662         my ($self, @argv) = @_;
 663         my %rdr = map { $_ => $self->{$_} } (0..2);
 664         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 665         dwaitpid($pid, \&reap_exec, $self);
 666 }
 667
 668 sub exec_buf ($$) {
 669         my ($argv, $env) = @_;
 670         my $argc = scalar @$argv;
 671         my $buf = 'exec '.join("\0", scalar(@$argv), @$argv);
 672         while (my ($k, $v) = each %$env) { $buf .= "\0$k=$v" };
 673         $buf;
 674 }
 675
 676 sub start_mua {
 677         my ($self, $sock) = @_;
 678         my $mua = $self->{opt}->{'mua-cmd'} // return;
 679         my $mfolder = $self->{ovv}->{dst};
 680         require Text::ParseWords;
 681         my $replaced;
 682         my @cmd = Text::ParseWords::shellwords($mua);
 683         # mutt uses '%f' for open-hook with compressed folders, so we use %f
 684         @cmd = map { $_ eq '%f' ? ($replaced = $mfolder) : $_ } @cmd;
 685         push @cmd, $mfolder unless defined($replaced);
 686         $sock //= $self->{sock};
 687         if ($sock) { # lei(1) client process runs it
 688                 send($sock, exec_buf(\@cmd, {}), MSG_EOR);
 689         } else { # oneshot
 690                 $self->{"mua.pid.$self.$$"} = spawn(\@cmd);
 691         }
 692 }
 693
 694 # caller needs to "-t $self->{1}" to check if tty
 695 sub start_pager {
 696         my ($self) = @_;
 697         my $env = $self->{env};
 698         my $fh = popen_rd([qw(git var GIT_PAGER)], $env);
 699         chomp(my $pager = <$fh> // '');
 700         close($fh) or warn "`git var PAGER' error: \$?=$?";
 701         return if $pager eq 'cat' || $pager eq '';
 702         # TODO TIOCGWINSZ
 703         my $new_env = { LESS => 'FRX', LV => '-c', COLUMNS => 80 };
 704         $new_env->{MORE} = 'FRX' if $^O eq 'freebsd';
 705         pipe(my ($r, $wpager)) or return warn "pipe: $!";
 706         my $rdr = { 0 => $r, 1 => $self->{1}, 2 => $self->{2} };
 707         my $pgr = [ undef, @$rdr{1, 2}, $$ ];
 708         if (my $sock = $self->{sock}) { # lei(1) process runs it
 709                 delete @$new_env{keys %$env}; # only set iff unset
 710                 my $fds = [ map { fileno($_) } @$rdr{0..2} ];
 711                 $send_cmd->($sock, $fds, exec_buf([$pager], $new_env), MSG_EOR);
 712         } else {
 713                 $pgr->[0] = spawn([$pager], $new_env, $rdr);
 714         }
 715         $self->{1} = $wpager;
 716         $self->{2} = $wpager if -t $self->{2};
 717         $env->{GIT_PAGER_IN_USE} = 'true'; # we may spawn git
 718         $self->{pgr} = $pgr;
 719 }
 720
 721 sub stop_pager {
 722         my ($self) = @_;
 723         my $pgr = delete($self->{pgr}) or return;
 724         $self->{2} = $pgr->[2];
 725         # do not restore original stdout, just close it so we error out
 726         close(delete($self->{1})) if $self->{1};
 727         my $pid = $pgr->[0];
 728         dwaitpid($pid, undef, $self->{sock}) if $pid && $pgr->[3] == $$;
 729 }
 730
 731 sub accept_dispatch { # Listener {post_accept} callback
 732         my ($sock) = @_; # ignore other
 733         $sock->autoflush(1);
 734         my $self = bless { sock => $sock }, __PACKAGE__;
 735         vec(my $rvec = '', fileno($sock), 1) = 1;
 736         select($rvec, undef, undef, 1) or
 737                 return send($sock, 'timed out waiting to recv FDs', MSG_EOR);
 738         my @fds = $recv_cmd->($sock, my $buf, 4096 * 33); # >MAX_ARG_STRLEN
 739         if (scalar(@fds) == 4) {
 740                 my $i = 0;
 741                 for my $rdr (qw(<&= >&= >&= <&=)) {
 742                         my $fd = shift(@fds);
 743                         open($self->{$i++}, $rdr, $fd) and next;
 744                         send($sock, "open($rdr$fd) (FD=$i): $!", MSG_EOR);
 745                 }
 746         } else {
 747                 return send($sock, "recv_cmd failed: $!", MSG_EOR);
 748         }
 749         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 750         # $ENV_STR = join('', map { "\0$_=$ENV{$_}" } keys %ENV);
 751         # $buf = "$$\0$argc\0".join("\0", @ARGV).$ENV_STR."\0\0";
 752         substr($buf, -2, 2, '') eq "\0\0" or  # s/\0\0\z//
 753                 return send($sock, 'request command truncated', MSG_EOR);
 754         my ($argc, @argv) = split(/\0/, $buf, -1);
 755         undef $buf;
 756         my %env = map { split(/=/, $_, 2) } splice(@argv, $argc);
 757         if (chdir(delete($self->{3}))) {
 758                 local %ENV = %env;
 759                 $self->{env} = \%env;
 760                 eval { dispatch($self, @argv) };
 761                 send($sock, $@, MSG_EOR) if $@;
 762         } else {
 763                 send($sock, "fchdir: $!", MSG_EOR); # implicit close
 764         }
 765 }
 766
 767 sub dclose {
 768         my ($self) = @_;
 769         delete $self->{lxs}; # stops LeiXSearch queries
 770         close(delete $self->{1}) if $self->{1}; # may reap_compress
 771         $self->close if $self->{sock}; # PublicInbox::DS::close
 772 }
 773
 774 # for long-running results
 775 sub event_step {
 776         my ($self) = @_;
 777         local %ENV = %{$self->{env}};
 778         my $sock = $self->{sock};
 779         local $current_lei = $self;
 780         eval {
 781                 while (my @fds = $recv_cmd->($sock, my $buf, 4096)) {
 782                         if (scalar(@fds) == 1 && !defined($fds[0])) {
 783                                 return if $! == EAGAIN;
 784                                 next if $! == EINTR;
 785                                 last if $! == ECONNRESET;
 786                                 die "recvmsg: $!";
 787                         }
 788                         for my $fd (@fds) {
 789                                 open my $rfh, '+<&=', $fd;
 790                         }
 791                         die "unrecognized client signal: $buf";
 792                 }
 793                 dclose($self);
 794         };
 795         if (my $err = $@) {
 796                 eval { $self->fail($err) };
 797                 dclose($self);
 798         }
 799 }
 800
 801 sub event_step_init {
 802         my ($self) = @_;
 803         if (my $sock = $self->{sock}) { # using DS->EventLoop
 804                 $sock->blocking(0);
 805                 $self->SUPER::new($sock, EPOLLIN|EPOLLET);
 806         }
 807 }
 808
 809 sub noop {}
 810
 811 our $oldset; sub oldset { $oldset }
 812
 813 sub dump_and_clear_log {
 814         if (defined($errors_log) && -s STDIN && seek(STDIN, 0, SEEK_SET)) {
 815                 my @pfx = @_;
 816                 unshift(@pfx, "$errors_log ") if @pfx;
 817                 warn @pfx, do { local $/; <STDIN> };
 818                 truncate(STDIN, 0) or warn "ftruncate ($errors_log): $!";
 819         }
 820 }
 821
 822 # lei(1) calls this when it can't connect
 823 sub lazy_start {
 824         my ($path, $errno, $narg) = @_;
 825         if ($errno == ECONNREFUSED) {
 826                 unlink($path) or die "unlink($path): $!";
 827         } elsif ($errno != ENOENT) {
 828                 $! = $errno; # allow interpolation to stringify in die
 829                 die "connect($path): $!";
 830         }
 831         umask(077) // die("umask(077): $!");
 832         socket(my $l, AF_UNIX, SOCK_SEQPACKET, 0) or die "socket: $!";
 833         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 834         listen($l, 1024) or die "listen: $!";
 835         my @st = stat($path) or die "stat($path): $!";
 836         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 837         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 838         local $oldset = PublicInbox::DS::block_signals();
 839         if ($narg == 5) {
 840                 $send_cmd = PublicInbox::Spawn->can('send_cmd4');
 841                 $recv_cmd = PublicInbox::Spawn->can('recv_cmd4') // do {
 842                         require PublicInbox::CmdIPC4;
 843                         $send_cmd = PublicInbox::CmdIPC4->can('send_cmd4');
 844                         PublicInbox::CmdIPC4->can('recv_cmd4');
 845                 };
 846         }
 847         $recv_cmd or die <<"";
 848 (Socket::MsgHdr || Inline::C) missing/unconfigured (narg=$narg);
 849
 850         require PublicInbox::Listener;
 851         require PublicInbox::EOFpipe;
 852         (-p STDOUT) or die "E: stdout must be a pipe\n";
 853         local $errors_log;
 854         ($errors_log) = ($path =~ m!\A(.+?/)[^/]+\z!);
 855         $errors_log .= 'errors.log';
 856         open(STDIN, '+>>', $errors_log) or die "open($errors_log): $!";
 857         STDIN->autoflush(1);
 858         dump_and_clear_log("from previous daemon process:\n");
 859         POSIX::setsid() > 0 or die "setsid: $!";
 860         my $pid = fork // die "fork: $!";
 861         return if $pid;
 862         $0 = "lei-daemon $path";
 863         local %PATH2CFG;
 864         local @TO_CLOSE_ATFORK_CHILD = ($l, $eof_w);
 865         $l->blocking(0);
 866         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 867         my $exit_code;
 868         local $quit = sub {
 869                 $exit_code //= shift;
 870                 my $listener = $l or exit($exit_code);
 871                 # closing eof_w triggers \&noop wakeup
 872                 $eof_w = $l = $path = undef;
 873                 $listener->close; # DS::close
 874                 PublicInbox::DS->SetLoopTimeout(1000);
 875         };
 876         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 877         undef $eof_r;
 878         my $sig = {
 879                 CHLD => \&PublicInbox::DS::enqueue_reap,
 880                 QUIT => $quit,
 881                 INT => $quit,
 882                 TERM => $quit,
 883                 HUP => \&noop,
 884                 USR1 => \&noop,
 885                 USR2 => \&noop,
 886         };
 887         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 888         local @SIG{keys %$sig} = values(%$sig) unless $sigfd;
 889         undef $sig;
 890         local $SIG{PIPE} = 'IGNORE';
 891         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 892                 undef $sigfd;
 893                 PublicInbox::DS->SetLoopTimeout(5000);
 894         } else {
 895                 # wake up every second to accept signals if we don't
 896                 # have signalfd or IO::KQueue:
 897                 PublicInbox::DS::sig_setmask($oldset);
 898                 PublicInbox::DS->SetLoopTimeout(1000);
 899         }
 900         PublicInbox::DS->SetPostLoopCallback(sub {
 901                 my ($dmap, undef) = @_;
 902                 if (@st = defined($path) ? stat($path) : ()) {
 903                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 904                                 warn "$path dev/ino changed, quitting\n";
 905                                 $path = undef;
 906                         }
 907                 } elsif (defined($path)) {
 908                         warn "stat($path): $!, quitting ...\n";
 909                         undef $path; # don't unlink
 910                         $quit->();
 911                 }
 912                 return 1 if defined($path);
 913                 my $now = now();
 914                 my $n = 0;
 915                 for my $s (values %$dmap) {
 916                         $s->can('busy') or next;
 917                         if ($s->busy($now)) {
 918                                 ++$n;
 919                         } else {
 920                                 $s->close;
 921                         }
 922                 }
 923                 $n; # true: continue, false: stop
 924         });
 925
 926         # STDIN was redirected to /dev/null above, closing STDERR and
 927         # STDOUT will cause the calling `lei' client process to finish
 928         # reading the <$daemon> pipe.
 929         openlog($path, 'pid', 'user');
 930         local $SIG{__WARN__} = sub {
 931                 $current_lei ? err($current_lei, @_) : syslog('warning', "@_");
 932         };
 933         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 934                 syslog('crit', "$@") if $@;
 935         });
 936         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 937         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 938         # $daemon pipe to `lei' closed, main loop begins:
 939         PublicInbox::DS->EventLoop;
 940         @$on_destroy = (); # cancel on_destroy if we get here
 941         exit($exit_code // 0);
 942 }
 943
 944 # for users w/o Socket::Msghdr
 945 sub oneshot {
 946         my ($main_pkg) = @_;
 947         my $exit = $main_pkg->can('exit'); # caller may override exit()
 948         local $quit = $exit if $exit;
 949         local %PATH2CFG;
 950         umask(077) // die("umask(077): $!");
 951         dispatch((bless {
 952                 0 => *STDIN{GLOB},
 953                 1 => *STDOUT{GLOB},
 954                 2 => *STDERR{GLOB},
 955                 env => \%ENV
 956         }, __PACKAGE__), @ARGV);
 957 }
 958
 959 # ensures stdout hits the FS before sock disconnects so a client
 960 # can immediately reread it
 961 sub DESTROY {
 962         my ($self) = @_;
 963         $self->{1}->autoflush(1) if $self->{1};
 964         stop_pager($self);
 965         if (my $mua_pid = delete $self->{"mua.pid.$self.$$"}) {
 966                 waitpid($mua_pid, 0);
 967         }
 968 }
 969
 970 1;