lib/PublicInbox/LEI.pm

   1 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Backend for `lei' (local email interface).  Unlike the C10K-oriented
   5 # PublicInbox::Daemon, this is designed exclusively to handle trusted
   6 # local clients with read/write access to the FS and use as many
   7 # system resources as the local user has access to.
   8 package PublicInbox::LEI;
   9 use strict;
  10 use v5.10.1;
  11 use parent qw(PublicInbox::DS PublicInbox::LeiExternal);
  12 use Getopt::Long ();
  13 use Socket qw(AF_UNIX SOCK_STREAM pack_sockaddr_un);
  14 use Errno qw(EAGAIN ECONNREFUSED ENOENT);
  15 use POSIX ();
  16 use IO::Handle ();
  17 use Sys::Syslog qw(syslog openlog);
  18 use PublicInbox::Config;
  19 use PublicInbox::Syscall qw(SFD_NONBLOCK EPOLLIN EPOLLONESHOT);
  20 use PublicInbox::Sigfd;
  21 use PublicInbox::DS qw(now dwaitpid);
  22 use PublicInbox::Spawn qw(spawn run_die);
  23 use PublicInbox::OnDestroy;
  24 use Text::Wrap qw(wrap);
  25 use File::Path qw(mkpath);
  26 use File::Spec;
  27 our $quit = \&CORE::exit;
  28 my $recv_3fds;
  29 my $GLP = Getopt::Long::Parser->new;
  30 $GLP->configure(qw(gnu_getopt no_ignore_case auto_abbrev));
  31 my $GLP_PASS = Getopt::Long::Parser->new;
  32 $GLP_PASS->configure(qw(gnu_getopt no_ignore_case auto_abbrev pass_through));
  33
  34 our %PATH2CFG; # persistent for socket daemon
  35
  36 # TBD: this is a documentation mechanism to show a subcommand
  37 # (may) pass options through to another command:
  38 sub pass_through { $GLP_PASS }
  39
  40 my $OPT;
  41 sub opt_dash ($$) {
  42         my ($spec, $re_str) = @_; # 'limit|n=i', '([0-9]+)'
  43         my ($key) = ($spec =~ m/\A([a-z]+)/g);
  44         my $cb = sub { # Getopt::Long "<>" catch-all handler
  45                 my ($arg) = @_;
  46                 if ($arg =~ /\A-($re_str)\z/) {
  47                         $OPT->{$key} = $1;
  48                 } elsif ($arg eq '--') { # "--" arg separator, ignore first
  49                         push @{$OPT->{-argv}}, $arg if $OPT->{'--'}++;
  50                 # lone (single) dash is handled elsewhere
  51                 } elsif (substr($arg, 0, 1) eq '-') {
  52                         if ($OPT->{'--'}) {
  53                                 push @{$OPT->{-argv}}, $arg;
  54                         } else {
  55                                 die "bad argument: $arg\n";
  56                         }
  57                 } else {
  58                         push @{$OPT->{-argv}}, $arg;
  59                 }
  60         };
  61         ($spec, '<>' => $cb, $GLP_PASS) # for Getopt::Long
  62 }
  63
  64 sub _store_path ($) {
  65         my ($env) = @_;
  66         File::Spec->rel2abs(($env->{XDG_DATA_HOME} //
  67                 ($env->{HOME} // '/nonexistent').'/.local/share')
  68                 .'/lei/store', $env->{PWD});
  69 }
  70
  71 sub _config_path ($) {
  72         my ($env) = @_;
  73         File::Spec->rel2abs(($env->{XDG_CONFIG_HOME} //
  74                 ($env->{HOME} // '/nonexistent').'/.config')
  75                 .'/lei/config', $env->{PWD});
  76 }
  77
  78 # TODO: generate shell completion + help using %CMD and %OPTDESC
  79 # command => [ positional_args, 1-line description, Getopt::Long option spec ]
  80 our %CMD = ( # sorted in order of importance/use:
  81 'q' => [ 'SEARCH_TERMS...', 'search for messages matching terms', qw(
  82         save-as=s output|mfolder|o=s format|f=s dedupe|d=s thread|t augment|a
  83         sort|s=s@ reverse|r offset=i remote local! external!
  84         since|after=s until|before=s), opt_dash('limit|n=i', '[0-9]+') ],
  85
  86 'show' => [ 'MID|OID', 'show a given object (Message-ID or object ID)',
  87         qw(type=s solve! format|f=s dedupe|d=s thread|t remote local!),
  88         pass_through('git show') ],
  89
  90 'add-external' => [ 'URL_OR_PATHNAME',
  91         'add/set priority of a publicinbox|extindex for extra matches',
  92         qw(boost=i quiet|q) ],
  93 'ls-external' => [ '[FILTER...]', 'list publicinbox|extindex locations',
  94         qw(format|f=s z|0 local remote quiet|q) ],
  95 'forget-external' => [ '{URL_OR_PATHNAME|--prune}',
  96         'exclude further results from a publicinbox|extindex',
  97         qw(prune quiet|q) ],
  98
  99 'ls-query' => [ '[FILTER...]', 'list saved search queries',
 100                 qw(name-only format|f=s z) ],
 101 'rm-query' => [ 'QUERY_NAME', 'remove a saved search' ],
 102 'mv-query' => [ qw(OLD_NAME NEW_NAME), 'rename a saved search' ],
 103
 104 'plonk' => [ '--thread|--from=IDENT',
 105         'exclude mail matching From: or thread from non-Message-ID searches',
 106         qw(stdin| thread|t from|f=s mid=s oid=s) ],
 107 'mark' => [ 'MESSAGE_FLAGS...',
 108         'set/unset flags on message(s) from stdin',
 109         qw(stdin| oid=s exact by-mid|mid:s) ],
 110 'forget' => [ '[--stdin|--oid=OID|--by-mid=MID]',
 111         "exclude message(s) on stdin from `q' search results",
 112         qw(stdin| oid=s exact by-mid|mid:s quiet|q) ],
 113
 114 'purge-mailsource' => [ '{URL_OR_PATHNAME|--all}',
 115         'remove imported messages from IMAP, Maildirs, and MH',
 116         qw(exact! all jobs:i indexed) ],
 117
 118 # code repos are used for `show' to solve blobs from patch mails
 119 'add-coderepo' => [ 'PATHNAME', 'add or set priority of a git code repo',
 120         qw(boost=i) ],
 121 'ls-coderepo' => [ '[FILTER_TERMS...]',
 122                 'list known code repos', qw(format|f=s z) ],
 123 'forget-coderepo' => [ 'PATHNAME',
 124         'stop using repo to solve blobs from patches',
 125         qw(prune) ],
 126
 127 'add-watch' => [ '[URL_OR_PATHNAME]',
 128                 'watch for new messages and flag changes',
 129         qw(import! flags! interval=s recursive|r exclude=s include=s) ],
 130 'ls-watch' => [ '[FILTER...]', 'list active watches with numbers and status',
 131                 qw(format|f=s z) ],
 132 'pause-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 133 'resume-watch' => [ '[WATCH_NUMBER_OR_FILTER]', qw(all local remote) ],
 134 'forget-watch' => [ '{WATCH_NUMBER|--prune}', 'stop and forget a watch',
 135         qw(prune) ],
 136
 137 'import' => [ '{URL_OR_PATHNAME|--stdin}',
 138         'one-shot import/update from URL or filesystem',
 139         qw(stdin| offset=i recursive|r exclude=s include=s !flags),
 140         ],
 141
 142 'config' => [ '[...]', sub {
 143                 'git-config(1) wrapper for '._config_path($_[0]);
 144         }, qw(config-file|system|global|file|f=s), # for conflict detection
 145         pass_through('git config') ],
 146 'init' => [ '[PATHNAME]', sub {
 147                 'initialize storage, default: '._store_path($_[0]);
 148         }, qw(quiet|q) ],
 149 'daemon-kill' => [ '[-SIGNAL]', 'signal the lei-daemon',
 150         opt_dash('signal|s=s', '[0-9]+|(?:[A-Z][A-Z0-9]+)') ],
 151 'daemon-pid' => [ '', 'show the PID of the lei-daemon' ],
 152 'daemon-env' => [ '[NAME=VALUE...]', 'set, unset, or show daemon environment',
 153         qw(clear| unset|u=s@ z|0) ],
 154 'help' => [ '[SUBCOMMAND]', 'show help' ],
 155
 156 # XXX do we need this?
 157 # 'git' => [ '[ANYTHING...]', 'git(1) wrapper', pass_through('git') ],
 158
 159 'reorder-local-store-and-break-history' => [ '[REFNAME]',
 160         'rewrite git history in an attempt to improve compression',
 161         'gc!' ],
 162
 163 # internal commands are prefixed with '_'
 164 '_complete' => [ '[...]', 'internal shell completion helper',
 165                 pass_through('everything') ],
 166 ); # @CMD
 167
 168 # switch descriptions, try to keep consistent across commands
 169 # $spec: Getopt::Long option specification
 170 # $spec => [@ALLOWED_VALUES (default is first), $description],
 171 # $spec => $description
 172 # "$SUB_COMMAND TAB $spec" => as above
 173 my $stdin_formats = [ 'IN|auto|raw|mboxrd|mboxcl2|mboxcl|mboxo',
 174                 'specify message input format' ];
 175 my $ls_format = [ 'OUT|plain|json|null', 'listing output format' ];
 176
 177 my %OPTDESC = (
 178 'help|h' => 'show this built-in help',
 179 'quiet|q' => 'be quiet',
 180 'solve!' => 'do not attempt to reconstruct blobs from emails',
 181 'save-as=s' => ['NAME', 'save a search terms by given name'],
 182
 183 'type=s' => [ 'any|mid|git', 'disambiguate type' ],
 184
 185 'dedupe|d=s' => ['STRAT|content|oid|mid|none',
 186                 'deduplication strategy'],
 187 'show   thread|t' => 'display entire thread a message belongs to',
 188 'q      thread|t' =>
 189         'return all messages in the same thread as the actual match(es)',
 190 'augment|a' => 'augment --output destination instead of clobbering',
 191
 192 'output|o=s' => [ 'DEST',
 193         "destination (e.g. `/path/to/Maildir', or `-' for stdout)" ],
 194
 195 'show   format|f=s' => [ 'OUT|plain|raw|html|mboxrd|mboxcl2|mboxcl',
 196                         'message/object output format' ],
 197 'mark   format|f=s' => $stdin_formats,
 198 'forget format|f=s' => $stdin_formats,
 199 'q      format|f=s' => [ 'OUT|maildir|mboxrd|mboxcl2|mboxcl|html|oid|json',
 200                 'specify output format, default depends on --output'],
 201 'ls-query       format|f=s' => $ls_format,
 202 'ls-external    format|f=s' => $ls_format,
 203
 204 'limit|n=i@' => ['NUM', 'limit on number of matches (default: 10000)' ],
 205 'offset=i' => ['OFF', 'search result offset (default: 0)'],
 206
 207 'sort|s=s@' => [ 'VAL|internaldate,date,relevance,docid',
 208                 "order of results `--output'-dependent"],
 209
 210 'boost=i' => 'increase/decrease priority of results (default: 0)',
 211
 212 'local' => 'limit operations to the local filesystem',
 213 'local!' => 'exclude results from the local filesystem',
 214 'remote' => 'limit operations to those requiring network access',
 215 'remote!' => 'prevent operations requiring network access',
 216
 217 'mid=s' => 'specify the Message-ID of a message',
 218 'oid=s' => 'specify the git object ID of a message',
 219
 220 'recursive|r' => 'scan directories/mailboxes/newsgroups recursively',
 221 'exclude=s' => 'exclude mailboxes/newsgroups based on pattern',
 222 'include=s' => 'include mailboxes/newsgroups based on pattern',
 223
 224 'exact' => 'operate on exact header matches only',
 225 'exact!' => 'rely on content match instead of exact header matches',
 226
 227 'by-mid|mid:s' => [ 'MID', 'match only by Message-ID, ignoring contents' ],
 228 'jobs:i' => 'set parallelism level',
 229
 230 # xargs, env, use "-0", git(1) uses "-z".  We support z|0 everywhere
 231 'z|0' => 'use NUL \\0 instead of newline (CR) to delimit lines',
 232
 233 # note: no "--ignore-environment" / "-i" support like env(1) since that
 234 # is one-shot and this is for a persistent daemon:
 235 'clear|' => 'clear the daemon environment',
 236 'unset|u=s@' => ['NAME',
 237         'unset matching NAME, may be specified multiple times'],
 238
 239 'signal|s=s' => [ 'SIG', 'signal to send lei-daemon (default: TERM)' ],
 240 ); # %OPTDESC
 241
 242 my %CONFIG_KEYS = (
 243         'leistore.dir' => 'top-level storage location',
 244 );
 245
 246 sub x_it ($$) { # pronounced "exit"
 247         my ($self, $code) = @_;
 248         $self->{1}->autoflush(1); # make sure client sees stdout before exit
 249         if (my $sig = ($code & 127)) {
 250                 kill($sig, $self->{pid} // $$);
 251         } else {
 252                 $code >>= 8;
 253                 if (my $sock = $self->{sock}) {
 254                         say $sock "exit=$code";
 255                 } else { # for oneshot
 256                         $quit->($code);
 257                 }
 258         }
 259 }
 260
 261 sub puts ($;@) { print { shift->{1} } map { "$_\n" } @_ }
 262
 263 sub out ($;@) { print { shift->{1} } @_ }
 264
 265 sub err ($;@) {
 266         print { shift->{2} } @_, (substr($_[-1], -1, 1) eq "\n" ? () : "\n");
 267 }
 268
 269 sub qerr ($;@) { $_[0]->{opt}->{quiet} or err(shift, @_) }
 270
 271 sub fail ($$;$) {
 272         my ($self, $buf, $exit_code) = @_;
 273         err($self, $buf);
 274         x_it($self, ($exit_code // 1) << 8);
 275         undef;
 276 }
 277
 278 sub _help ($;$) {
 279         my ($self, $errmsg) = @_;
 280         my $cmd = $self->{cmd} // 'COMMAND';
 281         my @info = @{$CMD{$cmd} // [ '...', '...' ]};
 282         my @top = ($cmd, shift(@info) // ());
 283         my $cmd_desc = shift(@info);
 284         $cmd_desc = $cmd_desc->($self->{env}) if ref($cmd_desc) eq 'CODE';
 285         my @opt_desc;
 286         my $lpad = 2;
 287         for my $sw (grep { !ref } @info) { # ("prio=s", "z", $GLP_PASS)
 288                 my $desc = $OPTDESC{"$cmd\t$sw"} // $OPTDESC{$sw} // next;
 289                 my $arg_vals = '';
 290                 ($arg_vals, $desc) = @$desc if ref($desc) eq 'ARRAY';
 291
 292                 # lower-case is a keyword (e.g. `content', `oid'),
 293                 # ALL_CAPS is a string description (e.g. `PATH')
 294                 if ($desc !~ /default/ && $arg_vals =~ /\b([a-z]+)[,\|]/) {
 295                         $desc .= "\ndefault: `$1'";
 296                 }
 297                 my (@vals, @s, @l);
 298                 my $x = $sw;
 299                 if ($x =~ s/!\z//) { # solve! => --no-solve
 300                         $x = "no-$x";
 301                 } elsif ($x =~ s/:.+//) { # optional args: $x = "mid:s"
 302                         @vals = (' [', undef, ']');
 303                 } elsif ($x =~ s/=.+//) { # required arg: $x = "type=s"
 304                         @vals = (' ', undef);
 305                 } # else: no args $x = 'thread|t'
 306                 for (split(/\|/, $x)) { # help|h
 307                         length($_) > 1 ? push(@l, "--$_") : push(@s, "-$_");
 308                 }
 309                 if (!scalar(@vals)) { # no args 'thread|t'
 310                 } elsif ($arg_vals =~ s/\A([A-Z_]+)\b//) { # "NAME"
 311                         $vals[1] = $1;
 312                 } else {
 313                         $vals[1] = uc(substr($l[0], 2)); # "--type" => "TYPE"
 314                 }
 315                 if ($arg_vals =~ /([,\|])/) {
 316                         my $sep = $1;
 317                         my @allow = split(/\Q$sep\E/, $arg_vals);
 318                         my $must = $sep eq '|' ? 'Must' : 'Can';
 319                         @allow = map { "`$_'" } @allow;
 320                         my $last = pop @allow;
 321                         $desc .= "\n$must be one of: " .
 322                                 join(', ', @allow) . " or $last";
 323                 }
 324                 my $lhs = join(', ', @s, @l) . join('', @vals);
 325                 if ($x =~ /\|\z/) { # "stdin|" or "clear|"
 326                         $lhs =~ s/\A--/- , --/;
 327                 } else {
 328                         $lhs =~ s/\A--/    --/; # pad if no short options
 329                 }
 330                 $lpad = length($lhs) if length($lhs) > $lpad;
 331                 push @opt_desc, $lhs, $desc;
 332         }
 333         my $msg = $errmsg ? "E: $errmsg\n" : '';
 334         $msg .= <<EOF;
 335 usage: lei @top
 336   $cmd_desc
 337
 338 EOF
 339         $lpad += 2;
 340         local $Text::Wrap::columns = 78 - $lpad;
 341         my $padding = ' ' x ($lpad + 2);
 342         while (my ($lhs, $rhs) = splice(@opt_desc, 0, 2)) {
 343                 $msg .= '  '.pack("A$lpad", $lhs);
 344                 $rhs = wrap('', '', $rhs);
 345                 $rhs =~ s/\n/\n$padding/sg; # LHS pad continuation lines
 346                 $msg .= $rhs;
 347                 $msg .= "\n";
 348         }
 349         print { $self->{$errmsg ? 2 : 1} } $msg;
 350         x_it($self, $errmsg ? 1 << 8 : 0); # stderr => failure
 351         undef;
 352 }
 353
 354 sub optparse ($$$) {
 355         my ($self, $cmd, $argv) = @_;
 356         $self->{cmd} = $cmd;
 357         $OPT = $self->{opt} = {};
 358         my $info = $CMD{$cmd} // [ '[...]' ];
 359         my ($proto, undef, @spec) = @$info;
 360         my $glp = ref($spec[-1]) eq ref($GLP) ? pop(@spec) : $GLP;
 361         push @spec, qw(help|h);
 362         my $lone_dash;
 363         if ($spec[0] =~ s/\|\z//s) { # "stdin|" or "clear|" allows "-" alias
 364                 $lone_dash = $spec[0];
 365                 $OPT->{$spec[0]} = \(my $var);
 366                 push @spec, '' => \$var;
 367         }
 368         $glp->getoptionsfromarray($argv, $OPT, @spec) or
 369                 return _help($self, "bad arguments or options for $cmd");
 370         return _help($self) if $OPT->{help};
 371
 372         push @$argv, @{$OPT->{-argv}} if defined($OPT->{-argv});
 373
 374         # "-" aliases "stdin" or "clear"
 375         $OPT->{$lone_dash} = ${$OPT->{$lone_dash}} if defined $lone_dash;
 376
 377         my $i = 0;
 378         my $POS_ARG = '[A-Z][A-Z0-9_]+';
 379         my ($err, $inf);
 380         my @args = split(/ /, $proto);
 381         for my $var (@args) {
 382                 if ($var =~ /\A$POS_ARG\.\.\.\z/o) { # >= 1 args;
 383                         $inf = defined($argv->[$i]) and last;
 384                         $var =~ s/\.\.\.\z//;
 385                         $err = "$var not supplied";
 386                 } elsif ($var =~ /\A$POS_ARG\z/o) { # required arg at $i
 387                         $argv->[$i++] // ($err = "$var not supplied");
 388                 } elsif ($var =~ /\.\.\.\]\z/) { # optional args start
 389                         $inf = 1;
 390                         last;
 391                 } elsif ($var =~ /\A\[-?$POS_ARG\]\z/) { # one optional arg
 392                         $i++;
 393                 } elsif ($var =~ /\A.+?\|/) { # required FOO|--stdin
 394                         my @or = split(/\|/, $var);
 395                         my $ok;
 396                         for my $o (@or) {
 397                                 if ($o =~ /\A--([a-z0-9\-]+)/) {
 398                                         $ok = defined($OPT->{$1});
 399                                         last;
 400                                 } elsif (defined($argv->[$i])) {
 401                                         $ok = 1;
 402                                         $i++;
 403                                         last;
 404                                 } # else continue looping
 405                         }
 406                         my $last = pop @or;
 407                         $err = join(', ', @or) . " or $last must be set";
 408                 } else {
 409                         warn "BUG: can't parse `$var' in $proto";
 410                 }
 411                 last if $err;
 412         }
 413         if (!$inf && scalar(@$argv) > scalar(@args)) {
 414                 $err //= 'too many arguments';
 415         }
 416         $err ? fail($self, "usage: lei $cmd $proto\nE: $err") : 1;
 417 }
 418
 419 sub dispatch {
 420         my ($self, $cmd, @argv) = @_;
 421         local $SIG{__WARN__} = sub { err($self, @_) };
 422         return _help($self, 'no command given') unless defined($cmd);
 423         my $func = "lei_$cmd";
 424         $func =~ tr/-/_/;
 425         if (my $cb = __PACKAGE__->can($func)) {
 426                 optparse($self, $cmd, \@argv) or return;
 427                 $cb->($self, @argv);
 428         } elsif (grep(/\A-/, $cmd, @argv)) { # --help or -h only
 429                 my $opt = {};
 430                 $GLP->getoptionsfromarray([$cmd, @argv], $opt, qw(help|h)) or
 431                         return _help($self, 'bad arguments or options');
 432                 _help($self);
 433         } else {
 434                 fail($self, "`$cmd' is not an lei command");
 435         }
 436 }
 437
 438 sub _lei_cfg ($;$) {
 439         my ($self, $creat) = @_;
 440         my $f = _config_path($self->{env});
 441         my @st = stat($f);
 442         my $cur_st = @st ? pack('dd', $st[10], $st[7]) : ''; # 10:ctime, 7:size
 443         if (my $cfg = $PATH2CFG{$f}) { # reuse existing object in common case
 444                 return ($self->{cfg} = $cfg) if $cur_st eq $cfg->{-st};
 445         }
 446         if (!@st) {
 447                 unless ($creat) {
 448                         delete $self->{cfg};
 449                         return;
 450                 }
 451                 my (undef, $cfg_dir, undef) = File::Spec->splitpath($f);
 452                 -d $cfg_dir or mkpath($cfg_dir) or die "mkpath($cfg_dir): $!\n";
 453                 open my $fh, '>>', $f or die "open($f): $!\n";
 454                 @st = stat($fh) or die "fstat($f): $!\n";
 455                 $cur_st = pack('dd', $st[10], $st[7]);
 456                 qerr($self, "I: $f created") if $self->{cmd} ne 'config';
 457         }
 458         my $cfg = PublicInbox::Config::git_config_dump($f);
 459         $cfg->{-st} = $cur_st;
 460         $cfg->{'-f'} = $f;
 461         $self->{cfg} = $PATH2CFG{$f} = $cfg;
 462 }
 463
 464 sub _lei_store ($;$) {
 465         my ($self, $creat) = @_;
 466         my $cfg = _lei_cfg($self, $creat);
 467         $cfg->{-lei_store} //= do {
 468                 require PublicInbox::LeiStore;
 469                 my $dir = $cfg->{'leistore.dir'};
 470                 $dir //= _store_path($self->{env}) if $creat;
 471                 return unless $dir;
 472                 PublicInbox::LeiStore->new($dir, { creat => $creat });
 473         };
 474 }
 475
 476 sub lei_show {
 477         my ($self, @argv) = @_;
 478 }
 479
 480 sub lei_query {
 481         my ($self, @argv) = @_;
 482 }
 483
 484 sub lei_mark {
 485         my ($self, @argv) = @_;
 486 }
 487
 488 sub lei_config {
 489         my ($self, @argv) = @_;
 490         $self->{opt}->{'config-file'} and return fail $self,
 491                 "config file switches not supported by `lei config'";
 492         my $env = $self->{env};
 493         delete local $env->{GIT_CONFIG};
 494         my $cfg = _lei_cfg($self, 1);
 495         my $cmd = [ qw(git config -f), $cfg->{'-f'}, @argv ];
 496         my %rdr = map { $_ => $self->{$_} } (0..2);
 497         run_die($cmd, $env, \%rdr);
 498 }
 499
 500 sub lei_init {
 501         my ($self, $dir) = @_;
 502         my $cfg = _lei_cfg($self, 1);
 503         my $cur = $cfg->{'leistore.dir'};
 504         my $env = $self->{env};
 505         $dir //= _store_path($env);
 506         $dir = File::Spec->rel2abs($dir, $env->{PWD}); # PWD is symlink-aware
 507         my @cur = stat($cur) if defined($cur);
 508         $cur = File::Spec->canonpath($cur // $dir);
 509         my @dir = stat($dir);
 510         my $exists = "I: leistore.dir=$cur already initialized" if @dir;
 511         if (@cur) {
 512                 if ($cur eq $dir) {
 513                         _lei_store($self, 1)->done;
 514                         return qerr($self, $exists);
 515                 }
 516
 517                 # some folks like symlinks and bind mounts :P
 518                 if (@dir && "$cur[0] $cur[1]" eq "$dir[0] $dir[1]") {
 519                         lei_config($self, 'leistore.dir', $dir);
 520                         _lei_store($self, 1)->done;
 521                         return qerr($self, "$exists (as $cur)");
 522                 }
 523                 return fail($self, <<"");
 524 E: leistore.dir=$cur already initialized and it is not $dir
 525
 526         }
 527         lei_config($self, 'leistore.dir', $dir);
 528         _lei_store($self, 1)->done;
 529         $exists //= "I: leistore.dir=$dir newly initialized";
 530         return qerr($self, $exists);
 531 }
 532
 533 sub lei_daemon_pid { puts shift, $$ }
 534
 535 sub lei_daemon_kill {
 536         my ($self) = @_;
 537         my $sig = $self->{opt}->{signal} // 'TERM';
 538         kill($sig, $$) or fail($self, "kill($sig, $$): $!");
 539 }
 540
 541 sub lei_daemon_env {
 542         my ($self, @argv) = @_;
 543         my $opt = $self->{opt};
 544         if (defined $opt->{clear}) {
 545                 %ENV = ();
 546         } elsif (my $u = $opt->{unset}) {
 547                 delete @ENV{@$u};
 548         }
 549         if (@argv) {
 550                 %ENV = (%ENV, map { split(/=/, $_, 2) } @argv);
 551         } elsif (!defined($opt->{clear}) && !$opt->{unset}) {
 552                 my $eor = $opt->{z} ? "\0" : "\n";
 553                 my $buf = '';
 554                 while (my ($k, $v) = each %ENV) { $buf .= "$k=$v$eor" }
 555                 out $self, $buf;
 556         }
 557 }
 558
 559 sub lei_help { _help($_[0]) }
 560
 561 # Shell completion helper.  Used by lei-completion.bash and hopefully
 562 # other shells.  Try to do as much here as possible to avoid redundancy
 563 # and improve maintainability.
 564 sub lei__complete {
 565         my ($self, @argv) = @_; # argv = qw(lei and any other args...)
 566         shift @argv; # ignore "lei", the entire command is sent
 567         @argv or return puts $self, grep(!/^_/, keys %CMD), qw(--help -h);
 568         my $cmd = shift @argv;
 569         my $info = $CMD{$cmd} // do { # filter matching commands
 570                 @argv or puts $self, grep(/\A\Q$cmd\E/, keys %CMD);
 571                 return;
 572         };
 573         my ($proto, undef, @spec) = @$info;
 574         my $cur = pop @argv;
 575         my $re = defined($cur) ? qr/\A\Q$cur\E/ : qr/./;
 576         if (substr($cur // '-', 0, 1) eq '-') { # --switches
 577                 # gross special case since the only git-config options
 578                 # Consider moving to a table if we need more special cases
 579                 # we use Getopt::Long for are the ones we reject, so these
 580                 # are the ones we don't reject:
 581                 if ($cmd eq 'config') {
 582                         puts $self, grep(/$re/, keys %CONFIG_KEYS);
 583                         @spec = qw(add z|null get get-all unset unset-all
 584                                 replace-all get-urlmatch
 585                                 remove-section rename-section
 586                                 name-only list|l edit|e
 587                                 get-color-name get-colorbool);
 588                         # fall-through
 589                 }
 590                 # TODO: arg support
 591                 puts $self, grep(/$re/, map { # generate short/long names
 592                         my $eq = '';
 593                         if (s/=.+\z//) { # required arg, e.g. output|o=i
 594                                 $eq = '=';
 595                         } elsif (s/:.+\z//) { # optional arg, e.g. mid:s
 596                         } else { # negation: solve! => no-solve|solve
 597                                 s/\A(.+)!\z/no-$1|$1/;
 598                         }
 599                         map {
 600                                 length > 1 ? "--$_$eq" : "-$_"
 601                         } split(/\|/, $_, -1) # help|h
 602                 } grep { $OPTDESC{"$cmd\t$_"} || $OPTDESC{$_} } @spec);
 603         } elsif ($cmd eq 'config' && !@argv && !$CONFIG_KEYS{$cur}) {
 604                 puts $self, grep(/$re/, keys %CONFIG_KEYS);
 605         }
 606         # TODO: URLs, pathnames, OIDs, MIDs, etc...  See optparse() for
 607         # proto parsing.
 608 }
 609
 610 sub reap_exec { # dwaitpid callback
 611         my ($self, $pid) = @_;
 612         x_it($self, $?);
 613 }
 614
 615 sub lei_git { # support passing through random git commands
 616         my ($self, @argv) = @_;
 617         my %rdr = map { $_ => $self->{$_} } (0..2);
 618         my $pid = spawn(['git', @argv], $self->{env}, \%rdr);
 619         dwaitpid($pid, \&reap_exec, $self);
 620 }
 621
 622 sub accept_dispatch { # Listener {post_accept} callback
 623         my ($sock) = @_; # ignore other
 624         $sock->blocking(1);
 625         $sock->autoflush(1);
 626         my $self = bless { sock => $sock }, __PACKAGE__;
 627         vec(my $rin = '', fileno($sock), 1) = 1;
 628         # `say $sock' triggers "die" in lei(1)
 629         if (select(my $rout = $rin, undef, undef, 1)) {
 630                 my @fds = $recv_3fds->(fileno($sock));
 631                 if (scalar(@fds) == 3) {
 632                         my $i = 0;
 633                         for my $rdr (qw(<&= >&= >&=)) {
 634                                 my $fd = shift(@fds);
 635                                 if (open(my $fh, $rdr, $fd)) {
 636                                         $self->{$i++} = $fh;
 637                                 }  else {
 638                                         say $sock "open($rdr$fd) (FD=$i): $!";
 639                                         return;
 640                                 }
 641                         }
 642                 } else {
 643                         say $sock "recv_3fds failed: $!";
 644                         return;
 645                 }
 646         } else {
 647                 say $sock "timed out waiting to recv FDs";
 648                 return;
 649         }
 650         $self->{2}->autoflush(1); # keep stdout buffered until x_it|DESTROY
 651         # $ARGV_STR = join("]\0[", @ARGV);
 652         # $ENV_STR = join('', map { "$_=$ENV{$_}\0" } keys %ENV);
 653         # $line = "$$\0\0>$ARGV_STR\0\0>$ENV_STR\0\0";
 654         my ($client_pid, $argv, $env) = do {
 655                 local $/ = "\0\0\0"; # yes, 3 NULs at EOL, not 2
 656                 chomp(my $line = <$sock>);
 657                 split(/\0\0>/, $line, 3);
 658         };
 659         my %env = map { split(/=/, $_, 2) } split(/\0/, $env);
 660         if (chdir($env{PWD})) {
 661                 $self->{env} = \%env;
 662                 $self->{pid} = $client_pid;
 663                 eval { dispatch($self, split(/\]\0\[/, $argv)) };
 664                 say $sock $@ if $@;
 665         } else {
 666                 say $sock "chdir($env{PWD}): $!"; # implicit close
 667         }
 668 }
 669
 670 sub noop {}
 671
 672 # lei(1) calls this when it can't connect
 673 sub lazy_start {
 674         my ($path, $errno, $nfd) = @_;
 675         if ($errno == ECONNREFUSED) {
 676                 unlink($path) or die "unlink($path): $!";
 677         } elsif ($errno != ENOENT) {
 678                 $! = $errno; # allow interpolation to stringify in die
 679                 die "connect($path): $!";
 680         }
 681         umask(077) // die("umask(077): $!");
 682         socket(my $l, AF_UNIX, SOCK_STREAM, 0) or die "socket: $!";
 683         bind($l, pack_sockaddr_un($path)) or die "bind($path): $!";
 684         listen($l, 1024) or die "listen: $!";
 685         my @st = stat($path) or die "stat($path): $!";
 686         my $dev_ino_expect = pack('dd', $st[0], $st[1]); # dev+ino
 687         pipe(my ($eof_r, $eof_w)) or die "pipe: $!";
 688         my $oldset = PublicInbox::Sigfd::block_signals();
 689         if ($nfd == 1) {
 690                 require IO::FDPass;
 691                 $recv_3fds = sub { map { IO::FDPass::recv($_[0]) } (0..2) };
 692         } elsif ($nfd == 3) {
 693                 $recv_3fds = PublicInbox::Spawn->can('recv_3fds');
 694         }
 695         $recv_3fds or die
 696                 "IO::FDPass missing or Inline::C not installed/configured\n";
 697         require PublicInbox::Listener;
 698         require PublicInbox::EOFpipe;
 699         (-p STDOUT) or die "E: stdout must be a pipe\n";
 700         open(STDIN, '+<', '/dev/null') or die "redirect stdin failed: $!";
 701         POSIX::setsid() > 0 or die "setsid: $!";
 702         my $pid = fork // die "fork: $!";
 703         return if $pid;
 704         $0 = "lei-daemon $path";
 705         local %PATH2CFG;
 706         $_->blocking(0) for ($l, $eof_r, $eof_w);
 707         $l = PublicInbox::Listener->new($l, \&accept_dispatch, $l);
 708         my $exit_code;
 709         local $quit = sub {
 710                 $exit_code //= shift;
 711                 my $listener = $l or exit($exit_code);
 712                 unlink($path) if defined($path);
 713                 # closing eof_w triggers \&noop wakeup
 714                 $eof_w = $l = $path = undef;
 715                 $listener->close; # DS::close
 716                 PublicInbox::DS->SetLoopTimeout(1000);
 717         };
 718         PublicInbox::EOFpipe->new($eof_r, \&noop, undef);
 719         my $sig = {
 720                 CHLD => \&PublicInbox::DS::enqueue_reap,
 721                 QUIT => $quit,
 722                 INT => $quit,
 723                 TERM => $quit,
 724                 HUP => \&noop,
 725                 USR1 => \&noop,
 726                 USR2 => \&noop,
 727         };
 728         my $sigfd = PublicInbox::Sigfd->new($sig, SFD_NONBLOCK);
 729         local %SIG = (%SIG, %$sig) if !$sigfd;
 730         if ($sigfd) { # TODO: use inotify/kqueue to detect unlinked sockets
 731                 PublicInbox::DS->SetLoopTimeout(5000);
 732         } else {
 733                 # wake up every second to accept signals if we don't
 734                 # have signalfd or IO::KQueue:
 735                 PublicInbox::Sigfd::sig_setmask($oldset);
 736                 PublicInbox::DS->SetLoopTimeout(1000);
 737         }
 738         PublicInbox::DS->SetPostLoopCallback(sub {
 739                 my ($dmap, undef) = @_;
 740                 if (@st = defined($path) ? stat($path) : ()) {
 741                         if ($dev_ino_expect ne pack('dd', $st[0], $st[1])) {
 742                                 warn "$path dev/ino changed, quitting\n";
 743                                 $path = undef;
 744                         }
 745                 } elsif (defined($path)) {
 746                         warn "stat($path): $!, quitting ...\n";
 747                         undef $path; # don't unlink
 748                         $quit->();
 749                 }
 750                 return 1 if defined($path);
 751                 my $now = now();
 752                 my $n = 0;
 753                 for my $s (values %$dmap) {
 754                         $s->can('busy') or next;
 755                         if ($s->busy($now)) {
 756                                 ++$n;
 757                         } else {
 758                                 $s->close;
 759                         }
 760                 }
 761                 $n; # true: continue, false: stop
 762         });
 763
 764         # STDIN was redirected to /dev/null above, closing STDERR and
 765         # STDOUT will cause the calling `lei' client process to finish
 766         # reading the <$daemon> pipe.
 767         openlog($path, 'pid', 'user');
 768         local $SIG{__WARN__} = sub { syslog('warning', "@_") };
 769         my $on_destroy = PublicInbox::OnDestroy->new($$, sub {
 770                 syslog('crit', "$@") if $@;
 771         });
 772         open STDERR, '>&STDIN' or die "redirect stderr failed: $!";
 773         open STDOUT, '>&STDIN' or die "redirect stdout failed: $!";
 774         # $daemon pipe to `lei' closed, main loop begins:
 775         PublicInbox::DS->EventLoop;
 776         @$on_destroy = (); # cancel on_destroy if we get here
 777         exit($exit_code // 0);
 778 }
 779
 780 # for users w/o IO::FDPass
 781 sub oneshot {
 782         my ($main_pkg) = @_;
 783         my $exit = $main_pkg->can('exit'); # caller may override exit()
 784         local $quit = $exit if $exit;
 785         local %PATH2CFG;
 786         umask(077) // die("umask(077): $!");
 787         dispatch((bless {
 788                 0 => *STDIN{IO},
 789                 1 => *STDOUT{IO},
 790                 2 => *STDERR{IO},
 791                 env => \%ENV
 792         }, __PACKAGE__), @ARGV);
 793 }
 794
 795 # ensures stdout hits the FS before sock disconnects so a client
 796 # can immediately reread it
 797 sub DESTROY { $_[0]->{1}->autoflush(1) }
 798
 799 1;